src/HOL/OrderedGroup.thy
author wenzelm
Wed Sep 17 21:27:08 2008 +0200 (2008-09-17)
changeset 28262 aa7ca36d67fd
parent 28130 32b4185bfdc7
child 28823 dcbef866c9e2
permissions -rw-r--r--
back to dynamic the_context(), because static @{theory} is invalidated if ML environment changes within the same code block;
     1 (*  Title:   HOL/OrderedGroup.thy
     2     ID:      $Id$
     3     Author:  Gertrud Bauer, Steven Obua, Lawrence C Paulson, and Markus Wenzel,
     4              with contributions by Jeremy Avigad
     5 *)
     6 
     7 header {* Ordered Groups *}
     8 
     9 theory OrderedGroup
    10 imports Lattices
    11 uses "~~/src/Provers/Arith/abel_cancel.ML"
    12 begin
    13 
    14 text {*
    15   The theory of partially ordered groups is taken from the books:
    16   \begin{itemize}
    17   \item \emph{Lattice Theory} by Garret Birkhoff, American Mathematical Society 1979 
    18   \item \emph{Partially Ordered Algebraic Systems}, Pergamon Press 1963
    19   \end{itemize}
    20   Most of the used notions can also be looked up in 
    21   \begin{itemize}
    22   \item \url{http://www.mathworld.com} by Eric Weisstein et. al.
    23   \item \emph{Algebra I} by van der Waerden, Springer.
    24   \end{itemize}
    25 *}
    26 
    27 subsection {* Semigroups and Monoids *}
    28 
    29 class semigroup_add = plus +
    30   assumes add_assoc: "(a + b) + c = a + (b + c)"
    31 
    32 class ab_semigroup_add = semigroup_add +
    33   assumes add_commute: "a + b = b + a"
    34 begin
    35 
    36 lemma add_left_commute: "a + (b + c) = b + (a + c)"
    37   by (rule mk_left_commute [of "plus", OF add_assoc add_commute])
    38 
    39 theorems add_ac = add_assoc add_commute add_left_commute
    40 
    41 end
    42 
    43 theorems add_ac = add_assoc add_commute add_left_commute
    44 
    45 class semigroup_mult = times +
    46   assumes mult_assoc: "(a * b) * c = a * (b * c)"
    47 
    48 class ab_semigroup_mult = semigroup_mult +
    49   assumes mult_commute: "a * b = b * a"
    50 begin
    51 
    52 lemma mult_left_commute: "a * (b * c) = b * (a * c)"
    53   by (rule mk_left_commute [of "times", OF mult_assoc mult_commute])
    54 
    55 theorems mult_ac = mult_assoc mult_commute mult_left_commute
    56 
    57 end
    58 
    59 theorems mult_ac = mult_assoc mult_commute mult_left_commute
    60 
    61 class ab_semigroup_idem_mult = ab_semigroup_mult +
    62   assumes mult_idem: "x * x = x"
    63 begin
    64 
    65 lemma mult_left_idem: "x * (x * y) = x * y"
    66   unfolding mult_assoc [symmetric, of x] mult_idem ..
    67 
    68 lemmas mult_ac_idem = mult_ac mult_idem mult_left_idem
    69 
    70 end
    71 
    72 lemmas mult_ac_idem = mult_ac mult_idem mult_left_idem
    73 
    74 class monoid_add = zero + semigroup_add +
    75   assumes add_0_left [simp]: "0 + a = a"
    76     and add_0_right [simp]: "a + 0 = a"
    77 
    78 lemma zero_reorient: "0 = x \<longleftrightarrow> x = 0"
    79   by (rule eq_commute)
    80 
    81 class comm_monoid_add = zero + ab_semigroup_add +
    82   assumes add_0: "0 + a = a"
    83 begin
    84 
    85 subclass monoid_add
    86   by unfold_locales (insert add_0, simp_all add: add_commute)
    87 
    88 end
    89 
    90 class monoid_mult = one + semigroup_mult +
    91   assumes mult_1_left [simp]: "1 * a  = a"
    92   assumes mult_1_right [simp]: "a * 1 = a"
    93 
    94 lemma one_reorient: "1 = x \<longleftrightarrow> x = 1"
    95   by (rule eq_commute)
    96 
    97 class comm_monoid_mult = one + ab_semigroup_mult +
    98   assumes mult_1: "1 * a = a"
    99 begin
   100 
   101 subclass monoid_mult
   102   by unfold_locales (insert mult_1, simp_all add: mult_commute)
   103 
   104 end
   105 
   106 class cancel_semigroup_add = semigroup_add +
   107   assumes add_left_imp_eq: "a + b = a + c \<Longrightarrow> b = c"
   108   assumes add_right_imp_eq: "b + a = c + a \<Longrightarrow> b = c"
   109 begin
   110 
   111 lemma add_left_cancel [simp]:
   112   "a + b = a + c \<longleftrightarrow> b = c"
   113   by (blast dest: add_left_imp_eq)
   114 
   115 lemma add_right_cancel [simp]:
   116   "b + a = c + a \<longleftrightarrow> b = c"
   117   by (blast dest: add_right_imp_eq)
   118 
   119 end
   120 
   121 class cancel_ab_semigroup_add = ab_semigroup_add +
   122   assumes add_imp_eq: "a + b = a + c \<Longrightarrow> b = c"
   123 begin
   124 
   125 subclass cancel_semigroup_add
   126 proof unfold_locales
   127   fix a b c :: 'a
   128   assume "a + b = a + c" 
   129   then show "b = c" by (rule add_imp_eq)
   130 next
   131   fix a b c :: 'a
   132   assume "b + a = c + a"
   133   then have "a + b = a + c" by (simp only: add_commute)
   134   then show "b = c" by (rule add_imp_eq)
   135 qed
   136 
   137 end
   138 
   139 subsection {* Groups *}
   140 
   141 class group_add = minus + uminus + monoid_add +
   142   assumes left_minus [simp]: "- a + a = 0"
   143   assumes diff_minus: "a - b = a + (- b)"
   144 begin
   145 
   146 lemma minus_add_cancel: "- a + (a + b) = b"
   147   by (simp add: add_assoc[symmetric])
   148 
   149 lemma minus_zero [simp]: "- 0 = 0"
   150 proof -
   151   have "- 0 = - 0 + (0 + 0)" by (simp only: add_0_right)
   152   also have "\<dots> = 0" by (rule minus_add_cancel)
   153   finally show ?thesis .
   154 qed
   155 
   156 lemma minus_minus [simp]: "- (- a) = a"
   157 proof -
   158   have "- (- a) = - (- a) + (- a + a)" by simp
   159   also have "\<dots> = a" by (rule minus_add_cancel)
   160   finally show ?thesis .
   161 qed
   162 
   163 lemma right_minus [simp]: "a + - a = 0"
   164 proof -
   165   have "a + - a = - (- a) + - a" by simp
   166   also have "\<dots> = 0" by (rule left_minus)
   167   finally show ?thesis .
   168 qed
   169 
   170 lemma right_minus_eq: "a - b = 0 \<longleftrightarrow> a = b"
   171 proof
   172   assume "a - b = 0"
   173   have "a = (a - b) + b" by (simp add:diff_minus add_assoc)
   174   also have "\<dots> = b" using `a - b = 0` by simp
   175   finally show "a = b" .
   176 next
   177   assume "a = b" thus "a - b = 0" by (simp add: diff_minus)
   178 qed
   179 
   180 lemma equals_zero_I:
   181   assumes "a + b = 0"
   182   shows "- a = b"
   183 proof -
   184   have "- a = - a + (a + b)" using assms by simp
   185   also have "\<dots> = b" by (simp add: add_assoc[symmetric])
   186   finally show ?thesis .
   187 qed
   188 
   189 lemma diff_self [simp]: "a - a = 0"
   190   by (simp add: diff_minus)
   191 
   192 lemma diff_0 [simp]: "0 - a = - a"
   193   by (simp add: diff_minus)
   194 
   195 lemma diff_0_right [simp]: "a - 0 = a" 
   196   by (simp add: diff_minus)
   197 
   198 lemma diff_minus_eq_add [simp]: "a - - b = a + b"
   199   by (simp add: diff_minus)
   200 
   201 lemma neg_equal_iff_equal [simp]:
   202   "- a = - b \<longleftrightarrow> a = b" 
   203 proof 
   204   assume "- a = - b"
   205   hence "- (- a) = - (- b)"
   206     by simp
   207   thus "a = b" by simp
   208 next
   209   assume "a = b"
   210   thus "- a = - b" by simp
   211 qed
   212 
   213 lemma neg_equal_0_iff_equal [simp]:
   214   "- a = 0 \<longleftrightarrow> a = 0"
   215   by (subst neg_equal_iff_equal [symmetric], simp)
   216 
   217 lemma neg_0_equal_iff_equal [simp]:
   218   "0 = - a \<longleftrightarrow> 0 = a"
   219   by (subst neg_equal_iff_equal [symmetric], simp)
   220 
   221 text{*The next two equations can make the simplifier loop!*}
   222 
   223 lemma equation_minus_iff:
   224   "a = - b \<longleftrightarrow> b = - a"
   225 proof -
   226   have "- (- a) = - b \<longleftrightarrow> - a = b" by (rule neg_equal_iff_equal)
   227   thus ?thesis by (simp add: eq_commute)
   228 qed
   229 
   230 lemma minus_equation_iff:
   231   "- a = b \<longleftrightarrow> - b = a"
   232 proof -
   233   have "- a = - (- b) \<longleftrightarrow> a = -b" by (rule neg_equal_iff_equal)
   234   thus ?thesis by (simp add: eq_commute)
   235 qed
   236 
   237 lemma diff_add_cancel: "a - b + b = a"
   238   by (simp add: diff_minus add_assoc)
   239 
   240 lemma add_diff_cancel: "a + b - b = a"
   241   by (simp add: diff_minus add_assoc)
   242 
   243 end
   244 
   245 class ab_group_add = minus + uminus + comm_monoid_add +
   246   assumes ab_left_minus: "- a + a = 0"
   247   assumes ab_diff_minus: "a - b = a + (- b)"
   248 begin
   249 
   250 subclass group_add
   251   by unfold_locales (simp_all add: ab_left_minus ab_diff_minus)
   252 
   253 subclass cancel_ab_semigroup_add
   254 proof unfold_locales
   255   fix a b c :: 'a
   256   assume "a + b = a + c"
   257   then have "- a + a + b = - a + a + c"
   258     unfolding add_assoc by simp
   259   then show "b = c" by simp
   260 qed
   261 
   262 lemma uminus_add_conv_diff:
   263   "- a + b = b - a"
   264   by (simp add:diff_minus add_commute)
   265 
   266 lemma minus_add_distrib [simp]:
   267   "- (a + b) = - a + - b"
   268   by (rule equals_zero_I) (simp add: add_ac)
   269 
   270 lemma minus_diff_eq [simp]:
   271   "- (a - b) = b - a"
   272   by (simp add: diff_minus add_commute)
   273 
   274 lemma add_diff_eq: "a + (b - c) = (a + b) - c"
   275   by (simp add: diff_minus add_ac)
   276 
   277 lemma diff_add_eq: "(a - b) + c = (a + c) - b"
   278   by (simp add: diff_minus add_ac)
   279 
   280 lemma diff_eq_eq: "a - b = c \<longleftrightarrow> a = c + b"
   281   by (auto simp add: diff_minus add_assoc)
   282 
   283 lemma eq_diff_eq: "a = c - b \<longleftrightarrow> a + b = c"
   284   by (auto simp add: diff_minus add_assoc)
   285 
   286 lemma diff_diff_eq: "(a - b) - c = a - (b + c)"
   287   by (simp add: diff_minus add_ac)
   288 
   289 lemma diff_diff_eq2: "a - (b - c) = (a + c) - b"
   290   by (simp add: diff_minus add_ac)
   291 
   292 lemmas compare_rls =
   293        diff_minus [symmetric]
   294        add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   295        diff_eq_eq eq_diff_eq
   296 
   297 lemma eq_iff_diff_eq_0: "a = b \<longleftrightarrow> a - b = 0"
   298   by (simp add: compare_rls)
   299 
   300 end
   301 
   302 subsection {* (Partially) Ordered Groups *} 
   303 
   304 class pordered_ab_semigroup_add = order + ab_semigroup_add +
   305   assumes add_left_mono: "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   306 begin
   307 
   308 lemma add_right_mono:
   309   "a \<le> b \<Longrightarrow> a + c \<le> b + c"
   310   by (simp add: add_commute [of _ c] add_left_mono)
   311 
   312 text {* non-strict, in both arguments *}
   313 lemma add_mono:
   314   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> a + c \<le> b + d"
   315   apply (erule add_right_mono [THEN order_trans])
   316   apply (simp add: add_commute add_left_mono)
   317   done
   318 
   319 end
   320 
   321 class pordered_cancel_ab_semigroup_add =
   322   pordered_ab_semigroup_add + cancel_ab_semigroup_add
   323 begin
   324 
   325 lemma add_strict_left_mono:
   326   "a < b \<Longrightarrow> c + a < c + b"
   327   by (auto simp add: less_le add_left_mono)
   328 
   329 lemma add_strict_right_mono:
   330   "a < b \<Longrightarrow> a + c < b + c"
   331   by (simp add: add_commute [of _ c] add_strict_left_mono)
   332 
   333 text{*Strict monotonicity in both arguments*}
   334 lemma add_strict_mono:
   335   "a < b \<Longrightarrow> c < d \<Longrightarrow> a + c < b + d"
   336 apply (erule add_strict_right_mono [THEN less_trans])
   337 apply (erule add_strict_left_mono)
   338 done
   339 
   340 lemma add_less_le_mono:
   341   "a < b \<Longrightarrow> c \<le> d \<Longrightarrow> a + c < b + d"
   342 apply (erule add_strict_right_mono [THEN less_le_trans])
   343 apply (erule add_left_mono)
   344 done
   345 
   346 lemma add_le_less_mono:
   347   "a \<le> b \<Longrightarrow> c < d \<Longrightarrow> a + c < b + d"
   348 apply (erule add_right_mono [THEN le_less_trans])
   349 apply (erule add_strict_left_mono) 
   350 done
   351 
   352 end
   353 
   354 class pordered_ab_semigroup_add_imp_le =
   355   pordered_cancel_ab_semigroup_add +
   356   assumes add_le_imp_le_left: "c + a \<le> c + b \<Longrightarrow> a \<le> b"
   357 begin
   358 
   359 lemma add_less_imp_less_left:
   360    assumes less: "c + a < c + b"
   361    shows "a < b"
   362 proof -
   363   from less have le: "c + a <= c + b" by (simp add: order_le_less)
   364   have "a <= b" 
   365     apply (insert le)
   366     apply (drule add_le_imp_le_left)
   367     by (insert le, drule add_le_imp_le_left, assumption)
   368   moreover have "a \<noteq> b"
   369   proof (rule ccontr)
   370     assume "~(a \<noteq> b)"
   371     then have "a = b" by simp
   372     then have "c + a = c + b" by simp
   373     with less show "False"by simp
   374   qed
   375   ultimately show "a < b" by (simp add: order_le_less)
   376 qed
   377 
   378 lemma add_less_imp_less_right:
   379   "a + c < b + c \<Longrightarrow> a < b"
   380 apply (rule add_less_imp_less_left [of c])
   381 apply (simp add: add_commute)  
   382 done
   383 
   384 lemma add_less_cancel_left [simp]:
   385   "c + a < c + b \<longleftrightarrow> a < b"
   386   by (blast intro: add_less_imp_less_left add_strict_left_mono) 
   387 
   388 lemma add_less_cancel_right [simp]:
   389   "a + c < b + c \<longleftrightarrow> a < b"
   390   by (blast intro: add_less_imp_less_right add_strict_right_mono)
   391 
   392 lemma add_le_cancel_left [simp]:
   393   "c + a \<le> c + b \<longleftrightarrow> a \<le> b"
   394   by (auto, drule add_le_imp_le_left, simp_all add: add_left_mono) 
   395 
   396 lemma add_le_cancel_right [simp]:
   397   "a + c \<le> b + c \<longleftrightarrow> a \<le> b"
   398   by (simp add: add_commute [of a c] add_commute [of b c])
   399 
   400 lemma add_le_imp_le_right:
   401   "a + c \<le> b + c \<Longrightarrow> a \<le> b"
   402   by simp
   403 
   404 lemma max_add_distrib_left:
   405   "max x y + z = max (x + z) (y + z)"
   406   unfolding max_def by auto
   407 
   408 lemma min_add_distrib_left:
   409   "min x y + z = min (x + z) (y + z)"
   410   unfolding min_def by auto
   411 
   412 end
   413 
   414 subsection {* Support for reasoning about signs *}
   415 
   416 class pordered_comm_monoid_add =
   417   pordered_cancel_ab_semigroup_add + comm_monoid_add
   418 begin
   419 
   420 lemma add_pos_nonneg:
   421   assumes "0 < a" and "0 \<le> b"
   422     shows "0 < a + b"
   423 proof -
   424   have "0 + 0 < a + b" 
   425     using assms by (rule add_less_le_mono)
   426   then show ?thesis by simp
   427 qed
   428 
   429 lemma add_pos_pos:
   430   assumes "0 < a" and "0 < b"
   431     shows "0 < a + b"
   432   by (rule add_pos_nonneg) (insert assms, auto)
   433 
   434 lemma add_nonneg_pos:
   435   assumes "0 \<le> a" and "0 < b"
   436     shows "0 < a + b"
   437 proof -
   438   have "0 + 0 < a + b" 
   439     using assms by (rule add_le_less_mono)
   440   then show ?thesis by simp
   441 qed
   442 
   443 lemma add_nonneg_nonneg:
   444   assumes "0 \<le> a" and "0 \<le> b"
   445     shows "0 \<le> a + b"
   446 proof -
   447   have "0 + 0 \<le> a + b" 
   448     using assms by (rule add_mono)
   449   then show ?thesis by simp
   450 qed
   451 
   452 lemma add_neg_nonpos: 
   453   assumes "a < 0" and "b \<le> 0"
   454   shows "a + b < 0"
   455 proof -
   456   have "a + b < 0 + 0"
   457     using assms by (rule add_less_le_mono)
   458   then show ?thesis by simp
   459 qed
   460 
   461 lemma add_neg_neg: 
   462   assumes "a < 0" and "b < 0"
   463   shows "a + b < 0"
   464   by (rule add_neg_nonpos) (insert assms, auto)
   465 
   466 lemma add_nonpos_neg:
   467   assumes "a \<le> 0" and "b < 0"
   468   shows "a + b < 0"
   469 proof -
   470   have "a + b < 0 + 0"
   471     using assms by (rule add_le_less_mono)
   472   then show ?thesis by simp
   473 qed
   474 
   475 lemma add_nonpos_nonpos:
   476   assumes "a \<le> 0" and "b \<le> 0"
   477   shows "a + b \<le> 0"
   478 proof -
   479   have "a + b \<le> 0 + 0"
   480     using assms by (rule add_mono)
   481   then show ?thesis by simp
   482 qed
   483 
   484 end
   485 
   486 class pordered_ab_group_add =
   487   ab_group_add + pordered_ab_semigroup_add
   488 begin
   489 
   490 subclass pordered_cancel_ab_semigroup_add ..
   491 
   492 subclass pordered_ab_semigroup_add_imp_le
   493 proof unfold_locales
   494   fix a b c :: 'a
   495   assume "c + a \<le> c + b"
   496   hence "(-c) + (c + a) \<le> (-c) + (c + b)" by (rule add_left_mono)
   497   hence "((-c) + c) + a \<le> ((-c) + c) + b" by (simp only: add_assoc)
   498   thus "a \<le> b" by simp
   499 qed
   500 
   501 subclass pordered_comm_monoid_add ..
   502 
   503 lemma max_diff_distrib_left:
   504   shows "max x y - z = max (x - z) (y - z)"
   505   by (simp add: diff_minus, rule max_add_distrib_left) 
   506 
   507 lemma min_diff_distrib_left:
   508   shows "min x y - z = min (x - z) (y - z)"
   509   by (simp add: diff_minus, rule min_add_distrib_left) 
   510 
   511 lemma le_imp_neg_le:
   512   assumes "a \<le> b"
   513   shows "-b \<le> -a"
   514 proof -
   515   have "-a+a \<le> -a+b"
   516     using `a \<le> b` by (rule add_left_mono) 
   517   hence "0 \<le> -a+b"
   518     by simp
   519   hence "0 + (-b) \<le> (-a + b) + (-b)"
   520     by (rule add_right_mono) 
   521   thus ?thesis
   522     by (simp add: add_assoc)
   523 qed
   524 
   525 lemma neg_le_iff_le [simp]: "- b \<le> - a \<longleftrightarrow> a \<le> b"
   526 proof 
   527   assume "- b \<le> - a"
   528   hence "- (- a) \<le> - (- b)"
   529     by (rule le_imp_neg_le)
   530   thus "a\<le>b" by simp
   531 next
   532   assume "a\<le>b"
   533   thus "-b \<le> -a" by (rule le_imp_neg_le)
   534 qed
   535 
   536 lemma neg_le_0_iff_le [simp]: "- a \<le> 0 \<longleftrightarrow> 0 \<le> a"
   537   by (subst neg_le_iff_le [symmetric], simp)
   538 
   539 lemma neg_0_le_iff_le [simp]: "0 \<le> - a \<longleftrightarrow> a \<le> 0"
   540   by (subst neg_le_iff_le [symmetric], simp)
   541 
   542 lemma neg_less_iff_less [simp]: "- b < - a \<longleftrightarrow> a < b"
   543   by (force simp add: less_le) 
   544 
   545 lemma neg_less_0_iff_less [simp]: "- a < 0 \<longleftrightarrow> 0 < a"
   546   by (subst neg_less_iff_less [symmetric], simp)
   547 
   548 lemma neg_0_less_iff_less [simp]: "0 < - a \<longleftrightarrow> a < 0"
   549   by (subst neg_less_iff_less [symmetric], simp)
   550 
   551 text{*The next several equations can make the simplifier loop!*}
   552 
   553 lemma less_minus_iff: "a < - b \<longleftrightarrow> b < - a"
   554 proof -
   555   have "(- (-a) < - b) = (b < - a)" by (rule neg_less_iff_less)
   556   thus ?thesis by simp
   557 qed
   558 
   559 lemma minus_less_iff: "- a < b \<longleftrightarrow> - b < a"
   560 proof -
   561   have "(- a < - (-b)) = (- b < a)" by (rule neg_less_iff_less)
   562   thus ?thesis by simp
   563 qed
   564 
   565 lemma le_minus_iff: "a \<le> - b \<longleftrightarrow> b \<le> - a"
   566 proof -
   567   have mm: "!! a (b::'a). (-(-a)) < -b \<Longrightarrow> -(-b) < -a" by (simp only: minus_less_iff)
   568   have "(- (- a) <= -b) = (b <= - a)" 
   569     apply (auto simp only: le_less)
   570     apply (drule mm)
   571     apply (simp_all)
   572     apply (drule mm[simplified], assumption)
   573     done
   574   then show ?thesis by simp
   575 qed
   576 
   577 lemma minus_le_iff: "- a \<le> b \<longleftrightarrow> - b \<le> a"
   578   by (auto simp add: le_less minus_less_iff)
   579 
   580 lemma less_iff_diff_less_0: "a < b \<longleftrightarrow> a - b < 0"
   581 proof -
   582   have  "(a < b) = (a + (- b) < b + (-b))"  
   583     by (simp only: add_less_cancel_right)
   584   also have "... =  (a - b < 0)" by (simp add: diff_minus)
   585   finally show ?thesis .
   586 qed
   587 
   588 lemma diff_less_eq: "a - b < c \<longleftrightarrow> a < c + b"
   589 apply (subst less_iff_diff_less_0 [of a])
   590 apply (rule less_iff_diff_less_0 [of _ c, THEN ssubst])
   591 apply (simp add: diff_minus add_ac)
   592 done
   593 
   594 lemma less_diff_eq: "a < c - b \<longleftrightarrow> a + b < c"
   595 apply (subst less_iff_diff_less_0 [of "plus a b"])
   596 apply (subst less_iff_diff_less_0 [of a])
   597 apply (simp add: diff_minus add_ac)
   598 done
   599 
   600 lemma diff_le_eq: "a - b \<le> c \<longleftrightarrow> a \<le> c + b"
   601   by (auto simp add: le_less diff_less_eq diff_add_cancel add_diff_cancel)
   602 
   603 lemma le_diff_eq: "a \<le> c - b \<longleftrightarrow> a + b \<le> c"
   604   by (auto simp add: le_less less_diff_eq diff_add_cancel add_diff_cancel)
   605 
   606 lemmas compare_rls =
   607        diff_minus [symmetric]
   608        add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   609        diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   610        diff_eq_eq eq_diff_eq
   611 
   612 text{*This list of rewrites simplifies (in)equalities by bringing subtractions
   613   to the top and then moving negative terms to the other side.
   614   Use with @{text add_ac}*}
   615 lemmas (in -) compare_rls =
   616        diff_minus [symmetric]
   617        add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   618        diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   619        diff_eq_eq eq_diff_eq
   620 
   621 lemma le_iff_diff_le_0: "a \<le> b \<longleftrightarrow> a - b \<le> 0"
   622   by (simp add: compare_rls)
   623 
   624 lemmas group_simps =
   625   add_ac
   626   add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   627   diff_eq_eq eq_diff_eq diff_minus [symmetric] uminus_add_conv_diff
   628   diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   629 
   630 end
   631 
   632 lemmas group_simps =
   633   mult_ac
   634   add_ac
   635   add_diff_eq diff_add_eq diff_diff_eq diff_diff_eq2
   636   diff_eq_eq eq_diff_eq diff_minus [symmetric] uminus_add_conv_diff
   637   diff_less_eq less_diff_eq diff_le_eq le_diff_eq
   638 
   639 class ordered_ab_semigroup_add =
   640   linorder + pordered_ab_semigroup_add
   641 
   642 class ordered_cancel_ab_semigroup_add =
   643   linorder + pordered_cancel_ab_semigroup_add
   644 begin
   645 
   646 subclass ordered_ab_semigroup_add ..
   647 
   648 subclass pordered_ab_semigroup_add_imp_le
   649 proof unfold_locales
   650   fix a b c :: 'a
   651   assume le: "c + a <= c + b"  
   652   show "a <= b"
   653   proof (rule ccontr)
   654     assume w: "~ a \<le> b"
   655     hence "b <= a" by (simp add: linorder_not_le)
   656     hence le2: "c + b <= c + a" by (rule add_left_mono)
   657     have "a = b" 
   658       apply (insert le)
   659       apply (insert le2)
   660       apply (drule antisym, simp_all)
   661       done
   662     with w show False 
   663       by (simp add: linorder_not_le [symmetric])
   664   qed
   665 qed
   666 
   667 end
   668 
   669 class ordered_ab_group_add =
   670   linorder + pordered_ab_group_add
   671 begin
   672 
   673 subclass ordered_cancel_ab_semigroup_add ..
   674 
   675 lemma neg_less_eq_nonneg:
   676   "- a \<le> a \<longleftrightarrow> 0 \<le> a"
   677 proof
   678   assume A: "- a \<le> a" show "0 \<le> a"
   679   proof (rule classical)
   680     assume "\<not> 0 \<le> a"
   681     then have "a < 0" by auto
   682     with A have "- a < 0" by (rule le_less_trans)
   683     then show ?thesis by auto
   684   qed
   685 next
   686   assume A: "0 \<le> a" show "- a \<le> a"
   687   proof (rule order_trans)
   688     show "- a \<le> 0" using A by (simp add: minus_le_iff)
   689   next
   690     show "0 \<le> a" using A .
   691   qed
   692 qed
   693   
   694 lemma less_eq_neg_nonpos:
   695   "a \<le> - a \<longleftrightarrow> a \<le> 0"
   696 proof
   697   assume A: "a \<le> - a" show "a \<le> 0"
   698   proof (rule classical)
   699     assume "\<not> a \<le> 0"
   700     then have "0 < a" by auto
   701     then have "0 < - a" using A by (rule less_le_trans)
   702     then show ?thesis by auto
   703   qed
   704 next
   705   assume A: "a \<le> 0" show "a \<le> - a"
   706   proof (rule order_trans)
   707     show "0 \<le> - a" using A by (simp add: minus_le_iff)
   708   next
   709     show "a \<le> 0" using A .
   710   qed
   711 qed
   712 
   713 lemma equal_neg_zero:
   714   "a = - a \<longleftrightarrow> a = 0"
   715 proof
   716   assume "a = 0" then show "a = - a" by simp
   717 next
   718   assume A: "a = - a" show "a = 0"
   719   proof (cases "0 \<le> a")
   720     case True with A have "0 \<le> - a" by auto
   721     with le_minus_iff have "a \<le> 0" by simp
   722     with True show ?thesis by (auto intro: order_trans)
   723   next
   724     case False then have B: "a \<le> 0" by auto
   725     with A have "- a \<le> 0" by auto
   726     with B show ?thesis by (auto intro: order_trans)
   727   qed
   728 qed
   729 
   730 lemma neg_equal_zero:
   731   "- a = a \<longleftrightarrow> a = 0"
   732   unfolding equal_neg_zero [symmetric] by auto
   733 
   734 end
   735 
   736 -- {* FIXME localize the following *}
   737 
   738 lemma add_increasing:
   739   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   740   shows  "[|0\<le>a; b\<le>c|] ==> b \<le> a + c"
   741 by (insert add_mono [of 0 a b c], simp)
   742 
   743 lemma add_increasing2:
   744   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   745   shows  "[|0\<le>c; b\<le>a|] ==> b \<le> a + c"
   746 by (simp add:add_increasing add_commute[of a])
   747 
   748 lemma add_strict_increasing:
   749   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   750   shows "[|0<a; b\<le>c|] ==> b < a + c"
   751 by (insert add_less_le_mono [of 0 a b c], simp)
   752 
   753 lemma add_strict_increasing2:
   754   fixes c :: "'a::{pordered_ab_semigroup_add_imp_le, comm_monoid_add}"
   755   shows "[|0\<le>a; b<c|] ==> b < a + c"
   756 by (insert add_le_less_mono [of 0 a b c], simp)
   757 
   758 
   759 class pordered_ab_group_add_abs = pordered_ab_group_add + abs +
   760   assumes abs_ge_zero [simp]: "\<bar>a\<bar> \<ge> 0"
   761     and abs_ge_self: "a \<le> \<bar>a\<bar>"
   762     and abs_leI: "a \<le> b \<Longrightarrow> - a \<le> b \<Longrightarrow> \<bar>a\<bar> \<le> b"
   763     and abs_minus_cancel [simp]: "\<bar>-a\<bar> = \<bar>a\<bar>"
   764     and abs_triangle_ineq: "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   765 begin
   766 
   767 lemma abs_minus_le_zero: "- \<bar>a\<bar> \<le> 0"
   768   unfolding neg_le_0_iff_le by simp
   769 
   770 lemma abs_of_nonneg [simp]:
   771   assumes nonneg: "0 \<le> a"
   772   shows "\<bar>a\<bar> = a"
   773 proof (rule antisym)
   774   from nonneg le_imp_neg_le have "- a \<le> 0" by simp
   775   from this nonneg have "- a \<le> a" by (rule order_trans)
   776   then show "\<bar>a\<bar> \<le> a" by (auto intro: abs_leI)
   777 qed (rule abs_ge_self)
   778 
   779 lemma abs_idempotent [simp]: "\<bar>\<bar>a\<bar>\<bar> = \<bar>a\<bar>"
   780   by (rule antisym)
   781     (auto intro!: abs_ge_self abs_leI order_trans [of "uminus (abs a)" zero "abs a"])
   782 
   783 lemma abs_eq_0 [simp]: "\<bar>a\<bar> = 0 \<longleftrightarrow> a = 0"
   784 proof -
   785   have "\<bar>a\<bar> = 0 \<Longrightarrow> a = 0"
   786   proof (rule antisym)
   787     assume zero: "\<bar>a\<bar> = 0"
   788     with abs_ge_self show "a \<le> 0" by auto
   789     from zero have "\<bar>-a\<bar> = 0" by simp
   790     with abs_ge_self [of "uminus a"] have "- a \<le> 0" by auto
   791     with neg_le_0_iff_le show "0 \<le> a" by auto
   792   qed
   793   then show ?thesis by auto
   794 qed
   795 
   796 lemma abs_zero [simp]: "\<bar>0\<bar> = 0"
   797   by simp
   798 
   799 lemma abs_0_eq [simp, noatp]: "0 = \<bar>a\<bar> \<longleftrightarrow> a = 0"
   800 proof -
   801   have "0 = \<bar>a\<bar> \<longleftrightarrow> \<bar>a\<bar> = 0" by (simp only: eq_ac)
   802   thus ?thesis by simp
   803 qed
   804 
   805 lemma abs_le_zero_iff [simp]: "\<bar>a\<bar> \<le> 0 \<longleftrightarrow> a = 0" 
   806 proof
   807   assume "\<bar>a\<bar> \<le> 0"
   808   then have "\<bar>a\<bar> = 0" by (rule antisym) simp
   809   thus "a = 0" by simp
   810 next
   811   assume "a = 0"
   812   thus "\<bar>a\<bar> \<le> 0" by simp
   813 qed
   814 
   815 lemma zero_less_abs_iff [simp]: "0 < \<bar>a\<bar> \<longleftrightarrow> a \<noteq> 0"
   816   by (simp add: less_le)
   817 
   818 lemma abs_not_less_zero [simp]: "\<not> \<bar>a\<bar> < 0"
   819 proof -
   820   have a: "\<And>x y. x \<le> y \<Longrightarrow> \<not> y < x" by auto
   821   show ?thesis by (simp add: a)
   822 qed
   823 
   824 lemma abs_ge_minus_self: "- a \<le> \<bar>a\<bar>"
   825 proof -
   826   have "- a \<le> \<bar>-a\<bar>" by (rule abs_ge_self)
   827   then show ?thesis by simp
   828 qed
   829 
   830 lemma abs_minus_commute: 
   831   "\<bar>a - b\<bar> = \<bar>b - a\<bar>"
   832 proof -
   833   have "\<bar>a - b\<bar> = \<bar>- (a - b)\<bar>" by (simp only: abs_minus_cancel)
   834   also have "... = \<bar>b - a\<bar>" by simp
   835   finally show ?thesis .
   836 qed
   837 
   838 lemma abs_of_pos: "0 < a \<Longrightarrow> \<bar>a\<bar> = a"
   839   by (rule abs_of_nonneg, rule less_imp_le)
   840 
   841 lemma abs_of_nonpos [simp]:
   842   assumes "a \<le> 0"
   843   shows "\<bar>a\<bar> = - a"
   844 proof -
   845   let ?b = "- a"
   846   have "- ?b \<le> 0 \<Longrightarrow> \<bar>- ?b\<bar> = - (- ?b)"
   847   unfolding abs_minus_cancel [of "?b"]
   848   unfolding neg_le_0_iff_le [of "?b"]
   849   unfolding minus_minus by (erule abs_of_nonneg)
   850   then show ?thesis using assms by auto
   851 qed
   852   
   853 lemma abs_of_neg: "a < 0 \<Longrightarrow> \<bar>a\<bar> = - a"
   854   by (rule abs_of_nonpos, rule less_imp_le)
   855 
   856 lemma abs_le_D1: "\<bar>a\<bar> \<le> b \<Longrightarrow> a \<le> b"
   857   by (insert abs_ge_self, blast intro: order_trans)
   858 
   859 lemma abs_le_D2: "\<bar>a\<bar> \<le> b \<Longrightarrow> - a \<le> b"
   860   by (insert abs_le_D1 [of "uminus a"], simp)
   861 
   862 lemma abs_le_iff: "\<bar>a\<bar> \<le> b \<longleftrightarrow> a \<le> b \<and> - a \<le> b"
   863   by (blast intro: abs_leI dest: abs_le_D1 abs_le_D2)
   864 
   865 lemma abs_triangle_ineq2: "\<bar>a\<bar> - \<bar>b\<bar> \<le> \<bar>a - b\<bar>"
   866   apply (simp add: compare_rls)
   867   apply (subgoal_tac "abs a = abs (plus (minus a b) b)")
   868   apply (erule ssubst)
   869   apply (rule abs_triangle_ineq)
   870   apply (rule arg_cong) back
   871   apply (simp add: compare_rls)
   872 done
   873 
   874 lemma abs_triangle_ineq3: "\<bar>\<bar>a\<bar> - \<bar>b\<bar>\<bar> \<le> \<bar>a - b\<bar>"
   875   apply (subst abs_le_iff)
   876   apply auto
   877   apply (rule abs_triangle_ineq2)
   878   apply (subst abs_minus_commute)
   879   apply (rule abs_triangle_ineq2)
   880 done
   881 
   882 lemma abs_triangle_ineq4: "\<bar>a - b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
   883 proof -
   884   have "abs(a - b) = abs(a + - b)"
   885     by (subst diff_minus, rule refl)
   886   also have "... <= abs a + abs (- b)"
   887     by (rule abs_triangle_ineq)
   888   finally show ?thesis
   889     by simp
   890 qed
   891 
   892 lemma abs_diff_triangle_ineq: "\<bar>a + b - (c + d)\<bar> \<le> \<bar>a - c\<bar> + \<bar>b - d\<bar>"
   893 proof -
   894   have "\<bar>a + b - (c+d)\<bar> = \<bar>(a-c) + (b-d)\<bar>" by (simp add: diff_minus add_ac)
   895   also have "... \<le> \<bar>a-c\<bar> + \<bar>b-d\<bar>" by (rule abs_triangle_ineq)
   896   finally show ?thesis .
   897 qed
   898 
   899 lemma abs_add_abs [simp]:
   900   "\<bar>\<bar>a\<bar> + \<bar>b\<bar>\<bar> = \<bar>a\<bar> + \<bar>b\<bar>" (is "?L = ?R")
   901 proof (rule antisym)
   902   show "?L \<ge> ?R" by(rule abs_ge_self)
   903 next
   904   have "?L \<le> \<bar>\<bar>a\<bar>\<bar> + \<bar>\<bar>b\<bar>\<bar>" by(rule abs_triangle_ineq)
   905   also have "\<dots> = ?R" by simp
   906   finally show "?L \<le> ?R" .
   907 qed
   908 
   909 end
   910 
   911 
   912 subsection {* Lattice Ordered (Abelian) Groups *}
   913 
   914 class lordered_ab_group_add_meet = pordered_ab_group_add + lower_semilattice
   915 begin
   916 
   917 lemma add_inf_distrib_left:
   918   "a + inf b c = inf (a + b) (a + c)"
   919 apply (rule antisym)
   920 apply (simp_all add: le_infI)
   921 apply (rule add_le_imp_le_left [of "uminus a"])
   922 apply (simp only: add_assoc [symmetric], simp)
   923 apply rule
   924 apply (rule add_le_imp_le_left[of "a"], simp only: add_assoc[symmetric], simp)+
   925 done
   926 
   927 lemma add_inf_distrib_right:
   928   "inf a b + c = inf (a + c) (b + c)"
   929 proof -
   930   have "c + inf a b = inf (c+a) (c+b)" by (simp add: add_inf_distrib_left)
   931   thus ?thesis by (simp add: add_commute)
   932 qed
   933 
   934 end
   935 
   936 class lordered_ab_group_add_join = pordered_ab_group_add + upper_semilattice
   937 begin
   938 
   939 lemma add_sup_distrib_left:
   940   "a + sup b c = sup (a + b) (a + c)" 
   941 apply (rule antisym)
   942 apply (rule add_le_imp_le_left [of "uminus a"])
   943 apply (simp only: add_assoc[symmetric], simp)
   944 apply rule
   945 apply (rule add_le_imp_le_left [of "a"], simp only: add_assoc[symmetric], simp)+
   946 apply (rule le_supI)
   947 apply (simp_all)
   948 done
   949 
   950 lemma add_sup_distrib_right:
   951   "sup a b + c = sup (a+c) (b+c)"
   952 proof -
   953   have "c + sup a b = sup (c+a) (c+b)" by (simp add: add_sup_distrib_left)
   954   thus ?thesis by (simp add: add_commute)
   955 qed
   956 
   957 end
   958 
   959 class lordered_ab_group_add = pordered_ab_group_add + lattice
   960 begin
   961 
   962 subclass lordered_ab_group_add_meet ..
   963 subclass lordered_ab_group_add_join ..
   964 
   965 lemmas add_sup_inf_distribs = add_inf_distrib_right add_inf_distrib_left add_sup_distrib_right add_sup_distrib_left
   966 
   967 lemma inf_eq_neg_sup: "inf a b = - sup (-a) (-b)"
   968 proof (rule inf_unique)
   969   fix a b :: 'a
   970   show "- sup (-a) (-b) \<le> a"
   971     by (rule add_le_imp_le_right [of _ "sup (uminus a) (uminus b)"])
   972       (simp, simp add: add_sup_distrib_left)
   973 next
   974   fix a b :: 'a
   975   show "- sup (-a) (-b) \<le> b"
   976     by (rule add_le_imp_le_right [of _ "sup (uminus a) (uminus b)"])
   977       (simp, simp add: add_sup_distrib_left)
   978 next
   979   fix a b c :: 'a
   980   assume "a \<le> b" "a \<le> c"
   981   then show "a \<le> - sup (-b) (-c)" by (subst neg_le_iff_le [symmetric])
   982     (simp add: le_supI)
   983 qed
   984   
   985 lemma sup_eq_neg_inf: "sup a b = - inf (-a) (-b)"
   986 proof (rule sup_unique)
   987   fix a b :: 'a
   988   show "a \<le> - inf (-a) (-b)"
   989     by (rule add_le_imp_le_right [of _ "inf (uminus a) (uminus b)"])
   990       (simp, simp add: add_inf_distrib_left)
   991 next
   992   fix a b :: 'a
   993   show "b \<le> - inf (-a) (-b)"
   994     by (rule add_le_imp_le_right [of _ "inf (uminus a) (uminus b)"])
   995       (simp, simp add: add_inf_distrib_left)
   996 next
   997   fix a b c :: 'a
   998   assume "a \<le> c" "b \<le> c"
   999   then show "- inf (-a) (-b) \<le> c" by (subst neg_le_iff_le [symmetric])
  1000     (simp add: le_infI)
  1001 qed
  1002 
  1003 lemma neg_inf_eq_sup: "- inf a b = sup (-a) (-b)"
  1004   by (simp add: inf_eq_neg_sup)
  1005 
  1006 lemma neg_sup_eq_inf: "- sup a b = inf (-a) (-b)"
  1007   by (simp add: sup_eq_neg_inf)
  1008 
  1009 lemma add_eq_inf_sup: "a + b = sup a b + inf a b"
  1010 proof -
  1011   have "0 = - inf 0 (a-b) + inf (a-b) 0" by (simp add: inf_commute)
  1012   hence "0 = sup 0 (b-a) + inf (a-b) 0" by (simp add: inf_eq_neg_sup)
  1013   hence "0 = (-a + sup a b) + (inf a b + (-b))"
  1014     apply (simp add: add_sup_distrib_left add_inf_distrib_right)
  1015     by (simp add: diff_minus add_commute)
  1016   thus ?thesis
  1017     apply (simp add: compare_rls)
  1018     apply (subst add_left_cancel [symmetric, of "plus a b" "plus (sup a b) (inf a b)" "uminus a"])
  1019     apply (simp only: add_assoc, simp add: add_assoc[symmetric])
  1020     done
  1021 qed
  1022 
  1023 subsection {* Positive Part, Negative Part, Absolute Value *}
  1024 
  1025 definition
  1026   nprt :: "'a \<Rightarrow> 'a" where
  1027   "nprt x = inf x 0"
  1028 
  1029 definition
  1030   pprt :: "'a \<Rightarrow> 'a" where
  1031   "pprt x = sup x 0"
  1032 
  1033 lemma pprt_neg: "pprt (- x) = - nprt x"
  1034 proof -
  1035   have "sup (- x) 0 = sup (- x) (- 0)" unfolding minus_zero ..
  1036   also have "\<dots> = - inf x 0" unfolding neg_inf_eq_sup ..
  1037   finally have "sup (- x) 0 = - inf x 0" .
  1038   then show ?thesis unfolding pprt_def nprt_def .
  1039 qed
  1040 
  1041 lemma nprt_neg: "nprt (- x) = - pprt x"
  1042 proof -
  1043   from pprt_neg have "pprt (- (- x)) = - nprt (- x)" .
  1044   then have "pprt x = - nprt (- x)" by simp
  1045   then show ?thesis by simp
  1046 qed
  1047 
  1048 lemma prts: "a = pprt a + nprt a"
  1049   by (simp add: pprt_def nprt_def add_eq_inf_sup[symmetric])
  1050 
  1051 lemma zero_le_pprt[simp]: "0 \<le> pprt a"
  1052   by (simp add: pprt_def)
  1053 
  1054 lemma nprt_le_zero[simp]: "nprt a \<le> 0"
  1055   by (simp add: nprt_def)
  1056 
  1057 lemma le_eq_neg: "a \<le> - b \<longleftrightarrow> a + b \<le> 0" (is "?l = ?r")
  1058 proof -
  1059   have a: "?l \<longrightarrow> ?r"
  1060     apply (auto)
  1061     apply (rule add_le_imp_le_right[of _ "uminus b" _])
  1062     apply (simp add: add_assoc)
  1063     done
  1064   have b: "?r \<longrightarrow> ?l"
  1065     apply (auto)
  1066     apply (rule add_le_imp_le_right[of _ "b" _])
  1067     apply (simp)
  1068     done
  1069   from a b show ?thesis by blast
  1070 qed
  1071 
  1072 lemma pprt_0[simp]: "pprt 0 = 0" by (simp add: pprt_def)
  1073 lemma nprt_0[simp]: "nprt 0 = 0" by (simp add: nprt_def)
  1074 
  1075 lemma pprt_eq_id [simp, noatp]: "0 \<le> x \<Longrightarrow> pprt x = x"
  1076   by (simp add: pprt_def le_iff_sup sup_ACI)
  1077 
  1078 lemma nprt_eq_id [simp, noatp]: "x \<le> 0 \<Longrightarrow> nprt x = x"
  1079   by (simp add: nprt_def le_iff_inf inf_ACI)
  1080 
  1081 lemma pprt_eq_0 [simp, noatp]: "x \<le> 0 \<Longrightarrow> pprt x = 0"
  1082   by (simp add: pprt_def le_iff_sup sup_ACI)
  1083 
  1084 lemma nprt_eq_0 [simp, noatp]: "0 \<le> x \<Longrightarrow> nprt x = 0"
  1085   by (simp add: nprt_def le_iff_inf inf_ACI)
  1086 
  1087 lemma sup_0_imp_0: "sup a (- a) = 0 \<Longrightarrow> a = 0"
  1088 proof -
  1089   {
  1090     fix a::'a
  1091     assume hyp: "sup a (-a) = 0"
  1092     hence "sup a (-a) + a = a" by (simp)
  1093     hence "sup (a+a) 0 = a" by (simp add: add_sup_distrib_right) 
  1094     hence "sup (a+a) 0 <= a" by (simp)
  1095     hence "0 <= a" by (blast intro: order_trans inf_sup_ord)
  1096   }
  1097   note p = this
  1098   assume hyp:"sup a (-a) = 0"
  1099   hence hyp2:"sup (-a) (-(-a)) = 0" by (simp add: sup_commute)
  1100   from p[OF hyp] p[OF hyp2] show "a = 0" by simp
  1101 qed
  1102 
  1103 lemma inf_0_imp_0: "inf a (-a) = 0 \<Longrightarrow> a = 0"
  1104 apply (simp add: inf_eq_neg_sup)
  1105 apply (simp add: sup_commute)
  1106 apply (erule sup_0_imp_0)
  1107 done
  1108 
  1109 lemma inf_0_eq_0 [simp, noatp]: "inf a (- a) = 0 \<longleftrightarrow> a = 0"
  1110   by (rule, erule inf_0_imp_0) simp
  1111 
  1112 lemma sup_0_eq_0 [simp, noatp]: "sup a (- a) = 0 \<longleftrightarrow> a = 0"
  1113   by (rule, erule sup_0_imp_0) simp
  1114 
  1115 lemma zero_le_double_add_iff_zero_le_single_add [simp]:
  1116   "0 \<le> a + a \<longleftrightarrow> 0 \<le> a"
  1117 proof
  1118   assume "0 <= a + a"
  1119   hence a:"inf (a+a) 0 = 0" by (simp add: le_iff_inf inf_commute)
  1120   have "(inf a 0)+(inf a 0) = inf (inf (a+a) 0) a" (is "?l=_")
  1121     by (simp add: add_sup_inf_distribs inf_ACI)
  1122   hence "?l = 0 + inf a 0" by (simp add: a, simp add: inf_commute)
  1123   hence "inf a 0 = 0" by (simp only: add_right_cancel)
  1124   then show "0 <= a" by (simp add: le_iff_inf inf_commute)    
  1125 next  
  1126   assume a: "0 <= a"
  1127   show "0 <= a + a" by (simp add: add_mono[OF a a, simplified])
  1128 qed
  1129 
  1130 lemma double_zero: "a + a = 0 \<longleftrightarrow> a = 0"
  1131 proof
  1132   assume assm: "a + a = 0"
  1133   then have "a + a + - a = - a" by simp
  1134   then have "a + (a + - a) = - a" by (simp only: add_assoc)
  1135   then have a: "- a = a" by simp (*FIXME tune proof*)
  1136   show "a = 0" apply (rule antisym)
  1137   apply (unfold neg_le_iff_le [symmetric, of a])
  1138   unfolding a apply simp
  1139   unfolding zero_le_double_add_iff_zero_le_single_add [symmetric, of a]
  1140   unfolding assm unfolding le_less apply simp_all done
  1141 next
  1142   assume "a = 0" then show "a + a = 0" by simp
  1143 qed
  1144 
  1145 lemma zero_less_double_add_iff_zero_less_single_add:
  1146   "0 < a + a \<longleftrightarrow> 0 < a"
  1147 proof (cases "a = 0")
  1148   case True then show ?thesis by auto
  1149 next
  1150   case False then show ?thesis (*FIXME tune proof*)
  1151   unfolding less_le apply simp apply rule
  1152   apply clarify
  1153   apply rule
  1154   apply assumption
  1155   apply (rule notI)
  1156   unfolding double_zero [symmetric, of a] apply simp
  1157   done
  1158 qed
  1159 
  1160 lemma double_add_le_zero_iff_single_add_le_zero [simp]:
  1161   "a + a \<le> 0 \<longleftrightarrow> a \<le> 0" 
  1162 proof -
  1163   have "a + a \<le> 0 \<longleftrightarrow> 0 \<le> - (a + a)" by (subst le_minus_iff, simp)
  1164   moreover have "\<dots> \<longleftrightarrow> a \<le> 0" by (simp add: zero_le_double_add_iff_zero_le_single_add)
  1165   ultimately show ?thesis by blast
  1166 qed
  1167 
  1168 lemma double_add_less_zero_iff_single_less_zero [simp]:
  1169   "a + a < 0 \<longleftrightarrow> a < 0"
  1170 proof -
  1171   have "a + a < 0 \<longleftrightarrow> 0 < - (a + a)" by (subst less_minus_iff, simp)
  1172   moreover have "\<dots> \<longleftrightarrow> a < 0" by (simp add: zero_less_double_add_iff_zero_less_single_add)
  1173   ultimately show ?thesis by blast
  1174 qed
  1175 
  1176 declare neg_inf_eq_sup [simp] neg_sup_eq_inf [simp]
  1177 
  1178 lemma le_minus_self_iff: "a \<le> - a \<longleftrightarrow> a \<le> 0"
  1179 proof -
  1180   from add_le_cancel_left [of "uminus a" "plus a a" zero]
  1181   have "(a <= -a) = (a+a <= 0)" 
  1182     by (simp add: add_assoc[symmetric])
  1183   thus ?thesis by simp
  1184 qed
  1185 
  1186 lemma minus_le_self_iff: "- a \<le> a \<longleftrightarrow> 0 \<le> a"
  1187 proof -
  1188   from add_le_cancel_left [of "uminus a" zero "plus a a"]
  1189   have "(-a <= a) = (0 <= a+a)" 
  1190     by (simp add: add_assoc[symmetric])
  1191   thus ?thesis by simp
  1192 qed
  1193 
  1194 lemma zero_le_iff_zero_nprt: "0 \<le> a \<longleftrightarrow> nprt a = 0"
  1195   by (simp add: le_iff_inf nprt_def inf_commute)
  1196 
  1197 lemma le_zero_iff_zero_pprt: "a \<le> 0 \<longleftrightarrow> pprt a = 0"
  1198   by (simp add: le_iff_sup pprt_def sup_commute)
  1199 
  1200 lemma le_zero_iff_pprt_id: "0 \<le> a \<longleftrightarrow> pprt a = a"
  1201   by (simp add: le_iff_sup pprt_def sup_commute)
  1202 
  1203 lemma zero_le_iff_nprt_id: "a \<le> 0 \<longleftrightarrow> nprt a = a"
  1204   by (simp add: le_iff_inf nprt_def inf_commute)
  1205 
  1206 lemma pprt_mono [simp, noatp]: "a \<le> b \<Longrightarrow> pprt a \<le> pprt b"
  1207   by (simp add: le_iff_sup pprt_def sup_ACI sup_assoc [symmetric, of a])
  1208 
  1209 lemma nprt_mono [simp, noatp]: "a \<le> b \<Longrightarrow> nprt a \<le> nprt b"
  1210   by (simp add: le_iff_inf nprt_def inf_ACI inf_assoc [symmetric, of a])
  1211 
  1212 end
  1213 
  1214 lemmas add_sup_inf_distribs = add_inf_distrib_right add_inf_distrib_left add_sup_distrib_right add_sup_distrib_left
  1215 
  1216 
  1217 class lordered_ab_group_add_abs = lordered_ab_group_add + abs +
  1218   assumes abs_lattice: "\<bar>a\<bar> = sup a (- a)"
  1219 begin
  1220 
  1221 lemma abs_prts: "\<bar>a\<bar> = pprt a - nprt a"
  1222 proof -
  1223   have "0 \<le> \<bar>a\<bar>"
  1224   proof -
  1225     have a: "a \<le> \<bar>a\<bar>" and b: "- a \<le> \<bar>a\<bar>" by (auto simp add: abs_lattice)
  1226     show ?thesis by (rule add_mono [OF a b, simplified])
  1227   qed
  1228   then have "0 \<le> sup a (- a)" unfolding abs_lattice .
  1229   then have "sup (sup a (- a)) 0 = sup a (- a)" by (rule sup_absorb1)
  1230   then show ?thesis
  1231     by (simp add: add_sup_inf_distribs sup_ACI
  1232       pprt_def nprt_def diff_minus abs_lattice)
  1233 qed
  1234 
  1235 subclass pordered_ab_group_add_abs
  1236 proof -
  1237   have abs_ge_zero [simp]: "\<And>a. 0 \<le> \<bar>a\<bar>"
  1238   proof -
  1239     fix a b
  1240     have a: "a \<le> \<bar>a\<bar>" and b: "- a \<le> \<bar>a\<bar>" by (auto simp add: abs_lattice)
  1241     show "0 \<le> \<bar>a\<bar>" by (rule add_mono [OF a b, simplified])
  1242   qed
  1243   have abs_leI: "\<And>a b. a \<le> b \<Longrightarrow> - a \<le> b \<Longrightarrow> \<bar>a\<bar> \<le> b"
  1244     by (simp add: abs_lattice le_supI)
  1245   show ?thesis
  1246   proof unfold_locales
  1247     fix a
  1248     show "0 \<le> \<bar>a\<bar>" by simp
  1249   next
  1250     fix a
  1251     show "a \<le> \<bar>a\<bar>"
  1252       by (auto simp add: abs_lattice)
  1253   next
  1254     fix a
  1255     show "\<bar>-a\<bar> = \<bar>a\<bar>"
  1256       by (simp add: abs_lattice sup_commute)
  1257   next
  1258     fix a b
  1259     show "a \<le> b \<Longrightarrow> - a \<le> b \<Longrightarrow> \<bar>a\<bar> \<le> b" by (erule abs_leI)
  1260   next
  1261     fix a b
  1262     show "\<bar>a + b\<bar> \<le> \<bar>a\<bar> + \<bar>b\<bar>"
  1263     proof -
  1264       have g:"abs a + abs b = sup (a+b) (sup (-a-b) (sup (-a+b) (a + (-b))))" (is "_=sup ?m ?n")
  1265         by (simp add: abs_lattice add_sup_inf_distribs sup_ACI diff_minus)
  1266       have a:"a+b <= sup ?m ?n" by (simp)
  1267       have b:"-a-b <= ?n" by (simp) 
  1268       have c:"?n <= sup ?m ?n" by (simp)
  1269       from b c have d: "-a-b <= sup ?m ?n" by(rule order_trans)
  1270       have e:"-a-b = -(a+b)" by (simp add: diff_minus)
  1271       from a d e have "abs(a+b) <= sup ?m ?n" 
  1272         by (drule_tac abs_leI, auto)
  1273       with g[symmetric] show ?thesis by simp
  1274     qed
  1275   qed auto
  1276 qed
  1277 
  1278 end
  1279 
  1280 lemma sup_eq_if:
  1281   fixes a :: "'a\<Colon>{lordered_ab_group_add, linorder}"
  1282   shows "sup a (- a) = (if a < 0 then - a else a)"
  1283 proof -
  1284   note add_le_cancel_right [of a a "- a", symmetric, simplified]
  1285   moreover note add_le_cancel_right [of "-a" a a, symmetric, simplified]
  1286   then show ?thesis by (auto simp: sup_max max_def)
  1287 qed
  1288 
  1289 lemma abs_if_lattice:
  1290   fixes a :: "'a\<Colon>{lordered_ab_group_add_abs, linorder}"
  1291   shows "\<bar>a\<bar> = (if a < 0 then - a else a)"
  1292   by auto
  1293 
  1294 
  1295 text {* Needed for abelian cancellation simprocs: *}
  1296 
  1297 lemma add_cancel_21: "((x::'a::ab_group_add) + (y + z) = y + u) = (x + z = u)"
  1298 apply (subst add_left_commute)
  1299 apply (subst add_left_cancel)
  1300 apply simp
  1301 done
  1302 
  1303 lemma add_cancel_end: "(x + (y + z) = y) = (x = - (z::'a::ab_group_add))"
  1304 apply (subst add_cancel_21[of _ _ _ 0, simplified])
  1305 apply (simp add: add_right_cancel[symmetric, of "x" "-z" "z", simplified])
  1306 done
  1307 
  1308 lemma less_eqI: "(x::'a::pordered_ab_group_add) - y = x' - y' \<Longrightarrow> (x < y) = (x' < y')"
  1309 by (simp add: less_iff_diff_less_0[of x y] less_iff_diff_less_0[of x' y'])
  1310 
  1311 lemma le_eqI: "(x::'a::pordered_ab_group_add) - y = x' - y' \<Longrightarrow> (y <= x) = (y' <= x')"
  1312 apply (simp add: le_iff_diff_le_0[of y x] le_iff_diff_le_0[of  y' x'])
  1313 apply (simp add: neg_le_iff_le[symmetric, of "y-x" 0] neg_le_iff_le[symmetric, of "y'-x'" 0])
  1314 done
  1315 
  1316 lemma eq_eqI: "(x::'a::ab_group_add) - y = x' - y' \<Longrightarrow> (x = y) = (x' = y')"
  1317 by (simp add: eq_iff_diff_eq_0[of x y] eq_iff_diff_eq_0[of x' y'])
  1318 
  1319 lemma diff_def: "(x::'a::ab_group_add) - y == x + (-y)"
  1320 by (simp add: diff_minus)
  1321 
  1322 lemma add_minus_cancel: "(a::'a::ab_group_add) + (-a + b) = b"
  1323 by (simp add: add_assoc[symmetric])
  1324 
  1325 lemma le_add_right_mono: 
  1326   assumes 
  1327   "a <= b + (c::'a::pordered_ab_group_add)"
  1328   "c <= d"    
  1329   shows "a <= b + d"
  1330   apply (rule_tac order_trans[where y = "b+c"])
  1331   apply (simp_all add: prems)
  1332   done
  1333 
  1334 lemma estimate_by_abs:
  1335   "a + b <= (c::'a::lordered_ab_group_add_abs) \<Longrightarrow> a <= c + abs b" 
  1336 proof -
  1337   assume "a+b <= c"
  1338   hence 2: "a <= c+(-b)" by (simp add: group_simps)
  1339   have 3: "(-b) <= abs b" by (rule abs_ge_minus_self)
  1340   show ?thesis by (rule le_add_right_mono[OF 2 3])
  1341 qed
  1342 
  1343 subsection {* Tools setup *}
  1344 
  1345 lemma add_mono_thms_ordered_semiring [noatp]:
  1346   fixes i j k :: "'a\<Colon>pordered_ab_semigroup_add"
  1347   shows "i \<le> j \<and> k \<le> l \<Longrightarrow> i + k \<le> j + l"
  1348     and "i = j \<and> k \<le> l \<Longrightarrow> i + k \<le> j + l"
  1349     and "i \<le> j \<and> k = l \<Longrightarrow> i + k \<le> j + l"
  1350     and "i = j \<and> k = l \<Longrightarrow> i + k = j + l"
  1351 by (rule add_mono, clarify+)+
  1352 
  1353 lemma add_mono_thms_ordered_field [noatp]:
  1354   fixes i j k :: "'a\<Colon>pordered_cancel_ab_semigroup_add"
  1355   shows "i < j \<and> k = l \<Longrightarrow> i + k < j + l"
  1356     and "i = j \<and> k < l \<Longrightarrow> i + k < j + l"
  1357     and "i < j \<and> k \<le> l \<Longrightarrow> i + k < j + l"
  1358     and "i \<le> j \<and> k < l \<Longrightarrow> i + k < j + l"
  1359     and "i < j \<and> k < l \<Longrightarrow> i + k < j + l"
  1360 by (auto intro: add_strict_right_mono add_strict_left_mono
  1361   add_less_le_mono add_le_less_mono add_strict_mono)
  1362 
  1363 text{*Simplification of @{term "x-y < 0"}, etc.*}
  1364 lemmas diff_less_0_iff_less [simp] = less_iff_diff_less_0 [symmetric]
  1365 lemmas diff_eq_0_iff_eq [simp, noatp] = eq_iff_diff_eq_0 [symmetric]
  1366 lemmas diff_le_0_iff_le [simp] = le_iff_diff_le_0 [symmetric]
  1367 
  1368 ML {*
  1369 structure ab_group_add_cancel = Abel_Cancel
  1370 (
  1371 
  1372 (* term order for abelian groups *)
  1373 
  1374 fun agrp_ord (Const (a, _)) = find_index (fn a' => a = a')
  1375       [@{const_name HOL.zero}, @{const_name HOL.plus},
  1376         @{const_name HOL.uminus}, @{const_name HOL.minus}]
  1377   | agrp_ord _ = ~1;
  1378 
  1379 fun termless_agrp (a, b) = (Term.term_lpo agrp_ord (a, b) = LESS);
  1380 
  1381 local
  1382   val ac1 = mk_meta_eq @{thm add_assoc};
  1383   val ac2 = mk_meta_eq @{thm add_commute};
  1384   val ac3 = mk_meta_eq @{thm add_left_commute};
  1385   fun solve_add_ac thy _ (_ $ (Const (@{const_name HOL.plus},_) $ _ $ _) $ _) =
  1386         SOME ac1
  1387     | solve_add_ac thy _ (_ $ x $ (Const (@{const_name HOL.plus},_) $ y $ z)) =
  1388         if termless_agrp (y, x) then SOME ac3 else NONE
  1389     | solve_add_ac thy _ (_ $ x $ y) =
  1390         if termless_agrp (y, x) then SOME ac2 else NONE
  1391     | solve_add_ac thy _ _ = NONE
  1392 in
  1393   val add_ac_proc = Simplifier.simproc (the_context ())
  1394     "add_ac_proc" ["x + y::'a::ab_semigroup_add"] solve_add_ac;
  1395 end;
  1396 
  1397 val eq_reflection = @{thm eq_reflection};
  1398   
  1399 val T = @{typ "'a::ab_group_add"};
  1400 
  1401 val cancel_ss = HOL_basic_ss settermless termless_agrp
  1402   addsimprocs [add_ac_proc] addsimps
  1403   [@{thm add_0_left}, @{thm add_0_right}, @{thm diff_def},
  1404    @{thm minus_add_distrib}, @{thm minus_minus}, @{thm minus_zero},
  1405    @{thm right_minus}, @{thm left_minus}, @{thm add_minus_cancel},
  1406    @{thm minus_add_cancel}];
  1407 
  1408 val sum_pats = [@{cterm "x + y::'a::ab_group_add"}, @{cterm "x - y::'a::ab_group_add"}];
  1409   
  1410 val eqI_rules = [@{thm less_eqI}, @{thm le_eqI}, @{thm eq_eqI}];
  1411 
  1412 val dest_eqI = 
  1413   fst o HOLogic.dest_bin "op =" HOLogic.boolT o HOLogic.dest_Trueprop o concl_of;
  1414 
  1415 );
  1416 *}
  1417 
  1418 ML {*
  1419   Addsimprocs [ab_group_add_cancel.sum_conv, ab_group_add_cancel.rel_conv];
  1420 *}
  1421 
  1422 end