src/HOL/Fun.thy
author haftmann
Tue Feb 26 20:38:12 2008 +0100 (2008-02-26)
changeset 26147 ae2bf929e33c
parent 26105 ae06618225ec
child 26342 0f65fa163304
permissions -rw-r--r--
moved some set lemmas to Set.thy
     1 (*  Title:      HOL/Fun.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     4     Copyright   1994  University of Cambridge
     5 *)
     6 
     7 header {* Notions about functions *}
     8 
     9 theory Fun
    10 imports Set
    11 begin
    12 
    13 text{*As a simplification rule, it replaces all function equalities by
    14   first-order equalities.*}
    15 lemma expand_fun_eq: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    16 apply (rule iffI)
    17 apply (simp (no_asm_simp))
    18 apply (rule ext)
    19 apply (simp (no_asm_simp))
    20 done
    21 
    22 lemma apply_inverse:
    23   "f x =u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    24   by auto
    25 
    26 
    27 subsection {* The Identity Function @{text id} *}
    28 
    29 definition
    30   id :: "'a \<Rightarrow> 'a"
    31 where
    32   "id = (\<lambda>x. x)"
    33 
    34 lemma id_apply [simp]: "id x = x"
    35   by (simp add: id_def)
    36 
    37 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    38 by blast
    39 
    40 lemma image_id [simp]: "id ` Y = Y"
    41 by (simp add: id_def)
    42 
    43 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    44 by blast
    45 
    46 lemma vimage_id [simp]: "id -` A = A"
    47 by (simp add: id_def)
    48 
    49 
    50 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    51 
    52 definition
    53   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    54 where
    55   "f o g = (\<lambda>x. f (g x))"
    56 
    57 notation (xsymbols)
    58   comp  (infixl "\<circ>" 55)
    59 
    60 notation (HTML output)
    61   comp  (infixl "\<circ>" 55)
    62 
    63 text{*compatibility*}
    64 lemmas o_def = comp_def
    65 
    66 lemma o_apply [simp]: "(f o g) x = f (g x)"
    67 by (simp add: comp_def)
    68 
    69 lemma o_assoc: "f o (g o h) = f o g o h"
    70 by (simp add: comp_def)
    71 
    72 lemma id_o [simp]: "id o g = g"
    73 by (simp add: comp_def)
    74 
    75 lemma o_id [simp]: "f o id = f"
    76 by (simp add: comp_def)
    77 
    78 lemma image_compose: "(f o g) ` r = f`(g`r)"
    79 by (simp add: comp_def, blast)
    80 
    81 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    82 by (unfold comp_def, blast)
    83 
    84 
    85 subsection {* Injectivity and Surjectivity *}
    86 
    87 constdefs
    88   inj_on :: "['a => 'b, 'a set] => bool"  -- "injective"
    89   "inj_on f A == ! x:A. ! y:A. f(x)=f(y) --> x=y"
    90 
    91 text{*A common special case: functions injective over the entire domain type.*}
    92 
    93 abbreviation
    94   "inj f == inj_on f UNIV"
    95 
    96 definition
    97   bij_betw :: "('a => 'b) => 'a set => 'b set => bool" where -- "bijective"
    98   "bij_betw f A B \<longleftrightarrow> inj_on f A & f ` A = B"
    99 
   100 constdefs
   101   surj :: "('a => 'b) => bool"                   (*surjective*)
   102   "surj f == ! y. ? x. y=f(x)"
   103 
   104   bij :: "('a => 'b) => bool"                    (*bijective*)
   105   "bij f == inj f & surj f"
   106 
   107 lemma injI:
   108   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   109   shows "inj f"
   110   using assms unfolding inj_on_def by auto
   111 
   112 text{*For Proofs in @{text "Tools/datatype_rep_proofs"}*}
   113 lemma datatype_injI:
   114     "(!! x. ALL y. f(x) = f(y) --> x=y) ==> inj(f)"
   115 by (simp add: inj_on_def)
   116 
   117 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   118   by (unfold inj_on_def, blast)
   119 
   120 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   121 by (simp add: inj_on_def)
   122 
   123 (*Useful with the simplifier*)
   124 lemma inj_eq: "inj(f) ==> (f(x) = f(y)) = (x=y)"
   125 by (force simp add: inj_on_def)
   126 
   127 lemma inj_on_id[simp]: "inj_on id A"
   128   by (simp add: inj_on_def) 
   129 
   130 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   131 by (simp add: inj_on_def) 
   132 
   133 lemma surj_id[simp]: "surj id"
   134 by (simp add: surj_def) 
   135 
   136 lemma bij_id[simp]: "bij id"
   137 by (simp add: bij_def inj_on_id surj_id) 
   138 
   139 lemma inj_onI:
   140     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   141 by (simp add: inj_on_def)
   142 
   143 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   144 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   145 
   146 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   147 by (unfold inj_on_def, blast)
   148 
   149 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   150 by (blast dest!: inj_onD)
   151 
   152 lemma comp_inj_on:
   153      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   154 by (simp add: comp_def inj_on_def)
   155 
   156 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   157 apply(simp add:inj_on_def image_def)
   158 apply blast
   159 done
   160 
   161 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   162   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   163 apply(unfold inj_on_def)
   164 apply blast
   165 done
   166 
   167 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   168 by (unfold inj_on_def, blast)
   169 
   170 lemma inj_singleton: "inj (%s. {s})"
   171 by (simp add: inj_on_def)
   172 
   173 lemma inj_on_empty[iff]: "inj_on f {}"
   174 by(simp add: inj_on_def)
   175 
   176 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   177 by (unfold inj_on_def, blast)
   178 
   179 lemma inj_on_Un:
   180  "inj_on f (A Un B) =
   181   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   182 apply(unfold inj_on_def)
   183 apply (blast intro:sym)
   184 done
   185 
   186 lemma inj_on_insert[iff]:
   187   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   188 apply(unfold inj_on_def)
   189 apply (blast intro:sym)
   190 done
   191 
   192 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   193 apply(unfold inj_on_def)
   194 apply (blast)
   195 done
   196 
   197 lemma surjI: "(!! x. g(f x) = x) ==> surj g"
   198 apply (simp add: surj_def)
   199 apply (blast intro: sym)
   200 done
   201 
   202 lemma surj_range: "surj f ==> range f = UNIV"
   203 by (auto simp add: surj_def)
   204 
   205 lemma surjD: "surj f ==> EX x. y = f x"
   206 by (simp add: surj_def)
   207 
   208 lemma surjE: "surj f ==> (!!x. y = f x ==> C) ==> C"
   209 by (simp add: surj_def, blast)
   210 
   211 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   212 apply (simp add: comp_def surj_def, clarify)
   213 apply (drule_tac x = y in spec, clarify)
   214 apply (drule_tac x = x in spec, blast)
   215 done
   216 
   217 lemma bijI: "[| inj f; surj f |] ==> bij f"
   218 by (simp add: bij_def)
   219 
   220 lemma bij_is_inj: "bij f ==> inj f"
   221 by (simp add: bij_def)
   222 
   223 lemma bij_is_surj: "bij f ==> surj f"
   224 by (simp add: bij_def)
   225 
   226 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   227 by (simp add: bij_betw_def)
   228 
   229 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   230 proof -
   231   have i: "inj_on f A" and s: "f ` A = B"
   232     using assms by(auto simp:bij_betw_def)
   233   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   234   { fix a b assume P: "?P b a"
   235     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   236     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   237     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   238   } note g = this
   239   have "inj_on ?g B"
   240   proof(rule inj_onI)
   241     fix x y assume "x:B" "y:B" "?g x = ?g y"
   242     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   243     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   244     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   245   qed
   246   moreover have "?g ` B = A"
   247   proof(auto simp:image_def)
   248     fix b assume "b:B"
   249     with s obtain a where P: "?P b a" unfolding image_def by blast
   250     thus "?g b \<in> A" using g[OF P] by auto
   251   next
   252     fix a assume "a:A"
   253     then obtain b where P: "?P b a" using s unfolding image_def by blast
   254     then have "b:B" using s unfolding image_def by blast
   255     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   256   qed
   257   ultimately show ?thesis by(auto simp:bij_betw_def)
   258 qed
   259 
   260 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   261 by (simp add: surj_range)
   262 
   263 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   264 by (simp add: inj_on_def, blast)
   265 
   266 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   267 apply (unfold surj_def)
   268 apply (blast intro: sym)
   269 done
   270 
   271 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   272 by (unfold inj_on_def, blast)
   273 
   274 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   275 apply (unfold bij_def)
   276 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   277 done
   278 
   279 lemma inj_on_image_Int:
   280    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   281 apply (simp add: inj_on_def, blast)
   282 done
   283 
   284 lemma inj_on_image_set_diff:
   285    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   286 apply (simp add: inj_on_def, blast)
   287 done
   288 
   289 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   290 by (simp add: inj_on_def, blast)
   291 
   292 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   293 by (simp add: inj_on_def, blast)
   294 
   295 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   296 by (blast dest: injD)
   297 
   298 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   299 by (simp add: inj_on_def, blast)
   300 
   301 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   302 by (blast dest: injD)
   303 
   304 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   305 lemma image_INT:
   306    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   307     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   308 apply (simp add: inj_on_def, blast)
   309 done
   310 
   311 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   312   it doesn't matter whether A is empty*)
   313 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   314 apply (simp add: bij_def)
   315 apply (simp add: inj_on_def surj_def, blast)
   316 done
   317 
   318 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   319 by (auto simp add: surj_def)
   320 
   321 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   322 by (auto simp add: inj_on_def)
   323 
   324 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   325 apply (simp add: bij_def)
   326 apply (rule equalityI)
   327 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   328 done
   329 
   330 
   331 subsection{*Function Updating*}
   332 
   333 constdefs
   334   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)"
   335   "fun_upd f a b == % x. if x=a then b else f x"
   336 
   337 nonterminals
   338   updbinds updbind
   339 syntax
   340   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   341   ""         :: "updbind => updbinds"             ("_")
   342   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   343   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000,0] 900)
   344 
   345 translations
   346   "_Update f (_updbinds b bs)"  == "_Update (_Update f b) bs"
   347   "f(x:=y)"                     == "fun_upd f x y"
   348 
   349 (* Hint: to define the sum of two functions (or maps), use sum_case.
   350          A nice infix syntax could be defined (in Datatype.thy or below) by
   351 consts
   352   fun_sum :: "('a => 'c) => ('b => 'c) => (('a+'b) => 'c)" (infixr "'(+')"80)
   353 translations
   354  "fun_sum" == sum_case
   355 *)
   356 
   357 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   358 apply (simp add: fun_upd_def, safe)
   359 apply (erule subst)
   360 apply (rule_tac [2] ext, auto)
   361 done
   362 
   363 (* f x = y ==> f(x:=y) = f *)
   364 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   365 
   366 (* f(x := f x) = f *)
   367 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   368 declare fun_upd_triv [iff]
   369 
   370 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   371 by (simp add: fun_upd_def)
   372 
   373 (* fun_upd_apply supersedes these two,   but they are useful
   374    if fun_upd_apply is intentionally removed from the simpset *)
   375 lemma fun_upd_same: "(f(x:=y)) x = y"
   376 by simp
   377 
   378 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   379 by simp
   380 
   381 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   382 by (simp add: expand_fun_eq)
   383 
   384 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   385 by (rule ext, auto)
   386 
   387 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   388 by(fastsimp simp:inj_on_def image_def)
   389 
   390 lemma fun_upd_image:
   391      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   392 by auto
   393 
   394 
   395 subsection {* @{text override_on} *}
   396 
   397 definition
   398   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   399 where
   400   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   401 
   402 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   403 by(simp add:override_on_def)
   404 
   405 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   406 by(simp add:override_on_def)
   407 
   408 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   409 by(simp add:override_on_def)
   410 
   411 
   412 subsection {* @{text swap} *}
   413 
   414 definition
   415   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   416 where
   417   "swap a b f = f (a := f b, b:= f a)"
   418 
   419 lemma swap_self: "swap a a f = f"
   420 by (simp add: swap_def)
   421 
   422 lemma swap_commute: "swap a b f = swap b a f"
   423 by (rule ext, simp add: fun_upd_def swap_def)
   424 
   425 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   426 by (rule ext, simp add: fun_upd_def swap_def)
   427 
   428 lemma inj_on_imp_inj_on_swap:
   429   "[|inj_on f A; a \<in> A; b \<in> A|] ==> inj_on (swap a b f) A"
   430 by (simp add: inj_on_def swap_def, blast)
   431 
   432 lemma inj_on_swap_iff [simp]:
   433   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A = inj_on f A"
   434 proof 
   435   assume "inj_on (swap a b f) A"
   436   with A have "inj_on (swap a b (swap a b f)) A" 
   437     by (iprover intro: inj_on_imp_inj_on_swap) 
   438   thus "inj_on f A" by simp 
   439 next
   440   assume "inj_on f A"
   441   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   442 qed
   443 
   444 lemma surj_imp_surj_swap: "surj f ==> surj (swap a b f)"
   445 apply (simp add: surj_def swap_def, clarify)
   446 apply (rule_tac P = "y = f b" in case_split_thm, blast)
   447 apply (rule_tac P = "y = f a" in case_split_thm, auto)
   448   --{*We don't yet have @{text case_tac}*}
   449 done
   450 
   451 lemma surj_swap_iff [simp]: "surj (swap a b f) = surj f"
   452 proof 
   453   assume "surj (swap a b f)"
   454   hence "surj (swap a b (swap a b f))" by (rule surj_imp_surj_swap) 
   455   thus "surj f" by simp 
   456 next
   457   assume "surj f"
   458   thus "surj (swap a b f)" by (rule surj_imp_surj_swap) 
   459 qed
   460 
   461 lemma bij_swap_iff: "bij (swap a b f) = bij f"
   462 by (simp add: bij_def)
   463 
   464 
   465 subsection {* Proof tool setup *} 
   466 
   467 text {* simplifies terms of the form
   468   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   469 
   470 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   471 let
   472   fun gen_fun_upd NONE T _ _ = NONE
   473     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   474   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   475   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   476     let
   477       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   478             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   479         | find t = NONE
   480     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   481 
   482   fun proc ss ct =
   483     let
   484       val ctxt = Simplifier.the_context ss
   485       val t = Thm.term_of ct
   486     in
   487       case find_double t of
   488         (T, NONE) => NONE
   489       | (T, SOME rhs) =>
   490           SOME (Goal.prove ctxt [] [] (Term.equals T $ t $ rhs)
   491             (fn _ =>
   492               rtac eq_reflection 1 THEN
   493               rtac ext 1 THEN
   494               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   495     end
   496 in proc end
   497 *}
   498 
   499 
   500 subsection {* Code generator setup *}
   501 
   502 types_code
   503   "fun"  ("(_ ->/ _)")
   504 attach (term_of) {*
   505 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   506 *}
   507 attach (test) {*
   508 fun gen_fun_type aF aT bG bT i =
   509   let
   510     val tab = ref [];
   511     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   512       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   513   in
   514     (fn x =>
   515        case AList.lookup op = (!tab) x of
   516          NONE =>
   517            let val p as (y, _) = bG i
   518            in (tab := (x, p) :: !tab; y) end
   519        | SOME (y, _) => y,
   520      fn () => Basics.fold mk_upd (!tab) (Const ("arbitrary", aT --> bT)))
   521   end;
   522 *}
   523 
   524 code_const "op \<circ>"
   525   (SML infixl 5 "o")
   526   (Haskell infixr 9 ".")
   527 
   528 code_const "id"
   529   (Haskell "id")
   530 
   531 
   532 subsection {* ML legacy bindings *} 
   533 
   534 ML {*
   535 val set_cs = claset() delrules [equalityI]
   536 *}
   537 
   538 ML {*
   539 val id_apply = @{thm id_apply}
   540 val id_def = @{thm id_def}
   541 val o_apply = @{thm o_apply}
   542 val o_assoc = @{thm o_assoc}
   543 val o_def = @{thm o_def}
   544 val injD = @{thm injD}
   545 val datatype_injI = @{thm datatype_injI}
   546 val range_ex1_eq = @{thm range_ex1_eq}
   547 val expand_fun_eq = @{thm expand_fun_eq}
   548 *}
   549 
   550 end