src/HOLCF/Cfun.thy
author wenzelm
Tue Mar 02 23:59:54 2010 +0100 (2010-03-02)
changeset 35427 ad039d29e01c
parent 35168 07b3112e464b
child 35547 991a6af75978
permissions -rw-r--r--
proper (type_)notation;
     1 (*  Title:      HOLCF/Cfun.thy
     2     Author:     Franz Regensburger
     3 
     4 Definition of the type ->  of continuous functions.
     5 *)
     6 
     7 header {* The type of continuous functions *}
     8 
     9 theory Cfun
    10 imports Pcpodef Ffun Product_Cpo
    11 begin
    12 
    13 defaultsort cpo
    14 
    15 subsection {* Definition of continuous function type *}
    16 
    17 lemma Ex_cont: "\<exists>f. cont f"
    18 by (rule exI, rule cont_const)
    19 
    20 lemma adm_cont: "adm cont"
    21 by (rule admI, rule cont_lub_fun)
    22 
    23 cpodef (CFun)  ('a, 'b) "->" (infixr "->" 0) = "{f::'a => 'b. cont f}"
    24 by (simp_all add: Ex_cont adm_cont)
    25 
    26 type_notation (xsymbols)
    27   "->"  ("(_ \<rightarrow>/ _)" [1, 0] 0)
    28 
    29 notation
    30   Rep_CFun  ("(_$/_)" [999,1000] 999)
    31 
    32 notation (xsymbols)
    33   Rep_CFun  ("(_\<cdot>/_)" [999,1000] 999)
    34 
    35 notation (HTML output)
    36   Rep_CFun  ("(_\<cdot>/_)" [999,1000] 999)
    37 
    38 subsection {* Syntax for continuous lambda abstraction *}
    39 
    40 syntax "_cabs" :: "'a"
    41 
    42 parse_translation {*
    43 (* rewrite (_cabs x t) => (Abs_CFun (%x. t)) *)
    44   [mk_binder_tr (@{syntax_const "_cabs"}, @{const_syntax Abs_CFun})];
    45 *}
    46 
    47 text {* To avoid eta-contraction of body: *}
    48 typed_print_translation {*
    49   let
    50     fun cabs_tr' _ _ [Abs abs] = let
    51           val (x,t) = atomic_abs_tr' abs
    52         in Syntax.const @{syntax_const "_cabs"} $ x $ t end
    53 
    54       | cabs_tr' _ T [t] = let
    55           val xT = domain_type (domain_type T);
    56           val abs' = ("x",xT,(incr_boundvars 1 t)$Bound 0);
    57           val (x,t') = atomic_abs_tr' abs';
    58         in Syntax.const @{syntax_const "_cabs"} $ x $ t' end;
    59 
    60   in [(@{const_syntax Abs_CFun}, cabs_tr')] end;
    61 *}
    62 
    63 text {* Syntax for nested abstractions *}
    64 
    65 syntax
    66   "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic"  ("(3LAM _./ _)" [1000, 10] 10)
    67 
    68 syntax (xsymbols)
    69   "_Lambda" :: "[cargs, 'a] \<Rightarrow> logic" ("(3\<Lambda> _./ _)" [1000, 10] 10)
    70 
    71 parse_ast_translation {*
    72 (* rewrite (LAM x y z. t) => (_cabs x (_cabs y (_cabs z t))) *)
    73 (* cf. Syntax.lambda_ast_tr from src/Pure/Syntax/syn_trans.ML *)
    74   let
    75     fun Lambda_ast_tr [pats, body] =
    76           Syntax.fold_ast_p @{syntax_const "_cabs"}
    77             (Syntax.unfold_ast @{syntax_const "_cargs"} pats, body)
    78       | Lambda_ast_tr asts = raise Syntax.AST ("Lambda_ast_tr", asts);
    79   in [(@{syntax_const "_Lambda"}, Lambda_ast_tr)] end;
    80 *}
    81 
    82 print_ast_translation {*
    83 (* rewrite (_cabs x (_cabs y (_cabs z t))) => (LAM x y z. t) *)
    84 (* cf. Syntax.abs_ast_tr' from src/Pure/Syntax/syn_trans.ML *)
    85   let
    86     fun cabs_ast_tr' asts =
    87       (case Syntax.unfold_ast_p @{syntax_const "_cabs"}
    88           (Syntax.Appl (Syntax.Constant @{syntax_const "_cabs"} :: asts)) of
    89         ([], _) => raise Syntax.AST ("cabs_ast_tr'", asts)
    90       | (xs, body) => Syntax.Appl
    91           [Syntax.Constant @{syntax_const "_Lambda"},
    92            Syntax.fold_ast @{syntax_const "_cargs"} xs, body]);
    93   in [(@{syntax_const "_cabs"}, cabs_ast_tr')] end
    94 *}
    95 
    96 text {* Dummy patterns for continuous abstraction *}
    97 translations
    98   "\<Lambda> _. t" => "CONST Abs_CFun (\<lambda> _. t)"
    99 
   100 
   101 subsection {* Continuous function space is pointed *}
   102 
   103 lemma UU_CFun: "\<bottom> \<in> CFun"
   104 by (simp add: CFun_def inst_fun_pcpo cont_const)
   105 
   106 instance "->" :: (finite_po, finite_po) finite_po
   107 by (rule typedef_finite_po [OF type_definition_CFun])
   108 
   109 instance "->" :: (finite_po, chfin) chfin
   110 by (rule typedef_chfin [OF type_definition_CFun below_CFun_def])
   111 
   112 instance "->" :: (cpo, discrete_cpo) discrete_cpo
   113 by intro_classes (simp add: below_CFun_def Rep_CFun_inject)
   114 
   115 instance "->" :: (cpo, pcpo) pcpo
   116 by (rule typedef_pcpo [OF type_definition_CFun below_CFun_def UU_CFun])
   117 
   118 lemmas Rep_CFun_strict =
   119   typedef_Rep_strict [OF type_definition_CFun below_CFun_def UU_CFun]
   120 
   121 lemmas Abs_CFun_strict =
   122   typedef_Abs_strict [OF type_definition_CFun below_CFun_def UU_CFun]
   123 
   124 text {* function application is strict in its first argument *}
   125 
   126 lemma Rep_CFun_strict1 [simp]: "\<bottom>\<cdot>x = \<bottom>"
   127 by (simp add: Rep_CFun_strict)
   128 
   129 text {* for compatibility with old HOLCF-Version *}
   130 lemma inst_cfun_pcpo: "\<bottom> = (\<Lambda> x. \<bottom>)"
   131 by (simp add: inst_fun_pcpo [symmetric] Abs_CFun_strict)
   132 
   133 subsection {* Basic properties of continuous functions *}
   134 
   135 text {* Beta-equality for continuous functions *}
   136 
   137 lemma Abs_CFun_inverse2: "cont f \<Longrightarrow> Rep_CFun (Abs_CFun f) = f"
   138 by (simp add: Abs_CFun_inverse CFun_def)
   139 
   140 lemma beta_cfun [simp]: "cont f \<Longrightarrow> (\<Lambda> x. f x)\<cdot>u = f u"
   141 by (simp add: Abs_CFun_inverse2)
   142 
   143 text {* Eta-equality for continuous functions *}
   144 
   145 lemma eta_cfun: "(\<Lambda> x. f\<cdot>x) = f"
   146 by (rule Rep_CFun_inverse)
   147 
   148 text {* Extensionality for continuous functions *}
   149 
   150 lemma expand_cfun_eq: "(f = g) = (\<forall>x. f\<cdot>x = g\<cdot>x)"
   151 by (simp add: Rep_CFun_inject [symmetric] expand_fun_eq)
   152 
   153 lemma ext_cfun: "(\<And>x. f\<cdot>x = g\<cdot>x) \<Longrightarrow> f = g"
   154 by (simp add: expand_cfun_eq)
   155 
   156 text {* Extensionality wrt. ordering for continuous functions *}
   157 
   158 lemma expand_cfun_below: "f \<sqsubseteq> g = (\<forall>x. f\<cdot>x \<sqsubseteq> g\<cdot>x)" 
   159 by (simp add: below_CFun_def expand_fun_below)
   160 
   161 lemma below_cfun_ext: "(\<And>x. f\<cdot>x \<sqsubseteq> g\<cdot>x) \<Longrightarrow> f \<sqsubseteq> g"
   162 by (simp add: expand_cfun_below)
   163 
   164 text {* Congruence for continuous function application *}
   165 
   166 lemma cfun_cong: "\<lbrakk>f = g; x = y\<rbrakk> \<Longrightarrow> f\<cdot>x = g\<cdot>y"
   167 by simp
   168 
   169 lemma cfun_fun_cong: "f = g \<Longrightarrow> f\<cdot>x = g\<cdot>x"
   170 by simp
   171 
   172 lemma cfun_arg_cong: "x = y \<Longrightarrow> f\<cdot>x = f\<cdot>y"
   173 by simp
   174 
   175 subsection {* Continuity of application *}
   176 
   177 lemma cont_Rep_CFun1: "cont (\<lambda>f. f\<cdot>x)"
   178 by (rule cont_Rep_CFun [THEN cont2cont_fun])
   179 
   180 lemma cont_Rep_CFun2: "cont (\<lambda>x. f\<cdot>x)"
   181 apply (cut_tac x=f in Rep_CFun)
   182 apply (simp add: CFun_def)
   183 done
   184 
   185 lemmas monofun_Rep_CFun = cont_Rep_CFun [THEN cont2mono]
   186 lemmas contlub_Rep_CFun = cont_Rep_CFun [THEN cont2contlub]
   187 
   188 lemmas monofun_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2mono, standard]
   189 lemmas contlub_Rep_CFun1 = cont_Rep_CFun1 [THEN cont2contlub, standard]
   190 lemmas monofun_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2mono, standard]
   191 lemmas contlub_Rep_CFun2 = cont_Rep_CFun2 [THEN cont2contlub, standard]
   192 
   193 text {* contlub, cont properties of @{term Rep_CFun} in each argument *}
   194 
   195 lemma contlub_cfun_arg: "chain Y \<Longrightarrow> f\<cdot>(\<Squnion>i. Y i) = (\<Squnion>i. f\<cdot>(Y i))"
   196 by (rule contlub_Rep_CFun2 [THEN contlubE])
   197 
   198 lemma cont_cfun_arg: "chain Y \<Longrightarrow> range (\<lambda>i. f\<cdot>(Y i)) <<| f\<cdot>(\<Squnion>i. Y i)"
   199 by (rule cont_Rep_CFun2 [THEN contE])
   200 
   201 lemma contlub_cfun_fun: "chain F \<Longrightarrow> (\<Squnion>i. F i)\<cdot>x = (\<Squnion>i. F i\<cdot>x)"
   202 by (rule contlub_Rep_CFun1 [THEN contlubE])
   203 
   204 lemma cont_cfun_fun: "chain F \<Longrightarrow> range (\<lambda>i. F i\<cdot>x) <<| (\<Squnion>i. F i)\<cdot>x"
   205 by (rule cont_Rep_CFun1 [THEN contE])
   206 
   207 text {* monotonicity of application *}
   208 
   209 lemma monofun_cfun_fun: "f \<sqsubseteq> g \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>x"
   210 by (simp add: expand_cfun_below)
   211 
   212 lemma monofun_cfun_arg: "x \<sqsubseteq> y \<Longrightarrow> f\<cdot>x \<sqsubseteq> f\<cdot>y"
   213 by (rule monofun_Rep_CFun2 [THEN monofunE])
   214 
   215 lemma monofun_cfun: "\<lbrakk>f \<sqsubseteq> g; x \<sqsubseteq> y\<rbrakk> \<Longrightarrow> f\<cdot>x \<sqsubseteq> g\<cdot>y"
   216 by (rule below_trans [OF monofun_cfun_fun monofun_cfun_arg])
   217 
   218 text {* ch2ch - rules for the type @{typ "'a -> 'b"} *}
   219 
   220 lemma chain_monofun: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   221 by (erule monofun_Rep_CFun2 [THEN ch2ch_monofun])
   222 
   223 lemma ch2ch_Rep_CFunR: "chain Y \<Longrightarrow> chain (\<lambda>i. f\<cdot>(Y i))"
   224 by (rule monofun_Rep_CFun2 [THEN ch2ch_monofun])
   225 
   226 lemma ch2ch_Rep_CFunL: "chain F \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>x)"
   227 by (rule monofun_Rep_CFun1 [THEN ch2ch_monofun])
   228 
   229 lemma ch2ch_Rep_CFun [simp]:
   230   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> chain (\<lambda>i. (F i)\<cdot>(Y i))"
   231 by (simp add: chain_def monofun_cfun)
   232 
   233 lemma ch2ch_LAM [simp]:
   234   "\<lbrakk>\<And>x. chain (\<lambda>i. S i x); \<And>i. cont (\<lambda>x. S i x)\<rbrakk> \<Longrightarrow> chain (\<lambda>i. \<Lambda> x. S i x)"
   235 by (simp add: chain_def expand_cfun_below)
   236 
   237 text {* contlub, cont properties of @{term Rep_CFun} in both arguments *}
   238 
   239 lemma contlub_cfun: 
   240   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i) = (\<Squnion>i. F i\<cdot>(Y i))"
   241 by (simp add: contlub_cfun_fun contlub_cfun_arg diag_lub)
   242 
   243 lemma cont_cfun: 
   244   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> range (\<lambda>i. F i\<cdot>(Y i)) <<| (\<Squnion>i. F i)\<cdot>(\<Squnion>i. Y i)"
   245 apply (rule thelubE)
   246 apply (simp only: ch2ch_Rep_CFun)
   247 apply (simp only: contlub_cfun)
   248 done
   249 
   250 lemma contlub_LAM:
   251   "\<lbrakk>\<And>x. chain (\<lambda>i. F i x); \<And>i. cont (\<lambda>x. F i x)\<rbrakk>
   252     \<Longrightarrow> (\<Lambda> x. \<Squnion>i. F i x) = (\<Squnion>i. \<Lambda> x. F i x)"
   253 apply (simp add: thelub_CFun)
   254 apply (simp add: Abs_CFun_inverse2)
   255 apply (simp add: thelub_fun ch2ch_lambda)
   256 done
   257 
   258 lemmas lub_distribs = 
   259   contlub_cfun [symmetric]
   260   contlub_LAM [symmetric]
   261 
   262 text {* strictness *}
   263 
   264 lemma strictI: "f\<cdot>x = \<bottom> \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   265 apply (rule UU_I)
   266 apply (erule subst)
   267 apply (rule minimal [THEN monofun_cfun_arg])
   268 done
   269 
   270 text {* the lub of a chain of continous functions is monotone *}
   271 
   272 lemma lub_cfun_mono: "chain F \<Longrightarrow> monofun (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
   273 apply (drule ch2ch_monofun [OF monofun_Rep_CFun])
   274 apply (simp add: thelub_fun [symmetric])
   275 apply (erule monofun_lub_fun)
   276 apply (simp add: monofun_Rep_CFun2)
   277 done
   278 
   279 text {* a lemma about the exchange of lubs for type @{typ "'a -> 'b"} *}
   280 
   281 lemma ex_lub_cfun:
   282   "\<lbrakk>chain F; chain Y\<rbrakk> \<Longrightarrow> (\<Squnion>j. \<Squnion>i. F j\<cdot>(Y i)) = (\<Squnion>i. \<Squnion>j. F j\<cdot>(Y i))"
   283 by (simp add: diag_lub)
   284 
   285 text {* the lub of a chain of cont. functions is continuous *}
   286 
   287 lemma cont_lub_cfun: "chain F \<Longrightarrow> cont (\<lambda>x. \<Squnion>i. F i\<cdot>x)"
   288 apply (rule cont2cont_lub)
   289 apply (erule monofun_Rep_CFun [THEN ch2ch_monofun])
   290 apply (rule cont_Rep_CFun2)
   291 done
   292 
   293 text {* type @{typ "'a -> 'b"} is chain complete *}
   294 
   295 lemma lub_cfun: "chain F \<Longrightarrow> range F <<| (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
   296 by (simp only: contlub_cfun_fun [symmetric] eta_cfun thelubE)
   297 
   298 lemma thelub_cfun: "chain F \<Longrightarrow> (\<Squnion>i. F i) = (\<Lambda> x. \<Squnion>i. F i\<cdot>x)"
   299 by (rule lub_cfun [THEN thelubI])
   300 
   301 subsection {* Continuity simplification procedure *}
   302 
   303 text {* cont2cont lemma for @{term Rep_CFun} *}
   304 
   305 lemma cont2cont_Rep_CFun [cont2cont]:
   306   assumes f: "cont (\<lambda>x. f x)"
   307   assumes t: "cont (\<lambda>x. t x)"
   308   shows "cont (\<lambda>x. (f x)\<cdot>(t x))"
   309 proof -
   310   have "cont (\<lambda>x. Rep_CFun (f x))"
   311     using cont_Rep_CFun f by (rule cont2cont_app3)
   312   thus "cont (\<lambda>x. (f x)\<cdot>(t x))"
   313     using cont_Rep_CFun2 t by (rule cont2cont_app2)
   314 qed
   315 
   316 text {* cont2mono Lemma for @{term "%x. LAM y. c1(x)(y)"} *}
   317 
   318 lemma cont2mono_LAM:
   319   "\<lbrakk>\<And>x. cont (\<lambda>y. f x y); \<And>y. monofun (\<lambda>x. f x y)\<rbrakk>
   320     \<Longrightarrow> monofun (\<lambda>x. \<Lambda> y. f x y)"
   321   unfolding monofun_def expand_cfun_below by simp
   322 
   323 text {* cont2cont Lemma for @{term "%x. LAM y. f x y"} *}
   324 
   325 text {*
   326   Not suitable as a cont2cont rule, because on nested lambdas
   327   it causes exponential blow-up in the number of subgoals.
   328 *}
   329 
   330 lemma cont2cont_LAM:
   331   assumes f1: "\<And>x. cont (\<lambda>y. f x y)"
   332   assumes f2: "\<And>y. cont (\<lambda>x. f x y)"
   333   shows "cont (\<lambda>x. \<Lambda> y. f x y)"
   334 proof (rule cont_Abs_CFun)
   335   fix x
   336   from f1 show "f x \<in> CFun" by (simp add: CFun_def)
   337   from f2 show "cont f" by (rule cont2cont_lambda)
   338 qed
   339 
   340 text {*
   341   This version does work as a cont2cont rule, since it
   342   has only a single subgoal.
   343 *}
   344 
   345 lemma cont2cont_LAM' [cont2cont]:
   346   fixes f :: "'a::cpo \<Rightarrow> 'b::cpo \<Rightarrow> 'c::cpo"
   347   assumes f: "cont (\<lambda>p. f (fst p) (snd p))"
   348   shows "cont (\<lambda>x. \<Lambda> y. f x y)"
   349 proof (rule cont2cont_LAM)
   350   fix x :: 'a show "cont (\<lambda>y. f x y)"
   351     using f by (rule cont_fst_snd_D2)
   352 next
   353   fix y :: 'b show "cont (\<lambda>x. f x y)"
   354     using f by (rule cont_fst_snd_D1)
   355 qed
   356 
   357 lemma cont2cont_LAM_discrete [cont2cont]:
   358   "(\<And>y::'a::discrete_cpo. cont (\<lambda>x. f x y)) \<Longrightarrow> cont (\<lambda>x. \<Lambda> y. f x y)"
   359 by (simp add: cont2cont_LAM)
   360 
   361 lemmas cont_lemmas1 =
   362   cont_const cont_id cont_Rep_CFun2 cont2cont_Rep_CFun cont2cont_LAM
   363 
   364 subsection {* Miscellaneous *}
   365 
   366 text {* Monotonicity of @{term Abs_CFun} *}
   367 
   368 lemma semi_monofun_Abs_CFun:
   369   "\<lbrakk>cont f; cont g; f \<sqsubseteq> g\<rbrakk> \<Longrightarrow> Abs_CFun f \<sqsubseteq> Abs_CFun g"
   370 by (simp add: below_CFun_def Abs_CFun_inverse2)
   371 
   372 text {* some lemmata for functions with flat/chfin domain/range types *}
   373 
   374 lemma chfin_Rep_CFunR: "chain (Y::nat => 'a::cpo->'b::chfin)  
   375       ==> !s. ? n. (LUB i. Y i)$s = Y n$s"
   376 apply (rule allI)
   377 apply (subst contlub_cfun_fun)
   378 apply assumption
   379 apply (fast intro!: thelubI chfin lub_finch2 chfin2finch ch2ch_Rep_CFunL)
   380 done
   381 
   382 lemma adm_chfindom: "adm (\<lambda>(u::'a::cpo \<rightarrow> 'b::chfin). P(u\<cdot>s))"
   383 by (rule adm_subst, simp, rule adm_chfin)
   384 
   385 subsection {* Continuous injection-retraction pairs *}
   386 
   387 text {* Continuous retractions are strict. *}
   388 
   389 lemma retraction_strict:
   390   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> f\<cdot>\<bottom> = \<bottom>"
   391 apply (rule UU_I)
   392 apply (drule_tac x="\<bottom>" in spec)
   393 apply (erule subst)
   394 apply (rule monofun_cfun_arg)
   395 apply (rule minimal)
   396 done
   397 
   398 lemma injection_eq:
   399   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x = g\<cdot>y) = (x = y)"
   400 apply (rule iffI)
   401 apply (drule_tac f=f in cfun_arg_cong)
   402 apply simp
   403 apply simp
   404 done
   405 
   406 lemma injection_below:
   407   "\<forall>x. f\<cdot>(g\<cdot>x) = x \<Longrightarrow> (g\<cdot>x \<sqsubseteq> g\<cdot>y) = (x \<sqsubseteq> y)"
   408 apply (rule iffI)
   409 apply (drule_tac f=f in monofun_cfun_arg)
   410 apply simp
   411 apply (erule monofun_cfun_arg)
   412 done
   413 
   414 lemma injection_defined_rev:
   415   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; g\<cdot>z = \<bottom>\<rbrakk> \<Longrightarrow> z = \<bottom>"
   416 apply (drule_tac f=f in cfun_arg_cong)
   417 apply (simp add: retraction_strict)
   418 done
   419 
   420 lemma injection_defined:
   421   "\<lbrakk>\<forall>x. f\<cdot>(g\<cdot>x) = x; z \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> g\<cdot>z \<noteq> \<bottom>"
   422 by (erule contrapos_nn, rule injection_defined_rev)
   423 
   424 text {* propagation of flatness and chain-finiteness by retractions *}
   425 
   426 lemma chfin2chfin:
   427   "\<forall>y. (f::'a::chfin \<rightarrow> 'b)\<cdot>(g\<cdot>y) = y
   428     \<Longrightarrow> \<forall>Y::nat \<Rightarrow> 'b. chain Y \<longrightarrow> (\<exists>n. max_in_chain n Y)"
   429 apply clarify
   430 apply (drule_tac f=g in chain_monofun)
   431 apply (drule chfin)
   432 apply (unfold max_in_chain_def)
   433 apply (simp add: injection_eq)
   434 done
   435 
   436 lemma flat2flat:
   437   "\<forall>y. (f::'a::flat \<rightarrow> 'b::pcpo)\<cdot>(g\<cdot>y) = y
   438     \<Longrightarrow> \<forall>x y::'b. x \<sqsubseteq> y \<longrightarrow> x = \<bottom> \<or> x = y"
   439 apply clarify
   440 apply (drule_tac f=g in monofun_cfun_arg)
   441 apply (drule ax_flat)
   442 apply (erule disjE)
   443 apply (simp add: injection_defined_rev)
   444 apply (simp add: injection_eq)
   445 done
   446 
   447 text {* a result about functions with flat codomain *}
   448 
   449 lemma flat_eqI: "\<lbrakk>(x::'a::flat) \<sqsubseteq> y; x \<noteq> \<bottom>\<rbrakk> \<Longrightarrow> x = y"
   450 by (drule ax_flat, simp)
   451 
   452 lemma flat_codom:
   453   "f\<cdot>x = (c::'b::flat) \<Longrightarrow> f\<cdot>\<bottom> = \<bottom> \<or> (\<forall>z. f\<cdot>z = c)"
   454 apply (case_tac "f\<cdot>x = \<bottom>")
   455 apply (rule disjI1)
   456 apply (rule UU_I)
   457 apply (erule_tac t="\<bottom>" in subst)
   458 apply (rule minimal [THEN monofun_cfun_arg])
   459 apply clarify
   460 apply (rule_tac a = "f\<cdot>\<bottom>" in refl [THEN box_equals])
   461 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   462 apply (erule minimal [THEN monofun_cfun_arg, THEN flat_eqI])
   463 done
   464 
   465 
   466 subsection {* Identity and composition *}
   467 
   468 definition
   469   ID :: "'a \<rightarrow> 'a" where
   470   "ID = (\<Lambda> x. x)"
   471 
   472 definition
   473   cfcomp  :: "('b \<rightarrow> 'c) \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'c" where
   474   oo_def: "cfcomp = (\<Lambda> f g x. f\<cdot>(g\<cdot>x))"
   475 
   476 abbreviation
   477   cfcomp_syn :: "['b \<rightarrow> 'c, 'a \<rightarrow> 'b] \<Rightarrow> 'a \<rightarrow> 'c"  (infixr "oo" 100)  where
   478   "f oo g == cfcomp\<cdot>f\<cdot>g"
   479 
   480 lemma ID1 [simp]: "ID\<cdot>x = x"
   481 by (simp add: ID_def)
   482 
   483 lemma cfcomp1: "(f oo g) = (\<Lambda> x. f\<cdot>(g\<cdot>x))"
   484 by (simp add: oo_def)
   485 
   486 lemma cfcomp2 [simp]: "(f oo g)\<cdot>x = f\<cdot>(g\<cdot>x)"
   487 by (simp add: cfcomp1)
   488 
   489 lemma cfcomp_LAM: "cont g \<Longrightarrow> f oo (\<Lambda> x. g x) = (\<Lambda> x. f\<cdot>(g x))"
   490 by (simp add: cfcomp1)
   491 
   492 lemma cfcomp_strict [simp]: "\<bottom> oo f = \<bottom>"
   493 by (simp add: expand_cfun_eq)
   494 
   495 text {*
   496   Show that interpretation of (pcpo,@{text "_->_"}) is a category.
   497   The class of objects is interpretation of syntactical class pcpo.
   498   The class of arrows  between objects @{typ 'a} and @{typ 'b} is interpret. of @{typ "'a -> 'b"}.
   499   The identity arrow is interpretation of @{term ID}.
   500   The composition of f and g is interpretation of @{text "oo"}.
   501 *}
   502 
   503 lemma ID2 [simp]: "f oo ID = f"
   504 by (rule ext_cfun, simp)
   505 
   506 lemma ID3 [simp]: "ID oo f = f"
   507 by (rule ext_cfun, simp)
   508 
   509 lemma assoc_oo: "f oo (g oo h) = (f oo g) oo h"
   510 by (rule ext_cfun, simp)
   511 
   512 
   513 subsection {* Strictified functions *}
   514 
   515 defaultsort pcpo
   516 
   517 definition
   518   strictify  :: "('a \<rightarrow> 'b) \<rightarrow> 'a \<rightarrow> 'b" where
   519   "strictify = (\<Lambda> f x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   520 
   521 text {* results about strictify *}
   522 
   523 lemma cont_strictify1: "cont (\<lambda>f. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   524 by simp
   525 
   526 lemma monofun_strictify2: "monofun (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   527 apply (rule monofunI)
   528 apply (auto simp add: monofun_cfun_arg)
   529 done
   530 
   531 (*FIXME: long proof*)
   532 lemma contlub_strictify2: "contlub (\<lambda>x. if x = \<bottom> then \<bottom> else f\<cdot>x)"
   533 apply (rule contlubI)
   534 apply (case_tac "(\<Squnion>i. Y i) = \<bottom>")
   535 apply (drule (1) chain_UU_I)
   536 apply simp
   537 apply (simp del: if_image_distrib)
   538 apply (simp only: contlub_cfun_arg)
   539 apply (rule lub_equal2)
   540 apply (rule chain_mono2 [THEN exE])
   541 apply (erule chain_UU_I_inverse2)
   542 apply (assumption)
   543 apply (rule_tac x=x in exI, clarsimp)
   544 apply (erule chain_monofun)
   545 apply (erule monofun_strictify2 [THEN ch2ch_monofun])
   546 done
   547 
   548 lemmas cont_strictify2 =
   549   monocontlub2cont [OF monofun_strictify2 contlub_strictify2, standard]
   550 
   551 lemma strictify_conv_if: "strictify\<cdot>f\<cdot>x = (if x = \<bottom> then \<bottom> else f\<cdot>x)"
   552   unfolding strictify_def
   553   by (simp add: cont_strictify1 cont_strictify2 cont2cont_LAM)
   554 
   555 lemma strictify1 [simp]: "strictify\<cdot>f\<cdot>\<bottom> = \<bottom>"
   556 by (simp add: strictify_conv_if)
   557 
   558 lemma strictify2 [simp]: "x \<noteq> \<bottom> \<Longrightarrow> strictify\<cdot>f\<cdot>x = f\<cdot>x"
   559 by (simp add: strictify_conv_if)
   560 
   561 subsection {* Continuous let-bindings *}
   562 
   563 definition
   564   CLet :: "'a \<rightarrow> ('a \<rightarrow> 'b) \<rightarrow> 'b" where
   565   "CLet = (\<Lambda> s f. f\<cdot>s)"
   566 
   567 syntax
   568   "_CLet" :: "[letbinds, 'a] => 'a" ("(Let (_)/ in (_))" 10)
   569 
   570 translations
   571   "_CLet (_binds b bs) e" == "_CLet b (_CLet bs e)"
   572   "Let x = a in e" == "CONST CLet\<cdot>a\<cdot>(\<Lambda> x. e)"
   573 
   574 end