src/Pure/library.ML
author wenzelm
Mon Aug 01 19:20:38 2005 +0200 (2005-08-01)
changeset 16984 abc48b981e60
parent 16878 07213f0e291f
child 17028 a497f621bfd4
permissions -rw-r--r--
tuned dict_ord;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |-> ||> ||>> |>> |>>> #> #-> ~~ \ \\ ins ins_string ins_int
    12   orf andf prefix upto downto mem mem_int mem_string union union_int
    13   union_string inter inter_int inter_string subset subset_int
    14   subset_string;
    15 
    16 infix 3 oo ooo oooo;
    17 
    18 signature BASIC_LIBRARY =
    19 sig
    20   (*functions*)
    21   val I: 'a -> 'a
    22   val K: 'a -> 'b -> 'a
    23   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    24   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    25   val |> : 'a * ('a -> 'b) -> 'b
    26   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    27   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    28   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    29   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    30   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    31   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    32   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    33   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    34   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    35   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    36   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    37   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    38   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    39   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    40 
    41   (*old options -- invalidated*)
    42   datatype invalid = None of invalid
    43   exception OPTION of invalid
    44 
    45   (*options*)
    46   val the: 'a option -> 'a
    47   val if_none: 'a option -> 'a -> 'a
    48   val is_some: 'a option -> bool
    49   val is_none: 'a option -> bool
    50 
    51   exception ERROR
    52   val try: ('a -> 'b) -> 'a -> 'b option
    53   val can: ('a -> 'b) -> 'a -> bool
    54   datatype 'a result = Result of 'a | Exn of exn
    55   val capture: ('a -> 'b) -> 'a -> 'b result
    56   val release: 'a result -> 'a
    57   val get_result: 'a result -> 'a option
    58   val get_exn: 'a result -> exn option
    59 
    60   (*pairs*)
    61   val pair: 'a -> 'b -> 'a * 'b
    62   val rpair: 'a -> 'b -> 'b * 'a
    63   val fst: 'a * 'b -> 'a
    64   val snd: 'a * 'b -> 'b
    65   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    66   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    67   val swap: 'a * 'b -> 'b * 'a
    68   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    69   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    70   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    71 
    72   (*booleans*)
    73   val equal: ''a -> ''a -> bool
    74   val not_equal: ''a -> ''a -> bool
    75   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    76   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    77   val exists: ('a -> bool) -> 'a list -> bool
    78   val forall: ('a -> bool) -> 'a list -> bool
    79   val set: bool ref -> bool
    80   val reset: bool ref -> bool
    81   val toggle: bool ref -> bool
    82   val change: 'a ref -> ('a -> 'a) -> unit
    83   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    84   val conditional: bool -> (unit -> unit) -> unit
    85 
    86   (*lists*)
    87   exception UnequalLengths
    88   val cons: 'a -> 'a list -> 'a list
    89   val single: 'a -> 'a list
    90   val append: 'a list -> 'a list -> 'a list
    91   val apply: ('a -> 'a) list -> 'a -> 'a
    92   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    93   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    94   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
    95   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    96   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    97   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    98   val unflat: 'a list list -> 'b list -> 'b list list
    99   val splitAt: int * 'a list -> 'a list * 'a list
   100   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   101   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
   102   val split_last: 'a list -> 'a list * 'a
   103   val nth_update: 'a -> int * 'a list -> 'a list
   104   val find_index: ('a -> bool) -> 'a list -> int
   105   val find_index_eq: ''a -> ''a list -> int
   106   val find_first: ('a -> bool) -> 'a list -> 'a option
   107   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   108   val separate: 'a -> 'a list -> 'a list
   109   val replicate: int -> 'a -> 'a list
   110   val multiply: 'a list * 'a list list -> 'a list list
   111   val product: 'a list -> 'b list -> ('a * 'b) list
   112   val filter: ('a -> bool) -> 'a list -> 'a list
   113   val filter_out: ('a -> bool) -> 'a list -> 'a list
   114   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   115   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   116   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   117   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   118   val ~~ : 'a list * 'b list -> ('a * 'b) list
   119   val split_list: ('a * 'b) list -> 'a list * 'b list
   120   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   121   val prefix: ''a list * ''a list -> bool
   122   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   123   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   124   val prefixes1: 'a list -> 'a list list
   125   val suffixes1: 'a list -> 'a list list
   126 
   127   (*integers*)
   128   val gcd: IntInf.int * IntInf.int -> IntInf.int
   129   val lcm: IntInf.int * IntInf.int -> IntInf.int
   130   val inc: int ref -> int
   131   val dec: int ref -> int
   132   val upto: int * int -> int list
   133   val downto: int * int -> int list
   134   val downto0: int list * int -> bool
   135   val radixpand: int * int -> int list
   136   val radixstring: int * string * int -> string
   137   val string_of_int: int -> string
   138   val string_of_indexname: string * int -> string
   139   val read_radixint: int * string list -> int * string list
   140   val read_int: string list -> int * string list
   141   val oct_char: string -> string
   142 
   143   (*rational numbers*)
   144   type rat
   145   exception RAT of string
   146   val rep_rat: rat -> IntInf.int * IntInf.int
   147   val ratadd: rat * rat -> rat
   148   val ratmul: rat * rat -> rat
   149   val ratinv: rat -> rat
   150   val int_ratdiv: IntInf.int * IntInf.int -> rat
   151   val ratneg: rat -> rat
   152   val rat_of_int: int -> rat
   153   val rat_of_intinf: IntInf.int -> rat
   154 
   155   (*strings*)
   156   val nth_elem_string: int * string -> string
   157   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   158   val exists_string: (string -> bool) -> string -> bool
   159   val forall_string: (string -> bool) -> string -> bool
   160   val enclose: string -> string -> string -> string
   161   val unenclose: string -> string
   162   val quote: string -> string
   163   val space_implode: string -> string list -> string
   164   val commas: string list -> string
   165   val commas_quote: string list -> string
   166   val cat_lines: string list -> string
   167   val space_explode: string -> string -> string list
   168   val split_lines: string -> string list
   169   val prefix_lines: string -> string -> string
   170   val untabify: string list -> string list
   171   val suffix: string -> string -> string
   172   val unsuffix: string -> string -> string
   173   val unprefix: string -> string -> string
   174   val replicate_string: int -> string -> string
   175   val translate_string: (string -> string) -> string -> string
   176 
   177   (*lists as sets -- see also Pure/General/ord_list.ML*)
   178   val mem: ''a * ''a list -> bool
   179   val mem_int: int * int list -> bool
   180   val mem_string: string * string list -> bool
   181   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   182   val ins: ''a * ''a list -> ''a list
   183   val ins_int: int * int list -> int list
   184   val ins_string: string * string list -> string list
   185   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   186   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   187   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   188   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   189   val union: ''a list * ''a list -> ''a list
   190   val union_int: int list * int list -> int list
   191   val union_string: string list * string list -> string list
   192   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   193   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   194   val inter: ''a list * ''a list -> ''a list
   195   val inter_int: int list * int list -> int list
   196   val inter_string: string list * string list -> string list
   197   val subset: ''a list * ''a list -> bool
   198   val subset_int: int list * int list -> bool
   199   val subset_string: string list * string list -> bool
   200   val eq_set: ''a list * ''a list -> bool
   201   val eq_set_string: string list * string list -> bool
   202   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   203   val \ : ''a list * ''a -> ''a list
   204   val \\ : ''a list * ''a list -> ''a list
   205   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   206   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   207   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   208   val distinct: ''a list -> ''a list
   209   val findrep: ''a list -> ''a list
   210   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   211   val duplicates: ''a list -> ''a list
   212   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   213 
   214   (*association lists*)
   215   val assoc: (''a * 'b) list * ''a -> 'b option
   216   val assoc_int: (int * 'a) list * int -> 'a option
   217   val assoc_string: (string * 'a) list * string -> 'a option
   218   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   219   val assocs: (''a * 'b list) list -> ''a -> 'b list
   220   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   221   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   222   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   223   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   224 
   225   (*lists as tables*)
   226   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   227   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   228   val merge_lists: ''a list -> ''a list -> ''a list
   229   val merge_lists': ''a list -> ''a list -> ''a list
   230   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   231   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   232 
   233   (*balanced trees*)
   234   exception Balance
   235   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   236   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   237   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   238 
   239   (*orders*)
   240   val rev_order: order -> order
   241   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   242   val int_ord: int * int -> order
   243   val string_ord: string * string -> order
   244   val fast_string_ord: string * string -> order
   245   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   246   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   247   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   248   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   249   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   250   val sort_strings: string list -> string list
   251   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   252   val unique_strings: string list -> string list
   253 
   254   (*random numbers*)
   255   exception RANDOM
   256   val random: unit -> real
   257   val random_range: int -> int -> int
   258   val one_of: 'a list -> 'a
   259   val frequency: (int * 'a) list -> 'a
   260 
   261   (*current directory*)
   262   val cd: string -> unit
   263   val pwd: unit -> string
   264 
   265   (*misc*)
   266   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   267   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   268   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   269   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   270   val gensym: string -> string
   271   val scanwords: (string -> bool) -> string list -> string list
   272   type stamp
   273   val stamp: unit -> stamp
   274   type serial
   275   val serial: unit -> serial
   276   structure Object: sig type T end
   277 end;
   278 
   279 signature LIBRARY =
   280 sig
   281   include BASIC_LIBRARY
   282   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   283   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   284   val take: int * 'a list -> 'a list
   285   val drop: int * 'a list -> 'a list
   286   val nth_elem: int * 'a list -> 'a
   287   val last_elem: 'a list -> 'a
   288   val flat: 'a list list -> 'a list
   289   val seq: ('a -> unit) -> 'a list -> unit
   290   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   291   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   292 end;
   293 
   294 structure Library: LIBRARY =
   295 struct
   296 
   297 
   298 (** functions **)
   299 
   300 fun I x = x;
   301 fun K x = fn _ => x;
   302 fun curry f x y = f (x, y);
   303 fun uncurry f (x, y) = f x y;
   304 
   305 (*reverse application and structured results*)
   306 fun x |> f = f x;
   307 fun (x, y) |-> f = f x y;
   308 fun (x, y) |>> f = (f x, y);
   309 fun (x, y) ||> f = (x, f y);
   310 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   311 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   312 
   313 (*reverse composition*)
   314 fun f #> g = g o f;
   315 fun f #-> g = uncurry g o f;
   316 
   317 (*view results*)
   318 fun `f = fn x => (f x, x);
   319 
   320 (*composition with multiple args*)
   321 fun (f oo g) x y = f (g x y);
   322 fun (f ooo g) x y z = f (g x y z);
   323 fun (f oooo g) x y z w = f (g x y z w);
   324 
   325 (*function exponentiation: f(...(f x)...) with n applications of f*)
   326 fun funpow n f x =
   327   let fun rep (0, x) = x
   328         | rep (n, x) = rep (n - 1, f x)
   329   in rep (n, x) end;
   330 
   331 (*application of (infix) operator to its left or right argument*)
   332 fun apl (x, f) y = f (x, y);
   333 fun apr (f, y) x = f (x, y);
   334 
   335 
   336 (** options **)
   337 
   338 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   339 datatype invalid = None of invalid;
   340 exception OPTION of invalid;
   341 
   342 val the = Option.valOf;
   343 
   344 (*strict!*)
   345 fun if_none NONE y = y
   346   | if_none (SOME x) _ = x;
   347 
   348 fun is_some (SOME _) = true
   349   | is_some NONE = false;
   350 
   351 fun is_none (SOME _) = false
   352   | is_none NONE = true;
   353 
   354 
   355 (* exception handling *)
   356 
   357 exception ERROR;
   358 
   359 fun try f x = SOME (f x)
   360   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   361 
   362 fun can f x = is_some (try f x);
   363 
   364 
   365 datatype 'a result =
   366   Result of 'a |
   367   Exn of exn;
   368 
   369 fun capture f x = Result (f x) handle e => Exn e;
   370 
   371 fun release (Result y) = y
   372   | release (Exn e) = raise e;
   373 
   374 fun get_result (Result x) = SOME x
   375   | get_result _ = NONE;
   376 
   377 fun get_exn (Exn exn) = SOME exn
   378   | get_exn _ = NONE;
   379 
   380 
   381 
   382 (** pairs **)
   383 
   384 fun pair x y = (x, y);
   385 fun rpair x y = (y, x);
   386 
   387 fun fst (x, y) = x;
   388 fun snd (x, y) = y;
   389 
   390 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   391 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   392 
   393 fun swap (x, y) = (y, x);
   394 
   395 (*apply function to components*)
   396 fun apfst f (x, y) = (f x, y);
   397 fun apsnd f (x, y) = (x, f y);
   398 fun pairself f (x, y) = (f x, f y);
   399 
   400 
   401 
   402 (** booleans **)
   403 
   404 (* equality *)
   405 
   406 fun equal x y = x = y;
   407 fun not_equal x y = x <> y;
   408 
   409 
   410 (* operators for combining predicates *)
   411 
   412 fun p orf q = fn x => p x orelse q x;
   413 fun p andf q = fn x => p x andalso q x;
   414 
   415 
   416 (* predicates on lists *)
   417 
   418 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   419 fun exists (pred: 'a -> bool) : 'a list -> bool =
   420   let fun boolf [] = false
   421         | boolf (x :: xs) = pred x orelse boolf xs
   422   in boolf end;
   423 
   424 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   425 fun forall (pred: 'a -> bool) : 'a list -> bool =
   426   let fun boolf [] = true
   427         | boolf (x :: xs) = pred x andalso boolf xs
   428   in boolf end;
   429 
   430 
   431 (* flags *)
   432 
   433 fun set flag = (flag := true; true);
   434 fun reset flag = (flag := false; false);
   435 fun toggle flag = (flag := not (! flag); ! flag);
   436 
   437 fun change r f = r := f (! r);
   438 
   439 (*temporarily set flag, handling exceptions*)
   440 fun setmp flag value f x =
   441   let
   442     val orig_value = ! flag;
   443     fun return y = (flag := orig_value; y);
   444   in
   445     flag := value;
   446     return (f x handle exn => (return (); raise exn))
   447   end;
   448 
   449 
   450 (* conditional execution *)
   451 
   452 fun conditional b f = if b then f () else ();
   453 
   454 
   455 
   456 (** lists **)
   457 
   458 exception UnequalLengths;
   459 
   460 fun cons x xs = x :: xs;
   461 fun single x = [x];
   462 
   463 fun append xs ys = xs @ ys;
   464 
   465 fun apply [] x = x
   466   | apply (f :: fs) x = apply fs (f x);
   467 
   468 
   469 (* fold *)
   470 
   471 fun fold f =
   472   let
   473     fun fold_aux [] y = y
   474       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   475   in fold_aux end;
   476 
   477 fun fold_rev f =
   478   let
   479     fun fold_aux [] y = y
   480       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   481   in fold_aux end;
   482 
   483 fun fold_map f =
   484   let
   485     fun fold_aux [] y = ([], y)
   486       | fold_aux (x :: xs) y =
   487           let
   488             val (x', y') = f x y;
   489             val (xs', y'') = fold_aux xs y';
   490           in (x' :: xs', y'') end;
   491   in fold_aux end;
   492 
   493 (*the following versions of fold are designed to fit nicely with infixes*)
   494 
   495 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   496     for operators that associate to the left (TAIL RECURSIVE)*)
   497 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   498   let fun itl (e, [])  = e
   499         | itl (e, a::l) = itl (f(e, a), l)
   500   in  itl end;
   501 
   502 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   503     for operators that associate to the right (not tail recursive)*)
   504 fun foldr f (l, e) =
   505   let fun itr [] = e
   506         | itr (a::l) = f(a, itr l)
   507   in  itr l  end;
   508 
   509 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   510     for n > 0, operators that associate to the right (not tail recursive)*)
   511 fun foldr1 f l =
   512   let fun itr [x] = x
   513         | itr (x::l) = f(x, itr l)
   514   in  itr l  end;
   515 
   516 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   517 
   518 fun foldl_map f =
   519   let
   520     fun fold_aux (x, []) = (x, [])
   521       | fold_aux (x, y :: ys) =
   522           let
   523             val (x', y') = f (x, y);
   524             val (x'', ys') = fold_aux (x', ys);
   525           in (x'', y' :: ys') end;
   526   in fold_aux end;
   527 
   528 
   529 (* basic list functions *)
   530 
   531 (*take the first n elements from a list*)
   532 fun take (n, []) = []
   533   | take (n, x :: xs) =
   534       if n > 0 then x :: take (n - 1, xs) else [];
   535 
   536 (*drop the first n elements from a list*)
   537 fun drop (n, []) = []
   538   | drop (n, x :: xs) =
   539       if n > 0 then drop (n - 1, xs) else x :: xs;
   540 
   541 fun splitAt(n,[]) = ([],[])
   542   | splitAt(n,xs as x::ys) =
   543       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   544       else ([],xs)
   545 
   546 fun dropwhile P [] = []
   547   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   548 
   549 (*return nth element of a list, where 0 designates the first element;
   550   raise EXCEPTION if list too short*)
   551 fun nth_elem (i,xs) = List.nth(xs,i);
   552 
   553 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   554   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   555   | map_nth_elem _ _ [] = raise Subscript;
   556 
   557 (*last element of a list*)
   558 val last_elem = List.last;
   559 
   560 (*rear decomposition*)
   561 fun split_last [] = raise Empty
   562   | split_last [x] = ([], x)
   563   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   564 
   565 (*update nth element*)
   566 fun nth_update x n_xs =
   567     (case splitAt n_xs of
   568       (_,[]) => raise Subscript
   569     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   570 
   571 (*find the position of an element in a list*)
   572 fun find_index pred =
   573   let fun find _ [] = ~1
   574         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   575   in find 0 end;
   576 
   577 fun find_index_eq x = find_index (equal x);
   578 
   579 (*find first element satisfying predicate*)
   580 fun find_first _ [] = NONE
   581   | find_first pred (x :: xs) =
   582       if pred x then SOME x else find_first pred xs;
   583 
   584 (*get first element by lookup function*)
   585 fun get_first _ [] = NONE
   586   | get_first f (x :: xs) =
   587       (case f x of
   588         NONE => get_first f xs
   589       | some => some);
   590 
   591 (*flatten a list of lists to a list*)
   592 val flat = List.concat;
   593 
   594 fun unflat (xs :: xss) ys =
   595       let val (ps,qs) = splitAt(length xs,ys)
   596       in ps :: unflat xss qs end
   597   | unflat [] [] = []
   598   | unflat _ _ = raise UnequalLengths;
   599 
   600 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   601   (proc x1; ...; proc xn) for side effects*)
   602 val seq = List.app;
   603 
   604 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   605 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   606   | separate _ xs = xs;
   607 
   608 (*make the list [x, x, ..., x] of length n*)
   609 fun replicate n (x: 'a) : 'a list =
   610   let fun rep (0, xs) = xs
   611         | rep (n, xs) = rep (n - 1, x :: xs)
   612   in
   613     if n < 0 then raise Subscript
   614     else rep (n, [])
   615   end;
   616 
   617 fun translate_string f = String.translate (f o String.str);
   618 
   619 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   620 fun multiply ([], _) = []
   621   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   622 
   623 (*direct product*)
   624 fun product _ [] = []
   625   | product [] _ = []
   626   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   627 
   628 
   629 (* filter *)
   630 
   631 (*copy the list preserving elements that satisfy the predicate*)
   632 val filter = List.filter;
   633 fun filter_out f = filter (not o f);
   634 val mapfilter = List.mapPartial;
   635 
   636 
   637 (* lists of pairs *)
   638 
   639 exception UnequalLengths;
   640 
   641 fun map2 _ ([], []) = []
   642   | map2 f (x :: xs, y :: ys) = f (x, y) :: map2 f (xs, ys)
   643   | map2 _ _ = raise UnequalLengths;
   644 
   645 fun exists2 _ ([], []) = false
   646   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   647   | exists2 _ _ = raise UnequalLengths;
   648 
   649 fun forall2 _ ([], []) = true
   650   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   651   | forall2 _ _ = raise UnequalLengths;
   652 
   653 fun seq2 _ ([], []) = ()
   654   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   655   | seq2 _ _ = raise UnequalLengths;
   656 
   657 (*combine two lists forming a list of pairs:
   658   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   659 fun [] ~~ [] = []
   660   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   661   | _ ~~ _ = raise UnequalLengths;
   662 
   663 (*inverse of ~~; the old 'split':
   664   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   665 val split_list = ListPair.unzip;
   666 
   667 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   668 
   669 
   670 (* prefixes, suffixes *)
   671 
   672 fun [] prefix _ = true
   673   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   674   | _ prefix _ = false;
   675 
   676 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   677    where xi is the first element that does not satisfy the predicate*)
   678 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   679   let fun take (rxs, []) = (rev rxs, [])
   680         | take (rxs, x :: xs) =
   681             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   682   in  take([], xs)  end;
   683 
   684 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   685    where xi is the last element that does not satisfy the predicate*)
   686 fun take_suffix _ [] = ([], [])
   687   | take_suffix pred (x :: xs) =
   688       (case take_suffix pred xs of
   689         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   690       | (prfx, sffx) => (x :: prfx, sffx));
   691 
   692 fun prefixes1 [] = []
   693   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   694 
   695 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   696 
   697 
   698 
   699 (** integers **)
   700 
   701 fun gcd (x, y) =
   702   let fun gxd x y : IntInf.int =
   703     if y = 0 then x else gxd y (x mod y)
   704   in if x < y then gxd y x else gxd x y end;
   705 
   706 fun lcm (x, y) = (x * y) div gcd (x, y);
   707 
   708 fun inc i = (i := ! i + 1; ! i);
   709 fun dec i = (i := ! i - 1; ! i);
   710 
   711 
   712 (* lists of integers *)
   713 
   714 (*make the list [from, from + 1, ..., to]*)
   715 fun (from upto to) =
   716   if from > to then [] else from :: ((from + 1) upto to);
   717 
   718 (*make the list [from, from - 1, ..., to]*)
   719 fun (from downto to) =
   720   if from < to then [] else from :: ((from - 1) downto to);
   721 
   722 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   723 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   724   | downto0 ([], n) = n = ~1;
   725 
   726 
   727 (* convert integers to strings *)
   728 
   729 (*expand the number in the given base;
   730   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   731 fun radixpand (base, num) : int list =
   732   let
   733     fun radix (n, tail) =
   734       if n < base then n :: tail
   735       else radix (n div base, (n mod base) :: tail)
   736   in radix (num, []) end;
   737 
   738 (*expands a number into a string of characters starting from "zerochar";
   739   example: radixstring (2, "0", 8) gives "1000"*)
   740 fun radixstring (base, zerochar, num) =
   741   let val offset = ord zerochar;
   742       fun chrof n = chr (offset + n)
   743   in implode (map chrof (radixpand (base, num))) end;
   744 
   745 
   746 val string_of_int = Int.toString;
   747 
   748 fun string_of_indexname (a,0) = a
   749   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   750 
   751 
   752 (* read integers *)
   753 
   754 fun read_radixint (radix: int, cs) : int * string list =
   755   let val zero = ord"0"
   756       val limit = zero+radix
   757       fun scan (num,[]) = (num,[])
   758         | scan (num, c::cs) =
   759               if  zero <= ord c  andalso  ord c < limit
   760               then scan(radix*num + ord c - zero, cs)
   761               else (num, c::cs)
   762   in  scan(0,cs)  end;
   763 
   764 fun read_int cs = read_radixint (10, cs);
   765 
   766 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   767 
   768 
   769 
   770 (** strings **)
   771 
   772 (* functions tuned for strings, avoiding explode *)
   773 
   774 fun nth_elem_string (i, str) =
   775   (case try String.substring (str, i, 1) of
   776     SOME s => s
   777   | NONE => raise Subscript);
   778 
   779 fun fold_string f str x0 =
   780   let
   781     val n = size str;
   782     fun iter (x, i) =
   783       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   784   in iter (x0, 0) end;
   785 
   786 fun exists_string pred str =
   787   let
   788     val n = size str;
   789     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   790   in ex 0 end;
   791 
   792 fun forall_string pred = not o exists_string (not o pred);
   793 
   794 (*enclose in brackets*)
   795 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   796 fun unenclose str = String.substring (str, 1, size str - 2);
   797 
   798 (*simple quoting (does not escape special chars)*)
   799 val quote = enclose "\"" "\"";
   800 
   801 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   802 fun space_implode a bs = implode (separate a bs);
   803 
   804 val commas = space_implode ", ";
   805 val commas_quote = commas o map quote;
   806 
   807 (*concatenate messages, one per line, into a string*)
   808 val cat_lines = space_implode "\n";
   809 
   810 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   811 fun space_explode _ "" = []
   812   | space_explode sep str =
   813       let
   814         fun expl chs =
   815           (case take_prefix (not_equal sep) chs of
   816             (cs, []) => [implode cs]
   817           | (cs, _ :: cs') => implode cs :: expl cs');
   818       in expl (explode str) end;
   819 
   820 val split_lines = space_explode "\n";
   821 
   822 fun prefix_lines "" txt = txt
   823   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   824 
   825 fun untabify chs =
   826   let
   827     val tab_width = 8;
   828 
   829     fun untab (_, "\n") = (0, ["\n"])
   830       | untab (pos, "\t") =
   831           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   832       | untab (pos, c) = (pos + 1, [c]);
   833   in
   834     if not (exists (equal "\t") chs) then chs
   835     else flat (#2 (foldl_map untab (0, chs)))
   836   end;
   837 
   838 fun suffix sffx s = s ^ sffx;
   839 
   840 fun unsuffix sffx s =
   841   let val m = size sffx; val n = size s - m in
   842     if n >= 0 andalso String.substring (s, n, m) = sffx then String.substring (s, 0, n)
   843     else raise Fail "unsuffix"
   844   end;
   845 
   846 fun unprefix prfx s =
   847   let val m = size prfx; val n = size s - m in
   848     if String.isPrefix prfx s then String.substring (s, m, n)
   849     else raise Fail "unprefix"
   850   end;
   851 
   852 fun replicate_string 0 _ = ""
   853   | replicate_string 1 a = a
   854   | replicate_string k a =
   855       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   856       else replicate_string (k div 2) (a ^ a) ^ a;
   857 
   858 
   859 
   860 (** lists as sets -- see also Pure/General/ord_list.ML **)
   861 
   862 (*membership in a list*)
   863 fun x mem [] = false
   864   | x mem (y :: ys) = x = y orelse x mem ys;
   865 
   866 (*membership in a list, optimized version for ints*)
   867 fun (x:int) mem_int [] = false
   868   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   869 
   870 (*membership in a list, optimized version for strings*)
   871 fun (x:string) mem_string [] = false
   872   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   873 
   874 (*generalized membership test*)
   875 fun gen_mem eq (x, []) = false
   876   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   877 
   878 (*member, insert, and remove -- with canonical argument order*)
   879 fun member eq xs x = gen_mem eq (x, xs);
   880 fun insert eq x xs = if gen_mem eq (x, xs) then xs else x :: xs;
   881 fun remove eq x xs = if gen_mem eq (x, xs) then filter_out (fn y => eq (x, y)) xs else xs;
   882 
   883 (*insertion into list if not already there*)
   884 fun (x ins xs) = if x mem xs then xs else x :: xs;
   885 
   886 (*insertion into list, optimized version for ints*)
   887 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   888 
   889 (*insertion into list, optimized version for strings*)
   890 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   891 
   892 (*generalized insertion*)
   893 fun gen_ins eq (x, xs) = insert eq x xs;
   894 
   895 (*union of sets represented as lists: no repetitions*)
   896 fun xs union [] = xs
   897   | [] union ys = ys
   898   | (x :: xs) union ys = xs union (x ins ys);
   899 
   900 (*union of sets, optimized version for ints*)
   901 fun (xs:int list) union_int [] = xs
   902   | [] union_int ys = ys
   903   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   904 
   905 (*union of sets, optimized version for strings*)
   906 fun (xs:string list) union_string [] = xs
   907   | [] union_string ys = ys
   908   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   909 
   910 (*generalized union*)
   911 fun gen_union eq (xs, []) = xs
   912   | gen_union eq ([], ys) = ys
   913   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   914 
   915 
   916 (*intersection*)
   917 fun [] inter ys = []
   918   | (x :: xs) inter ys =
   919       if x mem ys then x :: (xs inter ys) else xs inter ys;
   920 
   921 (*intersection, optimized version for ints*)
   922 fun ([]:int list) inter_int ys = []
   923   | (x :: xs) inter_int ys =
   924       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   925 
   926 (*intersection, optimized version for strings *)
   927 fun ([]:string list) inter_string ys = []
   928   | (x :: xs) inter_string ys =
   929       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   930 
   931 (*generalized intersection*)
   932 fun gen_inter eq ([], ys) = []
   933   | gen_inter eq (x::xs, ys) =
   934       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   935                            else      gen_inter eq (xs, ys);
   936 
   937 
   938 (*subset*)
   939 fun [] subset ys = true
   940   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   941 
   942 (*subset, optimized version for ints*)
   943 fun ([]: int list) subset_int ys = true
   944   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   945 
   946 (*subset, optimized version for strings*)
   947 fun ([]: string list) subset_string ys = true
   948   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   949 
   950 (*set equality*)
   951 fun eq_set (xs, ys) =
   952   xs = ys orelse (xs subset ys andalso ys subset xs);
   953 
   954 (*set equality for strings*)
   955 fun eq_set_string ((xs: string list), ys) =
   956   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   957 
   958 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   959 
   960 
   961 (*removing an element from a list WITHOUT duplicates*)
   962 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   963   | [] \ x = [];
   964 
   965 fun ys \\ xs = foldl (op \) (ys,xs);
   966 
   967 (*removing an element from a list -- possibly WITH duplicates*)
   968 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   969 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   970 
   971 (*makes a list of the distinct members of the input; preserves order, takes
   972   first of equal elements*)
   973 fun gen_distinct eq lst =
   974   let
   975     val memb = gen_mem eq;
   976 
   977     fun dist (rev_seen, []) = rev rev_seen
   978       | dist (rev_seen, x :: xs) =
   979           if memb (x, rev_seen) then dist (rev_seen, xs)
   980           else dist (x :: rev_seen, xs);
   981   in
   982     dist ([], lst)
   983   end;
   984 
   985 fun distinct l = gen_distinct (op =) l;
   986 
   987 (*returns the tail beginning with the first repeated element, or []*)
   988 fun findrep [] = []
   989   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   990 
   991 
   992 (*returns a list containing all repeated elements exactly once; preserves
   993   order, takes first of equal elements*)
   994 fun gen_duplicates eq lst =
   995   let
   996     val memb = gen_mem eq;
   997 
   998     fun dups (rev_dups, []) = rev rev_dups
   999       | dups (rev_dups, x :: xs) =
  1000           if memb (x, rev_dups) orelse not (memb (x, xs)) then
  1001             dups (rev_dups, xs)
  1002           else dups (x :: rev_dups, xs);
  1003   in
  1004     dups ([], lst)
  1005   end;
  1006 
  1007 fun duplicates l = gen_duplicates (op =) l;
  1008 
  1009 fun has_duplicates eq =
  1010   let
  1011     fun dups [] = false
  1012       | dups (x :: xs) = member eq xs x orelse dups xs;
  1013   in dups end;
  1014 
  1015 
  1016 
  1017 (** association lists **)
  1018 
  1019 (*association list lookup*)
  1020 fun assoc ([], key) = NONE
  1021   | assoc ((keyi, xi) :: pairs, key) =
  1022       if key = keyi then SOME xi else assoc (pairs, key);
  1023 
  1024 (*association list lookup, optimized version for ints*)
  1025 fun assoc_int ([], (key:int)) = NONE
  1026   | assoc_int ((keyi, xi) :: pairs, key) =
  1027       if key = keyi then SOME xi else assoc_int (pairs, key);
  1028 
  1029 (*association list lookup, optimized version for strings*)
  1030 fun assoc_string ([], (key:string)) = NONE
  1031   | assoc_string ((keyi, xi) :: pairs, key) =
  1032       if key = keyi then SOME xi else assoc_string (pairs, key);
  1033 
  1034 (*association list lookup, optimized version for string*ints*)
  1035 fun assoc_string_int ([], (key:string*int)) = NONE
  1036   | assoc_string_int ((keyi, xi) :: pairs, key) =
  1037       if key = keyi then SOME xi else assoc_string_int (pairs, key);
  1038 
  1039 fun assocs ps x =
  1040   (case assoc (ps, x) of
  1041     NONE => []
  1042   | SOME ys => ys);
  1043 
  1044 (*two-fold association list lookup*)
  1045 fun assoc2 (aal, (key1, key2)) =
  1046   (case assoc (aal, key1) of
  1047     SOME al => assoc (al, key2)
  1048   | NONE => NONE);
  1049 
  1050 (*generalized association list lookup*)
  1051 fun gen_assoc eq ([], key) = NONE
  1052   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1053       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1054 
  1055 (*association list update*)
  1056 fun overwrite (al, p as (key, _)) =
  1057   let fun over ((q as (keyi, _)) :: pairs) =
  1058             if keyi = key then p :: pairs else q :: (over pairs)
  1059         | over [] = [p]
  1060   in over al end;
  1061 
  1062 fun gen_overwrite eq (al, p as (key, _)) =
  1063   let fun over ((q as (keyi, _)) :: pairs) =
  1064             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1065         | over [] = [p]
  1066   in over al end;
  1067 
  1068 
  1069 (* lists as tables *)
  1070 
  1071 fun gen_merge_lists _ xs [] = xs
  1072   | gen_merge_lists _ [] ys = ys
  1073   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1074 
  1075 fun gen_merge_lists' _ xs [] = xs
  1076   | gen_merge_lists' _ [] ys = ys
  1077   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1078 
  1079 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1080 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1081 fun merge_alists al = gen_merge_lists eq_fst al;
  1082 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1083 
  1084 
  1085 
  1086 (** balanced trees **)
  1087 
  1088 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1089 
  1090 (*balanced folding; avoids deep nesting*)
  1091 fun fold_bal f [x] = x
  1092   | fold_bal f [] = raise Balance
  1093   | fold_bal f xs =
  1094       let val (ps,qs) = splitAt(length xs div 2, xs)
  1095       in  f (fold_bal f ps, fold_bal f qs)  end;
  1096 
  1097 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1098 fun access_bal (f, g, x) n i =
  1099   let fun acc n i =     (*1<=i<=n*)
  1100           if n=1 then x else
  1101           let val n2 = n div 2
  1102           in  if i<=n2 then f (acc n2 i)
  1103                        else g (acc (n-n2) (i-n2))
  1104           end
  1105   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1106 
  1107 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1108 fun accesses_bal (f, g, x) n =
  1109   let fun acc n =
  1110           if n=1 then [x] else
  1111           let val n2 = n div 2
  1112               val acc2 = acc n2
  1113           in  if n-n2=n2 then map f acc2 @ map g acc2
  1114                          else map f acc2 @ map g (acc (n-n2)) end
  1115   in  if 1<=n then acc n else raise Balance  end;
  1116 
  1117 
  1118 
  1119 (** orders **)
  1120 
  1121 fun rev_order LESS = GREATER
  1122   | rev_order EQUAL = EQUAL
  1123   | rev_order GREATER = LESS;
  1124 
  1125 (*assume rel is a linear strict order*)
  1126 fun make_ord rel (x, y) =
  1127   if rel (x, y) then LESS
  1128   else if rel (y, x) then GREATER
  1129   else EQUAL;
  1130 
  1131 val int_ord = Int.compare;
  1132 val string_ord = String.compare;
  1133 
  1134 fun fast_string_ord (s1, s2) =
  1135   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1136 
  1137 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1138   | option_ord _ (NONE, NONE) = EQUAL
  1139   | option_ord _ (NONE, SOME _) = LESS
  1140   | option_ord _ (SOME _, NONE) = GREATER;
  1141 
  1142 (*lexicographic product*)
  1143 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1144   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1145 
  1146 (*dictionary order -- in general NOT well-founded!*)
  1147 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1148       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1149   | dict_ord _ ([], []) = EQUAL
  1150   | dict_ord _ ([], _ :: _) = LESS
  1151   | dict_ord _ (_ :: _, []) = GREATER;
  1152 
  1153 (*lexicographic product of lists*)
  1154 fun list_ord elem_ord (xs, ys) =
  1155   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1156 
  1157 
  1158 (* sorting *)
  1159 
  1160 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1161 fun sort ord =
  1162   let
  1163     fun qsort [] = []
  1164       | qsort (xs as [_]) = xs
  1165       | qsort (xs as [x, y]) = if ord (x, y) = GREATER then [y, x] else xs
  1166       | qsort xs =
  1167           let val (lts, eqs, gts) = part (nth_elem (length xs div 2, xs)) xs
  1168           in qsort lts @ eqs @ qsort gts end
  1169     and part _ [] = ([], [], [])
  1170       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1171     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1172       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1173       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1174   in qsort end;
  1175 
  1176 (*sort strings*)
  1177 val sort_strings = sort string_ord;
  1178 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1179 
  1180 fun unique_strings ([]: string list) = []
  1181   | unique_strings [x] = [x]
  1182   | unique_strings (x :: y :: ys) =
  1183       if x = y then unique_strings (y :: ys)
  1184       else x :: unique_strings (y :: ys);
  1185 
  1186 
  1187 (** random numbers **)
  1188 
  1189 exception RANDOM;
  1190 
  1191 fun rmod x y = x - y * Real.realFloor (x / y);
  1192 
  1193 local
  1194   val a = 16807.0;
  1195   val m = 2147483647.0;
  1196   val random_seed = ref 1.0;
  1197 in
  1198 
  1199 fun random () =
  1200   let val r = rmod (a * !random_seed) m
  1201   in (random_seed := r; r) end;
  1202 
  1203 end;
  1204 
  1205 fun random_range l h =
  1206   if h < l orelse l < 0 then raise RANDOM
  1207   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1208 
  1209 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1210 
  1211 fun frequency xs =
  1212   let
  1213     val sum = foldl op + (0, map fst xs);
  1214     fun pick n ((k, x) :: xs) =
  1215       if n <= k then x else pick (n - k) xs
  1216   in pick (random_range 1 sum) xs end;
  1217 
  1218 
  1219 (** current directory **)
  1220 
  1221 val cd = OS.FileSys.chDir;
  1222 val pwd = OS.FileSys.getDir;
  1223 
  1224 
  1225 
  1226 (** rational numbers **)
  1227 
  1228 datatype rat = Rat of bool * IntInf.int * IntInf.int
  1229 
  1230 exception RAT of string;
  1231 
  1232 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1233 
  1234 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1235   let val absp = abs p
  1236       val m = gcd(absp,q)
  1237   in Rat(a = (0 <= p), absp div m, q div m) end;
  1238 
  1239 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1240   let val den = lcm(q,s)
  1241       val p = p*(den div q) and r = r*(den div s)
  1242       val num = (if a then p else ~p) + (if b then r else ~r)
  1243   in ratnorm(true,num,den) end;
  1244 
  1245 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1246 
  1247 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1248 
  1249 fun int_ratdiv(p,q) =
  1250   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1251 
  1252 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1253 
  1254 fun rat_of_intinf i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1255 
  1256 fun rat_of_int i = rat_of_intinf (IntInf.fromInt i);
  1257 
  1258 
  1259 (** misc **)
  1260 
  1261 (*use the keyfun to make a list of (x, key) pairs*)
  1262 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1263   let fun keypair x = (x, keyfun x)
  1264   in map keypair end;
  1265 
  1266 (*given a list of (x, key) pairs and a searchkey
  1267   return the list of xs from each pair whose key equals searchkey*)
  1268 fun keyfilter [] searchkey = []
  1269   | keyfilter ((x, key) :: pairs) searchkey =
  1270       if key = searchkey then x :: keyfilter pairs searchkey
  1271       else keyfilter pairs searchkey;
  1272 
  1273 
  1274 (*Partition list into elements that satisfy predicate and those that don't.
  1275   Preserves order of elements in both lists.*)
  1276 val partition = List.partition;
  1277 
  1278 fun partition_eq (eq:'a * 'a -> bool) =
  1279   let
  1280     fun part [] = []
  1281       | part (x :: ys) =
  1282           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1283           in (x::xs)::(part xs') end
  1284   in part end;
  1285 
  1286 
  1287 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1288    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1289 fun partition_list p i j =
  1290   let fun part k xs =
  1291             if k>j then
  1292               (case xs of [] => []
  1293                          | _ => raise Fail "partition_list")
  1294             else
  1295             let val (ns, rest) = partition (p k) xs;
  1296             in  ns :: part(k+1)rest  end
  1297   in  part i end;
  1298 
  1299 
  1300 (* generating identifiers *)
  1301 
  1302 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1303 local
  1304 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1305 fun char i =      if i<26 then chr (ord "A" + i)
  1306              else if i<52 then chr (ord "a" + i - 26)
  1307              else if i<62 then chr (ord"0" + i - 52)
  1308              else if i=62 then "_"
  1309              else  (*i=63*)    "'";
  1310 
  1311 val charVec = Vector.tabulate (64, char);
  1312 
  1313 fun newid n =
  1314   let
  1315   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1316 
  1317 val seedr = ref 0;
  1318 
  1319 in
  1320 
  1321 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1322 
  1323 end;
  1324 
  1325 
  1326 (* lexical scanning *)
  1327 
  1328 (*scan a list of characters into "words" composed of "letters" (recognized by
  1329   is_let) and separated by any number of non-"letters"*)
  1330 fun scanwords is_let cs =
  1331   let fun scan1 [] = []
  1332         | scan1 cs =
  1333             let val (lets, rest) = take_prefix is_let cs
  1334             in implode lets :: scanwords is_let rest end;
  1335   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1336 
  1337 
  1338 (* stamps and serial numbers *)
  1339 
  1340 type stamp = unit ref;
  1341 val stamp: unit -> stamp = ref;
  1342 
  1343 type serial = int;
  1344 local val count = ref 0
  1345 in fun serial () = inc count end;
  1346 
  1347 
  1348 (* generic objects *)
  1349 
  1350 (*note that the builtin exception datatype may be extended by new
  1351   constructors at any time*)
  1352 structure Object = struct type T = exn end;
  1353 
  1354 end;
  1355 
  1356 structure BasicLibrary: BASIC_LIBRARY = Library;
  1357 open BasicLibrary;