src/HOL/Extraction.thy
author huffman
Mon Jan 12 12:09:54 2009 -0800 (2009-01-12)
changeset 29460 ad87e5d1488b
parent 28797 9dcd32ee5dbe
child 29930 80a9a55b0a0e
permissions -rw-r--r--
new lemmas about synthetic_div; declare degree_pCons_eq_if [simp]
     1 (*  Title:      HOL/Extraction.thy
     2     ID:         $Id$
     3     Author:     Stefan Berghofer, TU Muenchen
     4 *)
     5 
     6 header {* Program extraction for HOL *}
     7 
     8 theory Extraction
     9 imports Datatype
    10 uses "Tools/rewrite_hol_proof.ML"
    11 begin
    12 
    13 subsection {* Setup *}
    14 
    15 setup {*
    16 let
    17 fun realizes_set_proc (Const ("realizes", Type ("fun", [Type ("Null", []), _])) $ r $
    18       (Const ("op :", _) $ x $ S)) = (case strip_comb S of
    19         (Var (ixn, U), ts) => SOME (list_comb (Var (ixn, binder_types U @
    20            [HOLogic.dest_setT (body_type U)] ---> HOLogic.boolT), ts @ [x]))
    21       | (Free (s, U), ts) => SOME (list_comb (Free (s, binder_types U @
    22            [HOLogic.dest_setT (body_type U)] ---> HOLogic.boolT), ts @ [x]))
    23       | _ => NONE)
    24   | realizes_set_proc (Const ("realizes", Type ("fun", [T, _])) $ r $
    25       (Const ("op :", _) $ x $ S)) = (case strip_comb S of
    26         (Var (ixn, U), ts) => SOME (list_comb (Var (ixn, T :: binder_types U @
    27            [HOLogic.dest_setT (body_type U)] ---> HOLogic.boolT), r :: ts @ [x]))
    28       | (Free (s, U), ts) => SOME (list_comb (Free (s, T :: binder_types U @
    29            [HOLogic.dest_setT (body_type U)] ---> HOLogic.boolT), r :: ts @ [x]))
    30       | _ => NONE)
    31   | realizes_set_proc _ = NONE;
    32 
    33 fun mk_realizes_set r rT s (setT as Type ("set", [elT])) =
    34   Abs ("x", elT, Const ("realizes", rT --> HOLogic.boolT --> HOLogic.boolT) $
    35     incr_boundvars 1 r $ (Const ("op :", elT --> setT --> HOLogic.boolT) $
    36       Bound 0 $ incr_boundvars 1 s));
    37 in
    38   Extraction.add_types
    39       [("bool", ([], NONE)),
    40        ("set", ([realizes_set_proc], SOME mk_realizes_set))] #>
    41   Extraction.set_preprocessor (fn thy =>
    42       Proofterm.rewrite_proof_notypes
    43         ([], RewriteHOLProof.elim_cong :: ProofRewriteRules.rprocs true) o
    44       Proofterm.rewrite_proof thy
    45         (RewriteHOLProof.rews, ProofRewriteRules.rprocs true) o
    46       ProofRewriteRules.elim_vars (curry Const @{const_name default}))
    47 end
    48 *}
    49 
    50 lemmas [extraction_expand] =
    51   meta_spec atomize_eq atomize_all atomize_imp atomize_conj
    52   allE rev_mp conjE Eq_TrueI Eq_FalseI eqTrueI eqTrueE eq_cong2
    53   notE' impE' impE iffE imp_cong simp_thms eq_True eq_False
    54   induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
    55   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
    56   induct_atomize induct_rulify induct_rulify_fallback
    57   True_implies_equals TrueE
    58 
    59 datatype sumbool = Left | Right
    60 
    61 subsection {* Type of extracted program *}
    62 
    63 extract_type
    64   "typeof (Trueprop P) \<equiv> typeof P"
    65 
    66   "typeof P \<equiv> Type (TYPE(Null)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE('Q)) \<Longrightarrow>
    67      typeof (P \<longrightarrow> Q) \<equiv> Type (TYPE('Q))"
    68 
    69   "typeof Q \<equiv> Type (TYPE(Null)) \<Longrightarrow> typeof (P \<longrightarrow> Q) \<equiv> Type (TYPE(Null))"
    70 
    71   "typeof P \<equiv> Type (TYPE('P)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE('Q)) \<Longrightarrow>
    72      typeof (P \<longrightarrow> Q) \<equiv> Type (TYPE('P \<Rightarrow> 'Q))"
    73 
    74   "(\<lambda>x. typeof (P x)) \<equiv> (\<lambda>x. Type (TYPE(Null))) \<Longrightarrow>
    75      typeof (\<forall>x. P x) \<equiv> Type (TYPE(Null))"
    76 
    77   "(\<lambda>x. typeof (P x)) \<equiv> (\<lambda>x. Type (TYPE('P))) \<Longrightarrow>
    78      typeof (\<forall>x::'a. P x) \<equiv> Type (TYPE('a \<Rightarrow> 'P))"
    79 
    80   "(\<lambda>x. typeof (P x)) \<equiv> (\<lambda>x. Type (TYPE(Null))) \<Longrightarrow>
    81      typeof (\<exists>x::'a. P x) \<equiv> Type (TYPE('a))"
    82 
    83   "(\<lambda>x. typeof (P x)) \<equiv> (\<lambda>x. Type (TYPE('P))) \<Longrightarrow>
    84      typeof (\<exists>x::'a. P x) \<equiv> Type (TYPE('a \<times> 'P))"
    85 
    86   "typeof P \<equiv> Type (TYPE(Null)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE(Null)) \<Longrightarrow>
    87      typeof (P \<or> Q) \<equiv> Type (TYPE(sumbool))"
    88 
    89   "typeof P \<equiv> Type (TYPE(Null)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE('Q)) \<Longrightarrow>
    90      typeof (P \<or> Q) \<equiv> Type (TYPE('Q option))"
    91 
    92   "typeof P \<equiv> Type (TYPE('P)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE(Null)) \<Longrightarrow>
    93      typeof (P \<or> Q) \<equiv> Type (TYPE('P option))"
    94 
    95   "typeof P \<equiv> Type (TYPE('P)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE('Q)) \<Longrightarrow>
    96      typeof (P \<or> Q) \<equiv> Type (TYPE('P + 'Q))"
    97 
    98   "typeof P \<equiv> Type (TYPE(Null)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE('Q)) \<Longrightarrow>
    99      typeof (P \<and> Q) \<equiv> Type (TYPE('Q))"
   100 
   101   "typeof P \<equiv> Type (TYPE('P)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE(Null)) \<Longrightarrow>
   102      typeof (P \<and> Q) \<equiv> Type (TYPE('P))"
   103 
   104   "typeof P \<equiv> Type (TYPE('P)) \<Longrightarrow> typeof Q \<equiv> Type (TYPE('Q)) \<Longrightarrow>
   105      typeof (P \<and> Q) \<equiv> Type (TYPE('P \<times> 'Q))"
   106 
   107   "typeof (P = Q) \<equiv> typeof ((P \<longrightarrow> Q) \<and> (Q \<longrightarrow> P))"
   108 
   109   "typeof (x \<in> P) \<equiv> typeof P"
   110 
   111 subsection {* Realizability *}
   112 
   113 realizability
   114   "(realizes t (Trueprop P)) \<equiv> (Trueprop (realizes t P))"
   115 
   116   "(typeof P) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   117      (realizes t (P \<longrightarrow> Q)) \<equiv> (realizes Null P \<longrightarrow> realizes t Q)"
   118 
   119   "(typeof P) \<equiv> (Type (TYPE('P))) \<Longrightarrow>
   120    (typeof Q) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   121      (realizes t (P \<longrightarrow> Q)) \<equiv> (\<forall>x::'P. realizes x P \<longrightarrow> realizes Null Q)"
   122 
   123   "(realizes t (P \<longrightarrow> Q)) \<equiv> (\<forall>x. realizes x P \<longrightarrow> realizes (t x) Q)"
   124 
   125   "(\<lambda>x. typeof (P x)) \<equiv> (\<lambda>x. Type (TYPE(Null))) \<Longrightarrow>
   126      (realizes t (\<forall>x. P x)) \<equiv> (\<forall>x. realizes Null (P x))"
   127 
   128   "(realizes t (\<forall>x. P x)) \<equiv> (\<forall>x. realizes (t x) (P x))"
   129 
   130   "(\<lambda>x. typeof (P x)) \<equiv> (\<lambda>x. Type (TYPE(Null))) \<Longrightarrow>
   131      (realizes t (\<exists>x. P x)) \<equiv> (realizes Null (P t))"
   132 
   133   "(realizes t (\<exists>x. P x)) \<equiv> (realizes (snd t) (P (fst t)))"
   134 
   135   "(typeof P) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   136    (typeof Q) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   137      (realizes t (P \<or> Q)) \<equiv>
   138      (case t of Left \<Rightarrow> realizes Null P | Right \<Rightarrow> realizes Null Q)"
   139 
   140   "(typeof P) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   141      (realizes t (P \<or> Q)) \<equiv>
   142      (case t of None \<Rightarrow> realizes Null P | Some q \<Rightarrow> realizes q Q)"
   143 
   144   "(typeof Q) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   145      (realizes t (P \<or> Q)) \<equiv>
   146      (case t of None \<Rightarrow> realizes Null Q | Some p \<Rightarrow> realizes p P)"
   147 
   148   "(realizes t (P \<or> Q)) \<equiv>
   149    (case t of Inl p \<Rightarrow> realizes p P | Inr q \<Rightarrow> realizes q Q)"
   150 
   151   "(typeof P) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   152      (realizes t (P \<and> Q)) \<equiv> (realizes Null P \<and> realizes t Q)"
   153 
   154   "(typeof Q) \<equiv> (Type (TYPE(Null))) \<Longrightarrow>
   155      (realizes t (P \<and> Q)) \<equiv> (realizes t P \<and> realizes Null Q)"
   156 
   157   "(realizes t (P \<and> Q)) \<equiv> (realizes (fst t) P \<and> realizes (snd t) Q)"
   158 
   159   "typeof P \<equiv> Type (TYPE(Null)) \<Longrightarrow>
   160      realizes t (\<not> P) \<equiv> \<not> realizes Null P"
   161 
   162   "typeof P \<equiv> Type (TYPE('P)) \<Longrightarrow>
   163      realizes t (\<not> P) \<equiv> (\<forall>x::'P. \<not> realizes x P)"
   164 
   165   "typeof (P::bool) \<equiv> Type (TYPE(Null)) \<Longrightarrow>
   166    typeof Q \<equiv> Type (TYPE(Null)) \<Longrightarrow>
   167      realizes t (P = Q) \<equiv> realizes Null P = realizes Null Q"
   168 
   169   "(realizes t (P = Q)) \<equiv> (realizes t ((P \<longrightarrow> Q) \<and> (Q \<longrightarrow> P)))"
   170 
   171 subsection {* Computational content of basic inference rules *}
   172 
   173 theorem disjE_realizer:
   174   assumes r: "case x of Inl p \<Rightarrow> P p | Inr q \<Rightarrow> Q q"
   175   and r1: "\<And>p. P p \<Longrightarrow> R (f p)" and r2: "\<And>q. Q q \<Longrightarrow> R (g q)"
   176   shows "R (case x of Inl p \<Rightarrow> f p | Inr q \<Rightarrow> g q)"
   177 proof (cases x)
   178   case Inl
   179   with r show ?thesis by simp (rule r1)
   180 next
   181   case Inr
   182   with r show ?thesis by simp (rule r2)
   183 qed
   184 
   185 theorem disjE_realizer2:
   186   assumes r: "case x of None \<Rightarrow> P | Some q \<Rightarrow> Q q"
   187   and r1: "P \<Longrightarrow> R f" and r2: "\<And>q. Q q \<Longrightarrow> R (g q)"
   188   shows "R (case x of None \<Rightarrow> f | Some q \<Rightarrow> g q)"
   189 proof (cases x)
   190   case None
   191   with r show ?thesis by simp (rule r1)
   192 next
   193   case Some
   194   with r show ?thesis by simp (rule r2)
   195 qed
   196 
   197 theorem disjE_realizer3:
   198   assumes r: "case x of Left \<Rightarrow> P | Right \<Rightarrow> Q"
   199   and r1: "P \<Longrightarrow> R f" and r2: "Q \<Longrightarrow> R g"
   200   shows "R (case x of Left \<Rightarrow> f | Right \<Rightarrow> g)"
   201 proof (cases x)
   202   case Left
   203   with r show ?thesis by simp (rule r1)
   204 next
   205   case Right
   206   with r show ?thesis by simp (rule r2)
   207 qed
   208 
   209 theorem conjI_realizer:
   210   "P p \<Longrightarrow> Q q \<Longrightarrow> P (fst (p, q)) \<and> Q (snd (p, q))"
   211   by simp
   212 
   213 theorem exI_realizer:
   214   "P y x \<Longrightarrow> P (snd (x, y)) (fst (x, y))" by simp
   215 
   216 theorem exE_realizer: "P (snd p) (fst p) \<Longrightarrow>
   217   (\<And>x y. P y x \<Longrightarrow> Q (f x y)) \<Longrightarrow> Q (let (x, y) = p in f x y)"
   218   by (cases p) (simp add: Let_def)
   219 
   220 theorem exE_realizer': "P (snd p) (fst p) \<Longrightarrow>
   221   (\<And>x y. P y x \<Longrightarrow> Q) \<Longrightarrow> Q" by (cases p) simp
   222 
   223 setup {*
   224   Sign.add_const_constraint (@{const_name "default"}, SOME @{typ "'a::type"})
   225 *}
   226 
   227 realizers
   228   impI (P, Q): "\<lambda>pq. pq"
   229     "\<Lambda> P Q pq (h: _). allI \<cdot> _ \<bullet> (\<Lambda> x. impI \<cdot> _ \<cdot> _ \<bullet> (h \<cdot> x))"
   230 
   231   impI (P): "Null"
   232     "\<Lambda> P Q (h: _). allI \<cdot> _ \<bullet> (\<Lambda> x. impI \<cdot> _ \<cdot> _ \<bullet> (h \<cdot> x))"
   233 
   234   impI (Q): "\<lambda>q. q" "\<Lambda> P Q q. impI \<cdot> _ \<cdot> _"
   235 
   236   impI: "Null" "impI"
   237 
   238   mp (P, Q): "\<lambda>pq. pq"
   239     "\<Lambda> P Q pq (h: _) p. mp \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> p \<bullet> h)"
   240 
   241   mp (P): "Null"
   242     "\<Lambda> P Q (h: _) p. mp \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> p \<bullet> h)"
   243 
   244   mp (Q): "\<lambda>q. q" "\<Lambda> P Q q. mp \<cdot> _ \<cdot> _"
   245 
   246   mp: "Null" "mp"
   247 
   248   allI (P): "\<lambda>p. p" "\<Lambda> P p. allI \<cdot> _"
   249 
   250   allI: "Null" "allI"
   251 
   252   spec (P): "\<lambda>x p. p x" "\<Lambda> P x p. spec \<cdot> _ \<cdot> x"
   253 
   254   spec: "Null" "spec"
   255 
   256   exI (P): "\<lambda>x p. (x, p)" "\<Lambda> P x p. exI_realizer \<cdot> P \<cdot> p \<cdot> x"
   257 
   258   exI: "\<lambda>x. x" "\<Lambda> P x (h: _). h"
   259 
   260   exE (P, Q): "\<lambda>p pq. let (x, y) = p in pq x y"
   261     "\<Lambda> P Q p (h: _) pq. exE_realizer \<cdot> P \<cdot> p \<cdot> Q \<cdot> pq \<bullet> h"
   262 
   263   exE (P): "Null"
   264     "\<Lambda> P Q p. exE_realizer' \<cdot> _ \<cdot> _ \<cdot> _"
   265 
   266   exE (Q): "\<lambda>x pq. pq x"
   267     "\<Lambda> P Q x (h1: _) pq (h2: _). h2 \<cdot> x \<bullet> h1"
   268 
   269   exE: "Null"
   270     "\<Lambda> P Q x (h1: _) (h2: _). h2 \<cdot> x \<bullet> h1"
   271 
   272   conjI (P, Q): "Pair"
   273     "\<Lambda> P Q p (h: _) q. conjI_realizer \<cdot> P \<cdot> p \<cdot> Q \<cdot> q \<bullet> h"
   274 
   275   conjI (P): "\<lambda>p. p"
   276     "\<Lambda> P Q p. conjI \<cdot> _ \<cdot> _"
   277 
   278   conjI (Q): "\<lambda>q. q"
   279     "\<Lambda> P Q (h: _) q. conjI \<cdot> _ \<cdot> _ \<bullet> h"
   280 
   281   conjI: "Null" "conjI"
   282 
   283   conjunct1 (P, Q): "fst"
   284     "\<Lambda> P Q pq. conjunct1 \<cdot> _ \<cdot> _"
   285 
   286   conjunct1 (P): "\<lambda>p. p"
   287     "\<Lambda> P Q p. conjunct1 \<cdot> _ \<cdot> _"
   288 
   289   conjunct1 (Q): "Null"
   290     "\<Lambda> P Q q. conjunct1 \<cdot> _ \<cdot> _"
   291 
   292   conjunct1: "Null" "conjunct1"
   293 
   294   conjunct2 (P, Q): "snd"
   295     "\<Lambda> P Q pq. conjunct2 \<cdot> _ \<cdot> _"
   296 
   297   conjunct2 (P): "Null"
   298     "\<Lambda> P Q p. conjunct2 \<cdot> _ \<cdot> _"
   299 
   300   conjunct2 (Q): "\<lambda>p. p"
   301     "\<Lambda> P Q p. conjunct2 \<cdot> _ \<cdot> _"
   302 
   303   conjunct2: "Null" "conjunct2"
   304 
   305   disjI1 (P, Q): "Inl"
   306     "\<Lambda> P Q p. iffD2 \<cdot> _ \<cdot> _ \<bullet> (sum.cases_1 \<cdot> P \<cdot> _ \<cdot> p)"
   307 
   308   disjI1 (P): "Some"
   309     "\<Lambda> P Q p. iffD2 \<cdot> _ \<cdot> _ \<bullet> (option.cases_2 \<cdot> _ \<cdot> P \<cdot> p)"
   310 
   311   disjI1 (Q): "None"
   312     "\<Lambda> P Q. iffD2 \<cdot> _ \<cdot> _ \<bullet> (option.cases_1 \<cdot> _ \<cdot> _)"
   313 
   314   disjI1: "Left"
   315     "\<Lambda> P Q. iffD2 \<cdot> _ \<cdot> _ \<bullet> (sumbool.cases_1 \<cdot> _ \<cdot> _)"
   316 
   317   disjI2 (P, Q): "Inr"
   318     "\<Lambda> Q P q. iffD2 \<cdot> _ \<cdot> _ \<bullet> (sum.cases_2 \<cdot> _ \<cdot> Q \<cdot> q)"
   319 
   320   disjI2 (P): "None"
   321     "\<Lambda> Q P. iffD2 \<cdot> _ \<cdot> _ \<bullet> (option.cases_1 \<cdot> _ \<cdot> _)"
   322 
   323   disjI2 (Q): "Some"
   324     "\<Lambda> Q P q. iffD2 \<cdot> _ \<cdot> _ \<bullet> (option.cases_2 \<cdot> _ \<cdot> Q \<cdot> q)"
   325 
   326   disjI2: "Right"
   327     "\<Lambda> Q P. iffD2 \<cdot> _ \<cdot> _ \<bullet> (sumbool.cases_2 \<cdot> _ \<cdot> _)"
   328 
   329   disjE (P, Q, R): "\<lambda>pq pr qr.
   330      (case pq of Inl p \<Rightarrow> pr p | Inr q \<Rightarrow> qr q)"
   331     "\<Lambda> P Q R pq (h1: _) pr (h2: _) qr.
   332        disjE_realizer \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> R \<cdot> pr \<cdot> qr \<bullet> h1 \<bullet> h2"
   333 
   334   disjE (Q, R): "\<lambda>pq pr qr.
   335      (case pq of None \<Rightarrow> pr | Some q \<Rightarrow> qr q)"
   336     "\<Lambda> P Q R pq (h1: _) pr (h2: _) qr.
   337        disjE_realizer2 \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> R \<cdot> pr \<cdot> qr \<bullet> h1 \<bullet> h2"
   338 
   339   disjE (P, R): "\<lambda>pq pr qr.
   340      (case pq of None \<Rightarrow> qr | Some p \<Rightarrow> pr p)"
   341     "\<Lambda> P Q R pq (h1: _) pr (h2: _) qr (h3: _).
   342        disjE_realizer2 \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> R \<cdot> qr \<cdot> pr \<bullet> h1 \<bullet> h3 \<bullet> h2"
   343 
   344   disjE (R): "\<lambda>pq pr qr.
   345      (case pq of Left \<Rightarrow> pr | Right \<Rightarrow> qr)"
   346     "\<Lambda> P Q R pq (h1: _) pr (h2: _) qr.
   347        disjE_realizer3 \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> R \<cdot> pr \<cdot> qr \<bullet> h1 \<bullet> h2"
   348 
   349   disjE (P, Q): "Null"
   350     "\<Lambda> P Q R pq. disjE_realizer \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> (\<lambda>x. R) \<cdot> _ \<cdot> _"
   351 
   352   disjE (Q): "Null"
   353     "\<Lambda> P Q R pq. disjE_realizer2 \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> (\<lambda>x. R) \<cdot> _ \<cdot> _"
   354 
   355   disjE (P): "Null"
   356     "\<Lambda> P Q R pq (h1: _) (h2: _) (h3: _).
   357        disjE_realizer2 \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> (\<lambda>x. R) \<cdot> _ \<cdot> _ \<bullet> h1 \<bullet> h3 \<bullet> h2"
   358 
   359   disjE: "Null"
   360     "\<Lambda> P Q R pq. disjE_realizer3 \<cdot> _ \<cdot> _ \<cdot> pq \<cdot> (\<lambda>x. R) \<cdot> _ \<cdot> _"
   361 
   362   FalseE (P): "default"
   363     "\<Lambda> P. FalseE \<cdot> _"
   364 
   365   FalseE: "Null" "FalseE"
   366 
   367   notI (P): "Null"
   368     "\<Lambda> P (h: _). allI \<cdot> _ \<bullet> (\<Lambda> x. notI \<cdot> _ \<bullet> (h \<cdot> x))"
   369 
   370   notI: "Null" "notI"
   371 
   372   notE (P, R): "\<lambda>p. default"
   373     "\<Lambda> P R (h: _) p. notE \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> p \<bullet> h)"
   374 
   375   notE (P): "Null"
   376     "\<Lambda> P R (h: _) p. notE \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> p \<bullet> h)"
   377 
   378   notE (R): "default"
   379     "\<Lambda> P R. notE \<cdot> _ \<cdot> _"
   380 
   381   notE: "Null" "notE"
   382 
   383   subst (P): "\<lambda>s t ps. ps"
   384     "\<Lambda> s t P (h: _) ps. subst \<cdot> s \<cdot> t \<cdot> P ps \<bullet> h"
   385 
   386   subst: "Null" "subst"
   387 
   388   iffD1 (P, Q): "fst"
   389     "\<Lambda> Q P pq (h: _) p.
   390        mp \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> p \<bullet> (conjunct1 \<cdot> _ \<cdot> _ \<bullet> h))"
   391 
   392   iffD1 (P): "\<lambda>p. p"
   393     "\<Lambda> Q P p (h: _). mp \<cdot> _ \<cdot> _ \<bullet> (conjunct1 \<cdot> _ \<cdot> _ \<bullet> h)"
   394 
   395   iffD1 (Q): "Null"
   396     "\<Lambda> Q P q1 (h: _) q2.
   397        mp \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> q2 \<bullet> (conjunct1 \<cdot> _ \<cdot> _ \<bullet> h))"
   398 
   399   iffD1: "Null" "iffD1"
   400 
   401   iffD2 (P, Q): "snd"
   402     "\<Lambda> P Q pq (h: _) q.
   403        mp \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> q \<bullet> (conjunct2 \<cdot> _ \<cdot> _ \<bullet> h))"
   404 
   405   iffD2 (P): "\<lambda>p. p"
   406     "\<Lambda> P Q p (h: _). mp \<cdot> _ \<cdot> _ \<bullet> (conjunct2 \<cdot> _ \<cdot> _ \<bullet> h)"
   407 
   408   iffD2 (Q): "Null"
   409     "\<Lambda> P Q q1 (h: _) q2.
   410        mp \<cdot> _ \<cdot> _ \<bullet> (spec \<cdot> _ \<cdot> q2 \<bullet> (conjunct2 \<cdot> _ \<cdot> _ \<bullet> h))"
   411 
   412   iffD2: "Null" "iffD2"
   413 
   414   iffI (P, Q): "Pair"
   415     "\<Lambda> P Q pq (h1 : _) qp (h2 : _). conjI_realizer \<cdot>
   416        (\<lambda>pq. \<forall>x. P x \<longrightarrow> Q (pq x)) \<cdot> pq \<cdot>
   417        (\<lambda>qp. \<forall>x. Q x \<longrightarrow> P (qp x)) \<cdot> qp \<bullet>
   418        (allI \<cdot> _ \<bullet> (\<Lambda> x. impI \<cdot> _ \<cdot> _ \<bullet> (h1 \<cdot> x))) \<bullet>
   419        (allI \<cdot> _ \<bullet> (\<Lambda> x. impI \<cdot> _ \<cdot> _ \<bullet> (h2 \<cdot> x)))"
   420 
   421   iffI (P): "\<lambda>p. p"
   422     "\<Lambda> P Q (h1 : _) p (h2 : _). conjI \<cdot> _ \<cdot> _ \<bullet>
   423        (allI \<cdot> _ \<bullet> (\<Lambda> x. impI \<cdot> _ \<cdot> _ \<bullet> (h1 \<cdot> x))) \<bullet>
   424        (impI \<cdot> _ \<cdot> _ \<bullet> h2)"
   425 
   426   iffI (Q): "\<lambda>q. q"
   427     "\<Lambda> P Q q (h1 : _) (h2 : _). conjI \<cdot> _ \<cdot> _ \<bullet>
   428        (impI \<cdot> _ \<cdot> _ \<bullet> h1) \<bullet>
   429        (allI \<cdot> _ \<bullet> (\<Lambda> x. impI \<cdot> _ \<cdot> _ \<bullet> (h2 \<cdot> x)))"
   430 
   431   iffI: "Null" "iffI"
   432 
   433 (*
   434   classical: "Null"
   435     "\<Lambda> P. classical \<cdot> _"
   436 *)
   437 
   438 setup {*
   439   Sign.add_const_constraint (@{const_name "default"}, SOME @{typ "'a::default"})
   440 *}
   441 
   442 end