src/Tools/Code/code_thingol.ML
author haftmann
Tue Jun 05 07:05:56 2012 +0200 (2012-06-05)
changeset 48072 ace701efe203
parent 48003 1d11af40b106
child 48074 c6d514717d7b
permissions -rw-r--r--
prefer records with speaking labels over deeply nested tuples
     1 (*  Title:      Tools/Code/code_thingol.ML
     2     Author:     Florian Haftmann, TU Muenchen
     3 
     4 Intermediate language ("Thin-gol") representing executable code.
     5 Representation and translation.
     6 *)
     7 
     8 infix 8 `%%;
     9 infix 4 `$;
    10 infix 4 `$$;
    11 infixr 3 `|=>;
    12 infixr 3 `|==>;
    13 
    14 signature BASIC_CODE_THINGOL =
    15 sig
    16   type vname = string;
    17   datatype dict =
    18       Dict of string list * plain_dict
    19   and plain_dict = 
    20       Dict_Const of string * dict list list
    21     | Dict_Var of vname * (int * int);
    22   datatype itype =
    23       `%% of string * itype list
    24     | ITyVar of vname;
    25   type const = { name: string, typargs: itype list, dicts: dict list list,
    26     dom: itype list, range: itype, annotate: bool };
    27   datatype iterm =
    28       IConst of const
    29     | IVar of vname option
    30     | `$ of iterm * iterm
    31     | `|=> of (vname option * itype) * iterm
    32     | ICase of { term: iterm, typ: itype, clauses: (iterm * iterm) list, primitive: iterm };
    33   val `$$ : iterm * iterm list -> iterm;
    34   val `|==> : (vname option * itype) list * iterm -> iterm;
    35   type typscheme = (vname * sort) list * itype;
    36 end;
    37 
    38 signature CODE_THINGOL =
    39 sig
    40   include BASIC_CODE_THINGOL
    41   val fun_tyco: string
    42   val unfoldl: ('a -> ('a * 'b) option) -> 'a -> 'a * 'b list
    43   val unfoldr: ('a -> ('b * 'a) option) -> 'a -> 'b list * 'a
    44   val unfold_fun: itype -> itype list * itype
    45   val unfold_fun_n: int -> itype -> itype list * itype
    46   val unfold_app: iterm -> iterm * iterm list
    47   val unfold_abs: iterm -> (vname option * itype) list * iterm
    48   val split_let: iterm -> (((iterm * itype) * iterm) * iterm) option
    49   val unfold_let: iterm -> ((iterm * itype) * iterm) list * iterm
    50   val split_pat_abs: iterm -> ((iterm * itype) * iterm) option
    51   val unfold_pat_abs: iterm -> (iterm * itype) list * iterm
    52   val unfold_const_app: iterm -> (const * iterm list) option
    53   val is_IVar: iterm -> bool
    54   val is_IAbs: iterm -> bool
    55   val eta_expand: int -> const * iterm list -> iterm
    56   val contains_dict_var: iterm -> bool
    57   val add_constnames: iterm -> string list -> string list
    58   val add_tyconames: iterm -> string list -> string list
    59   val fold_varnames: (string -> 'a -> 'a) -> iterm -> 'a -> 'a
    60 
    61   type naming
    62   val empty_naming: naming
    63   val lookup_class: naming -> class -> string option
    64   val lookup_classrel: naming -> class * class -> string option
    65   val lookup_tyco: naming -> string -> string option
    66   val lookup_instance: naming -> class * string -> string option
    67   val lookup_const: naming -> string -> string option
    68   val ensure_declared_const: theory -> string -> naming -> string * naming
    69 
    70   datatype stmt =
    71       NoStmt
    72     | Fun of string * ((typscheme * ((iterm list * iterm) * (thm option * bool)) list) * thm option)
    73     | Datatype of string * (vname list *
    74         ((string * vname list (*type argument wrt. canonical order*)) * itype list) list)
    75     | Datatypecons of string * string
    76     | Class of class * (vname * ((class * string) list * (string * itype) list))
    77     | Classrel of class * class
    78     | Classparam of string * class
    79     | Classinst of { class: string, tyco: string, vs: (vname * sort) list,
    80         superinsts: (class * (string * (string * dict list list))) list,
    81         inst_params: ((string * const) * (thm * bool)) list,
    82         superinst_params: ((string * const) * (thm * bool)) list };
    83   type program = stmt Graph.T
    84   val empty_funs: program -> string list
    85   val map_terms_bottom_up: (iterm -> iterm) -> iterm -> iterm
    86   val map_terms_stmt: (iterm -> iterm) -> stmt -> stmt
    87   val is_cons: program -> string -> bool
    88   val is_case: stmt -> bool
    89   val labelled_name: theory -> program -> string -> string
    90   val group_stmts: theory -> program
    91     -> ((string * stmt) list * (string * stmt) list
    92       * ((string * stmt) list * (string * stmt) list)) list
    93 
    94   val read_const_exprs: theory -> string list -> string list * string list
    95   val consts_program: theory -> bool -> string list -> string list * (naming * program)
    96   val dynamic_conv: theory -> (naming -> program
    97     -> ((string * sort) list * typscheme) * iterm -> string list -> conv)
    98     -> conv
    99   val dynamic_value: theory -> ((term -> term) -> 'a -> 'a) -> (naming -> program
   100     -> ((string * sort) list * typscheme) * iterm -> string list -> 'a)
   101     -> term -> 'a
   102   val static_conv: theory -> string list -> (naming -> program -> string list
   103     -> ((string * sort) list * typscheme) * iterm -> string list -> conv)
   104     -> conv
   105   val static_conv_simple: theory -> string list
   106     -> (program -> (string * sort) list -> term -> conv) -> conv
   107   val static_value: theory -> ((term -> term) -> 'a -> 'a) -> string list ->
   108     (naming -> program -> string list
   109       -> ((string * sort) list * typscheme) * iterm -> string list -> 'a)
   110     -> term -> 'a
   111 end;
   112 
   113 structure Code_Thingol: CODE_THINGOL =
   114 struct
   115 
   116 (** auxiliary **)
   117 
   118 fun unfoldl dest x =
   119   case dest x
   120    of NONE => (x, [])
   121     | SOME (x1, x2) =>
   122         let val (x', xs') = unfoldl dest x1 in (x', xs' @ [x2]) end;
   123 
   124 fun unfoldr dest x =
   125   case dest x
   126    of NONE => ([], x)
   127     | SOME (x1, x2) =>
   128         let val (xs', x') = unfoldr dest x2 in (x1 :: xs', x') end;
   129 
   130 
   131 (** language core - types, terms **)
   132 
   133 type vname = string;
   134 
   135 datatype dict =
   136     Dict of string list * plain_dict
   137 and plain_dict = 
   138     Dict_Const of string * dict list list
   139   | Dict_Var of vname * (int * int);
   140 
   141 datatype itype =
   142     `%% of string * itype list
   143   | ITyVar of vname;
   144 
   145 type const = { name: string, typargs: itype list, dicts: dict list list,
   146   dom: itype list, range: itype, annotate: bool };
   147 
   148 datatype iterm =
   149     IConst of const
   150   | IVar of vname option
   151   | `$ of iterm * iterm
   152   | `|=> of (vname option * itype) * iterm
   153   | ICase of { term: iterm, typ: itype, clauses: (iterm * iterm) list, primitive: iterm };
   154     (*see also signature*)
   155 
   156 fun is_IVar (IVar _) = true
   157   | is_IVar _ = false;
   158 
   159 fun is_IAbs (_ `|=> _) = true
   160   | is_IAbs _ = false;
   161 
   162 val op `$$ = Library.foldl (op `$);
   163 val op `|==> = Library.foldr (op `|=>);
   164 
   165 val unfold_app = unfoldl
   166   (fn op `$ t => SOME t
   167     | _ => NONE);
   168 
   169 val unfold_abs = unfoldr
   170   (fn op `|=> t => SOME t
   171     | _ => NONE);
   172 
   173 val split_let = 
   174   (fn ICase { term = t, typ = ty, clauses = [(p, body)], ... } => SOME (((p, ty), t), body)
   175     | _ => NONE);
   176 
   177 val unfold_let = unfoldr split_let;
   178 
   179 fun unfold_const_app t =
   180  case unfold_app t
   181   of (IConst c, ts) => SOME (c, ts)
   182    | _ => NONE;
   183 
   184 fun fold_constexprs f =
   185   let
   186     fun fold' (IConst c) = f c
   187       | fold' (IVar _) = I
   188       | fold' (t1 `$ t2) = fold' t1 #> fold' t2
   189       | fold' (_ `|=> t) = fold' t
   190       | fold' (ICase { term = t, clauses = clauses, ... }) = fold' t
   191           #> fold (fn (p, body) => fold' p #> fold' body) clauses
   192   in fold' end;
   193 
   194 val add_constnames = fold_constexprs (fn { name = c, ... } => insert (op =) c);
   195 
   196 fun add_tycos (tyco `%% tys) = insert (op =) tyco #> fold add_tycos tys
   197   | add_tycos (ITyVar _) = I;
   198 
   199 val add_tyconames = fold_constexprs (fn { typargs = tys, ... } => fold add_tycos tys);
   200 
   201 fun fold_varnames f =
   202   let
   203     fun fold_aux add f =
   204       let
   205         fun fold_term _ (IConst _) = I
   206           | fold_term vs (IVar (SOME v)) = if member (op =) vs v then I else f v
   207           | fold_term _ (IVar NONE) = I
   208           | fold_term vs (t1 `$ t2) = fold_term vs t1 #> fold_term vs t2
   209           | fold_term vs ((SOME v, _) `|=> t) = fold_term (insert (op =) v vs) t
   210           | fold_term vs ((NONE, _) `|=> t) = fold_term vs t
   211           | fold_term vs (ICase { term = t, clauses = clauses, ... }) = fold_term vs t #> fold (fold_case vs) clauses
   212         and fold_case vs (p, t) = fold_term (add p vs) t;
   213       in fold_term [] end;
   214     fun add t = fold_aux add (insert (op =)) t;
   215   in fold_aux add f end;
   216 
   217 fun exists_var t v = fold_varnames (fn w => fn b => v = w orelse b) t false;
   218 
   219 fun split_pat_abs ((NONE, ty) `|=> t) = SOME ((IVar NONE, ty), t)
   220   | split_pat_abs ((SOME v, ty) `|=> t) = SOME (case t
   221      of ICase { term = IVar (SOME w), clauses = [(p, body)], ... } =>
   222           if v = w andalso (exists_var p v orelse not (exists_var body v))
   223           then ((p, ty), body)
   224           else ((IVar (SOME v), ty), t)
   225       | _ => ((IVar (SOME v), ty), t))
   226   | split_pat_abs _ = NONE;
   227 
   228 val unfold_pat_abs = unfoldr split_pat_abs;
   229 
   230 fun unfold_abs_eta [] t = ([], t)
   231   | unfold_abs_eta (_ :: tys) (v_ty `|=> t) =
   232       let
   233         val (vs_tys, t') = unfold_abs_eta tys t;
   234       in (v_ty :: vs_tys, t') end
   235   | unfold_abs_eta tys t =
   236       let
   237         val ctxt = fold_varnames Name.declare t Name.context;
   238         val vs_tys = (map o apfst) SOME (Name.invent_names ctxt "a" tys);
   239       in (vs_tys, t `$$ map (IVar o fst) vs_tys) end;
   240 
   241 fun eta_expand k (const as { name = c, dom = tys, ... }, ts) =
   242   let
   243     val j = length ts;
   244     val l = k - j;
   245     val _ = if l > length tys
   246       then error ("Impossible eta-expansion for constant " ^ quote c) else ();
   247     val ctxt = (fold o fold_varnames) Name.declare ts Name.context;
   248     val vs_tys = (map o apfst) SOME
   249       (Name.invent_names ctxt "a" ((take l o drop j) tys));
   250   in vs_tys `|==> IConst const `$$ ts @ map (IVar o fst) vs_tys end;
   251 
   252 fun contains_dict_var t =
   253   let
   254     fun cont_dict (Dict (_, d)) = cont_plain_dict d
   255     and cont_plain_dict (Dict_Const (_, dss)) = (exists o exists) cont_dict dss
   256       | cont_plain_dict (Dict_Var _) = true;
   257     fun cont_term (IConst { dicts = dss, ... }) = (exists o exists) cont_dict dss
   258       | cont_term (IVar _) = false
   259       | cont_term (t1 `$ t2) = cont_term t1 orelse cont_term t2
   260       | cont_term (_ `|=> t) = cont_term t
   261       | cont_term (ICase { primitive = t, ... }) = cont_term t;
   262   in cont_term t end;
   263 
   264 
   265 (** namings **)
   266 
   267 (* policies *)
   268 
   269 local
   270   fun thyname_of_type thy = #theory_name o Name_Space.the_entry (Sign.type_space thy);
   271   fun thyname_of_class thy = #theory_name o Name_Space.the_entry (Sign.class_space thy);
   272   fun thyname_of_instance thy inst = case AxClass.thynames_of_arity thy inst
   273    of [] => error ("No such instance: " ^ quote (snd inst ^ " :: " ^ fst inst))
   274     | thyname :: _ => thyname;
   275   fun thyname_of_const thy c = case AxClass.class_of_param thy c
   276    of SOME class => thyname_of_class thy class
   277     | NONE => (case Code.get_type_of_constr_or_abstr thy c
   278        of SOME (tyco, _) => thyname_of_type thy tyco
   279         | NONE => #theory_name (Name_Space.the_entry (Sign.const_space thy) c));
   280   fun purify_base "==>" = "follows"
   281     | purify_base "==" = "meta_eq"
   282     | purify_base s = Name.desymbolize false s;
   283   fun namify thy get_basename get_thyname name =
   284     let
   285       val prefix = get_thyname thy name;
   286       val base = (purify_base o get_basename) name;
   287     in Long_Name.append prefix base end;
   288 in
   289 
   290 fun namify_class thy = namify thy Long_Name.base_name thyname_of_class;
   291 fun namify_classrel thy = namify thy (fn (sub_class, super_class) => 
   292     Long_Name.base_name super_class ^ "_" ^ Long_Name.base_name sub_class)
   293   (fn thy => thyname_of_class thy o fst);
   294   (*order fits nicely with composed projections*)
   295 fun namify_tyco thy "fun" = "Pure.fun"
   296   | namify_tyco thy tyco = namify thy Long_Name.base_name thyname_of_type tyco;
   297 fun namify_instance thy = namify thy (fn (class, tyco) => 
   298   Long_Name.base_name class ^ "_" ^ Long_Name.base_name tyco) thyname_of_instance;
   299 fun namify_const thy = namify thy Long_Name.base_name thyname_of_const;
   300 
   301 end; (* local *)
   302 
   303 
   304 (* data *)
   305 
   306 datatype naming = Naming of {
   307   class: class Symtab.table * Name.context,
   308   classrel: string Symreltab.table * Name.context,
   309   tyco: string Symtab.table * Name.context,
   310   instance: string Symreltab.table * Name.context,
   311   const: string Symtab.table * Name.context
   312 }
   313 
   314 fun dest_Naming (Naming naming) = naming;
   315 
   316 val empty_naming = Naming {
   317   class = (Symtab.empty, Name.context),
   318   classrel = (Symreltab.empty, Name.context),
   319   tyco = (Symtab.empty, Name.context),
   320   instance = (Symreltab.empty, Name.context),
   321   const = (Symtab.empty, Name.context)
   322 };
   323 
   324 local
   325   fun mk_naming (class, classrel, tyco, instance, const) =
   326     Naming { class = class, classrel = classrel,
   327       tyco = tyco, instance = instance, const = const };
   328   fun map_naming f (Naming { class, classrel, tyco, instance, const }) =
   329     mk_naming (f (class, classrel, tyco, instance, const));
   330 in
   331   fun map_class f = map_naming
   332     (fn (class, classrel, tyco, inst, const) =>
   333       (f class, classrel, tyco, inst, const));
   334   fun map_classrel f = map_naming
   335     (fn (class, classrel, tyco, inst, const) =>
   336       (class, f classrel, tyco, inst, const));
   337   fun map_tyco f = map_naming
   338     (fn (class, classrel, tyco, inst, const) =>
   339       (class, classrel, f tyco, inst, const));
   340   fun map_instance f = map_naming
   341     (fn (class, classrel, tyco, inst, const) =>
   342       (class, classrel, tyco, f inst, const));
   343   fun map_const f = map_naming
   344     (fn (class, classrel, tyco, inst, const) =>
   345       (class, classrel, tyco, inst, f const));
   346 end; (*local*)
   347 
   348 fun add_variant update (thing, name) (tab, used) =
   349   let
   350     val (name', used') = Name.variant name used;
   351     val tab' = update (thing, name') tab;
   352   in (tab', used') end;
   353 
   354 fun declare thy mapp lookup update namify thing =
   355   mapp (add_variant update (thing, namify thy thing))
   356   #> `(fn naming => the (lookup naming thing));
   357 
   358 
   359 (* lookup and declare *)
   360 
   361 local
   362 
   363 val suffix_class = "class";
   364 val suffix_classrel = "classrel"
   365 val suffix_tyco = "tyco";
   366 val suffix_instance = "inst";
   367 val suffix_const = "const";
   368 
   369 fun add_suffix nsp NONE = NONE
   370   | add_suffix nsp (SOME name) = SOME (Long_Name.append name nsp);
   371 
   372 in
   373 
   374 val lookup_class = add_suffix suffix_class
   375   oo Symtab.lookup o fst o #class o dest_Naming;
   376 val lookup_classrel = add_suffix suffix_classrel
   377   oo Symreltab.lookup o fst o #classrel o dest_Naming;
   378 val lookup_tyco = add_suffix suffix_tyco
   379   oo Symtab.lookup o fst o #tyco o dest_Naming;
   380 val lookup_instance = add_suffix suffix_instance
   381   oo Symreltab.lookup o fst o #instance o dest_Naming;
   382 val lookup_const = add_suffix suffix_const
   383   oo Symtab.lookup o fst o #const o dest_Naming;
   384 
   385 fun declare_class thy = declare thy map_class
   386   lookup_class Symtab.update_new namify_class;
   387 fun declare_classrel thy = declare thy map_classrel
   388   lookup_classrel Symreltab.update_new namify_classrel;
   389 fun declare_tyco thy = declare thy map_tyco
   390   lookup_tyco Symtab.update_new namify_tyco;
   391 fun declare_instance thy = declare thy map_instance
   392   lookup_instance Symreltab.update_new namify_instance;
   393 fun declare_const thy = declare thy map_const
   394   lookup_const Symtab.update_new namify_const;
   395 
   396 fun ensure_declared_const thy const naming =
   397   case lookup_const naming const
   398    of SOME const' => (const', naming)
   399     | NONE => declare_const thy const naming;
   400 
   401 val fun_tyco = Long_Name.append (namify_tyco Pure.thy "fun") suffix_tyco
   402   (*depends on add_suffix*);
   403 
   404 val unfold_fun = unfoldr
   405   (fn tyco `%% [ty1, ty2] => if tyco = fun_tyco then SOME (ty1, ty2) else NONE
   406     | _ => NONE);
   407 
   408 fun unfold_fun_n n ty =
   409   let
   410     val (tys1, ty1) = unfold_fun ty;
   411     val (tys3, tys2) = chop n tys1;
   412     val ty3 = Library.foldr (fn (ty1, ty2) => fun_tyco `%% [ty1, ty2]) (tys2, ty1);
   413   in (tys3, ty3) end;
   414 
   415 end; (* local *)
   416 
   417 
   418 (** statements, abstract programs **)
   419 
   420 type typscheme = (vname * sort) list * itype;
   421 datatype stmt =
   422     NoStmt
   423   | Fun of string * ((typscheme * ((iterm list * iterm) * (thm option * bool)) list) * thm option)
   424   | Datatype of string * (vname list * ((string * vname list) * itype list) list)
   425   | Datatypecons of string * string
   426   | Class of class * (vname * ((class * string) list * (string * itype) list))
   427   | Classrel of class * class
   428   | Classparam of string * class
   429   | Classinst of { class: string, tyco: string, vs: (vname * sort) list,
   430       superinsts: (class * (string * (string * dict list list))) list,
   431       inst_params: ((string * const) * (thm * bool)) list,
   432       superinst_params: ((string * const) * (thm * bool)) list };
   433 
   434 type program = stmt Graph.T;
   435 
   436 fun empty_funs program =
   437   Graph.fold (fn (_, (Fun (c, ((_, []), _)), _)) => cons c | _ => I) program [];
   438 
   439 fun map_terms_bottom_up f (t as IConst _) = f t
   440   | map_terms_bottom_up f (t as IVar _) = f t
   441   | map_terms_bottom_up f (t1 `$ t2) = f
   442       (map_terms_bottom_up f t1 `$ map_terms_bottom_up f t2)
   443   | map_terms_bottom_up f ((v, ty) `|=> t) = f
   444       ((v, ty) `|=> map_terms_bottom_up f t)
   445   | map_terms_bottom_up f (ICase { term = t, typ = ty, clauses = clauses, primitive = t0 }) = f
   446       (ICase { term = map_terms_bottom_up f t, typ = ty,
   447         clauses = (map o pairself) (map_terms_bottom_up f) clauses,
   448         primitive = map_terms_bottom_up f t0 });
   449 
   450 fun map_classparam_instances_as_term f =
   451   (map o apfst o apsnd) (fn const => case f (IConst const) of IConst const' => const')
   452 
   453 fun map_terms_stmt f NoStmt = NoStmt
   454   | map_terms_stmt f (Fun (c, ((tysm, eqs), case_cong))) = Fun (c, ((tysm, (map o apfst)
   455       (fn (ts, t) => (map f ts, f t)) eqs), case_cong))
   456   | map_terms_stmt f (stmt as Datatype _) = stmt
   457   | map_terms_stmt f (stmt as Datatypecons _) = stmt
   458   | map_terms_stmt f (stmt as Class _) = stmt
   459   | map_terms_stmt f (stmt as Classrel _) = stmt
   460   | map_terms_stmt f (stmt as Classparam _) = stmt
   461   | map_terms_stmt f (Classinst { class, tyco, vs, superinsts,
   462       inst_params, superinst_params }) =
   463         Classinst { class = class, tyco = tyco, vs = vs, superinsts = superinsts,
   464           inst_params = map_classparam_instances_as_term f inst_params,
   465           superinst_params = map_classparam_instances_as_term f superinst_params };
   466 
   467 fun is_cons program name = case Graph.get_node program name
   468  of Datatypecons _ => true
   469   | _ => false;
   470 
   471 fun is_case (Fun (_, (_, SOME _))) = true
   472   | is_case _ = false;
   473 
   474 fun labelled_name thy program name =
   475   let val ctxt = Proof_Context.init_global thy in
   476     case Graph.get_node program name of
   477       Fun (c, _) => quote (Code.string_of_const thy c)
   478     | Datatype (tyco, _) => "type " ^ quote (Proof_Context.extern_type ctxt tyco)
   479     | Datatypecons (c, _) => quote (Code.string_of_const thy c)
   480     | Class (class, _) => "class " ^ quote (Proof_Context.extern_class ctxt class)
   481     | Classrel (sub, super) =>
   482         let
   483           val Class (sub, _) = Graph.get_node program sub;
   484           val Class (super, _) = Graph.get_node program super;
   485         in
   486           quote (Proof_Context.extern_class ctxt sub ^ " < " ^ Proof_Context.extern_class ctxt super)
   487         end
   488     | Classparam (c, _) => quote (Code.string_of_const thy c)
   489     | Classinst { class, tyco, ... } =>
   490         let
   491           val Class (class, _) = Graph.get_node program class;
   492           val Datatype (tyco, _) = Graph.get_node program tyco;
   493         in
   494           quote (Proof_Context.extern_type ctxt tyco ^ " :: " ^ Proof_Context.extern_class ctxt class)
   495         end
   496   end;
   497 
   498 fun linear_stmts program =
   499   rev (Graph.strong_conn program)
   500   |> map (AList.make (Graph.get_node program));
   501 
   502 fun group_stmts thy program =
   503   let
   504     fun is_fun (_, Fun _) = true | is_fun _ = false;
   505     fun is_datatypecons (_, Datatypecons _) = true | is_datatypecons _ = false;
   506     fun is_datatype (_, Datatype _) = true | is_datatype _ = false;
   507     fun is_class (_, Class _) = true | is_class _ = false;
   508     fun is_classrel (_, Classrel _) = true | is_classrel _ = false;
   509     fun is_classparam (_, Classparam _) = true | is_classparam _ = false;
   510     fun is_classinst (_, Classinst _) = true | is_classinst _ = false;
   511     fun group stmts =
   512       if forall (is_datatypecons orf is_datatype) stmts
   513       then (filter is_datatype stmts, [], ([], []))
   514       else if forall (is_class orf is_classrel orf is_classparam) stmts
   515       then ([], filter is_class stmts, ([], []))
   516       else if forall (is_fun orf is_classinst) stmts
   517       then ([], [], List.partition is_fun stmts)
   518       else error ("Illegal mutual dependencies: " ^
   519         (commas o map (labelled_name thy program o fst)) stmts)
   520   in
   521     linear_stmts program
   522     |> map group
   523   end;
   524 
   525 
   526 (** translation kernel **)
   527 
   528 (* generic mechanisms *)
   529 
   530 fun ensure_stmt lookup declare generate thing (dep, (naming, program)) =
   531   let
   532     fun add_dep name = case dep of NONE => I
   533       | SOME dep => Graph.add_edge (dep, name);
   534     val (name, naming') = case lookup naming thing
   535      of SOME name => (name, naming)
   536       | NONE => declare thing naming;
   537   in
   538     if can (Graph.get_node program) name
   539     then
   540       program
   541       |> add_dep name
   542       |> pair naming'
   543       |> pair dep
   544       |> pair name
   545     else
   546       program
   547       |> Graph.default_node (name, NoStmt)
   548       |> add_dep name
   549       |> pair naming'
   550       |> curry generate (SOME name)
   551       ||> snd
   552       |-> (fn stmt => (apsnd o Graph.map_node name) (K stmt))
   553       |> pair dep
   554       |> pair name
   555   end;
   556 
   557 exception PERMISSIVE of unit;
   558 
   559 fun translation_error thy permissive some_thm msg sub_msg =
   560   if permissive
   561   then raise PERMISSIVE ()
   562   else
   563     let
   564       val err_thm =
   565         (case some_thm of
   566           SOME thm => "\n(in code equation " ^ Display.string_of_thm_global thy thm ^ ")"
   567         | NONE => "");
   568     in error (msg ^ err_thm ^ ":\n" ^ sub_msg) end;
   569 
   570 fun not_wellsorted thy permissive some_thm ty sort e =
   571   let
   572     val err_class = Sorts.class_error (Context.pretty_global thy) e;
   573     val err_typ =
   574       "Type " ^ Syntax.string_of_typ_global thy ty ^ " not of sort " ^
   575         Syntax.string_of_sort_global thy sort;
   576   in
   577     translation_error thy permissive some_thm "Wellsortedness error"
   578       (err_typ ^ "\n" ^ err_class)
   579   end;
   580 
   581 
   582 (* inference of type annotations for disambiguation with type classes *)
   583 
   584 fun mk_tagged_type (true, T) = Type ("", [T])
   585   | mk_tagged_type (false, T) = T;
   586 
   587 fun dest_tagged_type (Type ("", [T])) = (true, T)
   588   | dest_tagged_type T = (false, T);
   589 
   590 val untag_term = map_types (snd o dest_tagged_type);
   591 
   592 fun tag_term (proj_sort, _) eqngr =
   593   let
   594     val has_sort_constraints = exists (not o null) o map proj_sort o Code_Preproc.sortargs eqngr;
   595     fun tag (Const (_, T')) (Const (c, T)) =
   596         Const (c,
   597           mk_tagged_type (not (null (Term.add_tvarsT T' [])) andalso has_sort_constraints c, T))
   598       | tag (t1 $ u1) (t $ u) = tag t1 t $ tag u1 u
   599       | tag (Abs (_, _, t1)) (Abs (x, T, t)) = Abs (x, T, tag t1 t)
   600       | tag (Free _) (t as Free _) = t
   601       | tag (Var _) (t as Var _) = t
   602       | tag (Bound _) (t as Bound _) = t;
   603   in
   604     tag
   605   end
   606 
   607 fun annotate thy algbr eqngr (c, ty) args rhs =
   608   let
   609     val ctxt = Proof_Context.init_global thy |> Config.put Type_Infer_Context.const_sorts false
   610     val erase = map_types (fn _ => Type_Infer.anyT [])
   611     val reinfer = singleton (Type_Infer_Context.infer_types ctxt)
   612     val lhs = list_comb (Const (c, ty), map (map_types Type.strip_sorts o fst) args)
   613     val reinferred_rhs = snd (Logic.dest_equals (reinfer (Logic.mk_equals (lhs, erase rhs))))
   614   in
   615     tag_term algbr eqngr reinferred_rhs rhs
   616   end
   617 
   618 fun annotate_eqns thy algbr eqngr (c, ty) eqns = 
   619   map (apfst (fn (args, (rhs, some_abs)) => (args,
   620     (annotate thy algbr eqngr (c, ty) args rhs, some_abs)))) eqns
   621 
   622 
   623 (* translation *)
   624 
   625 fun ensure_tyco thy algbr eqngr permissive tyco =
   626   let
   627     val ((vs, cos), _) = Code.get_type thy tyco;
   628     val stmt_datatype =
   629       fold_map (translate_tyvar_sort thy algbr eqngr permissive) vs
   630       #>> map fst
   631       ##>> fold_map (fn (c, (vs, tys)) =>
   632         ensure_const thy algbr eqngr permissive c
   633         ##>> pair (map (unprefix "'" o fst) vs)
   634         ##>> fold_map (translate_typ thy algbr eqngr permissive) tys) cos
   635       #>> (fn info => Datatype (tyco, info));
   636   in ensure_stmt lookup_tyco (declare_tyco thy) stmt_datatype tyco end
   637 and ensure_const thy algbr eqngr permissive c =
   638   let
   639     fun stmt_datatypecons tyco =
   640       ensure_tyco thy algbr eqngr permissive tyco
   641       #>> (fn tyco => Datatypecons (c, tyco));
   642     fun stmt_classparam class =
   643       ensure_class thy algbr eqngr permissive class
   644       #>> (fn class => Classparam (c, class));
   645     fun stmt_fun cert =
   646       let
   647         val ((vs, ty), eqns) = Code.equations_of_cert thy cert;
   648         val eqns' = annotate_eqns thy algbr eqngr (c, ty) eqns
   649         val some_case_cong = Code.get_case_cong thy c;
   650       in
   651         fold_map (translate_tyvar_sort thy algbr eqngr permissive) vs
   652         ##>> translate_typ thy algbr eqngr permissive ty
   653         ##>> translate_eqns thy algbr eqngr permissive eqns'
   654         #>> (fn info => Fun (c, (info, some_case_cong)))
   655       end;
   656     val stmt_const = case Code.get_type_of_constr_or_abstr thy c
   657      of SOME (tyco, _) => stmt_datatypecons tyco
   658       | NONE => (case AxClass.class_of_param thy c
   659          of SOME class => stmt_classparam class
   660           | NONE => stmt_fun (Code_Preproc.cert eqngr c))
   661   in ensure_stmt lookup_const (declare_const thy) stmt_const c end
   662 and ensure_class thy (algbr as (_, algebra)) eqngr permissive class =
   663   let
   664     val super_classes = (Sorts.minimize_sort algebra o Sorts.super_classes algebra) class;
   665     val cs = #params (AxClass.get_info thy class);
   666     val stmt_class =
   667       fold_map (fn super_class => ensure_class thy algbr eqngr permissive super_class
   668         ##>> ensure_classrel thy algbr eqngr permissive (class, super_class)) super_classes
   669       ##>> fold_map (fn (c, ty) => ensure_const thy algbr eqngr permissive c
   670         ##>> translate_typ thy algbr eqngr permissive ty) cs
   671       #>> (fn info => Class (class, (unprefix "'" Name.aT, info)))
   672   in ensure_stmt lookup_class (declare_class thy) stmt_class class end
   673 and ensure_classrel thy algbr eqngr permissive (sub_class, super_class) =
   674   let
   675     val stmt_classrel =
   676       ensure_class thy algbr eqngr permissive sub_class
   677       ##>> ensure_class thy algbr eqngr permissive super_class
   678       #>> Classrel;
   679   in ensure_stmt lookup_classrel (declare_classrel thy) stmt_classrel (sub_class, super_class) end
   680 and ensure_inst thy (algbr as (_, algebra)) eqngr permissive (class, tyco) =
   681   let
   682     val super_classes = (Sorts.minimize_sort algebra o Sorts.super_classes algebra) class;
   683     val these_class_params = these o try (#params o AxClass.get_info thy);
   684     val class_params = these_class_params class;
   685     val superclass_params = maps these_class_params
   686       ((Sorts.complete_sort algebra o Sorts.super_classes algebra) class);
   687     val vs = Name.invent_names Name.context "'a" (Sorts.mg_domain algebra tyco [class]);
   688     val sorts' = Sorts.mg_domain (Sign.classes_of thy) tyco [class];
   689     val vs' = map2 (fn (v, sort1) => fn sort2 => (v,
   690       Sorts.inter_sort (Sign.classes_of thy) (sort1, sort2))) vs sorts';
   691     val arity_typ = Type (tyco, map TFree vs);
   692     val arity_typ' = Type (tyco, map (fn (v, sort) => TVar ((v, 0), sort)) vs');
   693     fun translate_super_instance super_class =
   694       ensure_class thy algbr eqngr permissive super_class
   695       ##>> ensure_classrel thy algbr eqngr permissive (class, super_class)
   696       ##>> translate_dicts thy algbr eqngr permissive NONE (arity_typ, [super_class])
   697       #>> (fn ((super_class, classrel), [Dict ([], Dict_Const (inst, dss))]) =>
   698             (super_class, (classrel, (inst, dss))));
   699     fun translate_classparam_instance (c, ty) =
   700       let
   701         val raw_const = Const (c, map_type_tfree (K arity_typ') ty);
   702         val thm = AxClass.unoverload_conv thy (Thm.cterm_of thy raw_const);
   703         val const = (apsnd Logic.unvarifyT_global o dest_Const o snd
   704           o Logic.dest_equals o Thm.prop_of) thm;
   705       in
   706         ensure_const thy algbr eqngr permissive c
   707         ##>> translate_const thy algbr eqngr permissive (SOME thm) (const, NONE)
   708         #>> (fn (c, IConst const') => ((c, const'), (thm, true)))
   709       end;
   710     val stmt_inst =
   711       ensure_class thy algbr eqngr permissive class
   712       ##>> ensure_tyco thy algbr eqngr permissive tyco
   713       ##>> fold_map (translate_tyvar_sort thy algbr eqngr permissive) vs
   714       ##>> fold_map translate_super_instance super_classes
   715       ##>> fold_map translate_classparam_instance class_params
   716       ##>> fold_map translate_classparam_instance superclass_params
   717       #>> (fn (((((class, tyco), vs), superinsts), inst_params), superinst_params) =>
   718           Classinst { class = class, tyco = tyco, vs = vs,
   719             superinsts = superinsts, inst_params = inst_params, superinst_params = superinst_params });
   720   in ensure_stmt lookup_instance (declare_instance thy) stmt_inst (class, tyco) end
   721 and translate_typ thy algbr eqngr permissive (TFree (v, _)) =
   722       pair (ITyVar (unprefix "'" v))
   723   | translate_typ thy algbr eqngr permissive (Type (tyco, tys)) =
   724       ensure_tyco thy algbr eqngr permissive tyco
   725       ##>> fold_map (translate_typ thy algbr eqngr permissive) tys
   726       #>> (fn (tyco, tys) => tyco `%% tys)
   727 and translate_term thy algbr eqngr permissive some_thm (Const (c, ty), some_abs) =
   728       translate_app thy algbr eqngr permissive some_thm (((c, ty), []), some_abs)
   729   | translate_term thy algbr eqngr permissive some_thm (Free (v, _), some_abs) =
   730       pair (IVar (SOME v))
   731   | translate_term thy algbr eqngr permissive some_thm (Abs (v, ty, t), some_abs) =
   732       let
   733         val (v', t') = Syntax_Trans.variant_abs (Name.desymbolize false v, ty, t);
   734         val v'' = if member (op =) (Term.add_free_names t' []) v'
   735           then SOME v' else NONE
   736       in
   737         translate_typ thy algbr eqngr permissive ty
   738         ##>> translate_term thy algbr eqngr permissive some_thm (t', some_abs)
   739         #>> (fn (ty, t) => (v'', ty) `|=> t)
   740       end
   741   | translate_term thy algbr eqngr permissive some_thm (t as _ $ _, some_abs) =
   742       case strip_comb t
   743        of (Const (c, ty), ts) =>
   744             translate_app thy algbr eqngr permissive some_thm (((c, ty), ts), some_abs)
   745         | (t', ts) =>
   746             translate_term thy algbr eqngr permissive some_thm (t', some_abs)
   747             ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) ts
   748             #>> (fn (t, ts) => t `$$ ts)
   749 and translate_eqn thy algbr eqngr permissive ((args, (rhs, some_abs)), (some_thm, proper)) =
   750   fold_map (translate_term thy algbr eqngr permissive some_thm) args
   751   ##>> translate_term thy algbr eqngr permissive some_thm (rhs, some_abs)
   752   #>> rpair (some_thm, proper)
   753 and translate_eqns thy algbr eqngr permissive eqns prgrm =
   754   prgrm |> fold_map (translate_eqn thy algbr eqngr permissive) eqns
   755     handle PERMISSIVE () => ([], prgrm)
   756 and translate_const thy algbr eqngr permissive some_thm ((c, ty), some_abs) =
   757   let
   758     val _ = if (case some_abs of NONE => true | SOME abs => not (c = abs))
   759         andalso Code.is_abstr thy c
   760         then translation_error thy permissive some_thm
   761           "Abstraction violation" ("constant " ^ Code.string_of_const thy c)
   762       else ()
   763     val (annotate, ty') = dest_tagged_type ty;
   764     val typargs = Sign.const_typargs thy (c, ty');
   765     val sorts = Code_Preproc.sortargs eqngr c;
   766     val (dom, range) = Term.strip_type ty';
   767   in
   768     ensure_const thy algbr eqngr permissive c
   769     ##>> fold_map (translate_typ thy algbr eqngr permissive) typargs
   770     ##>> fold_map (translate_dicts thy algbr eqngr permissive some_thm) (typargs ~~ sorts)
   771     ##>> fold_map (translate_typ thy algbr eqngr permissive) (range :: dom)
   772     #>> (fn (((c, typargs), dss), range :: dom) =>
   773       IConst { name = c, typargs = typargs, dicts = dss,
   774         dom = dom, range = range, annotate = annotate })
   775   end
   776 and translate_app_const thy algbr eqngr permissive some_thm ((c_ty, ts), some_abs) =
   777   translate_const thy algbr eqngr permissive some_thm (c_ty, some_abs)
   778   ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) ts
   779   #>> (fn (t, ts) => t `$$ ts)
   780 and translate_case thy algbr eqngr permissive some_thm (num_args, (t_pos, case_pats)) (c_ty, ts) =
   781   let
   782     fun arg_types num_args ty = fst (chop num_args (binder_types ty));
   783     val tys = arg_types num_args (snd c_ty);
   784     val ty = nth tys t_pos;
   785     fun mk_constr NONE t = NONE
   786       | mk_constr (SOME c) t =
   787           let
   788             val n = Code.args_number thy c;
   789           in SOME ((c, arg_types n (fastype_of (untag_term t)) ---> ty), n) end;
   790     val constrs =
   791       if null case_pats then []
   792       else map_filter I (map2 mk_constr case_pats (nth_drop t_pos ts));
   793     fun casify naming constrs ty t_app ts =
   794       let
   795         val undefineds = map_filter (lookup_const naming) (Code.undefineds thy);
   796         fun collapse_clause vs_map ts body =
   797           let
   798           in case body
   799            of IConst { name = c, ... } => if member (op =) undefineds c
   800                 then []
   801                 else [(ts, body)]
   802             | ICase { term = IVar (SOME v), clauses = clauses, ... } =>
   803                 if forall (fn (pat', body') => exists_var pat' v
   804                   orelse not (exists_var body' v)) clauses
   805                 then case AList.lookup (op =) vs_map v
   806                  of SOME i => maps (fn (pat', body') =>
   807                       collapse_clause (AList.delete (op =) v vs_map)
   808                         (nth_map i (K pat') ts) body') clauses
   809                   | NONE => [(ts, body)]
   810                 else [(ts, body)]
   811             | _ => [(ts, body)]
   812           end;
   813         fun mk_clause mk tys t =
   814           let
   815             val (vs, body) = unfold_abs_eta tys t;
   816             val vs_map = fold_index (fn (i, (SOME v, _)) => cons (v, i) | _ => I) vs [];
   817             val ts = map (IVar o fst) vs;
   818           in map mk (collapse_clause vs_map ts body) end;
   819         val t = nth ts t_pos;
   820         val ts_clause = nth_drop t_pos ts;
   821         val clauses = if null case_pats
   822           then mk_clause (fn ([t], body) => (t, body)) [ty] (the_single ts_clause)
   823           else maps (fn ((constr as IConst { dom = tys, ... }, n), t) =>
   824             mk_clause (fn (ts, body) => (constr `$$ ts, body)) (take n tys) t)
   825               (constrs ~~ (map_filter (fn (NONE, _) => NONE | (SOME _, t) => SOME t)
   826                 (case_pats ~~ ts_clause)));
   827       in ICase { term = t, typ = ty, clauses = clauses, primitive = t_app `$$ ts } end;
   828   in
   829     translate_const thy algbr eqngr permissive some_thm (c_ty, NONE)
   830     ##>> fold_map (fn (constr, n) => translate_const thy algbr eqngr permissive some_thm (constr, NONE)
   831       #>> rpair n) constrs
   832     ##>> translate_typ thy algbr eqngr permissive ty
   833     ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) ts
   834     #-> (fn (((t, constrs), ty), ts) =>
   835       `(fn (_, (naming, _)) => casify naming constrs ty t ts))
   836   end
   837 and translate_app_case thy algbr eqngr permissive some_thm (case_scheme as (num_args, _)) ((c, ty), ts) =
   838   if length ts < num_args then
   839     let
   840       val k = length ts;
   841       val tys = (take (num_args - k) o drop k o fst o strip_type) ty;
   842       val ctxt = (fold o fold_aterms) Term.declare_term_frees ts Name.context;
   843       val vs = Name.invent_names ctxt "a" tys;
   844     in
   845       fold_map (translate_typ thy algbr eqngr permissive) tys
   846       ##>> translate_case thy algbr eqngr permissive some_thm case_scheme ((c, ty), ts @ map Free vs)
   847       #>> (fn (tys, t) => map2 (fn (v, _) => pair (SOME v)) vs tys `|==> t)
   848     end
   849   else if length ts > num_args then
   850     translate_case thy algbr eqngr permissive some_thm case_scheme ((c, ty), take num_args ts)
   851     ##>> fold_map (translate_term thy algbr eqngr permissive some_thm o rpair NONE) (drop num_args ts)
   852     #>> (fn (t, ts) => t `$$ ts)
   853   else
   854     translate_case thy algbr eqngr permissive some_thm case_scheme ((c, ty), ts)
   855 and translate_app thy algbr eqngr permissive some_thm (c_ty_ts as ((c, _), _), some_abs) =
   856   case Code.get_case_scheme thy c
   857    of SOME case_scheme => translate_app_case thy algbr eqngr permissive some_thm case_scheme c_ty_ts
   858     | NONE => translate_app_const thy algbr eqngr permissive some_thm (c_ty_ts, some_abs)
   859 and translate_tyvar_sort thy (algbr as (proj_sort, _)) eqngr permissive (v, sort) =
   860   fold_map (ensure_class thy algbr eqngr permissive) (proj_sort sort)
   861   #>> (fn sort => (unprefix "'" v, sort))
   862 and translate_dicts thy (algbr as (proj_sort, algebra)) eqngr permissive some_thm (ty, sort) =
   863   let
   864     datatype typarg_witness =
   865         Weakening of (class * class) list * plain_typarg_witness
   866     and plain_typarg_witness =
   867         Global of (class * string) * typarg_witness list list
   868       | Local of string * (int * sort);
   869     fun class_relation ((Weakening (classrels, x)), sub_class) super_class =
   870       Weakening ((sub_class, super_class) :: classrels, x);
   871     fun type_constructor (tyco, _) dss class =
   872       Weakening ([], Global ((class, tyco), (map o map) fst dss));
   873     fun type_variable (TFree (v, sort)) =
   874       let
   875         val sort' = proj_sort sort;
   876       in map_index (fn (n, class) => (Weakening ([], Local (v, (n, sort'))), class)) sort' end;
   877     val typarg_witnesses = Sorts.of_sort_derivation algebra
   878       {class_relation = K (Sorts.classrel_derivation algebra class_relation),
   879        type_constructor = type_constructor,
   880        type_variable = type_variable} (ty, proj_sort sort)
   881       handle Sorts.CLASS_ERROR e => not_wellsorted thy permissive some_thm ty sort e;
   882     fun mk_dict (Weakening (classrels, x)) =
   883           fold_map (ensure_classrel thy algbr eqngr permissive) classrels
   884           ##>> mk_plain_dict x
   885           #>> Dict 
   886     and mk_plain_dict (Global (inst, dss)) =
   887           ensure_inst thy algbr eqngr permissive inst
   888           ##>> (fold_map o fold_map) mk_dict dss
   889           #>> (fn (inst, dss) => Dict_Const (inst, dss))
   890       | mk_plain_dict (Local (v, (n, sort))) =
   891           pair (Dict_Var (unprefix "'" v, (n, length sort)))
   892   in fold_map mk_dict typarg_witnesses end;
   893 
   894 
   895 (* store *)
   896 
   897 structure Program = Code_Data
   898 (
   899   type T = naming * program;
   900   val empty = (empty_naming, Graph.empty);
   901 );
   902 
   903 fun invoke_generation ignore_cache thy (algebra, eqngr) generate thing =
   904   Program.change_yield (if ignore_cache then NONE else SOME thy)
   905     (fn naming_program => (NONE, naming_program)
   906       |> generate thy algebra eqngr thing
   907       |-> (fn thing => fn (_, naming_program) => (thing, naming_program)));
   908 
   909 
   910 (* program generation *)
   911 
   912 fun consts_program thy permissive consts =
   913   let
   914     fun project_consts consts (naming, program) =
   915       if permissive then (consts, (naming, program))
   916       else (consts, (naming, Graph.restrict
   917         (member (op =) (Graph.all_succs program consts)) program));
   918     fun generate_consts thy algebra eqngr =
   919       fold_map (ensure_const thy algebra eqngr permissive);
   920   in
   921     invoke_generation permissive thy (Code_Preproc.obtain false thy consts [])
   922       generate_consts consts
   923     |-> project_consts
   924   end;
   925 
   926 
   927 (* value evaluation *)
   928 
   929 fun ensure_value thy algbr eqngr t =
   930   let
   931     val ty = fastype_of t;
   932     val vs = fold_term_types (K (fold_atyps (insert (eq_fst op =)
   933       o dest_TFree))) t [];
   934     val t' = annotate thy algbr eqngr (Term.dummy_patternN, ty) [] t;
   935     val stmt_value =
   936       fold_map (translate_tyvar_sort thy algbr eqngr false) vs
   937       ##>> translate_typ thy algbr eqngr false ty
   938       ##>> translate_term thy algbr eqngr false NONE (t', NONE)
   939       #>> (fn ((vs, ty), t) => Fun
   940         (Term.dummy_patternN, (((vs, ty), [(([], t), (NONE, true))]), NONE)));
   941     fun term_value (dep, (naming, program1)) =
   942       let
   943         val Fun (_, ((vs_ty, [(([], t), _)]), _)) =
   944           Graph.get_node program1 Term.dummy_patternN;
   945         val deps = Graph.immediate_succs program1 Term.dummy_patternN;
   946         val program2 = Graph.del_node Term.dummy_patternN program1;
   947         val deps_all = Graph.all_succs program2 deps;
   948         val program3 = Graph.restrict (member (op =) deps_all) program2;
   949       in (((naming, program3), ((vs_ty, t), deps)), (dep, (naming, program2))) end;
   950   in
   951     ensure_stmt ((K o K) NONE) pair stmt_value Term.dummy_patternN
   952     #> snd
   953     #> term_value
   954   end;
   955 
   956 fun original_sorts vs =
   957   map (fn (v, _) => (v, (the o AList.lookup (op =) vs o prefix "'") v));
   958 
   959 fun dynamic_evaluator thy evaluator algebra eqngr vs t =
   960   let
   961     val (((naming, program), (((vs', ty'), t'), deps)), _) =
   962       invoke_generation false thy (algebra, eqngr) ensure_value t;
   963   in evaluator naming program ((original_sorts vs vs', (vs', ty')), t') deps end;
   964 
   965 fun dynamic_conv thy evaluator =
   966   Code_Preproc.dynamic_conv thy (dynamic_evaluator thy evaluator);
   967 
   968 fun dynamic_value thy postproc evaluator =
   969   Code_Preproc.dynamic_value thy postproc (dynamic_evaluator thy evaluator);
   970 
   971 fun lift_evaluation thy evaluation' algebra eqngr naming program vs t =
   972   let
   973     val (((_, _), (((vs', ty'), t'), deps)), _) =
   974       ensure_value thy algebra eqngr t (NONE, (naming, program));
   975   in evaluation' ((original_sorts vs vs', (vs', ty')), t') deps end;
   976 
   977 fun lift_evaluator thy evaluator' consts algebra eqngr =
   978   let
   979     fun generate_consts thy algebra eqngr =
   980       fold_map (ensure_const thy algebra eqngr false);
   981     val (consts', (naming, program)) =
   982       invoke_generation true thy (algebra, eqngr) generate_consts consts;
   983     val evaluation' = evaluator' naming program consts';
   984   in lift_evaluation thy evaluation' algebra eqngr naming program end;
   985 
   986 fun lift_evaluator_simple thy evaluator' consts algebra eqngr =
   987   let
   988     fun generate_consts thy algebra eqngr =
   989       fold_map (ensure_const thy algebra eqngr false);
   990     val (_, (_, program)) =
   991       invoke_generation true thy (algebra, eqngr) generate_consts consts;
   992   in evaluator' program end;
   993 
   994 fun static_conv thy consts conv =
   995   Code_Preproc.static_conv thy consts (lift_evaluator thy conv consts);
   996 
   997 fun static_conv_simple thy consts conv =
   998   Code_Preproc.static_conv thy consts (lift_evaluator_simple thy conv consts);
   999 
  1000 fun static_value thy postproc consts evaluator =
  1001   Code_Preproc.static_value thy postproc consts (lift_evaluator thy evaluator consts);
  1002 
  1003 
  1004 (** diagnostic commands **)
  1005 
  1006 fun read_const_exprs thy =
  1007   let
  1008     fun consts_of thy' = Symtab.fold (fn (c, (_, NONE)) => cons c | _ => I)
  1009       ((snd o #constants o Consts.dest o Sign.consts_of) thy') [];
  1010     fun belongs_here thy' c = forall
  1011       (fn thy'' => not (Sign.declared_const thy'' c)) (Theory.parents_of thy');
  1012     fun consts_of_select thy' = filter (belongs_here thy') (consts_of thy');
  1013     fun read_const_expr "_" = ([], consts_of thy)
  1014       | read_const_expr s = if String.isSuffix "._" s
  1015           then ([], consts_of_select (Context.this_theory thy (unsuffix "._" s)))
  1016           else ([Code.read_const thy s], []);
  1017   in pairself flat o split_list o map read_const_expr end;
  1018 
  1019 fun code_depgr thy consts =
  1020   let
  1021     val (_, eqngr) = Code_Preproc.obtain true thy consts [];
  1022     val all_consts = Graph.all_succs eqngr consts;
  1023   in Graph.restrict (member (op =) all_consts) eqngr end;
  1024 
  1025 fun code_thms thy = Pretty.writeln o Code_Preproc.pretty thy o code_depgr thy;
  1026 
  1027 fun code_deps thy consts =
  1028   let
  1029     val eqngr = code_depgr thy consts;
  1030     val constss = Graph.strong_conn eqngr;
  1031     val mapping = Symtab.empty |> fold (fn consts => fold (fn const =>
  1032       Symtab.update (const, consts)) consts) constss;
  1033     fun succs consts = consts
  1034       |> maps (Graph.immediate_succs eqngr)
  1035       |> subtract (op =) consts
  1036       |> map (the o Symtab.lookup mapping)
  1037       |> distinct (op =);
  1038     val conn = [] |> fold (fn consts => cons (consts, succs consts)) constss;
  1039     fun namify consts = map (Code.string_of_const thy) consts
  1040       |> commas;
  1041     val prgr = map (fn (consts, constss) =>
  1042       { name = namify consts, ID = namify consts, dir = "", unfold = true,
  1043         path = "", parents = map namify constss }) conn;
  1044   in Present.display_graph prgr end;
  1045 
  1046 local
  1047 
  1048 fun code_thms_cmd thy = code_thms thy o op @ o read_const_exprs thy;
  1049 fun code_deps_cmd thy = code_deps thy o op @ o read_const_exprs thy;
  1050 
  1051 in
  1052 
  1053 val _ =
  1054   Outer_Syntax.improper_command @{command_spec "code_thms"}
  1055     "print system of code equations for code"
  1056     (Scan.repeat1 Parse.term_group
  1057       >> (fn cs => Toplevel.no_timing o Toplevel.unknown_theory
  1058         o Toplevel.keep ((fn thy => code_thms_cmd thy cs) o Toplevel.theory_of)));
  1059 
  1060 val _ =
  1061   Outer_Syntax.improper_command @{command_spec "code_deps"}
  1062     "visualize dependencies of code equations for code"
  1063     (Scan.repeat1 Parse.term_group
  1064       >> (fn cs => Toplevel.no_timing o Toplevel.unknown_theory
  1065         o Toplevel.keep ((fn thy => code_deps_cmd thy cs) o Toplevel.theory_of)));
  1066 
  1067 end;
  1068 
  1069 end; (*struct*)
  1070 
  1071 
  1072 structure Basic_Code_Thingol: BASIC_CODE_THINGOL = Code_Thingol;