src/HOL/Tools/Datatype/datatype.ML
author haftmann
Mon Sep 28 09:47:18 2009 +0200 (2009-09-28)
changeset 32722 ad04cda866be
parent 32721 a5fcc7960681
child 32727 9072201cd69d
permissions -rw-r--r--
explicit pointless checkpoint
     1 (*  Title:      HOL/Tools/datatype.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Datatype package for Isabelle/HOL.
     5 *)
     6 
     7 signature DATATYPE =
     8 sig
     9   include DATATYPE_COMMON
    10   val add_datatype : config -> string list -> (string list * binding * mixfix *
    11     (binding * typ list * mixfix) list) list -> theory -> string list * theory
    12   val datatype_cmd : string list -> (string list * binding * mixfix *
    13     (binding * string list * mixfix) list) list -> theory -> theory
    14   val rep_datatype : config -> (string list -> Proof.context -> Proof.context)
    15     -> string list option -> term list -> theory -> Proof.state
    16   val rep_datatype_cmd : string list option -> string list -> theory -> Proof.state
    17   val get_info : theory -> string -> info option
    18   val the_info : theory -> string -> info
    19   val the_descr : theory -> string list
    20     -> descr * (string * sort) list * string list
    21       * string * (string list * string list) * (typ list * typ list)
    22   val the_spec : theory -> string -> (string * sort) list * (string * typ list) list
    23   val get_constrs : theory -> string -> (string * typ) list option
    24   val get_all : theory -> info Symtab.table
    25   val info_of_constr : theory -> string -> info option
    26   val info_of_case : theory -> string -> info option
    27   val interpretation : (config -> string list -> theory -> theory) -> theory -> theory
    28   val distinct_simproc : simproc
    29   val make_case :  Proof.context -> DatatypeCase.config -> string list -> term ->
    30     (term * term) list -> term * (term * (int * bool)) list
    31   val strip_case : Proof.context -> bool -> term -> (term * (term * term) list) option
    32   val read_typ: theory ->
    33     (typ list * (string * sort) list) * string -> typ list * (string * sort) list
    34   val setup: theory -> theory
    35 end;
    36 
    37 structure Datatype : DATATYPE =
    38 struct
    39 
    40 open DatatypeAux;
    41 
    42 (** theory data **)
    43 
    44 (* data management *)
    45 
    46 structure DatatypesData = TheoryDataFun
    47 (
    48   type T =
    49     {types: info Symtab.table,
    50      constrs: info Symtab.table,
    51      cases: info Symtab.table};
    52 
    53   val empty =
    54     {types = Symtab.empty, constrs = Symtab.empty, cases = Symtab.empty};
    55   val copy = I;
    56   val extend = I;
    57   fun merge _
    58     ({types = types1, constrs = constrs1, cases = cases1},
    59      {types = types2, constrs = constrs2, cases = cases2}) =
    60     {types = Symtab.merge (K true) (types1, types2),
    61      constrs = Symtab.merge (K true) (constrs1, constrs2),
    62      cases = Symtab.merge (K true) (cases1, cases2)};
    63 );
    64 
    65 val get_all = #types o DatatypesData.get;
    66 val get_info = Symtab.lookup o get_all;
    67 fun the_info thy name = (case get_info thy name of
    68       SOME info => info
    69     | NONE => error ("Unknown datatype " ^ quote name));
    70 
    71 val info_of_constr = Symtab.lookup o #constrs o DatatypesData.get;
    72 val info_of_case = Symtab.lookup o #cases o DatatypesData.get;
    73 
    74 fun register (dt_infos : (string * info) list) =
    75   DatatypesData.map (fn {types, constrs, cases} =>
    76     {types = fold Symtab.update dt_infos types,
    77      constrs = fold Symtab.default (*conservative wrt. overloaded constructors*)
    78        (maps (fn (_, info as {descr, index, ...}) => map (rpair info o fst)
    79           (#3 (the (AList.lookup op = descr index)))) dt_infos) constrs,
    80      cases = fold Symtab.update
    81        (map (fn (_, info as {case_name, ...}) => (case_name, info)) dt_infos)
    82        cases});
    83 
    84 (* complex queries *)
    85 
    86 fun the_spec thy dtco =
    87   let
    88     val info as { descr, index, sorts = raw_sorts, ... } = the_info thy dtco;
    89     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr index;
    90     val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
    91       o DatatypeAux.dest_DtTFree) dtys;
    92     val cos = map
    93       (fn (co, tys) => (co, map (DatatypeAux.typ_of_dtyp descr sorts) tys)) raw_cos;
    94   in (sorts, cos) end;
    95 
    96 fun the_descr thy (raw_tycos as raw_tyco :: _) =
    97   let
    98     val info = the_info thy raw_tyco;
    99     val descr = #descr info;
   100 
   101     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr (#index info);
   102     val vs = map ((fn v => (v, (the o AList.lookup (op =) (#sorts info)) v))
   103       o dest_DtTFree) dtys;
   104 
   105     fun is_DtTFree (DtTFree _) = true
   106       | is_DtTFree _ = false
   107     val k = find_index (fn (_, (_, dTs, _)) => not (forall is_DtTFree dTs)) descr;
   108     val protoTs as (dataTs, _) = chop k descr
   109       |> (pairself o map) (fn (_, (tyco, dTs, _)) => (tyco, map (typ_of_dtyp descr vs) dTs));
   110     
   111     val tycos = map fst dataTs;
   112     val _ = if gen_eq_set (op =) (tycos, raw_tycos) then ()
   113       else error ("Type constructors " ^ commas (map quote raw_tycos)
   114         ^ " do not belong exhaustively to one mutual recursive datatype");
   115 
   116     val (Ts, Us) = (pairself o map) Type protoTs;
   117 
   118     val names = map Long_Name.base_name (the_default tycos (#alt_names info));
   119     val (auxnames, _) = Name.make_context names
   120       |> fold_map (yield_singleton Name.variants o name_of_typ) Us;
   121     val prefix = space_implode "_" names;
   122 
   123   in (descr, vs, tycos, prefix, (names, auxnames), (Ts, Us)) end;
   124 
   125 fun get_constrs thy dtco =
   126   case try (the_spec thy) dtco
   127    of SOME (sorts, cos) =>
   128         let
   129           fun subst (v, sort) = TVar ((v, 0), sort);
   130           fun subst_ty (TFree v) = subst v
   131             | subst_ty ty = ty;
   132           val dty = Type (dtco, map subst sorts);
   133           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   134         in SOME (map mk_co cos) end
   135     | NONE => NONE;
   136 
   137 
   138 (** various auxiliary **)
   139 
   140 (* simplification procedure for showing distinctness of constructors *)
   141 
   142 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   143   | stripT p = p;
   144 
   145 fun stripC (i, f $ x) = stripC (i + 1, f)
   146   | stripC p = p;
   147 
   148 val distinctN = "constr_distinct";
   149 
   150 fun distinct_rule thy ss tname eq_t = case #distinct (the_info thy tname) of
   151     FewConstrs thms => Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   152       (EVERY [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   153         atac 2, resolve_tac thms 1, etac FalseE 1]))
   154   | ManyConstrs (thm, simpset) =>
   155       let
   156         val [In0_inject, In1_inject, In0_not_In1, In1_not_In0] =
   157           map (PureThy.get_thm (ThyInfo.the_theory "Datatype" thy))
   158             ["In0_inject", "In1_inject", "In0_not_In1", "In1_not_In0"];
   159       in
   160         Goal.prove (Simplifier.the_context ss) [] [] eq_t (K
   161         (EVERY [rtac eq_reflection 1, rtac iffI 1, dtac thm 1,
   162           full_simp_tac (Simplifier.inherit_context ss simpset) 1,
   163           REPEAT (dresolve_tac [In0_inject, In1_inject] 1),
   164           eresolve_tac [In0_not_In1 RS notE, In1_not_In0 RS notE] 1,
   165           etac FalseE 1]))
   166       end;
   167 
   168 fun get_constr thy dtco =
   169   get_info thy dtco
   170   |> Option.map (fn { descr, index, ... } => (#3 o the o AList.lookup (op =) descr) index);
   171 
   172 fun distinct_proc thy ss (t as Const ("op =", _) $ t1 $ t2) =
   173   (case (stripC (0, t1), stripC (0, t2)) of
   174      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   175          (case (stripT (0, T1), stripT (0, T2)) of
   176             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   177                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   178                    (case get_constr thy tname1 of
   179                       SOME constrs => let val cnames = map fst constrs
   180                         in if cname1 mem cnames andalso cname2 mem cnames then
   181                              SOME (distinct_rule thy ss tname1
   182                                (Logic.mk_equals (t, HOLogic.false_const)))
   183                            else NONE
   184                         end
   185                     | NONE => NONE)
   186                 else NONE
   187           | _ => NONE)
   188    | _ => NONE)
   189   | distinct_proc _ _ _ = NONE;
   190 
   191 val distinct_simproc =
   192   Simplifier.simproc @{theory HOL} distinctN ["s = t"] distinct_proc;
   193 
   194 val dist_ss = HOL_ss addsimprocs [distinct_simproc];
   195 
   196 val simproc_setup =
   197   Simplifier.map_simpset (fn ss => ss addsimprocs [distinct_simproc]);
   198 
   199 (* prepare datatype specifications *)
   200 
   201 fun read_typ thy ((Ts, sorts), str) =
   202   let
   203     val ctxt = ProofContext.init thy
   204       |> fold (Variable.declare_typ o TFree) sorts;
   205     val T = Syntax.read_typ ctxt str;
   206   in (Ts @ [T], Term.add_tfreesT T sorts) end;
   207 
   208 fun cert_typ sign ((Ts, sorts), raw_T) =
   209   let
   210     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   211       TYPE (msg, _, _) => error msg;
   212     val sorts' = Term.add_tfreesT T sorts;
   213   in (Ts @ [T],
   214       case duplicates (op =) (map fst sorts') of
   215          [] => sorts'
   216        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   217   end;
   218 
   219 (* arrange data entries *)
   220 
   221 fun make_dt_info alt_names descr sorts inducts reccomb_names rec_thms
   222     ((((((((((i, (_, (tname, _, _))), case_name), case_thms),
   223       exhaust_thm), distinct_thm), inject), splits), nchotomy), case_cong), weak_case_cong) =
   224   (tname,
   225    {index = i,
   226     alt_names = alt_names,
   227     descr = descr,
   228     sorts = sorts,
   229     inject = inject,
   230     distinct = distinct_thm,
   231     inducts = inducts,
   232     exhaust = exhaust_thm,
   233     nchotomy = nchotomy,
   234     rec_names = reccomb_names,
   235     rec_rewrites = rec_thms,
   236     case_name = case_name,
   237     case_rewrites = case_thms,
   238     case_cong = case_cong,
   239     weak_case_cong = weak_case_cong,
   240     splits = splits});
   241 
   242 (* case names *)
   243 
   244 local
   245 
   246 fun dt_recs (DtTFree _) = []
   247   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   248   | dt_recs (DtRec i) = [i];
   249 
   250 fun dt_cases (descr: descr) (_, args, constrs) =
   251   let
   252     fun the_bname i = Long_Name.base_name (#1 (the (AList.lookup (op =) descr i)));
   253     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   254   in map (fn (c, _) => space_implode "_" (Long_Name.base_name c :: bnames)) constrs end;
   255 
   256 fun induct_cases descr =
   257   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   258 
   259 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   260 
   261 in
   262 
   263 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   264 
   265 fun mk_case_names_exhausts descr new =
   266   map (RuleCases.case_names o exhaust_cases descr o #1)
   267     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   268 
   269 end;
   270 
   271 (* translation rules for case *)
   272 
   273 fun make_case ctxt = DatatypeCase.make_case
   274   (info_of_constr (ProofContext.theory_of ctxt)) ctxt;
   275 
   276 fun strip_case ctxt = DatatypeCase.strip_case
   277   (info_of_case (ProofContext.theory_of ctxt));
   278 
   279 fun add_case_tr' case_names thy =
   280   Sign.add_advanced_trfuns ([], [],
   281     map (fn case_name =>
   282       let val case_name' = Sign.const_syntax_name thy case_name
   283       in (case_name', DatatypeCase.case_tr' info_of_case case_name')
   284       end) case_names, []) thy;
   285 
   286 val trfun_setup =
   287   Sign.add_advanced_trfuns ([],
   288     [("_case_syntax", DatatypeCase.case_tr true info_of_constr)],
   289     [], []);
   290 
   291 (* document antiquotation *)
   292 
   293 val _ = ThyOutput.antiquotation "datatype" Args.tyname
   294   (fn {source = src, context = ctxt, ...} => fn dtco =>
   295     let
   296       val thy = ProofContext.theory_of ctxt;
   297       val (vs, cos) = the_spec thy dtco;
   298       val ty = Type (dtco, map TFree vs);
   299       fun pretty_typ_bracket (ty as Type (_, _ :: _)) =
   300             Pretty.enclose "(" ")" [Syntax.pretty_typ ctxt ty]
   301         | pretty_typ_bracket ty =
   302             Syntax.pretty_typ ctxt ty;
   303       fun pretty_constr (co, tys) =
   304         (Pretty.block o Pretty.breaks)
   305           (Syntax.pretty_term ctxt (Const (co, tys ---> ty)) ::
   306             map pretty_typ_bracket tys);
   307       val pretty_datatype =
   308         Pretty.block
   309           (Pretty.command "datatype" :: Pretty.brk 1 ::
   310            Syntax.pretty_typ ctxt ty ::
   311            Pretty.str " =" :: Pretty.brk 1 ::
   312            flat (separate [Pretty.brk 1, Pretty.str "| "]
   313              (map (single o pretty_constr) cos)));
   314     in ThyOutput.output (ThyOutput.maybe_pretty_source (K pretty_datatype) src [()]) end);
   315 
   316 
   317 (** abstract theory extensions relative to a datatype characterisation **)
   318 
   319 structure DatatypeInterpretation = InterpretationFun
   320   (type T = config * string list val eq: T * T -> bool = eq_snd op =);
   321 fun interpretation f = DatatypeInterpretation.interpretation (uncurry f);
   322 
   323 fun add_rules simps case_thms rec_thms inject distinct
   324                   weak_case_congs cong_att =
   325   PureThy.add_thmss [((Binding.name "simps", simps), []),
   326     ((Binding.empty, flat case_thms @
   327           flat distinct @ rec_thms), [Simplifier.simp_add]),
   328     ((Binding.empty, rec_thms), [Code.add_default_eqn_attribute]),
   329     ((Binding.empty, flat inject), [iff_add]),
   330     ((Binding.empty, map (fn th => th RS notE) (flat distinct)), [Classical.safe_elim NONE]),
   331     ((Binding.empty, weak_case_congs), [cong_att])]
   332   #> snd;
   333 
   334 fun add_cases_induct infos inducts thy =
   335   let
   336     fun named_rules (name, {index, exhaust, ...}: info) =
   337       [((Binding.empty, nth inducts index), [Induct.induct_type name]),
   338        ((Binding.empty, exhaust), [Induct.cases_type name])];
   339     fun unnamed_rule i =
   340       ((Binding.empty, nth inducts i), [Thm.kind_internal, Induct.induct_type ""]);
   341   in
   342     thy |> PureThy.add_thms
   343       (maps named_rules infos @
   344         map unnamed_rule (length infos upto length inducts - 1)) |> snd
   345     |> PureThy.add_thmss [((Binding.name "inducts", inducts), [])] |> snd
   346   end;
   347 
   348 fun derive_datatype_props config dt_names alt_names descr sorts induct inject distinct thy1 =
   349   let
   350     val thy2 = thy1 |> Theory.checkpoint
   351     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   352     val _ = message config ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   353     val (case_names_induct, case_names_exhausts) =
   354       (mk_case_names_induct descr, mk_case_names_exhausts descr dt_names);
   355     val inducts = Project_Rule.projections (ProofContext.init thy2) induct;
   356 
   357     val (casedist_thms, thy3) = thy2 |>
   358       DatatypeAbsProofs.prove_casedist_thms config new_type_names [descr] sorts induct
   359         case_names_exhausts;
   360     val ((reccomb_names, rec_thms), thy4) = DatatypeAbsProofs.prove_primrec_thms
   361       config new_type_names [descr] sorts (get_all thy3) inject distinct
   362       (Simplifier.theory_context thy3 dist_ss) induct thy3;
   363     val ((case_thms, case_names), thy5) = DatatypeAbsProofs.prove_case_thms
   364       config new_type_names [descr] sorts reccomb_names rec_thms thy4;
   365     val (split_thms, thy6) = DatatypeAbsProofs.prove_split_thms
   366       config new_type_names [descr] sorts inject distinct casedist_thms case_thms thy5;
   367     val (nchotomys, thy7) = DatatypeAbsProofs.prove_nchotomys config new_type_names
   368       [descr] sorts casedist_thms thy6;
   369     val (case_congs, thy8) = DatatypeAbsProofs.prove_case_congs new_type_names
   370       [descr] sorts nchotomys case_thms thy7;
   371     val (weak_case_congs, thy9) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   372       [descr] sorts thy8;
   373 
   374     val simps = flat (distinct @ inject @ case_thms) @ rec_thms;
   375     val dt_infos = map (make_dt_info alt_names descr sorts (inducts, induct) reccomb_names rec_thms)
   376       ((0 upto length descr - 1) ~~ descr ~~ case_names ~~ case_thms ~~ casedist_thms ~~
   377         map FewConstrs distinct ~~ inject ~~ split_thms ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   378     val dt_names = map fst dt_infos;
   379   in
   380     thy9
   381     |> add_case_tr' case_names
   382     |> add_rules simps case_thms rec_thms inject distinct weak_case_congs (Simplifier.attrib (op addcongs))
   383     |> register dt_infos
   384     |> add_cases_induct dt_infos inducts
   385     |> Sign.parent_path
   386     |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms)
   387     |> snd
   388     |> DatatypeInterpretation.data (config, dt_names)
   389     |> pair dt_names
   390   end;
   391 
   392 
   393 (** declare existing type as datatype **)
   394 
   395 fun prove_rep_datatype config dt_names alt_names descr sorts raw_induct raw_inject half_distinct thy1 =
   396   let
   397     val raw_distinct = (map o maps) (fn thm => [thm, thm RS not_sym]) half_distinct;
   398     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   399     val (case_names_induct, case_names_exhausts) =
   400       (mk_case_names_induct descr, mk_case_names_exhausts descr dt_names);
   401     val (((inject, distinct), [induct]), thy2) =
   402       thy1
   403       |> store_thmss "inject" new_type_names raw_inject
   404       ||>> store_thmss "distinct" new_type_names raw_distinct
   405       ||> Sign.add_path (space_implode "_" new_type_names)
   406       ||>> PureThy.add_thms [((Binding.name "induct", raw_induct), [case_names_induct])];
   407   in
   408     thy2
   409     |> derive_datatype_props config dt_names alt_names descr sorts induct inject distinct
   410  end;
   411 
   412 fun gen_rep_datatype prep_term config after_qed alt_names raw_ts thy =
   413   let
   414     fun constr_of_term (Const (c, T)) = (c, T)
   415       | constr_of_term t =
   416           error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
   417     fun no_constr (c, T) = error ("Bad constructor: "
   418       ^ Sign.extern_const thy c ^ "::"
   419       ^ Syntax.string_of_typ_global thy T);
   420     fun type_of_constr (cT as (_, T)) =
   421       let
   422         val frees = OldTerm.typ_tfrees T;
   423         val (tyco, vs) = ((apsnd o map) (dest_TFree) o dest_Type o snd o strip_type) T
   424           handle TYPE _ => no_constr cT
   425         val _ = if has_duplicates (eq_fst (op =)) vs then no_constr cT else ();
   426         val _ = if length frees <> length vs then no_constr cT else ();
   427       in (tyco, (vs, cT)) end;
   428 
   429     val raw_cs = AList.group (op =) (map (type_of_constr o constr_of_term o prep_term thy) raw_ts);
   430     val _ = case map_filter (fn (tyco, _) =>
   431         if Symtab.defined (get_all thy) tyco then SOME tyco else NONE) raw_cs
   432      of [] => ()
   433       | tycos => error ("Type(s) " ^ commas (map quote tycos)
   434           ^ " already represented inductivly");
   435     val raw_vss = maps (map (map snd o fst) o snd) raw_cs;
   436     val ms = case distinct (op =) (map length raw_vss)
   437      of [n] => 0 upto n - 1
   438       | _ => error ("Different types in given constructors");
   439     fun inter_sort m = map (fn xs => nth xs m) raw_vss
   440       |> Library.foldr1 (Sorts.inter_sort (Sign.classes_of thy))
   441     val sorts = map inter_sort ms;
   442     val vs = Name.names Name.context Name.aT sorts;
   443 
   444     fun norm_constr (raw_vs, (c, T)) = (c, map_atyps
   445       (TFree o (the o AList.lookup (op =) (map fst raw_vs ~~ vs)) o fst o dest_TFree) T);
   446 
   447     val cs = map (apsnd (map norm_constr)) raw_cs;
   448     val dtyps_of_typ = map (dtyp_of_typ (map (rpair (map fst vs) o fst) cs))
   449       o fst o strip_type;
   450     val dt_names = map fst cs;
   451 
   452     fun mk_spec (i, (tyco, constr)) = (i, (tyco,
   453       map (DtTFree o fst) vs,
   454       (map o apsnd) dtyps_of_typ constr))
   455     val descr = map_index mk_spec cs;
   456     val injs = DatatypeProp.make_injs [descr] vs;
   457     val half_distincts = map snd (DatatypeProp.make_distincts [descr] vs);
   458     val ind = DatatypeProp.make_ind [descr] vs;
   459     val rules = (map o map o map) Logic.close_form [[[ind]], injs, half_distincts];
   460 
   461     fun after_qed' raw_thms =
   462       let
   463         val [[[induct]], injs, half_distincts] =
   464           unflat rules (map Drule.zero_var_indexes_list raw_thms);
   465             (*FIXME somehow dubious*)
   466       in
   467         ProofContext.theory_result
   468           (prove_rep_datatype config dt_names alt_names descr vs induct injs half_distincts)
   469         #-> after_qed
   470       end;
   471   in
   472     thy
   473     |> ProofContext.init
   474     |> Proof.theorem_i NONE after_qed' ((map o map) (rpair []) (flat rules))
   475   end;
   476 
   477 val rep_datatype = gen_rep_datatype Sign.cert_term;
   478 val rep_datatype_cmd = gen_rep_datatype Syntax.read_term_global default_config (K I);
   479 
   480 
   481 (** definitional introduction of datatypes **)
   482 
   483 fun add_datatype_def config new_type_names descr sorts types_syntax constr_syntax dt_info
   484     case_names_induct case_names_exhausts thy =
   485   let
   486     val _ = message config ("Proofs for datatype(s) " ^ commas_quote new_type_names);
   487 
   488     val ((inject, distinct, dist_rewrites, simproc_dists, induct), thy2) = thy |>
   489       DatatypeRepProofs.representation_proofs config dt_info new_type_names descr sorts
   490         types_syntax constr_syntax case_names_induct;
   491     val inducts = Project_Rule.projections (ProofContext.init thy2) induct;
   492 
   493     val (casedist_thms, thy3) = DatatypeAbsProofs.prove_casedist_thms config new_type_names descr
   494       sorts induct case_names_exhausts thy2;
   495     val ((reccomb_names, rec_thms), thy4) = DatatypeAbsProofs.prove_primrec_thms
   496       config new_type_names descr sorts dt_info inject dist_rewrites
   497       (Simplifier.theory_context thy3 dist_ss) induct thy3;
   498     val ((case_thms, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   499       config new_type_names descr sorts reccomb_names rec_thms thy4;
   500     val (split_thms, thy7) = DatatypeAbsProofs.prove_split_thms config new_type_names
   501       descr sorts inject dist_rewrites casedist_thms case_thms thy6;
   502     val (nchotomys, thy8) = DatatypeAbsProofs.prove_nchotomys config new_type_names
   503       descr sorts casedist_thms thy7;
   504     val (case_congs, thy9) = DatatypeAbsProofs.prove_case_congs new_type_names
   505       descr sorts nchotomys case_thms thy8;
   506     val (weak_case_congs, thy10) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   507       descr sorts thy9;
   508 
   509     val dt_infos = map
   510       (make_dt_info (SOME new_type_names) (flat descr) sorts (inducts, induct) reccomb_names rec_thms)
   511       ((0 upto length (hd descr) - 1) ~~ hd descr ~~ case_names ~~ case_thms ~~
   512         casedist_thms ~~ simproc_dists ~~ inject ~~ split_thms ~~ nchotomys ~~ case_congs ~~ weak_case_congs);
   513 
   514     val simps = flat (distinct @ inject @ case_thms) @ rec_thms;
   515     val dt_names = map fst dt_infos;
   516 
   517     val thy12 =
   518       thy10
   519       |> add_case_tr' case_names
   520       |> Sign.add_path (space_implode "_" new_type_names)
   521       |> add_rules simps case_thms rec_thms inject distinct
   522           weak_case_congs (Simplifier.attrib (op addcongs))
   523       |> register dt_infos
   524       |> add_cases_induct dt_infos inducts
   525       |> Sign.parent_path
   526       |> store_thmss "splits" new_type_names (map (fn (x, y) => [x, y]) split_thms) |> snd
   527       |> DatatypeInterpretation.data (config, map fst dt_infos);
   528   in (dt_names, thy12) end;
   529 
   530 fun gen_add_datatype prep_typ config new_type_names dts thy =
   531   let
   532     val _ = Theory.requires thy "Datatype" "datatype definitions";
   533 
   534     (* this theory is used just for parsing *)
   535 
   536     val tmp_thy = thy |>
   537       Theory.copy |>
   538       Sign.add_types (map (fn (tvs, tname, mx, _) =>
   539         (tname, length tvs, mx)) dts);
   540 
   541     val (tyvars, _, _, _)::_ = dts;
   542     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   543       let val full_tname = Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname)
   544       in (case duplicates (op =) tvs of
   545             [] => if eq_set (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   546                   else error ("Mutually recursive datatypes must have same type parameters")
   547           | dups => error ("Duplicate parameter(s) for datatype " ^ quote (Binding.str_of tname) ^
   548               " : " ^ commas dups))
   549       end) dts);
   550 
   551     val _ = (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   552       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   553 
   554     fun prep_dt_spec ((tvs, tname, mx, constrs), tname') (dts', constr_syntax, sorts, i) =
   555       let
   556         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   557           let
   558             val (cargs', sorts'') = Library.foldl (prep_typ tmp_thy) (([], sorts'), cargs);
   559             val _ = (case fold (curry OldTerm.add_typ_tfree_names) cargs' [] \\ tvs of
   560                 [] => ()
   561               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   562           in (constrs @ [(Sign.full_name_path tmp_thy tname'
   563                   (Binding.map_name (Syntax.const_name mx') cname),
   564                    map (dtyp_of_typ new_dts) cargs')],
   565               constr_syntax' @ [(cname, mx')], sorts'')
   566           end handle ERROR msg => cat_error msg
   567            ("The error above occured in constructor " ^ quote (Binding.str_of cname) ^
   568             " of datatype " ^ quote (Binding.str_of tname));
   569 
   570         val (constrs', constr_syntax', sorts') =
   571           fold prep_constr constrs ([], [], sorts)
   572 
   573       in
   574         case duplicates (op =) (map fst constrs') of
   575            [] =>
   576              (dts' @ [(i, (Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname),
   577                 map DtTFree tvs, constrs'))],
   578               constr_syntax @ [constr_syntax'], sorts', i + 1)
   579          | dups => error ("Duplicate constructors " ^ commas dups ^
   580              " in datatype " ^ quote (Binding.str_of tname))
   581       end;
   582 
   583     val (dts', constr_syntax, sorts', i) =
   584       fold prep_dt_spec (dts ~~ new_type_names) ([], [], [], 0);
   585     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (tyvars \\ map fst sorts'));
   586     val dt_info = get_all thy;
   587     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   588     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   589       if #strict config then error ("Nonemptiness check failed for datatype " ^ s)
   590       else raise exn;
   591 
   592     val descr' = flat descr;
   593     val case_names_induct = mk_case_names_induct descr';
   594     val case_names_exhausts = mk_case_names_exhausts descr' (map #1 new_dts);
   595   in
   596     add_datatype_def
   597       config new_type_names descr sorts types_syntax constr_syntax dt_info
   598       case_names_induct case_names_exhausts thy
   599   end;
   600 
   601 val add_datatype = gen_add_datatype cert_typ;
   602 val datatype_cmd = snd ooo gen_add_datatype read_typ default_config;
   603 
   604 
   605 (** package setup **)
   606 
   607 (* setup theory *)
   608 
   609 val setup =
   610   DatatypeRepProofs.distinctness_limit_setup #>
   611   simproc_setup #>
   612   trfun_setup #>
   613   DatatypeInterpretation.init;
   614 
   615 (* outer syntax *)
   616 
   617 local
   618 
   619 structure P = OuterParse and K = OuterKeyword
   620 
   621 fun prep_datatype_decls args =
   622   let
   623     val names = map
   624       (fn ((((NONE, _), t), _), _) => Binding.name_of t | ((((SOME t, _), _), _), _) => t) args;
   625     val specs = map (fn ((((_, vs), t), mx), cons) =>
   626       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   627   in (names, specs) end;
   628 
   629 val parse_datatype_decl =
   630   (Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.binding -- P.opt_infix --
   631     (P.$$$ "=" |-- P.enum1 "|" (P.binding -- Scan.repeat P.typ -- P.opt_mixfix)));
   632 
   633 val parse_datatype_decls = P.and_list1 parse_datatype_decl >> prep_datatype_decls;
   634 
   635 in
   636 
   637 val _ =
   638   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   639     (parse_datatype_decls >> (fn (names, specs) => Toplevel.theory (datatype_cmd names specs)));
   640 
   641 val _ =
   642   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_goal
   643     (Scan.option (P.$$$ "(" |-- Scan.repeat1 P.name --| P.$$$ ")") -- Scan.repeat1 P.term
   644       >> (fn (alt_names, ts) => Toplevel.print
   645            o Toplevel.theory_to_proof (rep_datatype_cmd alt_names ts)));
   646 
   647 end;
   648 
   649 end;
   650