src/HOL/Deriv.thy
author paulson
Fri Nov 13 11:33:33 2009 +0000 (2009-11-13)
changeset 33654 abf780db30ea
parent 31902 862ae16a799d
child 33659 2d7ab9458518
permissions -rw-r--r--
A number of theorems contributed by Jeremy Avigad
     1 (*  Title       : Deriv.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2004
     5     GMVT by Benjamin Porter, 2005
     6 *)
     7 
     8 header{* Differentiation *}
     9 
    10 theory Deriv
    11 imports Lim
    12 begin
    13 
    14 text{*Standard Definitions*}
    15 
    16 definition
    17   deriv :: "['a::real_normed_field \<Rightarrow> 'a, 'a, 'a] \<Rightarrow> bool"
    18     --{*Differentiation: D is derivative of function f at x*}
    19           ("(DERIV (_)/ (_)/ :> (_))" [1000, 1000, 60] 60) where
    20   "DERIV f x :> D = ((%h. (f(x + h) - f x) / h) -- 0 --> D)"
    21 
    22 consts
    23   Bolzano_bisect :: "[real*real=>bool, real, real, nat] => (real*real)"
    24 primrec
    25   "Bolzano_bisect P a b 0 = (a,b)"
    26   "Bolzano_bisect P a b (Suc n) =
    27       (let (x,y) = Bolzano_bisect P a b n
    28        in if P(x, (x+y)/2) then ((x+y)/2, y)
    29                             else (x, (x+y)/2))"
    30 
    31 
    32 subsection {* Derivatives *}
    33 
    34 lemma DERIV_iff: "(DERIV f x :> D) = ((%h. (f(x + h) - f(x))/h) -- 0 --> D)"
    35 by (simp add: deriv_def)
    36 
    37 lemma DERIV_D: "DERIV f x :> D ==> (%h. (f(x + h) - f(x))/h) -- 0 --> D"
    38 by (simp add: deriv_def)
    39 
    40 lemma DERIV_const [simp]: "DERIV (\<lambda>x. k) x :> 0"
    41 by (simp add: deriv_def)
    42 
    43 lemma DERIV_ident [simp]: "DERIV (\<lambda>x. x) x :> 1"
    44 by (simp add: deriv_def cong: LIM_cong)
    45 
    46 lemma add_diff_add:
    47   fixes a b c d :: "'a::ab_group_add"
    48   shows "(a + c) - (b + d) = (a - b) + (c - d)"
    49 by simp
    50 
    51 lemma DERIV_add:
    52   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + g x) x :> D + E"
    53 by (simp only: deriv_def add_diff_add add_divide_distrib LIM_add)
    54 
    55 lemma DERIV_minus:
    56   "DERIV f x :> D \<Longrightarrow> DERIV (\<lambda>x. - f x) x :> - D"
    57 by (simp only: deriv_def minus_diff_minus divide_minus_left LIM_minus)
    58 
    59 lemma DERIV_diff:
    60   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x - g x) x :> D - E"
    61 by (simp only: diff_def DERIV_add DERIV_minus)
    62 
    63 lemma DERIV_add_minus:
    64   "\<lbrakk>DERIV f x :> D; DERIV g x :> E\<rbrakk> \<Longrightarrow> DERIV (\<lambda>x. f x + - g x) x :> D + - E"
    65 by (simp only: DERIV_add DERIV_minus)
    66 
    67 lemma DERIV_isCont: "DERIV f x :> D \<Longrightarrow> isCont f x"
    68 proof (unfold isCont_iff)
    69   assume "DERIV f x :> D"
    70   hence "(\<lambda>h. (f(x+h) - f(x)) / h) -- 0 --> D"
    71     by (rule DERIV_D)
    72   hence "(\<lambda>h. (f(x+h) - f(x)) / h * h) -- 0 --> D * 0"
    73     by (intro LIM_mult LIM_ident)
    74   hence "(\<lambda>h. (f(x+h) - f(x)) * (h / h)) -- 0 --> 0"
    75     by simp
    76   hence "(\<lambda>h. f(x+h) - f(x)) -- 0 --> 0"
    77     by (simp cong: LIM_cong)
    78   thus "(\<lambda>h. f(x+h)) -- 0 --> f(x)"
    79     by (simp add: LIM_def dist_norm)
    80 qed
    81 
    82 lemma DERIV_mult_lemma:
    83   fixes a b c d :: "'a::real_field"
    84   shows "(a * b - c * d) / h = a * ((b - d) / h) + ((a - c) / h) * d"
    85 by (simp add: diff_minus add_divide_distrib [symmetric] ring_distribs)
    86 
    87 lemma DERIV_mult':
    88   assumes f: "DERIV f x :> D"
    89   assumes g: "DERIV g x :> E"
    90   shows "DERIV (\<lambda>x. f x * g x) x :> f x * E + D * g x"
    91 proof (unfold deriv_def)
    92   from f have "isCont f x"
    93     by (rule DERIV_isCont)
    94   hence "(\<lambda>h. f(x+h)) -- 0 --> f x"
    95     by (simp only: isCont_iff)
    96   hence "(\<lambda>h. f(x+h) * ((g(x+h) - g x) / h) +
    97               ((f(x+h) - f x) / h) * g x)
    98           -- 0 --> f x * E + D * g x"
    99     by (intro LIM_add LIM_mult LIM_const DERIV_D f g)
   100   thus "(\<lambda>h. (f(x+h) * g(x+h) - f x * g x) / h)
   101          -- 0 --> f x * E + D * g x"
   102     by (simp only: DERIV_mult_lemma)
   103 qed
   104 
   105 lemma DERIV_mult:
   106      "[| DERIV f x :> Da; DERIV g x :> Db |]
   107       ==> DERIV (%x. f x * g x) x :> (Da * g(x)) + (Db * f(x))"
   108 by (drule (1) DERIV_mult', simp only: mult_commute add_commute)
   109 
   110 lemma DERIV_unique:
   111       "[| DERIV f x :> D; DERIV f x :> E |] ==> D = E"
   112 apply (simp add: deriv_def)
   113 apply (blast intro: LIM_unique)
   114 done
   115 
   116 text{*Differentiation of finite sum*}
   117 
   118 lemma DERIV_setsum:
   119   assumes "finite S"
   120   and "\<And> n. n \<in> S \<Longrightarrow> DERIV (%x. f x n) x :> (f' x n)"
   121   shows "DERIV (%x. setsum (f x) S) x :> setsum (f' x) S"
   122   using assms by induct (auto intro!: DERIV_add)
   123 
   124 lemma DERIV_sumr [rule_format (no_asm)]:
   125      "(\<forall>r. m \<le> r & r < (m + n) --> DERIV (%x. f r x) x :> (f' r x))
   126       --> DERIV (%x. \<Sum>n=m..<n::nat. f n x :: real) x :> (\<Sum>r=m..<n. f' r x)"
   127   by (auto intro: DERIV_setsum)
   128 
   129 text{*Alternative definition for differentiability*}
   130 
   131 lemma DERIV_LIM_iff:
   132   fixes f :: "'a::{real_normed_vector,inverse} \<Rightarrow> 'a" shows
   133      "((%h. (f(a + h) - f(a)) / h) -- 0 --> D) =
   134       ((%x. (f(x)-f(a)) / (x-a)) -- a --> D)"
   135 apply (rule iffI)
   136 apply (drule_tac k="- a" in LIM_offset)
   137 apply (simp add: diff_minus)
   138 apply (drule_tac k="a" in LIM_offset)
   139 apply (simp add: add_commute)
   140 done
   141 
   142 lemma DERIV_iff2: "(DERIV f x :> D) = ((%z. (f(z) - f(x)) / (z-x)) -- x --> D)"
   143 by (simp add: deriv_def diff_minus [symmetric] DERIV_LIM_iff)
   144 
   145 lemma inverse_diff_inverse:
   146   "\<lbrakk>(a::'a::division_ring) \<noteq> 0; b \<noteq> 0\<rbrakk>
   147    \<Longrightarrow> inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
   148 by (simp add: algebra_simps)
   149 
   150 lemma DERIV_inverse_lemma:
   151   "\<lbrakk>a \<noteq> 0; b \<noteq> (0::'a::real_normed_field)\<rbrakk>
   152    \<Longrightarrow> (inverse a - inverse b) / h
   153      = - (inverse a * ((a - b) / h) * inverse b)"
   154 by (simp add: inverse_diff_inverse)
   155 
   156 lemma DERIV_inverse':
   157   assumes der: "DERIV f x :> D"
   158   assumes neq: "f x \<noteq> 0"
   159   shows "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * D * inverse (f x))"
   160     (is "DERIV _ _ :> ?E")
   161 proof (unfold DERIV_iff2)
   162   from der have lim_f: "f -- x --> f x"
   163     by (rule DERIV_isCont [unfolded isCont_def])
   164 
   165   from neq have "0 < norm (f x)" by simp
   166   with LIM_D [OF lim_f] obtain s
   167     where s: "0 < s"
   168     and less_fx: "\<And>z. \<lbrakk>z \<noteq> x; norm (z - x) < s\<rbrakk>
   169                   \<Longrightarrow> norm (f z - f x) < norm (f x)"
   170     by fast
   171 
   172   show "(\<lambda>z. (inverse (f z) - inverse (f x)) / (z - x)) -- x --> ?E"
   173   proof (rule LIM_equal2 [OF s])
   174     fix z
   175     assume "z \<noteq> x" "norm (z - x) < s"
   176     hence "norm (f z - f x) < norm (f x)" by (rule less_fx)
   177     hence "f z \<noteq> 0" by auto
   178     thus "(inverse (f z) - inverse (f x)) / (z - x) =
   179           - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x))"
   180       using neq by (rule DERIV_inverse_lemma)
   181   next
   182     from der have "(\<lambda>z. (f z - f x) / (z - x)) -- x --> D"
   183       by (unfold DERIV_iff2)
   184     thus "(\<lambda>z. - (inverse (f z) * ((f z - f x) / (z - x)) * inverse (f x)))
   185           -- x --> ?E"
   186       by (intro LIM_mult LIM_inverse LIM_minus LIM_const lim_f neq)
   187   qed
   188 qed
   189 
   190 lemma DERIV_divide:
   191   "\<lbrakk>DERIV f x :> D; DERIV g x :> E; g x \<noteq> 0\<rbrakk>
   192    \<Longrightarrow> DERIV (\<lambda>x. f x / g x) x :> (D * g x - f x * E) / (g x * g x)"
   193 apply (subgoal_tac "f x * - (inverse (g x) * E * inverse (g x)) +
   194           D * inverse (g x) = (D * g x - f x * E) / (g x * g x)")
   195 apply (erule subst)
   196 apply (unfold divide_inverse)
   197 apply (erule DERIV_mult')
   198 apply (erule (1) DERIV_inverse')
   199 apply (simp add: ring_distribs nonzero_inverse_mult_distrib)
   200 apply (simp add: mult_ac)
   201 done
   202 
   203 lemma DERIV_power_Suc:
   204   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field}"
   205   assumes f: "DERIV f x :> D"
   206   shows "DERIV (\<lambda>x. f x ^ Suc n) x :> (1 + of_nat n) * (D * f x ^ n)"
   207 proof (induct n)
   208 case 0
   209   show ?case by (simp add: f)
   210 case (Suc k)
   211   from DERIV_mult' [OF f Suc] show ?case
   212     apply (simp only: of_nat_Suc ring_distribs mult_1_left)
   213     apply (simp only: power_Suc algebra_simps)
   214     done
   215 qed
   216 
   217 lemma DERIV_power:
   218   fixes f :: "'a \<Rightarrow> 'a::{real_normed_field}"
   219   assumes f: "DERIV f x :> D"
   220   shows "DERIV (\<lambda>x. f x ^ n) x :> of_nat n * (D * f x ^ (n - Suc 0))"
   221 by (cases "n", simp, simp add: DERIV_power_Suc f del: power_Suc)
   222 
   223 text {* Caratheodory formulation of derivative at a point *}
   224 
   225 lemma CARAT_DERIV:
   226      "(DERIV f x :> l) =
   227       (\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) & isCont g x & g x = l)"
   228       (is "?lhs = ?rhs")
   229 proof
   230   assume der: "DERIV f x :> l"
   231   show "\<exists>g. (\<forall>z. f z - f x = g z * (z-x)) \<and> isCont g x \<and> g x = l"
   232   proof (intro exI conjI)
   233     let ?g = "(%z. if z = x then l else (f z - f x) / (z-x))"
   234     show "\<forall>z. f z - f x = ?g z * (z-x)" by simp
   235     show "isCont ?g x" using der
   236       by (simp add: isCont_iff DERIV_iff diff_minus
   237                cong: LIM_equal [rule_format])
   238     show "?g x = l" by simp
   239   qed
   240 next
   241   assume "?rhs"
   242   then obtain g where
   243     "(\<forall>z. f z - f x = g z * (z-x))" and "isCont g x" and "g x = l" by blast
   244   thus "(DERIV f x :> l)"
   245      by (auto simp add: isCont_iff DERIV_iff cong: LIM_cong)
   246 qed
   247 
   248 lemma DERIV_chain':
   249   assumes f: "DERIV f x :> D"
   250   assumes g: "DERIV g (f x) :> E"
   251   shows "DERIV (\<lambda>x. g (f x)) x :> E * D"
   252 proof (unfold DERIV_iff2)
   253   obtain d where d: "\<forall>y. g y - g (f x) = d y * (y - f x)"
   254     and cont_d: "isCont d (f x)" and dfx: "d (f x) = E"
   255     using CARAT_DERIV [THEN iffD1, OF g] by fast
   256   from f have "f -- x --> f x"
   257     by (rule DERIV_isCont [unfolded isCont_def])
   258   with cont_d have "(\<lambda>z. d (f z)) -- x --> d (f x)"
   259     by (rule isCont_LIM_compose)
   260   hence "(\<lambda>z. d (f z) * ((f z - f x) / (z - x)))
   261           -- x --> d (f x) * D"
   262     by (rule LIM_mult [OF _ f [unfolded DERIV_iff2]])
   263   thus "(\<lambda>z. (g (f z) - g (f x)) / (z - x)) -- x --> E * D"
   264     by (simp add: d dfx real_scaleR_def)
   265 qed
   266 
   267 text {*
   268  Let's do the standard proof, though theorem
   269  @{text "LIM_mult2"} follows from a NS proof
   270 *}
   271 
   272 lemma DERIV_cmult:
   273       "DERIV f x :> D ==> DERIV (%x. c * f x) x :> c*D"
   274 by (drule DERIV_mult' [OF DERIV_const], simp)
   275 
   276 lemma DERIV_cdivide: "DERIV f x :> D ==> DERIV (%x. f x / c) x :> D / c"
   277   apply (subgoal_tac "DERIV (%x. (1 / c) * f x) x :> (1 / c) * D", force)
   278   apply (erule DERIV_cmult)
   279   done
   280 
   281 text {* Standard version *}
   282 lemma DERIV_chain: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (f o g) x :> Da * Db"
   283 by (drule (1) DERIV_chain', simp add: o_def real_scaleR_def mult_commute)
   284 
   285 lemma DERIV_chain2: "[| DERIV f (g x) :> Da; DERIV g x :> Db |] ==> DERIV (%x. f (g x)) x :> Da * Db"
   286 by (auto dest: DERIV_chain simp add: o_def)
   287 
   288 text {* Derivative of linear multiplication *}
   289 lemma DERIV_cmult_Id [simp]: "DERIV (op * c) x :> c"
   290 by (cut_tac c = c and x = x in DERIV_ident [THEN DERIV_cmult], simp)
   291 
   292 lemma DERIV_pow: "DERIV (%x. x ^ n) x :> real n * (x ^ (n - Suc 0))"
   293 apply (cut_tac DERIV_power [OF DERIV_ident])
   294 apply (simp add: real_scaleR_def real_of_nat_def)
   295 done
   296 
   297 text {* Power of @{text "-1"} *}
   298 
   299 lemma DERIV_inverse:
   300   fixes x :: "'a::{real_normed_field}"
   301   shows "x \<noteq> 0 ==> DERIV (%x. inverse(x)) x :> (-(inverse x ^ Suc (Suc 0)))"
   302 by (drule DERIV_inverse' [OF DERIV_ident]) simp
   303 
   304 text {* Derivative of inverse *}
   305 lemma DERIV_inverse_fun:
   306   fixes x :: "'a::{real_normed_field}"
   307   shows "[| DERIV f x :> d; f(x) \<noteq> 0 |]
   308       ==> DERIV (%x. inverse(f x)) x :> (- (d * inverse(f(x) ^ Suc (Suc 0))))"
   309 by (drule (1) DERIV_inverse') (simp add: mult_ac nonzero_inverse_mult_distrib)
   310 
   311 text {* Derivative of quotient *}
   312 lemma DERIV_quotient:
   313   fixes x :: "'a::{real_normed_field}"
   314   shows "[| DERIV f x :> d; DERIV g x :> e; g(x) \<noteq> 0 |]
   315        ==> DERIV (%y. f(y) / (g y)) x :> (d*g(x) - (e*f(x))) / (g(x) ^ Suc (Suc 0))"
   316 by (drule (2) DERIV_divide) (simp add: mult_commute)
   317 
   318 lemma lemma_DERIV_subst: "[| DERIV f x :> D; D = E |] ==> DERIV f x :> E"
   319 by auto
   320 
   321 text {* @{text "DERIV_intros"} *}
   322 ML {*
   323 structure Deriv_Intros = Named_Thms
   324 (
   325   val name = "DERIV_intros"
   326   val description = "DERIV introduction rules"
   327 )
   328 *}
   329 
   330 setup Deriv_Intros.setup
   331 
   332 lemma DERIV_cong: "\<lbrakk> DERIV f x :> X ; X = Y \<rbrakk> \<Longrightarrow> DERIV f x :> Y"
   333   by simp
   334 
   335 declare
   336   DERIV_const[THEN DERIV_cong, DERIV_intros]
   337   DERIV_ident[THEN DERIV_cong, DERIV_intros]
   338   DERIV_add[THEN DERIV_cong, DERIV_intros]
   339   DERIV_minus[THEN DERIV_cong, DERIV_intros]
   340   DERIV_mult[THEN DERIV_cong, DERIV_intros]
   341   DERIV_diff[THEN DERIV_cong, DERIV_intros]
   342   DERIV_inverse'[THEN DERIV_cong, DERIV_intros]
   343   DERIV_divide[THEN DERIV_cong, DERIV_intros]
   344   DERIV_power[where 'a=real, THEN DERIV_cong,
   345               unfolded real_of_nat_def[symmetric], DERIV_intros]
   346   DERIV_setsum[THEN DERIV_cong, DERIV_intros]
   347 
   348 
   349 subsection {* Differentiability predicate *}
   350 
   351 definition
   352   differentiable :: "['a::real_normed_field \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
   353     (infixl "differentiable" 60) where
   354   "f differentiable x = (\<exists>D. DERIV f x :> D)"
   355 
   356 lemma differentiableE [elim?]:
   357   assumes "f differentiable x"
   358   obtains df where "DERIV f x :> df"
   359   using prems unfolding differentiable_def ..
   360 
   361 lemma differentiableD: "f differentiable x ==> \<exists>D. DERIV f x :> D"
   362 by (simp add: differentiable_def)
   363 
   364 lemma differentiableI: "DERIV f x :> D ==> f differentiable x"
   365 by (force simp add: differentiable_def)
   366 
   367 lemma differentiable_ident [simp]: "(\<lambda>x. x) differentiable x"
   368   by (rule DERIV_ident [THEN differentiableI])
   369 
   370 lemma differentiable_const [simp]: "(\<lambda>z. a) differentiable x"
   371   by (rule DERIV_const [THEN differentiableI])
   372 
   373 lemma differentiable_compose:
   374   assumes f: "f differentiable (g x)"
   375   assumes g: "g differentiable x"
   376   shows "(\<lambda>x. f (g x)) differentiable x"
   377 proof -
   378   from `f differentiable (g x)` obtain df where "DERIV f (g x) :> df" ..
   379   moreover
   380   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   381   ultimately
   382   have "DERIV (\<lambda>x. f (g x)) x :> df * dg" by (rule DERIV_chain2)
   383   thus ?thesis by (rule differentiableI)
   384 qed
   385 
   386 lemma differentiable_sum [simp]:
   387   assumes "f differentiable x"
   388   and "g differentiable x"
   389   shows "(\<lambda>x. f x + g x) differentiable x"
   390 proof -
   391   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   392   moreover
   393   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   394   ultimately
   395   have "DERIV (\<lambda>x. f x + g x) x :> df + dg" by (rule DERIV_add)
   396   thus ?thesis by (rule differentiableI)
   397 qed
   398 
   399 lemma differentiable_minus [simp]:
   400   assumes "f differentiable x"
   401   shows "(\<lambda>x. - f x) differentiable x"
   402 proof -
   403   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   404   hence "DERIV (\<lambda>x. - f x) x :> - df" by (rule DERIV_minus)
   405   thus ?thesis by (rule differentiableI)
   406 qed
   407 
   408 lemma differentiable_diff [simp]:
   409   assumes "f differentiable x"
   410   assumes "g differentiable x"
   411   shows "(\<lambda>x. f x - g x) differentiable x"
   412   unfolding diff_minus using prems by simp
   413 
   414 lemma differentiable_mult [simp]:
   415   assumes "f differentiable x"
   416   assumes "g differentiable x"
   417   shows "(\<lambda>x. f x * g x) differentiable x"
   418 proof -
   419   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   420   moreover
   421   from `g differentiable x` obtain dg where "DERIV g x :> dg" ..
   422   ultimately
   423   have "DERIV (\<lambda>x. f x * g x) x :> df * g x + dg * f x" by (rule DERIV_mult)
   424   thus ?thesis by (rule differentiableI)
   425 qed
   426 
   427 lemma differentiable_inverse [simp]:
   428   assumes "f differentiable x" and "f x \<noteq> 0"
   429   shows "(\<lambda>x. inverse (f x)) differentiable x"
   430 proof -
   431   from `f differentiable x` obtain df where "DERIV f x :> df" ..
   432   hence "DERIV (\<lambda>x. inverse (f x)) x :> - (inverse (f x) * df * inverse (f x))"
   433     using `f x \<noteq> 0` by (rule DERIV_inverse')
   434   thus ?thesis by (rule differentiableI)
   435 qed
   436 
   437 lemma differentiable_divide [simp]:
   438   assumes "f differentiable x"
   439   assumes "g differentiable x" and "g x \<noteq> 0"
   440   shows "(\<lambda>x. f x / g x) differentiable x"
   441   unfolding divide_inverse using prems by simp
   442 
   443 lemma differentiable_power [simp]:
   444   fixes f :: "'a::{real_normed_field} \<Rightarrow> 'a"
   445   assumes "f differentiable x"
   446   shows "(\<lambda>x. f x ^ n) differentiable x"
   447   by (induct n, simp, simp add: prems)
   448 
   449 
   450 subsection {* Nested Intervals and Bisection *}
   451 
   452 text{*Lemmas about nested intervals and proof by bisection (cf.Harrison).
   453      All considerably tidied by lcp.*}
   454 
   455 lemma lemma_f_mono_add [rule_format (no_asm)]: "(\<forall>n. (f::nat=>real) n \<le> f (Suc n)) --> f m \<le> f(m + no)"
   456 apply (induct "no")
   457 apply (auto intro: order_trans)
   458 done
   459 
   460 lemma f_inc_g_dec_Beq_f: "[| \<forall>n. f(n) \<le> f(Suc n);
   461          \<forall>n. g(Suc n) \<le> g(n);
   462          \<forall>n. f(n) \<le> g(n) |]
   463       ==> Bseq (f :: nat \<Rightarrow> real)"
   464 apply (rule_tac k = "f 0" and K = "g 0" in BseqI2, rule allI)
   465 apply (induct_tac "n")
   466 apply (auto intro: order_trans)
   467 apply (rule_tac y = "g (Suc na)" in order_trans)
   468 apply (induct_tac [2] "na")
   469 apply (auto intro: order_trans)
   470 done
   471 
   472 lemma f_inc_g_dec_Beq_g: "[| \<forall>n. f(n) \<le> f(Suc n);
   473          \<forall>n. g(Suc n) \<le> g(n);
   474          \<forall>n. f(n) \<le> g(n) |]
   475       ==> Bseq (g :: nat \<Rightarrow> real)"
   476 apply (subst Bseq_minus_iff [symmetric])
   477 apply (rule_tac g = "%x. - (f x)" in f_inc_g_dec_Beq_f)
   478 apply auto
   479 done
   480 
   481 lemma f_inc_imp_le_lim:
   482   fixes f :: "nat \<Rightarrow> real"
   483   shows "\<lbrakk>\<forall>n. f n \<le> f (Suc n); convergent f\<rbrakk> \<Longrightarrow> f n \<le> lim f"
   484 apply (rule linorder_not_less [THEN iffD1])
   485 apply (auto simp add: convergent_LIMSEQ_iff LIMSEQ_iff monoseq_Suc)
   486 apply (drule real_less_sum_gt_zero)
   487 apply (drule_tac x = "f n + - lim f" in spec, safe)
   488 apply (drule_tac P = "%na. no\<le>na --> ?Q na" and x = "no + n" in spec, auto)
   489 apply (subgoal_tac "lim f \<le> f (no + n) ")
   490 apply (drule_tac no=no and m=n in lemma_f_mono_add)
   491 apply (auto simp add: add_commute)
   492 apply (induct_tac "no")
   493 apply simp
   494 apply (auto intro: order_trans simp add: diff_minus abs_if)
   495 done
   496 
   497 lemma lim_uminus:
   498   fixes g :: "nat \<Rightarrow> 'a::real_normed_vector"
   499   shows "convergent g ==> lim (%x. - g x) = - (lim g)"
   500 apply (rule LIMSEQ_minus [THEN limI])
   501 apply (simp add: convergent_LIMSEQ_iff)
   502 done
   503 
   504 lemma g_dec_imp_lim_le:
   505   fixes g :: "nat \<Rightarrow> real"
   506   shows "\<lbrakk>\<forall>n. g (Suc n) \<le> g(n); convergent g\<rbrakk> \<Longrightarrow> lim g \<le> g n"
   507 apply (subgoal_tac "- (g n) \<le> - (lim g) ")
   508 apply (cut_tac [2] f = "%x. - (g x)" in f_inc_imp_le_lim)
   509 apply (auto simp add: lim_uminus convergent_minus_iff [symmetric])
   510 done
   511 
   512 lemma lemma_nest: "[| \<forall>n. f(n) \<le> f(Suc n);
   513          \<forall>n. g(Suc n) \<le> g(n);
   514          \<forall>n. f(n) \<le> g(n) |]
   515       ==> \<exists>l m :: real. l \<le> m &  ((\<forall>n. f(n) \<le> l) & f ----> l) &
   516                             ((\<forall>n. m \<le> g(n)) & g ----> m)"
   517 apply (subgoal_tac "monoseq f & monoseq g")
   518 prefer 2 apply (force simp add: LIMSEQ_iff monoseq_Suc)
   519 apply (subgoal_tac "Bseq f & Bseq g")
   520 prefer 2 apply (blast intro: f_inc_g_dec_Beq_f f_inc_g_dec_Beq_g)
   521 apply (auto dest!: Bseq_monoseq_convergent simp add: convergent_LIMSEQ_iff)
   522 apply (rule_tac x = "lim f" in exI)
   523 apply (rule_tac x = "lim g" in exI)
   524 apply (auto intro: LIMSEQ_le)
   525 apply (auto simp add: f_inc_imp_le_lim g_dec_imp_lim_le convergent_LIMSEQ_iff)
   526 done
   527 
   528 lemma lemma_nest_unique: "[| \<forall>n. f(n) \<le> f(Suc n);
   529          \<forall>n. g(Suc n) \<le> g(n);
   530          \<forall>n. f(n) \<le> g(n);
   531          (%n. f(n) - g(n)) ----> 0 |]
   532       ==> \<exists>l::real. ((\<forall>n. f(n) \<le> l) & f ----> l) &
   533                 ((\<forall>n. l \<le> g(n)) & g ----> l)"
   534 apply (drule lemma_nest, auto)
   535 apply (subgoal_tac "l = m")
   536 apply (drule_tac [2] X = f in LIMSEQ_diff)
   537 apply (auto intro: LIMSEQ_unique)
   538 done
   539 
   540 text{*The universal quantifiers below are required for the declaration
   541   of @{text Bolzano_nest_unique} below.*}
   542 
   543 lemma Bolzano_bisect_le:
   544  "a \<le> b ==> \<forall>n. fst (Bolzano_bisect P a b n) \<le> snd (Bolzano_bisect P a b n)"
   545 apply (rule allI)
   546 apply (induct_tac "n")
   547 apply (auto simp add: Let_def split_def)
   548 done
   549 
   550 lemma Bolzano_bisect_fst_le_Suc: "a \<le> b ==>
   551    \<forall>n. fst(Bolzano_bisect P a b n) \<le> fst (Bolzano_bisect P a b (Suc n))"
   552 apply (rule allI)
   553 apply (induct_tac "n")
   554 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   555 done
   556 
   557 lemma Bolzano_bisect_Suc_le_snd: "a \<le> b ==>
   558    \<forall>n. snd(Bolzano_bisect P a b (Suc n)) \<le> snd (Bolzano_bisect P a b n)"
   559 apply (rule allI)
   560 apply (induct_tac "n")
   561 apply (auto simp add: Bolzano_bisect_le Let_def split_def)
   562 done
   563 
   564 lemma eq_divide_2_times_iff: "((x::real) = y / (2 * z)) = (2 * x = y/z)"
   565 apply (auto)
   566 apply (drule_tac f = "%u. (1/2) *u" in arg_cong)
   567 apply (simp)
   568 done
   569 
   570 lemma Bolzano_bisect_diff:
   571      "a \<le> b ==>
   572       snd(Bolzano_bisect P a b n) - fst(Bolzano_bisect P a b n) =
   573       (b-a) / (2 ^ n)"
   574 apply (induct "n")
   575 apply (auto simp add: eq_divide_2_times_iff add_divide_distrib Let_def split_def)
   576 done
   577 
   578 lemmas Bolzano_nest_unique =
   579     lemma_nest_unique
   580     [OF Bolzano_bisect_fst_le_Suc Bolzano_bisect_Suc_le_snd Bolzano_bisect_le]
   581 
   582 
   583 lemma not_P_Bolzano_bisect:
   584   assumes P:    "!!a b c. [| P(a,b); P(b,c); a \<le> b; b \<le> c|] ==> P(a,c)"
   585       and notP: "~ P(a,b)"
   586       and le:   "a \<le> b"
   587   shows "~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   588 proof (induct n)
   589   case 0 show ?case using notP by simp
   590  next
   591   case (Suc n)
   592   thus ?case
   593  by (auto simp del: surjective_pairing [symmetric]
   594              simp add: Let_def split_def Bolzano_bisect_le [OF le]
   595      P [of "fst (Bolzano_bisect P a b n)" _ "snd (Bolzano_bisect P a b n)"])
   596 qed
   597 
   598 (*Now we re-package P_prem as a formula*)
   599 lemma not_P_Bolzano_bisect':
   600      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   601          ~ P(a,b);  a \<le> b |] ==>
   602       \<forall>n. ~ P(fst(Bolzano_bisect P a b n), snd(Bolzano_bisect P a b n))"
   603 by (blast elim!: not_P_Bolzano_bisect [THEN [2] rev_notE])
   604 
   605 
   606 
   607 lemma lemma_BOLZANO:
   608      "[| \<forall>a b c. P(a,b) & P(b,c) & a \<le> b & b \<le> c --> P(a,c);
   609          \<forall>x. \<exists>d::real. 0 < d &
   610                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b));
   611          a \<le> b |]
   612       ==> P(a,b)"
   613 apply (rule Bolzano_nest_unique [where P1=P, THEN exE], assumption+)
   614 apply (rule LIMSEQ_minus_cancel)
   615 apply (simp (no_asm_simp) add: Bolzano_bisect_diff LIMSEQ_divide_realpow_zero)
   616 apply (rule ccontr)
   617 apply (drule not_P_Bolzano_bisect', assumption+)
   618 apply (rename_tac "l")
   619 apply (drule_tac x = l in spec, clarify)
   620 apply (simp add: LIMSEQ_iff)
   621 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   622 apply (drule_tac P = "%r. 0<r --> ?Q r" and x = "d/2" in spec)
   623 apply (drule real_less_half_sum, auto)
   624 apply (drule_tac x = "fst (Bolzano_bisect P a b (no + noa))" in spec)
   625 apply (drule_tac x = "snd (Bolzano_bisect P a b (no + noa))" in spec)
   626 apply safe
   627 apply (simp_all (no_asm_simp))
   628 apply (rule_tac y = "abs (fst (Bolzano_bisect P a b (no + noa)) - l) + abs (snd (Bolzano_bisect P a b (no + noa)) - l)" in order_le_less_trans)
   629 apply (simp (no_asm_simp) add: abs_if)
   630 apply (rule real_sum_of_halves [THEN subst])
   631 apply (rule add_strict_mono)
   632 apply (simp_all add: diff_minus [symmetric])
   633 done
   634 
   635 
   636 lemma lemma_BOLZANO2: "((\<forall>a b c. (a \<le> b & b \<le> c & P(a,b) & P(b,c)) --> P(a,c)) &
   637        (\<forall>x. \<exists>d::real. 0 < d &
   638                 (\<forall>a b. a \<le> x & x \<le> b & (b-a) < d --> P(a,b))))
   639       --> (\<forall>a b. a \<le> b --> P(a,b))"
   640 apply clarify
   641 apply (blast intro: lemma_BOLZANO)
   642 done
   643 
   644 
   645 subsection {* Intermediate Value Theorem *}
   646 
   647 text {*Prove Contrapositive by Bisection*}
   648 
   649 lemma IVT: "[| f(a::real) \<le> (y::real); y \<le> f(b);
   650          a \<le> b;
   651          (\<forall>x. a \<le> x & x \<le> b --> isCont f x) |]
   652       ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   653 apply (rule contrapos_pp, assumption)
   654 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> ~ (f (u) \<le> y & y \<le> f (v))" in lemma_BOLZANO2)
   655 apply safe
   656 apply simp_all
   657 apply (simp add: isCont_iff LIM_eq)
   658 apply (rule ccontr)
   659 apply (subgoal_tac "a \<le> x & x \<le> b")
   660  prefer 2
   661  apply simp
   662  apply (drule_tac P = "%d. 0<d --> ?P d" and x = 1 in spec, arith)
   663 apply (drule_tac x = x in spec)+
   664 apply simp
   665 apply (drule_tac P = "%r. ?P r --> (\<exists>s>0. ?Q r s) " and x = "\<bar>y - f x\<bar>" in spec)
   666 apply safe
   667 apply simp
   668 apply (drule_tac x = s in spec, clarify)
   669 apply (cut_tac x = "f x" and y = y in linorder_less_linear, safe)
   670 apply (drule_tac x = "ba-x" in spec)
   671 apply (simp_all add: abs_if)
   672 apply (drule_tac x = "aa-x" in spec)
   673 apply (case_tac "x \<le> aa", simp_all)
   674 done
   675 
   676 lemma IVT2: "[| f(b::real) \<le> (y::real); y \<le> f(a);
   677          a \<le> b;
   678          (\<forall>x. a \<le> x & x \<le> b --> isCont f x)
   679       |] ==> \<exists>x. a \<le> x & x \<le> b & f(x) = y"
   680 apply (subgoal_tac "- f a \<le> -y & -y \<le> - f b", clarify)
   681 apply (drule IVT [where f = "%x. - f x"], assumption)
   682 apply (auto intro: isCont_minus)
   683 done
   684 
   685 (*HOL style here: object-level formulations*)
   686 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
   687       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   688       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   689 apply (blast intro: IVT)
   690 done
   691 
   692 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
   693       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
   694       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
   695 apply (blast intro: IVT2)
   696 done
   697 
   698 
   699 subsection {* Boundedness of continuous functions *}
   700 
   701 text{*By bisection, function continuous on closed interval is bounded above*}
   702 
   703 lemma isCont_bounded:
   704      "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   705       ==> \<exists>M::real. \<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M"
   706 apply (cut_tac P = "% (u,v) . a \<le> u & u \<le> v & v \<le> b --> (\<exists>M. \<forall>x. u \<le> x & x \<le> v --> f x \<le> M)" in lemma_BOLZANO2)
   707 apply safe
   708 apply simp_all
   709 apply (rename_tac x xa ya M Ma)
   710 apply (metis linorder_not_less order_le_less real_le_trans)
   711 apply (case_tac "a \<le> x & x \<le> b")
   712  prefer 2
   713  apply (rule_tac x = 1 in exI, force)
   714 apply (simp add: LIM_eq isCont_iff)
   715 apply (drule_tac x = x in spec, auto)
   716 apply (erule_tac V = "\<forall>M. \<exists>x. a \<le> x & x \<le> b & ~ f x \<le> M" in thin_rl)
   717 apply (drule_tac x = 1 in spec, auto)
   718 apply (rule_tac x = s in exI, clarify)
   719 apply (rule_tac x = "\<bar>f x\<bar> + 1" in exI, clarify)
   720 apply (drule_tac x = "xa-x" in spec)
   721 apply (auto simp add: abs_ge_self)
   722 done
   723 
   724 text{*Refine the above to existence of least upper bound*}
   725 
   726 lemma lemma_reals_complete: "((\<exists>x. x \<in> S) & (\<exists>y. isUb UNIV S (y::real))) -->
   727       (\<exists>t. isLub UNIV S t)"
   728 by (blast intro: reals_complete)
   729 
   730 lemma isCont_has_Ub: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   731          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> f(x) \<le> M) &
   732                    (\<forall>N. N < M --> (\<exists>x. a \<le> x & x \<le> b & N < f(x)))"
   733 apply (cut_tac S = "Collect (%y. \<exists>x. a \<le> x & x \<le> b & y = f x)"
   734         in lemma_reals_complete)
   735 apply auto
   736 apply (drule isCont_bounded, assumption)
   737 apply (auto simp add: isUb_def leastP_def isLub_def setge_def setle_def)
   738 apply (rule exI, auto)
   739 apply (auto dest!: spec simp add: linorder_not_less)
   740 done
   741 
   742 text{*Now show that it attains its upper bound*}
   743 
   744 lemma isCont_eq_Ub:
   745   assumes le: "a \<le> b"
   746       and con: "\<forall>x::real. a \<le> x & x \<le> b --> isCont f x"
   747   shows "\<exists>M::real. (\<forall>x. a \<le> x & x \<le> b --> f(x) \<le> M) &
   748              (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   749 proof -
   750   from isCont_has_Ub [OF le con]
   751   obtain M where M1: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
   752              and M2: "!!N. N<M ==> \<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x"  by blast
   753   show ?thesis
   754   proof (intro exI, intro conjI)
   755     show " \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M" by (rule M1)
   756     show "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M"
   757     proof (rule ccontr)
   758       assume "\<not> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
   759       with M1 have M3: "\<forall>x. a \<le> x & x \<le> b --> f x < M"
   760         by (fastsimp simp add: linorder_not_le [symmetric])
   761       hence "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. inverse (M - f x)) x"
   762         by (auto simp add: isCont_inverse isCont_diff con)
   763       from isCont_bounded [OF le this]
   764       obtain k where k: "!!x. a \<le> x & x \<le> b --> inverse (M - f x) \<le> k" by auto
   765       have Minv: "!!x. a \<le> x & x \<le> b --> 0 < inverse (M - f (x))"
   766         by (simp add: M3 algebra_simps)
   767       have "!!x. a \<le> x & x \<le> b --> inverse (M - f x) < k+1" using k
   768         by (auto intro: order_le_less_trans [of _ k])
   769       with Minv
   770       have "!!x. a \<le> x & x \<le> b --> inverse(k+1) < inverse(inverse(M - f x))"
   771         by (intro strip less_imp_inverse_less, simp_all)
   772       hence invlt: "!!x. a \<le> x & x \<le> b --> inverse(k+1) < M - f x"
   773         by simp
   774       have "M - inverse (k+1) < M" using k [of a] Minv [of a] le
   775         by (simp, arith)
   776       from M2 [OF this]
   777       obtain x where ax: "a \<le> x & x \<le> b & M - inverse(k+1) < f x" ..
   778       thus False using invlt [of x] by force
   779     qed
   780   qed
   781 qed
   782 
   783 
   784 text{*Same theorem for lower bound*}
   785 
   786 lemma isCont_eq_Lb: "[| a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   787          ==> \<exists>M::real. (\<forall>x::real. a \<le> x & x \<le> b --> M \<le> f(x)) &
   788                    (\<exists>x. a \<le> x & x \<le> b & f(x) = M)"
   789 apply (subgoal_tac "\<forall>x. a \<le> x & x \<le> b --> isCont (%x. - (f x)) x")
   790 prefer 2 apply (blast intro: isCont_minus)
   791 apply (drule_tac f = "(%x. - (f x))" in isCont_eq_Ub)
   792 apply safe
   793 apply auto
   794 done
   795 
   796 
   797 text{*Another version.*}
   798 
   799 lemma isCont_Lb_Ub: "[|a \<le> b; \<forall>x. a \<le> x & x \<le> b --> isCont f x |]
   800       ==> \<exists>L M::real. (\<forall>x::real. a \<le> x & x \<le> b --> L \<le> f(x) & f(x) \<le> M) &
   801           (\<forall>y. L \<le> y & y \<le> M --> (\<exists>x. a \<le> x & x \<le> b & (f(x) = y)))"
   802 apply (frule isCont_eq_Lb)
   803 apply (frule_tac [2] isCont_eq_Ub)
   804 apply (assumption+, safe)
   805 apply (rule_tac x = "f x" in exI)
   806 apply (rule_tac x = "f xa" in exI, simp, safe)
   807 apply (cut_tac x = x and y = xa in linorder_linear, safe)
   808 apply (cut_tac f = f and a = x and b = xa and y = y in IVT_objl)
   809 apply (cut_tac [2] f = f and a = xa and b = x and y = y in IVT2_objl, safe)
   810 apply (rule_tac [2] x = xb in exI)
   811 apply (rule_tac [4] x = xb in exI, simp_all)
   812 done
   813 
   814 
   815 subsection {* Local extrema *}
   816 
   817 text{*If @{term "0 < f'(x)"} then @{term x} is Locally Strictly Increasing At The Right*}
   818 
   819 lemma DERIV_pos_inc_right:
   820   fixes f :: "real => real"
   821   assumes der: "DERIV f x :> l"
   822       and l:   "0 < l"
   823   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x + h)"
   824 proof -
   825   from l der [THEN DERIV_D, THEN LIM_D [where r = "l"]]
   826   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l)"
   827     by (simp add: diff_minus)
   828   then obtain s
   829         where s:   "0 < s"
   830           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < l"
   831     by auto
   832   thus ?thesis
   833   proof (intro exI conjI strip)
   834     show "0<s" using s .
   835     fix h::real
   836     assume "0 < h" "h < s"
   837     with all [of h] show "f x < f (x+h)"
   838     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   839     split add: split_if_asm)
   840       assume "~ (f (x+h) - f x) / h < l" and h: "0 < h"
   841       with l
   842       have "0 < (f (x+h) - f x) / h" by arith
   843       thus "f x < f (x+h)"
   844   by (simp add: pos_less_divide_eq h)
   845     qed
   846   qed
   847 qed
   848 
   849 lemma DERIV_neg_dec_left:
   850   fixes f :: "real => real"
   851   assumes der: "DERIV f x :> l"
   852       and l:   "l < 0"
   853   shows "\<exists>d > 0. \<forall>h > 0. h < d --> f(x) < f(x-h)"
   854 proof -
   855   from l der [THEN DERIV_D, THEN LIM_D [where r = "-l"]]
   856   have "\<exists>s > 0. (\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l)"
   857     by (simp add: diff_minus)
   858   then obtain s
   859         where s:   "0 < s"
   860           and all: "!!z. z \<noteq> 0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>(f(x+z) - f x) / z - l\<bar> < -l"
   861     by auto
   862   thus ?thesis
   863   proof (intro exI conjI strip)
   864     show "0<s" using s .
   865     fix h::real
   866     assume "0 < h" "h < s"
   867     with all [of "-h"] show "f x < f (x-h)"
   868     proof (simp add: abs_if pos_less_divide_eq diff_minus [symmetric]
   869     split add: split_if_asm)
   870       assume " - ((f (x-h) - f x) / h) < l" and h: "0 < h"
   871       with l
   872       have "0 < (f (x-h) - f x) / h" by arith
   873       thus "f x < f (x-h)"
   874   by (simp add: pos_less_divide_eq h)
   875     qed
   876   qed
   877 qed
   878 
   879 
   880 lemma DERIV_pos_inc_left:
   881   fixes f :: "real => real"
   882   shows "DERIV f x :> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x - h) < f(x)"
   883   apply (rule DERIV_neg_dec_left [of "%x. - f x" x "-l", simplified])
   884   apply (auto simp add: DERIV_minus) 
   885   done
   886 
   887 lemma DERIV_neg_dec_right:
   888   fixes f :: "real => real"
   889   shows "DERIV f x :> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>d > 0. \<forall>h > 0. h < d --> f(x) > f(x + h)"
   890   apply (rule DERIV_pos_inc_right [of "%x. - f x" x "-l", simplified])
   891   apply (auto simp add: DERIV_minus) 
   892   done
   893 
   894 lemma DERIV_local_max:
   895   fixes f :: "real => real"
   896   assumes der: "DERIV f x :> l"
   897       and d:   "0 < d"
   898       and le:  "\<forall>y. \<bar>x-y\<bar> < d --> f(y) \<le> f(x)"
   899   shows "l = 0"
   900 proof (cases rule: linorder_cases [of l 0])
   901   case equal thus ?thesis .
   902 next
   903   case less
   904   from DERIV_neg_dec_left [OF der less]
   905   obtain d' where d': "0 < d'"
   906              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x-h)" by blast
   907   from real_lbound_gt_zero [OF d d']
   908   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   909   with lt le [THEN spec [where x="x-e"]]
   910   show ?thesis by (auto simp add: abs_if)
   911 next
   912   case greater
   913   from DERIV_pos_inc_right [OF der greater]
   914   obtain d' where d': "0 < d'"
   915              and lt: "\<forall>h > 0. h < d' \<longrightarrow> f x < f (x + h)" by blast
   916   from real_lbound_gt_zero [OF d d']
   917   obtain e where "0 < e \<and> e < d \<and> e < d'" ..
   918   with lt le [THEN spec [where x="x+e"]]
   919   show ?thesis by (auto simp add: abs_if)
   920 qed
   921 
   922 
   923 text{*Similar theorem for a local minimum*}
   924 lemma DERIV_local_min:
   925   fixes f :: "real => real"
   926   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) \<le> f(y) |] ==> l = 0"
   927 by (drule DERIV_minus [THEN DERIV_local_max], auto)
   928 
   929 
   930 text{*In particular, if a function is locally flat*}
   931 lemma DERIV_local_const:
   932   fixes f :: "real => real"
   933   shows "[| DERIV f x :> l; 0 < d; \<forall>y. \<bar>x-y\<bar> < d --> f(x) = f(y) |] ==> l = 0"
   934 by (auto dest!: DERIV_local_max)
   935 
   936 
   937 subsection {* Rolle's Theorem *}
   938 
   939 text{*Lemma about introducing open ball in open interval*}
   940 lemma lemma_interval_lt:
   941      "[| a < x;  x < b |]
   942       ==> \<exists>d::real. 0 < d & (\<forall>y. \<bar>x-y\<bar> < d --> a < y & y < b)"
   943 
   944 apply (simp add: abs_less_iff)
   945 apply (insert linorder_linear [of "x-a" "b-x"], safe)
   946 apply (rule_tac x = "x-a" in exI)
   947 apply (rule_tac [2] x = "b-x" in exI, auto)
   948 done
   949 
   950 lemma lemma_interval: "[| a < x;  x < b |] ==>
   951         \<exists>d::real. 0 < d &  (\<forall>y. \<bar>x-y\<bar> < d --> a \<le> y & y \<le> b)"
   952 apply (drule lemma_interval_lt, auto)
   953 apply (auto intro!: exI)
   954 done
   955 
   956 text{*Rolle's Theorem.
   957    If @{term f} is defined and continuous on the closed interval
   958    @{text "[a,b]"} and differentiable on the open interval @{text "(a,b)"},
   959    and @{term "f(a) = f(b)"},
   960    then there exists @{text "x0 \<in> (a,b)"} such that @{term "f'(x0) = 0"}*}
   961 theorem Rolle:
   962   assumes lt: "a < b"
   963       and eq: "f(a) = f(b)"
   964       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
   965       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
   966   shows "\<exists>z::real. a < z & z < b & DERIV f z :> 0"
   967 proof -
   968   have le: "a \<le> b" using lt by simp
   969   from isCont_eq_Ub [OF le con]
   970   obtain x where x_max: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f z \<le> f x"
   971              and alex: "a \<le> x" and xleb: "x \<le> b"
   972     by blast
   973   from isCont_eq_Lb [OF le con]
   974   obtain x' where x'_min: "\<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> f x' \<le> f z"
   975               and alex': "a \<le> x'" and x'leb: "x' \<le> b"
   976     by blast
   977   show ?thesis
   978   proof cases
   979     assume axb: "a < x & x < b"
   980         --{*@{term f} attains its maximum within the interval*}
   981     hence ax: "a<x" and xb: "x<b" by arith + 
   982     from lemma_interval [OF ax xb]
   983     obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
   984       by blast
   985     hence bound': "\<forall>y. \<bar>x-y\<bar> < d \<longrightarrow> f y \<le> f x" using x_max
   986       by blast
   987     from differentiableD [OF dif [OF axb]]
   988     obtain l where der: "DERIV f x :> l" ..
   989     have "l=0" by (rule DERIV_local_max [OF der d bound'])
   990         --{*the derivative at a local maximum is zero*}
   991     thus ?thesis using ax xb der by auto
   992   next
   993     assume notaxb: "~ (a < x & x < b)"
   994     hence xeqab: "x=a | x=b" using alex xleb by arith
   995     hence fb_eq_fx: "f b = f x" by (auto simp add: eq)
   996     show ?thesis
   997     proof cases
   998       assume ax'b: "a < x' & x' < b"
   999         --{*@{term f} attains its minimum within the interval*}
  1000       hence ax': "a<x'" and x'b: "x'<b" by arith+ 
  1001       from lemma_interval [OF ax' x'b]
  1002       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1003   by blast
  1004       hence bound': "\<forall>y. \<bar>x'-y\<bar> < d \<longrightarrow> f x' \<le> f y" using x'_min
  1005   by blast
  1006       from differentiableD [OF dif [OF ax'b]]
  1007       obtain l where der: "DERIV f x' :> l" ..
  1008       have "l=0" by (rule DERIV_local_min [OF der d bound'])
  1009         --{*the derivative at a local minimum is zero*}
  1010       thus ?thesis using ax' x'b der by auto
  1011     next
  1012       assume notax'b: "~ (a < x' & x' < b)"
  1013         --{*@{term f} is constant througout the interval*}
  1014       hence x'eqab: "x'=a | x'=b" using alex' x'leb by arith
  1015       hence fb_eq_fx': "f b = f x'" by (auto simp add: eq)
  1016       from dense [OF lt]
  1017       obtain r where ar: "a < r" and rb: "r < b" by blast
  1018       from lemma_interval [OF ar rb]
  1019       obtain d where d: "0<d" and bound: "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> a \<le> y \<and> y \<le> b"
  1020   by blast
  1021       have eq_fb: "\<forall>z. a \<le> z --> z \<le> b --> f z = f b"
  1022       proof (clarify)
  1023         fix z::real
  1024         assume az: "a \<le> z" and zb: "z \<le> b"
  1025         show "f z = f b"
  1026         proof (rule order_antisym)
  1027           show "f z \<le> f b" by (simp add: fb_eq_fx x_max az zb)
  1028           show "f b \<le> f z" by (simp add: fb_eq_fx' x'_min az zb)
  1029         qed
  1030       qed
  1031       have bound': "\<forall>y. \<bar>r-y\<bar> < d \<longrightarrow> f r = f y"
  1032       proof (intro strip)
  1033         fix y::real
  1034         assume lt: "\<bar>r-y\<bar> < d"
  1035         hence "f y = f b" by (simp add: eq_fb bound)
  1036         thus "f r = f y" by (simp add: eq_fb ar rb order_less_imp_le)
  1037       qed
  1038       from differentiableD [OF dif [OF conjI [OF ar rb]]]
  1039       obtain l where der: "DERIV f r :> l" ..
  1040       have "l=0" by (rule DERIV_local_const [OF der d bound'])
  1041         --{*the derivative of a constant function is zero*}
  1042       thus ?thesis using ar rb der by auto
  1043     qed
  1044   qed
  1045 qed
  1046 
  1047 
  1048 subsection{*Mean Value Theorem*}
  1049 
  1050 lemma lemma_MVT:
  1051      "f a - (f b - f a)/(b-a) * a = f b - (f b - f a)/(b-a) * (b::real)"
  1052 proof cases
  1053   assume "a=b" thus ?thesis by simp
  1054 next
  1055   assume "a\<noteq>b"
  1056   hence ba: "b-a \<noteq> 0" by arith
  1057   show ?thesis
  1058     by (rule real_mult_left_cancel [OF ba, THEN iffD1],
  1059         simp add: right_diff_distrib,
  1060         simp add: left_diff_distrib)
  1061 qed
  1062 
  1063 theorem MVT:
  1064   assumes lt:  "a < b"
  1065       and con: "\<forall>x. a \<le> x & x \<le> b --> isCont f x"
  1066       and dif [rule_format]: "\<forall>x. a < x & x < b --> f differentiable x"
  1067   shows "\<exists>l z::real. a < z & z < b & DERIV f z :> l &
  1068                    (f(b) - f(a) = (b-a) * l)"
  1069 proof -
  1070   let ?F = "%x. f x - ((f b - f a) / (b-a)) * x"
  1071   have contF: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?F x" using con
  1072     by (fast intro: isCont_diff isCont_const isCont_mult isCont_ident)
  1073   have difF: "\<forall>x. a < x \<and> x < b \<longrightarrow> ?F differentiable x"
  1074   proof (clarify)
  1075     fix x::real
  1076     assume ax: "a < x" and xb: "x < b"
  1077     from differentiableD [OF dif [OF conjI [OF ax xb]]]
  1078     obtain l where der: "DERIV f x :> l" ..
  1079     show "?F differentiable x"
  1080       by (rule differentiableI [where D = "l - (f b - f a)/(b-a)"],
  1081           blast intro: DERIV_diff DERIV_cmult_Id der)
  1082   qed
  1083   from Rolle [where f = ?F, OF lt lemma_MVT contF difF]
  1084   obtain z where az: "a < z" and zb: "z < b" and der: "DERIV ?F z :> 0"
  1085     by blast
  1086   have "DERIV (%x. ((f b - f a)/(b-a)) * x) z :> (f b - f a)/(b-a)"
  1087     by (rule DERIV_cmult_Id)
  1088   hence derF: "DERIV (\<lambda>x. ?F x + (f b - f a) / (b - a) * x) z
  1089                    :> 0 + (f b - f a) / (b - a)"
  1090     by (rule DERIV_add [OF der])
  1091   show ?thesis
  1092   proof (intro exI conjI)
  1093     show "a < z" using az .
  1094     show "z < b" using zb .
  1095     show "f b - f a = (b - a) * ((f b - f a)/(b-a))" by (simp)
  1096     show "DERIV f z :> ((f b - f a)/(b-a))"  using derF by simp
  1097   qed
  1098 qed
  1099 
  1100 lemma MVT2:
  1101      "[| a < b; \<forall>x. a \<le> x & x \<le> b --> DERIV f x :> f'(x) |]
  1102       ==> \<exists>z::real. a < z & z < b & (f b - f a = (b - a) * f'(z))"
  1103 apply (drule MVT)
  1104 apply (blast intro: DERIV_isCont)
  1105 apply (force dest: order_less_imp_le simp add: differentiable_def)
  1106 apply (blast dest: DERIV_unique order_less_imp_le)
  1107 done
  1108 
  1109 
  1110 text{*A function is constant if its derivative is 0 over an interval.*}
  1111 
  1112 lemma DERIV_isconst_end:
  1113   fixes f :: "real => real"
  1114   shows "[| a < b;
  1115          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1116          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1117         ==> f b = f a"
  1118 apply (drule MVT, assumption)
  1119 apply (blast intro: differentiableI)
  1120 apply (auto dest!: DERIV_unique simp add: diff_eq_eq)
  1121 done
  1122 
  1123 lemma DERIV_isconst1:
  1124   fixes f :: "real => real"
  1125   shows "[| a < b;
  1126          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1127          \<forall>x. a < x & x < b --> DERIV f x :> 0 |]
  1128         ==> \<forall>x. a \<le> x & x \<le> b --> f x = f a"
  1129 apply safe
  1130 apply (drule_tac x = a in order_le_imp_less_or_eq, safe)
  1131 apply (drule_tac b = x in DERIV_isconst_end, auto)
  1132 done
  1133 
  1134 lemma DERIV_isconst2:
  1135   fixes f :: "real => real"
  1136   shows "[| a < b;
  1137          \<forall>x. a \<le> x & x \<le> b --> isCont f x;
  1138          \<forall>x. a < x & x < b --> DERIV f x :> 0;
  1139          a \<le> x; x \<le> b |]
  1140         ==> f x = f a"
  1141 apply (blast dest: DERIV_isconst1)
  1142 done
  1143 
  1144 lemma DERIV_isconst3: fixes a b x y :: real
  1145   assumes "a < b" and "x \<in> {a <..< b}" and "y \<in> {a <..< b}"
  1146   assumes derivable: "\<And>x. x \<in> {a <..< b} \<Longrightarrow> DERIV f x :> 0"
  1147   shows "f x = f y"
  1148 proof (cases "x = y")
  1149   case False
  1150   let ?a = "min x y"
  1151   let ?b = "max x y"
  1152   
  1153   have "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> DERIV f z :> 0"
  1154   proof (rule allI, rule impI)
  1155     fix z :: real assume "?a \<le> z \<and> z \<le> ?b"
  1156     hence "a < z" and "z < b" using `x \<in> {a <..< b}` and `y \<in> {a <..< b}` by auto
  1157     hence "z \<in> {a<..<b}" by auto
  1158     thus "DERIV f z :> 0" by (rule derivable)
  1159   qed
  1160   hence isCont: "\<forall>z. ?a \<le> z \<and> z \<le> ?b \<longrightarrow> isCont f z"
  1161     and DERIV: "\<forall>z. ?a < z \<and> z < ?b \<longrightarrow> DERIV f z :> 0" using DERIV_isCont by auto
  1162 
  1163   have "?a < ?b" using `x \<noteq> y` by auto
  1164   from DERIV_isconst2[OF this isCont DERIV, of x] and DERIV_isconst2[OF this isCont DERIV, of y]
  1165   show ?thesis by auto
  1166 qed auto
  1167 
  1168 lemma DERIV_isconst_all:
  1169   fixes f :: "real => real"
  1170   shows "\<forall>x. DERIV f x :> 0 ==> f(x) = f(y)"
  1171 apply (rule linorder_cases [of x y])
  1172 apply (blast intro: sym DERIV_isCont DERIV_isconst_end)+
  1173 done
  1174 
  1175 lemma DERIV_const_ratio_const:
  1176   fixes f :: "real => real"
  1177   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a)) = (b-a) * k"
  1178 apply (rule linorder_cases [of a b], auto)
  1179 apply (drule_tac [!] f = f in MVT)
  1180 apply (auto dest: DERIV_isCont DERIV_unique simp add: differentiable_def)
  1181 apply (auto dest: DERIV_unique simp add: ring_distribs diff_minus)
  1182 done
  1183 
  1184 lemma DERIV_const_ratio_const2:
  1185   fixes f :: "real => real"
  1186   shows "[|a \<noteq> b; \<forall>x. DERIV f x :> k |] ==> (f(b) - f(a))/(b-a) = k"
  1187 apply (rule_tac c1 = "b-a" in real_mult_right_cancel [THEN iffD1])
  1188 apply (auto dest!: DERIV_const_ratio_const simp add: mult_assoc)
  1189 done
  1190 
  1191 lemma real_average_minus_first [simp]: "((a + b) /2 - a) = (b-a)/(2::real)"
  1192 by (simp)
  1193 
  1194 lemma real_average_minus_second [simp]: "((b + a)/2 - a) = (b-a)/(2::real)"
  1195 by (simp)
  1196 
  1197 text{*Gallileo's "trick": average velocity = av. of end velocities*}
  1198 
  1199 lemma DERIV_const_average:
  1200   fixes v :: "real => real"
  1201   assumes neq: "a \<noteq> (b::real)"
  1202       and der: "\<forall>x. DERIV v x :> k"
  1203   shows "v ((a + b)/2) = (v a + v b)/2"
  1204 proof (cases rule: linorder_cases [of a b])
  1205   case equal with neq show ?thesis by simp
  1206 next
  1207   case less
  1208   have "(v b - v a) / (b - a) = k"
  1209     by (rule DERIV_const_ratio_const2 [OF neq der])
  1210   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1211   moreover have "(v ((a + b) / 2) - v a) / ((a + b) / 2 - a) = k"
  1212     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1213   ultimately show ?thesis using neq by force
  1214 next
  1215   case greater
  1216   have "(v b - v a) / (b - a) = k"
  1217     by (rule DERIV_const_ratio_const2 [OF neq der])
  1218   hence "(b-a) * ((v b - v a) / (b-a)) = (b-a) * k" by simp
  1219   moreover have " (v ((b + a) / 2) - v a) / ((b + a) / 2 - a) = k"
  1220     by (rule DERIV_const_ratio_const2 [OF _ der], simp add: neq)
  1221   ultimately show ?thesis using neq by (force simp add: add_commute)
  1222 qed
  1223 
  1224 (* A function with positive derivative is increasing. 
  1225    A simple proof using the MVT, by Jeremy Avigad. And variants.
  1226 *)
  1227 
  1228 lemma DERIV_pos_imp_increasing:
  1229   fixes a::real and b::real and f::"real => real"
  1230   assumes "a < b" and "\<forall>x. a \<le> x & x \<le> b --> (EX y. DERIV f x :> y & y > 0)"
  1231   shows "f a < f b"
  1232 proof (rule ccontr)
  1233   assume "~ f a < f b"
  1234   from assms have "EX l z. a < z & z < b & DERIV f z :> l
  1235       & f b - f a = (b - a) * l"
  1236     by (metis MVT DERIV_isCont differentiableI real_less_def)
  1237   then obtain l z where "a < z" and "z < b" and "DERIV f z :> l"
  1238       and "f b - f a = (b - a) * l"
  1239     by auto
  1240   
  1241   from prems have "~(l > 0)"
  1242     by (metis assms(1) linorder_not_le mult_le_0_iff real_le_eq_diff)
  1243   with prems show False
  1244     by (metis DERIV_unique real_less_def)
  1245 qed
  1246 
  1247 
  1248 lemma DERIV_nonneg_imp_nonincreasing:
  1249   fixes a::real and b::real and f::"real => real"
  1250   assumes "a \<le> b" and
  1251     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<ge> 0)"
  1252   shows "f a \<le> f b"
  1253 proof (rule ccontr, cases "a = b")
  1254   assume "~ f a \<le> f b"
  1255   assume "a = b"
  1256   with prems show False by auto
  1257   next assume "~ f a \<le> f b"
  1258   assume "a ~= b"
  1259   with assms have "EX l z. a < z & z < b & DERIV f z :> l
  1260       & f b - f a = (b - a) * l"
  1261     apply (intro MVT)
  1262     apply auto
  1263     apply (metis DERIV_isCont)
  1264     apply (metis differentiableI real_less_def)
  1265     done
  1266   then obtain l z where "a < z" and "z < b" and "DERIV f z :> l"
  1267       and "f b - f a = (b - a) * l"
  1268     by auto
  1269   from prems have "~(l >= 0)"
  1270     by (metis diff_self le_eqI le_iff_diff_le_0 real_le_anti_sym real_le_linear
  1271               split_mult_pos_le)
  1272   with prems show False
  1273     by (metis DERIV_unique order_less_imp_le)
  1274 qed
  1275 
  1276 lemma DERIV_neg_imp_decreasing:
  1277   fixes a::real and b::real and f::"real => real"
  1278   assumes "a < b" and
  1279     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y < 0)"
  1280   shows "f a > f b"
  1281 proof -
  1282   have "(%x. -f x) a < (%x. -f x) b"
  1283     apply (rule DERIV_pos_imp_increasing [of a b "%x. -f x"])
  1284     apply (insert prems, auto)
  1285     apply (metis DERIV_minus neg_0_less_iff_less)
  1286     done
  1287   thus ?thesis
  1288     by simp
  1289 qed
  1290 
  1291 lemma DERIV_nonpos_imp_nonincreasing:
  1292   fixes a::real and b::real and f::"real => real"
  1293   assumes "a \<le> b" and
  1294     "\<forall>x. a \<le> x & x \<le> b --> (\<exists>y. DERIV f x :> y & y \<le> 0)"
  1295   shows "f a \<ge> f b"
  1296 proof -
  1297   have "(%x. -f x) a \<le> (%x. -f x) b"
  1298     apply (rule DERIV_nonneg_imp_nonincreasing [of a b "%x. -f x"])
  1299     apply (insert prems, auto)
  1300     apply (metis DERIV_minus neg_0_le_iff_le)
  1301     done
  1302   thus ?thesis
  1303     by simp
  1304 qed
  1305 
  1306 subsection {* Continuous injective functions *}
  1307 
  1308 text{*Dull lemma: an continuous injection on an interval must have a
  1309 strict maximum at an end point, not in the middle.*}
  1310 
  1311 lemma lemma_isCont_inj:
  1312   fixes f :: "real \<Rightarrow> real"
  1313   assumes d: "0 < d"
  1314       and inj [rule_format]: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1315       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1316   shows "\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z"
  1317 proof (rule ccontr)
  1318   assume  "~ (\<exists>z. \<bar>z-x\<bar> \<le> d & f x < f z)"
  1319   hence all [rule_format]: "\<forall>z. \<bar>z - x\<bar> \<le> d --> f z \<le> f x" by auto
  1320   show False
  1321   proof (cases rule: linorder_le_cases [of "f(x-d)" "f(x+d)"])
  1322     case le
  1323     from d cont all [of "x+d"]
  1324     have flef: "f(x+d) \<le> f x"
  1325      and xlex: "x - d \<le> x"
  1326      and cont': "\<forall>z. x - d \<le> z \<and> z \<le> x \<longrightarrow> isCont f z"
  1327        by (auto simp add: abs_if)
  1328     from IVT [OF le flef xlex cont']
  1329     obtain x' where "x-d \<le> x'" "x' \<le> x" "f x' = f(x+d)" by blast
  1330     moreover
  1331     hence "g(f x') = g (f(x+d))" by simp
  1332     ultimately show False using d inj [of x'] inj [of "x+d"]
  1333       by (simp add: abs_le_iff)
  1334   next
  1335     case ge
  1336     from d cont all [of "x-d"]
  1337     have flef: "f(x-d) \<le> f x"
  1338      and xlex: "x \<le> x+d"
  1339      and cont': "\<forall>z. x \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z"
  1340        by (auto simp add: abs_if)
  1341     from IVT2 [OF ge flef xlex cont']
  1342     obtain x' where "x \<le> x'" "x' \<le> x+d" "f x' = f(x-d)" by blast
  1343     moreover
  1344     hence "g(f x') = g (f(x-d))" by simp
  1345     ultimately show False using d inj [of x'] inj [of "x-d"]
  1346       by (simp add: abs_le_iff)
  1347   qed
  1348 qed
  1349 
  1350 
  1351 text{*Similar version for lower bound.*}
  1352 
  1353 lemma lemma_isCont_inj2:
  1354   fixes f g :: "real \<Rightarrow> real"
  1355   shows "[|0 < d; \<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z;
  1356         \<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z |]
  1357       ==> \<exists>z. \<bar>z-x\<bar> \<le> d & f z < f x"
  1358 apply (insert lemma_isCont_inj
  1359           [where f = "%x. - f x" and g = "%y. g(-y)" and x = x and d = d])
  1360 apply (simp add: isCont_minus linorder_not_le)
  1361 done
  1362 
  1363 text{*Show there's an interval surrounding @{term "f(x)"} in
  1364 @{text "f[[x - d, x + d]]"} .*}
  1365 
  1366 lemma isCont_inj_range:
  1367   fixes f :: "real \<Rightarrow> real"
  1368   assumes d: "0 < d"
  1369       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1370       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1371   shows "\<exists>e>0. \<forall>y. \<bar>y - f x\<bar> \<le> e --> (\<exists>z. \<bar>z-x\<bar> \<le> d & f z = y)"
  1372 proof -
  1373   have "x-d \<le> x+d" "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> isCont f z" using cont d
  1374     by (auto simp add: abs_le_iff)
  1375   from isCont_Lb_Ub [OF this]
  1376   obtain L M
  1377   where all1 [rule_format]: "\<forall>z. x-d \<le> z \<and> z \<le> x+d \<longrightarrow> L \<le> f z \<and> f z \<le> M"
  1378     and all2 [rule_format]:
  1379            "\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>z. x-d \<le> z \<and> z \<le> x+d \<and> f z = y)"
  1380     by auto
  1381   with d have "L \<le> f x & f x \<le> M" by simp
  1382   moreover have "L \<noteq> f x"
  1383   proof -
  1384     from lemma_isCont_inj2 [OF d inj cont]
  1385     obtain u where "\<bar>u - x\<bar> \<le> d" "f u < f x"  by auto
  1386     thus ?thesis using all1 [of u] by arith
  1387   qed
  1388   moreover have "f x \<noteq> M"
  1389   proof -
  1390     from lemma_isCont_inj [OF d inj cont]
  1391     obtain u where "\<bar>u - x\<bar> \<le> d" "f x < f u"  by auto
  1392     thus ?thesis using all1 [of u] by arith
  1393   qed
  1394   ultimately have "L < f x & f x < M" by arith
  1395   hence "0 < f x - L" "0 < M - f x" by arith+
  1396   from real_lbound_gt_zero [OF this]
  1397   obtain e where e: "0 < e" "e < f x - L" "e < M - f x" by auto
  1398   thus ?thesis
  1399   proof (intro exI conjI)
  1400     show "0<e" using e(1) .
  1401     show "\<forall>y. \<bar>y - f x\<bar> \<le> e \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y)"
  1402     proof (intro strip)
  1403       fix y::real
  1404       assume "\<bar>y - f x\<bar> \<le> e"
  1405       with e have "L \<le> y \<and> y \<le> M" by arith
  1406       from all2 [OF this]
  1407       obtain z where "x - d \<le> z" "z \<le> x + d" "f z = y" by blast
  1408       thus "\<exists>z. \<bar>z - x\<bar> \<le> d \<and> f z = y" 
  1409         by (force simp add: abs_le_iff)
  1410     qed
  1411   qed
  1412 qed
  1413 
  1414 
  1415 text{*Continuity of inverse function*}
  1416 
  1417 lemma isCont_inverse_function:
  1418   fixes f g :: "real \<Rightarrow> real"
  1419   assumes d: "0 < d"
  1420       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d --> g(f z) = z"
  1421       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d --> isCont f z"
  1422   shows "isCont g (f x)"
  1423 proof (simp add: isCont_iff LIM_eq)
  1424   show "\<forall>r. 0 < r \<longrightarrow>
  1425          (\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r)"
  1426   proof (intro strip)
  1427     fix r::real
  1428     assume r: "0<r"
  1429     from real_lbound_gt_zero [OF r d]
  1430     obtain e where e: "0 < e" and e_lt: "e < r \<and> e < d" by blast
  1431     with inj cont
  1432     have e_simps: "\<forall>z. \<bar>z-x\<bar> \<le> e --> g (f z) = z"
  1433                   "\<forall>z. \<bar>z-x\<bar> \<le> e --> isCont f z"   by auto
  1434     from isCont_inj_range [OF e this]
  1435     obtain e' where e': "0 < e'"
  1436         and all: "\<forall>y. \<bar>y - f x\<bar> \<le> e' \<longrightarrow> (\<exists>z. \<bar>z - x\<bar> \<le> e \<and> f z = y)"
  1437           by blast
  1438     show "\<exists>s>0. \<forall>z. z\<noteq>0 \<and> \<bar>z\<bar> < s \<longrightarrow> \<bar>g(f x + z) - g(f x)\<bar> < r"
  1439     proof (intro exI conjI)
  1440       show "0<e'" using e' .
  1441       show "\<forall>z. z \<noteq> 0 \<and> \<bar>z\<bar> < e' \<longrightarrow> \<bar>g (f x + z) - g (f x)\<bar> < r"
  1442       proof (intro strip)
  1443         fix z::real
  1444         assume z: "z \<noteq> 0 \<and> \<bar>z\<bar> < e'"
  1445         with e e_lt e_simps all [rule_format, of "f x + z"]
  1446         show "\<bar>g (f x + z) - g (f x)\<bar> < r" by force
  1447       qed
  1448     qed
  1449   qed
  1450 qed
  1451 
  1452 text {* Derivative of inverse function *}
  1453 
  1454 lemma DERIV_inverse_function:
  1455   fixes f g :: "real \<Rightarrow> real"
  1456   assumes der: "DERIV f (g x) :> D"
  1457   assumes neq: "D \<noteq> 0"
  1458   assumes a: "a < x" and b: "x < b"
  1459   assumes inj: "\<forall>y. a < y \<and> y < b \<longrightarrow> f (g y) = y"
  1460   assumes cont: "isCont g x"
  1461   shows "DERIV g x :> inverse D"
  1462 unfolding DERIV_iff2
  1463 proof (rule LIM_equal2)
  1464   show "0 < min (x - a) (b - x)"
  1465     using a b by arith 
  1466 next
  1467   fix y
  1468   assume "norm (y - x) < min (x - a) (b - x)"
  1469   hence "a < y" and "y < b" 
  1470     by (simp_all add: abs_less_iff)
  1471   thus "(g y - g x) / (y - x) =
  1472         inverse ((f (g y) - x) / (g y - g x))"
  1473     by (simp add: inj)
  1474 next
  1475   have "(\<lambda>z. (f z - f (g x)) / (z - g x)) -- g x --> D"
  1476     by (rule der [unfolded DERIV_iff2])
  1477   hence 1: "(\<lambda>z. (f z - x) / (z - g x)) -- g x --> D"
  1478     using inj a b by simp
  1479   have 2: "\<exists>d>0. \<forall>y. y \<noteq> x \<and> norm (y - x) < d \<longrightarrow> g y \<noteq> g x"
  1480   proof (safe intro!: exI)
  1481     show "0 < min (x - a) (b - x)"
  1482       using a b by simp
  1483   next
  1484     fix y
  1485     assume "norm (y - x) < min (x - a) (b - x)"
  1486     hence y: "a < y" "y < b"
  1487       by (simp_all add: abs_less_iff)
  1488     assume "g y = g x"
  1489     hence "f (g y) = f (g x)" by simp
  1490     hence "y = x" using inj y a b by simp
  1491     also assume "y \<noteq> x"
  1492     finally show False by simp
  1493   qed
  1494   have "(\<lambda>y. (f (g y) - x) / (g y - g x)) -- x --> D"
  1495     using cont 1 2 by (rule isCont_LIM_compose2)
  1496   thus "(\<lambda>y. inverse ((f (g y) - x) / (g y - g x)))
  1497         -- x --> inverse D"
  1498     using neq by (rule LIM_inverse)
  1499 qed
  1500 
  1501 
  1502 subsection {* Generalized Mean Value Theorem *}
  1503 
  1504 theorem GMVT:
  1505   fixes a b :: real
  1506   assumes alb: "a < b"
  1507   and fc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  1508   and fd: "\<forall>x. a < x \<and> x < b \<longrightarrow> f differentiable x"
  1509   and gc: "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont g x"
  1510   and gd: "\<forall>x. a < x \<and> x < b \<longrightarrow> g differentiable x"
  1511   shows "\<exists>g'c f'c c. DERIV g c :> g'c \<and> DERIV f c :> f'c \<and> a < c \<and> c < b \<and> ((f b - f a) * g'c) = ((g b - g a) * f'c)"
  1512 proof -
  1513   let ?h = "\<lambda>x. (f b - f a)*(g x) - (g b - g a)*(f x)"
  1514   from prems have "a < b" by simp
  1515   moreover have "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont ?h x"
  1516   proof -
  1517     have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. f b - f a) x" by simp
  1518     with gc have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. (f b - f a) * g x) x"
  1519       by (auto intro: isCont_mult)
  1520     moreover
  1521     have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. g b - g a) x" by simp
  1522     with fc have "\<forall>x. a <= x \<and> x <= b \<longrightarrow> isCont (\<lambda>x. (g b - g a) * f x) x"
  1523       by (auto intro: isCont_mult)
  1524     ultimately show ?thesis
  1525       by (fastsimp intro: isCont_diff)
  1526   qed
  1527   moreover
  1528   have "\<forall>x. a < x \<and> x < b \<longrightarrow> ?h differentiable x"
  1529   proof -
  1530     have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. f b - f a) differentiable x" by (simp add: differentiable_const)
  1531     with gd have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. (f b - f a) * g x) differentiable x" by (simp add: differentiable_mult)
  1532     moreover
  1533     have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. g b - g a) differentiable x" by (simp add: differentiable_const)
  1534     with fd have "\<forall>x. a < x \<and> x < b \<longrightarrow> (\<lambda>x. (g b - g a) * f x) differentiable x" by (simp add: differentiable_mult)
  1535     ultimately show ?thesis by (simp add: differentiable_diff)
  1536   qed
  1537   ultimately have "\<exists>l z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" by (rule MVT)
  1538   then obtain l where ldef: "\<exists>z. a < z \<and> z < b \<and> DERIV ?h z :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1539   then obtain c where cdef: "a < c \<and> c < b \<and> DERIV ?h c :> l \<and> ?h b - ?h a = (b - a) * l" ..
  1540 
  1541   from cdef have cint: "a < c \<and> c < b" by auto
  1542   with gd have "g differentiable c" by simp
  1543   hence "\<exists>D. DERIV g c :> D" by (rule differentiableD)
  1544   then obtain g'c where g'cdef: "DERIV g c :> g'c" ..
  1545 
  1546   from cdef have "a < c \<and> c < b" by auto
  1547   with fd have "f differentiable c" by simp
  1548   hence "\<exists>D. DERIV f c :> D" by (rule differentiableD)
  1549   then obtain f'c where f'cdef: "DERIV f c :> f'c" ..
  1550 
  1551   from cdef have "DERIV ?h c :> l" by auto
  1552   moreover
  1553   {
  1554     have "DERIV (\<lambda>x. (f b - f a) * g x) c :> g'c * (f b - f a)"
  1555       apply (insert DERIV_const [where k="f b - f a"])
  1556       apply (drule meta_spec [of _ c])
  1557       apply (drule DERIV_mult [OF _ g'cdef])
  1558       by simp
  1559     moreover have "DERIV (\<lambda>x. (g b - g a) * f x) c :> f'c * (g b - g a)"
  1560       apply (insert DERIV_const [where k="g b - g a"])
  1561       apply (drule meta_spec [of _ c])
  1562       apply (drule DERIV_mult [OF _ f'cdef])
  1563       by simp
  1564     ultimately have "DERIV ?h c :>  g'c * (f b - f a) - f'c * (g b - g a)"
  1565       by (simp add: DERIV_diff)
  1566   }
  1567   ultimately have leq: "l =  g'c * (f b - f a) - f'c * (g b - g a)" by (rule DERIV_unique)
  1568 
  1569   {
  1570     from cdef have "?h b - ?h a = (b - a) * l" by auto
  1571     also with leq have "\<dots> = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1572     finally have "?h b - ?h a = (b - a) * (g'c * (f b - f a) - f'c * (g b - g a))" by simp
  1573   }
  1574   moreover
  1575   {
  1576     have "?h b - ?h a =
  1577          ((f b)*(g b) - (f a)*(g b) - (g b)*(f b) + (g a)*(f b)) -
  1578           ((f b)*(g a) - (f a)*(g a) - (g b)*(f a) + (g a)*(f a))"
  1579       by (simp add: algebra_simps)
  1580     hence "?h b - ?h a = 0" by auto
  1581   }
  1582   ultimately have "(b - a) * (g'c * (f b - f a) - f'c * (g b - g a)) = 0" by auto
  1583   with alb have "g'c * (f b - f a) - f'c * (g b - g a) = 0" by simp
  1584   hence "g'c * (f b - f a) = f'c * (g b - g a)" by simp
  1585   hence "(f b - f a) * g'c = (g b - g a) * f'c" by (simp add: mult_ac)
  1586 
  1587   with g'cdef f'cdef cint show ?thesis by auto
  1588 qed
  1589 
  1590 
  1591 subsection {* Theorems about Limits *}
  1592 
  1593 (* need to rename second isCont_inverse *)
  1594 
  1595 lemma isCont_inv_fun:
  1596   fixes f g :: "real \<Rightarrow> real"
  1597   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1598          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1599       ==> isCont g (f x)"
  1600 by (rule isCont_inverse_function)
  1601 
  1602 lemma isCont_inv_fun_inv:
  1603   fixes f g :: "real \<Rightarrow> real"
  1604   shows "[| 0 < d;  
  1605          \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;  
  1606          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]  
  1607        ==> \<exists>e. 0 < e &  
  1608              (\<forall>y. 0 < \<bar>y - f(x)\<bar> & \<bar>y - f(x)\<bar> < e --> f(g(y)) = y)"
  1609 apply (drule isCont_inj_range)
  1610 prefer 2 apply (assumption, assumption, auto)
  1611 apply (rule_tac x = e in exI, auto)
  1612 apply (rotate_tac 2)
  1613 apply (drule_tac x = y in spec, auto)
  1614 done
  1615 
  1616 
  1617 text{*Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110*}
  1618 lemma LIM_fun_gt_zero:
  1619      "[| f -- c --> (l::real); 0 < l |]  
  1620          ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> 0 < f x)"
  1621 apply (auto simp add: LIM_eq)
  1622 apply (drule_tac x = "l/2" in spec, safe, force)
  1623 apply (rule_tac x = s in exI)
  1624 apply (auto simp only: abs_less_iff)
  1625 done
  1626 
  1627 lemma LIM_fun_less_zero:
  1628      "[| f -- c --> (l::real); l < 0 |]  
  1629       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x < 0)"
  1630 apply (auto simp add: LIM_eq)
  1631 apply (drule_tac x = "-l/2" in spec, safe, force)
  1632 apply (rule_tac x = s in exI)
  1633 apply (auto simp only: abs_less_iff)
  1634 done
  1635 
  1636 
  1637 lemma LIM_fun_not_zero:
  1638      "[| f -- c --> (l::real); l \<noteq> 0 |] 
  1639       ==> \<exists>r. 0 < r & (\<forall>x::real. x \<noteq> c & \<bar>c - x\<bar> < r --> f x \<noteq> 0)"
  1640 apply (cut_tac x = l and y = 0 in linorder_less_linear, auto)
  1641 apply (drule LIM_fun_less_zero)
  1642 apply (drule_tac [3] LIM_fun_gt_zero)
  1643 apply force+
  1644 done
  1645 
  1646 end