src/HOL/Complex.thy
author eberlm
Mon Nov 02 11:56:28 2015 +0100 (2015-11-02)
changeset 61531 ab2e862263e7
parent 61104 3c2d4636cebc
child 61552 980dd46a03fb
permissions -rw-r--r--
Rounding function, uniform limits, cotangent, binomial identities
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot
     3     Copyright:   2001 University of Edinburgh
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5 *)
     6 
     7 section \<open>Complex Numbers: Rectangular and Polar Representations\<close>
     8 
     9 theory Complex
    10 imports Transcendental
    11 begin
    12 
    13 text \<open>
    14 We use the @{text codatatype} command to define the type of complex numbers. This allows us to use
    15 @{text primcorec} to define complex functions by defining their real and imaginary result
    16 separately.
    17 \<close>
    18 
    19 codatatype complex = Complex (Re: real) (Im: real)
    20 
    21 lemma complex_surj: "Complex (Re z) (Im z) = z"
    22   by (rule complex.collapse)
    23 
    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"
    25   by (rule complex.expand) simp
    26 
    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    28   by (auto intro: complex.expand)
    29 
    30 subsection \<open>Addition and Subtraction\<close>
    31 
    32 instantiation complex :: ab_group_add
    33 begin
    34 
    35 primcorec zero_complex where
    36   "Re 0 = 0"
    37 | "Im 0 = 0"
    38 
    39 primcorec plus_complex where
    40   "Re (x + y) = Re x + Re y"
    41 | "Im (x + y) = Im x + Im y"
    42 
    43 primcorec uminus_complex where
    44   "Re (- x) = - Re x"
    45 | "Im (- x) = - Im x"
    46 
    47 primcorec minus_complex where
    48   "Re (x - y) = Re x - Re y"
    49 | "Im (x - y) = Im x - Im y"
    50 
    51 instance
    52   by intro_classes (simp_all add: complex_eq_iff)
    53 
    54 end
    55 
    56 subsection \<open>Multiplication and Division\<close>
    57 
    58 instantiation complex :: field
    59 begin
    60 
    61 primcorec one_complex where
    62   "Re 1 = 1"
    63 | "Im 1 = 0"
    64 
    65 primcorec times_complex where
    66   "Re (x * y) = Re x * Re y - Im x * Im y"
    67 | "Im (x * y) = Re x * Im y + Im x * Re y"
    68 
    69 primcorec inverse_complex where
    70   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    71 | "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    72 
    73 definition "x div (y::complex) = x * inverse y"
    74 
    75 instance
    76   by intro_classes
    77      (simp_all add: complex_eq_iff divide_complex_def
    78       distrib_left distrib_right right_diff_distrib left_diff_distrib
    79       power2_eq_square add_divide_distrib [symmetric])
    80 
    81 end
    82 
    83 lemma Re_divide: "Re (x / y) = (Re x * Re y + Im x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    84   unfolding divide_complex_def by (simp add: add_divide_distrib)
    85 
    86 lemma Im_divide: "Im (x / y) = (Im x * Re y - Re x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    87   unfolding divide_complex_def times_complex.sel inverse_complex.sel
    88   by (simp_all add: divide_simps)
    89 
    90 lemma Re_power2: "Re (x ^ 2) = (Re x)^2 - (Im x)^2"
    91   by (simp add: power2_eq_square)
    92 
    93 lemma Im_power2: "Im (x ^ 2) = 2 * Re x * Im x"
    94   by (simp add: power2_eq_square)
    95 
    96 lemma Re_power_real [simp]: "Im x = 0 \<Longrightarrow> Re (x ^ n) = Re x ^ n "
    97   by (induct n) simp_all
    98 
    99 lemma Im_power_real [simp]: "Im x = 0 \<Longrightarrow> Im (x ^ n) = 0"
   100   by (induct n) simp_all
   101 
   102 subsection \<open>Scalar Multiplication\<close>
   103 
   104 instantiation complex :: real_field
   105 begin
   106 
   107 primcorec scaleR_complex where
   108   "Re (scaleR r x) = r * Re x"
   109 | "Im (scaleR r x) = r * Im x"
   110 
   111 instance
   112 proof
   113   fix a b :: real and x y :: complex
   114   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   115     by (simp add: complex_eq_iff distrib_left)
   116   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   117     by (simp add: complex_eq_iff distrib_right)
   118   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   119     by (simp add: complex_eq_iff mult.assoc)
   120   show "scaleR 1 x = x"
   121     by (simp add: complex_eq_iff)
   122   show "scaleR a x * y = scaleR a (x * y)"
   123     by (simp add: complex_eq_iff algebra_simps)
   124   show "x * scaleR a y = scaleR a (x * y)"
   125     by (simp add: complex_eq_iff algebra_simps)
   126 qed
   127 
   128 end
   129 
   130 subsection \<open>Numerals, Arithmetic, and Embedding from Reals\<close>
   131 
   132 abbreviation complex_of_real :: "real \<Rightarrow> complex"
   133   where "complex_of_real \<equiv> of_real"
   134 
   135 declare [[coercion "of_real :: real \<Rightarrow> complex"]]
   136 declare [[coercion "of_rat :: rat \<Rightarrow> complex"]]
   137 declare [[coercion "of_int :: int \<Rightarrow> complex"]]
   138 declare [[coercion "of_nat :: nat \<Rightarrow> complex"]]
   139 
   140 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   141   by (induct n) simp_all
   142 
   143 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   144   by (induct n) simp_all
   145 
   146 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   147   by (cases z rule: int_diff_cases) simp
   148 
   149 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   150   by (cases z rule: int_diff_cases) simp
   151 
   152 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
   153   using complex_Re_of_int [of "numeral v"] by simp
   154 
   155 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
   156   using complex_Im_of_int [of "numeral v"] by simp
   157 
   158 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   159   by (simp add: of_real_def)
   160 
   161 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   162   by (simp add: of_real_def)
   163 
   164 lemma Re_divide_numeral [simp]: "Re (z / numeral w) = Re z / numeral w"
   165   by (simp add: Re_divide sqr_conv_mult)
   166 
   167 lemma Im_divide_numeral [simp]: "Im (z / numeral w) = Im z / numeral w"
   168   by (simp add: Im_divide sqr_conv_mult)
   169 
   170 lemma of_real_Re [simp]:
   171     "z \<in> \<real> \<Longrightarrow> of_real (Re z) = z"
   172   by (auto simp: Reals_def)
   173 
   174 lemma complex_Re_fact [simp]: "Re (fact n) = fact n"
   175 proof -
   176   have "(fact n :: complex) = of_real (fact n)" by simp
   177   also have "Re \<dots> = fact n" by (subst Re_complex_of_real) simp_all
   178   finally show ?thesis .
   179 qed
   180 
   181 lemma complex_Im_fact [simp]: "Im (fact n) = 0"
   182   by (subst of_nat_fact [symmetric]) (simp only: complex_Im_of_nat)
   183 
   184 
   185 subsection \<open>The Complex Number $i$\<close>
   186 
   187 primcorec "ii" :: complex  ("\<i>") where
   188   "Re ii = 0"
   189 | "Im ii = 1"
   190 
   191 lemma Complex_eq[simp]: "Complex a b = a + \<i> * b"
   192   by (simp add: complex_eq_iff)
   193 
   194 lemma complex_eq: "a = Re a + \<i> * Im a"
   195   by (simp add: complex_eq_iff)
   196 
   197 lemma fun_complex_eq: "f = (\<lambda>x. Re (f x) + \<i> * Im (f x))"
   198   by (simp add: fun_eq_iff complex_eq)
   199 
   200 lemma i_squared [simp]: "ii * ii = -1"
   201   by (simp add: complex_eq_iff)
   202 
   203 lemma power2_i [simp]: "ii\<^sup>2 = -1"
   204   by (simp add: power2_eq_square)
   205 
   206 lemma inverse_i [simp]: "inverse ii = - ii"
   207   by (rule inverse_unique) simp
   208 
   209 lemma divide_i [simp]: "x / ii = - ii * x"
   210   by (simp add: divide_complex_def)
   211 
   212 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"
   213   by (simp add: mult.assoc [symmetric])
   214 
   215 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"
   216   by (simp add: complex_eq_iff)
   217 
   218 lemma complex_i_not_one [simp]: "ii \<noteq> 1"
   219   by (simp add: complex_eq_iff)
   220 
   221 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"
   222   by (simp add: complex_eq_iff)
   223 
   224 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"
   225   by (simp add: complex_eq_iff)
   226 
   227 lemma complex_split_polar: "\<exists>r a. z = complex_of_real r * (cos a + \<i> * sin a)"
   228   by (simp add: complex_eq_iff polar_Ex)
   229 
   230 lemma i_even_power [simp]: "\<i> ^ (n * 2) = (-1) ^ n"
   231   by (metis mult.commute power2_i power_mult)
   232 
   233 lemma Re_ii_times [simp]: "Re (ii*z) = - Im z"
   234   by simp
   235 
   236 lemma Im_ii_times [simp]: "Im (ii*z) = Re z"
   237   by simp
   238 
   239 lemma ii_times_eq_iff: "ii*w = z \<longleftrightarrow> w = -(ii*z)"
   240   by auto
   241 
   242 lemma divide_numeral_i [simp]: "z / (numeral n * ii) = -(ii*z) / numeral n"
   243   by (metis divide_divide_eq_left divide_i mult.commute mult_minus_right)
   244 
   245 subsection \<open>Vector Norm\<close>
   246 
   247 instantiation complex :: real_normed_field
   248 begin
   249 
   250 definition "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   251 
   252 abbreviation cmod :: "complex \<Rightarrow> real"
   253   where "cmod \<equiv> norm"
   254 
   255 definition complex_sgn_def:
   256   "sgn x = x /\<^sub>R cmod x"
   257 
   258 definition dist_complex_def:
   259   "dist x y = cmod (x - y)"
   260 
   261 definition open_complex_def:
   262   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   263 
   264 instance proof
   265   fix r :: real and x y :: complex and S :: "complex set"
   266   show "(norm x = 0) = (x = 0)"
   267     by (simp add: norm_complex_def complex_eq_iff)
   268   show "norm (x + y) \<le> norm x + norm y"
   269     by (simp add: norm_complex_def complex_eq_iff real_sqrt_sum_squares_triangle_ineq)
   270   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   271     by (simp add: norm_complex_def complex_eq_iff power_mult_distrib distrib_left [symmetric] real_sqrt_mult)
   272   show "norm (x * y) = norm x * norm y"
   273     by (simp add: norm_complex_def complex_eq_iff real_sqrt_mult [symmetric] power2_eq_square algebra_simps)
   274 qed (rule complex_sgn_def dist_complex_def open_complex_def)+
   275 
   276 end
   277 
   278 lemma norm_ii [simp]: "norm ii = 1"
   279   by (simp add: norm_complex_def)
   280 
   281 lemma cmod_unit_one: "cmod (cos a + \<i> * sin a) = 1"
   282   by (simp add: norm_complex_def)
   283 
   284 lemma cmod_complex_polar: "cmod (r * (cos a + \<i> * sin a)) = \<bar>r\<bar>"
   285   by (simp add: norm_mult cmod_unit_one)
   286 
   287 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   288   unfolding norm_complex_def
   289   by (rule real_sqrt_sum_squares_ge1)
   290 
   291 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
   292   by (rule order_trans [OF _ norm_ge_zero]) simp
   293 
   294 lemma complex_mod_triangle_ineq2: "cmod (b + a) - cmod b \<le> cmod a"
   295   by (rule ord_le_eq_trans [OF norm_triangle_ineq2]) simp
   296 
   297 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   298   by (simp add: norm_complex_def)
   299 
   300 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   301   by (simp add: norm_complex_def)
   302 
   303 lemma cmod_le: "cmod z \<le> \<bar>Re z\<bar> + \<bar>Im z\<bar>"
   304   apply (subst complex_eq)
   305   apply (rule order_trans)
   306   apply (rule norm_triangle_ineq)
   307   apply (simp add: norm_mult)
   308   done
   309 
   310 lemma cmod_eq_Re: "Im z = 0 \<Longrightarrow> cmod z = \<bar>Re z\<bar>"
   311   by (simp add: norm_complex_def)
   312 
   313 lemma cmod_eq_Im: "Re z = 0 \<Longrightarrow> cmod z = \<bar>Im z\<bar>"
   314   by (simp add: norm_complex_def)
   315 
   316 lemma cmod_power2: "cmod z ^ 2 = (Re z)^2 + (Im z)^2"
   317   by (simp add: norm_complex_def)
   318 
   319 lemma cmod_plus_Re_le_0_iff: "cmod z + Re z \<le> 0 \<longleftrightarrow> Re z = - cmod z"
   320   using abs_Re_le_cmod[of z] by auto
   321 
   322 lemma Im_eq_0: "\<bar>Re z\<bar> = cmod z \<Longrightarrow> Im z = 0"
   323   by (subst (asm) power_eq_iff_eq_base[symmetric, where n=2])
   324      (auto simp add: norm_complex_def)
   325 
   326 lemma abs_sqrt_wlog:
   327   fixes x::"'a::linordered_idom"
   328   assumes "\<And>x::'a. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)" shows "P \<bar>x\<bar> (x\<^sup>2)"
   329 by (metis abs_ge_zero assms power2_abs)
   330 
   331 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"
   332   unfolding norm_complex_def
   333   apply (rule abs_sqrt_wlog [where x="Re z"])
   334   apply (rule abs_sqrt_wlog [where x="Im z"])
   335   apply (rule power2_le_imp_le)
   336   apply (simp_all add: power2_sum add.commute sum_squares_bound real_sqrt_mult [symmetric])
   337   done
   338 
   339 lemma complex_unit_circle: "z \<noteq> 0 \<Longrightarrow> (Re z / cmod z)\<^sup>2 + (Im z / cmod z)\<^sup>2 = 1"
   340   by (simp add: norm_complex_def divide_simps complex_eq_iff)
   341 
   342 
   343 text \<open>Properties of complex signum.\<close>
   344 
   345 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   346   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult.commute)
   347 
   348 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   349   by (simp add: complex_sgn_def divide_inverse)
   350 
   351 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   352   by (simp add: complex_sgn_def divide_inverse)
   353 
   354 
   355 subsection \<open>Completeness of the Complexes\<close>
   356 
   357 lemma bounded_linear_Re: "bounded_linear Re"
   358   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
   359 
   360 lemma bounded_linear_Im: "bounded_linear Im"
   361   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)
   362 
   363 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   364 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   365 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]
   366 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]
   367 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   368 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   369 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]
   370 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]
   371 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]
   372 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]
   373 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]
   374 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]
   375 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]
   376 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]
   377 
   378 lemma tendsto_Complex [tendsto_intros]:
   379   "(f ---> a) F \<Longrightarrow> (g ---> b) F \<Longrightarrow> ((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"
   380   by (auto intro!: tendsto_intros)
   381 
   382 lemma tendsto_complex_iff:
   383   "(f ---> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) ---> Re x) F \<and> ((\<lambda>x. Im (f x)) ---> Im x) F)"
   384 proof safe
   385   assume "((\<lambda>x. Re (f x)) ---> Re x) F" "((\<lambda>x. Im (f x)) ---> Im x) F"
   386   from tendsto_Complex[OF this] show "(f ---> x) F"
   387     unfolding complex.collapse .
   388 qed (auto intro: tendsto_intros)
   389 
   390 lemma continuous_complex_iff: "continuous F f \<longleftrightarrow>
   391     continuous F (\<lambda>x. Re (f x)) \<and> continuous F (\<lambda>x. Im (f x))"
   392   unfolding continuous_def tendsto_complex_iff ..
   393 
   394 lemma has_vector_derivative_complex_iff: "(f has_vector_derivative x) F \<longleftrightarrow>
   395     ((\<lambda>x. Re (f x)) has_field_derivative (Re x)) F \<and>
   396     ((\<lambda>x. Im (f x)) has_field_derivative (Im x)) F"
   397   unfolding has_vector_derivative_def has_field_derivative_def has_derivative_def tendsto_complex_iff
   398   by (simp add: field_simps bounded_linear_scaleR_left bounded_linear_mult_right)
   399 
   400 lemma has_field_derivative_Re[derivative_intros]:
   401   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Re (f x)) has_field_derivative (Re D)) F"
   402   unfolding has_vector_derivative_complex_iff by safe
   403 
   404 lemma has_field_derivative_Im[derivative_intros]:
   405   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Im (f x)) has_field_derivative (Im D)) F"
   406   unfolding has_vector_derivative_complex_iff by safe
   407 
   408 instance complex :: banach
   409 proof
   410   fix X :: "nat \<Rightarrow> complex"
   411   assume X: "Cauchy X"
   412   then have "(\<lambda>n. Complex (Re (X n)) (Im (X n))) ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   413     by (intro tendsto_Complex convergent_LIMSEQ_iff[THEN iffD1] Cauchy_convergent_iff[THEN iffD1] Cauchy_Re Cauchy_Im)
   414   then show "convergent X"
   415     unfolding complex.collapse by (rule convergentI)
   416 qed
   417 
   418 declare
   419   DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]
   420 
   421 subsection \<open>Complex Conjugation\<close>
   422 
   423 primcorec cnj :: "complex \<Rightarrow> complex" where
   424   "Re (cnj z) = Re z"
   425 | "Im (cnj z) = - Im z"
   426 
   427 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"
   428   by (simp add: complex_eq_iff)
   429 
   430 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   431   by (simp add: complex_eq_iff)
   432 
   433 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   434   by (simp add: complex_eq_iff)
   435 
   436 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"
   437   by (simp add: complex_eq_iff)
   438 
   439 lemma complex_cnj_add [simp]: "cnj (x + y) = cnj x + cnj y"
   440   by (simp add: complex_eq_iff)
   441 
   442 lemma cnj_setsum [simp]: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"
   443   by (induct s rule: infinite_finite_induct) auto
   444 
   445 lemma complex_cnj_diff [simp]: "cnj (x - y) = cnj x - cnj y"
   446   by (simp add: complex_eq_iff)
   447 
   448 lemma complex_cnj_minus [simp]: "cnj (- x) = - cnj x"
   449   by (simp add: complex_eq_iff)
   450 
   451 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   452   by (simp add: complex_eq_iff)
   453 
   454 lemma complex_cnj_mult [simp]: "cnj (x * y) = cnj x * cnj y"
   455   by (simp add: complex_eq_iff)
   456 
   457 lemma cnj_setprod [simp]: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"
   458   by (induct s rule: infinite_finite_induct) auto
   459 
   460 lemma complex_cnj_inverse [simp]: "cnj (inverse x) = inverse (cnj x)"
   461   by (simp add: complex_eq_iff)
   462 
   463 lemma complex_cnj_divide [simp]: "cnj (x / y) = cnj x / cnj y"
   464   by (simp add: divide_complex_def)
   465 
   466 lemma complex_cnj_power [simp]: "cnj (x ^ n) = cnj x ^ n"
   467   by (induct n) simp_all
   468 
   469 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   470   by (simp add: complex_eq_iff)
   471 
   472 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   473   by (simp add: complex_eq_iff)
   474 
   475 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
   476   by (simp add: complex_eq_iff)
   477 
   478 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
   479   by (simp add: complex_eq_iff)
   480 
   481 lemma complex_cnj_scaleR [simp]: "cnj (scaleR r x) = scaleR r (cnj x)"
   482   by (simp add: complex_eq_iff)
   483 
   484 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   485   by (simp add: norm_complex_def)
   486 
   487 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   488   by (simp add: complex_eq_iff)
   489 
   490 lemma complex_cnj_i [simp]: "cnj ii = - ii"
   491   by (simp add: complex_eq_iff)
   492 
   493 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   494   by (simp add: complex_eq_iff)
   495 
   496 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"
   497   by (simp add: complex_eq_iff)
   498 
   499 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   500   by (simp add: complex_eq_iff power2_eq_square)
   501 
   502 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
   503   by (simp add: norm_mult power2_eq_square)
   504 
   505 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   506   by (simp add: norm_complex_def power2_eq_square)
   507 
   508 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   509   by simp
   510 
   511 lemma complex_cnj_fact [simp]: "cnj (fact n) = fact n"
   512   by (subst of_nat_fact [symmetric], subst complex_cnj_of_nat) simp
   513 
   514 lemma complex_cnj_pochhammer [simp]: "cnj (pochhammer z n) = pochhammer (cnj z) n"
   515   by (induction n arbitrary: z) (simp_all add: pochhammer_rec)
   516 
   517 lemma bounded_linear_cnj: "bounded_linear cnj"
   518   using complex_cnj_add complex_cnj_scaleR
   519   by (rule bounded_linear_intro [where K=1], simp)
   520 
   521 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]
   522 lemmas isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]
   523 lemmas continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]
   524 lemmas continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]
   525 lemmas has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]
   526 
   527 lemma lim_cnj: "((\<lambda>x. cnj(f x)) ---> cnj l) F \<longleftrightarrow> (f ---> l) F"
   528   by (simp add: tendsto_iff dist_complex_def complex_cnj_diff [symmetric] del: complex_cnj_diff)
   529 
   530 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"
   531   by (simp add: sums_def lim_cnj cnj_setsum [symmetric] del: cnj_setsum)
   532 
   533 
   534 subsection\<open>Basic Lemmas\<close>
   535 
   536 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
   537   by (metis zero_complex.sel complex_eqI sum_power2_eq_zero_iff)
   538 
   539 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
   540   by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
   541 
   542 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
   543 by (cases z)
   544    (auto simp: complex_eq_iff norm_complex_def power2_eq_square[symmetric] of_real_power[symmetric]
   545          simp del: of_real_power)
   546 
   547 lemma complex_div_cnj: "a / b = (a * cnj b) / (norm b)^2"
   548   using complex_norm_square by auto
   549 
   550 lemma Re_complex_div_eq_0: "Re (a / b) = 0 \<longleftrightarrow> Re (a * cnj b) = 0"
   551   by (auto simp add: Re_divide)
   552 
   553 lemma Im_complex_div_eq_0: "Im (a / b) = 0 \<longleftrightarrow> Im (a * cnj b) = 0"
   554   by (auto simp add: Im_divide)
   555 
   556 lemma complex_div_gt_0:
   557   "(Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0) \<and> (Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0)"
   558 proof cases
   559   assume "b = 0" then show ?thesis by auto
   560 next
   561   assume "b \<noteq> 0"
   562   then have "0 < (Re b)\<^sup>2 + (Im b)\<^sup>2"
   563     by (simp add: complex_eq_iff sum_power2_gt_zero_iff)
   564   then show ?thesis
   565     by (simp add: Re_divide Im_divide zero_less_divide_iff)
   566 qed
   567 
   568 lemma Re_complex_div_gt_0: "Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0"
   569   and Im_complex_div_gt_0: "Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0"
   570   using complex_div_gt_0 by auto
   571 
   572 lemma Re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"
   573   by (metis le_less Re_complex_div_eq_0 Re_complex_div_gt_0)
   574 
   575 lemma Im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"
   576   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 le_less)
   577 
   578 lemma Re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"
   579   by (metis less_asym neq_iff Re_complex_div_eq_0 Re_complex_div_gt_0)
   580 
   581 lemma Im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"
   582   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 less_asym neq_iff)
   583 
   584 lemma Re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"
   585   by (metis not_le Re_complex_div_gt_0)
   586 
   587 lemma Im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"
   588   by (metis Im_complex_div_gt_0 not_le)
   589 
   590 lemma Re_divide_of_real [simp]: "Re (z / of_real r) = Re z / r"
   591   by (simp add: Re_divide power2_eq_square)
   592 
   593 lemma Im_divide_of_real [simp]: "Im (z / of_real r) = Im z / r"
   594   by (simp add: Im_divide power2_eq_square)
   595 
   596 lemma Re_divide_Reals: "r \<in> Reals \<Longrightarrow> Re (z / r) = Re z / Re r"
   597   by (metis Re_divide_of_real of_real_Re)
   598 
   599 lemma Im_divide_Reals: "r \<in> Reals \<Longrightarrow> Im (z / r) = Im z / Re r"
   600   by (metis Im_divide_of_real of_real_Re)
   601 
   602 lemma Re_setsum[simp]: "Re (setsum f s) = (\<Sum>x\<in>s. Re (f x))"
   603   by (induct s rule: infinite_finite_induct) auto
   604 
   605 lemma Im_setsum[simp]: "Im (setsum f s) = (\<Sum>x\<in>s. Im(f x))"
   606   by (induct s rule: infinite_finite_induct) auto
   607 
   608 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"
   609   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..
   610 
   611 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"
   612   unfolding summable_def sums_complex_iff[abs_def] by (metis complex.sel)
   613 
   614 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"
   615   unfolding summable_complex_iff by simp
   616 
   617 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"
   618   unfolding summable_complex_iff by blast
   619 
   620 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"
   621   unfolding summable_complex_iff by blast
   622 
   623 lemma complex_is_Nat_iff: "z \<in> \<nat> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_nat i)"
   624   by (auto simp: Nats_def complex_eq_iff)
   625 
   626 lemma complex_is_Int_iff: "z \<in> \<int> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_int i)"
   627   by (auto simp: Ints_def complex_eq_iff)
   628 
   629 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"
   630   by (auto simp: Reals_def complex_eq_iff)
   631 
   632 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
   633   by (auto simp: complex_is_Real_iff complex_eq_iff)
   634 
   635 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm(z) = abs(Re z)"
   636   by (simp add: complex_is_Real_iff norm_complex_def)
   637 
   638 lemma series_comparison_complex:
   639   fixes f:: "nat \<Rightarrow> 'a::banach"
   640   assumes sg: "summable g"
   641      and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"
   642      and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"
   643   shows "summable f"
   644 proof -
   645   have g: "\<And>n. cmod (g n) = Re (g n)" using assms
   646     by (metis abs_of_nonneg in_Reals_norm)
   647   show ?thesis
   648     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])
   649     using sg
   650     apply (auto simp: summable_def)
   651     apply (rule_tac x="Re s" in exI)
   652     apply (auto simp: g sums_Re)
   653     apply (metis fg g)
   654     done
   655 qed
   656 
   657 subsection\<open>Polar Form for Complex Numbers\<close>
   658 
   659 lemma complex_unimodular_polar: "(norm z = 1) \<Longrightarrow> \<exists>x. z = Complex (cos x) (sin x)"
   660   using sincos_total_2pi [of "Re z" "Im z"]
   661   by auto (metis cmod_power2 complex_eq power_one)
   662 
   663 subsubsection \<open>$\cos \theta + i \sin \theta$\<close>
   664 
   665 primcorec cis :: "real \<Rightarrow> complex" where
   666   "Re (cis a) = cos a"
   667 | "Im (cis a) = sin a"
   668 
   669 lemma cis_zero [simp]: "cis 0 = 1"
   670   by (simp add: complex_eq_iff)
   671 
   672 lemma norm_cis [simp]: "norm (cis a) = 1"
   673   by (simp add: norm_complex_def)
   674 
   675 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
   676   by (simp add: sgn_div_norm)
   677 
   678 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
   679   by (metis norm_cis norm_zero zero_neq_one)
   680 
   681 lemma cis_mult: "cis a * cis b = cis (a + b)"
   682   by (simp add: complex_eq_iff cos_add sin_add)
   683 
   684 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   685   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)
   686 
   687 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"
   688   by (simp add: complex_eq_iff)
   689 
   690 lemma cis_divide: "cis a / cis b = cis (a - b)"
   691   by (simp add: divide_complex_def cis_mult)
   692 
   693 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"
   694   by (auto simp add: DeMoivre)
   695 
   696 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"
   697   by (auto simp add: DeMoivre)
   698 
   699 lemma cis_pi: "cis pi = -1"
   700   by (simp add: complex_eq_iff)
   701 
   702 subsubsection \<open>$r(\cos \theta + i \sin \theta)$\<close>
   703 
   704 definition rcis :: "real \<Rightarrow> real \<Rightarrow> complex" where
   705   "rcis r a = complex_of_real r * cis a"
   706 
   707 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   708   by (simp add: rcis_def)
   709 
   710 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   711   by (simp add: rcis_def)
   712 
   713 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   714   by (simp add: complex_eq_iff polar_Ex)
   715 
   716 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"
   717   by (simp add: rcis_def norm_mult)
   718 
   719 lemma cis_rcis_eq: "cis a = rcis 1 a"
   720   by (simp add: rcis_def)
   721 
   722 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"
   723   by (simp add: rcis_def cis_mult)
   724 
   725 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   726   by (simp add: rcis_def)
   727 
   728 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   729   by (simp add: rcis_def)
   730 
   731 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
   732   by (simp add: rcis_def)
   733 
   734 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   735   by (simp add: rcis_def power_mult_distrib DeMoivre)
   736 
   737 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"
   738   by (simp add: divide_inverse rcis_def)
   739 
   740 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"
   741   by (simp add: rcis_def cis_divide [symmetric])
   742 
   743 subsubsection \<open>Complex exponential\<close>
   744 
   745 abbreviation Exp :: "complex \<Rightarrow> complex"
   746   where "Exp \<equiv> exp"
   747 
   748 lemma cis_conv_exp: "cis b = exp (\<i> * b)"
   749 proof -
   750   { fix n :: nat
   751     have "\<i> ^ n = fact n *\<^sub>R (cos_coeff n + \<i> * sin_coeff n)"
   752       by (induct n)
   753          (simp_all add: sin_coeff_Suc cos_coeff_Suc complex_eq_iff Re_divide Im_divide field_simps
   754                         power2_eq_square real_of_nat_Suc add_nonneg_eq_0_iff
   755                         real_of_nat_def[symmetric])
   756     then have "(\<i> * complex_of_real b) ^ n /\<^sub>R fact n =
   757         of_real (cos_coeff n * b^n) + \<i> * of_real (sin_coeff n * b^n)"
   758       by (simp add: field_simps) }
   759   then show ?thesis using sin_converges [of b] cos_converges [of b]
   760     by (auto simp add: cis.ctr exp_def simp del: of_real_mult
   761              intro!: sums_unique sums_add sums_mult sums_of_real)
   762 qed
   763 
   764 lemma Exp_eq_polar: "Exp z = exp (Re z) * cis (Im z)"
   765   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by (cases z) simp
   766 
   767 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
   768   unfolding Exp_eq_polar by simp
   769 
   770 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
   771   unfolding Exp_eq_polar by simp
   772 
   773 lemma norm_cos_sin [simp]: "norm (Complex (cos t) (sin t)) = 1"
   774   by (simp add: norm_complex_def)
   775 
   776 lemma norm_exp_eq_Re [simp]: "norm (exp z) = exp (Re z)"
   777   by (simp add: cis.code cmod_complex_polar Exp_eq_polar)
   778 
   779 lemma complex_Exp_Ex: "\<exists>a r. z = complex_of_real r * Exp a"
   780   apply (insert rcis_Ex [of z])
   781   apply (auto simp add: Exp_eq_polar rcis_def mult.assoc [symmetric])
   782   apply (rule_tac x = "ii * complex_of_real a" in exI, auto)
   783   done
   784 
   785 lemma Exp_two_pi_i [simp]: "Exp((2::complex) * complex_of_real pi * ii) = 1"
   786   by (simp add: Exp_eq_polar complex_eq_iff)
   787 
   788 subsubsection \<open>Complex argument\<close>
   789 
   790 definition arg :: "complex \<Rightarrow> real" where
   791   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"
   792 
   793 lemma arg_zero: "arg 0 = 0"
   794   by (simp add: arg_def)
   795 
   796 lemma arg_unique:
   797   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
   798   shows "arg z = x"
   799 proof -
   800   from assms have "z \<noteq> 0" by auto
   801   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
   802   proof
   803     fix a def d \<equiv> "a - x"
   804     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
   805     from a assms have "- (2*pi) < d \<and> d < 2*pi"
   806       unfolding d_def by simp
   807     moreover from a assms have "cos a = cos x" and "sin a = sin x"
   808       by (simp_all add: complex_eq_iff)
   809     hence cos: "cos d = 1" unfolding d_def cos_diff by simp
   810     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)
   811     ultimately have "d = 0"
   812       unfolding sin_zero_iff
   813       by (auto elim!: evenE dest!: less_2_cases)
   814     thus "a = x" unfolding d_def by simp
   815   qed (simp add: assms del: Re_sgn Im_sgn)
   816   with \<open>z \<noteq> 0\<close> show "arg z = x"
   817     unfolding arg_def by simp
   818 qed
   819 
   820 lemma arg_correct:
   821   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
   822 proof (simp add: arg_def assms, rule someI_ex)
   823   obtain r a where z: "z = rcis r a" using rcis_Ex by fast
   824   with assms have "r \<noteq> 0" by auto
   825   def b \<equiv> "if 0 < r then a else a + pi"
   826   have b: "sgn z = cis b"
   827     unfolding z b_def rcis_def using \<open>r \<noteq> 0\<close>
   828     by (simp add: of_real_def sgn_scaleR sgn_if complex_eq_iff)
   829   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"
   830     by (induct_tac n) (simp_all add: distrib_left cis_mult [symmetric] complex_eq_iff)
   831   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"
   832     by (case_tac x rule: int_diff_cases)
   833        (simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
   834   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"
   835   have "sgn z = cis c"
   836     unfolding b c_def
   837     by (simp add: cis_divide [symmetric] cis_2pi_int)
   838   moreover have "- pi < c \<and> c \<le> pi"
   839     using ceiling_correct [of "(b - pi) / (2*pi)"]
   840     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)
   841   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast
   842 qed
   843 
   844 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
   845   by (cases "z = 0") (simp_all add: arg_zero arg_correct)
   846 
   847 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
   848   by (simp add: arg_correct)
   849 
   850 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
   851   by (cases "z = 0") (simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
   852 
   853 lemma cos_arg_i_mult_zero [simp]: "y \<noteq> 0 \<Longrightarrow> Re y = 0 \<Longrightarrow> cos (arg y) = 0"
   854   using cis_arg [of y] by (simp add: complex_eq_iff)
   855 
   856 subsection \<open>Square root of complex numbers\<close>
   857 
   858 primcorec csqrt :: "complex \<Rightarrow> complex" where
   859   "Re (csqrt z) = sqrt ((cmod z + Re z) / 2)"
   860 | "Im (csqrt z) = (if Im z = 0 then 1 else sgn (Im z)) * sqrt ((cmod z - Re z) / 2)"
   861 
   862 lemma csqrt_of_real_nonneg [simp]: "Im x = 0 \<Longrightarrow> Re x \<ge> 0 \<Longrightarrow> csqrt x = sqrt (Re x)"
   863   by (simp add: complex_eq_iff norm_complex_def)
   864 
   865 lemma csqrt_of_real_nonpos [simp]: "Im x = 0 \<Longrightarrow> Re x \<le> 0 \<Longrightarrow> csqrt x = \<i> * sqrt \<bar>Re x\<bar>"
   866   by (simp add: complex_eq_iff norm_complex_def)
   867 
   868 lemma of_real_sqrt: "x \<ge> 0 \<Longrightarrow> of_real (sqrt x) = csqrt (of_real x)"
   869   by (simp add: complex_eq_iff norm_complex_def)
   870 
   871 lemma csqrt_0 [simp]: "csqrt 0 = 0"
   872   by simp
   873 
   874 lemma csqrt_1 [simp]: "csqrt 1 = 1"
   875   by simp
   876 
   877 lemma csqrt_ii [simp]: "csqrt \<i> = (1 + \<i>) / sqrt 2"
   878   by (simp add: complex_eq_iff Re_divide Im_divide real_sqrt_divide real_div_sqrt)
   879 
   880 lemma power2_csqrt[simp,algebra]: "(csqrt z)\<^sup>2 = z"
   881 proof cases
   882   assume "Im z = 0" then show ?thesis
   883     using real_sqrt_pow2[of "Re z"] real_sqrt_pow2[of "- Re z"]
   884     by (cases "0::real" "Re z" rule: linorder_cases)
   885        (simp_all add: complex_eq_iff Re_power2 Im_power2 power2_eq_square cmod_eq_Re)
   886 next
   887   assume "Im z \<noteq> 0"
   888   moreover
   889   have "cmod z * cmod z - Re z * Re z = Im z * Im z"
   890     by (simp add: norm_complex_def power2_eq_square)
   891   moreover
   892   have "\<bar>Re z\<bar> \<le> cmod z"
   893     by (simp add: norm_complex_def)
   894   ultimately show ?thesis
   895     by (simp add: Re_power2 Im_power2 complex_eq_iff real_sgn_eq
   896                   field_simps real_sqrt_mult[symmetric] real_sqrt_divide)
   897 qed
   898 
   899 lemma csqrt_eq_0 [simp]: "csqrt z = 0 \<longleftrightarrow> z = 0"
   900   by auto (metis power2_csqrt power_eq_0_iff)
   901 
   902 lemma csqrt_eq_1 [simp]: "csqrt z = 1 \<longleftrightarrow> z = 1"
   903   by auto (metis power2_csqrt power2_eq_1_iff)
   904 
   905 lemma csqrt_principal: "0 < Re (csqrt z) \<or> Re (csqrt z) = 0 \<and> 0 \<le> Im (csqrt z)"
   906   by (auto simp add: not_less cmod_plus_Re_le_0_iff Im_eq_0)
   907 
   908 lemma Re_csqrt: "0 \<le> Re (csqrt z)"
   909   by (metis csqrt_principal le_less)
   910 
   911 lemma csqrt_square:
   912   assumes "0 < Re b \<or> (Re b = 0 \<and> 0 \<le> Im b)"
   913   shows "csqrt (b^2) = b"
   914 proof -
   915   have "csqrt (b^2) = b \<or> csqrt (b^2) = - b"
   916     unfolding power2_eq_iff[symmetric] by (simp add: power2_csqrt)
   917   moreover have "csqrt (b^2) \<noteq> -b \<or> b = 0"
   918     using csqrt_principal[of "b ^ 2"] assms by (intro disjCI notI) (auto simp: complex_eq_iff)
   919   ultimately show ?thesis
   920     by auto
   921 qed
   922 
   923 lemma csqrt_unique:
   924     "w^2 = z \<Longrightarrow> (0 < Re w \<or> Re w = 0 \<and> 0 \<le> Im w) \<Longrightarrow> csqrt z = w"
   925   by (auto simp: csqrt_square)
   926 
   927 lemma csqrt_minus [simp]:
   928   assumes "Im x < 0 \<or> (Im x = 0 \<and> 0 \<le> Re x)"
   929   shows "csqrt (- x) = \<i> * csqrt x"
   930 proof -
   931   have "csqrt ((\<i> * csqrt x)^2) = \<i> * csqrt x"
   932   proof (rule csqrt_square)
   933     have "Im (csqrt x) \<le> 0"
   934       using assms by (auto simp add: cmod_eq_Re mult_le_0_iff field_simps complex_Re_le_cmod)
   935     then show "0 < Re (\<i> * csqrt x) \<or> Re (\<i> * csqrt x) = 0 \<and> 0 \<le> Im (\<i> * csqrt x)"
   936       by (auto simp add: Re_csqrt simp del: csqrt.simps)
   937   qed
   938   also have "(\<i> * csqrt x)^2 = - x"
   939     by (simp add: power_mult_distrib)
   940   finally show ?thesis .
   941 qed
   942 
   943 text \<open>Legacy theorem names\<close>
   944 
   945 lemmas expand_complex_eq = complex_eq_iff
   946 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
   947 lemmas complex_equality = complex_eqI
   948 lemmas cmod_def = norm_complex_def
   949 lemmas complex_norm_def = norm_complex_def
   950 lemmas complex_divide_def = divide_complex_def
   951 
   952 lemma legacy_Complex_simps:
   953   shows Complex_eq_0: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
   954     and complex_add: "Complex a b + Complex c d = Complex (a + c) (b + d)"
   955     and complex_minus: "- (Complex a b) = Complex (- a) (- b)"
   956     and complex_diff: "Complex a b - Complex c d = Complex (a - c) (b - d)"
   957     and Complex_eq_1: "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
   958     and Complex_eq_neg_1: "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
   959     and complex_mult: "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
   960     and complex_inverse: "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
   961     and Complex_eq_numeral: "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
   962     and Complex_eq_neg_numeral: "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
   963     and complex_scaleR: "scaleR r (Complex a b) = Complex (r * a) (r * b)"
   964     and Complex_eq_i: "(Complex x y = ii) = (x = 0 \<and> y = 1)"
   965     and i_mult_Complex: "ii * Complex a b = Complex (- b) a"
   966     and Complex_mult_i: "Complex a b * ii = Complex (- b) a"
   967     and i_complex_of_real: "ii * complex_of_real r = Complex 0 r"
   968     and complex_of_real_i: "complex_of_real r * ii = Complex 0 r"
   969     and Complex_add_complex_of_real: "Complex x y + complex_of_real r = Complex (x+r) y"
   970     and complex_of_real_add_Complex: "complex_of_real r + Complex x y = Complex (r+x) y"
   971     and Complex_mult_complex_of_real: "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
   972     and complex_of_real_mult_Complex: "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
   973     and complex_eq_cancel_iff2: "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"
   974     and complex_cn: "cnj (Complex a b) = Complex a (- b)"
   975     and Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"
   976     and Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"
   977     and complex_of_real_def: "complex_of_real r = Complex r 0"
   978     and complex_norm: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
   979   by (simp_all add: norm_complex_def field_simps complex_eq_iff Re_divide Im_divide del: Complex_eq)
   980 
   981 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
   982   by (metis Reals_of_real complex_of_real_def)
   983 
   984 end