src/HOL/Tools/Ctr_Sugar/ctr_sugar.ML
author blanchet
Tue Jun 10 12:16:22 2014 +0200 (2014-06-10)
changeset 57200 aab87ffa60cc
parent 57094 589ec121ce1a
child 57260 8747af0d1012
permissions -rw-r--r--
use 'where' clause for selector default value syntax
     1 (*  Title:      HOL/Tools/Ctr_Sugar/ctr_sugar.ML
     2     Author:     Jasmin Blanchette, TU Muenchen
     3     Copyright   2012, 2013
     4 
     5 Wrapping existing freely generated type's constructors.
     6 *)
     7 
     8 signature CTR_SUGAR =
     9 sig
    10   type ctr_sugar =
    11     {ctrs: term list,
    12      casex: term,
    13      discs: term list,
    14      selss: term list list,
    15      exhaust: thm,
    16      nchotomy: thm,
    17      injects: thm list,
    18      distincts: thm list,
    19      case_thms: thm list,
    20      case_cong: thm,
    21      weak_case_cong: thm,
    22      split: thm,
    23      split_asm: thm,
    24      disc_defs: thm list,
    25      disc_thmss: thm list list,
    26      discIs: thm list,
    27      sel_defs: thm list,
    28      sel_thmss: thm list list,
    29      disc_excludesss: thm list list list,
    30      disc_exhausts: thm list,
    31      sel_exhausts: thm list,
    32      collapses: thm list,
    33      expands: thm list,
    34      sel_splits: thm list,
    35      sel_split_asms: thm list,
    36      case_eq_ifs: thm list};
    37 
    38   val morph_ctr_sugar: morphism -> ctr_sugar -> ctr_sugar
    39   val transfer_ctr_sugar: Proof.context -> ctr_sugar -> ctr_sugar
    40   val ctr_sugar_of: Proof.context -> string -> ctr_sugar option
    41   val ctr_sugars_of: Proof.context -> ctr_sugar list
    42   val ctr_sugar_of_case: Proof.context -> string -> ctr_sugar option
    43   val ctr_sugar_interpretation: (ctr_sugar -> theory -> theory) -> theory -> theory
    44   val register_ctr_sugar: string -> ctr_sugar -> local_theory -> local_theory
    45   val default_register_ctr_sugar_global: string -> ctr_sugar -> theory -> theory
    46 
    47   val mk_half_pairss: 'a list * 'a list -> ('a * 'a) list list
    48   val join_halves: int -> 'a list list -> 'a list list -> 'a list * 'a list list list
    49 
    50   val mk_ctr: typ list -> term -> term
    51   val mk_case: typ list -> typ -> term -> term
    52   val mk_disc_or_sel: typ list -> term -> term
    53   val name_of_ctr: term -> string
    54   val name_of_disc: term -> string
    55   val dest_ctr: Proof.context -> string -> term -> term * term list
    56   val dest_case: Proof.context -> string -> typ list -> term ->
    57     (ctr_sugar * term list * term list) option
    58 
    59   type ('c, 'a) ctr_spec = (binding * 'c) * 'a list
    60 
    61   val disc_of_ctr_spec: ('c, 'a) ctr_spec -> binding
    62   val ctr_of_ctr_spec: ('c, 'a) ctr_spec -> 'c
    63   val args_of_ctr_spec: ('c, 'a) ctr_spec -> 'a list
    64 
    65   val free_constructors: ({prems: thm list, context: Proof.context} -> tactic) list list ->
    66     (((bool * bool) * binding) * (term, binding) ctr_spec list) * term list -> local_theory ->
    67     ctr_sugar * local_theory
    68   val parse_bound_term: (binding * string) parser
    69   val parse_ctr_options: (bool * bool) parser
    70   val parse_ctr_spec: 'c parser -> 'a parser -> ('c, 'a) ctr_spec parser
    71   val parse_sel_default_eqs: string list parser
    72 end;
    73 
    74 structure Ctr_Sugar : CTR_SUGAR =
    75 struct
    76 
    77 open Ctr_Sugar_Util
    78 open Ctr_Sugar_Tactics
    79 open Ctr_Sugar_Code
    80 
    81 type ctr_sugar =
    82   {ctrs: term list,
    83    casex: term,
    84    discs: term list,
    85    selss: term list list,
    86    exhaust: thm,
    87    nchotomy: thm,
    88    injects: thm list,
    89    distincts: thm list,
    90    case_thms: thm list,
    91    case_cong: thm,
    92    weak_case_cong: thm,
    93    split: thm,
    94    split_asm: thm,
    95    disc_defs: thm list,
    96    disc_thmss: thm list list,
    97    discIs: thm list,
    98    sel_defs: thm list,
    99    sel_thmss: thm list list,
   100    disc_excludesss: thm list list list,
   101    disc_exhausts: thm list,
   102    sel_exhausts: thm list,
   103    collapses: thm list,
   104    expands: thm list,
   105    sel_splits: thm list,
   106    sel_split_asms: thm list,
   107    case_eq_ifs: thm list};
   108 
   109 fun morph_ctr_sugar phi {ctrs, casex, discs, selss, exhaust, nchotomy, injects, distincts,
   110     case_thms, case_cong, weak_case_cong, split, split_asm, disc_defs, disc_thmss, discIs, sel_defs,
   111     sel_thmss, disc_excludesss, disc_exhausts, sel_exhausts, collapses, expands, sel_splits,
   112     sel_split_asms, case_eq_ifs} =
   113   {ctrs = map (Morphism.term phi) ctrs,
   114    casex = Morphism.term phi casex,
   115    discs = map (Morphism.term phi) discs,
   116    selss = map (map (Morphism.term phi)) selss,
   117    exhaust = Morphism.thm phi exhaust,
   118    nchotomy = Morphism.thm phi nchotomy,
   119    injects = map (Morphism.thm phi) injects,
   120    distincts = map (Morphism.thm phi) distincts,
   121    case_thms = map (Morphism.thm phi) case_thms,
   122    case_cong = Morphism.thm phi case_cong,
   123    weak_case_cong = Morphism.thm phi weak_case_cong,
   124    split = Morphism.thm phi split,
   125    split_asm = Morphism.thm phi split_asm,
   126    disc_defs = map (Morphism.thm phi) disc_defs,
   127    disc_thmss = map (map (Morphism.thm phi)) disc_thmss,
   128    discIs = map (Morphism.thm phi) discIs,
   129    sel_defs = map (Morphism.thm phi) sel_defs,
   130    sel_thmss = map (map (Morphism.thm phi)) sel_thmss,
   131    disc_excludesss = map (map (map (Morphism.thm phi))) disc_excludesss,
   132    disc_exhausts = map (Morphism.thm phi) disc_exhausts,
   133    sel_exhausts = map (Morphism.thm phi) sel_exhausts,
   134    collapses = map (Morphism.thm phi) collapses,
   135    expands = map (Morphism.thm phi) expands,
   136    sel_splits = map (Morphism.thm phi) sel_splits,
   137    sel_split_asms = map (Morphism.thm phi) sel_split_asms,
   138    case_eq_ifs = map (Morphism.thm phi) case_eq_ifs};
   139 
   140 val transfer_ctr_sugar =
   141   morph_ctr_sugar o Morphism.transfer_morphism o Proof_Context.theory_of;
   142 
   143 structure Data = Generic_Data
   144 (
   145   type T = ctr_sugar Symtab.table;
   146   val empty = Symtab.empty;
   147   val extend = I;
   148   fun merge data : T = Symtab.merge (K true) data;
   149 );
   150 
   151 fun ctr_sugar_of ctxt =
   152   Symtab.lookup (Data.get (Context.Proof ctxt))
   153   #> Option.map (transfer_ctr_sugar ctxt);
   154 
   155 fun ctr_sugars_of ctxt =
   156   Symtab.fold (cons o transfer_ctr_sugar ctxt o snd) (Data.get (Context.Proof ctxt)) [];
   157 
   158 fun ctr_sugar_of_case ctxt s =
   159   find_first (fn {casex = Const (s', _), ...} => s' = s | _ => false) (ctr_sugars_of ctxt);
   160 
   161 structure Ctr_Sugar_Interpretation = Interpretation
   162 (
   163   type T = ctr_sugar;
   164   val eq: T * T -> bool = op = o pairself #ctrs;
   165 );
   166 
   167 fun with_repaired_path f (ctr_sugar as {ctrs = ctr1 :: _, ...} : ctr_sugar) thy =
   168   thy
   169   |> Sign.root_path
   170   |> Sign.add_path (Long_Name.qualifier (fst (dest_Type (body_type (fastype_of ctr1)))))
   171   |> (fn thy => f (morph_ctr_sugar (Morphism.transfer_morphism thy) ctr_sugar) thy)
   172   |> Sign.restore_naming thy;
   173 
   174 fun ctr_sugar_interpretation f = Ctr_Sugar_Interpretation.interpretation (with_repaired_path f);
   175 
   176 fun register_ctr_sugar key ctr_sugar =
   177   Local_Theory.declaration {syntax = false, pervasive = true}
   178     (fn phi => Data.map (Symtab.update (key, morph_ctr_sugar phi ctr_sugar)))
   179   #> Local_Theory.background_theory (Ctr_Sugar_Interpretation.data ctr_sugar);
   180 
   181 fun default_register_ctr_sugar_global key ctr_sugar thy =
   182   let val tab = Data.get (Context.Theory thy) in
   183     if Symtab.defined tab key then
   184       thy
   185     else
   186       thy
   187       |> Context.theory_map (Data.put (Symtab.update_new (key, ctr_sugar) tab))
   188       |> Ctr_Sugar_Interpretation.data ctr_sugar
   189   end;
   190 
   191 val isN = "is_";
   192 val unN = "un_";
   193 fun mk_unN 1 1 suf = unN ^ suf
   194   | mk_unN _ l suf = unN ^ suf ^ string_of_int l;
   195 
   196 val caseN = "case";
   197 val case_congN = "case_cong";
   198 val case_eq_ifN = "case_eq_if";
   199 val collapseN = "collapse";
   200 val disc_excludeN = "disc_exclude";
   201 val disc_exhaustN = "disc_exhaust";
   202 val discN = "disc";
   203 val discIN = "discI";
   204 val distinctN = "distinct";
   205 val exhaustN = "exhaust";
   206 val expandN = "expand";
   207 val injectN = "inject";
   208 val nchotomyN = "nchotomy";
   209 val selN = "sel";
   210 val sel_exhaustN = "sel_exhaust";
   211 val sel_splitN = "sel_split";
   212 val sel_split_asmN = "sel_split_asm";
   213 val splitN = "split";
   214 val splitsN = "splits";
   215 val split_asmN = "split_asm";
   216 val weak_case_cong_thmsN = "weak_case_cong";
   217 
   218 val cong_attrs = @{attributes [cong]};
   219 val dest_attrs = @{attributes [dest]};
   220 val safe_elim_attrs = @{attributes [elim!]};
   221 val iff_attrs = @{attributes [iff]};
   222 val inductsimp_attrs = @{attributes [induct_simp]};
   223 val nitpicksimp_attrs = @{attributes [nitpick_simp]};
   224 val simp_attrs = @{attributes [simp]};
   225 val code_nitpicksimp_attrs = Code.add_default_eqn_attrib :: nitpicksimp_attrs;
   226 val code_nitpicksimp_simp_attrs = code_nitpicksimp_attrs @ simp_attrs;
   227 
   228 fun unflat_lookup eq xs ys = map (fn xs' => permute_like_unique eq xs xs' ys);
   229 
   230 fun mk_half_pairss' _ ([], []) = []
   231   | mk_half_pairss' indent (x :: xs, _ :: ys) =
   232     indent @ fold_rev (cons o single o pair x) ys (mk_half_pairss' ([] :: indent) (xs, ys));
   233 
   234 fun mk_half_pairss p = mk_half_pairss' [[]] p;
   235 
   236 fun join_halves n half_xss other_half_xss =
   237   (splice (flat half_xss) (flat other_half_xss),
   238    map2 (map2 append) (Library.chop_groups n half_xss)
   239      (transpose (Library.chop_groups n other_half_xss)));
   240 
   241 fun mk_undefined T = Const (@{const_name undefined}, T);
   242 
   243 fun mk_ctr Ts t =
   244   let val Type (_, Ts0) = body_type (fastype_of t) in
   245     subst_nonatomic_types (Ts0 ~~ Ts) t
   246   end;
   247 
   248 fun mk_case Ts T t =
   249   let val (Type (_, Ts0), body) = strip_type (fastype_of t) |>> List.last in
   250     subst_nonatomic_types ((body, T) :: (Ts0 ~~ Ts)) t
   251   end;
   252 
   253 fun mk_disc_or_sel Ts t =
   254   subst_nonatomic_types (snd (Term.dest_Type (domain_type (fastype_of t))) ~~ Ts) t;
   255 
   256 fun name_of_const what t =
   257   (case head_of t of
   258     Const (s, _) => s
   259   | Free (s, _) => s
   260   | _ => error ("Cannot extract name of " ^ what));
   261 
   262 val name_of_ctr = name_of_const "constructor";
   263 
   264 val notN = "not_";
   265 val eqN = "eq_";
   266 val neqN = "neq_";
   267 
   268 fun name_of_disc t =
   269   (case head_of t of
   270     Abs (_, _, @{const Not} $ (t' $ Bound 0)) =>
   271     Long_Name.map_base_name (prefix notN) (name_of_disc t')
   272   | Abs (_, _, Const (@{const_name HOL.eq}, _) $ Bound 0 $ t') =>
   273     Long_Name.map_base_name (prefix eqN) (name_of_disc t')
   274   | Abs (_, _, @{const Not} $ (Const (@{const_name HOL.eq}, _) $ Bound 0 $ t')) =>
   275     Long_Name.map_base_name (prefix neqN) (name_of_disc t')
   276   | t' => name_of_const "destructor" t');
   277 
   278 val base_name_of_ctr = Long_Name.base_name o name_of_ctr;
   279 
   280 fun dest_ctr ctxt s t =
   281   let val (f, args) = Term.strip_comb t in
   282     (case ctr_sugar_of ctxt s of
   283       SOME {ctrs, ...} =>
   284       (case find_first (can (fo_match ctxt f)) ctrs of
   285         SOME f' => (f', args)
   286       | NONE => raise Fail "dest_ctr")
   287     | NONE => raise Fail "dest_ctr")
   288   end;
   289 
   290 fun dest_case ctxt s Ts t =
   291   (case Term.strip_comb t of
   292     (Const (c, _), args as _ :: _) =>
   293     (case ctr_sugar_of ctxt s of
   294       SOME (ctr_sugar as {casex = Const (case_name, _), discs = discs0, selss = selss0, ...}) =>
   295       if case_name = c then
   296         let val n = length discs0 in
   297           if n < length args then
   298             let
   299               val (branches, obj :: leftovers) = chop n args;
   300               val discs = map (mk_disc_or_sel Ts) discs0;
   301               val selss = map (map (mk_disc_or_sel Ts)) selss0;
   302               val conds = map (rapp obj) discs;
   303               val branch_argss = map (fn sels => map (rapp obj) sels @ leftovers) selss;
   304               val branches' = map2 (curry Term.betapplys) branches branch_argss;
   305             in
   306               SOME (ctr_sugar, conds, branches')
   307             end
   308           else
   309             NONE
   310         end
   311       else
   312         NONE
   313     | _ => NONE)
   314   | _ => NONE);
   315 
   316 fun const_or_free_name (Const (s, _)) = Long_Name.base_name s
   317   | const_or_free_name (Free (s, _)) = s
   318   | const_or_free_name t = raise TERM ("const_or_free_name", [t])
   319 
   320 fun extract_sel_default ctxt t =
   321   let
   322     fun malformed () =
   323       error ("Malformed selector default value equation: " ^ Syntax.string_of_term ctxt t);
   324 
   325     val ((sel, (ctr, vars)), rhs) =
   326       fst (Term.replace_dummy_patterns (Syntax.check_term ctxt t) 0)
   327       |> HOLogic.dest_eq
   328       |>> (Term.dest_comb
   329         #>> const_or_free_name
   330         ##> (Term.strip_comb #>> (Term.dest_Const #> fst)))
   331       handle TERM _ => malformed ();
   332   in
   333     if forall (is_Free orf is_Var) vars andalso not (has_duplicates (op aconv) vars) then
   334       ((ctr, sel), fold_rev Term.lambda vars rhs)
   335     else
   336       malformed ()
   337   end;
   338 
   339 type ('c, 'a) ctr_spec = (binding * 'c) * 'a list;
   340 
   341 fun disc_of_ctr_spec ((disc, _), _) = disc;
   342 fun ctr_of_ctr_spec ((_, ctr), _) = ctr;
   343 fun args_of_ctr_spec (_, args) = args;
   344 
   345 fun prepare_free_constructors prep_term
   346     ((((discs_sels, no_code), raw_case_binding), ctr_specs), sel_default_eqs) no_defs_lthy =
   347   let
   348     (* TODO: sanity checks on arguments *)
   349 
   350     val raw_ctrs = map ctr_of_ctr_spec ctr_specs;
   351     val raw_disc_bindings = map disc_of_ctr_spec ctr_specs;
   352     val raw_sel_bindingss = map args_of_ctr_spec ctr_specs;
   353 
   354     val n = length raw_ctrs;
   355     val ks = 1 upto n;
   356 
   357     val _ = if n > 0 then () else error "No constructors specified";
   358 
   359     val ctrs0 = map (prep_term no_defs_lthy) raw_ctrs;
   360 
   361     val Type (fcT_name, As0) = body_type (fastype_of (hd ctrs0));
   362     val fc_b_name = Long_Name.base_name fcT_name;
   363     val fc_b = Binding.name fc_b_name;
   364 
   365     fun qualify mandatory = Binding.qualify mandatory fc_b_name;
   366 
   367     fun dest_TFree_or_TVar (TFree sS) = sS
   368       | dest_TFree_or_TVar (TVar ((s, _), S)) = (s, S)
   369       | dest_TFree_or_TVar _ = error "Invalid type argument";
   370 
   371     val (unsorted_As, B) =
   372       no_defs_lthy
   373       |> variant_tfrees (map (fst o dest_TFree_or_TVar) As0)
   374       ||> the_single o fst o mk_TFrees 1;
   375 
   376     val As = map2 (resort_tfree o snd o dest_TFree_or_TVar) As0 unsorted_As;
   377 
   378     val fcT = Type (fcT_name, As);
   379     val ctrs = map (mk_ctr As) ctrs0;
   380     val ctr_Tss = map (binder_types o fastype_of) ctrs;
   381 
   382     val ms = map length ctr_Tss;
   383 
   384     fun can_definitely_rely_on_disc k =
   385       not (Binding.is_empty (nth raw_disc_bindings (k - 1))) orelse nth ms (k - 1) = 0;
   386     fun can_rely_on_disc k =
   387       can_definitely_rely_on_disc k orelse (k = 1 andalso not (can_definitely_rely_on_disc 2));
   388     fun should_omit_disc_binding k = n = 1 orelse (n = 2 andalso can_rely_on_disc (3 - k));
   389 
   390     val equal_binding = @{binding "="};
   391 
   392     fun is_disc_binding_valid b =
   393       not (Binding.is_empty b orelse Binding.eq_name (b, equal_binding));
   394 
   395     val standard_disc_binding = Binding.name o prefix isN o base_name_of_ctr;
   396 
   397     val disc_bindings =
   398       raw_disc_bindings
   399       |> map4 (fn k => fn m => fn ctr => fn disc =>
   400         qualify false
   401           (if Binding.is_empty disc then
   402              if m = 0 then equal_binding
   403              else if should_omit_disc_binding k then disc
   404              else standard_disc_binding ctr
   405            else if Binding.eq_name (disc, standard_binding) then
   406              standard_disc_binding ctr
   407            else
   408              disc)) ks ms ctrs0;
   409 
   410     fun standard_sel_binding m l = Binding.name o mk_unN m l o base_name_of_ctr;
   411 
   412     val sel_bindingss =
   413       map3 (fn ctr => fn m => map2 (fn l => fn sel =>
   414         qualify false
   415           (if Binding.is_empty sel orelse Binding.eq_name (sel, standard_binding) then
   416             standard_sel_binding m l ctr
   417           else
   418             sel)) (1 upto m) o pad_list Binding.empty m) ctrs0 ms raw_sel_bindingss;
   419 
   420     val case_Ts = map (fn Ts => Ts ---> B) ctr_Tss;
   421 
   422     val (((((((([exh_y], (xss, xss')), yss), fs), gs), [u', v']), [w]), (p, p')), names_lthy) =
   423       no_defs_lthy
   424       |> mk_Frees "y" [fcT] (* for compatibility with "datatype_realizer.ML" *)
   425       ||>> mk_Freess' "x" ctr_Tss
   426       ||>> mk_Freess "y" ctr_Tss
   427       ||>> mk_Frees "f" case_Ts
   428       ||>> mk_Frees "g" case_Ts
   429       ||>> (apfst (map (rpair fcT)) oo Variable.variant_fixes) [fc_b_name, fc_b_name ^ "'"]
   430       ||>> mk_Frees "z" [B]
   431       ||>> yield_singleton (apfst (op ~~) oo mk_Frees' "P") HOLogic.boolT;
   432 
   433     val u = Free u';
   434     val v = Free v';
   435     val q = Free (fst p', mk_pred1T B);
   436 
   437     val xctrs = map2 (curry Term.list_comb) ctrs xss;
   438     val yctrs = map2 (curry Term.list_comb) ctrs yss;
   439 
   440     val xfs = map2 (curry Term.list_comb) fs xss;
   441     val xgs = map2 (curry Term.list_comb) gs xss;
   442 
   443     (* TODO: Eta-expension is for compatibility with the old datatype package (but it also provides
   444        nicer names). Consider removing. *)
   445     val eta_fs = map2 (fold_rev Term.lambda) xss xfs;
   446     val eta_gs = map2 (fold_rev Term.lambda) xss xgs;
   447 
   448     val case_binding =
   449       qualify false
   450         (if Binding.is_empty raw_case_binding orelse
   451             Binding.eq_name (raw_case_binding, standard_binding) then
   452            Binding.prefix_name (caseN ^ "_") fc_b
   453          else
   454            raw_case_binding);
   455 
   456     fun mk_case_disj xctr xf xs =
   457       list_exists_free xs (HOLogic.mk_conj (HOLogic.mk_eq (u, xctr), HOLogic.mk_eq (w, xf)));
   458 
   459     val case_rhs = fold_rev (fold_rev Term.lambda) [fs, [u]]
   460       (Const (@{const_name The}, (B --> HOLogic.boolT) --> B) $
   461          Term.lambda w (Library.foldr1 HOLogic.mk_disj (map3 mk_case_disj xctrs xfs xss)));
   462 
   463     val ((raw_case, (_, raw_case_def)), (lthy', lthy)) = no_defs_lthy
   464       |> Local_Theory.define ((case_binding, NoSyn),
   465         ((Binding.conceal (Thm.def_binding case_binding), []), case_rhs))
   466       ||> `Local_Theory.restore;
   467 
   468     val phi = Proof_Context.export_morphism lthy lthy';
   469 
   470     val case_def = Morphism.thm phi raw_case_def;
   471 
   472     val case0 = Morphism.term phi raw_case;
   473     val casex = mk_case As B case0;
   474 
   475     val fcase = Term.list_comb (casex, fs);
   476 
   477     val ufcase = fcase $ u;
   478     val vfcase = fcase $ v;
   479 
   480     val eta_fcase = Term.list_comb (casex, eta_fs);
   481     val eta_gcase = Term.list_comb (casex, eta_gs);
   482 
   483     val eta_ufcase = eta_fcase $ u;
   484     val eta_vgcase = eta_gcase $ v;
   485 
   486     fun mk_uu_eq () = HOLogic.mk_eq (u, u);
   487 
   488     val uv_eq = mk_Trueprop_eq (u, v);
   489 
   490     val exist_xs_u_eq_ctrs =
   491       map2 (fn xctr => fn xs => list_exists_free xs (HOLogic.mk_eq (u, xctr))) xctrs xss;
   492 
   493     val unique_disc_no_def = TrueI; (*arbitrary marker*)
   494     val alternate_disc_no_def = FalseE; (*arbitrary marker*)
   495 
   496     fun alternate_disc_lhs get_udisc k =
   497       HOLogic.mk_not
   498         (let val b = nth disc_bindings (k - 1) in
   499            if is_disc_binding_valid b then get_udisc b (k - 1) else nth exist_xs_u_eq_ctrs (k - 1)
   500          end);
   501 
   502     val no_discs_sels =
   503       not discs_sels andalso
   504       forall (forall Binding.is_empty) (raw_disc_bindings :: raw_sel_bindingss) andalso
   505       null sel_default_eqs;
   506 
   507     val (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy') =
   508       if no_discs_sels then
   509         (true, [], [], [], [], [], lthy')
   510       else
   511         let
   512           val sel_bindings = flat sel_bindingss;
   513           val uniq_sel_bindings = distinct Binding.eq_name sel_bindings;
   514           val all_sels_distinct = (length uniq_sel_bindings = length sel_bindings);
   515 
   516           val sel_binding_index =
   517             if all_sels_distinct then 1 upto length sel_bindings
   518             else map (fn b => find_index (curry Binding.eq_name b) uniq_sel_bindings) sel_bindings;
   519 
   520           val all_proto_sels = flat (map3 (fn k => fn xs => map (fn x => (k, (xs, x)))) ks xss xss);
   521           val sel_infos =
   522             AList.group (op =) (sel_binding_index ~~ all_proto_sels)
   523             |> sort (int_ord o pairself fst)
   524             |> map snd |> curry (op ~~) uniq_sel_bindings;
   525           val sel_bindings = map fst sel_infos;
   526           val sel_Ts = map (curry (op -->) fcT o fastype_of o snd o snd o hd o snd) sel_infos;
   527 
   528           val sel_default_lthy = no_defs_lthy
   529             |> Proof_Context.allow_dummies
   530             |> Proof_Context.add_fixes
   531               (map2 (fn b => fn T => (b, SOME T, NoSyn)) sel_bindings sel_Ts)
   532             |> snd;
   533 
   534           val sel_defaults =
   535             map (extract_sel_default sel_default_lthy o prep_term sel_default_lthy) sel_default_eqs;
   536 
   537           fun disc_free b = Free (Binding.name_of b, mk_pred1T fcT);
   538 
   539           fun disc_spec b exist_xs_u_eq_ctr = mk_Trueprop_eq (disc_free b $ u, exist_xs_u_eq_ctr);
   540 
   541           fun alternate_disc k =
   542             Term.lambda u (alternate_disc_lhs (K o rapp u o disc_free) (3 - k));
   543 
   544           fun mk_sel_case_args b proto_sels T =
   545             map3 (fn Const (c, _) => fn Ts => fn k =>
   546               (case AList.lookup (op =) proto_sels k of
   547                 NONE =>
   548                 (case filter (curry (op =) (c, Binding.name_of b) o fst) sel_defaults of
   549                   [] => fold_rev (Term.lambda o curry Free Name.uu) Ts (mk_undefined T)
   550                 | [(_, t)] => t
   551                 | _ => error "Multiple default values for selector/constructor pair")
   552               | SOME (xs, x) => fold_rev Term.lambda xs x)) ctrs ctr_Tss ks;
   553 
   554           fun sel_spec b proto_sels =
   555             let
   556               val _ =
   557                 (case duplicates (op =) (map fst proto_sels) of
   558                    k :: _ => error ("Duplicate selector name " ^ quote (Binding.name_of b) ^
   559                      " for constructor " ^ quote (Syntax.string_of_term lthy (nth ctrs (k - 1))))
   560                  | [] => ())
   561               val T =
   562                 (case distinct (op =) (map (fastype_of o snd o snd) proto_sels) of
   563                   [T] => T
   564                 | T :: T' :: _ => error ("Inconsistent range type for selector " ^
   565                     quote (Binding.name_of b) ^ ": " ^ quote (Syntax.string_of_typ lthy T) ^
   566                     " vs. " ^ quote (Syntax.string_of_typ lthy T')));
   567             in
   568               mk_Trueprop_eq (Free (Binding.name_of b, fcT --> T) $ u,
   569                 Term.list_comb (mk_case As T case0, mk_sel_case_args b proto_sels T) $ u)
   570             end;
   571 
   572           fun unflat_selss xs = unflat_lookup Binding.eq_name sel_bindings xs sel_bindingss;
   573 
   574           val (((raw_discs, raw_disc_defs), (raw_sels, raw_sel_defs)), (lthy', lthy)) =
   575             lthy
   576             |> apfst split_list o fold_map3 (fn k => fn exist_xs_u_eq_ctr => fn b =>
   577                 if Binding.is_empty b then
   578                   if n = 1 then pair (Term.lambda u (mk_uu_eq ()), unique_disc_no_def)
   579                   else pair (alternate_disc k, alternate_disc_no_def)
   580                 else if Binding.eq_name (b, equal_binding) then
   581                   pair (Term.lambda u exist_xs_u_eq_ctr, refl)
   582                 else
   583                   Specification.definition (SOME (b, NONE, NoSyn),
   584                     ((Thm.def_binding b, []), disc_spec b exist_xs_u_eq_ctr)) #>> apsnd snd)
   585               ks exist_xs_u_eq_ctrs disc_bindings
   586             ||>> apfst split_list o fold_map (fn (b, proto_sels) =>
   587               Specification.definition (SOME (b, NONE, NoSyn),
   588                 ((Thm.def_binding b, []), sel_spec b proto_sels)) #>> apsnd snd) sel_infos
   589             ||> `Local_Theory.restore;
   590 
   591           val phi = Proof_Context.export_morphism lthy lthy';
   592 
   593           val disc_defs = map (Morphism.thm phi) raw_disc_defs;
   594           val sel_defs = map (Morphism.thm phi) raw_sel_defs;
   595           val sel_defss = unflat_selss sel_defs;
   596 
   597           val discs0 = map (Morphism.term phi) raw_discs;
   598           val selss0 = unflat_selss (map (Morphism.term phi) raw_sels);
   599 
   600           val discs = map (mk_disc_or_sel As) discs0;
   601           val selss = map (map (mk_disc_or_sel As)) selss0;
   602         in
   603           (all_sels_distinct, discs, selss, disc_defs, sel_defs, sel_defss, lthy')
   604         end;
   605 
   606     fun mk_imp_p Qs = Logic.list_implies (Qs, HOLogic.mk_Trueprop p);
   607 
   608     val exhaust_goal =
   609       let fun mk_prem xctr xs = fold_rev Logic.all xs (mk_imp_p [mk_Trueprop_eq (exh_y, xctr)]) in
   610         fold_rev Logic.all [p, exh_y] (mk_imp_p (map2 mk_prem xctrs xss))
   611       end;
   612 
   613     val inject_goalss =
   614       let
   615         fun mk_goal _ _ [] [] = []
   616           | mk_goal xctr yctr xs ys =
   617             [fold_rev Logic.all (xs @ ys) (mk_Trueprop_eq (HOLogic.mk_eq (xctr, yctr),
   618               Library.foldr1 HOLogic.mk_conj (map2 (curry HOLogic.mk_eq) xs ys)))];
   619       in
   620         map4 mk_goal xctrs yctrs xss yss
   621       end;
   622 
   623     val half_distinct_goalss =
   624       let
   625         fun mk_goal ((xs, xc), (xs', xc')) =
   626           fold_rev Logic.all (xs @ xs')
   627             (HOLogic.mk_Trueprop (HOLogic.mk_not (HOLogic.mk_eq (xc, xc'))));
   628       in
   629         map (map mk_goal) (mk_half_pairss (`I (xss ~~ xctrs)))
   630       end;
   631 
   632     val goalss = [exhaust_goal] :: inject_goalss @ half_distinct_goalss;
   633 
   634     fun after_qed thmss lthy =
   635       let
   636         val ([exhaust_thm0], (inject_thmss, half_distinct_thmss)) = (hd thmss, chop n (tl thmss));
   637         (* for "datatype_realizer.ML": *)
   638         val exhaust_thm =
   639           Thm.name_derivation (fcT_name ^ Long_Name.separator ^ exhaustN) exhaust_thm0;
   640 
   641         val inject_thms = flat inject_thmss;
   642 
   643         val rho_As = map (pairself (certifyT lthy)) (map Logic.varifyT_global As ~~ As);
   644 
   645         fun inst_thm t thm =
   646           Drule.instantiate' [] [SOME (certify lthy t)]
   647             (Thm.instantiate (rho_As, []) (Drule.zero_var_indexes thm));
   648 
   649         val uexhaust_thm = inst_thm u exhaust_thm;
   650 
   651         val exhaust_cases = map base_name_of_ctr ctrs;
   652 
   653         val other_half_distinct_thmss = map (map (fn thm => thm RS not_sym)) half_distinct_thmss;
   654 
   655         val (distinct_thms, (distinct_thmsss', distinct_thmsss)) =
   656           join_halves n half_distinct_thmss other_half_distinct_thmss ||> `transpose;
   657 
   658         val nchotomy_thm =
   659           let
   660             val goal =
   661               HOLogic.mk_Trueprop (HOLogic.mk_all (fst u', snd u',
   662                 Library.foldr1 HOLogic.mk_disj exist_xs_u_eq_ctrs));
   663           in
   664             Goal.prove_sorry lthy [] [] goal (fn _ => mk_nchotomy_tac n exhaust_thm)
   665             |> Thm.close_derivation
   666           end;
   667 
   668         val case_thms =
   669           let
   670             val goals =
   671               map3 (fn xctr => fn xf => fn xs =>
   672                 fold_rev Logic.all (fs @ xs) (mk_Trueprop_eq (fcase $ xctr, xf))) xctrs xfs xss;
   673           in
   674             map4 (fn k => fn goal => fn injects => fn distinctss =>
   675                 Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   676                   mk_case_tac ctxt n k case_def injects distinctss)
   677                 |> Thm.close_derivation)
   678               ks goals inject_thmss distinct_thmsss
   679           end;
   680 
   681         val (case_cong_thm, weak_case_cong_thm) =
   682           let
   683             fun mk_prem xctr xs xf xg =
   684               fold_rev Logic.all xs (Logic.mk_implies (mk_Trueprop_eq (v, xctr),
   685                 mk_Trueprop_eq (xf, xg)));
   686 
   687             val goal =
   688               Logic.list_implies (uv_eq :: map4 mk_prem xctrs xss xfs xgs,
   689                  mk_Trueprop_eq (eta_ufcase, eta_vgcase));
   690             val weak_goal = Logic.mk_implies (uv_eq, mk_Trueprop_eq (ufcase, vfcase));
   691           in
   692             (Goal.prove_sorry lthy [] [] goal (fn _ => mk_case_cong_tac lthy uexhaust_thm case_thms),
   693              Goal.prove_sorry lthy [] [] weak_goal (K (etac arg_cong 1)))
   694             |> pairself (singleton (Proof_Context.export names_lthy lthy) #>
   695               Thm.close_derivation)
   696           end;
   697 
   698         val split_lhs = q $ ufcase;
   699 
   700         fun mk_split_conjunct xctr xs f_xs =
   701           list_all_free xs (HOLogic.mk_imp (HOLogic.mk_eq (u, xctr), q $ f_xs));
   702         fun mk_split_disjunct xctr xs f_xs =
   703           list_exists_free xs (HOLogic.mk_conj (HOLogic.mk_eq (u, xctr),
   704             HOLogic.mk_not (q $ f_xs)));
   705 
   706         fun mk_split_goal xctrs xss xfs =
   707           mk_Trueprop_eq (split_lhs, Library.foldr1 HOLogic.mk_conj
   708             (map3 mk_split_conjunct xctrs xss xfs));
   709         fun mk_split_asm_goal xctrs xss xfs =
   710           mk_Trueprop_eq (split_lhs, HOLogic.mk_not (Library.foldr1 HOLogic.mk_disj
   711             (map3 mk_split_disjunct xctrs xss xfs)));
   712 
   713         fun prove_split selss goal =
   714           Goal.prove_sorry lthy [] [] goal (fn _ =>
   715             mk_split_tac lthy uexhaust_thm case_thms selss inject_thmss distinct_thmsss)
   716           |> singleton (Proof_Context.export names_lthy lthy)
   717           |> Thm.close_derivation;
   718 
   719         fun prove_split_asm asm_goal split_thm =
   720           Goal.prove_sorry lthy [] [] asm_goal (fn {context = ctxt, ...} =>
   721             mk_split_asm_tac ctxt split_thm)
   722           |> singleton (Proof_Context.export names_lthy lthy)
   723           |> Thm.close_derivation;
   724 
   725         val (split_thm, split_asm_thm) =
   726           let
   727             val goal = mk_split_goal xctrs xss xfs;
   728             val asm_goal = mk_split_asm_goal xctrs xss xfs;
   729 
   730             val thm = prove_split (replicate n []) goal;
   731             val asm_thm = prove_split_asm asm_goal thm;
   732           in
   733             (thm, asm_thm)
   734           end;
   735 
   736         val (sel_defs, all_sel_thms, sel_thmss, disc_defs, disc_thmss, nontriv_disc_thmss,
   737              discI_thms, nontriv_discI_thms, disc_exclude_thms, disc_exclude_thmsss,
   738              disc_exhaust_thms, sel_exhaust_thms, all_collapse_thms, safe_collapse_thms,
   739              expand_thms, sel_split_thms, sel_split_asm_thms, case_eq_if_thms) =
   740           if no_discs_sels then
   741             ([], [], [], [], [], [], [], [], [], [], [], [], [], [], [], [], [], [])
   742           else
   743             let
   744               val udiscs = map (rapp u) discs;
   745               val uselss = map (map (rapp u)) selss;
   746               val usel_ctrs = map2 (curry Term.list_comb) ctrs uselss;
   747               val usel_fs = map2 (curry Term.list_comb) fs uselss;
   748 
   749               val vdiscs = map (rapp v) discs;
   750               val vselss = map (map (rapp v)) selss;
   751 
   752               fun make_sel_thm xs' case_thm sel_def =
   753                 zero_var_indexes (Drule.gen_all (Drule.rename_bvars' (map (SOME o fst) xs')
   754                     (Drule.forall_intr_vars (case_thm RS (sel_def RS trans)))));
   755 
   756               val sel_thmss = map3 (map oo make_sel_thm) xss' case_thms sel_defss;
   757 
   758               fun has_undefined_rhs thm =
   759                 (case snd (HOLogic.dest_eq (HOLogic.dest_Trueprop (prop_of thm))) of
   760                   Const (@{const_name undefined}, _) => true
   761                 | _ => false);
   762 
   763               val all_sel_thms =
   764                 (if all_sels_distinct andalso null sel_default_eqs then
   765                    flat sel_thmss
   766                  else
   767                    map_product (fn s => fn (xs', c) => make_sel_thm xs' c s) sel_defs
   768                      (xss' ~~ case_thms))
   769                 |> filter_out has_undefined_rhs;
   770 
   771               fun mk_unique_disc_def () =
   772                 let
   773                   val m = the_single ms;
   774                   val goal = mk_Trueprop_eq (mk_uu_eq (), the_single exist_xs_u_eq_ctrs);
   775                 in
   776                   Goal.prove_sorry lthy [] [] goal (fn _ => mk_unique_disc_def_tac m uexhaust_thm)
   777                   |> singleton (Proof_Context.export names_lthy lthy)
   778                   |> Thm.close_derivation
   779                 end;
   780 
   781               fun mk_alternate_disc_def k =
   782                 let
   783                   val goal =
   784                     mk_Trueprop_eq (alternate_disc_lhs (K (nth udiscs)) (3 - k),
   785                       nth exist_xs_u_eq_ctrs (k - 1));
   786                 in
   787                   Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   788                     mk_alternate_disc_def_tac ctxt k (nth disc_defs (2 - k))
   789                       (nth distinct_thms (2 - k)) uexhaust_thm)
   790                   |> singleton (Proof_Context.export names_lthy lthy)
   791                   |> Thm.close_derivation
   792                 end;
   793 
   794               val has_alternate_disc_def =
   795                 exists (fn def => Thm.eq_thm_prop (def, alternate_disc_no_def)) disc_defs;
   796 
   797               val disc_defs' =
   798                 map2 (fn k => fn def =>
   799                   if Thm.eq_thm_prop (def, unique_disc_no_def) then mk_unique_disc_def ()
   800                   else if Thm.eq_thm_prop (def, alternate_disc_no_def) then mk_alternate_disc_def k
   801                   else def) ks disc_defs;
   802 
   803               val discD_thms = map (fn def => def RS iffD1) disc_defs';
   804               val discI_thms =
   805                 map2 (fn m => fn def => funpow m (fn thm => exI RS thm) (def RS iffD2)) ms
   806                   disc_defs';
   807               val not_discI_thms =
   808                 map2 (fn m => fn def => funpow m (fn thm => allI RS thm)
   809                     (unfold_thms lthy @{thms not_ex} (def RS @{thm ssubst[of _ _ Not]})))
   810                   ms disc_defs';
   811 
   812               val (disc_thmss', disc_thmss) =
   813                 let
   814                   fun mk_thm discI _ [] = refl RS discI
   815                     | mk_thm _ not_discI [distinct] = distinct RS not_discI;
   816                   fun mk_thms discI not_discI distinctss = map (mk_thm discI not_discI) distinctss;
   817                 in
   818                   map3 mk_thms discI_thms not_discI_thms distinct_thmsss' |> `transpose
   819                 end;
   820 
   821               val nontriv_disc_thmss =
   822                 map2 (fn b => if is_disc_binding_valid b then I else K []) disc_bindings disc_thmss;
   823 
   824               fun is_discI_boring b =
   825                 (n = 1 andalso Binding.is_empty b) orelse Binding.eq_name (b, equal_binding);
   826 
   827               val nontriv_discI_thms =
   828                 flat (map2 (fn b => if is_discI_boring b then K [] else single) disc_bindings
   829                   discI_thms);
   830 
   831               val (disc_exclude_thms, (disc_exclude_thmsss', disc_exclude_thmsss)) =
   832                 let
   833                   fun mk_goal [] = []
   834                     | mk_goal [((_, udisc), (_, udisc'))] =
   835                       [Logic.all u (Logic.mk_implies (HOLogic.mk_Trueprop udisc,
   836                          HOLogic.mk_Trueprop (HOLogic.mk_not udisc')))];
   837 
   838                   fun prove tac goal =
   839                     Goal.prove_sorry lthy [] [] goal (K tac)
   840                     |> Thm.close_derivation;
   841 
   842                   val half_pairss = mk_half_pairss (`I (ms ~~ discD_thms ~~ udiscs));
   843 
   844                   val half_goalss = map mk_goal half_pairss;
   845                   val half_thmss =
   846                     map3 (fn [] => K (K []) | [goal] => fn [(((m, discD), _), _)] =>
   847                         fn disc_thm => [prove (mk_half_disc_exclude_tac lthy m discD disc_thm) goal])
   848                       half_goalss half_pairss (flat disc_thmss');
   849 
   850                   val other_half_goalss = map (mk_goal o map swap) half_pairss;
   851                   val other_half_thmss =
   852                     map2 (map2 (prove o mk_other_half_disc_exclude_tac)) half_thmss
   853                       other_half_goalss;
   854                 in
   855                   join_halves n half_thmss other_half_thmss ||> `transpose
   856                   |>> has_alternate_disc_def ? K []
   857                 end;
   858 
   859               val disc_exhaust_thm =
   860                 let
   861                   fun mk_prem udisc = mk_imp_p [HOLogic.mk_Trueprop udisc];
   862                   val goal = fold_rev Logic.all [p, u] (mk_imp_p (map mk_prem udiscs));
   863                 in
   864                   Goal.prove_sorry lthy [] [] goal (fn _ =>
   865                     mk_disc_exhaust_tac n exhaust_thm discI_thms)
   866                   |> Thm.close_derivation
   867                 end;
   868 
   869               val (safe_collapse_thms, all_collapse_thms) =
   870                 let
   871                   fun mk_goal m udisc usel_ctr =
   872                     let
   873                       val prem = HOLogic.mk_Trueprop udisc;
   874                       val concl = mk_Trueprop_eq ((usel_ctr, u) |> m = 0 ? swap);
   875                     in
   876                       (prem aconv concl, Logic.all u (Logic.mk_implies (prem, concl)))
   877                     end;
   878                   val (trivs, goals) = map3 mk_goal ms udiscs usel_ctrs |> split_list;
   879                   val thms =
   880                     map5 (fn m => fn discD => fn sel_thms => fn triv => fn goal =>
   881                         Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   882                           mk_collapse_tac ctxt m discD sel_thms ORELSE HEADGOAL atac)
   883                         |> Thm.close_derivation
   884                         |> not triv ? perhaps (try (fn thm => refl RS thm)))
   885                       ms discD_thms sel_thmss trivs goals;
   886                 in
   887                   (map_filter (fn (true, _) => NONE | (false, thm) => SOME thm) (trivs ~~ thms),
   888                    thms)
   889                 end;
   890 
   891               val swapped_all_collapse_thms =
   892                 map2 (fn m => fn thm => if m = 0 then thm else thm RS sym) ms all_collapse_thms;
   893 
   894               val sel_exhaust_thm =
   895                 let
   896                   fun mk_prem usel_ctr = mk_imp_p [mk_Trueprop_eq (u, usel_ctr)];
   897                   val goal = fold_rev Logic.all [p, u] (mk_imp_p (map mk_prem usel_ctrs));
   898                 in
   899                   Goal.prove_sorry lthy [] [] goal (fn _ =>
   900                     mk_sel_exhaust_tac n disc_exhaust_thm swapped_all_collapse_thms)
   901                   |> Thm.close_derivation
   902                 end;
   903 
   904               val expand_thm =
   905                 let
   906                   fun mk_prems k udisc usels vdisc vsels =
   907                     (if k = n then [] else [mk_Trueprop_eq (udisc, vdisc)]) @
   908                     (if null usels then
   909                        []
   910                      else
   911                        [Logic.list_implies
   912                           (if n = 1 then [] else map HOLogic.mk_Trueprop [udisc, vdisc],
   913                              HOLogic.mk_Trueprop (Library.foldr1 HOLogic.mk_conj
   914                                (map2 (curry HOLogic.mk_eq) usels vsels)))]);
   915 
   916                   val goal =
   917                     Library.foldr Logic.list_implies
   918                       (map5 mk_prems ks udiscs uselss vdiscs vselss, uv_eq);
   919                   val uncollapse_thms =
   920                     map2 (fn thm => fn [] => thm | _ => thm RS sym) all_collapse_thms uselss;
   921                 in
   922                   Goal.prove_sorry lthy [] [] goal (fn _ =>
   923                     mk_expand_tac lthy n ms (inst_thm u disc_exhaust_thm)
   924                       (inst_thm v disc_exhaust_thm) uncollapse_thms disc_exclude_thmsss
   925                       disc_exclude_thmsss')
   926                   |> singleton (Proof_Context.export names_lthy lthy)
   927                   |> Thm.close_derivation
   928                 end;
   929 
   930               val (sel_split_thm, sel_split_asm_thm) =
   931                 let
   932                   val zss = map (K []) xss;
   933                   val goal = mk_split_goal usel_ctrs zss usel_fs;
   934                   val asm_goal = mk_split_asm_goal usel_ctrs zss usel_fs;
   935 
   936                   val thm = prove_split sel_thmss goal;
   937                   val asm_thm = prove_split_asm asm_goal thm;
   938                 in
   939                   (thm, asm_thm)
   940                 end;
   941 
   942               val case_eq_if_thm =
   943                 let
   944                   val goal = mk_Trueprop_eq (ufcase, mk_IfN B udiscs usel_fs);
   945                 in
   946                   Goal.prove_sorry lthy [] [] goal (fn {context = ctxt, ...} =>
   947                     mk_case_eq_if_tac ctxt n uexhaust_thm case_thms disc_thmss' sel_thmss)
   948                   |> singleton (Proof_Context.export names_lthy lthy)
   949                   |> Thm.close_derivation
   950                 end;
   951             in
   952               (sel_defs, all_sel_thms, sel_thmss, disc_defs, disc_thmss, nontriv_disc_thmss,
   953                discI_thms, nontriv_discI_thms, disc_exclude_thms, disc_exclude_thmsss,
   954                [disc_exhaust_thm], [sel_exhaust_thm], all_collapse_thms, safe_collapse_thms,
   955                [expand_thm], [sel_split_thm], [sel_split_asm_thm], [case_eq_if_thm])
   956             end;
   957 
   958         val exhaust_case_names_attr = Attrib.internal (K (Rule_Cases.case_names exhaust_cases));
   959         val cases_type_attr = Attrib.internal (K (Induct.cases_type fcT_name));
   960 
   961         val nontriv_disc_eq_thmss =
   962           map (map (fn th => th RS @{thm eq_False[THEN iffD2]}
   963             handle THM _ => th RS @{thm eq_True[THEN iffD2]})) nontriv_disc_thmss;
   964 
   965         val anonymous_notes =
   966           [(map (fn th => th RS notE) distinct_thms, safe_elim_attrs),
   967            (flat nontriv_disc_eq_thmss, code_nitpicksimp_attrs)]
   968           |> map (fn (thms, attrs) => ((Binding.empty, attrs), [(thms, [])]));
   969 
   970         (* "exhaust" is deliberately put first to avoid apparent circular dependencies in the proof
   971            objects, which would confuse MaSh. *)
   972         val notes =
   973           [(exhaustN, [exhaust_thm], [exhaust_case_names_attr, cases_type_attr]),
   974            (caseN, case_thms, code_nitpicksimp_simp_attrs),
   975            (case_congN, [case_cong_thm], []),
   976            (case_eq_ifN, case_eq_if_thms, []),
   977            (collapseN, safe_collapse_thms, simp_attrs),
   978            (discN, flat nontriv_disc_thmss, simp_attrs),
   979            (discIN, nontriv_discI_thms, []),
   980            (disc_excludeN, disc_exclude_thms, dest_attrs),
   981            (disc_exhaustN, disc_exhaust_thms, [exhaust_case_names_attr]),
   982            (distinctN, distinct_thms, simp_attrs @ inductsimp_attrs),
   983            (expandN, expand_thms, []),
   984            (injectN, inject_thms, iff_attrs @ inductsimp_attrs),
   985            (nchotomyN, [nchotomy_thm], []),
   986            (selN, all_sel_thms, code_nitpicksimp_simp_attrs),
   987            (sel_exhaustN, sel_exhaust_thms, [exhaust_case_names_attr]),
   988            (sel_splitN, sel_split_thms, []),
   989            (sel_split_asmN, sel_split_asm_thms, []),
   990            (splitN, [split_thm], []),
   991            (split_asmN, [split_asm_thm], []),
   992            (splitsN, [split_thm, split_asm_thm], []),
   993            (weak_case_cong_thmsN, [weak_case_cong_thm], cong_attrs)]
   994           |> filter_out (null o #2)
   995           |> map (fn (thmN, thms, attrs) =>
   996             ((qualify true (Binding.name thmN), attrs), [(thms, [])]));
   997 
   998         val ctr_sugar =
   999           {ctrs = ctrs, casex = casex, discs = discs, selss = selss, exhaust = exhaust_thm,
  1000            nchotomy = nchotomy_thm, injects = inject_thms, distincts = distinct_thms,
  1001            case_thms = case_thms, case_cong = case_cong_thm, weak_case_cong = weak_case_cong_thm,
  1002            split = split_thm, split_asm = split_asm_thm, disc_defs = disc_defs,
  1003            disc_thmss = disc_thmss, discIs = discI_thms, sel_defs = sel_defs, sel_thmss = sel_thmss,
  1004            disc_excludesss = disc_exclude_thmsss, disc_exhausts = disc_exhaust_thms,
  1005            sel_exhausts = sel_exhaust_thms, collapses = all_collapse_thms, expands = expand_thms,
  1006            sel_splits = sel_split_thms, sel_split_asms = sel_split_asm_thms,
  1007            case_eq_ifs = case_eq_if_thms};
  1008       in
  1009         (ctr_sugar,
  1010          lthy
  1011          |> Spec_Rules.add Spec_Rules.Equational ([casex], case_thms)
  1012          |> fold (Spec_Rules.add Spec_Rules.Equational)
  1013            (AList.group (eq_list (op aconv)) (map (`(single o lhs_head_of)) all_sel_thms))
  1014          |> fold (Spec_Rules.add Spec_Rules.Equational)
  1015            (filter_out (null o snd) (map single discs ~~ nontriv_disc_eq_thmss))
  1016          |> Local_Theory.declaration {syntax = false, pervasive = true}
  1017               (fn phi => Case_Translation.register
  1018                  (Morphism.term phi casex) (map (Morphism.term phi) ctrs))
  1019          |> Local_Theory.background_theory (fold (fold Code.del_eqn) [disc_defs, sel_defs])
  1020          |> not no_code ?
  1021             Local_Theory.declaration {syntax = false, pervasive = false}
  1022               (fn phi => Context.mapping
  1023                 (add_ctr_code fcT_name (map (Morphism.typ phi) As)
  1024                   (map (dest_Const o Morphism.term phi) ctrs) (Morphism.fact phi inject_thms)
  1025                   (Morphism.fact phi distinct_thms) (Morphism.fact phi case_thms))
  1026                 I)
  1027          |> Local_Theory.notes (anonymous_notes @ notes) |> snd
  1028          |> register_ctr_sugar fcT_name ctr_sugar)
  1029       end;
  1030   in
  1031     (goalss, after_qed, lthy')
  1032   end;
  1033 
  1034 fun free_constructors tacss = (fn (goalss, after_qed, lthy) =>
  1035   map2 (map2 (Thm.close_derivation oo Goal.prove_sorry lthy [] [])) goalss tacss
  1036   |> (fn thms => after_qed thms lthy)) oo prepare_free_constructors (K I);
  1037 
  1038 val free_constructors_cmd = (fn (goalss, after_qed, lthy) =>
  1039   Proof.theorem NONE (snd oo after_qed) (map (map (rpair [])) goalss) lthy) oo
  1040   prepare_free_constructors Syntax.read_term;
  1041 
  1042 val parse_bound_term = Parse.binding --| @{keyword ":"} -- Parse.term;
  1043 
  1044 val parse_ctr_options =
  1045   Scan.optional (@{keyword "("} |-- Parse.list1
  1046         (Parse.reserved "discs_sels" >> K 0 || Parse.reserved "no_code" >> K 1) --|
  1047       @{keyword ")"}
  1048       >> (fn js => (member (op =) js 0, member (op =) js 1)))
  1049     (false, false);
  1050 
  1051 fun parse_ctr_spec parse_ctr parse_arg =
  1052   parse_opt_binding_colon -- parse_ctr -- Scan.repeat parse_arg;
  1053 
  1054 val parse_ctr_specs = Parse.enum1 "|" (parse_ctr_spec Parse.term Parse.binding);
  1055 val parse_sel_default_eqs = Scan.optional (@{keyword "where"} |-- Parse.enum1 "|" Parse.prop) [];
  1056 
  1057 val _ =
  1058   Outer_Syntax.local_theory_to_proof @{command_spec "free_constructors"}
  1059     "register an existing freely generated type's constructors"
  1060     (parse_ctr_options -- Parse.binding --| @{keyword "for"} -- parse_ctr_specs
  1061        -- parse_sel_default_eqs
  1062      >> free_constructors_cmd);
  1063 
  1064 val _ = Context.>> (Context.map_theory Ctr_Sugar_Interpretation.init);
  1065 
  1066 end;