src/Pure/Syntax/mixfix.ML
author wenzelm
Wed Mar 30 14:59:12 2016 +0200 (2016-03-30)
changeset 62760 aabcc727aa2d
parent 62759 d16b2ec535ba
child 62761 5c672b22dcc2
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/Syntax/mixfix.ML
     2     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     3 
     4 Mixfix declarations, infixes, binders.
     5 *)
     6 
     7 signature BASIC_MIXFIX =
     8 sig
     9   datatype mixfix =
    10     NoSyn |
    11     Mixfix of Input.source * int list * int * Position.range |
    12     Delimfix of Input.source * Position.range |
    13     Infix of Input.source * int * Position.range |
    14     Infixl of Input.source * int * Position.range |
    15     Infixr of Input.source * int * Position.range |
    16     Binder of Input.source * int * int * Position.range |
    17     Structure of Position.range
    18 end;
    19 
    20 signature MIXFIX =
    21 sig
    22   include BASIC_MIXFIX
    23   val is_empty: mixfix -> bool
    24   val equal: mixfix * mixfix -> bool
    25   val range_of: mixfix -> Position.range
    26   val pos_of: mixfix -> Position.T
    27   val reset_pos: mixfix -> mixfix
    28   val pretty_mixfix: mixfix -> Pretty.T
    29   val mixfix_args: mixfix -> int
    30   val mixfixT: mixfix -> typ
    31   val make_type: int -> typ
    32   val binder_name: string -> string
    33   val syn_ext_types: (string * typ * mixfix) list -> Syntax_Ext.syn_ext
    34   val syn_ext_consts: string list -> (string * typ * mixfix) list -> Syntax_Ext.syn_ext
    35 end;
    36 
    37 structure Mixfix: MIXFIX =
    38 struct
    39 
    40 (** mixfix declarations **)
    41 
    42 datatype mixfix =
    43   NoSyn |
    44   Mixfix of Input.source * int list * int * Position.range |
    45   Delimfix of Input.source * Position.range |
    46   Infix of Input.source * int * Position.range |
    47   Infixl of Input.source * int * Position.range |
    48   Infixr of Input.source * int * Position.range |
    49   Binder of Input.source * int * int * Position.range |
    50   Structure of Position.range;
    51 
    52 fun is_empty NoSyn = true
    53   | is_empty _ = false;
    54 
    55 fun equal (NoSyn, NoSyn) = true
    56   | equal (Mixfix (sy, ps, p, _), Mixfix (sy', ps', p', _)) =
    57       Input.equal_content (sy, sy') andalso ps = ps' andalso p = p'
    58   | equal (Delimfix (sy, _), Delimfix (sy', _)) = Input.equal_content (sy, sy')
    59   | equal (Infix (sy, p, _), Infix (sy', p', _)) = Input.equal_content (sy, sy') andalso p = p'
    60   | equal (Infixl (sy, p, _), Infixl (sy', p', _)) = Input.equal_content (sy, sy') andalso p = p'
    61   | equal (Infixr (sy, p, _), Infixr (sy', p', _)) = Input.equal_content (sy, sy') andalso p = p'
    62   | equal (Binder (sy, p, q, _), Binder (sy', p', q', _)) =
    63       Input.equal_content (sy, sy') andalso p = p' andalso q = q'
    64   | equal (Structure _, Structure _) = true
    65   | equal _ = false;
    66 
    67 fun range_of NoSyn = Position.no_range
    68   | range_of (Mixfix (_, _, _, range)) = range
    69   | range_of (Delimfix (_, range)) = range
    70   | range_of (Infix (_, _, range)) = range
    71   | range_of (Infixl (_, _, range)) = range
    72   | range_of (Infixr (_, _, range)) = range
    73   | range_of (Binder (_, _, _, range)) = range
    74   | range_of (Structure range) = range;
    75 
    76 val pos_of = Position.set_range o range_of;
    77 
    78 fun reset_pos NoSyn = NoSyn
    79   | reset_pos (Mixfix (sy, ps, p, _)) = Mixfix (Input.reset_pos sy, ps, p, Position.no_range)
    80   | reset_pos (Delimfix (sy, _)) = Delimfix (Input.reset_pos sy, Position.no_range)
    81   | reset_pos (Infix (sy, p, _)) = Infix (Input.reset_pos sy, p, Position.no_range)
    82   | reset_pos (Infixl (sy, p, _)) = Infixl (Input.reset_pos sy, p, Position.no_range)
    83   | reset_pos (Infixr (sy, p, _)) = Infixr (Input.reset_pos sy, p, Position.no_range)
    84   | reset_pos (Binder (sy, p, q, _)) = Binder (Input.reset_pos sy, p, q, Position.no_range)
    85   | reset_pos (Structure _) = Structure Position.no_range;
    86 
    87 
    88 (* pretty_mixfix *)
    89 
    90 local
    91 
    92 val quoted = Pretty.quote o Pretty.str o Input.source_content;
    93 val keyword = Pretty.keyword2;
    94 val parens = Pretty.enclose "(" ")";
    95 val brackets = Pretty.enclose "[" "]";
    96 val int = Pretty.str o string_of_int;
    97 
    98 in
    99 
   100 fun pretty_mixfix NoSyn = Pretty.str ""
   101   | pretty_mixfix (Mixfix (s, ps, p, _)) =
   102       parens (Pretty.breaks [quoted s, brackets (Pretty.commas (map int ps)), int p])
   103   | pretty_mixfix (Delimfix (s, _)) = parens [quoted s]
   104   | pretty_mixfix (Infix (s, p, _)) = parens (Pretty.breaks [keyword "infix", quoted s, int p])
   105   | pretty_mixfix (Infixl (s, p, _)) = parens (Pretty.breaks [keyword "infixl", quoted s, int p])
   106   | pretty_mixfix (Infixr (s, p, _)) = parens (Pretty.breaks [keyword "infixl", quoted s, int p])
   107   | pretty_mixfix (Binder (s, p1, p2, _)) =
   108       parens (Pretty.breaks [keyword "binder", quoted s, brackets [int p1], int p2])
   109   | pretty_mixfix (Structure _) = parens [keyword "structure"];
   110 
   111 end;
   112 
   113 
   114 (* syntax specifications *)
   115 
   116 fun mixfix_args NoSyn = 0
   117   | mixfix_args (Mixfix (sy, _, _, _)) = Syntax_Ext.mixfix_args sy
   118   | mixfix_args (Delimfix (sy, _)) = Syntax_Ext.mixfix_args sy
   119   | mixfix_args (Infix (sy, _, _)) = 2 + Syntax_Ext.mixfix_args sy
   120   | mixfix_args (Infixl (sy, _, _)) = 2 + Syntax_Ext.mixfix_args sy
   121   | mixfix_args (Infixr (sy, _, _)) = 2 + Syntax_Ext.mixfix_args sy
   122   | mixfix_args (Binder _) = 1
   123   | mixfix_args (Structure _) = 0;
   124 
   125 fun mixfixT (Binder _) = (dummyT --> dummyT) --> dummyT
   126   | mixfixT mx = replicate (mixfix_args mx) dummyT ---> dummyT;
   127 
   128 
   129 (* syn_ext_types *)
   130 
   131 val typeT = Type ("type", []);
   132 fun make_type n = replicate n typeT ---> typeT;
   133 
   134 fun syn_ext_types type_decls =
   135   let
   136     fun mk_infix sy ty t p1 p2 p3 range =
   137       Syntax_Ext.Mfix
   138         (Symbol_Pos.explode0 "(_ " @ Input.source_explode sy @ Symbol_Pos.explode0 "/ _)",
   139           ty, t, [p1, p2], p3, Position.set_range range);
   140 
   141     fun mfix_of (_, _, NoSyn) = NONE
   142       | mfix_of (t, ty, Mixfix (sy, ps, p, range)) =
   143           SOME (Syntax_Ext.Mfix (Input.source_explode sy, ty, t, ps, p, Position.set_range range))
   144       | mfix_of (t, ty, Delimfix (sy, range)) =
   145           SOME (Syntax_Ext.Mfix (Input.source_explode sy, ty, t, [], 1000, Position.set_range range))
   146       | mfix_of (t, ty, Infix (sy, p, range)) = SOME (mk_infix sy ty t (p + 1) (p + 1) p range)
   147       | mfix_of (t, ty, Infixl (sy, p, range)) = SOME (mk_infix sy ty t p (p + 1) p range)
   148       | mfix_of (t, ty, Infixr (sy, p, range)) = SOME (mk_infix sy ty t (p + 1) p p range)
   149       | mfix_of (t, _, _) = error ("Bad mixfix declaration for " ^ quote t);
   150 
   151     fun check_args (_, ty, mx) (SOME (Syntax_Ext.Mfix (sy, _, _, _, _, _))) =
   152           if length (Term.binder_types ty) = Syntax_Ext.mfix_args sy then ()
   153           else
   154             error ("Bad number of type constructor arguments in mixfix annotation" ^
   155               Position.here (pos_of mx))
   156       | check_args _ NONE = ();
   157 
   158     val mfix = map mfix_of type_decls;
   159     val _ = map2 check_args type_decls mfix;
   160     val consts = map (fn (t, _, _) => (t, "")) type_decls;
   161   in Syntax_Ext.syn_ext (map_filter I mfix) consts ([], [], [], []) ([], []) end;
   162 
   163 
   164 (* syn_ext_consts *)
   165 
   166 val binder_stamp = stamp ();
   167 val binder_name = suffix "_binder";
   168 
   169 fun syn_ext_consts logical_types const_decls =
   170   let
   171     fun mk_infix sy ty c p1 p2 p3 range =
   172       [Syntax_Ext.Mfix
   173         (Symbol_Pos.explode0 "op " @ Input.source_explode sy,
   174           ty, c, [], 1000, Position.set_range range),
   175        Syntax_Ext.Mfix
   176         (Symbol_Pos.explode0 "(_ " @ Input.source_explode sy @ Symbol_Pos.explode0 "/ _)",
   177           ty, c, [p1, p2], p3, Position.set_range range)];
   178 
   179     fun binder_typ _ (Type ("fun", [Type ("fun", [_, ty2]), ty3])) =
   180           [Type ("idts", []), ty2] ---> ty3
   181       | binder_typ c _ = error ("Bad type of binder: " ^ quote c);
   182 
   183     fun mfix_of (_, _, NoSyn) = []
   184       | mfix_of (c, ty, Mixfix (sy, ps, p, range)) =
   185           [Syntax_Ext.Mfix (Input.source_explode sy, ty, c, ps, p, Position.set_range range)]
   186       | mfix_of (c, ty, Delimfix (sy, range)) =
   187           [Syntax_Ext.Mfix (Input.source_explode sy, ty, c, [], 1000, Position.set_range range)]
   188       | mfix_of (c, ty, Infix (sy, p, range)) = mk_infix sy ty c (p + 1) (p + 1) p range
   189       | mfix_of (c, ty, Infixl (sy, p, range)) = mk_infix sy ty c p (p + 1) p range
   190       | mfix_of (c, ty, Infixr (sy, p, range)) = mk_infix sy ty c (p + 1) p p range
   191       | mfix_of (c, ty, Binder (sy, p, q, range)) =
   192           [Syntax_Ext.Mfix
   193             (Symbol_Pos.explode0 "(3" @ Input.source_explode sy @ Symbol_Pos.explode0 "_./ _)",
   194               binder_typ c ty, (binder_name c), [0, p], q, Position.set_range range)]
   195       | mfix_of (c, _, mx) =
   196           error ("Bad mixfix declaration for " ^ quote c ^ Position.here (pos_of mx));
   197 
   198     fun binder (c, _, Binder _) = SOME (binder_name c, c)
   199       | binder _ = NONE;
   200 
   201     val mfix = maps mfix_of const_decls;
   202     val binders = map_filter binder const_decls;
   203     val binder_trs = binders
   204       |> map (Syntax_Ext.stamp_trfun binder_stamp o Syntax_Trans.mk_binder_tr);
   205     val binder_trs' = binders
   206       |> map (Syntax_Ext.stamp_trfun binder_stamp o
   207           apsnd Syntax_Trans.non_typed_tr' o Syntax_Trans.mk_binder_tr' o swap);
   208 
   209     val consts = binders @ map (fn (c, _, _) => (c, "")) const_decls;
   210   in
   211     Syntax_Ext.syn_ext' logical_types mfix consts ([], binder_trs, binder_trs', []) ([], [])
   212   end;
   213 
   214 end;
   215 
   216 structure Basic_Mixfix: BASIC_MIXFIX = Mixfix;
   217 open Basic_Mixfix;