src/Pure/simplifier.ML
author wenzelm
Sat Jan 14 22:25:34 2006 +0100 (2006-01-14)
changeset 18688 abf0f018b5ec
parent 18629 bdf01da93ed4
child 18708 4b3dadb4fe33
permissions -rw-r--r--
generic attributes;
     1 (*  Title:      Pure/simplifier.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Markus Wenzel, TU Muenchen
     4 
     5 Generic simplifier, suitable for most logics (see also
     6 meta_simplifier.ML for the actual meta-level rewriting engine).
     7 *)
     8 
     9 signature BASIC_SIMPLIFIER =
    10 sig
    11   include BASIC_META_SIMPLIFIER
    12   val print_simpset: theory -> unit
    13   val change_simpset_of: theory -> (simpset -> simpset) -> unit
    14   val change_simpset: (simpset -> simpset) -> unit
    15   val simpset_of: theory -> simpset
    16   val simpset: unit -> simpset
    17   val SIMPSET: (simpset -> tactic) -> tactic
    18   val SIMPSET': (simpset -> 'a -> tactic) -> 'a -> tactic
    19   val Addsimps: thm list -> unit
    20   val Delsimps: thm list -> unit
    21   val Addsimprocs: simproc list -> unit
    22   val Delsimprocs: simproc list -> unit
    23   val Addcongs: thm list -> unit
    24   val Delcongs: thm list -> unit
    25   val local_simpset_of: Proof.context -> simpset
    26   val generic_simp_tac: bool -> bool * bool * bool -> simpset -> int -> tactic
    27   val safe_asm_full_simp_tac: simpset -> int -> tactic
    28   val               simp_tac: simpset -> int -> tactic
    29   val           asm_simp_tac: simpset -> int -> tactic
    30   val          full_simp_tac: simpset -> int -> tactic
    31   val        asm_lr_simp_tac: simpset -> int -> tactic
    32   val      asm_full_simp_tac: simpset -> int -> tactic
    33   val               Simp_tac:            int -> tactic
    34   val           Asm_simp_tac:            int -> tactic
    35   val          Full_simp_tac:            int -> tactic
    36   val        Asm_lr_simp_tac:            int -> tactic
    37   val      Asm_full_simp_tac:            int -> tactic
    38   val          simplify: simpset -> thm -> thm
    39   val      asm_simplify: simpset -> thm -> thm
    40   val     full_simplify: simpset -> thm -> thm
    41   val   asm_lr_simplify: simpset -> thm -> thm
    42   val asm_full_simplify: simpset -> thm -> thm
    43 end;
    44 
    45 signature SIMPLIFIER =
    46 sig
    47   include BASIC_SIMPLIFIER
    48   val clear_ss: simpset -> simpset
    49   val debug_bounds: bool ref
    50   val inherit_context: simpset -> simpset -> simpset
    51   val the_context: simpset -> Proof.context
    52   val context: Proof.context -> simpset -> simpset
    53   val theory_context: theory  -> simpset -> simpset
    54   val simproc_i: theory -> string -> term list
    55     -> (theory -> simpset -> term -> thm option) -> simproc
    56   val simproc: theory -> string -> string list
    57     -> (theory -> simpset -> term -> thm option) -> simproc
    58   val          rewrite: simpset -> cterm -> thm
    59   val      asm_rewrite: simpset -> cterm -> thm
    60   val     full_rewrite: simpset -> cterm -> thm
    61   val   asm_lr_rewrite: simpset -> cterm -> thm
    62   val asm_full_rewrite: simpset -> cterm -> thm
    63   val get_simpset: theory -> simpset
    64   val print_local_simpset: Proof.context -> unit
    65   val get_local_simpset: Proof.context -> simpset
    66   val put_local_simpset: simpset -> Proof.context -> Proof.context
    67   val attrib: (simpset * thm list -> simpset) -> Context.generic attribute
    68   val simp_add: Context.generic attribute
    69   val simp_del: Context.generic attribute
    70   val cong_add: Context.generic attribute
    71   val cong_del: Context.generic attribute
    72   val cong_modifiers: (Args.T list -> (Method.modifier * Args.T list)) list
    73   val simp_modifiers': (Args.T list -> (Method.modifier * Args.T list)) list
    74   val simp_modifiers: (Args.T list -> (Method.modifier * Args.T list)) list
    75   val method_setup: (Args.T list -> (Method.modifier * Args.T list)) list
    76     -> (theory -> theory) list
    77   val easy_setup: thm -> thm list -> (theory -> theory) list
    78 end;
    79 
    80 structure Simplifier: SIMPLIFIER =
    81 struct
    82 
    83 (** simpset data **)
    84 
    85 (* global simpsets *)
    86 
    87 structure GlobalSimpset = TheoryDataFun
    88 (struct
    89   val name = "Pure/simpset";
    90   type T = simpset ref;
    91 
    92   val empty = ref empty_ss;
    93   fun copy (ref ss) = ref ss: T;            (*create new reference!*)
    94   fun extend (ref ss) = ref (MetaSimplifier.inherit_context empty_ss ss);
    95   fun merge _ (ref ss1, ref ss2) = ref (merge_ss (ss1, ss2));
    96   fun print _ (ref ss) = print_ss ss;
    97 end);
    98 
    99 val _ = Context.add_setup [GlobalSimpset.init];
   100 val print_simpset = GlobalSimpset.print;
   101 val get_simpset = ! o GlobalSimpset.get;
   102 
   103 val change_simpset_of = change o GlobalSimpset.get;
   104 fun change_simpset f = change_simpset_of (Context.the_context ()) f;
   105 
   106 fun simpset_of thy = MetaSimplifier.context (ProofContext.init thy) (get_simpset thy);
   107 val simpset = simpset_of o Context.the_context;
   108 
   109 
   110 fun SIMPSET tacf st = tacf (simpset_of (Thm.theory_of_thm st)) st;
   111 fun SIMPSET' tacf i st = tacf (simpset_of (Thm.theory_of_thm st)) i st;
   112 
   113 fun Addsimps args = change_simpset (fn ss => ss addsimps args);
   114 fun Delsimps args = change_simpset (fn ss => ss delsimps args);
   115 fun Addsimprocs args = change_simpset (fn ss => ss addsimprocs args);
   116 fun Delsimprocs args = change_simpset (fn ss => ss delsimprocs args);
   117 fun Addcongs args = change_simpset (fn ss => ss addcongs args);
   118 fun Delcongs args = change_simpset (fn ss => ss delcongs args);
   119 
   120 
   121 (* local simpsets *)
   122 
   123 structure LocalSimpset = ProofDataFun
   124 (struct
   125   val name = "Pure/simpset";
   126   type T = simpset;
   127   val init = get_simpset;
   128   fun print _ ss = print_ss ss;
   129 end);
   130 
   131 val _ = Context.add_setup [LocalSimpset.init];
   132 val print_local_simpset = LocalSimpset.print;
   133 val get_local_simpset = LocalSimpset.get;
   134 val put_local_simpset = LocalSimpset.put;
   135 
   136 fun local_simpset_of ctxt = MetaSimplifier.context ctxt (get_local_simpset ctxt);
   137 
   138 
   139 (* attributes *)
   140 
   141 fun attrib f = Attrib.declaration (fn th =>
   142    fn Context.Theory thy => (change_simpset_of thy (fn ss => f (ss, [th])); Context.Theory thy)
   143     | Context.Proof ctxt => Context.Proof (LocalSimpset.map (fn ss => f (ss, [th])) ctxt));
   144 
   145 val simp_add = attrib (op addsimps);
   146 val simp_del = attrib (op delsimps);
   147 val cong_add = attrib (op addcongs);
   148 val cong_del = attrib (op delcongs);
   149 
   150 
   151 
   152 (** simplification tactics and rules **)
   153 
   154 fun solve_all_tac solvers ss =
   155   let
   156     val (_, {subgoal_tac, ...}) = MetaSimplifier.rep_ss ss;
   157     val solve_tac = subgoal_tac (MetaSimplifier.set_solvers solvers ss) THEN_ALL_NEW (K no_tac);
   158   in DEPTH_SOLVE (solve_tac 1) end;
   159 
   160 (*NOTE: may instantiate unknowns that appear also in other subgoals*)
   161 fun generic_simp_tac safe mode ss =
   162   let
   163     val (_, {loop_tacs, solvers = (unsafe_solvers, solvers), ...}) = MetaSimplifier.rep_ss ss;
   164     val loop_tac = FIRST' (map (fn (_, tac) => tac ss) loop_tacs);
   165     val solve_tac = FIRST' (map (MetaSimplifier.solver ss)
   166       (if safe then solvers else unsafe_solvers));
   167 
   168     fun simp_loop_tac i =
   169       asm_rewrite_goal_tac mode (solve_all_tac unsafe_solvers) ss i THEN
   170       (solve_tac i ORELSE TRY ((loop_tac THEN_ALL_NEW simp_loop_tac) i));
   171   in simp_loop_tac end;
   172 
   173 local
   174 
   175 fun simp rew mode ss thm =
   176   let
   177     val (_, {solvers = (unsafe_solvers, _), ...}) = MetaSimplifier.rep_ss ss;
   178     val tacf = solve_all_tac unsafe_solvers;
   179     fun prover s th = Option.map #1 (Seq.pull (tacf s th));
   180   in rew mode prover ss thm end;
   181 
   182 in
   183 
   184 val simp_thm = simp MetaSimplifier.rewrite_thm;
   185 val simp_cterm = simp MetaSimplifier.rewrite_cterm;
   186 
   187 end;
   188 
   189 
   190 (* tactics *)
   191 
   192 val simp_tac = generic_simp_tac false (false, false, false);
   193 val asm_simp_tac = generic_simp_tac false (false, true, false);
   194 val full_simp_tac = generic_simp_tac false (true, false, false);
   195 val asm_lr_simp_tac = generic_simp_tac false (true, true, false);
   196 val asm_full_simp_tac = generic_simp_tac false (true, true, true);
   197 val safe_asm_full_simp_tac = generic_simp_tac true (true, true, true);
   198 
   199 (*the abstraction over the proof state delays the dereferencing*)
   200 fun          Simp_tac i st =          simp_tac (simpset ()) i st;
   201 fun      Asm_simp_tac i st =      asm_simp_tac (simpset ()) i st;
   202 fun     Full_simp_tac i st =     full_simp_tac (simpset ()) i st;
   203 fun   Asm_lr_simp_tac i st =   asm_lr_simp_tac (simpset ()) i st;
   204 fun Asm_full_simp_tac i st = asm_full_simp_tac (simpset ()) i st;
   205 
   206 
   207 (* conversions *)
   208 
   209 val          simplify = simp_thm (false, false, false);
   210 val      asm_simplify = simp_thm (false, true, false);
   211 val     full_simplify = simp_thm (true, false, false);
   212 val   asm_lr_simplify = simp_thm (true, true, false);
   213 val asm_full_simplify = simp_thm (true, true, true);
   214 
   215 val          rewrite = simp_cterm (false, false, false);
   216 val      asm_rewrite = simp_cterm (false, true, false);
   217 val     full_rewrite = simp_cterm (true, false, false);
   218 val   asm_lr_rewrite = simp_cterm (true, true, false);
   219 val asm_full_rewrite = simp_cterm (true, true, true);
   220 
   221 
   222 
   223 (** concrete syntax of attributes **)
   224 
   225 (* add / del *)
   226 
   227 val simpN = "simp";
   228 val congN = "cong";
   229 val addN = "add";
   230 val delN = "del";
   231 val onlyN = "only";
   232 val no_asmN = "no_asm";
   233 val no_asm_useN = "no_asm_use";
   234 val no_asm_simpN = "no_asm_simp";
   235 val asm_lrN = "asm_lr";
   236 
   237 
   238 (* conversions *)
   239 
   240 local
   241 
   242 fun conv_mode x =
   243   ((Args.parens (Args.$$$ no_asmN) >> K simplify ||
   244     Args.parens (Args.$$$ no_asm_simpN) >> K asm_simplify ||
   245     Args.parens (Args.$$$ no_asm_useN) >> K full_simplify ||
   246     Scan.succeed asm_full_simplify) |> Scan.lift) x;
   247 
   248 fun get_ss (Context.Theory thy) = simpset_of thy
   249   | get_ss (Context.Proof ctxt) = local_simpset_of ctxt;
   250 
   251 in
   252 
   253 val simplified =
   254   Attrib.syntax (conv_mode -- Attrib.thmss >> (fn (f, ths) => Attrib.rule (fn x =>
   255     f ((if null ths then I else MetaSimplifier.clear_ss) (get_ss x) addsimps ths))));
   256 
   257 end;
   258 
   259 
   260 (* setup attributes *)
   261 
   262 val _ = Context.add_setup
   263  [Attrib.add_attributes
   264    [(simpN, Attrib.common (Attrib.add_del_args simp_add simp_del),
   265       "declaration of Simplifier rule"),
   266     (congN, Attrib.common (Attrib.add_del_args cong_add cong_del),
   267       "declaration of Simplifier congruence rule"),
   268     ("simplified", Attrib.common simplified, "simplified rule")]];
   269 
   270 
   271 
   272 (** proof methods **)
   273 
   274 (* simplification *)
   275 
   276 val simp_options =
   277  (Args.parens (Args.$$$ no_asmN) >> K simp_tac ||
   278   Args.parens (Args.$$$ no_asm_simpN) >> K asm_simp_tac ||
   279   Args.parens (Args.$$$ no_asm_useN) >> K full_simp_tac ||
   280   Args.parens (Args.$$$ asm_lrN) >> K asm_lr_simp_tac ||
   281   Scan.succeed asm_full_simp_tac);
   282 
   283 fun simp_flags x = (Scan.repeat
   284   (Args.parens (Args.$$$ "depth_limit" -- Args.colon |-- Args.nat)
   285     >> setmp MetaSimplifier.simp_depth_limit)
   286   >> (curry (Library.foldl op o) I o rev)) x;
   287 
   288 val cong_modifiers =
   289  [Args.$$$ congN -- Args.colon >> K ((I, Attrib.context cong_add): Method.modifier),
   290   Args.$$$ congN -- Args.add -- Args.colon >> K (I, Attrib.context cong_add),
   291   Args.$$$ congN -- Args.del -- Args.colon >> K (I, Attrib.context cong_del)];
   292 
   293 val simp_modifiers =
   294  [Args.$$$ simpN -- Args.colon >> K (I, Attrib.context simp_add),
   295   Args.$$$ simpN -- Args.add -- Args.colon >> K (I, Attrib.context simp_add),
   296   Args.$$$ simpN -- Args.del -- Args.colon >> K (I, Attrib.context simp_del),
   297   Args.$$$ simpN -- Args.$$$ onlyN -- Args.colon
   298     >> K (LocalSimpset.map MetaSimplifier.clear_ss, Attrib.context simp_add)]
   299    @ cong_modifiers;
   300 
   301 val simp_modifiers' =
   302  [Args.add -- Args.colon >> K (I, Attrib.context simp_add),
   303   Args.del -- Args.colon >> K (I, Attrib.context simp_del),
   304   Args.$$$ onlyN -- Args.colon
   305     >> K (LocalSimpset.map MetaSimplifier.clear_ss, Attrib.context simp_add)]
   306    @ cong_modifiers;
   307 
   308 fun simp_args more_mods =
   309   Method.sectioned_args (Args.bang_facts -- Scan.lift simp_options -- Scan.lift simp_flags)
   310     (more_mods @ simp_modifiers');
   311 
   312 fun simp_method ((prems, tac), FLAGS) ctxt = Method.METHOD (fn facts =>
   313   ALLGOALS (Method.insert_tac (prems @ facts)) THEN
   314     (FLAGS o CHANGED_PROP o ALLGOALS o tac) (local_simpset_of ctxt));
   315 
   316 fun simp_method' ((prems, tac), FLAGS) ctxt = Method.METHOD (fn facts =>
   317   HEADGOAL (Method.insert_tac (prems @ facts) THEN'
   318       ((FLAGS o CHANGED_PROP) oo tac) (local_simpset_of ctxt)));
   319 
   320 
   321 (* setup methods *)
   322 
   323 fun setup_methods more_mods = Method.add_methods
   324  [(simpN, simp_args more_mods simp_method', "simplification"),
   325   ("simp_all", simp_args more_mods simp_method, "simplification (all goals)")];
   326 
   327 fun method_setup mods = [setup_methods mods];
   328 
   329 
   330 (** easy_setup **)
   331 
   332 fun easy_setup reflect trivs =
   333   let
   334     val trivialities = Drule.reflexive_thm :: trivs;
   335 
   336     fun unsafe_solver_tac prems = FIRST' [resolve_tac (trivialities @ prems), assume_tac];
   337     val unsafe_solver = mk_solver "easy unsafe" unsafe_solver_tac;
   338 
   339     (*no premature instantiation of variables during simplification*)
   340     fun safe_solver_tac prems = FIRST' [match_tac (trivialities @ prems), eq_assume_tac];
   341     val safe_solver = mk_solver "easy safe" safe_solver_tac;
   342 
   343     fun mk_eq thm =
   344       if Logic.is_equals (Thm.concl_of thm) then [thm]
   345       else [thm RS reflect] handle THM _ => [];
   346 
   347     fun mksimps thm = mk_eq (Drule.forall_elim_vars (#maxidx (Thm.rep_thm thm) + 1) thm);
   348 
   349     fun init_ss thy =
   350       (GlobalSimpset.get thy :=
   351         empty_ss setsubgoaler asm_simp_tac
   352         setSSolver safe_solver
   353         setSolver unsafe_solver
   354         setmksimps mksimps; thy);
   355   in method_setup [] @ [init_ss] end;
   356 
   357 
   358 open MetaSimplifier;
   359 
   360 end;
   361 
   362 structure BasicSimplifier: BASIC_SIMPLIFIER = Simplifier;
   363 open BasicSimplifier;