src/Pure/Isar/attrib.ML
author wenzelm
Sat Mar 28 17:21:11 2009 +0100 (2009-03-28)
changeset 30761 ac7570d80c3d
parent 30759 3bc78fbb9f57
child 31174 f1f1e9b53c81
permissions -rw-r--r--
renamed ProofContext.note_thmss_i to ProofContext.note_thmss, eliminated obsolete external version;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Symbolic representation of attributes -- with name and syntax.
     5 *)
     6 
     7 signature ATTRIB =
     8 sig
     9   type src = Args.src
    10   type binding = binding * src list
    11   val empty_binding: binding
    12   val print_attributes: theory -> unit
    13   val intern: theory -> xstring -> string
    14   val intern_src: theory -> src -> src
    15   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    16   val defined: theory -> string -> bool
    17   val attribute: theory -> src -> attribute
    18   val attribute_i: theory -> src -> attribute
    19   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    20   val map_specs: ('a -> 'att) ->
    21     (('c * 'a list) * 'b) list -> (('c * 'att list) * 'b) list
    22   val map_facts: ('a -> 'att) ->
    23     (('c * 'a list) * ('d * 'a list) list) list ->
    24     (('c * 'att list) * ('d * 'att list) list) list
    25   val map_facts_refs: ('a -> 'att) -> ('b -> 'fact) ->
    26     (('c * 'a list) * ('b * 'a list) list) list ->
    27     (('c * 'att list) * ('fact * 'att list) list) list
    28   val crude_closure: Proof.context -> src -> src
    29   val add_attributes: (bstring * (src -> attribute) * string) list -> theory -> theory
    30   val syntax: attribute context_parser -> src -> attribute
    31   val setup: Binding.binding -> attribute context_parser -> string -> theory -> theory
    32   val attribute_setup: bstring * Position.T -> Symbol_Pos.text * Position.T -> string ->
    33     theory -> theory
    34   val no_args: attribute -> src -> attribute
    35   val add_del: attribute -> attribute -> attribute context_parser
    36   val add_del_args: attribute -> attribute -> src -> attribute
    37   val thm_sel: Facts.interval list parser
    38   val thm: thm context_parser
    39   val thms: thm list context_parser
    40   val multi_thm: thm list context_parser
    41   val print_configs: Proof.context -> unit
    42   val internal: (morphism -> attribute) -> src
    43   val register_config: Config.value Config.T -> theory -> theory
    44   val config_bool: bstring -> bool -> bool Config.T * (theory -> theory)
    45   val config_int: bstring -> int -> int Config.T * (theory -> theory)
    46   val config_string: bstring -> string -> string Config.T * (theory -> theory)
    47   val config_bool_global: bstring -> bool -> bool Config.T * (theory -> theory)
    48   val config_int_global: bstring -> int -> int Config.T * (theory -> theory)
    49   val config_string_global: bstring -> string -> string Config.T * (theory -> theory)
    50 end;
    51 
    52 structure Attrib: ATTRIB =
    53 struct
    54 
    55 structure T = OuterLex;
    56 structure P = OuterParse;
    57 
    58 
    59 (* source and bindings *)
    60 
    61 type src = Args.src;
    62 
    63 type binding = binding * src list;
    64 val empty_binding: binding = (Binding.empty, []);
    65 
    66 
    67 
    68 (** named attributes **)
    69 
    70 (* theory data *)
    71 
    72 structure Attributes = TheoryDataFun
    73 (
    74   type T = (((src -> attribute) * string) * stamp) NameSpace.table;
    75   val empty = NameSpace.empty_table;
    76   val copy = I;
    77   val extend = I;
    78   fun merge _ tables : T = NameSpace.merge_tables (eq_snd (op =)) tables handle Symtab.DUP dup =>
    79     error ("Attempt to merge different versions of attribute " ^ quote dup);
    80 );
    81 
    82 fun print_attributes thy =
    83   let
    84     val attribs = Attributes.get thy;
    85     fun prt_attr (name, ((_, comment), _)) = Pretty.block
    86       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    87   in
    88     [Pretty.big_list "attributes:" (map prt_attr (NameSpace.extern_table attribs))]
    89     |> Pretty.chunks |> Pretty.writeln
    90   end;
    91 
    92 
    93 (* name space *)
    94 
    95 val intern = NameSpace.intern o #1 o Attributes.get;
    96 val intern_src = Args.map_name o intern;
    97 
    98 val extern = NameSpace.extern o #1 o Attributes.get o ProofContext.theory_of;
    99 
   100 
   101 (* pretty printing *)
   102 
   103 fun pretty_attribs _ [] = []
   104   | pretty_attribs ctxt srcs =
   105       [Pretty.enclose "[" "]"
   106         (Pretty.commas (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs))];
   107 
   108 
   109 (* get attributes *)
   110 
   111 val defined = Symtab.defined o #2 o Attributes.get;
   112 
   113 fun attribute_i thy =
   114   let
   115     val attrs = #2 (Attributes.get thy);
   116     fun attr src =
   117       let val ((name, _), pos) = Args.dest_src src in
   118         (case Symtab.lookup attrs name of
   119           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   120         | SOME ((att, _), _) => (Position.report (Markup.attribute name) pos; att src))
   121       end;
   122   in attr end;
   123 
   124 fun attribute thy = attribute_i thy o intern_src thy;
   125 
   126 fun eval_thms ctxt args = ProofContext.note_thmss Thm.theoremK
   127     [(Thm.empty_binding, args |> map (fn (a, atts) =>
   128         (ProofContext.get_fact ctxt a, map (attribute (ProofContext.theory_of ctxt)) atts)))] ctxt
   129   |> fst |> maps snd;
   130 
   131 
   132 (* attributed declarations *)
   133 
   134 fun map_specs f = map (apfst (apsnd (map f)));
   135 
   136 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   137 fun map_facts_refs f g = map_facts f #> map (apsnd (map (apfst g)));
   138 
   139 
   140 (* crude_closure *)
   141 
   142 (*Produce closure without knowing facts in advance! The following
   143   works reasonably well for attribute parsers that do not peek at the
   144   thm structure.*)
   145 
   146 fun crude_closure ctxt src =
   147  (try (fn () => attribute_i (ProofContext.theory_of ctxt) src
   148     (Context.Proof ctxt, Drule.asm_rl)) ();
   149   Args.closure src);
   150 
   151 
   152 (* add_attributes *)
   153 
   154 fun add_attributes raw_attrs thy =
   155   let
   156     val new_attrs =
   157       raw_attrs |> map (fn (name, att, comment) => (Binding.name name, ((att, comment), stamp ())));
   158     fun add attrs = fold (snd oo NameSpace.define (Sign.naming_of thy)) new_attrs attrs
   159       handle Symtab.DUP dup => error ("Duplicate declaration of attributes " ^ quote dup);
   160   in Attributes.map add thy end;
   161 
   162 
   163 (* attribute setup *)
   164 
   165 fun syntax scan src (context, th) =
   166   let val (f: attribute, context') = Args.syntax "attribute" scan src context
   167   in f (context', th) end;
   168 
   169 fun setup name scan comment = add_attributes [(Binding.name_of name, syntax scan, comment)];
   170 
   171 fun attribute_setup name (txt, pos) cmt =
   172   Context.theory_map (ML_Context.expression pos
   173     "val (name, scan, comment): binding * attribute context_parser * string"
   174     "Context.map_theory (Attrib.setup name scan comment)"
   175     ("(" ^ ML_Syntax.make_binding name ^ ", " ^ txt ^ ", " ^ ML_Syntax.print_string cmt ^ ")"));
   176 
   177 
   178 (* basic syntax *)
   179 
   180 fun no_args x = syntax (Scan.succeed x);
   181 
   182 fun add_del add del = (Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add));
   183 fun add_del_args add del = syntax (add_del add del);
   184 
   185 
   186 
   187 (** parsing attributed theorems **)
   188 
   189 val thm_sel = P.$$$ "(" |-- P.list1
   190  (P.nat --| P.minus -- P.nat >> Facts.FromTo ||
   191   P.nat --| P.minus >> Facts.From ||
   192   P.nat >> Facts.Single) --| P.$$$ ")";
   193 
   194 local
   195 
   196 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   197 
   198 fun gen_thm pick = Scan.depend (fn context =>
   199   let
   200     val thy = Context.theory_of context;
   201     val get = Context.cases (PureThy.get_fact context) ProofContext.get_fact context;
   202     val get_fact = get o Facts.Fact;
   203     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   204   in
   205     P.$$$ "[" |-- Args.attribs (intern thy) --| P.$$$ "]" >> (fn srcs =>
   206       let
   207         val atts = map (attribute_i thy) srcs;
   208         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   209       in (context', pick "" [th']) end)
   210     ||
   211     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   212       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   213      Scan.ahead (P.position fact_name) :|-- (fn (name, pos) =>
   214       Args.named_fact (get_named pos) -- Scan.option thm_sel
   215         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   216     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   217       let
   218         val ths = Facts.select thmref fact;
   219         val atts = map (attribute_i thy) srcs;
   220         val (context', ths') = Library.foldl_map (Library.apply atts) (context, ths);
   221       in (context', pick name ths') end)
   222   end);
   223 
   224 in
   225 
   226 val thm = gen_thm Facts.the_single;
   227 val multi_thm = gen_thm (K I);
   228 val thms = Scan.repeat multi_thm >> flat;
   229 
   230 end;
   231 
   232 
   233 
   234 (** basic attributes **)
   235 
   236 (* internal *)
   237 
   238 fun internal att = Args.src (("Pure.attribute", [T.mk_attribute att]), Position.none);
   239 
   240 val internal_att =
   241   syntax (Scan.lift Args.internal_attribute >> Morphism.form);
   242 
   243 
   244 (* tags *)
   245 
   246 val tagged = syntax (Scan.lift (Args.name -- Args.name) >> Thm.tag);
   247 val untagged = syntax (Scan.lift Args.name >> Thm.untag);
   248 
   249 val kind = syntax (Scan.lift Args.name >> Thm.kind);
   250 
   251 
   252 (* rule composition *)
   253 
   254 val COMP_att =
   255   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   256     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B))));
   257 
   258 val THEN_att =
   259   syntax (Scan.lift (Scan.optional (Args.bracks P.nat) 1) -- thm
   260     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B))));
   261 
   262 val OF_att =
   263   syntax (thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A)));
   264 
   265 
   266 (* rename_abs *)
   267 
   268 val rename_abs = syntax
   269   (Scan.lift (Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars')));
   270 
   271 
   272 (* unfold / fold definitions *)
   273 
   274 fun unfolded_syntax rule =
   275   syntax (thms >>
   276     (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths)));
   277 
   278 val unfolded = unfolded_syntax LocalDefs.unfold;
   279 val folded = unfolded_syntax LocalDefs.fold;
   280 
   281 
   282 (* rule cases *)
   283 
   284 val consumes = syntax (Scan.lift (Scan.optional P.nat 1) >> RuleCases.consumes);
   285 val case_names = syntax (Scan.lift (Scan.repeat1 Args.name) >> RuleCases.case_names);
   286 val case_conclusion =
   287   syntax (Scan.lift (Args.name -- Scan.repeat Args.name) >> RuleCases.case_conclusion);
   288 val params = syntax (Scan.lift (P.and_list1 (Scan.repeat Args.name)) >> RuleCases.params);
   289 
   290 
   291 (* rule format *)
   292 
   293 val rule_format = syntax (Args.mode "no_asm"
   294   >> (fn true => ObjectLogic.rule_format_no_asm | false => ObjectLogic.rule_format));
   295 
   296 val elim_format = no_args (Thm.rule_attribute (K Tactic.make_elim));
   297 
   298 
   299 (* misc rules *)
   300 
   301 val standard = no_args (Thm.rule_attribute (K Drule.standard));
   302 
   303 val no_vars = no_args (Thm.rule_attribute (fn context => fn th =>
   304   let
   305     val ctxt = Variable.set_body false (Context.proof_of context);
   306     val ((_, [th']), _) = Variable.import_thms true [th] ctxt;
   307   in th' end));
   308 
   309 val eta_long =
   310   no_args (Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion)));
   311 
   312 val rotated = syntax
   313   (Scan.lift (Scan.optional P.int 1) >> (fn n => Thm.rule_attribute (K (rotate_prems n))));
   314 
   315 val abs_def = no_args (Thm.rule_attribute (K Drule.abs_def));
   316 
   317 
   318 (* theory setup *)
   319 
   320 val _ = Context.>> (Context.map_theory
   321  (add_attributes
   322    [("attribute", internal_att, "internal attribute"),
   323     ("tagged", tagged, "tagged theorem"),
   324     ("untagged", untagged, "untagged theorem"),
   325     ("kind", kind, "theorem kind"),
   326     ("COMP", COMP_att, "direct composition with rules (no lifting)"),
   327     ("THEN", THEN_att, "resolution with rule"),
   328     ("OF", OF_att, "rule applied to facts"),
   329     ("rename_abs", rename_abs, "rename bound variables in abstractions"),
   330     ("unfolded", unfolded, "unfolded definitions"),
   331     ("folded", folded, "folded definitions"),
   332     ("standard", standard, "result put into standard form"),
   333     ("elim_format", elim_format, "destruct rule turned into elimination rule format"),
   334     ("no_vars", no_vars, "frozen schematic vars"),
   335     ("eta_long", eta_long, "put theorem into eta long beta normal form"),
   336     ("consumes", consumes, "number of consumed facts"),
   337     ("case_names", case_names, "named rule cases"),
   338     ("case_conclusion", case_conclusion, "named conclusion of rule cases"),
   339     ("params", params, "named rule parameters"),
   340     ("atomize", no_args ObjectLogic.declare_atomize, "declaration of atomize rule"),
   341     ("rulify", no_args ObjectLogic.declare_rulify, "declaration of rulify rule"),
   342     ("rule_format", rule_format, "result put into standard rule format"),
   343     ("rotated", rotated, "rotated theorem premises"),
   344     ("defn", add_del_args LocalDefs.defn_add LocalDefs.defn_del,
   345       "declaration of definitional transformations"),
   346     ("abs_def", abs_def, "abstract over free variables of a definition")]));
   347 
   348 
   349 
   350 (** configuration options **)
   351 
   352 (* naming *)
   353 
   354 structure Configs = TheoryDataFun
   355 (
   356   type T = Config.value Config.T Symtab.table;
   357   val empty = Symtab.empty;
   358   val copy = I;
   359   val extend = I;
   360   fun merge _ = Symtab.merge (K true);
   361 );
   362 
   363 fun print_configs ctxt =
   364   let
   365     val thy = ProofContext.theory_of ctxt;
   366     fun prt (name, config) =
   367       let val value = Config.get ctxt config in
   368         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   369           Pretty.str (Config.print_value value)]
   370       end;
   371     val configs = NameSpace.extern_table (#1 (Attributes.get thy), Configs.get thy);
   372   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   373 
   374 
   375 (* concrete syntax *)
   376 
   377 local
   378 
   379 val equals = P.$$$ "=";
   380 
   381 fun scan_value (Config.Bool _) =
   382       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   383       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   384       Scan.succeed (Config.Bool true)
   385   | scan_value (Config.Int _) = equals |-- P.int >> Config.Int
   386   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   387 
   388 fun scan_config thy config =
   389   let val config_type = Config.get_thy thy config
   390   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   391 
   392 in
   393 
   394 fun register_config config thy =
   395   let
   396     val bname = Config.name_of config;
   397     val name = Sign.full_bname thy bname;
   398   in
   399     thy
   400     |> add_attributes [(bname, syntax (Scan.lift (scan_config thy config) >> Morphism.form),
   401       "configuration option")]
   402     |> Configs.map (Symtab.update (name, config))
   403   end;
   404 
   405 fun declare_config make coerce global name default =
   406   let
   407     val config_value = Config.declare global name (make default);
   408     val config = coerce config_value;
   409   in (config, register_config config_value) end;
   410 
   411 val config_bool   = declare_config Config.Bool Config.bool false;
   412 val config_int    = declare_config Config.Int Config.int false;
   413 val config_string = declare_config Config.String Config.string false;
   414 
   415 val config_bool_global   = declare_config Config.Bool Config.bool true;
   416 val config_int_global    = declare_config Config.Int Config.int true;
   417 val config_string_global = declare_config Config.String Config.string true;
   418 
   419 end;
   420 
   421 
   422 (* theory setup *)
   423 
   424 val _ = Context.>> (Context.map_theory
   425  (register_config Unify.trace_bound_value #>
   426   register_config Unify.search_bound_value #>
   427   register_config Unify.trace_simp_value #>
   428   register_config Unify.trace_types_value #>
   429   register_config MetaSimplifier.simp_depth_limit_value));
   430 
   431 end;