src/HOL/SetInterval.thy
author nipkow
Fri Oct 05 08:38:09 2007 +0200 (2007-10-05)
changeset 24853 aab5798e5a33
parent 24748 ee0a0eb6b738
child 25062 af5ef0d4d655
permissions -rw-r--r--
added lemmas
     1 (*  Title:      HOL/SetInterval.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Clemens Ballarin
     4                 Additions by Jeremy Avigad in March 2004
     5     Copyright   2000  TU Muenchen
     6 
     7 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     8 *)
     9 
    10 header {* Set intervals *}
    11 
    12 theory SetInterval
    13 imports IntArith
    14 begin
    15 
    16 context ord
    17 begin
    18 definition
    19   lessThan    :: "'a => 'a set"	("(1\<^loc>{..<_})") where
    20   "\<^loc>{..<u} == {x. x \<^loc>< u}"
    21 
    22 definition
    23   atMost      :: "'a => 'a set"	("(1\<^loc>{.._})") where
    24   "\<^loc>{..u} == {x. x \<^loc>\<le> u}"
    25 
    26 definition
    27   greaterThan :: "'a => 'a set"	("(1\<^loc>{_<..})") where
    28   "\<^loc>{l<..} == {x. l\<^loc><x}"
    29 
    30 definition
    31   atLeast     :: "'a => 'a set"	("(1\<^loc>{_..})") where
    32   "\<^loc>{l..} == {x. l\<^loc>\<le>x}"
    33 
    34 definition
    35   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1\<^loc>{_<..<_})") where
    36   "\<^loc>{l<..<u} == \<^loc>{l<..} Int \<^loc>{..<u}"
    37 
    38 definition
    39   atLeastLessThan :: "'a => 'a => 'a set"      ("(1\<^loc>{_..<_})") where
    40   "\<^loc>{l..<u} == \<^loc>{l..} Int \<^loc>{..<u}"
    41 
    42 definition
    43   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1\<^loc>{_<.._})") where
    44   "\<^loc>{l<..u} == \<^loc>{l<..} Int \<^loc>{..u}"
    45 
    46 definition
    47   atLeastAtMost :: "'a => 'a => 'a set"        ("(1\<^loc>{_.._})") where
    48   "\<^loc>{l..u} == \<^loc>{l..} Int \<^loc>{..u}"
    49 
    50 end
    51 (*
    52 constdefs
    53   lessThan    :: "('a::ord) => 'a set"	("(1{..<_})")
    54   "{..<u} == {x. x<u}"
    55 
    56   atMost      :: "('a::ord) => 'a set"	("(1{.._})")
    57   "{..u} == {x. x<=u}"
    58 
    59   greaterThan :: "('a::ord) => 'a set"	("(1{_<..})")
    60   "{l<..} == {x. l<x}"
    61 
    62   atLeast     :: "('a::ord) => 'a set"	("(1{_..})")
    63   "{l..} == {x. l<=x}"
    64 
    65   greaterThanLessThan :: "['a::ord, 'a] => 'a set"  ("(1{_<..<_})")
    66   "{l<..<u} == {l<..} Int {..<u}"
    67 
    68   atLeastLessThan :: "['a::ord, 'a] => 'a set"      ("(1{_..<_})")
    69   "{l..<u} == {l..} Int {..<u}"
    70 
    71   greaterThanAtMost :: "['a::ord, 'a] => 'a set"    ("(1{_<.._})")
    72   "{l<..u} == {l<..} Int {..u}"
    73 
    74   atLeastAtMost :: "['a::ord, 'a] => 'a set"        ("(1{_.._})")
    75   "{l..u} == {l..} Int {..u}"
    76 *)
    77 
    78 text{* A note of warning when using @{term"{..<n}"} on type @{typ
    79 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    80 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well. *}
    81 
    82 syntax
    83   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3UN _<=_./ _)" 10)
    84   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3UN _<_./ _)" 10)
    85   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3INT _<=_./ _)" 10)
    86   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3INT _<_./ _)" 10)
    87 
    88 syntax (input)
    89   "@UNION_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _\<le>_./ _)" 10)
    90   "@UNION_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Union> _<_./ _)" 10)
    91   "@INTER_le"   :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _\<le>_./ _)" 10)
    92   "@INTER_less" :: "nat => nat => 'b set => 'b set"       ("(3\<Inter> _<_./ _)" 10)
    93 
    94 syntax (xsymbols)
    95   "@UNION_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    96   "@UNION_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Union>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    97   "@INTER_le"   :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ \<le> _\<^esub>)/ _)" 10)
    98   "@INTER_less" :: "nat \<Rightarrow> nat => 'b set => 'b set"       ("(3\<Inter>(00\<^bsub>_ < _\<^esub>)/ _)" 10)
    99 
   100 translations
   101   "UN i<=n. A"  == "UN i:{..n}. A"
   102   "UN i<n. A"   == "UN i:{..<n}. A"
   103   "INT i<=n. A" == "INT i:{..n}. A"
   104   "INT i<n. A"  == "INT i:{..<n}. A"
   105 
   106 
   107 subsection {* Various equivalences *}
   108 
   109 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i\<^loc><k)"
   110 by (simp add: lessThan_def)
   111 
   112 lemma Compl_lessThan [simp]:
   113     "!!k:: 'a::linorder. -lessThan k = atLeast k"
   114 apply (auto simp add: lessThan_def atLeast_def)
   115 done
   116 
   117 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
   118 by auto
   119 
   120 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k\<^loc><i)"
   121 by (simp add: greaterThan_def)
   122 
   123 lemma Compl_greaterThan [simp]:
   124     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   125 apply (simp add: greaterThan_def atMost_def le_def, auto)
   126 done
   127 
   128 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   129 apply (subst Compl_greaterThan [symmetric])
   130 apply (rule double_complement)
   131 done
   132 
   133 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k\<^loc><=i)"
   134 by (simp add: atLeast_def)
   135 
   136 lemma Compl_atLeast [simp]:
   137     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   138 apply (simp add: lessThan_def atLeast_def le_def, auto)
   139 done
   140 
   141 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i\<^loc><=k)"
   142 by (simp add: atMost_def)
   143 
   144 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   145 by (blast intro: order_antisym)
   146 
   147 
   148 subsection {* Logical Equivalences for Set Inclusion and Equality *}
   149 
   150 lemma atLeast_subset_iff [iff]:
   151      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   152 by (blast intro: order_trans)
   153 
   154 lemma atLeast_eq_iff [iff]:
   155      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   156 by (blast intro: order_antisym order_trans)
   157 
   158 lemma greaterThan_subset_iff [iff]:
   159      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   160 apply (auto simp add: greaterThan_def)
   161  apply (subst linorder_not_less [symmetric], blast)
   162 done
   163 
   164 lemma greaterThan_eq_iff [iff]:
   165      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   166 apply (rule iffI)
   167  apply (erule equalityE)
   168  apply (simp_all add: greaterThan_subset_iff)
   169 done
   170 
   171 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   172 by (blast intro: order_trans)
   173 
   174 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   175 by (blast intro: order_antisym order_trans)
   176 
   177 lemma lessThan_subset_iff [iff]:
   178      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   179 apply (auto simp add: lessThan_def)
   180  apply (subst linorder_not_less [symmetric], blast)
   181 done
   182 
   183 lemma lessThan_eq_iff [iff]:
   184      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   185 apply (rule iffI)
   186  apply (erule equalityE)
   187  apply (simp_all add: lessThan_subset_iff)
   188 done
   189 
   190 
   191 subsection {*Two-sided intervals*}
   192 
   193 context ord
   194 begin
   195 
   196 lemma greaterThanLessThan_iff [simp,noatp]:
   197   "(i : \<^loc>{l<..<u}) = (l \<^loc>< i & i \<^loc>< u)"
   198 by (simp add: greaterThanLessThan_def)
   199 
   200 lemma atLeastLessThan_iff [simp,noatp]:
   201   "(i : \<^loc>{l..<u}) = (l \<^loc><= i & i \<^loc>< u)"
   202 by (simp add: atLeastLessThan_def)
   203 
   204 lemma greaterThanAtMost_iff [simp,noatp]:
   205   "(i : \<^loc>{l<..u}) = (l \<^loc>< i & i \<^loc><= u)"
   206 by (simp add: greaterThanAtMost_def)
   207 
   208 lemma atLeastAtMost_iff [simp,noatp]:
   209   "(i : \<^loc>{l..u}) = (l \<^loc><= i & i \<^loc><= u)"
   210 by (simp add: atLeastAtMost_def)
   211 
   212 text {* The above four lemmas could be declared as iffs.
   213   If we do so, a call to blast in Hyperreal/Star.ML, lemma @{text STAR_Int}
   214   seems to take forever (more than one hour). *}
   215 end
   216 
   217 subsubsection{* Emptyness and singletons *}
   218 
   219 context order
   220 begin
   221 
   222 lemma atLeastAtMost_empty [simp]: "n \<^loc>< m ==> \<^loc>{m..n} = {}";
   223 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   224 
   225 lemma atLeastLessThan_empty[simp]: "n \<^loc>\<le> m ==> \<^loc>{m..<n} = {}"
   226 by (auto simp add: atLeastLessThan_def)
   227 
   228 lemma greaterThanAtMost_empty[simp]:"l \<^loc>\<le> k ==> \<^loc>{k<..l} = {}"
   229 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   230 
   231 lemma greaterThanLessThan_empty[simp]:"l \<^loc>\<le> k ==> \<^loc>{k<..l} = {}"
   232 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   233 
   234 lemma atLeastAtMost_singleton [simp]: "\<^loc>{a..a} = {a}"
   235 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   236 
   237 end
   238 
   239 subsection {* Intervals of natural numbers *}
   240 
   241 subsubsection {* The Constant @{term lessThan} *}
   242 
   243 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   244 by (simp add: lessThan_def)
   245 
   246 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   247 by (simp add: lessThan_def less_Suc_eq, blast)
   248 
   249 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   250 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   251 
   252 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   253 by blast
   254 
   255 subsubsection {* The Constant @{term greaterThan} *}
   256 
   257 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   258 apply (simp add: greaterThan_def)
   259 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   260 done
   261 
   262 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   263 apply (simp add: greaterThan_def)
   264 apply (auto elim: linorder_neqE)
   265 done
   266 
   267 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   268 by blast
   269 
   270 subsubsection {* The Constant @{term atLeast} *}
   271 
   272 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   273 by (unfold atLeast_def UNIV_def, simp)
   274 
   275 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   276 apply (simp add: atLeast_def)
   277 apply (simp add: Suc_le_eq)
   278 apply (simp add: order_le_less, blast)
   279 done
   280 
   281 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   282   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   283 
   284 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   285 by blast
   286 
   287 subsubsection {* The Constant @{term atMost} *}
   288 
   289 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   290 by (simp add: atMost_def)
   291 
   292 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   293 apply (simp add: atMost_def)
   294 apply (simp add: less_Suc_eq order_le_less, blast)
   295 done
   296 
   297 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   298 by blast
   299 
   300 subsubsection {* The Constant @{term atLeastLessThan} *}
   301 
   302 text{*The orientation of the following rule is tricky. The lhs is
   303 defined in terms of the rhs.  Hence the chosen orientation makes sense
   304 in this theory --- the reverse orientation complicates proofs (eg
   305 nontermination). But outside, when the definition of the lhs is rarely
   306 used, the opposite orientation seems preferable because it reduces a
   307 specific concept to a more general one. *}
   308 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   309 by(simp add:lessThan_def atLeastLessThan_def)
   310 
   311 declare atLeast0LessThan[symmetric, code unfold]
   312 
   313 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   314 by (simp add: atLeastLessThan_def)
   315 
   316 subsubsection {* Intervals of nats with @{term Suc} *}
   317 
   318 text{*Not a simprule because the RHS is too messy.*}
   319 lemma atLeastLessThanSuc:
   320     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   321 by (auto simp add: atLeastLessThan_def)
   322 
   323 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   324 by (auto simp add: atLeastLessThan_def)
   325 (*
   326 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   327 by (induct k, simp_all add: atLeastLessThanSuc)
   328 
   329 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   330 by (auto simp add: atLeastLessThan_def)
   331 *)
   332 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   333   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   334 
   335 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   336   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   337     greaterThanAtMost_def)
   338 
   339 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   340   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   341     greaterThanLessThan_def)
   342 
   343 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   344 by (auto simp add: atLeastAtMost_def)
   345 
   346 subsubsection {* Image *}
   347 
   348 lemma image_add_atLeastAtMost:
   349   "(%n::nat. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   350 proof
   351   show "?A \<subseteq> ?B" by auto
   352 next
   353   show "?B \<subseteq> ?A"
   354   proof
   355     fix n assume a: "n : ?B"
   356     hence "n - k : {i..j}" by auto
   357     moreover have "n = (n - k) + k" using a by auto
   358     ultimately show "n : ?A" by blast
   359   qed
   360 qed
   361 
   362 lemma image_add_atLeastLessThan:
   363   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   364 proof
   365   show "?A \<subseteq> ?B" by auto
   366 next
   367   show "?B \<subseteq> ?A"
   368   proof
   369     fix n assume a: "n : ?B"
   370     hence "n - k : {i..<j}" by auto
   371     moreover have "n = (n - k) + k" using a by auto
   372     ultimately show "n : ?A" by blast
   373   qed
   374 qed
   375 
   376 corollary image_Suc_atLeastAtMost[simp]:
   377   "Suc ` {i..j} = {Suc i..Suc j}"
   378 using image_add_atLeastAtMost[where k=1] by simp
   379 
   380 corollary image_Suc_atLeastLessThan[simp]:
   381   "Suc ` {i..<j} = {Suc i..<Suc j}"
   382 using image_add_atLeastLessThan[where k=1] by simp
   383 
   384 lemma image_add_int_atLeastLessThan:
   385     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   386   apply (auto simp add: image_def)
   387   apply (rule_tac x = "x - l" in bexI)
   388   apply auto
   389   done
   390 
   391 
   392 subsubsection {* Finiteness *}
   393 
   394 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   395   by (induct k) (simp_all add: lessThan_Suc)
   396 
   397 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   398   by (induct k) (simp_all add: atMost_Suc)
   399 
   400 lemma finite_greaterThanLessThan [iff]:
   401   fixes l :: nat shows "finite {l<..<u}"
   402 by (simp add: greaterThanLessThan_def)
   403 
   404 lemma finite_atLeastLessThan [iff]:
   405   fixes l :: nat shows "finite {l..<u}"
   406 by (simp add: atLeastLessThan_def)
   407 
   408 lemma finite_greaterThanAtMost [iff]:
   409   fixes l :: nat shows "finite {l<..u}"
   410 by (simp add: greaterThanAtMost_def)
   411 
   412 lemma finite_atLeastAtMost [iff]:
   413   fixes l :: nat shows "finite {l..u}"
   414 by (simp add: atLeastAtMost_def)
   415 
   416 lemma bounded_nat_set_is_finite:
   417   "(ALL i:N. i < (n::nat)) ==> finite N"
   418   -- {* A bounded set of natural numbers is finite. *}
   419   apply (rule finite_subset)
   420    apply (rule_tac [2] finite_lessThan, auto)
   421   done
   422 
   423 text{* Any subset of an interval of natural numbers the size of the
   424 subset is exactly that interval. *}
   425 
   426 lemma subset_card_intvl_is_intvl:
   427   "A <= {k..<k+card A} \<Longrightarrow> A = {k..<k+card A}" (is "PROP ?P")
   428 proof cases
   429   assume "finite A"
   430   thus "PROP ?P"
   431   proof(induct A rule:finite_linorder_induct)
   432     case empty thus ?case by auto
   433   next
   434     case (insert A b)
   435     moreover hence "b ~: A" by auto
   436     moreover have "A <= {k..<k+card A}" and "b = k+card A"
   437       using `b ~: A` insert by fastsimp+
   438     ultimately show ?case by auto
   439   qed
   440 next
   441   assume "~finite A" thus "PROP ?P" by simp
   442 qed
   443 
   444 
   445 subsubsection {* Cardinality *}
   446 
   447 lemma card_lessThan [simp]: "card {..<u} = u"
   448   by (induct u, simp_all add: lessThan_Suc)
   449 
   450 lemma card_atMost [simp]: "card {..u} = Suc u"
   451   by (simp add: lessThan_Suc_atMost [THEN sym])
   452 
   453 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
   454   apply (subgoal_tac "card {l..<u} = card {..<u-l}")
   455   apply (erule ssubst, rule card_lessThan)
   456   apply (subgoal_tac "(%x. x + l) ` {..<u-l} = {l..<u}")
   457   apply (erule subst)
   458   apply (rule card_image)
   459   apply (simp add: inj_on_def)
   460   apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
   461   apply (rule_tac x = "x - l" in exI)
   462   apply arith
   463   done
   464 
   465 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
   466   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
   467 
   468 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
   469   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
   470 
   471 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
   472   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
   473 
   474 subsection {* Intervals of integers *}
   475 
   476 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
   477   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
   478 
   479 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
   480   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
   481 
   482 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
   483     "{l+1..<u} = {l<..<u::int}"
   484   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
   485 
   486 subsubsection {* Finiteness *}
   487 
   488 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
   489     {(0::int)..<u} = int ` {..<nat u}"
   490   apply (unfold image_def lessThan_def)
   491   apply auto
   492   apply (rule_tac x = "nat x" in exI)
   493   apply (auto simp add: zless_nat_conj zless_nat_eq_int_zless [THEN sym])
   494   done
   495 
   496 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
   497   apply (case_tac "0 \<le> u")
   498   apply (subst image_atLeastZeroLessThan_int, assumption)
   499   apply (rule finite_imageI)
   500   apply auto
   501   done
   502 
   503 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
   504   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   505   apply (erule subst)
   506   apply (rule finite_imageI)
   507   apply (rule finite_atLeastZeroLessThan_int)
   508   apply (rule image_add_int_atLeastLessThan)
   509   done
   510 
   511 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
   512   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
   513 
   514 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
   515   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   516 
   517 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
   518   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   519 
   520 
   521 subsubsection {* Cardinality *}
   522 
   523 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
   524   apply (case_tac "0 \<le> u")
   525   apply (subst image_atLeastZeroLessThan_int, assumption)
   526   apply (subst card_image)
   527   apply (auto simp add: inj_on_def)
   528   done
   529 
   530 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
   531   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
   532   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
   533   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
   534   apply (erule subst)
   535   apply (rule card_image)
   536   apply (simp add: inj_on_def)
   537   apply (rule image_add_int_atLeastLessThan)
   538   done
   539 
   540 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
   541   apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
   542   apply (auto simp add: compare_rls)
   543   done
   544 
   545 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
   546   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
   547 
   548 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
   549   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
   550 
   551 
   552 subsection {*Lemmas useful with the summation operator setsum*}
   553 
   554 text {* For examples, see Algebra/poly/UnivPoly2.thy *}
   555 
   556 subsubsection {* Disjoint Unions *}
   557 
   558 text {* Singletons and open intervals *}
   559 
   560 lemma ivl_disj_un_singleton:
   561   "{l::'a::linorder} Un {l<..} = {l..}"
   562   "{..<u} Un {u::'a::linorder} = {..u}"
   563   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
   564   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
   565   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
   566   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
   567 by auto
   568 
   569 text {* One- and two-sided intervals *}
   570 
   571 lemma ivl_disj_un_one:
   572   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
   573   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
   574   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
   575   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
   576   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
   577   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
   578   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
   579   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
   580 by auto
   581 
   582 text {* Two- and two-sided intervals *}
   583 
   584 lemma ivl_disj_un_two:
   585   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
   586   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
   587   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
   588   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
   589   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
   590   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
   591   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
   592   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
   593 by auto
   594 
   595 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two
   596 
   597 subsubsection {* Disjoint Intersections *}
   598 
   599 text {* Singletons and open intervals *}
   600 
   601 lemma ivl_disj_int_singleton:
   602   "{l::'a::order} Int {l<..} = {}"
   603   "{..<u} Int {u} = {}"
   604   "{l} Int {l<..<u} = {}"
   605   "{l<..<u} Int {u} = {}"
   606   "{l} Int {l<..u} = {}"
   607   "{l..<u} Int {u} = {}"
   608   by simp+
   609 
   610 text {* One- and two-sided intervals *}
   611 
   612 lemma ivl_disj_int_one:
   613   "{..l::'a::order} Int {l<..<u} = {}"
   614   "{..<l} Int {l..<u} = {}"
   615   "{..l} Int {l<..u} = {}"
   616   "{..<l} Int {l..u} = {}"
   617   "{l<..u} Int {u<..} = {}"
   618   "{l<..<u} Int {u..} = {}"
   619   "{l..u} Int {u<..} = {}"
   620   "{l..<u} Int {u..} = {}"
   621   by auto
   622 
   623 text {* Two- and two-sided intervals *}
   624 
   625 lemma ivl_disj_int_two:
   626   "{l::'a::order<..<m} Int {m..<u} = {}"
   627   "{l<..m} Int {m<..<u} = {}"
   628   "{l..<m} Int {m..<u} = {}"
   629   "{l..m} Int {m<..<u} = {}"
   630   "{l<..<m} Int {m..u} = {}"
   631   "{l<..m} Int {m<..u} = {}"
   632   "{l..<m} Int {m..u} = {}"
   633   "{l..m} Int {m<..u} = {}"
   634   by auto
   635 
   636 lemmas ivl_disj_int = ivl_disj_int_singleton ivl_disj_int_one ivl_disj_int_two
   637 
   638 subsubsection {* Some Differences *}
   639 
   640 lemma ivl_diff[simp]:
   641  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
   642 by(auto)
   643 
   644 
   645 subsubsection {* Some Subset Conditions *}
   646 
   647 lemma ivl_subset [simp,noatp]:
   648  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
   649 apply(auto simp:linorder_not_le)
   650 apply(rule ccontr)
   651 apply(insert linorder_le_less_linear[of i n])
   652 apply(clarsimp simp:linorder_not_le)
   653 apply(fastsimp)
   654 done
   655 
   656 
   657 subsection {* Summation indexed over intervals *}
   658 
   659 syntax
   660   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
   661   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
   662   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
   663   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
   664 syntax (xsymbols)
   665   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   666   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   667   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   668   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   669 syntax (HTML output)
   670   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
   671   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
   672   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
   673   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
   674 syntax (latex_sum output)
   675   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   676  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
   677   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   678  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
   679   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   680  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
   681   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
   682  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
   683 
   684 translations
   685   "\<Sum>x=a..b. t" == "setsum (%x. t) {a..b}"
   686   "\<Sum>x=a..<b. t" == "setsum (%x. t) {a..<b}"
   687   "\<Sum>i\<le>n. t" == "setsum (\<lambda>i. t) {..n}"
   688   "\<Sum>i<n. t" == "setsum (\<lambda>i. t) {..<n}"
   689 
   690 text{* The above introduces some pretty alternative syntaxes for
   691 summation over intervals:
   692 \begin{center}
   693 \begin{tabular}{lll}
   694 Old & New & \LaTeX\\
   695 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
   696 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
   697 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
   698 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
   699 \end{tabular}
   700 \end{center}
   701 The left column shows the term before introduction of the new syntax,
   702 the middle column shows the new (default) syntax, and the right column
   703 shows a special syntax. The latter is only meaningful for latex output
   704 and has to be activated explicitly by setting the print mode to
   705 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
   706 antiquotations). It is not the default \LaTeX\ output because it only
   707 works well with italic-style formulae, not tt-style.
   708 
   709 Note that for uniformity on @{typ nat} it is better to use
   710 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
   711 not provide all lemmas available for @{term"{m..<n}"} also in the
   712 special form for @{term"{..<n}"}. *}
   713 
   714 text{* This congruence rule should be used for sums over intervals as
   715 the standard theorem @{text[source]setsum_cong} does not work well
   716 with the simplifier who adds the unsimplified premise @{term"x:B"} to
   717 the context. *}
   718 
   719 lemma setsum_ivl_cong:
   720  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
   721  setsum f {a..<b} = setsum g {c..<d}"
   722 by(rule setsum_cong, simp_all)
   723 
   724 (* FIXME why are the following simp rules but the corresponding eqns
   725 on intervals are not? *)
   726 
   727 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
   728 by (simp add:atMost_Suc add_ac)
   729 
   730 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
   731 by (simp add:lessThan_Suc add_ac)
   732 
   733 lemma setsum_cl_ivl_Suc[simp]:
   734   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
   735 by (auto simp:add_ac atLeastAtMostSuc_conv)
   736 
   737 lemma setsum_op_ivl_Suc[simp]:
   738   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
   739 by (auto simp:add_ac atLeastLessThanSuc)
   740 (*
   741 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
   742     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
   743 by (auto simp:add_ac atLeastAtMostSuc_conv)
   744 *)
   745 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   746   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
   747 by (simp add:setsum_Un_disjoint[symmetric] ivl_disj_int ivl_disj_un)
   748 
   749 lemma setsum_diff_nat_ivl:
   750 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
   751 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
   752   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
   753 using setsum_add_nat_ivl [of m n p f,symmetric]
   754 apply (simp add: add_ac)
   755 done
   756 
   757 subsection{* Shifting bounds *}
   758 
   759 lemma setsum_shift_bounds_nat_ivl:
   760   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
   761 by (induct "n", auto simp:atLeastLessThanSuc)
   762 
   763 lemma setsum_shift_bounds_cl_nat_ivl:
   764   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
   765 apply (insert setsum_reindex[OF inj_on_add_nat, where h=f and B = "{m..n}"])
   766 apply (simp add:image_add_atLeastAtMost o_def)
   767 done
   768 
   769 corollary setsum_shift_bounds_cl_Suc_ivl:
   770   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
   771 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k=1,simplified])
   772 
   773 corollary setsum_shift_bounds_Suc_ivl:
   774   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
   775 by (simp add:setsum_shift_bounds_nat_ivl[where k=1,simplified])
   776 
   777 lemma setsum_head:
   778   fixes n :: nat
   779   assumes mn: "m <= n" 
   780   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
   781 proof -
   782   from mn
   783   have "{m..n} = {m} \<union> {m<..n}"
   784     by (auto intro: ivl_disj_un_singleton)
   785   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
   786     by (simp add: atLeast0LessThan)
   787   also have "\<dots> = ?rhs" by simp
   788   finally show ?thesis .
   789 qed
   790 
   791 lemma setsum_head_upt:
   792   fixes m::nat
   793   assumes m: "0 < m"
   794   shows "(\<Sum>x<m. P x) = P 0 + (\<Sum>x\<in>{1..<m}. P x)"
   795 proof -
   796   have "(\<Sum>x<m. P x) = (\<Sum>x\<in>{0..<m}. P x)" 
   797     by (simp add: atLeast0LessThan)
   798   also 
   799   from m 
   800   have "\<dots> = (\<Sum>x\<in>{0..m - 1}. P x)"
   801     by (cases m) (auto simp add: atLeastLessThanSuc_atLeastAtMost)
   802   also
   803   have "\<dots> = P 0 + (\<Sum>x\<in>{0<..m - 1}. P x)"
   804     by (simp add: setsum_head)
   805   also 
   806   from m 
   807   have "{0<..m - 1} = {1..<m}" 
   808     by (cases m) (auto simp add: atLeastLessThanSuc_atLeastAtMost)
   809   finally show ?thesis .
   810 qed
   811 
   812 subsection {* The formula for geometric sums *}
   813 
   814 lemma geometric_sum:
   815   "x ~= 1 ==> (\<Sum>i=0..<n. x ^ i) =
   816   (x ^ n - 1) / (x - 1::'a::{field, recpower})"
   817 by (induct "n") (simp_all add:field_simps power_Suc)
   818 
   819 subsection {* The formula for arithmetic sums *}
   820 
   821 lemma gauss_sum:
   822   "((1::'a::comm_semiring_1) + 1)*(\<Sum>i\<in>{1..n}. of_nat i) =
   823    of_nat n*((of_nat n)+1)"
   824 proof (induct n)
   825   case 0
   826   show ?case by simp
   827 next
   828   case (Suc n)
   829   then show ?case by (simp add: ring_simps)
   830 qed
   831 
   832 theorem arith_series_general:
   833   "((1::'a::comm_semiring_1) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   834   of_nat n * (a + (a + of_nat(n - 1)*d))"
   835 proof cases
   836   assume ngt1: "n > 1"
   837   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
   838   have
   839     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
   840      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
   841     by (rule setsum_addf)
   842   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
   843   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
   844     by (simp add: setsum_right_distrib setsum_head_upt mult_ac)
   845   also have "(1+1)*\<dots> = (1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..<n}. ?I i)"
   846     by (simp add: left_distrib right_distrib)
   847   also from ngt1 have "{1..<n} = {1..n - 1}"
   848     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)    
   849   also from ngt1 
   850   have "(1+1)*?n*a + d*(1+1)*(\<Sum>i\<in>{1..n - 1}. ?I i) = ((1+1)*?n*a + d*?I (n - 1)*?I n)"
   851     by (simp only: mult_ac gauss_sum [of "n - 1"])
   852        (simp add:  mult_ac trans [OF add_commute of_nat_Suc [symmetric]])
   853   finally show ?thesis by (simp add: mult_ac add_ac right_distrib)
   854 next
   855   assume "\<not>(n > 1)"
   856   hence "n = 1 \<or> n = 0" by auto
   857   thus ?thesis by (auto simp: mult_ac right_distrib)
   858 qed
   859 
   860 lemma arith_series_nat:
   861   "Suc (Suc 0) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
   862 proof -
   863   have
   864     "((1::nat) + 1) * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
   865     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
   866     by (rule arith_series_general)
   867   thus ?thesis by (auto simp add: of_nat_id)
   868 qed
   869 
   870 lemma arith_series_int:
   871   "(2::int) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   872   of_nat n * (a + (a + of_nat(n - 1)*d))"
   873 proof -
   874   have
   875     "((1::int) + 1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
   876     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
   877     by (rule arith_series_general)
   878   thus ?thesis by simp
   879 qed
   880 
   881 lemma sum_diff_distrib:
   882   fixes P::"nat\<Rightarrow>nat"
   883   shows
   884   "\<forall>x. Q x \<le> P x  \<Longrightarrow>
   885   (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x)"
   886 proof (induct n)
   887   case 0 show ?case by simp
   888 next
   889   case (Suc n)
   890 
   891   let ?lhs = "(\<Sum>x<n. P x) - (\<Sum>x<n. Q x)"
   892   let ?rhs = "\<Sum>x<n. P x - Q x"
   893 
   894   from Suc have "?lhs = ?rhs" by simp
   895   moreover
   896   from Suc have "?lhs + P n - Q n = ?rhs + (P n - Q n)" by simp
   897   moreover
   898   from Suc have
   899     "(\<Sum>x<n. P x) + P n - ((\<Sum>x<n. Q x) + Q n) = ?rhs + (P n - Q n)"
   900     by (subst diff_diff_left[symmetric],
   901         subst diff_add_assoc2)
   902        (auto simp: diff_add_assoc2 intro: setsum_mono)
   903   ultimately
   904   show ?case by simp
   905 qed
   906 
   907 
   908 ML
   909 {*
   910 val Compl_atLeast = thm "Compl_atLeast";
   911 val Compl_atMost = thm "Compl_atMost";
   912 val Compl_greaterThan = thm "Compl_greaterThan";
   913 val Compl_lessThan = thm "Compl_lessThan";
   914 val INT_greaterThan_UNIV = thm "INT_greaterThan_UNIV";
   915 val UN_atLeast_UNIV = thm "UN_atLeast_UNIV";
   916 val UN_atMost_UNIV = thm "UN_atMost_UNIV";
   917 val UN_lessThan_UNIV = thm "UN_lessThan_UNIV";
   918 val atLeastAtMost_def = thm "atLeastAtMost_def";
   919 val atLeastAtMost_iff = thm "atLeastAtMost_iff";
   920 val atLeastLessThan_def  = thm "atLeastLessThan_def";
   921 val atLeastLessThan_iff = thm "atLeastLessThan_iff";
   922 val atLeast_0 = thm "atLeast_0";
   923 val atLeast_Suc = thm "atLeast_Suc";
   924 val atLeast_def      = thm "atLeast_def";
   925 val atLeast_iff = thm "atLeast_iff";
   926 val atMost_0 = thm "atMost_0";
   927 val atMost_Int_atLeast = thm "atMost_Int_atLeast";
   928 val atMost_Suc = thm "atMost_Suc";
   929 val atMost_def       = thm "atMost_def";
   930 val atMost_iff = thm "atMost_iff";
   931 val greaterThanAtMost_def  = thm "greaterThanAtMost_def";
   932 val greaterThanAtMost_iff = thm "greaterThanAtMost_iff";
   933 val greaterThanLessThan_def  = thm "greaterThanLessThan_def";
   934 val greaterThanLessThan_iff = thm "greaterThanLessThan_iff";
   935 val greaterThan_0 = thm "greaterThan_0";
   936 val greaterThan_Suc = thm "greaterThan_Suc";
   937 val greaterThan_def  = thm "greaterThan_def";
   938 val greaterThan_iff = thm "greaterThan_iff";
   939 val ivl_disj_int = thms "ivl_disj_int";
   940 val ivl_disj_int_one = thms "ivl_disj_int_one";
   941 val ivl_disj_int_singleton = thms "ivl_disj_int_singleton";
   942 val ivl_disj_int_two = thms "ivl_disj_int_two";
   943 val ivl_disj_un = thms "ivl_disj_un";
   944 val ivl_disj_un_one = thms "ivl_disj_un_one";
   945 val ivl_disj_un_singleton = thms "ivl_disj_un_singleton";
   946 val ivl_disj_un_two = thms "ivl_disj_un_two";
   947 val lessThan_0 = thm "lessThan_0";
   948 val lessThan_Suc = thm "lessThan_Suc";
   949 val lessThan_Suc_atMost = thm "lessThan_Suc_atMost";
   950 val lessThan_def     = thm "lessThan_def";
   951 val lessThan_iff = thm "lessThan_iff";
   952 val single_Diff_lessThan = thm "single_Diff_lessThan";
   953 
   954 val bounded_nat_set_is_finite = thm "bounded_nat_set_is_finite";
   955 val finite_atMost = thm "finite_atMost";
   956 val finite_lessThan = thm "finite_lessThan";
   957 *}
   958 
   959 end