src/HOL/Orderings.thy
author haftmann
Fri Feb 23 08:39:21 2007 +0100 (2007-02-23)
changeset 22348 ab505d281015
parent 22344 eddeabf16b5d
child 22377 61610b1beedf
permissions -rw-r--r--
adjusted code lemmas
     1 (*  Title:      HOL/Orderings.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     4 *)
     5 
     6 header {* Syntactic and abstract orders *}
     7 
     8 theory Orderings
     9 imports HOL
    10 begin
    11 
    12 subsection {* Order syntax *}
    13 
    14 class ord =
    15   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubseteq>" 50)
    16     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"  (infix "\<sqsubset>" 50)
    17 begin
    18 
    19 notation
    20   less_eq  ("op \<^loc><=") and
    21   less_eq  ("(_/ \<^loc><= _)" [51, 51] 50) and
    22   less  ("op \<^loc><") and
    23   less  ("(_/ \<^loc>< _)"  [51, 51] 50)
    24   
    25 notation (xsymbols)
    26   less_eq  ("op \<^loc>\<le>") and
    27   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    28 
    29 notation (HTML output)
    30   less_eq  ("op \<^loc>\<le>") and
    31   less_eq  ("(_/ \<^loc>\<le> _)"  [51, 51] 50)
    32 
    33 abbreviation (input)
    34   greater  (infix "\<^loc>>" 50) where
    35   "x \<^loc>> y \<equiv> y \<^loc>< x"
    36 
    37 abbreviation (input)
    38   greater_eq  (infix "\<^loc>>=" 50) where
    39   "x \<^loc>>= y \<equiv> y \<^loc><= x"
    40 
    41 notation (input)
    42   greater_eq  (infix "\<^loc>\<ge>" 50)
    43 
    44 end
    45 
    46 notation
    47   less_eq  ("op <=") and
    48   less_eq  ("(_/ <= _)" [51, 51] 50) and
    49   less  ("op <") and
    50   less  ("(_/ < _)"  [51, 51] 50)
    51   
    52 notation (xsymbols)
    53   less_eq  ("op \<le>") and
    54   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    55 
    56 notation (HTML output)
    57   less_eq  ("op \<le>") and
    58   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
    59 
    60 abbreviation (input)
    61   greater  (infix ">" 50) where
    62   "x > y \<equiv> y < x"
    63 
    64 abbreviation (input)
    65   greater_eq  (infix ">=" 50) where
    66   "x >= y \<equiv> y <= x"
    67 
    68 notation (input)
    69   greater_eq  (infix "\<ge>" 50)
    70 
    71 
    72 subsection {* Quasiorders (preorders) *}
    73 
    74 class preorder = ord +
    75   assumes less_le: "x \<sqsubset> y \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<noteq> y"
    76   and refl [iff]: "x \<sqsubseteq> x"
    77   and trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    78 begin
    79 
    80 text {* Reflexivity. *}
    81 
    82 lemma eq_refl: "x = y \<Longrightarrow> x \<sqsubseteq> y"
    83     -- {* This form is useful with the classical reasoner. *}
    84   by (erule ssubst) (rule refl)
    85 
    86 lemma less_irrefl [iff]: "\<not> x \<sqsubset> x"
    87   by (simp add: less_le)
    88 
    89 lemma le_less: "x \<sqsubseteq> y \<longleftrightarrow> x \<sqsubset> y \<or> x = y"
    90     -- {* NOT suitable for iff, since it can cause PROOF FAILED. *}
    91   by (simp add: less_le) blast
    92 
    93 lemma le_imp_less_or_eq: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubset> y \<or> x = y"
    94   unfolding less_le by blast
    95 
    96 lemma less_imp_le: "x \<sqsubset> y \<Longrightarrow> x \<sqsubseteq> y"
    97   unfolding less_le by blast
    98 
    99 lemma less_imp_neq: "x \<sqsubset> y \<Longrightarrow> x \<noteq> y"
   100   by (erule contrapos_pn, erule subst, rule less_irrefl)
   101 
   102 
   103 text {* Useful for simplification, but too risky to include by default. *}
   104 
   105 lemma less_imp_not_eq: "x \<sqsubset> y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   106   by auto
   107 
   108 lemma less_imp_not_eq2: "x \<sqsubset> y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   109   by auto
   110 
   111 
   112 text {* Transitivity rules for calculational reasoning *}
   113 
   114 lemma neq_le_trans: "\<lbrakk> a \<noteq> b; a \<sqsubseteq> b \<rbrakk> \<Longrightarrow> a \<sqsubset> b"
   115   by (simp add: less_le)
   116 
   117 lemma le_neq_trans: "\<lbrakk> a \<sqsubseteq> b; a \<noteq> b \<rbrakk> \<Longrightarrow> a \<sqsubset> b"
   118   by (simp add: less_le)
   119 
   120 end
   121 
   122 
   123 subsection {* Partial orderings *}
   124 
   125 class order = preorder + 
   126   assumes antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
   127 begin
   128 
   129 text {* Asymmetry. *}
   130 
   131 lemma less_not_sym: "x \<sqsubset> y \<Longrightarrow> \<not> (y \<sqsubset> x)"
   132   by (simp add: less_le antisym)
   133 
   134 lemma less_asym: "x \<sqsubset> y \<Longrightarrow> (\<not> P \<Longrightarrow> y \<sqsubset> x) \<Longrightarrow> P"
   135   by (drule less_not_sym, erule contrapos_np) simp
   136 
   137 lemma eq_iff: "x = y \<longleftrightarrow> x \<sqsubseteq> y \<and> y \<sqsubseteq> x"
   138   by (blast intro: antisym)
   139 
   140 lemma antisym_conv: "y \<sqsubseteq> x \<Longrightarrow> x \<sqsubseteq> y \<longleftrightarrow> x = y"
   141   by (blast intro: antisym)
   142 
   143 lemma less_imp_neq: "x \<sqsubset> y \<Longrightarrow> x \<noteq> y"
   144   by (erule contrapos_pn, erule subst, rule less_irrefl)
   145 
   146 
   147 text {* Transitivity. *}
   148 
   149 lemma less_trans: "\<lbrakk> x \<sqsubset> y; y \<sqsubset> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   150   by (simp add: less_le) (blast intro: trans antisym)
   151 
   152 lemma le_less_trans: "\<lbrakk> x \<sqsubseteq> y; y \<sqsubset> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   153   by (simp add: less_le) (blast intro: trans antisym)
   154 
   155 lemma less_le_trans: "\<lbrakk> x \<sqsubset> y; y \<sqsubseteq> z \<rbrakk> \<Longrightarrow> x \<sqsubset> z"
   156   by (simp add: less_le) (blast intro: trans antisym)
   157 
   158 
   159 text {* Useful for simplification, but too risky to include by default. *}
   160 
   161 lemma less_imp_not_less: "x \<sqsubset> y \<Longrightarrow> (\<not> y \<sqsubset> x) \<longleftrightarrow> True"
   162   by (blast elim: less_asym)
   163 
   164 lemma less_imp_triv: "x \<sqsubset> y \<Longrightarrow> (y \<sqsubset> x \<longrightarrow> P) \<longleftrightarrow> True"
   165   by (blast elim: less_asym)
   166 
   167 
   168 text {* Transitivity rules for calculational reasoning *}
   169 
   170 lemma less_asym': "\<lbrakk> a \<sqsubset> b; b \<sqsubset> a \<rbrakk> \<Longrightarrow> P"
   171   by (rule less_asym)
   172 
   173 end
   174 
   175 
   176 subsection {* Linear (total) orders *}
   177 
   178 class linorder = order +
   179   assumes linear: "x \<sqsubseteq> y \<or> y \<sqsubseteq> x"
   180 begin
   181 
   182 lemma less_linear: "x \<sqsubset> y \<or> x = y \<or> y \<sqsubset> x"
   183   unfolding less_le using less_le linear by blast 
   184 
   185 lemma le_less_linear: "x \<sqsubseteq> y \<or> y \<sqsubset> x"
   186   by (simp add: le_less less_linear)
   187 
   188 lemma le_cases [case_names le ge]:
   189   "\<lbrakk> x \<sqsubseteq> y \<Longrightarrow> P; y \<sqsubseteq> x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   190   using linear by blast
   191 
   192 lemma cases [case_names less equal greater]:
   193     "\<lbrakk> x \<sqsubset> y \<Longrightarrow> P; x = y \<Longrightarrow> P; y \<sqsubset> x \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   194   using less_linear by blast
   195 
   196 lemma not_less: "\<not> x \<sqsubset> y \<longleftrightarrow> y \<sqsubseteq> x"
   197   apply (simp add: less_le)
   198   using linear apply (blast intro: antisym)
   199   done
   200 
   201 lemma not_le: "\<not> x \<sqsubseteq> y \<longleftrightarrow> y \<sqsubset> x"
   202   apply (simp add: less_le)
   203   using linear apply (blast intro: antisym)
   204   done
   205 
   206 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x \<sqsubset> y \<or> y \<sqsubset> x"
   207   by (cut_tac x = x and y = y in less_linear, auto)
   208 
   209 lemma neqE: "\<lbrakk> x \<noteq> y; x \<sqsubset> y \<Longrightarrow> R; y \<sqsubset> x \<Longrightarrow> R\<rbrakk> \<Longrightarrow> R"
   210   by (simp add: neq_iff) blast
   211 
   212 lemma antisym_conv1: "\<not> x \<sqsubset> y \<Longrightarrow> x \<sqsubseteq> y \<longleftrightarrow> x = y"
   213   by (blast intro: antisym dest: not_less [THEN iffD1])
   214 
   215 lemma antisym_conv2: "x \<sqsubseteq> y \<Longrightarrow> \<not> x \<sqsubset> y \<longleftrightarrow> x = y"
   216   by (blast intro: antisym dest: not_less [THEN iffD1])
   217 
   218 lemma antisym_conv3: "\<not> y \<sqsubset> x \<Longrightarrow> \<not> x \<sqsubset> y \<longleftrightarrow> x = y"
   219   by (blast intro: antisym dest: not_less [THEN iffD1])
   220 
   221 text{*Replacing the old Nat.leI*}
   222 lemma leI: "\<not> x \<sqsubset> y \<Longrightarrow> y \<sqsubseteq> x"
   223   unfolding not_less .
   224 
   225 lemma leD: "y \<sqsubseteq> x \<Longrightarrow> \<not> x \<sqsubset> y"
   226   unfolding not_less .
   227 
   228 (*FIXME inappropriate name (or delete altogether)*)
   229 lemma not_leE: "\<not> y \<sqsubseteq> x \<Longrightarrow> x \<sqsubset> y"
   230   unfolding not_le .
   231 
   232 (* min/max *)
   233 
   234 definition
   235   min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   236   "min a b = (if a \<sqsubseteq> b then a else b)"
   237 
   238 definition
   239   max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
   240   "max a b = (if a \<sqsubseteq> b then b else a)"
   241 
   242 lemma min_le_iff_disj:
   243   "min x y \<sqsubseteq> z \<longleftrightarrow> x \<sqsubseteq> z \<or> y \<sqsubseteq> z"
   244   unfolding min_def using linear by (auto intro: trans)
   245 
   246 lemma le_max_iff_disj:
   247   "z \<sqsubseteq> max x y \<longleftrightarrow> z \<sqsubseteq> x \<or> z \<sqsubseteq> y"
   248   unfolding max_def using linear by (auto intro: trans)
   249 
   250 lemma min_less_iff_disj:
   251   "min x y \<sqsubset> z \<longleftrightarrow> x \<sqsubset> z \<or> y \<sqsubset> z"
   252   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   253 
   254 lemma less_max_iff_disj:
   255   "z \<sqsubset> max x y \<longleftrightarrow> z \<sqsubset> x \<or> z \<sqsubset> y"
   256   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   257 
   258 lemma min_less_iff_conj [simp]:
   259   "z \<sqsubset> min x y \<longleftrightarrow> z \<sqsubset> x \<and> z \<sqsubset> y"
   260   unfolding min_def le_less using less_linear by (auto intro: less_trans)
   261 
   262 lemma max_less_iff_conj [simp]:
   263   "max x y \<sqsubset> z \<longleftrightarrow> x \<sqsubset> z \<and> y \<sqsubset> z"
   264   unfolding max_def le_less using less_linear by (auto intro: less_trans)
   265 
   266 lemma split_min:
   267   "P (min i j) \<longleftrightarrow> (i \<sqsubseteq> j \<longrightarrow> P i) \<and> (\<not> i \<sqsubseteq> j \<longrightarrow> P j)"
   268   by (simp add: min_def)
   269 
   270 lemma split_max:
   271   "P (max i j) \<longleftrightarrow> (i \<sqsubseteq> j \<longrightarrow> P j) \<and> (\<not> i \<sqsubseteq> j \<longrightarrow> P i)"
   272   by (simp add: max_def)
   273 
   274 end
   275 
   276 
   277 subsection {* Name duplicates *}
   278 
   279 lemmas order_refl [iff] = preorder_class.refl
   280 lemmas order_trans = preorder_class.trans
   281 lemmas order_less_le = preorder_class.less_le
   282 lemmas order_eq_refl = preorder_class.eq_refl
   283 lemmas order_less_irrefl = preorder_class.less_irrefl
   284 lemmas order_le_less = preorder_class.le_less
   285 lemmas order_le_imp_less_or_eq = preorder_class.le_imp_less_or_eq
   286 lemmas order_less_imp_le = preorder_class.less_imp_le
   287 lemmas order_less_imp_not_eq = preorder_class.less_imp_not_eq
   288 lemmas order_less_imp_not_eq2 = preorder_class.less_imp_not_eq2
   289 lemmas order_neq_le_trans = preorder_class.neq_le_trans
   290 lemmas order_le_neq_trans = preorder_class.le_neq_trans
   291 
   292 lemmas order_antisym = order_class.antisym
   293 lemmas order_less_not_sym = order_class.less_not_sym
   294 lemmas order_less_asym = order_class.less_asym
   295 lemmas order_eq_iff = order_class.eq_iff
   296 lemmas order_antisym_conv = order_class.antisym_conv
   297 lemmas less_imp_neq = order_class.less_imp_neq
   298 lemmas order_less_trans = order_class.less_trans
   299 lemmas order_le_less_trans = order_class.le_less_trans
   300 lemmas order_less_le_trans = order_class.less_le_trans
   301 lemmas order_less_imp_not_less = order_class.less_imp_not_less
   302 lemmas order_less_imp_triv = order_class.less_imp_triv
   303 lemmas order_less_asym' = order_class.less_asym'
   304 
   305 lemmas linorder_linear = linorder_class.linear
   306 lemmas linorder_less_linear = linorder_class.less_linear
   307 lemmas linorder_le_less_linear = linorder_class.le_less_linear
   308 lemmas linorder_le_cases = linorder_class.le_cases
   309 lemmas linorder_cases = linorder_class.cases
   310 lemmas linorder_not_less = linorder_class.not_less
   311 lemmas linorder_not_le = linorder_class.not_le
   312 lemmas linorder_neq_iff = linorder_class.neq_iff
   313 lemmas linorder_neqE = linorder_class.neqE
   314 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
   315 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
   316 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
   317 lemmas leI = linorder_class.leI
   318 lemmas leD = linorder_class.leD
   319 lemmas not_leE = linorder_class.not_leE
   320 
   321 
   322 subsection {* Reasoning tools setup *}
   323 
   324 ML {*
   325 local
   326 
   327 fun decomp_gen sort thy (Trueprop $ t) =
   328   let
   329     fun of_sort t =
   330       let
   331         val T = type_of t
   332       in
   333         (* exclude numeric types: linear arithmetic subsumes transitivity *)
   334         T <> HOLogic.natT andalso T <> HOLogic.intT
   335           andalso T <> HOLogic.realT andalso Sign.of_sort thy (T, sort)
   336       end;
   337     fun dec (Const ("Not", _) $ t) = (case dec t
   338           of NONE => NONE
   339            | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   340       | dec (Const ("op =",  _) $ t1 $ t2) =
   341           if of_sort t1
   342           then SOME (t1, "=", t2)
   343           else NONE
   344       | dec (Const ("Orderings.less_eq",  _) $ t1 $ t2) =
   345           if of_sort t1
   346           then SOME (t1, "<=", t2)
   347           else NONE
   348       | dec (Const ("Orderings.less",  _) $ t1 $ t2) =
   349           if of_sort t1
   350           then SOME (t1, "<", t2)
   351           else NONE
   352       | dec _ = NONE;
   353   in dec t end;
   354 
   355 in
   356 
   357 (* The setting up of Quasi_Tac serves as a demo.  Since there is no
   358    class for quasi orders, the tactics Quasi_Tac.trans_tac and
   359    Quasi_Tac.quasi_tac are not of much use. *)
   360 
   361 structure Quasi_Tac = Quasi_Tac_Fun (
   362 struct
   363   val le_trans = thm "order_trans";
   364   val le_refl = thm "order_refl";
   365   val eqD1 = thm "order_eq_refl";
   366   val eqD2 = thm "sym" RS thm "order_eq_refl";
   367   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   368   val less_imp_le = thm "order_less_imp_le";
   369   val le_neq_trans = thm "order_le_neq_trans";
   370   val neq_le_trans = thm "order_neq_le_trans";
   371   val less_imp_neq = thm "less_imp_neq";
   372   val decomp_trans = decomp_gen ["Orderings.order"];
   373   val decomp_quasi = decomp_gen ["Orderings.order"];
   374 end);
   375 
   376 structure Order_Tac = Order_Tac_Fun (
   377 struct
   378   val less_reflE = thm "order_less_irrefl" RS thm "notE";
   379   val le_refl = thm "order_refl";
   380   val less_imp_le = thm "order_less_imp_le";
   381   val not_lessI = thm "linorder_not_less" RS thm "iffD2";
   382   val not_leI = thm "linorder_not_le" RS thm "iffD2";
   383   val not_lessD = thm "linorder_not_less" RS thm "iffD1";
   384   val not_leD = thm "linorder_not_le" RS thm "iffD1";
   385   val eqI = thm "order_antisym";
   386   val eqD1 = thm "order_eq_refl";
   387   val eqD2 = thm "sym" RS thm "order_eq_refl";
   388   val less_trans = thm "order_less_trans";
   389   val less_le_trans = thm "order_less_le_trans";
   390   val le_less_trans = thm "order_le_less_trans";
   391   val le_trans = thm "order_trans";
   392   val le_neq_trans = thm "order_le_neq_trans";
   393   val neq_le_trans = thm "order_neq_le_trans";
   394   val less_imp_neq = thm "less_imp_neq";
   395   val eq_neq_eq_imp_neq = thm "eq_neq_eq_imp_neq";
   396   val not_sym = thm "not_sym";
   397   val decomp_part = decomp_gen ["Orderings.order"];
   398   val decomp_lin = decomp_gen ["Orderings.linorder"];
   399 end);
   400 
   401 end;
   402 *}
   403 
   404 setup {*
   405 let
   406 
   407 val order_antisym_conv = thm "order_antisym_conv"
   408 val linorder_antisym_conv1 = thm "linorder_antisym_conv1"
   409 val linorder_antisym_conv2 = thm "linorder_antisym_conv2"
   410 val linorder_antisym_conv3 = thm "linorder_antisym_conv3"
   411 
   412 fun prp t thm = (#prop (rep_thm thm) = t);
   413 
   414 fun prove_antisym_le sg ss ((le as Const(_,T)) $ r $ s) =
   415   let val prems = prems_of_ss ss;
   416       val less = Const("Orderings.less",T);
   417       val t = HOLogic.mk_Trueprop(le $ s $ r);
   418   in case find_first (prp t) prems of
   419        NONE =>
   420          let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s))
   421          in case find_first (prp t) prems of
   422               NONE => NONE
   423             | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv1))
   424          end
   425      | SOME thm => SOME(mk_meta_eq(thm RS order_antisym_conv))
   426   end
   427   handle THM _ => NONE;
   428 
   429 fun prove_antisym_less sg ss (NotC $ ((less as Const(_,T)) $ r $ s)) =
   430   let val prems = prems_of_ss ss;
   431       val le = Const("Orderings.less_eq",T);
   432       val t = HOLogic.mk_Trueprop(le $ r $ s);
   433   in case find_first (prp t) prems of
   434        NONE =>
   435          let val t = HOLogic.mk_Trueprop(NotC $ (less $ s $ r))
   436          in case find_first (prp t) prems of
   437               NONE => NONE
   438             | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv3))
   439          end
   440      | SOME thm => SOME(mk_meta_eq(thm RS linorder_antisym_conv2))
   441   end
   442   handle THM _ => NONE;
   443 
   444 fun add_simprocs procs thy =
   445   (Simplifier.change_simpset_of thy (fn ss => ss
   446     addsimprocs (map (fn (name, raw_ts, proc) =>
   447       Simplifier.simproc thy name raw_ts proc)) procs); thy);
   448 fun add_solver name tac thy =
   449   (Simplifier.change_simpset_of thy (fn ss => ss addSolver
   450     (mk_solver name (K tac))); thy);
   451 
   452 in
   453   add_simprocs [
   454        ("antisym le", ["(x::'a::order) <= y"], prove_antisym_le),
   455        ("antisym less", ["~ (x::'a::linorder) < y"], prove_antisym_less)
   456      ]
   457   #> add_solver "Trans_linear" Order_Tac.linear_tac
   458   #> add_solver "Trans_partial" Order_Tac.partial_tac
   459   (* Adding the transitivity reasoners also as safe solvers showed a slight
   460      speed up, but the reasoning strength appears to be not higher (at least
   461      no breaking of additional proofs in the entire HOL distribution, as
   462      of 5 March 2004, was observed). *)
   463 end
   464 *}
   465 
   466 
   467 subsection {* Bounded quantifiers *}
   468 
   469 syntax
   470   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   471   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   472   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   473   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   474 
   475   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   476   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   477   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   478   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   479 
   480 syntax (xsymbols)
   481   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   482   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   483   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   484   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   485 
   486   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   487   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   488   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   489   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   490 
   491 syntax (HOL)
   492   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   493   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   494   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   495   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   496 
   497 syntax (HTML output)
   498   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   499   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   500   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   501   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   502 
   503   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   504   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   505   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   506   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   507 
   508 translations
   509   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   510   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   511   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   512   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   513   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   514   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   515   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   516   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   517 
   518 print_translation {*
   519 let
   520   val syntax_name = Sign.const_syntax_name (the_context ());
   521   val binder_name = Syntax.binder_name o syntax_name;
   522   val All_binder = binder_name "All";
   523   val Ex_binder = binder_name "Ex";
   524   val impl = syntax_name "op -->";
   525   val conj = syntax_name "op &";
   526   val less = syntax_name "Orderings.less";
   527   val less_eq = syntax_name "Orderings.less_eq";
   528 
   529   val trans =
   530    [((All_binder, impl, less), ("_All_less", "_All_greater")),
   531     ((All_binder, impl, less_eq), ("_All_less_eq", "_All_greater_eq")),
   532     ((Ex_binder, conj, less), ("_Ex_less", "_Ex_greater")),
   533     ((Ex_binder, conj, less_eq), ("_Ex_less_eq", "_Ex_greater_eq"))];
   534 
   535   fun matches_bound v t = 
   536      case t of (Const ("_bound", _) $ Free (v', _)) => (v = v')
   537               | _ => false
   538   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false)
   539   fun mk v c n P = Syntax.const c $ Syntax.mark_bound v $ n $ P
   540 
   541   fun tr' q = (q,
   542     fn [Const ("_bound", _) $ Free (v, _), Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   543       (case AList.lookup (op =) trans (q, c, d) of
   544         NONE => raise Match
   545       | SOME (l, g) =>
   546           if matches_bound v t andalso not (contains_var v u) then mk v l u P
   547           else if matches_bound v u andalso not (contains_var v t) then mk v g t P
   548           else raise Match)
   549      | _ => raise Match);
   550 in [tr' All_binder, tr' Ex_binder] end
   551 *}
   552 
   553 
   554 subsection {* Transitivity reasoning *}
   555 
   556 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
   557   by (rule subst)
   558 
   559 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
   560   by (rule ssubst)
   561 
   562 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
   563   by (rule subst)
   564 
   565 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
   566   by (rule ssubst)
   567 
   568 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   569   (!!x y. x < y ==> f x < f y) ==> f a < c"
   570 proof -
   571   assume r: "!!x y. x < y ==> f x < f y"
   572   assume "a < b" hence "f a < f b" by (rule r)
   573   also assume "f b < c"
   574   finally (order_less_trans) show ?thesis .
   575 qed
   576 
   577 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   578   (!!x y. x < y ==> f x < f y) ==> a < f c"
   579 proof -
   580   assume r: "!!x y. x < y ==> f x < f y"
   581   assume "a < f b"
   582   also assume "b < c" hence "f b < f c" by (rule r)
   583   finally (order_less_trans) show ?thesis .
   584 qed
   585 
   586 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   587   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   588 proof -
   589   assume r: "!!x y. x <= y ==> f x <= f y"
   590   assume "a <= b" hence "f a <= f b" by (rule r)
   591   also assume "f b < c"
   592   finally (order_le_less_trans) show ?thesis .
   593 qed
   594 
   595 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   596   (!!x y. x < y ==> f x < f y) ==> a < f c"
   597 proof -
   598   assume r: "!!x y. x < y ==> f x < f y"
   599   assume "a <= f b"
   600   also assume "b < c" hence "f b < f c" by (rule r)
   601   finally (order_le_less_trans) show ?thesis .
   602 qed
   603 
   604 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   605   (!!x y. x < y ==> f x < f y) ==> f a < c"
   606 proof -
   607   assume r: "!!x y. x < y ==> f x < f y"
   608   assume "a < b" hence "f a < f b" by (rule r)
   609   also assume "f b <= c"
   610   finally (order_less_le_trans) show ?thesis .
   611 qed
   612 
   613 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   614   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   615 proof -
   616   assume r: "!!x y. x <= y ==> f x <= f y"
   617   assume "a < f b"
   618   also assume "b <= c" hence "f b <= f c" by (rule r)
   619   finally (order_less_le_trans) show ?thesis .
   620 qed
   621 
   622 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   623   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   624 proof -
   625   assume r: "!!x y. x <= y ==> f x <= f y"
   626   assume "a <= f b"
   627   also assume "b <= c" hence "f b <= f c" by (rule r)
   628   finally (order_trans) show ?thesis .
   629 qed
   630 
   631 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   632   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   633 proof -
   634   assume r: "!!x y. x <= y ==> f x <= f y"
   635   assume "a <= b" hence "f a <= f b" by (rule r)
   636   also assume "f b <= c"
   637   finally (order_trans) show ?thesis .
   638 qed
   639 
   640 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   641   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   642 proof -
   643   assume r: "!!x y. x <= y ==> f x <= f y"
   644   assume "a <= b" hence "f a <= f b" by (rule r)
   645   also assume "f b = c"
   646   finally (ord_le_eq_trans) show ?thesis .
   647 qed
   648 
   649 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   650   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   651 proof -
   652   assume r: "!!x y. x <= y ==> f x <= f y"
   653   assume "a = f b"
   654   also assume "b <= c" hence "f b <= f c" by (rule r)
   655   finally (ord_eq_le_trans) show ?thesis .
   656 qed
   657 
   658 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   659   (!!x y. x < y ==> f x < f y) ==> f a < c"
   660 proof -
   661   assume r: "!!x y. x < y ==> f x < f y"
   662   assume "a < b" hence "f a < f b" by (rule r)
   663   also assume "f b = c"
   664   finally (ord_less_eq_trans) show ?thesis .
   665 qed
   666 
   667 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   668   (!!x y. x < y ==> f x < f y) ==> a < f c"
   669 proof -
   670   assume r: "!!x y. x < y ==> f x < f y"
   671   assume "a = f b"
   672   also assume "b < c" hence "f b < f c" by (rule r)
   673   finally (ord_eq_less_trans) show ?thesis .
   674 qed
   675 
   676 text {*
   677   Note that this list of rules is in reverse order of priorities.
   678 *}
   679 
   680 lemmas order_trans_rules [trans] =
   681   order_less_subst2
   682   order_less_subst1
   683   order_le_less_subst2
   684   order_le_less_subst1
   685   order_less_le_subst2
   686   order_less_le_subst1
   687   order_subst2
   688   order_subst1
   689   ord_le_eq_subst
   690   ord_eq_le_subst
   691   ord_less_eq_subst
   692   ord_eq_less_subst
   693   forw_subst
   694   back_subst
   695   rev_mp
   696   mp
   697   order_neq_le_trans
   698   order_le_neq_trans
   699   order_less_trans
   700   order_less_asym'
   701   order_le_less_trans
   702   order_less_le_trans
   703   order_trans
   704   order_antisym
   705   ord_le_eq_trans
   706   ord_eq_le_trans
   707   ord_less_eq_trans
   708   ord_eq_less_trans
   709   trans
   710 
   711 
   712 (* FIXME cleanup *)
   713 
   714 text {* These support proving chains of decreasing inequalities
   715     a >= b >= c ... in Isar proofs. *}
   716 
   717 lemma xt1:
   718   "a = b ==> b > c ==> a > c"
   719   "a > b ==> b = c ==> a > c"
   720   "a = b ==> b >= c ==> a >= c"
   721   "a >= b ==> b = c ==> a >= c"
   722   "(x::'a::order) >= y ==> y >= x ==> x = y"
   723   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   724   "(x::'a::order) > y ==> y >= z ==> x > z"
   725   "(x::'a::order) >= y ==> y > z ==> x > z"
   726   "(a::'a::order) > b ==> b > a ==> ?P"
   727   "(x::'a::order) > y ==> y > z ==> x > z"
   728   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   729   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   730   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c" 
   731   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   732   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   733   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   734 by auto
   735 
   736 lemma xt2:
   737   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   738 by (subgoal_tac "f b >= f c", force, force)
   739 
   740 lemma xt3: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==> 
   741     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
   742 by (subgoal_tac "f a >= f b", force, force)
   743 
   744 lemma xt4: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
   745   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
   746 by (subgoal_tac "f b >= f c", force, force)
   747 
   748 lemma xt5: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
   749     (!!x y. x > y ==> f x > f y) ==> f a > c"
   750 by (subgoal_tac "f a > f b", force, force)
   751 
   752 lemma xt6: "(a::'a::order) >= f b ==> b > c ==>
   753     (!!x y. x > y ==> f x > f y) ==> a > f c"
   754 by (subgoal_tac "f b > f c", force, force)
   755 
   756 lemma xt7: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
   757     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
   758 by (subgoal_tac "f a >= f b", force, force)
   759 
   760 lemma xt8: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
   761     (!!x y. x > y ==> f x > f y) ==> a > f c"
   762 by (subgoal_tac "f b > f c", force, force)
   763 
   764 lemma xt9: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
   765     (!!x y. x > y ==> f x > f y) ==> f a > c"
   766 by (subgoal_tac "f a > f b", force, force)
   767 
   768 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
   769 
   770 (* 
   771   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
   772   for the wrong thing in an Isar proof.
   773 
   774   The extra transitivity rules can be used as follows: 
   775 
   776 lemma "(a::'a::order) > z"
   777 proof -
   778   have "a >= b" (is "_ >= ?rhs")
   779     sorry
   780   also have "?rhs >= c" (is "_ >= ?rhs")
   781     sorry
   782   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
   783     sorry
   784   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
   785     sorry
   786   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
   787     sorry
   788   also (xtrans) have "?rhs > z"
   789     sorry
   790   finally (xtrans) show ?thesis .
   791 qed
   792 
   793   Alternatively, one can use "declare xtrans [trans]" and then
   794   leave out the "(xtrans)" above.
   795 *)
   796 
   797 subsection {* Order on bool *}
   798 
   799 instance bool :: linorder 
   800   le_bool_def: "P \<le> Q \<equiv> P \<longrightarrow> Q"
   801   less_bool_def: "P < Q \<equiv> P \<le> Q \<and> P \<noteq> Q"
   802   by default (auto simp add: le_bool_def less_bool_def)
   803 
   804 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
   805   by (simp add: le_bool_def)
   806 
   807 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
   808   by (simp add: le_bool_def)
   809 
   810 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
   811   by (simp add: le_bool_def)
   812 
   813 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
   814   by (simp add: le_bool_def)
   815 
   816 lemma [code func]:
   817   "False \<le> b \<longleftrightarrow> True"
   818   "True \<le> b \<longleftrightarrow> b"
   819   "False < b \<longleftrightarrow> b"
   820   "True < b \<longleftrightarrow> False"
   821   unfolding le_bool_def less_bool_def by simp_all
   822 
   823 subsection {* Monotonicity, syntactic least value operator and min/max *}
   824 
   825 locale mono =
   826   fixes f
   827   assumes mono: "A \<le> B \<Longrightarrow> f A \<le> f B"
   828 
   829 lemmas monoI [intro?] = mono.intro
   830   and monoD [dest?] = mono.mono
   831 
   832 constdefs
   833   Least :: "('a::ord => bool) => 'a"               (binder "LEAST " 10)
   834   "Least P == THE x. P x & (ALL y. P y --> x <= y)"
   835     -- {* We can no longer use LeastM because the latter requires Hilbert-AC. *}
   836 
   837 lemma LeastI2_order:
   838   "[| P (x::'a::order);
   839       !!y. P y ==> x <= y;
   840       !!x. [| P x; ALL y. P y --> x \<le> y |] ==> Q x |]
   841    ==> Q (Least P)"
   842   apply (unfold Least_def)
   843   apply (rule theI2)
   844     apply (blast intro: order_antisym)+
   845   done
   846 
   847 lemma Least_equality:
   848     "[| P (k::'a::order); !!x. P x ==> k <= x |] ==> (LEAST x. P x) = k"
   849   apply (simp add: Least_def)
   850   apply (rule the_equality)
   851   apply (auto intro!: order_antisym)
   852   done
   853 
   854 constdefs
   855   min :: "['a::ord, 'a] => 'a"
   856   "min a b == (if a <= b then a else b)"
   857   max :: "['a::ord, 'a] => 'a"
   858   "max a b == (if a <= b then b else a)"
   859 
   860 lemma min_linorder:
   861   "linorder.min (op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool) = min"
   862   by rule+ (simp add: min_def linorder_class.min_def)
   863 
   864 lemma max_linorder:
   865   "linorder.max (op \<le> \<Colon> 'a\<Colon>linorder \<Rightarrow> 'a \<Rightarrow> bool) = max"
   866   by rule+ (simp add: max_def linorder_class.max_def)
   867 
   868 lemmas min_le_iff_disj = linorder_class.min_le_iff_disj [unfolded min_linorder]
   869 lemmas le_max_iff_disj = linorder_class.le_max_iff_disj [unfolded max_linorder]
   870 lemmas min_less_iff_disj = linorder_class.min_less_iff_disj [unfolded min_linorder]
   871 lemmas less_max_iff_disj = linorder_class.less_max_iff_disj [unfolded max_linorder]
   872 lemmas min_less_iff_conj [simp] = linorder_class.min_less_iff_conj [unfolded min_linorder]
   873 lemmas max_less_iff_conj [simp] = linorder_class.max_less_iff_conj [unfolded max_linorder]
   874 lemmas split_min = linorder_class.split_min [unfolded min_linorder]
   875 lemmas split_max = linorder_class.split_max [unfolded max_linorder]
   876 
   877 lemma min_leastL: "(!!x. least <= x) ==> min least x = least"
   878   by (simp add: min_def)
   879 
   880 lemma max_leastL: "(!!x. least <= x) ==> max least x = x"
   881   by (simp add: max_def)
   882 
   883 lemma min_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> min x least = least"
   884   apply (simp add: min_def)
   885   apply (blast intro: order_antisym)
   886   done
   887 
   888 lemma max_leastR: "(\<And>x\<Colon>'a\<Colon>order. least \<le> x) \<Longrightarrow> max x least = x"
   889   apply (simp add: max_def)
   890   apply (blast intro: order_antisym)
   891   done
   892 
   893 lemma min_of_mono:
   894     "(!!x y. (f x <= f y) = (x <= y)) ==> min (f m) (f n) = f (min m n)"
   895   by (simp add: min_def)
   896 
   897 lemma max_of_mono:
   898     "(!!x y. (f x <= f y) = (x <= y)) ==> max (f m) (f n) = f (max m n)"
   899   by (simp add: max_def)
   900 
   901 
   902 subsection {* Basic ML bindings *}
   903 
   904 ML {*
   905 val leD = thm "leD";
   906 val leI = thm "leI";
   907 val linorder_neqE = thm "linorder_neqE";
   908 val linorder_neq_iff = thm "linorder_neq_iff";
   909 val linorder_not_le = thm "linorder_not_le";
   910 val linorder_not_less = thm "linorder_not_less";
   911 val monoD = thm "monoD";
   912 val monoI = thm "monoI";
   913 val order_antisym = thm "order_antisym";
   914 val order_less_irrefl = thm "order_less_irrefl";
   915 val order_refl = thm "order_refl";
   916 val order_trans = thm "order_trans";
   917 val split_max = thm "split_max";
   918 val split_min = thm "split_min";
   919 *}
   920 
   921 ML {*
   922 structure HOL =
   923 struct
   924   val thy = theory "HOL";
   925 end;
   926 *}  -- "belongs to theory HOL"
   927 
   928 end