src/HOL/Complete_Lattice.thy
author hoelzl
Tue Aug 24 14:41:37 2010 +0200 (2010-08-24)
changeset 38705 aaee86c0e237
parent 37767 a2b7a20d6ea3
child 39302 d7728f65b353
permissions -rw-r--r--
moved generic lemmas in Probability to HOL
     1 (*  Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel; Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Complete lattices, with special focus on sets *}
     4 
     5 theory Complete_Lattice
     6 imports Set
     7 begin
     8 
     9 notation
    10   less_eq (infix "\<sqsubseteq>" 50) and
    11   less (infix "\<sqsubset>" 50) and
    12   inf (infixl "\<sqinter>" 70) and
    13   sup (infixl "\<squnion>" 65) and
    14   top ("\<top>") and
    15   bot ("\<bottom>")
    16 
    17 
    18 subsection {* Syntactic infimum and supremum operations *}
    19 
    20 class Inf =
    21   fixes Inf :: "'a set \<Rightarrow> 'a" ("\<Sqinter>_" [900] 900)
    22 
    23 class Sup =
    24   fixes Sup :: "'a set \<Rightarrow> 'a" ("\<Squnion>_" [900] 900)
    25 
    26 subsection {* Abstract complete lattices *}
    27 
    28 class complete_lattice = bounded_lattice + Inf + Sup +
    29   assumes Inf_lower: "x \<in> A \<Longrightarrow> \<Sqinter>A \<sqsubseteq> x"
    30      and Inf_greatest: "(\<And>x. x \<in> A \<Longrightarrow> z \<sqsubseteq> x) \<Longrightarrow> z \<sqsubseteq> \<Sqinter>A"
    31   assumes Sup_upper: "x \<in> A \<Longrightarrow> x \<sqsubseteq> \<Squnion>A"
    32      and Sup_least: "(\<And>x. x \<in> A \<Longrightarrow> x \<sqsubseteq> z) \<Longrightarrow> \<Squnion>A \<sqsubseteq> z"
    33 begin
    34 
    35 lemma dual_complete_lattice:
    36   "class.complete_lattice Sup Inf (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) \<top> \<bottom>"
    37   by (auto intro!: class.complete_lattice.intro dual_bounded_lattice)
    38     (unfold_locales, (fact bot_least top_greatest
    39         Sup_upper Sup_least Inf_lower Inf_greatest)+)
    40 
    41 lemma Inf_Sup: "\<Sqinter>A = \<Squnion>{b. \<forall>a \<in> A. b \<sqsubseteq> a}"
    42   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    43 
    44 lemma Sup_Inf:  "\<Squnion>A = \<Sqinter>{b. \<forall>a \<in> A. a \<sqsubseteq> b}"
    45   by (auto intro: antisym Inf_lower Inf_greatest Sup_upper Sup_least)
    46 
    47 lemma Inf_empty:
    48   "\<Sqinter>{} = \<top>"
    49   by (auto intro: antisym Inf_greatest)
    50 
    51 lemma Sup_empty:
    52   "\<Squnion>{} = \<bottom>"
    53   by (auto intro: antisym Sup_least)
    54 
    55 lemma Inf_insert: "\<Sqinter>insert a A = a \<sqinter> \<Sqinter>A"
    56   by (auto intro: le_infI le_infI1 le_infI2 antisym Inf_greatest Inf_lower)
    57 
    58 lemma Sup_insert: "\<Squnion>insert a A = a \<squnion> \<Squnion>A"
    59   by (auto intro: le_supI le_supI1 le_supI2 antisym Sup_least Sup_upper)
    60 
    61 lemma Inf_singleton [simp]:
    62   "\<Sqinter>{a} = a"
    63   by (auto intro: antisym Inf_lower Inf_greatest)
    64 
    65 lemma Sup_singleton [simp]:
    66   "\<Squnion>{a} = a"
    67   by (auto intro: antisym Sup_upper Sup_least)
    68 
    69 lemma Inf_binary:
    70   "\<Sqinter>{a, b} = a \<sqinter> b"
    71   by (simp add: Inf_empty Inf_insert)
    72 
    73 lemma Sup_binary:
    74   "\<Squnion>{a, b} = a \<squnion> b"
    75   by (simp add: Sup_empty Sup_insert)
    76 
    77 lemma Inf_UNIV:
    78   "\<Sqinter>UNIV = bot"
    79   by (simp add: Sup_Inf Sup_empty [symmetric])
    80 
    81 lemma Sup_UNIV:
    82   "\<Squnion>UNIV = top"
    83   by (simp add: Inf_Sup Inf_empty [symmetric])
    84 
    85 lemma Sup_le_iff: "Sup A \<sqsubseteq> b \<longleftrightarrow> (\<forall>a\<in>A. a \<sqsubseteq> b)"
    86   by (auto intro: Sup_least dest: Sup_upper)
    87 
    88 lemma le_Inf_iff: "b \<sqsubseteq> Inf A \<longleftrightarrow> (\<forall>a\<in>A. b \<sqsubseteq> a)"
    89   by (auto intro: Inf_greatest dest: Inf_lower)
    90 
    91 lemma Sup_mono:
    92   assumes "\<And>a. a \<in> A \<Longrightarrow> \<exists>b\<in>B. a \<le> b"
    93   shows "Sup A \<le> Sup B"
    94 proof (rule Sup_least)
    95   fix a assume "a \<in> A"
    96   with assms obtain b where "b \<in> B" and "a \<le> b" by blast
    97   from `b \<in> B` have "b \<le> Sup B" by (rule Sup_upper)
    98   with `a \<le> b` show "a \<le> Sup B" by auto
    99 qed
   100 
   101 lemma Inf_mono:
   102   assumes "\<And>b. b \<in> B \<Longrightarrow> \<exists>a\<in>A. a \<le> b"
   103   shows "Inf A \<le> Inf B"
   104 proof (rule Inf_greatest)
   105   fix b assume "b \<in> B"
   106   with assms obtain a where "a \<in> A" and "a \<le> b" by blast
   107   from `a \<in> A` have "Inf A \<le> a" by (rule Inf_lower)
   108   with `a \<le> b` show "Inf A \<le> b" by auto
   109 qed
   110 
   111 definition SUPR :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   112   "SUPR A f = \<Squnion> (f ` A)"
   113 
   114 definition INFI :: "'b set \<Rightarrow> ('b \<Rightarrow> 'a) \<Rightarrow> 'a" where
   115   "INFI A f = \<Sqinter> (f ` A)"
   116 
   117 end
   118 
   119 syntax
   120   "_SUP1"     :: "pttrns => 'b => 'b"           ("(3SUP _./ _)" [0, 10] 10)
   121   "_SUP"      :: "pttrn => 'a set => 'b => 'b"  ("(3SUP _:_./ _)" [0, 0, 10] 10)
   122   "_INF1"     :: "pttrns => 'b => 'b"           ("(3INF _./ _)" [0, 10] 10)
   123   "_INF"      :: "pttrn => 'a set => 'b => 'b"  ("(3INF _:_./ _)" [0, 0, 10] 10)
   124 
   125 translations
   126   "SUP x y. B"   == "SUP x. SUP y. B"
   127   "SUP x. B"     == "CONST SUPR CONST UNIV (%x. B)"
   128   "SUP x. B"     == "SUP x:CONST UNIV. B"
   129   "SUP x:A. B"   == "CONST SUPR A (%x. B)"
   130   "INF x y. B"   == "INF x. INF y. B"
   131   "INF x. B"     == "CONST INFI CONST UNIV (%x. B)"
   132   "INF x. B"     == "INF x:CONST UNIV. B"
   133   "INF x:A. B"   == "CONST INFI A (%x. B)"
   134 
   135 print_translation {*
   136   [Syntax.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"},
   137     Syntax.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"}]
   138 *} -- {* to avoid eta-contraction of body *}
   139 
   140 context complete_lattice
   141 begin
   142 
   143 lemma le_SUPI: "i : A \<Longrightarrow> M i \<sqsubseteq> (SUP i:A. M i)"
   144   by (auto simp add: SUPR_def intro: Sup_upper)
   145 
   146 lemma SUP_leI: "(\<And>i. i : A \<Longrightarrow> M i \<sqsubseteq> u) \<Longrightarrow> (SUP i:A. M i) \<sqsubseteq> u"
   147   by (auto simp add: SUPR_def intro: Sup_least)
   148 
   149 lemma INF_leI: "i : A \<Longrightarrow> (INF i:A. M i) \<sqsubseteq> M i"
   150   by (auto simp add: INFI_def intro: Inf_lower)
   151 
   152 lemma le_INFI: "(\<And>i. i : A \<Longrightarrow> u \<sqsubseteq> M i) \<Longrightarrow> u \<sqsubseteq> (INF i:A. M i)"
   153   by (auto simp add: INFI_def intro: Inf_greatest)
   154 
   155 lemma SUP_le_iff: "(SUP i:A. M i) \<sqsubseteq> u \<longleftrightarrow> (\<forall>i \<in> A. M i \<sqsubseteq> u)"
   156   unfolding SUPR_def by (auto simp add: Sup_le_iff)
   157 
   158 lemma le_INF_iff: "u \<sqsubseteq> (INF i:A. M i) \<longleftrightarrow> (\<forall>i \<in> A. u \<sqsubseteq> M i)"
   159   unfolding INFI_def by (auto simp add: le_Inf_iff)
   160 
   161 lemma SUP_const[simp]: "A \<noteq> {} \<Longrightarrow> (SUP i:A. M) = M"
   162   by (auto intro: antisym SUP_leI le_SUPI)
   163 
   164 lemma INF_const[simp]: "A \<noteq> {} \<Longrightarrow> (INF i:A. M) = M"
   165   by (auto intro: antisym INF_leI le_INFI)
   166 
   167 lemma SUP_mono:
   168   "(\<And>n. n \<in> A \<Longrightarrow> \<exists>m\<in>B. f n \<le> g m) \<Longrightarrow> (SUP n:A. f n) \<le> (SUP n:B. g n)"
   169   by (force intro!: Sup_mono simp: SUPR_def)
   170 
   171 lemma INF_mono:
   172   "(\<And>m. m \<in> B \<Longrightarrow> \<exists>n\<in>A. f n \<le> g m) \<Longrightarrow> (INF n:A. f n) \<le> (INF n:B. g n)"
   173   by (force intro!: Inf_mono simp: INFI_def)
   174 
   175 end
   176 
   177 lemma less_Sup_iff:
   178   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   179   shows "a < Sup S \<longleftrightarrow> (\<exists>x\<in>S. a < x)"
   180   unfolding not_le[symmetric] Sup_le_iff by auto
   181 
   182 lemma Inf_less_iff:
   183   fixes a :: "'a\<Colon>{complete_lattice,linorder}"
   184   shows "Inf S < a \<longleftrightarrow> (\<exists>x\<in>S. x < a)"
   185   unfolding not_le[symmetric] le_Inf_iff by auto
   186 
   187 subsection {* @{typ bool} and @{typ "_ \<Rightarrow> _"} as complete lattice *}
   188 
   189 instantiation bool :: complete_lattice
   190 begin
   191 
   192 definition
   193   Inf_bool_def: "\<Sqinter>A \<longleftrightarrow> (\<forall>x\<in>A. x)"
   194 
   195 definition
   196   Sup_bool_def: "\<Squnion>A \<longleftrightarrow> (\<exists>x\<in>A. x)"
   197 
   198 instance proof
   199 qed (auto simp add: Inf_bool_def Sup_bool_def le_bool_def)
   200 
   201 end
   202 
   203 lemma Inf_empty_bool [simp]:
   204   "\<Sqinter>{}"
   205   unfolding Inf_bool_def by auto
   206 
   207 lemma not_Sup_empty_bool [simp]:
   208   "\<not> \<Squnion>{}"
   209   unfolding Sup_bool_def by auto
   210 
   211 lemma INFI_bool_eq:
   212   "INFI = Ball"
   213 proof (rule ext)+
   214   fix A :: "'a set"
   215   fix P :: "'a \<Rightarrow> bool"
   216   show "(INF x:A. P x) \<longleftrightarrow> (\<forall>x \<in> A. P x)"
   217     by (auto simp add: Ball_def INFI_def Inf_bool_def)
   218 qed
   219 
   220 lemma SUPR_bool_eq:
   221   "SUPR = Bex"
   222 proof (rule ext)+
   223   fix A :: "'a set"
   224   fix P :: "'a \<Rightarrow> bool"
   225   show "(SUP x:A. P x) \<longleftrightarrow> (\<exists>x \<in> A. P x)"
   226     by (auto simp add: Bex_def SUPR_def Sup_bool_def)
   227 qed
   228 
   229 instantiation "fun" :: (type, complete_lattice) complete_lattice
   230 begin
   231 
   232 definition
   233   Inf_fun_def: "\<Sqinter>A = (\<lambda>x. \<Sqinter>{y. \<exists>f\<in>A. y = f x})"
   234 
   235 definition
   236   Sup_fun_def: "\<Squnion>A = (\<lambda>x. \<Squnion>{y. \<exists>f\<in>A. y = f x})"
   237 
   238 instance proof
   239 qed (auto simp add: Inf_fun_def Sup_fun_def le_fun_def
   240   intro: Inf_lower Sup_upper Inf_greatest Sup_least)
   241 
   242 end
   243 
   244 lemma SUPR_fun_expand:
   245   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c\<Colon>{complete_lattice}"
   246   shows "(SUP y:A. f y) = (\<lambda>x. SUP y:A. f y x)"
   247   by (auto intro!: arg_cong[where f=Sup] ext[where 'a='b]
   248            simp: SUPR_def Sup_fun_def)
   249 
   250 lemma INFI_fun_expand:
   251   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c\<Colon>{complete_lattice}"
   252   shows "(INF y:A. f y) x = (INF y:A. f y x)"
   253   by (auto intro!: arg_cong[where f=Inf] ext[where 'a='b]
   254            simp: INFI_def Inf_fun_def)
   255 
   256 lemma Inf_empty_fun:
   257   "\<Sqinter>{} = (\<lambda>_. \<Sqinter>{})"
   258   by (simp add: Inf_fun_def)
   259 
   260 lemma Sup_empty_fun:
   261   "\<Squnion>{} = (\<lambda>_. \<Squnion>{})"
   262   by (simp add: Sup_fun_def)
   263 
   264 
   265 subsection {* Union *}
   266 
   267 abbreviation Union :: "'a set set \<Rightarrow> 'a set" where
   268   "Union S \<equiv> \<Squnion>S"
   269 
   270 notation (xsymbols)
   271   Union  ("\<Union>_" [90] 90)
   272 
   273 lemma Union_eq:
   274   "\<Union>A = {x. \<exists>B \<in> A. x \<in> B}"
   275 proof (rule set_ext)
   276   fix x
   277   have "(\<exists>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<exists>B\<in>A. x \<in> B)"
   278     by auto
   279   then show "x \<in> \<Union>A \<longleftrightarrow> x \<in> {x. \<exists>B\<in>A. x \<in> B}"
   280     by (simp add: Sup_fun_def Sup_bool_def) (simp add: mem_def)
   281 qed
   282 
   283 lemma Union_iff [simp, no_atp]:
   284   "A \<in> \<Union>C \<longleftrightarrow> (\<exists>X\<in>C. A\<in>X)"
   285   by (unfold Union_eq) blast
   286 
   287 lemma UnionI [intro]:
   288   "X \<in> C \<Longrightarrow> A \<in> X \<Longrightarrow> A \<in> \<Union>C"
   289   -- {* The order of the premises presupposes that @{term C} is rigid;
   290     @{term A} may be flexible. *}
   291   by auto
   292 
   293 lemma UnionE [elim!]:
   294   "A \<in> \<Union>C \<Longrightarrow> (\<And>X. A\<in>X \<Longrightarrow> X\<in>C \<Longrightarrow> R) \<Longrightarrow> R"
   295   by auto
   296 
   297 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   298   by (iprover intro: subsetI UnionI)
   299 
   300 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   301   by (iprover intro: subsetI elim: UnionE dest: subsetD)
   302 
   303 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
   304   by blast
   305 
   306 lemma Union_empty [simp]: "Union({}) = {}"
   307   by blast
   308 
   309 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
   310   by blast
   311 
   312 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
   313   by blast
   314 
   315 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
   316   by blast
   317 
   318 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
   319   by blast
   320 
   321 lemma Union_empty_conv [simp,no_atp]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
   322   by blast
   323 
   324 lemma empty_Union_conv [simp,no_atp]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
   325   by blast
   326 
   327 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
   328   by blast
   329 
   330 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
   331   by blast
   332 
   333 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
   334   by blast
   335 
   336 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
   337   by blast
   338 
   339 
   340 subsection {* Unions of families *}
   341 
   342 abbreviation UNION :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   343   "UNION \<equiv> SUPR"
   344 
   345 syntax
   346   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" [0, 10] 10)
   347   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" [0, 0, 10] 10)
   348 
   349 syntax (xsymbols)
   350   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" [0, 10] 10)
   351   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" [0, 0, 10] 10)
   352 
   353 syntax (latex output)
   354   "_UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   355   "_UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   356 
   357 translations
   358   "UN x y. B"   == "UN x. UN y. B"
   359   "UN x. B"     == "CONST UNION CONST UNIV (%x. B)"
   360   "UN x. B"     == "UN x:CONST UNIV. B"
   361   "UN x:A. B"   == "CONST UNION A (%x. B)"
   362 
   363 text {*
   364   Note the difference between ordinary xsymbol syntax of indexed
   365   unions and intersections (e.g.\ @{text"\<Union>a\<^isub>1\<in>A\<^isub>1. B"})
   366   and their \LaTeX\ rendition: @{term"\<Union>a\<^isub>1\<in>A\<^isub>1. B"}. The
   367   former does not make the index expression a subscript of the
   368   union/intersection symbol because this leads to problems with nested
   369   subscripts in Proof General.
   370 *}
   371 
   372 print_translation {*
   373   [Syntax.preserve_binder_abs2_tr' @{const_syntax UNION} @{syntax_const "_UNION"}]
   374 *} -- {* to avoid eta-contraction of body *}
   375 
   376 lemma UNION_eq_Union_image:
   377   "(\<Union>x\<in>A. B x) = \<Union>(B`A)"
   378   by (fact SUPR_def)
   379 
   380 lemma Union_def:
   381   "\<Union>S = (\<Union>x\<in>S. x)"
   382   by (simp add: UNION_eq_Union_image image_def)
   383 
   384 lemma UNION_def [no_atp]:
   385   "(\<Union>x\<in>A. B x) = {y. \<exists>x\<in>A. y \<in> B x}"
   386   by (auto simp add: UNION_eq_Union_image Union_eq)
   387   
   388 lemma Union_image_eq [simp]:
   389   "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
   390   by (rule sym) (fact UNION_eq_Union_image)
   391   
   392 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   393   by (unfold UNION_def) blast
   394 
   395 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   396   -- {* The order of the premises presupposes that @{term A} is rigid;
   397     @{term b} may be flexible. *}
   398   by auto
   399 
   400 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   401   by (unfold UNION_def) blast
   402 
   403 lemma UN_cong [cong]:
   404     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   405   by (simp add: UNION_def)
   406 
   407 lemma strong_UN_cong:
   408     "A = B ==> (!!x. x:B =simp=> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   409   by (simp add: UNION_def simp_implies_def)
   410 
   411 lemma image_eq_UN: "f`A = (UN x:A. {f x})"
   412   by blast
   413 
   414 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   415   by (fact le_SUPI)
   416 
   417 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   418   by (iprover intro: subsetI elim: UN_E dest: subsetD)
   419 
   420 lemma Collect_bex_eq [no_atp]: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
   421   by blast
   422 
   423 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
   424   by blast
   425 
   426 lemma UN_empty [simp,no_atp]: "(\<Union>x\<in>{}. B x) = {}"
   427   by blast
   428 
   429 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
   430   by blast
   431 
   432 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
   433   by blast
   434 
   435 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
   436   by auto
   437 
   438 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
   439   by blast
   440 
   441 lemma UN_Un[simp]: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
   442   by blast
   443 
   444 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
   445   by blast
   446 
   447 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
   448   by (fact SUP_le_iff)
   449 
   450 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
   451   by blast
   452 
   453 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
   454   by auto
   455 
   456 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
   457   by blast
   458 
   459 lemma UNION_empty_conv[simp]:
   460   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
   461   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
   462 by blast+
   463 
   464 lemma Collect_ex_eq [no_atp]: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
   465   by blast
   466 
   467 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
   468   by blast
   469 
   470 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
   471   by blast
   472 
   473 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
   474   by (auto simp add: split_if_mem2)
   475 
   476 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
   477   by (auto intro: bool_contrapos)
   478 
   479 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
   480   by blast
   481 
   482 lemma UN_mono:
   483   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   484     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
   485   by (blast dest: subsetD)
   486 
   487 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
   488   by blast
   489 
   490 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
   491   by blast
   492 
   493 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
   494   -- {* NOT suitable for rewriting *}
   495   by blast
   496 
   497 lemma image_UN: "(f ` (UNION A B)) = (UN x:A.(f ` (B x)))"
   498 by blast
   499 
   500 
   501 subsection {* Inter *}
   502 
   503 abbreviation Inter :: "'a set set \<Rightarrow> 'a set" where
   504   "Inter S \<equiv> \<Sqinter>S"
   505   
   506 notation (xsymbols)
   507   Inter  ("\<Inter>_" [90] 90)
   508 
   509 lemma Inter_eq:
   510   "\<Inter>A = {x. \<forall>B \<in> A. x \<in> B}"
   511 proof (rule set_ext)
   512   fix x
   513   have "(\<forall>Q\<in>{P. \<exists>B\<in>A. P \<longleftrightarrow> x \<in> B}. Q) \<longleftrightarrow> (\<forall>B\<in>A. x \<in> B)"
   514     by auto
   515   then show "x \<in> \<Inter>A \<longleftrightarrow> x \<in> {x. \<forall>B \<in> A. x \<in> B}"
   516     by (simp add: Inf_fun_def Inf_bool_def) (simp add: mem_def)
   517 qed
   518 
   519 lemma Inter_iff [simp,no_atp]: "(A : Inter C) = (ALL X:C. A:X)"
   520   by (unfold Inter_eq) blast
   521 
   522 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   523   by (simp add: Inter_eq)
   524 
   525 text {*
   526   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   527   contains @{term A} as an element, but @{prop "A:X"} can hold when
   528   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   529 *}
   530 
   531 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   532   by auto
   533 
   534 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   535   -- {* ``Classical'' elimination rule -- does not require proving
   536     @{prop "X:C"}. *}
   537   by (unfold Inter_eq) blast
   538 
   539 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   540   by blast
   541 
   542 lemma Inter_subset:
   543   "[| !!X. X \<in> A ==> X \<subseteq> B; A ~= {} |] ==> \<Inter>A \<subseteq> B"
   544   by blast
   545 
   546 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   547   by (iprover intro: InterI subsetI dest: subsetD)
   548 
   549 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
   550   by blast
   551 
   552 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
   553   by blast
   554 
   555 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
   556   by blast
   557 
   558 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
   559   by blast
   560 
   561 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
   562   by blast
   563 
   564 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
   565   by blast
   566 
   567 lemma Inter_UNIV_conv [simp,no_atp]:
   568   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
   569   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
   570   by blast+
   571 
   572 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
   573   by blast
   574 
   575 
   576 subsection {* Intersections of families *}
   577 
   578 abbreviation INTER :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> 'b set" where
   579   "INTER \<equiv> INFI"
   580 
   581 syntax
   582   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" [0, 10] 10)
   583   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" [0, 0, 10] 10)
   584 
   585 syntax (xsymbols)
   586   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" [0, 10] 10)
   587   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" [0, 0, 10] 10)
   588 
   589 syntax (latex output)
   590   "_INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>(00\<^bsub>_\<^esub>)/ _)" [0, 10] 10)
   591   "_INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>(00\<^bsub>_\<in>_\<^esub>)/ _)" [0, 0, 10] 10)
   592 
   593 translations
   594   "INT x y. B"  == "INT x. INT y. B"
   595   "INT x. B"    == "CONST INTER CONST UNIV (%x. B)"
   596   "INT x. B"    == "INT x:CONST UNIV. B"
   597   "INT x:A. B"  == "CONST INTER A (%x. B)"
   598 
   599 print_translation {*
   600   [Syntax.preserve_binder_abs2_tr' @{const_syntax INTER} @{syntax_const "_INTER"}]
   601 *} -- {* to avoid eta-contraction of body *}
   602 
   603 lemma INTER_eq_Inter_image:
   604   "(\<Inter>x\<in>A. B x) = \<Inter>(B`A)"
   605   by (fact INFI_def)
   606   
   607 lemma Inter_def:
   608   "\<Inter>S = (\<Inter>x\<in>S. x)"
   609   by (simp add: INTER_eq_Inter_image image_def)
   610 
   611 lemma INTER_def:
   612   "(\<Inter>x\<in>A. B x) = {y. \<forall>x\<in>A. y \<in> B x}"
   613   by (auto simp add: INTER_eq_Inter_image Inter_eq)
   614 
   615 lemma Inter_image_eq [simp]:
   616   "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
   617   by (rule sym) (fact INTER_eq_Inter_image)
   618 
   619 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   620   by (unfold INTER_def) blast
   621 
   622 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   623   by (unfold INTER_def) blast
   624 
   625 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   626   by auto
   627 
   628 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   629   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   630   by (unfold INTER_def) blast
   631 
   632 lemma INT_cong [cong]:
   633     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   634   by (simp add: INTER_def)
   635 
   636 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
   637   by blast
   638 
   639 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
   640   by blast
   641 
   642 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   643   by (fact INF_leI)
   644 
   645 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   646   by (fact le_INFI)
   647 
   648 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
   649   by blast
   650 
   651 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
   652   by blast
   653 
   654 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
   655   by (fact le_INF_iff)
   656 
   657 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
   658   by blast
   659 
   660 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
   661   by blast
   662 
   663 lemma INT_insert_distrib:
   664     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
   665   by blast
   666 
   667 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
   668   by auto
   669 
   670 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
   671   -- {* Look: it has an \emph{existential} quantifier *}
   672   by blast
   673 
   674 lemma INTER_UNIV_conv[simp]:
   675  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
   676  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
   677 by blast+
   678 
   679 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
   680   by (auto intro: bool_induct)
   681 
   682 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
   683   by blast
   684 
   685 lemma INT_anti_mono:
   686   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
   687     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
   688   -- {* The last inclusion is POSITIVE! *}
   689   by (blast dest: subsetD)
   690 
   691 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
   692   by blast
   693 
   694 
   695 subsection {* Distributive laws *}
   696 
   697 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
   698   by blast
   699 
   700 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
   701   by blast
   702 
   703 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
   704   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
   705   -- {* Union of a family of unions *}
   706   by blast
   707 
   708 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
   709   -- {* Equivalent version *}
   710   by blast
   711 
   712 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
   713   by blast
   714 
   715 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
   716   by blast
   717 
   718 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
   719   -- {* Equivalent version *}
   720   by blast
   721 
   722 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
   723   -- {* Halmos, Naive Set Theory, page 35. *}
   724   by blast
   725 
   726 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
   727   by blast
   728 
   729 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
   730   by blast
   731 
   732 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
   733   by blast
   734 
   735 
   736 subsection {* Complement *}
   737 
   738 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
   739   by blast
   740 
   741 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
   742   by blast
   743 
   744 
   745 subsection {* Miniscoping and maxiscoping *}
   746 
   747 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
   748            and Intersections. *}
   749 
   750 lemma UN_simps [simp]:
   751   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
   752   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
   753   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
   754   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
   755   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
   756   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
   757   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
   758   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
   759   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
   760   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
   761   by auto
   762 
   763 lemma INT_simps [simp]:
   764   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
   765   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
   766   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
   767   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
   768   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
   769   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
   770   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
   771   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
   772   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
   773   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
   774   by auto
   775 
   776 lemma ball_simps [simp,no_atp]:
   777   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
   778   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
   779   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
   780   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
   781   "!!P. (ALL x:{}. P x) = True"
   782   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
   783   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
   784   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
   785   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
   786   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
   787   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
   788   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
   789   by auto
   790 
   791 lemma bex_simps [simp,no_atp]:
   792   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
   793   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
   794   "!!P. (EX x:{}. P x) = False"
   795   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
   796   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
   797   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
   798   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
   799   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
   800   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
   801   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
   802   by auto
   803 
   804 lemma ball_conj_distrib:
   805   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
   806   by blast
   807 
   808 lemma bex_disj_distrib:
   809   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
   810   by blast
   811 
   812 
   813 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
   814 
   815 lemma UN_extend_simps:
   816   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
   817   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
   818   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
   819   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
   820   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
   821   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
   822   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
   823   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
   824   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
   825   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
   826   by auto
   827 
   828 lemma INT_extend_simps:
   829   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
   830   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
   831   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
   832   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
   833   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
   834   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
   835   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
   836   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
   837   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
   838   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
   839   by auto
   840 
   841 
   842 no_notation
   843   less_eq  (infix "\<sqsubseteq>" 50) and
   844   less (infix "\<sqsubset>" 50) and
   845   inf  (infixl "\<sqinter>" 70) and
   846   sup  (infixl "\<squnion>" 65) and
   847   Inf  ("\<Sqinter>_" [900] 900) and
   848   Sup  ("\<Squnion>_" [900] 900) and
   849   top ("\<top>") and
   850   bot ("\<bottom>")
   851 
   852 lemmas mem_simps =
   853   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   854   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   855   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   856 
   857 end