src/HOL/Lim.thy
author huffman
Tue Aug 16 09:31:23 2011 -0700 (2011-08-16)
changeset 44233 aa74ce315bae
parent 44218 f0e442e24816
child 44251 d101ed3177b6
permissions -rw-r--r--
add simp rules for isCont
     1 (*  Title       : Lim.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     5 *)
     6 
     7 header{* Limits and Continuity *}
     8 
     9 theory Lim
    10 imports SEQ
    11 begin
    12 
    13 text{*Standard Definitions*}
    14 
    15 abbreviation
    16   LIM :: "['a::topological_space \<Rightarrow> 'b::topological_space, 'a, 'b] \<Rightarrow> bool"
    17         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
    18   "f -- a --> L \<equiv> (f ---> L) (at a)"
    19 
    20 definition
    21   isCont :: "['a::topological_space \<Rightarrow> 'b::topological_space, 'a] \<Rightarrow> bool" where
    22   "isCont f a = (f -- a --> (f a))"
    23 
    24 definition
    25   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
    26   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
    27 
    28 subsection {* Limits of Functions *}
    29 
    30 lemma LIM_def: "f -- a --> L =
    31      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
    32         --> dist (f x) L < r)"
    33 unfolding tendsto_iff eventually_at ..
    34 
    35 lemma metric_LIM_I:
    36   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
    37     \<Longrightarrow> f -- a --> L"
    38 by (simp add: LIM_def)
    39 
    40 lemma metric_LIM_D:
    41   "\<lbrakk>f -- a --> L; 0 < r\<rbrakk>
    42     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
    43 by (simp add: LIM_def)
    44 
    45 lemma LIM_eq:
    46   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
    47   shows "f -- a --> L =
    48      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
    49 by (simp add: LIM_def dist_norm)
    50 
    51 lemma LIM_I:
    52   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
    53   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
    54       ==> f -- a --> L"
    55 by (simp add: LIM_eq)
    56 
    57 lemma LIM_D:
    58   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
    59   shows "[| f -- a --> L; 0<r |]
    60       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
    61 by (simp add: LIM_eq)
    62 
    63 lemma LIM_offset:
    64   fixes a :: "'a::real_normed_vector"
    65   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
    66 apply (rule topological_tendstoI)
    67 apply (drule (2) topological_tendstoD)
    68 apply (simp only: eventually_at dist_norm)
    69 apply (clarify, rule_tac x=d in exI, safe)
    70 apply (drule_tac x="x + k" in spec)
    71 apply (simp add: algebra_simps)
    72 done
    73 
    74 lemma LIM_offset_zero:
    75   fixes a :: "'a::real_normed_vector"
    76   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
    77 by (drule_tac k="a" in LIM_offset, simp add: add_commute)
    78 
    79 lemma LIM_offset_zero_cancel:
    80   fixes a :: "'a::real_normed_vector"
    81   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
    82 by (drule_tac k="- a" in LIM_offset, simp)
    83 
    84 lemma LIM_const [simp]: "(%x. k) -- x --> k"
    85 by (rule tendsto_const)
    86 
    87 lemma LIM_cong_limit: "\<lbrakk> f -- x --> L ; K = L \<rbrakk> \<Longrightarrow> f -- x --> K" by simp
    88 
    89 lemma LIM_add:
    90   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
    91   assumes f: "f -- a --> L" and g: "g -- a --> M"
    92   shows "(\<lambda>x. f x + g x) -- a --> (L + M)"
    93 using assms by (rule tendsto_add)
    94 
    95 lemma LIM_add_zero:
    96   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
    97   shows "\<lbrakk>f -- a --> 0; g -- a --> 0\<rbrakk> \<Longrightarrow> (\<lambda>x. f x + g x) -- a --> 0"
    98   by (rule tendsto_add_zero)
    99 
   100 lemma LIM_minus:
   101   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   102   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. - f x) -- a --> - L"
   103 by (rule tendsto_minus)
   104 
   105 (* TODO: delete *)
   106 lemma LIM_add_minus:
   107   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   108   shows "[| f -- x --> l; g -- x --> m |] ==> (%x. f(x) + -g(x)) -- x --> (l + -m)"
   109 by (intro LIM_add LIM_minus)
   110 
   111 lemma LIM_diff:
   112   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   113   shows "\<lbrakk>f -- x --> l; g -- x --> m\<rbrakk> \<Longrightarrow> (\<lambda>x. f x - g x) -- x --> l - m"
   114 by (rule tendsto_diff)
   115 
   116 lemma LIM_zero:
   117   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   118   shows "f -- a --> l \<Longrightarrow> (\<lambda>x. f x - l) -- a --> 0"
   119 unfolding tendsto_iff dist_norm by simp
   120 
   121 lemma LIM_zero_cancel:
   122   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   123   shows "(\<lambda>x. f x - l) -- a --> 0 \<Longrightarrow> f -- a --> l"
   124 unfolding tendsto_iff dist_norm by simp
   125 
   126 lemma LIM_zero_iff:
   127   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
   128   shows "(\<lambda>x. f x - l) -- a --> 0 = f -- a --> l"
   129 unfolding tendsto_iff dist_norm by simp
   130 
   131 lemma metric_LIM_imp_LIM:
   132   assumes f: "f -- a --> l"
   133   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
   134   shows "g -- a --> m"
   135 apply (rule tendstoI, drule tendstoD [OF f])
   136 apply (simp add: eventually_at_topological, safe)
   137 apply (rule_tac x="S" in exI, safe)
   138 apply (drule_tac x="x" in bspec, safe)
   139 apply (erule (1) order_le_less_trans [OF le])
   140 done
   141 
   142 lemma LIM_imp_LIM:
   143   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   144   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
   145   assumes f: "f -- a --> l"
   146   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
   147   shows "g -- a --> m"
   148 apply (rule metric_LIM_imp_LIM [OF f])
   149 apply (simp add: dist_norm le)
   150 done
   151 
   152 lemma LIM_norm:
   153   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   154   shows "f -- a --> l \<Longrightarrow> (\<lambda>x. norm (f x)) -- a --> norm l"
   155 by (rule tendsto_norm)
   156 
   157 lemma LIM_norm_zero:
   158   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   159   shows "f -- a --> 0 \<Longrightarrow> (\<lambda>x. norm (f x)) -- a --> 0"
   160 by (rule tendsto_norm_zero)
   161 
   162 lemma LIM_norm_zero_cancel:
   163   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   164   shows "(\<lambda>x. norm (f x)) -- a --> 0 \<Longrightarrow> f -- a --> 0"
   165 by (rule tendsto_norm_zero_cancel)
   166 
   167 lemma LIM_norm_zero_iff:
   168   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   169   shows "(\<lambda>x. norm (f x)) -- a --> 0 = f -- a --> 0"
   170 by (rule tendsto_norm_zero_iff)
   171 
   172 lemma LIM_rabs: "f -- a --> (l::real) \<Longrightarrow> (\<lambda>x. \<bar>f x\<bar>) -- a --> \<bar>l\<bar>"
   173   by (rule tendsto_rabs)
   174 
   175 lemma LIM_rabs_zero: "f -- a --> (0::real) \<Longrightarrow> (\<lambda>x. \<bar>f x\<bar>) -- a --> 0"
   176   by (rule tendsto_rabs_zero)
   177 
   178 lemma LIM_rabs_zero_cancel: "(\<lambda>x. \<bar>f x\<bar>) -- a --> (0::real) \<Longrightarrow> f -- a --> 0"
   179   by (rule tendsto_rabs_zero_cancel)
   180 
   181 lemma LIM_rabs_zero_iff: "(\<lambda>x. \<bar>f x\<bar>) -- a --> (0::real) = f -- a --> 0"
   182   by (rule tendsto_rabs_zero_iff)
   183 
   184 lemma trivial_limit_at:
   185   fixes a :: "'a::real_normed_algebra_1"
   186   shows "\<not> trivial_limit (at a)"  -- {* TODO: find a more appropriate class *}
   187 unfolding trivial_limit_def
   188 unfolding eventually_at dist_norm
   189 by (clarsimp, rule_tac x="a + of_real (d/2)" in exI, simp)
   190 
   191 lemma LIM_const_not_eq:
   192   fixes a :: "'a::real_normed_algebra_1"
   193   fixes k L :: "'b::t2_space"
   194   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
   195 by (simp add: tendsto_const_iff trivial_limit_at)
   196 
   197 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
   198 
   199 lemma LIM_const_eq:
   200   fixes a :: "'a::real_normed_algebra_1"
   201   fixes k L :: "'b::t2_space"
   202   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
   203   by (simp add: tendsto_const_iff trivial_limit_at)
   204 
   205 lemma LIM_unique:
   206   fixes a :: "'a::real_normed_algebra_1" -- {* TODO: find a more appropriate class *}
   207   fixes L M :: "'b::t2_space"
   208   shows "\<lbrakk>f -- a --> L; f -- a --> M\<rbrakk> \<Longrightarrow> L = M"
   209   using trivial_limit_at by (rule tendsto_unique)
   210 
   211 lemma LIM_ident [simp]: "(\<lambda>x. x) -- a --> a"
   212 by (rule tendsto_ident_at)
   213 
   214 text{*Limits are equal for functions equal except at limit point*}
   215 lemma LIM_equal:
   216      "[| \<forall>x. x \<noteq> a --> (f x = g x) |] ==> (f -- a --> l) = (g -- a --> l)"
   217 unfolding tendsto_def eventually_at_topological by simp
   218 
   219 lemma LIM_cong:
   220   "\<lbrakk>a = b; \<And>x. x \<noteq> b \<Longrightarrow> f x = g x; l = m\<rbrakk>
   221    \<Longrightarrow> ((\<lambda>x. f x) -- a --> l) = ((\<lambda>x. g x) -- b --> m)"
   222 by (simp add: LIM_equal)
   223 
   224 lemma metric_LIM_equal2:
   225   assumes 1: "0 < R"
   226   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
   227   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
   228 apply (rule topological_tendstoI)
   229 apply (drule (2) topological_tendstoD)
   230 apply (simp add: eventually_at, safe)
   231 apply (rule_tac x="min d R" in exI, safe)
   232 apply (simp add: 1)
   233 apply (simp add: 2)
   234 done
   235 
   236 lemma LIM_equal2:
   237   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
   238   assumes 1: "0 < R"
   239   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
   240   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
   241 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
   242 
   243 text{*Two uses in Transcendental.ML*} (* BH: no longer true; delete? *)
   244 lemma LIM_trans:
   245   fixes f g :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
   246   shows "[| (%x. f(x) + -g(x)) -- a --> 0;  g -- a --> l |] ==> f -- a --> l"
   247 apply (drule LIM_add, assumption)
   248 apply (auto simp add: add_assoc)
   249 done
   250 
   251 lemma LIM_compose:
   252   assumes g: "g -- l --> g l"
   253   assumes f: "f -- a --> l"
   254   shows "(\<lambda>x. g (f x)) -- a --> g l"
   255   using assms by (rule tendsto_compose)
   256 
   257 lemma LIM_compose_eventually:
   258   assumes f: "f -- a --> b"
   259   assumes g: "g -- b --> c"
   260   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
   261   shows "(\<lambda>x. g (f x)) -- a --> c"
   262 proof (rule topological_tendstoI)
   263   fix C assume C: "open C" "c \<in> C"
   264   obtain B where B: "open B" "b \<in> B"
   265     and gC: "\<And>y. y \<in> B \<Longrightarrow> y \<noteq> b \<Longrightarrow> g y \<in> C"
   266     using topological_tendstoD [OF g C]
   267     unfolding eventually_at_topological by fast
   268   obtain A where A: "open A" "a \<in> A"
   269     and fB: "\<And>x. x \<in> A \<Longrightarrow> x \<noteq> a \<Longrightarrow> f x \<in> B"
   270     using topological_tendstoD [OF f B]
   271     unfolding eventually_at_topological by fast
   272   have "eventually (\<lambda>x. f x \<noteq> b \<longrightarrow> g (f x) \<in> C) (at a)"
   273   unfolding eventually_at_topological
   274   proof (intro exI conjI ballI impI)
   275     show "open A" and "a \<in> A" using A .
   276   next
   277     fix x assume "x \<in> A" and "x \<noteq> a" and "f x \<noteq> b"
   278     then show "g (f x) \<in> C" by (simp add: gC fB)
   279   qed
   280   with inj show "eventually (\<lambda>x. g (f x) \<in> C) (at a)"
   281     by (rule eventually_rev_mp)
   282 qed
   283 
   284 lemma metric_LIM_compose2:
   285   assumes f: "f -- a --> b"
   286   assumes g: "g -- b --> c"
   287   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
   288   shows "(\<lambda>x. g (f x)) -- a --> c"
   289 using f g inj [folded eventually_at]
   290 by (rule LIM_compose_eventually)
   291 
   292 lemma LIM_compose2:
   293   fixes a :: "'a::real_normed_vector"
   294   assumes f: "f -- a --> b"
   295   assumes g: "g -- b --> c"
   296   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
   297   shows "(\<lambda>x. g (f x)) -- a --> c"
   298 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
   299 
   300 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
   301 unfolding o_def by (rule LIM_compose)
   302 
   303 lemma real_LIM_sandwich_zero:
   304   fixes f g :: "'a::topological_space \<Rightarrow> real"
   305   assumes f: "f -- a --> 0"
   306   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
   307   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
   308   shows "g -- a --> 0"
   309 proof (rule LIM_imp_LIM [OF f])
   310   fix x assume x: "x \<noteq> a"
   311   have "norm (g x - 0) = g x" by (simp add: 1 x)
   312   also have "g x \<le> f x" by (rule 2 [OF x])
   313   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
   314   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
   315   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
   316 qed
   317 
   318 text {* Bounded Linear Operators *}
   319 
   320 lemma (in bounded_linear) LIM:
   321   "g -- a --> l \<Longrightarrow> (\<lambda>x. f (g x)) -- a --> f l"
   322 by (rule tendsto)
   323 
   324 lemma (in bounded_linear) LIM_zero:
   325   "g -- a --> 0 \<Longrightarrow> (\<lambda>x. f (g x)) -- a --> 0"
   326   by (rule tendsto_zero)
   327 
   328 text {* Bounded Bilinear Operators *}
   329 
   330 lemma (in bounded_bilinear) LIM:
   331   "\<lbrakk>f -- a --> L; g -- a --> M\<rbrakk> \<Longrightarrow> (\<lambda>x. f x ** g x) -- a --> L ** M"
   332 by (rule tendsto)
   333 
   334 lemma (in bounded_bilinear) LIM_prod_zero:
   335   fixes a :: "'d::metric_space"
   336   assumes f: "f -- a --> 0"
   337   assumes g: "g -- a --> 0"
   338   shows "(\<lambda>x. f x ** g x) -- a --> 0"
   339   using f g by (rule tendsto_zero)
   340 
   341 lemma (in bounded_bilinear) LIM_left_zero:
   342   "f -- a --> 0 \<Longrightarrow> (\<lambda>x. f x ** c) -- a --> 0"
   343   by (rule tendsto_left_zero)
   344 
   345 lemma (in bounded_bilinear) LIM_right_zero:
   346   "f -- a --> 0 \<Longrightarrow> (\<lambda>x. c ** f x) -- a --> 0"
   347   by (rule tendsto_right_zero)
   348 
   349 lemmas LIM_mult = mult.LIM
   350 
   351 lemmas LIM_mult_zero = mult.LIM_prod_zero
   352 
   353 lemmas LIM_mult_left_zero = mult.LIM_left_zero
   354 
   355 lemmas LIM_mult_right_zero = mult.LIM_right_zero
   356 
   357 lemmas LIM_scaleR = scaleR.LIM
   358 
   359 lemmas LIM_of_real = of_real.LIM
   360 
   361 lemma LIM_power:
   362   fixes f :: "'a::topological_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   363   assumes f: "f -- a --> l"
   364   shows "(\<lambda>x. f x ^ n) -- a --> l ^ n"
   365   using assms by (rule tendsto_power)
   366 
   367 lemma LIM_inverse:
   368   fixes L :: "'a::real_normed_div_algebra"
   369   shows "\<lbrakk>f -- a --> L; L \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>x. inverse (f x)) -- a --> inverse L"
   370 by (rule tendsto_inverse)
   371 
   372 lemma LIM_inverse_fun:
   373   assumes a: "a \<noteq> (0::'a::real_normed_div_algebra)"
   374   shows "inverse -- a --> inverse a"
   375 by (rule LIM_inverse [OF LIM_ident a])
   376 
   377 lemma LIM_sgn:
   378   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   379   shows "\<lbrakk>f -- a --> l; l \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>x. sgn (f x)) -- a --> sgn l"
   380   by (rule tendsto_sgn)
   381 
   382 
   383 subsection {* Continuity *}
   384 
   385 lemma LIM_isCont_iff:
   386   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
   387   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
   388 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
   389 
   390 lemma isCont_iff:
   391   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
   392   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
   393 by (simp add: isCont_def LIM_isCont_iff)
   394 
   395 lemma isCont_ident [simp]: "isCont (\<lambda>x. x) a"
   396   unfolding isCont_def by (rule LIM_ident)
   397 
   398 lemma isCont_const [simp]: "isCont (\<lambda>x. k) a"
   399   unfolding isCont_def by (rule LIM_const)
   400 
   401 lemma isCont_norm [simp]:
   402   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   403   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
   404   unfolding isCont_def by (rule LIM_norm)
   405 
   406 lemma isCont_rabs [simp]:
   407   fixes f :: "'a::topological_space \<Rightarrow> real"
   408   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
   409   unfolding isCont_def by (rule LIM_rabs)
   410 
   411 lemma isCont_add [simp]:
   412   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   413   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
   414   unfolding isCont_def by (rule LIM_add)
   415 
   416 lemma isCont_minus [simp]:
   417   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   418   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
   419   unfolding isCont_def by (rule LIM_minus)
   420 
   421 lemma isCont_diff [simp]:
   422   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   423   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
   424   unfolding isCont_def by (rule LIM_diff)
   425 
   426 lemma isCont_mult [simp]:
   427   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_algebra"
   428   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
   429   unfolding isCont_def by (rule LIM_mult)
   430 
   431 lemma isCont_inverse [simp]:
   432   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   433   shows "\<lbrakk>isCont f a; f a \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. inverse (f x)) a"
   434   unfolding isCont_def by (rule LIM_inverse)
   435 
   436 lemma isCont_divide [simp]:
   437   fixes f g :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   438   shows "\<lbrakk>isCont f a; isCont g a; g a \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x / g x) a"
   439   unfolding isCont_def by (rule tendsto_divide)
   440 
   441 lemma isCont_LIM_compose:
   442   "\<lbrakk>isCont g l; f -- a --> l\<rbrakk> \<Longrightarrow> (\<lambda>x. g (f x)) -- a --> g l"
   443   unfolding isCont_def by (rule LIM_compose)
   444 
   445 lemma metric_isCont_LIM_compose2:
   446   assumes f [unfolded isCont_def]: "isCont f a"
   447   assumes g: "g -- f a --> l"
   448   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
   449   shows "(\<lambda>x. g (f x)) -- a --> l"
   450 by (rule metric_LIM_compose2 [OF f g inj])
   451 
   452 lemma isCont_LIM_compose2:
   453   fixes a :: "'a::real_normed_vector"
   454   assumes f [unfolded isCont_def]: "isCont f a"
   455   assumes g: "g -- f a --> l"
   456   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
   457   shows "(\<lambda>x. g (f x)) -- a --> l"
   458 by (rule LIM_compose2 [OF f g inj])
   459 
   460 lemma isCont_o2: "\<lbrakk>isCont f a; isCont g (f a)\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
   461   unfolding isCont_def by (rule LIM_compose)
   462 
   463 lemma isCont_o: "\<lbrakk>isCont f a; isCont g (f a)\<rbrakk> \<Longrightarrow> isCont (g o f) a"
   464   unfolding o_def by (rule isCont_o2)
   465 
   466 lemma (in bounded_linear) isCont:
   467   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
   468   unfolding isCont_def by (rule LIM)
   469 
   470 lemma (in bounded_bilinear) isCont:
   471   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
   472   unfolding isCont_def by (rule LIM)
   473 
   474 lemmas isCont_scaleR [simp] = scaleR.isCont
   475 
   476 lemma isCont_of_real [simp]:
   477   "isCont f a \<Longrightarrow> isCont (\<lambda>x. of_real (f x)::'b::real_normed_algebra_1) a"
   478   by (rule of_real.isCont)
   479 
   480 lemma isCont_power [simp]:
   481   fixes f :: "'a::topological_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   482   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
   483   unfolding isCont_def by (rule LIM_power)
   484 
   485 lemma isCont_sgn [simp]:
   486   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   487   shows "\<lbrakk>isCont f a; f a \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. sgn (f x)) a"
   488   unfolding isCont_def by (rule LIM_sgn)
   489 
   490 lemma isCont_setsum [simp]:
   491   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::real_normed_vector"
   492   fixes A :: "'a set"
   493   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
   494   unfolding isCont_def by (simp add: tendsto_setsum)
   495 
   496 lemmas isCont_intros =
   497   isCont_ident isCont_const isCont_norm isCont_rabs isCont_add isCont_minus
   498   isCont_diff isCont_mult isCont_inverse isCont_divide isCont_scaleR
   499   isCont_of_real isCont_power isCont_sgn isCont_setsum
   500 
   501 lemma LIM_less_bound: fixes f :: "real \<Rightarrow> real" assumes "b < x"
   502   and all_le: "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and isCont: "isCont f x"
   503   shows "0 \<le> f x"
   504 proof (rule ccontr)
   505   assume "\<not> 0 \<le> f x" hence "f x < 0" by auto
   506   hence "0 < - f x / 2" by auto
   507   from isCont[unfolded isCont_def, THEN LIM_D, OF this]
   508   obtain s where "s > 0" and s_D: "\<And>x'. \<lbrakk> x' \<noteq> x ; \<bar> x' - x \<bar> < s \<rbrakk> \<Longrightarrow> \<bar> f x' - f x \<bar> < - f x / 2" by auto
   509 
   510   let ?x = "x - min (s / 2) ((x - b) / 2)"
   511   have "?x < x" and "\<bar> ?x - x \<bar> < s"
   512     using `b < x` and `0 < s` by auto
   513   have "b < ?x"
   514   proof (cases "s < x - b")
   515     case True thus ?thesis using `0 < s` by auto
   516   next
   517     case False hence "s / 2 \<ge> (x - b) / 2" by auto
   518     hence "?x = (x + b) / 2" by (simp add: field_simps min_max.inf_absorb2)
   519     thus ?thesis using `b < x` by auto
   520   qed
   521   hence "0 \<le> f ?x" using all_le `?x < x` by auto
   522   moreover have "\<bar>f ?x - f x\<bar> < - f x / 2"
   523     using s_D[OF _ `\<bar> ?x - x \<bar> < s`] `?x < x` by auto
   524   hence "f ?x - f x < - f x / 2" by auto
   525   hence "f ?x < f x / 2" by auto
   526   hence "f ?x < 0" using `f x < 0` by auto
   527   thus False using `0 \<le> f ?x` by auto
   528 qed
   529 
   530 
   531 subsection {* Uniform Continuity *}
   532 
   533 lemma isUCont_isCont: "isUCont f ==> isCont f x"
   534 by (simp add: isUCont_def isCont_def LIM_def, force)
   535 
   536 lemma isUCont_Cauchy:
   537   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
   538 unfolding isUCont_def
   539 apply (rule metric_CauchyI)
   540 apply (drule_tac x=e in spec, safe)
   541 apply (drule_tac e=s in metric_CauchyD, safe)
   542 apply (rule_tac x=M in exI, simp)
   543 done
   544 
   545 lemma (in bounded_linear) isUCont: "isUCont f"
   546 unfolding isUCont_def dist_norm
   547 proof (intro allI impI)
   548   fix r::real assume r: "0 < r"
   549   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
   550     using pos_bounded by fast
   551   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
   552   proof (rule exI, safe)
   553     from r K show "0 < r / K" by (rule divide_pos_pos)
   554   next
   555     fix x y :: 'a
   556     assume xy: "norm (x - y) < r / K"
   557     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
   558     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
   559     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
   560     finally show "norm (f x - f y) < r" .
   561   qed
   562 qed
   563 
   564 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
   565 by (rule isUCont [THEN isUCont_Cauchy])
   566 
   567 
   568 subsection {* Relation of LIM and LIMSEQ *}
   569 
   570 lemma LIMSEQ_SEQ_conv1:
   571   fixes a :: "'a::metric_space" and L :: "'b::metric_space"
   572   assumes X: "X -- a --> L"
   573   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
   574 proof (safe intro!: metric_LIMSEQ_I)
   575   fix S :: "nat \<Rightarrow> 'a"
   576   fix r :: real
   577   assume rgz: "0 < r"
   578   assume as: "\<forall>n. S n \<noteq> a"
   579   assume S: "S ----> a"
   580   from metric_LIM_D [OF X rgz] obtain s
   581     where sgz: "0 < s"
   582     and aux: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < s\<rbrakk> \<Longrightarrow> dist (X x) L < r"
   583     by fast
   584   from metric_LIMSEQ_D [OF S sgz]
   585   obtain no where "\<forall>n\<ge>no. dist (S n) a < s" by blast
   586   hence "\<forall>n\<ge>no. dist (X (S n)) L < r" by (simp add: aux as)
   587   thus "\<exists>no. \<forall>n\<ge>no. dist (X (S n)) L < r" ..
   588 qed
   589 
   590 
   591 lemma LIMSEQ_SEQ_conv2:
   592   fixes a :: real and L :: "'a::metric_space"
   593   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
   594   shows "X -- a --> L"
   595 proof (rule ccontr)
   596   assume "\<not> (X -- a --> L)"
   597   hence "\<not> (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & norm (x - a) < s --> dist (X x) L < r)"
   598     unfolding LIM_def dist_norm .
   599   hence "\<exists>r > 0. \<forall>s > 0. \<exists>x. \<not>(x \<noteq> a \<and> \<bar>x - a\<bar> < s --> dist (X x) L < r)" by simp
   600   hence "\<exists>r > 0. \<forall>s > 0. \<exists>x. (x \<noteq> a \<and> \<bar>x - a\<bar> < s \<and> dist (X x) L \<ge> r)" by (simp add: not_less)
   601   then obtain r where rdef: "r > 0 \<and> (\<forall>s > 0. \<exists>x. (x \<noteq> a \<and> \<bar>x - a\<bar> < s \<and> dist (X x) L \<ge> r))" by auto
   602 
   603   let ?F = "\<lambda>n::nat. SOME x. x\<noteq>a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> dist (X x) L \<ge> r"
   604   have "\<And>n. \<exists>x. x\<noteq>a \<and> \<bar>x - a\<bar> < inverse (real (Suc n)) \<and> dist (X x) L \<ge> r"
   605     using rdef by simp
   606   hence F: "\<And>n. ?F n \<noteq> a \<and> \<bar>?F n - a\<bar> < inverse (real (Suc n)) \<and> dist (X (?F n)) L \<ge> r"
   607     by (rule someI_ex)
   608   hence F1: "\<And>n. ?F n \<noteq> a"
   609     and F2: "\<And>n. \<bar>?F n - a\<bar> < inverse (real (Suc n))"
   610     and F3: "\<And>n. dist (X (?F n)) L \<ge> r"
   611     by fast+
   612 
   613   have "?F ----> a"
   614   proof (rule LIMSEQ_I, unfold real_norm_def)
   615       fix e::real
   616       assume "0 < e"
   617         (* choose no such that inverse (real (Suc n)) < e *)
   618       then have "\<exists>no. inverse (real (Suc no)) < e" by (rule reals_Archimedean)
   619       then obtain m where nodef: "inverse (real (Suc m)) < e" by auto
   620       show "\<exists>no. \<forall>n. no \<le> n --> \<bar>?F n - a\<bar> < e"
   621       proof (intro exI allI impI)
   622         fix n
   623         assume mlen: "m \<le> n"
   624         have "\<bar>?F n - a\<bar> < inverse (real (Suc n))"
   625           by (rule F2)
   626         also have "inverse (real (Suc n)) \<le> inverse (real (Suc m))"
   627           using mlen by auto
   628         also from nodef have
   629           "inverse (real (Suc m)) < e" .
   630         finally show "\<bar>?F n - a\<bar> < e" .
   631       qed
   632   qed
   633   
   634   moreover have "\<forall>n. ?F n \<noteq> a"
   635     by (rule allI) (rule F1)
   636 
   637   moreover note `\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L`
   638   ultimately have "(\<lambda>n. X (?F n)) ----> L" by simp
   639   
   640   moreover have "\<not> ((\<lambda>n. X (?F n)) ----> L)"
   641   proof -
   642     {
   643       fix no::nat
   644       obtain n where "n = no + 1" by simp
   645       then have nolen: "no \<le> n" by simp
   646         (* We prove this by showing that for any m there is an n\<ge>m such that |X (?F n) - L| \<ge> r *)
   647       have "dist (X (?F n)) L \<ge> r"
   648         by (rule F3)
   649       with nolen have "\<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> r" by fast
   650     }
   651     then have "(\<forall>no. \<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> r)" by simp
   652     with rdef have "\<exists>e>0. (\<forall>no. \<exists>n. no \<le> n \<and> dist (X (?F n)) L \<ge> e)" by auto
   653     thus ?thesis by (unfold LIMSEQ_def, auto simp add: not_less)
   654   qed
   655   ultimately show False by simp
   656 qed
   657 
   658 lemma LIMSEQ_SEQ_conv:
   659   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::real) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
   660    (X -- a --> (L::'a::metric_space))"
   661 proof
   662   assume "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L"
   663   thus "X -- a --> L" by (rule LIMSEQ_SEQ_conv2)
   664 next
   665   assume "(X -- a --> L)"
   666   thus "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. X (S n)) ----> L" by (rule LIMSEQ_SEQ_conv1)
   667 qed
   668 
   669 end