src/HOL/Map.thy
author wenzelm
Tue Mar 02 23:59:54 2010 +0100 (2010-03-02)
changeset 35427 ad039d29e01c
parent 35159 df38e92af926
child 35553 a8c8008a2c9d
permissions -rw-r--r--
proper (type_)notation;
     1 (*  Title:      HOL/Map.thy
     2     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     3     Copyright   1997-2003 TU Muenchen
     4 
     5 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     6 *)
     7 
     8 header {* Maps *}
     9 
    10 theory Map
    11 imports List
    12 begin
    13 
    14 types ('a,'b) "~=>" = "'a => 'b option"  (infixr "~=>" 0)
    15 translations (type) "'a ~=> 'b" <= (type) "'a => 'b option"
    16 
    17 type_notation (xsymbols)
    18   "~=>"  (infixr "\<rightharpoonup>" 0)
    19 
    20 abbreviation
    21   empty :: "'a ~=> 'b" where
    22   "empty == %x. None"
    23 
    24 definition
    25   map_comp :: "('b ~=> 'c) => ('a ~=> 'b) => ('a ~=> 'c)"  (infixl "o'_m" 55) where
    26   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    27 
    28 notation (xsymbols)
    29   map_comp  (infixl "\<circ>\<^sub>m" 55)
    30 
    31 definition
    32   map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)"  (infixl "++" 100) where
    33   "m1 ++ m2 = (\<lambda>x. case m2 x of None => m1 x | Some y => Some y)"
    34 
    35 definition
    36   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)"  (infixl "|`"  110) where
    37   "m|`A = (\<lambda>x. if x : A then m x else None)"
    38 
    39 notation (latex output)
    40   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    41 
    42 definition
    43   dom :: "('a ~=> 'b) => 'a set" where
    44   "dom m = {a. m a ~= None}"
    45 
    46 definition
    47   ran :: "('a ~=> 'b) => 'b set" where
    48   "ran m = {b. EX a. m a = Some b}"
    49 
    50 definition
    51   map_le :: "('a ~=> 'b) => ('a ~=> 'b) => bool"  (infix "\<subseteq>\<^sub>m" 50) where
    52   "(m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2) = (\<forall>a \<in> dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a)"
    53 
    54 nonterminals
    55   maplets maplet
    56 
    57 syntax
    58   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    59   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    60   ""         :: "maplet => maplets"             ("_")
    61   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    62   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    63   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    64 
    65 syntax (xsymbols)
    66   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    67   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    68 
    69 translations
    70   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    71   "_MapUpd m (_maplet  x y)"    == "m(x := CONST Some y)"
    72   "_Map ms"                     == "_MapUpd (CONST empty) ms"
    73   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    74   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    75 
    76 primrec
    77   map_of :: "('a \<times> 'b) list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    78     "map_of [] = empty"
    79   | "map_of (p # ps) = (map_of ps)(fst p \<mapsto> snd p)"
    80 
    81 definition
    82   map_upds :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    83   "map_upds m xs ys = m ++ map_of (rev (zip xs ys))"
    84 
    85 translations
    86   "_MapUpd m (_maplets x y)"    == "CONST map_upds m x y"
    87 
    88 lemma map_of_Cons_code [code]: 
    89   "map_of [] k = None"
    90   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    91   by simp_all
    92 
    93 
    94 subsection {* @{term [source] empty} *}
    95 
    96 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    97 by (rule ext) simp
    98 
    99 
   100 subsection {* @{term [source] map_upd} *}
   101 
   102 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   103 by (rule ext) simp
   104 
   105 lemma map_upd_nonempty [simp]: "t(k|->x) ~= empty"
   106 proof
   107   assume "t(k \<mapsto> x) = empty"
   108   then have "(t(k \<mapsto> x)) k = None" by simp
   109   then show False by simp
   110 qed
   111 
   112 lemma map_upd_eqD1:
   113   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   114   shows "x = y"
   115 proof -
   116   from prems have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   117   then show ?thesis by simp
   118 qed
   119 
   120 lemma map_upd_Some_unfold:
   121   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   122 by auto
   123 
   124 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   125 by auto
   126 
   127 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   128 unfolding image_def
   129 apply (simp (no_asm_use) add:full_SetCompr_eq)
   130 apply (rule finite_subset)
   131  prefer 2 apply assumption
   132 apply (auto)
   133 done
   134 
   135 
   136 subsection {* @{term [source] map_of} *}
   137 
   138 lemma map_of_eq_None_iff:
   139   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   140 by (induct xys) simp_all
   141 
   142 lemma map_of_is_SomeD: "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   143 apply (induct xys)
   144  apply simp
   145 apply (clarsimp split: if_splits)
   146 done
   147 
   148 lemma map_of_eq_Some_iff [simp]:
   149   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   150 apply (induct xys)
   151  apply simp
   152 apply (auto simp: map_of_eq_None_iff [symmetric])
   153 done
   154 
   155 lemma Some_eq_map_of_iff [simp]:
   156   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   157 by (auto simp del:map_of_eq_Some_iff simp add: map_of_eq_Some_iff [symmetric])
   158 
   159 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   160     \<Longrightarrow> map_of xys x = Some y"
   161 apply (induct xys)
   162  apply simp
   163 apply force
   164 done
   165 
   166 lemma map_of_zip_is_None [simp]:
   167   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   168 by (induct rule: list_induct2) simp_all
   169 
   170 lemma map_of_zip_is_Some:
   171   assumes "length xs = length ys"
   172   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   173 using assms by (induct rule: list_induct2) simp_all
   174 
   175 lemma map_of_zip_upd:
   176   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   177   assumes "length ys = length xs"
   178     and "length zs = length xs"
   179     and "x \<notin> set xs"
   180     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   181   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   182 proof
   183   fix x' :: 'a
   184   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   185   proof (cases "x = x'")
   186     case True
   187     from assms True map_of_zip_is_None [of xs ys x']
   188       have "map_of (zip xs ys) x' = None" by simp
   189     moreover from assms True map_of_zip_is_None [of xs zs x']
   190       have "map_of (zip xs zs) x' = None" by simp
   191     ultimately show ?thesis by simp
   192   next
   193     case False from assms
   194       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   195     with False show ?thesis by simp
   196   qed
   197 qed
   198 
   199 lemma map_of_zip_inject:
   200   assumes "length ys = length xs"
   201     and "length zs = length xs"
   202     and dist: "distinct xs"
   203     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   204   shows "ys = zs"
   205 using assms(1) assms(2)[symmetric] using dist map_of proof (induct ys xs zs rule: list_induct3)
   206   case Nil show ?case by simp
   207 next
   208   case (Cons y ys x xs z zs)
   209   from `map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))`
   210     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   211   from Cons have "length ys = length xs" and "length zs = length xs"
   212     and "x \<notin> set xs" by simp_all
   213   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   214   with Cons.hyps `distinct (x # xs)` have "ys = zs" by simp
   215   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   216   ultimately show ?case by simp
   217 qed
   218 
   219 lemma map_of_zip_map:
   220   "map_of (zip xs (map f xs)) = (\<lambda>x. if x \<in> set xs then Some (f x) else None)"
   221   by (induct xs) (simp_all add: expand_fun_eq)
   222 
   223 lemma finite_range_map_of: "finite (range (map_of xys))"
   224 apply (induct xys)
   225  apply (simp_all add: image_constant)
   226 apply (rule finite_subset)
   227  prefer 2 apply assumption
   228 apply auto
   229 done
   230 
   231 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   232 by (induct xs) (simp, atomize (full), auto)
   233 
   234 lemma map_of_mapk_SomeI:
   235   "inj f ==> map_of t k = Some x ==>
   236    map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   237 by (induct t) (auto simp add: inj_eq)
   238 
   239 lemma weak_map_of_SomeI: "(k, x) : set l ==> \<exists>x. map_of l k = Some x"
   240 by (induct l) auto
   241 
   242 lemma map_of_filter_in:
   243   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (split P) xs) k = Some z"
   244 by (induct xs) auto
   245 
   246 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = Option.map f (map_of xs x)"
   247 by (induct xs) auto
   248 
   249 
   250 subsection {* @{const Option.map} related *}
   251 
   252 lemma option_map_o_empty [simp]: "Option.map f o empty = empty"
   253 by (rule ext) simp
   254 
   255 lemma option_map_o_map_upd [simp]:
   256   "Option.map f o m(a|->b) = (Option.map f o m)(a|->f b)"
   257 by (rule ext) simp
   258 
   259 
   260 subsection {* @{term [source] map_comp} related *}
   261 
   262 lemma map_comp_empty [simp]:
   263   "m \<circ>\<^sub>m empty = empty"
   264   "empty \<circ>\<^sub>m m = empty"
   265 by (auto simp add: map_comp_def intro: ext split: option.splits)
   266 
   267 lemma map_comp_simps [simp]:
   268   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   269   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   270 by (auto simp add: map_comp_def)
   271 
   272 lemma map_comp_Some_iff:
   273   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   274 by (auto simp add: map_comp_def split: option.splits)
   275 
   276 lemma map_comp_None_iff:
   277   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   278 by (auto simp add: map_comp_def split: option.splits)
   279 
   280 
   281 subsection {* @{text "++"} *}
   282 
   283 lemma map_add_empty[simp]: "m ++ empty = m"
   284 by(simp add: map_add_def)
   285 
   286 lemma empty_map_add[simp]: "empty ++ m = m"
   287 by (rule ext) (simp add: map_add_def split: option.split)
   288 
   289 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   290 by (rule ext) (simp add: map_add_def split: option.split)
   291 
   292 lemma map_add_Some_iff:
   293   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   294 by (simp add: map_add_def split: option.split)
   295 
   296 lemma map_add_SomeD [dest!]:
   297   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   298 by (rule map_add_Some_iff [THEN iffD1])
   299 
   300 lemma map_add_find_right [simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   301 by (subst map_add_Some_iff) fast
   302 
   303 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   304 by (simp add: map_add_def split: option.split)
   305 
   306 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   307 by (rule ext) (simp add: map_add_def)
   308 
   309 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   310 by (simp add: map_upds_def)
   311 
   312 lemma map_add_upd_left: "m\<notin>dom e2 \<Longrightarrow> e1(m \<mapsto> u1) ++ e2 = (e1 ++ e2)(m \<mapsto> u1)"
   313 by (rule ext) (auto simp: map_add_def dom_def split: option.split)
   314 
   315 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   316 unfolding map_add_def
   317 apply (induct xs)
   318  apply simp
   319 apply (rule ext)
   320 apply (simp split add: option.split)
   321 done
   322 
   323 lemma finite_range_map_of_map_add:
   324   "finite (range f) ==> finite (range (f ++ map_of l))"
   325 apply (induct l)
   326  apply (auto simp del: fun_upd_apply)
   327 apply (erule finite_range_updI)
   328 done
   329 
   330 lemma inj_on_map_add_dom [iff]:
   331   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   332 by (fastsimp simp: map_add_def dom_def inj_on_def split: option.splits)
   333 
   334 lemma map_upds_fold_map_upd:
   335   "f(ks[\<mapsto>]vs) = foldl (\<lambda>f (k, v). f(k\<mapsto>v)) f (zip ks vs)"
   336 unfolding map_upds_def proof (rule sym, rule zip_obtain_same_length)
   337   fix ks :: "'a list" and vs :: "'b list"
   338   assume "length ks = length vs"
   339   then show "foldl (\<lambda>f (k, v). f(k\<mapsto>v)) f (zip ks vs) = f ++ map_of (rev (zip ks vs))"
   340     by (induct arbitrary: f rule: list_induct2) simp_all
   341 qed
   342 
   343 lemma map_add_map_of_foldr:
   344   "m ++ map_of ps = foldr (\<lambda>(k, v) m. m(k \<mapsto> v)) ps m"
   345   by (induct ps) (auto simp add: expand_fun_eq map_add_def)
   346 
   347 
   348 subsection {* @{term [source] restrict_map} *}
   349 
   350 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   351 by (simp add: restrict_map_def)
   352 
   353 lemma restrict_map_insert: "f |` (insert a A) = (f |` A)(a := f a)"
   354 by (auto simp add: restrict_map_def intro: ext)
   355 
   356 lemma restrict_map_empty [simp]: "empty|`D = empty"
   357 by (simp add: restrict_map_def)
   358 
   359 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   360 by (simp add: restrict_map_def)
   361 
   362 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   363 by (simp add: restrict_map_def)
   364 
   365 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   366 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   367 
   368 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   369 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   370 
   371 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   372 by (rule ext) (auto simp: restrict_map_def)
   373 
   374 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   375 by (rule ext) (auto simp: restrict_map_def)
   376 
   377 lemma restrict_fun_upd [simp]:
   378   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   379 by (simp add: restrict_map_def expand_fun_eq)
   380 
   381 lemma fun_upd_None_restrict [simp]:
   382   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   383 by (simp add: restrict_map_def expand_fun_eq)
   384 
   385 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   386 by (simp add: restrict_map_def expand_fun_eq)
   387 
   388 lemma fun_upd_restrict_conv [simp]:
   389   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   390 by (simp add: restrict_map_def expand_fun_eq)
   391 
   392 lemma map_of_map_restrict:
   393   "map_of (map (\<lambda>k. (k, f k)) ks) = (Some \<circ> f) |` set ks"
   394   by (induct ks) (simp_all add: expand_fun_eq restrict_map_insert)
   395 
   396 
   397 subsection {* @{term [source] map_upds} *}
   398 
   399 lemma map_upds_Nil1 [simp]: "m([] [|->] bs) = m"
   400 by (simp add: map_upds_def)
   401 
   402 lemma map_upds_Nil2 [simp]: "m(as [|->] []) = m"
   403 by (simp add:map_upds_def)
   404 
   405 lemma map_upds_Cons [simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   406 by (simp add:map_upds_def)
   407 
   408 lemma map_upds_append1 [simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   409   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   410 apply(induct xs)
   411  apply (clarsimp simp add: neq_Nil_conv)
   412 apply (case_tac ys)
   413  apply simp
   414 apply simp
   415 done
   416 
   417 lemma map_upds_list_update2_drop [simp]:
   418   "\<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   419     \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   420 apply (induct xs arbitrary: m ys i)
   421  apply simp
   422 apply (case_tac ys)
   423  apply simp
   424 apply (simp split: nat.split)
   425 done
   426 
   427 lemma map_upd_upds_conv_if:
   428   "(f(x|->y))(xs [|->] ys) =
   429    (if x : set(take (length ys) xs) then f(xs [|->] ys)
   430                                     else (f(xs [|->] ys))(x|->y))"
   431 apply (induct xs arbitrary: x y ys f)
   432  apply simp
   433 apply (case_tac ys)
   434  apply (auto split: split_if simp: fun_upd_twist)
   435 done
   436 
   437 lemma map_upds_twist [simp]:
   438   "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   439 using set_take_subset by (fastsimp simp add: map_upd_upds_conv_if)
   440 
   441 lemma map_upds_apply_nontin [simp]:
   442   "x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   443 apply (induct xs arbitrary: ys)
   444  apply simp
   445 apply (case_tac ys)
   446  apply (auto simp: map_upd_upds_conv_if)
   447 done
   448 
   449 lemma fun_upds_append_drop [simp]:
   450   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   451 apply (induct xs arbitrary: m ys)
   452  apply simp
   453 apply (case_tac ys)
   454  apply simp_all
   455 done
   456 
   457 lemma fun_upds_append2_drop [simp]:
   458   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   459 apply (induct xs arbitrary: m ys)
   460  apply simp
   461 apply (case_tac ys)
   462  apply simp_all
   463 done
   464 
   465 
   466 lemma restrict_map_upds[simp]:
   467   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   468     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   469 apply (induct xs arbitrary: m ys)
   470  apply simp
   471 apply (case_tac ys)
   472  apply simp
   473 apply (simp add: Diff_insert [symmetric] insert_absorb)
   474 apply (simp add: map_upd_upds_conv_if)
   475 done
   476 
   477 
   478 subsection {* @{term [source] dom} *}
   479 
   480 lemma dom_eq_empty_conv [simp]: "dom f = {} \<longleftrightarrow> f = empty"
   481 by(auto intro!:ext simp: dom_def)
   482 
   483 lemma domI: "m a = Some b ==> a : dom m"
   484 by(simp add:dom_def)
   485 (* declare domI [intro]? *)
   486 
   487 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   488 by (cases "m a") (auto simp add: dom_def)
   489 
   490 lemma domIff [iff, simp del]: "(a : dom m) = (m a ~= None)"
   491 by(simp add:dom_def)
   492 
   493 lemma dom_empty [simp]: "dom empty = {}"
   494 by(simp add:dom_def)
   495 
   496 lemma dom_fun_upd [simp]:
   497   "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   498 by(auto simp add:dom_def)
   499 
   500 lemma dom_if:
   501   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   502   by (auto split: if_splits)
   503 
   504 lemma dom_map_of_conv_image_fst:
   505   "dom (map_of xys) = fst ` set xys"
   506   by (induct xys) (auto simp add: dom_if)
   507 
   508 lemma dom_map_of_zip [simp]: "[| length xs = length ys; distinct xs |] ==>
   509   dom(map_of(zip xs ys)) = set xs"
   510 by (induct rule: list_induct2) simp_all
   511 
   512 lemma finite_dom_map_of: "finite (dom (map_of l))"
   513 by (induct l) (auto simp add: dom_def insert_Collect [symmetric])
   514 
   515 lemma dom_map_upds [simp]:
   516   "dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   517 apply (induct xs arbitrary: m ys)
   518  apply simp
   519 apply (case_tac ys)
   520  apply auto
   521 done
   522 
   523 lemma dom_map_add [simp]: "dom(m++n) = dom n Un dom m"
   524 by(auto simp:dom_def)
   525 
   526 lemma dom_override_on [simp]:
   527   "dom(override_on f g A) =
   528     (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   529 by(auto simp: dom_def override_on_def)
   530 
   531 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   532 by (rule ext) (force simp: map_add_def dom_def split: option.split)
   533 
   534 lemma map_add_dom_app_simps:
   535   "\<lbrakk> m\<in>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   536   "\<lbrakk> m\<notin>dom l1 \<rbrakk> \<Longrightarrow> (l1++l2) m = l2 m"
   537   "\<lbrakk> m\<notin>dom l2 \<rbrakk> \<Longrightarrow> (l1++l2) m = l1 m"
   538 by (auto simp add: map_add_def split: option.split_asm)
   539 
   540 lemma dom_const [simp]:
   541   "dom (\<lambda>x. Some (f x)) = UNIV"
   542   by auto
   543 
   544 (* Due to John Matthews - could be rephrased with dom *)
   545 lemma finite_map_freshness:
   546   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   547    \<exists>x. f x = None"
   548 by(bestsimp dest:ex_new_if_finite)
   549 
   550 lemma dom_minus:
   551   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   552   unfolding dom_def by simp
   553 
   554 lemma insert_dom:
   555   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   556   unfolding dom_def by auto
   557 
   558 
   559 subsection {* @{term [source] ran} *}
   560 
   561 lemma ranI: "m a = Some b ==> b : ran m"
   562 by(auto simp: ran_def)
   563 (* declare ranI [intro]? *)
   564 
   565 lemma ran_empty [simp]: "ran empty = {}"
   566 by(auto simp: ran_def)
   567 
   568 lemma ran_map_upd [simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   569 unfolding ran_def
   570 apply auto
   571 apply (subgoal_tac "aa ~= a")
   572  apply auto
   573 done
   574 
   575 lemma ran_distinct: 
   576   assumes dist: "distinct (map fst al)" 
   577   shows "ran (map_of al) = snd ` set al"
   578 using assms proof (induct al)
   579   case Nil then show ?case by simp
   580 next
   581   case (Cons kv al)
   582   then have "ran (map_of al) = snd ` set al" by simp
   583   moreover from Cons.prems have "map_of al (fst kv) = None"
   584     by (simp add: map_of_eq_None_iff)
   585   ultimately show ?case by (simp only: map_of.simps ran_map_upd) simp
   586 qed
   587 
   588 
   589 subsection {* @{text "map_le"} *}
   590 
   591 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   592 by (simp add: map_le_def)
   593 
   594 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   595 by (force simp add: map_le_def)
   596 
   597 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   598 by (fastsimp simp add: map_le_def)
   599 
   600 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   601 by (force simp add: map_le_def)
   602 
   603 lemma map_le_upds [simp]:
   604   "f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   605 apply (induct as arbitrary: f g bs)
   606  apply simp
   607 apply (case_tac bs)
   608  apply auto
   609 done
   610 
   611 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   612 by (fastsimp simp add: map_le_def dom_def)
   613 
   614 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   615 by (simp add: map_le_def)
   616 
   617 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   618 by (auto simp add: map_le_def dom_def)
   619 
   620 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   621 unfolding map_le_def
   622 apply (rule ext)
   623 apply (case_tac "x \<in> dom f", simp)
   624 apply (case_tac "x \<in> dom g", simp, fastsimp)
   625 done
   626 
   627 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   628 by (fastsimp simp add: map_le_def)
   629 
   630 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   631 by(fastsimp simp: map_add_def map_le_def expand_fun_eq split: option.splits)
   632 
   633 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   634 by (fastsimp simp add: map_le_def map_add_def dom_def)
   635 
   636 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   637 by (clarsimp simp add: map_le_def map_add_def dom_def split: option.splits)
   638 
   639 lemma dom_eq_singleton_conv: "dom f = {x} \<longleftrightarrow> (\<exists>v. f = [x \<mapsto> v])"
   640 proof(rule iffI)
   641   assume "\<exists>v. f = [x \<mapsto> v]"
   642   thus "dom f = {x}" by(auto split: split_if_asm)
   643 next
   644   assume "dom f = {x}"
   645   then obtain v where "f x = Some v" by auto
   646   hence "[x \<mapsto> v] \<subseteq>\<^sub>m f" by(auto simp add: map_le_def)
   647   moreover have "f \<subseteq>\<^sub>m [x \<mapsto> v]" using `dom f = {x}` `f x = Some v`
   648     by(auto simp add: map_le_def)
   649   ultimately have "f = [x \<mapsto> v]" by-(rule map_le_antisym)
   650   thus "\<exists>v. f = [x \<mapsto> v]" by blast
   651 qed
   652 
   653 end
   654