src/HOL/RealDef.thy
author huffman
Mon Jan 12 12:09:54 2009 -0800 (2009-01-12)
changeset 29460 ad87e5d1488b
parent 28952 15a4b2cf8c34
child 29667 53103fc8ffa3
permissions -rw-r--r--
new lemmas about synthetic_div; declare degree_pCons_eq_if [simp]
     1 (*  Title       : HOL/RealDef.thy
     2     Author      : Jacques D. Fleuriot
     3     Copyright   : 1998  University of Cambridge
     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     5     Additional contributions by Jeremy Avigad
     6 *)
     7 
     8 header{*Defining the Reals from the Positive Reals*}
     9 
    10 theory RealDef
    11 imports PReal
    12 uses ("Tools/real_arith.ML")
    13 begin
    14 
    15 definition
    16   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    17   [code del]: "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    18 
    19 typedef (Real)  real = "UNIV//realrel"
    20   by (auto simp add: quotient_def)
    21 
    22 definition
    23   (** these don't use the overloaded "real" function: users don't see them **)
    24   real_of_preal :: "preal => real" where
    25   [code del]: "real_of_preal m = Abs_Real (realrel `` {(m + 1, 1)})"
    26 
    27 instantiation real :: "{zero, one, plus, minus, uminus, times, inverse, ord, abs, sgn}"
    28 begin
    29 
    30 definition
    31   real_zero_def [code del]: "0 = Abs_Real(realrel``{(1, 1)})"
    32 
    33 definition
    34   real_one_def [code del]: "1 = Abs_Real(realrel``{(1 + 1, 1)})"
    35 
    36 definition
    37   real_add_def [code del]: "z + w =
    38        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    39                  { Abs_Real(realrel``{(x+u, y+v)}) })"
    40 
    41 definition
    42   real_minus_def [code del]: "- r =  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    43 
    44 definition
    45   real_diff_def [code del]: "r - (s::real) = r + - s"
    46 
    47 definition
    48   real_mult_def [code del]:
    49     "z * w =
    50        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    51                  { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    52 
    53 definition
    54   real_inverse_def [code del]: "inverse (R::real) = (THE S. (R = 0 & S = 0) | S * R = 1)"
    55 
    56 definition
    57   real_divide_def [code del]: "R / (S::real) = R * inverse S"
    58 
    59 definition
    60   real_le_def [code del]: "z \<le> (w::real) \<longleftrightarrow>
    61     (\<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w)"
    62 
    63 definition
    64   real_less_def [code del]: "x < (y\<Colon>real) \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
    65 
    66 definition
    67   real_abs_def:  "abs (r::real) = (if r < 0 then - r else r)"
    68 
    69 definition
    70   real_sgn_def: "sgn (x::real) = (if x=0 then 0 else if 0<x then 1 else - 1)"
    71 
    72 instance ..
    73 
    74 end
    75 
    76 subsection {* Equivalence relation over positive reals *}
    77 
    78 lemma preal_trans_lemma:
    79   assumes "x + y1 = x1 + y"
    80       and "x + y2 = x2 + y"
    81   shows "x1 + y2 = x2 + (y1::preal)"
    82 proof -
    83   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    84   also have "... = (x2 + y) + x1"  by (simp add: prems)
    85   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    86   also have "... = x2 + (x + y1)"  by (simp add: prems)
    87   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    88   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    89   thus ?thesis by (rule add_right_imp_eq)
    90 qed
    91 
    92 
    93 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    94 by (simp add: realrel_def)
    95 
    96 lemma equiv_realrel: "equiv UNIV realrel"
    97 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
    98 apply (blast dest: preal_trans_lemma) 
    99 done
   100 
   101 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   102   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   103 lemmas equiv_realrel_iff = 
   104        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   105 
   106 declare equiv_realrel_iff [simp]
   107 
   108 
   109 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   110 by (simp add: Real_def realrel_def quotient_def, blast)
   111 
   112 declare Abs_Real_inject [simp]
   113 declare Abs_Real_inverse [simp]
   114 
   115 
   116 text{*Case analysis on the representation of a real number as an equivalence
   117       class of pairs of positive reals.*}
   118 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   119      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   120 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   121 apply (drule arg_cong [where f=Abs_Real])
   122 apply (auto simp add: Rep_Real_inverse)
   123 done
   124 
   125 
   126 subsection {* Addition and Subtraction *}
   127 
   128 lemma real_add_congruent2_lemma:
   129      "[|a + ba = aa + b; ab + bc = ac + bb|]
   130       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   131 apply (simp add: add_assoc)
   132 apply (rule add_left_commute [of ab, THEN ssubst])
   133 apply (simp add: add_assoc [symmetric])
   134 apply (simp add: add_ac)
   135 done
   136 
   137 lemma real_add:
   138      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   139       Abs_Real (realrel``{(x+u, y+v)})"
   140 proof -
   141   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   142         respects2 realrel"
   143     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   144   thus ?thesis
   145     by (simp add: real_add_def UN_UN_split_split_eq
   146                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   147 qed
   148 
   149 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   150 proof -
   151   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   152     by (simp add: congruent_def add_commute) 
   153   thus ?thesis
   154     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   155 qed
   156 
   157 instance real :: ab_group_add
   158 proof
   159   fix x y z :: real
   160   show "(x + y) + z = x + (y + z)"
   161     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   162   show "x + y = y + x"
   163     by (cases x, cases y, simp add: real_add add_commute)
   164   show "0 + x = x"
   165     by (cases x, simp add: real_add real_zero_def add_ac)
   166   show "- x + x = 0"
   167     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   168   show "x - y = x + - y"
   169     by (simp add: real_diff_def)
   170 qed
   171 
   172 
   173 subsection {* Multiplication *}
   174 
   175 lemma real_mult_congruent2_lemma:
   176      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   177           x * x1 + y * y1 + (x * y2 + y * x2) =
   178           x * x2 + y * y2 + (x * y1 + y * x1)"
   179 apply (simp add: add_left_commute add_assoc [symmetric])
   180 apply (simp add: add_assoc right_distrib [symmetric])
   181 apply (simp add: add_commute)
   182 done
   183 
   184 lemma real_mult_congruent2:
   185     "(%p1 p2.
   186         (%(x1,y1). (%(x2,y2). 
   187           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   188      respects2 realrel"
   189 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   190 apply (simp add: mult_commute add_commute)
   191 apply (auto simp add: real_mult_congruent2_lemma)
   192 done
   193 
   194 lemma real_mult:
   195       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   196        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   197 by (simp add: real_mult_def UN_UN_split_split_eq
   198          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   199 
   200 lemma real_mult_commute: "(z::real) * w = w * z"
   201 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   202 
   203 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   204 apply (cases z1, cases z2, cases z3)
   205 apply (simp add: real_mult right_distrib add_ac mult_ac)
   206 done
   207 
   208 lemma real_mult_1: "(1::real) * z = z"
   209 apply (cases z)
   210 apply (simp add: real_mult real_one_def right_distrib
   211                   mult_1_right mult_ac add_ac)
   212 done
   213 
   214 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   215 apply (cases z1, cases z2, cases w)
   216 apply (simp add: real_add real_mult right_distrib add_ac mult_ac)
   217 done
   218 
   219 text{*one and zero are distinct*}
   220 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   221 proof -
   222   have "(1::preal) < 1 + 1"
   223     by (simp add: preal_self_less_add_left)
   224   thus ?thesis
   225     by (simp add: real_zero_def real_one_def)
   226 qed
   227 
   228 instance real :: comm_ring_1
   229 proof
   230   fix x y z :: real
   231   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   232   show "x * y = y * x" by (rule real_mult_commute)
   233   show "1 * x = x" by (rule real_mult_1)
   234   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   235   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   236 qed
   237 
   238 subsection {* Inverse and Division *}
   239 
   240 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   241 by (simp add: real_zero_def add_commute)
   242 
   243 text{*Instead of using an existential quantifier and constructing the inverse
   244 within the proof, we could define the inverse explicitly.*}
   245 
   246 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   247 apply (simp add: real_zero_def real_one_def, cases x)
   248 apply (cut_tac x = xa and y = y in linorder_less_linear)
   249 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   250 apply (rule_tac
   251         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   252        in exI)
   253 apply (rule_tac [2]
   254         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   255        in exI)
   256 apply (auto simp add: real_mult preal_mult_inverse_right ring_simps)
   257 done
   258 
   259 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   260 apply (simp add: real_inverse_def)
   261 apply (drule real_mult_inverse_left_ex, safe)
   262 apply (rule theI, assumption, rename_tac z)
   263 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   264 apply (simp add: mult_commute)
   265 apply (rule mult_assoc)
   266 done
   267 
   268 
   269 subsection{*The Real Numbers form a Field*}
   270 
   271 instance real :: field
   272 proof
   273   fix x y z :: real
   274   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   275   show "x / y = x * inverse y" by (simp add: real_divide_def)
   276 qed
   277 
   278 
   279 text{*Inverse of zero!  Useful to simplify certain equations*}
   280 
   281 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   282 by (simp add: real_inverse_def)
   283 
   284 instance real :: division_by_zero
   285 proof
   286   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   287 qed
   288 
   289 
   290 subsection{*The @{text "\<le>"} Ordering*}
   291 
   292 lemma real_le_refl: "w \<le> (w::real)"
   293 by (cases w, force simp add: real_le_def)
   294 
   295 text{*The arithmetic decision procedure is not set up for type preal.
   296   This lemma is currently unused, but it could simplify the proofs of the
   297   following two lemmas.*}
   298 lemma preal_eq_le_imp_le:
   299   assumes eq: "a+b = c+d" and le: "c \<le> a"
   300   shows "b \<le> (d::preal)"
   301 proof -
   302   have "c+d \<le> a+d" by (simp add: prems)
   303   hence "a+b \<le> a+d" by (simp add: prems)
   304   thus "b \<le> d" by simp
   305 qed
   306 
   307 lemma real_le_lemma:
   308   assumes l: "u1 + v2 \<le> u2 + v1"
   309       and "x1 + v1 = u1 + y1"
   310       and "x2 + v2 = u2 + y2"
   311   shows "x1 + y2 \<le> x2 + (y1::preal)"
   312 proof -
   313   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   314   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   315   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   316   finally show ?thesis by simp
   317 qed
   318 
   319 lemma real_le: 
   320      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   321       (x1 + y2 \<le> x2 + y1)"
   322 apply (simp add: real_le_def)
   323 apply (auto intro: real_le_lemma)
   324 done
   325 
   326 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   327 by (cases z, cases w, simp add: real_le)
   328 
   329 lemma real_trans_lemma:
   330   assumes "x + v \<le> u + y"
   331       and "u + v' \<le> u' + v"
   332       and "x2 + v2 = u2 + y2"
   333   shows "x + v' \<le> u' + (y::preal)"
   334 proof -
   335   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   336   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   337   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   338   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   339   finally show ?thesis by simp
   340 qed
   341 
   342 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   343 apply (cases i, cases j, cases k)
   344 apply (simp add: real_le)
   345 apply (blast intro: real_trans_lemma)
   346 done
   347 
   348 instance real :: order
   349 proof
   350   fix u v :: real
   351   show "u < v \<longleftrightarrow> u \<le> v \<and> \<not> v \<le> u" 
   352     by (auto simp add: real_less_def intro: real_le_anti_sym)
   353 qed (assumption | rule real_le_refl real_le_trans real_le_anti_sym)+
   354 
   355 (* Axiom 'linorder_linear' of class 'linorder': *)
   356 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   357 apply (cases z, cases w)
   358 apply (auto simp add: real_le real_zero_def add_ac)
   359 done
   360 
   361 instance real :: linorder
   362   by (intro_classes, rule real_le_linear)
   363 
   364 
   365 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   366 apply (cases x, cases y) 
   367 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   368                       add_ac)
   369 apply (simp_all add: add_assoc [symmetric])
   370 done
   371 
   372 lemma real_add_left_mono: 
   373   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   374 proof -
   375   have "z + x - (z + y) = (z + -z) + (x - y)" 
   376     by (simp add: diff_minus add_ac) 
   377   with le show ?thesis 
   378     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   379 qed
   380 
   381 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   382 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   383 
   384 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   385 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   386 
   387 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   388 apply (cases x, cases y)
   389 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   390                  linorder_not_le [where 'a = preal] 
   391                   real_zero_def real_le real_mult)
   392   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   393 apply (auto dest!: less_add_left_Ex
   394      simp add: add_ac mult_ac
   395           right_distrib preal_self_less_add_left)
   396 done
   397 
   398 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   399 apply (rule real_sum_gt_zero_less)
   400 apply (drule real_less_sum_gt_zero [of x y])
   401 apply (drule real_mult_order, assumption)
   402 apply (simp add: right_distrib)
   403 done
   404 
   405 instantiation real :: distrib_lattice
   406 begin
   407 
   408 definition
   409   "(inf \<Colon> real \<Rightarrow> real \<Rightarrow> real) = min"
   410 
   411 definition
   412   "(sup \<Colon> real \<Rightarrow> real \<Rightarrow> real) = max"
   413 
   414 instance
   415   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   416 
   417 end
   418 
   419 
   420 subsection{*The Reals Form an Ordered Field*}
   421 
   422 instance real :: ordered_field
   423 proof
   424   fix x y z :: real
   425   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   426   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   427   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   428   show "sgn x = (if x=0 then 0 else if 0<x then 1 else - 1)"
   429     by (simp only: real_sgn_def)
   430 qed
   431 
   432 instance real :: lordered_ab_group_add ..
   433 
   434 text{*The function @{term real_of_preal} requires many proofs, but it seems
   435 to be essential for proving completeness of the reals from that of the
   436 positive reals.*}
   437 
   438 lemma real_of_preal_add:
   439      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   440 by (simp add: real_of_preal_def real_add left_distrib add_ac)
   441 
   442 lemma real_of_preal_mult:
   443      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   444 by (simp add: real_of_preal_def real_mult right_distrib add_ac mult_ac)
   445 
   446 
   447 text{*Gleason prop 9-4.4 p 127*}
   448 lemma real_of_preal_trichotomy:
   449       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   450 apply (simp add: real_of_preal_def real_zero_def, cases x)
   451 apply (auto simp add: real_minus add_ac)
   452 apply (cut_tac x = x and y = y in linorder_less_linear)
   453 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   454 done
   455 
   456 lemma real_of_preal_leD:
   457       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   458 by (simp add: real_of_preal_def real_le)
   459 
   460 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   461 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   462 
   463 lemma real_of_preal_lessD:
   464       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   465 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   466 
   467 lemma real_of_preal_less_iff [simp]:
   468      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   469 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   470 
   471 lemma real_of_preal_le_iff:
   472      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   473 by (simp add: linorder_not_less [symmetric])
   474 
   475 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   476 apply (insert preal_self_less_add_left [of 1 m])
   477 apply (auto simp add: real_zero_def real_of_preal_def
   478                       real_less_def real_le_def add_ac)
   479 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   480 apply (simp add: add_ac)
   481 done
   482 
   483 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   484 by (simp add: real_of_preal_zero_less)
   485 
   486 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   487 proof -
   488   from real_of_preal_minus_less_zero
   489   show ?thesis by (blast dest: order_less_trans)
   490 qed
   491 
   492 
   493 subsection{*Theorems About the Ordering*}
   494 
   495 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   496 apply (auto simp add: real_of_preal_zero_less)
   497 apply (cut_tac x = x in real_of_preal_trichotomy)
   498 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   499 done
   500 
   501 lemma real_gt_preal_preal_Ex:
   502      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   503 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   504              intro: real_gt_zero_preal_Ex [THEN iffD1])
   505 
   506 lemma real_ge_preal_preal_Ex:
   507      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   508 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   509 
   510 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   511 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   512             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   513             simp add: real_of_preal_zero_less)
   514 
   515 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   516 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   517 
   518 
   519 subsection{*More Lemmas*}
   520 
   521 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   522 by auto
   523 
   524 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   525 by auto
   526 
   527 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   528   by (force elim: order_less_asym
   529             simp add: Ring_and_Field.mult_less_cancel_right)
   530 
   531 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   532 apply (simp add: mult_le_cancel_right)
   533 apply (blast intro: elim: order_less_asym)
   534 done
   535 
   536 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   537 by(simp add:mult_commute)
   538 
   539 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   540 by (simp add: one_less_inverse_iff) (* TODO: generalize/move *)
   541 
   542 
   543 subsection {* Embedding numbers into the Reals *}
   544 
   545 abbreviation
   546   real_of_nat :: "nat \<Rightarrow> real"
   547 where
   548   "real_of_nat \<equiv> of_nat"
   549 
   550 abbreviation
   551   real_of_int :: "int \<Rightarrow> real"
   552 where
   553   "real_of_int \<equiv> of_int"
   554 
   555 abbreviation
   556   real_of_rat :: "rat \<Rightarrow> real"
   557 where
   558   "real_of_rat \<equiv> of_rat"
   559 
   560 consts
   561   (*overloaded constant for injecting other types into "real"*)
   562   real :: "'a => real"
   563 
   564 defs (overloaded)
   565   real_of_nat_def [code unfold]: "real == real_of_nat"
   566   real_of_int_def [code unfold]: "real == real_of_int"
   567 
   568 lemma real_eq_of_nat: "real = of_nat"
   569   unfolding real_of_nat_def ..
   570 
   571 lemma real_eq_of_int: "real = of_int"
   572   unfolding real_of_int_def ..
   573 
   574 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   575 by (simp add: real_of_int_def) 
   576 
   577 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   578 by (simp add: real_of_int_def) 
   579 
   580 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   581 by (simp add: real_of_int_def) 
   582 
   583 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   584 by (simp add: real_of_int_def) 
   585 
   586 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   587 by (simp add: real_of_int_def) 
   588 
   589 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   590 by (simp add: real_of_int_def) 
   591 
   592 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   593   apply (subst real_eq_of_int)+
   594   apply (rule of_int_setsum)
   595 done
   596 
   597 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   598     (PROD x:A. real(f x))"
   599   apply (subst real_eq_of_int)+
   600   apply (rule of_int_setprod)
   601 done
   602 
   603 lemma real_of_int_zero_cancel [simp, algebra, presburger]: "(real x = 0) = (x = (0::int))"
   604 by (simp add: real_of_int_def) 
   605 
   606 lemma real_of_int_inject [iff, algebra, presburger]: "(real (x::int) = real y) = (x = y)"
   607 by (simp add: real_of_int_def) 
   608 
   609 lemma real_of_int_less_iff [iff, presburger]: "(real (x::int) < real y) = (x < y)"
   610 by (simp add: real_of_int_def) 
   611 
   612 lemma real_of_int_le_iff [simp, presburger]: "(real (x::int) \<le> real y) = (x \<le> y)"
   613 by (simp add: real_of_int_def) 
   614 
   615 lemma real_of_int_gt_zero_cancel_iff [simp, presburger]: "(0 < real (n::int)) = (0 < n)"
   616 by (simp add: real_of_int_def) 
   617 
   618 lemma real_of_int_ge_zero_cancel_iff [simp, presburger]: "(0 <= real (n::int)) = (0 <= n)"
   619 by (simp add: real_of_int_def) 
   620 
   621 lemma real_of_int_lt_zero_cancel_iff [simp, presburger]: "(real (n::int) < 0) = (n < 0)" 
   622 by (simp add: real_of_int_def)
   623 
   624 lemma real_of_int_le_zero_cancel_iff [simp, presburger]: "(real (n::int) <= 0) = (n <= 0)"
   625 by (simp add: real_of_int_def)
   626 
   627 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   628 by (auto simp add: abs_if)
   629 
   630 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   631   apply (subgoal_tac "real n + 1 = real (n + 1)")
   632   apply (simp del: real_of_int_add)
   633   apply auto
   634 done
   635 
   636 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   637   apply (subgoal_tac "real m + 1 = real (m + 1)")
   638   apply (simp del: real_of_int_add)
   639   apply simp
   640 done
   641 
   642 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   643     real (x div d) + (real (x mod d)) / (real d)"
   644 proof -
   645   assume "d ~= 0"
   646   have "x = (x div d) * d + x mod d"
   647     by auto
   648   then have "real x = real (x div d) * real d + real(x mod d)"
   649     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   650   then have "real x / real d = ... / real d"
   651     by simp
   652   then show ?thesis
   653     by (auto simp add: add_divide_distrib ring_simps prems)
   654 qed
   655 
   656 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   657     real(n div d) = real n / real d"
   658   apply (frule real_of_int_div_aux [of d n])
   659   apply simp
   660   apply (simp add: zdvd_iff_zmod_eq_0)
   661 done
   662 
   663 lemma real_of_int_div2:
   664   "0 <= real (n::int) / real (x) - real (n div x)"
   665   apply (case_tac "x = 0")
   666   apply simp
   667   apply (case_tac "0 < x")
   668   apply (simp add: compare_rls)
   669   apply (subst real_of_int_div_aux)
   670   apply simp
   671   apply simp
   672   apply (subst zero_le_divide_iff)
   673   apply auto
   674   apply (simp add: compare_rls)
   675   apply (subst real_of_int_div_aux)
   676   apply simp
   677   apply simp
   678   apply (subst zero_le_divide_iff)
   679   apply auto
   680 done
   681 
   682 lemma real_of_int_div3:
   683   "real (n::int) / real (x) - real (n div x) <= 1"
   684   apply(case_tac "x = 0")
   685   apply simp
   686   apply (simp add: compare_rls)
   687   apply (subst real_of_int_div_aux)
   688   apply assumption
   689   apply simp
   690   apply (subst divide_le_eq)
   691   apply clarsimp
   692   apply (rule conjI)
   693   apply (rule impI)
   694   apply (rule order_less_imp_le)
   695   apply simp
   696   apply (rule impI)
   697   apply (rule order_less_imp_le)
   698   apply simp
   699 done
   700 
   701 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   702 by (insert real_of_int_div2 [of n x], simp)
   703 
   704 
   705 subsection{*Embedding the Naturals into the Reals*}
   706 
   707 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   708 by (simp add: real_of_nat_def)
   709 
   710 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   711 by (simp add: real_of_nat_def)
   712 
   713 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   714 by (simp add: real_of_nat_def)
   715 
   716 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   717 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   718 by (simp add: real_of_nat_def)
   719 
   720 lemma real_of_nat_less_iff [iff]: 
   721      "(real (n::nat) < real m) = (n < m)"
   722 by (simp add: real_of_nat_def)
   723 
   724 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   725 by (simp add: real_of_nat_def)
   726 
   727 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   728 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   729 
   730 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   731 by (simp add: real_of_nat_def del: of_nat_Suc)
   732 
   733 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   734 by (simp add: real_of_nat_def of_nat_mult)
   735 
   736 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   737     (SUM x:A. real(f x))"
   738   apply (subst real_eq_of_nat)+
   739   apply (rule of_nat_setsum)
   740 done
   741 
   742 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   743     (PROD x:A. real(f x))"
   744   apply (subst real_eq_of_nat)+
   745   apply (rule of_nat_setprod)
   746 done
   747 
   748 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   749   apply (subst card_eq_setsum)
   750   apply (subst real_of_nat_setsum)
   751   apply simp
   752 done
   753 
   754 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   755 by (simp add: real_of_nat_def)
   756 
   757 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   758 by (simp add: real_of_nat_def)
   759 
   760 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   761 by (simp add: add: real_of_nat_def of_nat_diff)
   762 
   763 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   764 by (auto simp: real_of_nat_def)
   765 
   766 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   767 by (simp add: add: real_of_nat_def)
   768 
   769 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   770 by (simp add: add: real_of_nat_def)
   771 
   772 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat))"
   773 by (simp add: add: real_of_nat_def)
   774 
   775 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   776   apply (subgoal_tac "real n + 1 = real (Suc n)")
   777   apply simp
   778   apply (auto simp add: real_of_nat_Suc)
   779 done
   780 
   781 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   782   apply (subgoal_tac "real m + 1 = real (Suc m)")
   783   apply (simp add: less_Suc_eq_le)
   784   apply (simp add: real_of_nat_Suc)
   785 done
   786 
   787 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   788     real (x div d) + (real (x mod d)) / (real d)"
   789 proof -
   790   assume "0 < d"
   791   have "x = (x div d) * d + x mod d"
   792     by auto
   793   then have "real x = real (x div d) * real d + real(x mod d)"
   794     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   795   then have "real x / real d = \<dots> / real d"
   796     by simp
   797   then show ?thesis
   798     by (auto simp add: add_divide_distrib ring_simps prems)
   799 qed
   800 
   801 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   802     real(n div d) = real n / real d"
   803   apply (frule real_of_nat_div_aux [of d n])
   804   apply simp
   805   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   806   apply assumption
   807 done
   808 
   809 lemma real_of_nat_div2:
   810   "0 <= real (n::nat) / real (x) - real (n div x)"
   811 apply(case_tac "x = 0")
   812  apply (simp)
   813 apply (simp add: compare_rls)
   814 apply (subst real_of_nat_div_aux)
   815  apply simp
   816 apply simp
   817 apply (subst zero_le_divide_iff)
   818 apply simp
   819 done
   820 
   821 lemma real_of_nat_div3:
   822   "real (n::nat) / real (x) - real (n div x) <= 1"
   823 apply(case_tac "x = 0")
   824 apply (simp)
   825 apply (simp add: compare_rls)
   826 apply (subst real_of_nat_div_aux)
   827  apply simp
   828 apply simp
   829 done
   830 
   831 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   832   by (insert real_of_nat_div2 [of n x], simp)
   833 
   834 lemma real_of_int_real_of_nat: "real (int n) = real n"
   835 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   836 
   837 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   838 by (simp add: real_of_int_def real_of_nat_def)
   839 
   840 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   841   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   842   apply force
   843   apply (simp only: real_of_int_real_of_nat)
   844 done
   845 
   846 
   847 subsection{* Rationals *}
   848 
   849 lemma Rats_real_nat[simp]: "real(n::nat) \<in> \<rat>"
   850 by (simp add: real_eq_of_nat)
   851 
   852 
   853 lemma Rats_eq_int_div_int:
   854   "\<rat> = { real(i::int)/real(j::int) |i j. j \<noteq> 0}" (is "_ = ?S")
   855 proof
   856   show "\<rat> \<subseteq> ?S"
   857   proof
   858     fix x::real assume "x : \<rat>"
   859     then obtain r where "x = of_rat r" unfolding Rats_def ..
   860     have "of_rat r : ?S"
   861       by (cases r)(auto simp add:of_rat_rat real_eq_of_int)
   862     thus "x : ?S" using `x = of_rat r` by simp
   863   qed
   864 next
   865   show "?S \<subseteq> \<rat>"
   866   proof(auto simp:Rats_def)
   867     fix i j :: int assume "j \<noteq> 0"
   868     hence "real i / real j = of_rat(Fract i j)"
   869       by (simp add:of_rat_rat real_eq_of_int)
   870     thus "real i / real j \<in> range of_rat" by blast
   871   qed
   872 qed
   873 
   874 lemma Rats_eq_int_div_nat:
   875   "\<rat> = { real(i::int)/real(n::nat) |i n. n \<noteq> 0}"
   876 proof(auto simp:Rats_eq_int_div_int)
   877   fix i j::int assume "j \<noteq> 0"
   878   show "EX (i'::int) (n::nat). real i/real j = real i'/real n \<and> 0<n"
   879   proof cases
   880     assume "j>0"
   881     hence "real i/real j = real i/real(nat j) \<and> 0<nat j"
   882       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
   883     thus ?thesis by blast
   884   next
   885     assume "~ j>0"
   886     hence "real i/real j = real(-i)/real(nat(-j)) \<and> 0<nat(-j)" using `j\<noteq>0`
   887       by (simp add: real_eq_of_int real_eq_of_nat of_nat_nat)
   888     thus ?thesis by blast
   889   qed
   890 next
   891   fix i::int and n::nat assume "0 < n"
   892   hence "real i/real n = real i/real(int n) \<and> int n \<noteq> 0" by simp
   893   thus "\<exists>(i'::int) j::int. real i/real n = real i'/real j \<and> j \<noteq> 0" by blast
   894 qed
   895 
   896 lemma Rats_abs_nat_div_natE:
   897   assumes "x \<in> \<rat>"
   898   obtains m n where "n \<noteq> 0" and "\<bar>x\<bar> = real m / real n" and "gcd m n = 1"
   899 proof -
   900   from `x \<in> \<rat>` obtain i::int and n::nat where "n \<noteq> 0" and "x = real i / real n"
   901     by(auto simp add: Rats_eq_int_div_nat)
   902   hence "\<bar>x\<bar> = real(nat(abs i)) / real n" by simp
   903   then obtain m :: nat where x_rat: "\<bar>x\<bar> = real m / real n" by blast
   904   let ?gcd = "gcd m n"
   905   from `n\<noteq>0` have gcd: "?gcd \<noteq> 0" by (simp add: gcd_zero)
   906   let ?k = "m div ?gcd"
   907   let ?l = "n div ?gcd"
   908   let ?gcd' = "gcd ?k ?l"
   909   have "?gcd dvd m" .. then have gcd_k: "?gcd * ?k = m"
   910     by (rule dvd_mult_div_cancel)
   911   have "?gcd dvd n" .. then have gcd_l: "?gcd * ?l = n"
   912     by (rule dvd_mult_div_cancel)
   913   from `n\<noteq>0` and gcd_l have "?l \<noteq> 0" by (auto iff del: neq0_conv)
   914   moreover
   915   have "\<bar>x\<bar> = real ?k / real ?l"
   916   proof -
   917     from gcd have "real ?k / real ?l =
   918         real (?gcd * ?k) / real (?gcd * ?l)" by simp
   919     also from gcd_k and gcd_l have "\<dots> = real m / real n" by simp
   920     also from x_rat have "\<dots> = \<bar>x\<bar>" ..
   921     finally show ?thesis ..
   922   qed
   923   moreover
   924   have "?gcd' = 1"
   925   proof -
   926     have "?gcd * ?gcd' = gcd (?gcd * ?k) (?gcd * ?l)"
   927       by (rule gcd_mult_distrib2)
   928     with gcd_k gcd_l have "?gcd * ?gcd' = ?gcd" by simp
   929     with gcd show ?thesis by simp
   930   qed
   931   ultimately show ?thesis ..
   932 qed
   933 
   934 
   935 subsection{*Numerals and Arithmetic*}
   936 
   937 instantiation real :: number_ring
   938 begin
   939 
   940 definition
   941   real_number_of_def [code del]: "number_of w = real_of_int w"
   942 
   943 instance
   944   by intro_classes (simp add: real_number_of_def)
   945 
   946 end
   947 
   948 lemma [code unfold, symmetric, code post]:
   949   "number_of k = real_of_int (number_of k)"
   950   unfolding number_of_is_id real_number_of_def ..
   951 
   952 
   953 text{*Collapse applications of @{term real} to @{term number_of}*}
   954 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   955 by (simp add:  real_of_int_def of_int_number_of_eq)
   956 
   957 lemma real_of_nat_number_of [simp]:
   958      "real (number_of v :: nat) =  
   959         (if neg (number_of v :: int) then 0  
   960          else (number_of v :: real))"
   961 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   962  
   963 
   964 use "Tools/real_arith.ML"
   965 declaration {* K real_arith_setup *}
   966 
   967 
   968 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   969 
   970 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   971 lemma real_0_le_divide_iff:
   972      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   973 by (simp add: real_divide_def zero_le_mult_iff, auto)
   974 
   975 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   976 by arith
   977 
   978 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   979 by auto
   980 
   981 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   982 by auto
   983 
   984 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   985 by auto
   986 
   987 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   988 by auto
   989 
   990 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   991 by auto
   992 
   993 
   994 (*
   995 FIXME: we should have this, as for type int, but many proofs would break.
   996 It replaces x+-y by x-y.
   997 declare real_diff_def [symmetric, simp]
   998 *)
   999 
  1000 subsubsection{*Density of the Reals*}
  1001 
  1002 lemma real_lbound_gt_zero:
  1003      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
  1004 apply (rule_tac x = " (min d1 d2) /2" in exI)
  1005 apply (simp add: min_def)
  1006 done
  1007 
  1008 
  1009 text{*Similar results are proved in @{text Ring_and_Field}*}
  1010 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
  1011   by auto
  1012 
  1013 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
  1014   by auto
  1015 
  1016 
  1017 subsection{*Absolute Value Function for the Reals*}
  1018 
  1019 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
  1020 by (simp add: abs_if)
  1021 
  1022 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
  1023 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
  1024 by (force simp add: OrderedGroup.abs_le_iff)
  1025 
  1026 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
  1027 by (simp add: abs_if)
  1028 
  1029 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
  1030 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
  1031 
  1032 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
  1033 by simp
  1034  
  1035 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
  1036 by simp
  1037 
  1038 instance real :: lordered_ring
  1039 proof
  1040   fix a::real
  1041   show "abs a = sup a (-a)"
  1042     by (auto simp add: real_abs_def sup_real_def)
  1043 qed
  1044 
  1045 
  1046 subsection {* Implementation of rational real numbers *}
  1047 
  1048 definition Ratreal :: "rat \<Rightarrow> real" where
  1049   [simp]: "Ratreal = of_rat"
  1050 
  1051 code_datatype Ratreal
  1052 
  1053 lemma Ratreal_number_collapse [code post]:
  1054   "Ratreal 0 = 0"
  1055   "Ratreal 1 = 1"
  1056   "Ratreal (number_of k) = number_of k"
  1057 by simp_all
  1058 
  1059 lemma zero_real_code [code, code unfold]:
  1060   "0 = Ratreal 0"
  1061 by simp
  1062 
  1063 lemma one_real_code [code, code unfold]:
  1064   "1 = Ratreal 1"
  1065 by simp
  1066 
  1067 lemma number_of_real_code [code unfold]:
  1068   "number_of k = Ratreal (number_of k)"
  1069 by simp
  1070 
  1071 lemma Ratreal_number_of_quotient [code post]:
  1072   "Ratreal (number_of r) / Ratreal (number_of s) = number_of r / number_of s"
  1073 by simp
  1074 
  1075 lemma Ratreal_number_of_quotient2 [code post]:
  1076   "Ratreal (number_of r / number_of s) = number_of r / number_of s"
  1077 unfolding Ratreal_number_of_quotient [symmetric] Ratreal_def of_rat_divide ..
  1078 
  1079 instantiation real :: eq
  1080 begin
  1081 
  1082 definition "eq_class.eq (x\<Colon>real) y \<longleftrightarrow> x - y = 0"
  1083 
  1084 instance by default (simp add: eq_real_def)
  1085 
  1086 lemma real_eq_code [code]: "eq_class.eq (Ratreal x) (Ratreal y) \<longleftrightarrow> eq_class.eq x y"
  1087   by (simp add: eq_real_def eq)
  1088 
  1089 lemma real_eq_refl [code nbe]:
  1090   "eq_class.eq (x::real) x \<longleftrightarrow> True"
  1091   by (rule HOL.eq_refl)
  1092 
  1093 end
  1094 
  1095 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> x \<le> y"
  1096   by (simp add: of_rat_less_eq)
  1097 
  1098 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> x < y"
  1099   by (simp add: of_rat_less)
  1100 
  1101 lemma real_plus_code [code]: "Ratreal x + Ratreal y = Ratreal (x + y)"
  1102   by (simp add: of_rat_add)
  1103 
  1104 lemma real_times_code [code]: "Ratreal x * Ratreal y = Ratreal (x * y)"
  1105   by (simp add: of_rat_mult)
  1106 
  1107 lemma real_uminus_code [code]: "- Ratreal x = Ratreal (- x)"
  1108   by (simp add: of_rat_minus)
  1109 
  1110 lemma real_minus_code [code]: "Ratreal x - Ratreal y = Ratreal (x - y)"
  1111   by (simp add: of_rat_diff)
  1112 
  1113 lemma real_inverse_code [code]: "inverse (Ratreal x) = Ratreal (inverse x)"
  1114   by (simp add: of_rat_inverse)
  1115  
  1116 lemma real_divide_code [code]: "Ratreal x / Ratreal y = Ratreal (x / y)"
  1117   by (simp add: of_rat_divide)
  1118 
  1119 text {* Setup for SML code generator *}
  1120 
  1121 types_code
  1122   real ("(int */ int)")
  1123 attach (term_of) {*
  1124 fun term_of_real (p, q) =
  1125   let
  1126     val rT = HOLogic.realT
  1127   in
  1128     if q = 1 orelse p = 0 then HOLogic.mk_number rT p
  1129     else @{term "op / \<Colon> real \<Rightarrow> real \<Rightarrow> real"} $
  1130       HOLogic.mk_number rT p $ HOLogic.mk_number rT q
  1131   end;
  1132 *}
  1133 attach (test) {*
  1134 fun gen_real i =
  1135   let
  1136     val p = random_range 0 i;
  1137     val q = random_range 1 (i + 1);
  1138     val g = Integer.gcd p q;
  1139     val p' = p div g;
  1140     val q' = q div g;
  1141     val r = (if one_of [true, false] then p' else ~ p',
  1142       if p' = 0 then 0 else q')
  1143   in
  1144     (r, fn () => term_of_real r)
  1145   end;
  1146 *}
  1147 
  1148 consts_code
  1149   Ratreal ("(_)")
  1150 
  1151 consts_code
  1152   "of_int :: int \<Rightarrow> real" ("\<module>real'_of'_int")
  1153 attach {*
  1154 fun real_of_int 0 = (0, 0)
  1155   | real_of_int i = (i, 1);
  1156 *}
  1157 
  1158 end