src/HOL/Real/RealDef.thy
author nipkow
Tue Oct 23 23:27:23 2007 +0200 (2007-10-23)
changeset 25162 ad4d5365d9d8
parent 25140 273772abbea2
child 25303 0699e20feabd
permissions -rw-r--r--
went back to >0
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 definition
    17   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    18   "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 definition
    24   (** these don't use the overloaded "real" function: users don't see them **)
    25   real_of_preal :: "preal => real" where
    26   "real_of_preal m = Abs_Real(realrel``{(m + 1, 1)})"
    27 
    28 instance real :: zero
    29   real_zero_def: "0 == Abs_Real(realrel``{(1, 1)})" ..
    30 lemmas [code func del] = real_zero_def
    31 
    32 instance real :: one
    33   real_one_def: "1 == Abs_Real(realrel``{(1 + 1, 1)})" ..
    34 lemmas [code func del] = real_one_def
    35 
    36 instance real :: plus
    37   real_add_def: "z + w ==
    38        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    39 		 { Abs_Real(realrel``{(x+u, y+v)}) })" ..
    40 lemmas [code func del] = real_add_def
    41 
    42 instance real :: minus
    43   real_minus_def: "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    44   real_diff_def: "r - (s::real) == r + - s" ..
    45 lemmas [code func del] = real_minus_def real_diff_def
    46 
    47 instance real :: times
    48   real_mult_def:
    49     "z * w ==
    50        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    51 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })" ..
    52 lemmas [code func del] = real_mult_def
    53 
    54 instance real :: inverse
    55   real_inverse_def: "inverse (R::real) == (THE S. (R = 0 & S = 0) | S * R = 1)"
    56   real_divide_def: "R / (S::real) == R * inverse S" ..
    57 lemmas [code func del] = real_inverse_def real_divide_def
    58 
    59 instance real :: ord
    60   real_le_def: "z \<le> (w::real) == 
    61     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    62   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)" ..
    63 lemmas [code func del] = real_le_def real_less_def
    64 
    65 instance real :: abs
    66   real_abs_def:  "abs (r::real) == (if r < 0 then - r else r)" ..
    67 
    68 instance real :: sgn
    69   real_sgn_def: "sgn x == (if x=0 then 0 else if 0<x then 1 else - 1)" ..
    70 
    71 subsection {* Equivalence relation over positive reals *}
    72 
    73 lemma preal_trans_lemma:
    74   assumes "x + y1 = x1 + y"
    75       and "x + y2 = x2 + y"
    76   shows "x1 + y2 = x2 + (y1::preal)"
    77 proof -
    78   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    79   also have "... = (x2 + y) + x1"  by (simp add: prems)
    80   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    81   also have "... = x2 + (x + y1)"  by (simp add: prems)
    82   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    83   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    84   thus ?thesis by (rule add_right_imp_eq)
    85 qed
    86 
    87 
    88 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    89 by (simp add: realrel_def)
    90 
    91 lemma equiv_realrel: "equiv UNIV realrel"
    92 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
    93 apply (blast dest: preal_trans_lemma) 
    94 done
    95 
    96 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
    97   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
    98 lemmas equiv_realrel_iff = 
    99        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   100 
   101 declare equiv_realrel_iff [simp]
   102 
   103 
   104 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   105 by (simp add: Real_def realrel_def quotient_def, blast)
   106 
   107 declare Abs_Real_inject [simp]
   108 declare Abs_Real_inverse [simp]
   109 
   110 
   111 text{*Case analysis on the representation of a real number as an equivalence
   112       class of pairs of positive reals.*}
   113 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   114      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   115 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   116 apply (drule arg_cong [where f=Abs_Real])
   117 apply (auto simp add: Rep_Real_inverse)
   118 done
   119 
   120 
   121 subsection {* Addition and Subtraction *}
   122 
   123 lemma real_add_congruent2_lemma:
   124      "[|a + ba = aa + b; ab + bc = ac + bb|]
   125       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   126 apply (simp add: add_assoc)
   127 apply (rule add_left_commute [of ab, THEN ssubst])
   128 apply (simp add: add_assoc [symmetric])
   129 apply (simp add: add_ac)
   130 done
   131 
   132 lemma real_add:
   133      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   134       Abs_Real (realrel``{(x+u, y+v)})"
   135 proof -
   136   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   137         respects2 realrel"
   138     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   139   thus ?thesis
   140     by (simp add: real_add_def UN_UN_split_split_eq
   141                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   142 qed
   143 
   144 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   145 proof -
   146   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   147     by (simp add: congruent_def add_commute) 
   148   thus ?thesis
   149     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   150 qed
   151 
   152 instance real :: ab_group_add
   153 proof
   154   fix x y z :: real
   155   show "(x + y) + z = x + (y + z)"
   156     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   157   show "x + y = y + x"
   158     by (cases x, cases y, simp add: real_add add_commute)
   159   show "0 + x = x"
   160     by (cases x, simp add: real_add real_zero_def add_ac)
   161   show "- x + x = 0"
   162     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   163   show "x - y = x + - y"
   164     by (simp add: real_diff_def)
   165 qed
   166 
   167 
   168 subsection {* Multiplication *}
   169 
   170 lemma real_mult_congruent2_lemma:
   171      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   172           x * x1 + y * y1 + (x * y2 + y * x2) =
   173           x * x2 + y * y2 + (x * y1 + y * x1)"
   174 apply (simp add: add_left_commute add_assoc [symmetric])
   175 apply (simp add: add_assoc right_distrib [symmetric])
   176 apply (simp add: add_commute)
   177 done
   178 
   179 lemma real_mult_congruent2:
   180     "(%p1 p2.
   181         (%(x1,y1). (%(x2,y2). 
   182           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   183      respects2 realrel"
   184 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   185 apply (simp add: mult_commute add_commute)
   186 apply (auto simp add: real_mult_congruent2_lemma)
   187 done
   188 
   189 lemma real_mult:
   190       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   191        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   192 by (simp add: real_mult_def UN_UN_split_split_eq
   193          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   194 
   195 lemma real_mult_commute: "(z::real) * w = w * z"
   196 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   197 
   198 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   199 apply (cases z1, cases z2, cases z3)
   200 apply (simp add: real_mult right_distrib add_ac mult_ac)
   201 done
   202 
   203 lemma real_mult_1: "(1::real) * z = z"
   204 apply (cases z)
   205 apply (simp add: real_mult real_one_def right_distrib
   206                   mult_1_right mult_ac add_ac)
   207 done
   208 
   209 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   210 apply (cases z1, cases z2, cases w)
   211 apply (simp add: real_add real_mult right_distrib add_ac mult_ac)
   212 done
   213 
   214 text{*one and zero are distinct*}
   215 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   216 proof -
   217   have "(1::preal) < 1 + 1"
   218     by (simp add: preal_self_less_add_left)
   219   thus ?thesis
   220     by (simp add: real_zero_def real_one_def)
   221 qed
   222 
   223 instance real :: comm_ring_1
   224 proof
   225   fix x y z :: real
   226   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   227   show "x * y = y * x" by (rule real_mult_commute)
   228   show "1 * x = x" by (rule real_mult_1)
   229   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   230   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   231 qed
   232 
   233 subsection {* Inverse and Division *}
   234 
   235 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   236 by (simp add: real_zero_def add_commute)
   237 
   238 text{*Instead of using an existential quantifier and constructing the inverse
   239 within the proof, we could define the inverse explicitly.*}
   240 
   241 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   242 apply (simp add: real_zero_def real_one_def, cases x)
   243 apply (cut_tac x = xa and y = y in linorder_less_linear)
   244 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   245 apply (rule_tac
   246         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   247        in exI)
   248 apply (rule_tac [2]
   249         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   250        in exI)
   251 apply (auto simp add: real_mult preal_mult_inverse_right ring_simps)
   252 done
   253 
   254 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   255 apply (simp add: real_inverse_def)
   256 apply (drule real_mult_inverse_left_ex, safe)
   257 apply (rule theI, assumption, rename_tac z)
   258 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   259 apply (simp add: mult_commute)
   260 apply (rule mult_assoc)
   261 done
   262 
   263 
   264 subsection{*The Real Numbers form a Field*}
   265 
   266 instance real :: field
   267 proof
   268   fix x y z :: real
   269   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   270   show "x / y = x * inverse y" by (simp add: real_divide_def)
   271 qed
   272 
   273 
   274 text{*Inverse of zero!  Useful to simplify certain equations*}
   275 
   276 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   277 by (simp add: real_inverse_def)
   278 
   279 instance real :: division_by_zero
   280 proof
   281   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   282 qed
   283 
   284 
   285 subsection{*The @{text "\<le>"} Ordering*}
   286 
   287 lemma real_le_refl: "w \<le> (w::real)"
   288 by (cases w, force simp add: real_le_def)
   289 
   290 text{*The arithmetic decision procedure is not set up for type preal.
   291   This lemma is currently unused, but it could simplify the proofs of the
   292   following two lemmas.*}
   293 lemma preal_eq_le_imp_le:
   294   assumes eq: "a+b = c+d" and le: "c \<le> a"
   295   shows "b \<le> (d::preal)"
   296 proof -
   297   have "c+d \<le> a+d" by (simp add: prems)
   298   hence "a+b \<le> a+d" by (simp add: prems)
   299   thus "b \<le> d" by simp
   300 qed
   301 
   302 lemma real_le_lemma:
   303   assumes l: "u1 + v2 \<le> u2 + v1"
   304       and "x1 + v1 = u1 + y1"
   305       and "x2 + v2 = u2 + y2"
   306   shows "x1 + y2 \<le> x2 + (y1::preal)"
   307 proof -
   308   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   309   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   310   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   311   finally show ?thesis by simp
   312 qed
   313 
   314 lemma real_le: 
   315      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   316       (x1 + y2 \<le> x2 + y1)"
   317 apply (simp add: real_le_def)
   318 apply (auto intro: real_le_lemma)
   319 done
   320 
   321 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   322 by (cases z, cases w, simp add: real_le)
   323 
   324 lemma real_trans_lemma:
   325   assumes "x + v \<le> u + y"
   326       and "u + v' \<le> u' + v"
   327       and "x2 + v2 = u2 + y2"
   328   shows "x + v' \<le> u' + (y::preal)"
   329 proof -
   330   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   331   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   332   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   333   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   334   finally show ?thesis by simp
   335 qed
   336 
   337 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   338 apply (cases i, cases j, cases k)
   339 apply (simp add: real_le)
   340 apply (blast intro: real_trans_lemma)
   341 done
   342 
   343 (* Axiom 'order_less_le' of class 'order': *)
   344 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   345 by (simp add: real_less_def)
   346 
   347 instance real :: order
   348 proof qed
   349  (assumption |
   350   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   351 
   352 (* Axiom 'linorder_linear' of class 'linorder': *)
   353 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   354 apply (cases z, cases w)
   355 apply (auto simp add: real_le real_zero_def add_ac)
   356 done
   357 
   358 
   359 instance real :: linorder
   360   by (intro_classes, rule real_le_linear)
   361 
   362 
   363 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   364 apply (cases x, cases y) 
   365 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   366                       add_ac)
   367 apply (simp_all add: add_assoc [symmetric])
   368 done
   369 
   370 lemma real_add_left_mono: 
   371   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   372 proof -
   373   have "z + x - (z + y) = (z + -z) + (x - y)"
   374     by (simp add: diff_minus add_ac) 
   375   with le show ?thesis 
   376     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   377 qed
   378 
   379 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   380 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   381 
   382 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   383 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   384 
   385 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   386 apply (cases x, cases y)
   387 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   388                  linorder_not_le [where 'a = preal] 
   389                   real_zero_def real_le real_mult)
   390   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   391 apply (auto dest!: less_add_left_Ex
   392      simp add: add_ac mult_ac
   393           right_distrib preal_self_less_add_left)
   394 done
   395 
   396 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   397 apply (rule real_sum_gt_zero_less)
   398 apply (drule real_less_sum_gt_zero [of x y])
   399 apply (drule real_mult_order, assumption)
   400 apply (simp add: right_distrib)
   401 done
   402 
   403 instance real :: distrib_lattice
   404   "inf x y \<equiv> min x y"
   405   "sup x y \<equiv> max x y"
   406   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   407 
   408 
   409 subsection{*The Reals Form an Ordered Field*}
   410 
   411 instance real :: ordered_field
   412 proof
   413   fix x y z :: real
   414   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   415   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   416   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   417   show "sgn x = (if x=0 then 0 else if 0<x then 1 else - 1)"
   418     by (simp only: real_sgn_def)
   419 qed
   420 
   421 text{*The function @{term real_of_preal} requires many proofs, but it seems
   422 to be essential for proving completeness of the reals from that of the
   423 positive reals.*}
   424 
   425 lemma real_of_preal_add:
   426      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   427 by (simp add: real_of_preal_def real_add left_distrib add_ac)
   428 
   429 lemma real_of_preal_mult:
   430      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   431 by (simp add: real_of_preal_def real_mult right_distrib add_ac mult_ac)
   432 
   433 
   434 text{*Gleason prop 9-4.4 p 127*}
   435 lemma real_of_preal_trichotomy:
   436       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   437 apply (simp add: real_of_preal_def real_zero_def, cases x)
   438 apply (auto simp add: real_minus add_ac)
   439 apply (cut_tac x = x and y = y in linorder_less_linear)
   440 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   441 done
   442 
   443 lemma real_of_preal_leD:
   444       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   445 by (simp add: real_of_preal_def real_le)
   446 
   447 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   448 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   449 
   450 lemma real_of_preal_lessD:
   451       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   452 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   453 
   454 lemma real_of_preal_less_iff [simp]:
   455      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   456 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   457 
   458 lemma real_of_preal_le_iff:
   459      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   460 by (simp add: linorder_not_less [symmetric])
   461 
   462 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   463 apply (insert preal_self_less_add_left [of 1 m])
   464 apply (auto simp add: real_zero_def real_of_preal_def
   465                       real_less_def real_le_def add_ac)
   466 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   467 apply (simp add: add_ac)
   468 done
   469 
   470 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   471 by (simp add: real_of_preal_zero_less)
   472 
   473 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   474 proof -
   475   from real_of_preal_minus_less_zero
   476   show ?thesis by (blast dest: order_less_trans)
   477 qed
   478 
   479 
   480 subsection{*Theorems About the Ordering*}
   481 
   482 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   483 apply (auto simp add: real_of_preal_zero_less)
   484 apply (cut_tac x = x in real_of_preal_trichotomy)
   485 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   486 done
   487 
   488 lemma real_gt_preal_preal_Ex:
   489      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   490 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   491              intro: real_gt_zero_preal_Ex [THEN iffD1])
   492 
   493 lemma real_ge_preal_preal_Ex:
   494      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   495 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   496 
   497 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   498 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   499             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   500             simp add: real_of_preal_zero_less)
   501 
   502 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   503 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   504 
   505 
   506 subsection{*More Lemmas*}
   507 
   508 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   509 by auto
   510 
   511 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   512 by auto
   513 
   514 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   515   by (force elim: order_less_asym
   516             simp add: Ring_and_Field.mult_less_cancel_right)
   517 
   518 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   519 apply (simp add: mult_le_cancel_right)
   520 apply (blast intro: elim: order_less_asym)
   521 done
   522 
   523 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   524 by(simp add:mult_commute)
   525 
   526 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   527 by (simp add: one_less_inverse_iff) (* TODO: generalize/move *)
   528 
   529 
   530 subsection {* Embedding numbers into the Reals *}
   531 
   532 abbreviation
   533   real_of_nat :: "nat \<Rightarrow> real"
   534 where
   535   "real_of_nat \<equiv> of_nat"
   536 
   537 abbreviation
   538   real_of_int :: "int \<Rightarrow> real"
   539 where
   540   "real_of_int \<equiv> of_int"
   541 
   542 abbreviation
   543   real_of_rat :: "rat \<Rightarrow> real"
   544 where
   545   "real_of_rat \<equiv> of_rat"
   546 
   547 consts
   548   (*overloaded constant for injecting other types into "real"*)
   549   real :: "'a => real"
   550 
   551 defs (overloaded)
   552   real_of_nat_def [code inline]: "real == real_of_nat"
   553   real_of_int_def [code inline]: "real == real_of_int"
   554 
   555 lemma real_eq_of_nat: "real = of_nat"
   556   unfolding real_of_nat_def ..
   557 
   558 lemma real_eq_of_int: "real = of_int"
   559   unfolding real_of_int_def ..
   560 
   561 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   562 by (simp add: real_of_int_def) 
   563 
   564 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   565 by (simp add: real_of_int_def) 
   566 
   567 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   568 by (simp add: real_of_int_def) 
   569 
   570 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   571 by (simp add: real_of_int_def) 
   572 
   573 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   574 by (simp add: real_of_int_def) 
   575 
   576 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   577 by (simp add: real_of_int_def) 
   578 
   579 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   580   apply (subst real_eq_of_int)+
   581   apply (rule of_int_setsum)
   582 done
   583 
   584 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   585     (PROD x:A. real(f x))"
   586   apply (subst real_eq_of_int)+
   587   apply (rule of_int_setprod)
   588 done
   589 
   590 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   591 by (simp add: real_of_int_def) 
   592 
   593 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   594 by (simp add: real_of_int_def) 
   595 
   596 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   597 by (simp add: real_of_int_def) 
   598 
   599 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   600 by (simp add: real_of_int_def) 
   601 
   602 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   603 by (simp add: real_of_int_def) 
   604 
   605 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   606 by (simp add: real_of_int_def) 
   607 
   608 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   609 by (simp add: real_of_int_def)
   610 
   611 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   612 by (simp add: real_of_int_def)
   613 
   614 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   615 by (auto simp add: abs_if)
   616 
   617 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   618   apply (subgoal_tac "real n + 1 = real (n + 1)")
   619   apply (simp del: real_of_int_add)
   620   apply auto
   621 done
   622 
   623 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   624   apply (subgoal_tac "real m + 1 = real (m + 1)")
   625   apply (simp del: real_of_int_add)
   626   apply simp
   627 done
   628 
   629 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   630     real (x div d) + (real (x mod d)) / (real d)"
   631 proof -
   632   assume "d ~= 0"
   633   have "x = (x div d) * d + x mod d"
   634     by auto
   635   then have "real x = real (x div d) * real d + real(x mod d)"
   636     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   637   then have "real x / real d = ... / real d"
   638     by simp
   639   then show ?thesis
   640     by (auto simp add: add_divide_distrib ring_simps prems)
   641 qed
   642 
   643 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   644     real(n div d) = real n / real d"
   645   apply (frule real_of_int_div_aux [of d n])
   646   apply simp
   647   apply (simp add: zdvd_iff_zmod_eq_0)
   648 done
   649 
   650 lemma real_of_int_div2:
   651   "0 <= real (n::int) / real (x) - real (n div x)"
   652   apply (case_tac "x = 0")
   653   apply simp
   654   apply (case_tac "0 < x")
   655   apply (simp add: compare_rls)
   656   apply (subst real_of_int_div_aux)
   657   apply simp
   658   apply simp
   659   apply (subst zero_le_divide_iff)
   660   apply auto
   661   apply (simp add: compare_rls)
   662   apply (subst real_of_int_div_aux)
   663   apply simp
   664   apply simp
   665   apply (subst zero_le_divide_iff)
   666   apply auto
   667 done
   668 
   669 lemma real_of_int_div3:
   670   "real (n::int) / real (x) - real (n div x) <= 1"
   671   apply(case_tac "x = 0")
   672   apply simp
   673   apply (simp add: compare_rls)
   674   apply (subst real_of_int_div_aux)
   675   apply assumption
   676   apply simp
   677   apply (subst divide_le_eq)
   678   apply clarsimp
   679   apply (rule conjI)
   680   apply (rule impI)
   681   apply (rule order_less_imp_le)
   682   apply simp
   683   apply (rule impI)
   684   apply (rule order_less_imp_le)
   685   apply simp
   686 done
   687 
   688 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   689   by (insert real_of_int_div2 [of n x], simp)
   690 
   691 subsection{*Embedding the Naturals into the Reals*}
   692 
   693 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   694 by (simp add: real_of_nat_def)
   695 
   696 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   697 by (simp add: real_of_nat_def)
   698 
   699 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   700 by (simp add: real_of_nat_def)
   701 
   702 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   703 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   704 by (simp add: real_of_nat_def)
   705 
   706 lemma real_of_nat_less_iff [iff]: 
   707      "(real (n::nat) < real m) = (n < m)"
   708 by (simp add: real_of_nat_def)
   709 
   710 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   711 by (simp add: real_of_nat_def)
   712 
   713 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   714 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   715 
   716 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   717 by (simp add: real_of_nat_def del: of_nat_Suc)
   718 
   719 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   720 by (simp add: real_of_nat_def of_nat_mult)
   721 
   722 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   723     (SUM x:A. real(f x))"
   724   apply (subst real_eq_of_nat)+
   725   apply (rule of_nat_setsum)
   726 done
   727 
   728 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   729     (PROD x:A. real(f x))"
   730   apply (subst real_eq_of_nat)+
   731   apply (rule of_nat_setprod)
   732 done
   733 
   734 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   735   apply (subst card_eq_setsum)
   736   apply (subst real_of_nat_setsum)
   737   apply simp
   738 done
   739 
   740 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   741 by (simp add: real_of_nat_def)
   742 
   743 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   744 by (simp add: real_of_nat_def)
   745 
   746 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   747 by (simp add: add: real_of_nat_def of_nat_diff)
   748 
   749 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   750 by (auto simp: real_of_nat_def)
   751 
   752 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   753 by (simp add: add: real_of_nat_def)
   754 
   755 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   756 by (simp add: add: real_of_nat_def)
   757 
   758 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat))"
   759 by (simp add: add: real_of_nat_def)
   760 
   761 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   762   apply (subgoal_tac "real n + 1 = real (Suc n)")
   763   apply simp
   764   apply (auto simp add: real_of_nat_Suc)
   765 done
   766 
   767 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   768   apply (subgoal_tac "real m + 1 = real (Suc m)")
   769   apply (simp add: less_Suc_eq_le)
   770   apply (simp add: real_of_nat_Suc)
   771 done
   772 
   773 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   774     real (x div d) + (real (x mod d)) / (real d)"
   775 proof -
   776   assume "0 < d"
   777   have "x = (x div d) * d + x mod d"
   778     by auto
   779   then have "real x = real (x div d) * real d + real(x mod d)"
   780     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   781   then have "real x / real d = \<dots> / real d"
   782     by simp
   783   then show ?thesis
   784     by (auto simp add: add_divide_distrib ring_simps prems)
   785 qed
   786 
   787 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   788     real(n div d) = real n / real d"
   789   apply (frule real_of_nat_div_aux [of d n])
   790   apply simp
   791   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   792   apply assumption
   793 done
   794 
   795 lemma real_of_nat_div2:
   796   "0 <= real (n::nat) / real (x) - real (n div x)"
   797 apply(case_tac "x = 0")
   798  apply (simp)
   799 apply (simp add: compare_rls)
   800 apply (subst real_of_nat_div_aux)
   801  apply simp
   802 apply simp
   803 apply (subst zero_le_divide_iff)
   804 apply simp
   805 done
   806 
   807 lemma real_of_nat_div3:
   808   "real (n::nat) / real (x) - real (n div x) <= 1"
   809 apply(case_tac "x = 0")
   810 apply (simp)
   811 apply (simp add: compare_rls)
   812 apply (subst real_of_nat_div_aux)
   813  apply simp
   814 apply simp
   815 done
   816 
   817 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   818   by (insert real_of_nat_div2 [of n x], simp)
   819 
   820 lemma real_of_int_real_of_nat: "real (int n) = real n"
   821 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   822 
   823 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   824 by (simp add: real_of_int_def real_of_nat_def)
   825 
   826 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   827   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   828   apply force
   829   apply (simp only: real_of_int_real_of_nat)
   830 done
   831 
   832 subsection{*Numerals and Arithmetic*}
   833 
   834 instance real :: number_ring
   835   real_number_of_def: "number_of w \<equiv> real_of_int w"
   836   by intro_classes (simp add: real_number_of_def)
   837 
   838 lemma [code, code unfold]:
   839   "number_of k = real_of_int (number_of k)"
   840   unfolding number_of_is_id real_number_of_def ..
   841 
   842 
   843 text{*Collapse applications of @{term real} to @{term number_of}*}
   844 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   845 by (simp add:  real_of_int_def of_int_number_of_eq)
   846 
   847 lemma real_of_nat_number_of [simp]:
   848      "real (number_of v :: nat) =  
   849         (if neg (number_of v :: int) then 0  
   850          else (number_of v :: real))"
   851 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   852  
   853 
   854 use "real_arith.ML"
   855 declaration {* K real_arith_setup *}
   856 
   857 
   858 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   859 
   860 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   861 lemma real_0_le_divide_iff:
   862      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   863 by (simp add: real_divide_def zero_le_mult_iff, auto)
   864 
   865 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   866 by arith
   867 
   868 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   869 by auto
   870 
   871 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   872 by auto
   873 
   874 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   875 by auto
   876 
   877 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   878 by auto
   879 
   880 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   881 by auto
   882 
   883 
   884 (*
   885 FIXME: we should have this, as for type int, but many proofs would break.
   886 It replaces x+-y by x-y.
   887 declare real_diff_def [symmetric, simp]
   888 *)
   889 
   890 
   891 subsubsection{*Density of the Reals*}
   892 
   893 lemma real_lbound_gt_zero:
   894      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   895 apply (rule_tac x = " (min d1 d2) /2" in exI)
   896 apply (simp add: min_def)
   897 done
   898 
   899 
   900 text{*Similar results are proved in @{text Ring_and_Field}*}
   901 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   902   by auto
   903 
   904 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   905   by auto
   906 
   907 
   908 subsection{*Absolute Value Function for the Reals*}
   909 
   910 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   911 by (simp add: abs_if)
   912 
   913 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
   914 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   915 by (force simp add: OrderedGroup.abs_le_iff)
   916 
   917 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   918 by (simp add: abs_if)
   919 
   920 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   921 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
   922 
   923 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   924 by simp
   925  
   926 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   927 by simp
   928 
   929 
   930 subsection {* Implementation of rational real numbers as pairs of integers *}
   931 
   932 definition
   933   Ratreal :: "int \<times> int \<Rightarrow> real"
   934 where
   935   "Ratreal = INum"
   936 
   937 code_datatype Ratreal
   938 
   939 lemma Ratreal_simp:
   940   "Ratreal (k, l) = real_of_int k / real_of_int l"
   941   unfolding Ratreal_def INum_def by simp
   942 
   943 lemma Ratreal_zero [simp]: "Ratreal 0\<^sub>N = 0"
   944   by (simp add: Ratreal_simp)
   945 
   946 lemma Ratreal_lit [simp]: "Ratreal i\<^sub>N = real_of_int i"
   947   by (simp add: Ratreal_simp)
   948 
   949 lemma zero_real_code [code, code unfold]:
   950   "0 = Ratreal 0\<^sub>N" by simp
   951 
   952 lemma one_real_code [code, code unfold]:
   953   "1 = Ratreal 1\<^sub>N" by simp
   954 
   955 instance real :: eq ..
   956 
   957 lemma real_eq_code [code]: "Ratreal x = Ratreal y \<longleftrightarrow> normNum x = normNum y"
   958   unfolding Ratreal_def INum_normNum_iff ..
   959 
   960 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> normNum x \<le>\<^sub>N normNum y"
   961 proof -
   962   have "normNum x \<le>\<^sub>N normNum y \<longleftrightarrow> Ratreal (normNum x) \<le> Ratreal (normNum y)" 
   963     by (simp add: Ratreal_def del: normNum)
   964   also have "\<dots> = (Ratreal x \<le> Ratreal y)" by (simp add: Ratreal_def)
   965   finally show ?thesis by simp
   966 qed
   967 
   968 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> normNum x <\<^sub>N normNum y"
   969 proof -
   970   have "normNum x <\<^sub>N normNum y \<longleftrightarrow> Ratreal (normNum x) < Ratreal (normNum y)" 
   971     by (simp add: Ratreal_def del: normNum)
   972   also have "\<dots> = (Ratreal x < Ratreal y)" by (simp add: Ratreal_def)
   973   finally show ?thesis by simp
   974 qed
   975 
   976 lemma real_add_code [code]: "Ratreal x + Ratreal y = Ratreal (x +\<^sub>N y)"
   977   unfolding Ratreal_def by simp
   978 
   979 lemma real_mul_code [code]: "Ratreal x * Ratreal y = Ratreal (x *\<^sub>N y)"
   980   unfolding Ratreal_def by simp
   981 
   982 lemma real_neg_code [code]: "- Ratreal x = Ratreal (~\<^sub>N x)"
   983   unfolding Ratreal_def by simp
   984 
   985 lemma real_sub_code [code]: "Ratreal x - Ratreal y = Ratreal (x -\<^sub>N y)"
   986   unfolding Ratreal_def by simp
   987 
   988 lemma real_inv_code [code]: "inverse (Ratreal x) = Ratreal (Ninv x)"
   989   unfolding Ratreal_def Ninv real_divide_def by simp
   990 
   991 lemma real_div_code [code]: "Ratreal x / Ratreal y = Ratreal (x \<div>\<^sub>N y)"
   992   unfolding Ratreal_def by simp
   993 
   994 text {* Setup for SML code generator *}
   995 
   996 types_code
   997   real ("(int */ int)")
   998 attach (term_of) {*
   999 fun term_of_real (p, q) =
  1000   let
  1001     val rT = HOLogic.realT
  1002   in
  1003     if q = 1 orelse p = 0 then HOLogic.mk_number rT p
  1004     else @{term "op / \<Colon> real \<Rightarrow> real \<Rightarrow> real"} $
  1005       HOLogic.mk_number rT p $ HOLogic.mk_number rT q
  1006   end;
  1007 *}
  1008 attach (test) {*
  1009 fun gen_real i =
  1010   let
  1011     val p = random_range 0 i;
  1012     val q = random_range 1 (i + 1);
  1013     val g = Integer.gcd p q;
  1014     val p' = p div g;
  1015     val q' = q div g;
  1016   in
  1017     (if one_of [true, false] then p' else ~ p',
  1018      if p' = 0 then 0 else q')
  1019   end;
  1020 *}
  1021 
  1022 consts_code
  1023   Ratreal ("(_)")
  1024 
  1025 consts_code
  1026   "of_int :: int \<Rightarrow> real" ("\<module>real'_of'_int")
  1027 attach {*
  1028 fun real_of_int 0 = (0, 0)
  1029   | real_of_int i = (i, 1);
  1030 *}
  1031 
  1032 declare real_of_int_of_nat_eq [symmetric, code]
  1033 
  1034 end