src/HOL/Product_Type.thy
author bulwahn
Wed Oct 19 08:37:21 2011 +0200 (2011-10-19)
changeset 45175 ae8411edd939
parent 44921 58eef4843641
child 45176 df4cbfc5ca4f
permissions -rw-r--r--
removing old code generator setup for product types
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Typedef Inductive Fun
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/inductive_set.ML")
    14 begin
    15 
    16 subsection {* @{typ bool} is a datatype *}
    17 
    18 rep_datatype True False by (auto intro: bool_induct)
    19 
    20 declare case_split [cases type: bool]
    21   -- "prefer plain propositional version"
    22 
    23 lemma
    24   shows [code]: "HOL.equal False P \<longleftrightarrow> \<not> P"
    25     and [code]: "HOL.equal True P \<longleftrightarrow> P" 
    26     and [code]: "HOL.equal P False \<longleftrightarrow> \<not> P" 
    27     and [code]: "HOL.equal P True \<longleftrightarrow> P"
    28     and [code nbe]: "HOL.equal P P \<longleftrightarrow> True"
    29   by (simp_all add: equal)
    30 
    31 lemma If_case_cert:
    32   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
    33   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
    34   using assms by simp_all
    35 
    36 setup {*
    37   Code.add_case @{thm If_case_cert}
    38 *}
    39 
    40 code_const "HOL.equal \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    41   (Haskell infix 4 "==")
    42 
    43 code_instance bool :: equal
    44   (Haskell -)
    45 
    46 
    47 subsection {* The @{text unit} type *}
    48 
    49 typedef (open) unit = "{True}"
    50 proof
    51   show "True : ?unit" ..
    52 qed
    53 
    54 definition
    55   Unity :: unit    ("'(')")
    56 where
    57   "() = Abs_unit True"
    58 
    59 lemma unit_eq [no_atp]: "u = ()"
    60   by (induct u) (simp add: Unity_def)
    61 
    62 text {*
    63   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    64   this rule directly --- it loops!
    65 *}
    66 
    67 simproc_setup unit_eq ("x::unit") = {*
    68   fn _ => fn _ => fn ct =>
    69     if HOLogic.is_unit (term_of ct) then NONE
    70     else SOME (mk_meta_eq @{thm unit_eq})
    71 *}
    72 
    73 rep_datatype "()" by simp
    74 
    75 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    76   by simp
    77 
    78 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    79   by (rule triv_forall_equality)
    80 
    81 text {*
    82   This rewrite counters the effect of simproc @{text unit_eq} on @{term
    83   [source] "%u::unit. f u"}, replacing it by @{term [source]
    84   f} rather than by @{term [source] "%u. f ()"}.
    85 *}
    86 
    87 lemma unit_abs_eta_conv [simp, no_atp]: "(%u::unit. f ()) = f"
    88   by (rule ext) simp
    89 
    90 lemma UNIV_unit [no_atp]:
    91   "UNIV = {()}" by auto
    92 
    93 instantiation unit :: default
    94 begin
    95 
    96 definition "default = ()"
    97 
    98 instance ..
    99 
   100 end
   101 
   102 lemma [code]:
   103   "HOL.equal (u\<Colon>unit) v \<longleftrightarrow> True" unfolding equal unit_eq [of u] unit_eq [of v] by rule+
   104 
   105 code_type unit
   106   (SML "unit")
   107   (OCaml "unit")
   108   (Haskell "()")
   109   (Scala "Unit")
   110 
   111 code_const Unity
   112   (SML "()")
   113   (OCaml "()")
   114   (Haskell "()")
   115   (Scala "()")
   116 
   117 code_instance unit :: equal
   118   (Haskell -)
   119 
   120 code_const "HOL.equal \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   121   (Haskell infix 4 "==")
   122 
   123 code_reserved SML
   124   unit
   125 
   126 code_reserved OCaml
   127   unit
   128 
   129 code_reserved Scala
   130   Unit
   131 
   132 
   133 subsection {* The product type *}
   134 
   135 subsubsection {* Type definition *}
   136 
   137 definition Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool" where
   138   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   139 
   140 typedef ('a, 'b) prod (infixr "*" 20)
   141   = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   142 proof
   143   fix a b show "Pair_Rep a b \<in> ?prod"
   144     by rule+
   145 qed
   146 
   147 type_notation (xsymbols)
   148   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   149 type_notation (HTML output)
   150   "prod"  ("(_ \<times>/ _)" [21, 20] 20)
   151 
   152 definition Pair :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b" where
   153   "Pair a b = Abs_prod (Pair_Rep a b)"
   154 
   155 rep_datatype Pair proof -
   156   fix P :: "'a \<times> 'b \<Rightarrow> bool" and p
   157   assume "\<And>a b. P (Pair a b)"
   158   then show "P p" by (cases p) (auto simp add: prod_def Pair_def Pair_Rep_def)
   159 next
   160   fix a c :: 'a and b d :: 'b
   161   have "Pair_Rep a b = Pair_Rep c d \<longleftrightarrow> a = c \<and> b = d"
   162     by (auto simp add: Pair_Rep_def fun_eq_iff)
   163   moreover have "Pair_Rep a b \<in> prod" and "Pair_Rep c d \<in> prod"
   164     by (auto simp add: prod_def)
   165   ultimately show "Pair a b = Pair c d \<longleftrightarrow> a = c \<and> b = d"
   166     by (simp add: Pair_def Abs_prod_inject)
   167 qed
   168 
   169 declare prod.simps(2) [nitpick_simp del]
   170 
   171 declare prod.weak_case_cong [cong del]
   172 
   173 
   174 subsubsection {* Tuple syntax *}
   175 
   176 abbreviation (input) split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   177   "split \<equiv> prod_case"
   178 
   179 text {*
   180   Patterns -- extends pre-defined type @{typ pttrn} used in
   181   abstractions.
   182 *}
   183 
   184 nonterminal tuple_args and patterns
   185 
   186 syntax
   187   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   188   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   189   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   190   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   191   ""            :: "pttrn => patterns"                  ("_")
   192   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   193 
   194 translations
   195   "(x, y)" == "CONST Pair x y"
   196   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   197   "%(x, y, zs). b" == "CONST prod_case (%x (y, zs). b)"
   198   "%(x, y). b" == "CONST prod_case (%x y. b)"
   199   "_abs (CONST Pair x y) t" => "%(x, y). t"
   200   -- {* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   201      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *}
   202 
   203 (*reconstruct pattern from (nested) splits, avoiding eta-contraction of body;
   204   works best with enclosing "let", if "let" does not avoid eta-contraction*)
   205 print_translation {*
   206 let
   207   fun split_tr' [Abs (x, T, t as (Abs abs))] =
   208         (* split (%x y. t) => %(x,y) t *)
   209         let
   210           val (y, t') = Syntax_Trans.atomic_abs_tr' abs;
   211           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   212         in
   213           Syntax.const @{syntax_const "_abs"} $
   214             (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   215         end
   216     | split_tr' [Abs (x, T, (s as Const (@{const_syntax prod_case}, _) $ t))] =
   217         (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   218         let
   219           val Const (@{syntax_const "_abs"}, _) $
   220             (Const (@{syntax_const "_pattern"}, _) $ y $ z) $ t' = split_tr' [t];
   221           val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, T, t');
   222         in
   223           Syntax.const @{syntax_const "_abs"} $
   224             (Syntax.const @{syntax_const "_pattern"} $ x' $
   225               (Syntax.const @{syntax_const "_patterns"} $ y $ z)) $ t''
   226         end
   227     | split_tr' [Const (@{const_syntax prod_case}, _) $ t] =
   228         (* split (split (%x y z. t)) => %((x, y), z). t *)
   229         split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   230     | split_tr' [Const (@{syntax_const "_abs"}, _) $ x_y $ Abs abs] =
   231         (* split (%pttrn z. t) => %(pttrn,z). t *)
   232         let val (z, t) = Syntax_Trans.atomic_abs_tr' abs in
   233           Syntax.const @{syntax_const "_abs"} $
   234             (Syntax.const @{syntax_const "_pattern"} $ x_y $ z) $ t
   235         end
   236     | split_tr' _ = raise Match;
   237 in [(@{const_syntax prod_case}, split_tr')] end
   238 *}
   239 
   240 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   241 typed_print_translation {*
   242 let
   243   fun split_guess_names_tr' T [Abs (x, _, Abs _)] = raise Match
   244     | split_guess_names_tr' T [Abs (x, xT, t)] =
   245         (case (head_of t) of
   246           Const (@{const_syntax prod_case}, _) => raise Match
   247         | _ =>
   248           let 
   249             val (_ :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   250             val (y, t') = Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 1 t $ Bound 0);
   251             val (x', t'') = Syntax_Trans.atomic_abs_tr' (x, xT, t');
   252           in
   253             Syntax.const @{syntax_const "_abs"} $
   254               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   255           end)
   256     | split_guess_names_tr' T [t] =
   257         (case head_of t of
   258           Const (@{const_syntax prod_case}, _) => raise Match
   259         | _ =>
   260           let
   261             val (xT :: yT :: _) = binder_types (domain_type T) handle Bind => raise Match;
   262             val (y, t') =
   263               Syntax_Trans.atomic_abs_tr' ("y", yT, incr_boundvars 2 t $ Bound 1 $ Bound 0);
   264             val (x', t'') = Syntax_Trans.atomic_abs_tr' ("x", xT, t');
   265           in
   266             Syntax.const @{syntax_const "_abs"} $
   267               (Syntax.const @{syntax_const "_pattern"} $ x' $ y) $ t''
   268           end)
   269     | split_guess_names_tr' _ _ = raise Match;
   270 in [(@{const_syntax prod_case}, split_guess_names_tr')] end
   271 *}
   272 
   273 (* Force eta-contraction for terms of the form "Q A (%p. prod_case P p)"
   274    where Q is some bounded quantifier or set operator.
   275    Reason: the above prints as "Q p : A. case p of (x,y) \<Rightarrow> P x y"
   276    whereas we want "Q (x,y):A. P x y".
   277    Otherwise prevent eta-contraction.
   278 *)
   279 print_translation {*
   280 let
   281   fun contract Q f ts =
   282     case ts of
   283       [A, Abs(_, _, (s as Const (@{const_syntax prod_case},_) $ t) $ Bound 0)]
   284       => if Term.is_dependent t then f ts else Syntax.const Q $ A $ s
   285     | _ => f ts;
   286   fun contract2 (Q,f) = (Q, contract Q f);
   287   val pairs =
   288     [Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Ball} @{syntax_const "_Ball"},
   289      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax Bex} @{syntax_const "_Bex"},
   290      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax INFI} @{syntax_const "_INF"},
   291      Syntax_Trans.preserve_binder_abs2_tr' @{const_syntax SUPR} @{syntax_const "_SUP"}]
   292 in map contract2 pairs end
   293 *}
   294 
   295 subsubsection {* Code generator setup *}
   296 
   297 code_type prod
   298   (SML infix 2 "*")
   299   (OCaml infix 2 "*")
   300   (Haskell "!((_),/ (_))")
   301   (Scala "((_),/ (_))")
   302 
   303 code_const Pair
   304   (SML "!((_),/ (_))")
   305   (OCaml "!((_),/ (_))")
   306   (Haskell "!((_),/ (_))")
   307   (Scala "!((_),/ (_))")
   308 
   309 code_instance prod :: equal
   310   (Haskell -)
   311 
   312 code_const "HOL.equal \<Colon> 'a \<times> 'b \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   313   (Haskell infix 4 "==")
   314 
   315 
   316 subsubsection {* Fundamental operations and properties *}
   317 
   318 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   319   by (cases p) simp
   320 
   321 definition fst :: "'a \<times> 'b \<Rightarrow> 'a" where
   322   "fst p = (case p of (a, b) \<Rightarrow> a)"
   323 
   324 definition snd :: "'a \<times> 'b \<Rightarrow> 'b" where
   325   "snd p = (case p of (a, b) \<Rightarrow> b)"
   326 
   327 lemma fst_conv [simp, code]: "fst (a, b) = a"
   328   unfolding fst_def by simp
   329 
   330 lemma snd_conv [simp, code]: "snd (a, b) = b"
   331   unfolding snd_def by simp
   332 
   333 code_const fst and snd
   334   (Haskell "fst" and "snd")
   335 
   336 lemma prod_case_unfold [nitpick_unfold]: "prod_case = (%c p. c (fst p) (snd p))"
   337   by (simp add: fun_eq_iff split: prod.split)
   338 
   339 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   340   by simp
   341 
   342 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   343   by simp
   344 
   345 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   346   by (cases p) simp
   347 
   348 lemmas surjective_pairing = pair_collapse [symmetric]
   349 
   350 lemma prod_eq_iff: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   351   by (cases s, cases t) simp
   352 
   353 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   354   by (simp add: prod_eq_iff)
   355 
   356 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   357   by (fact prod.cases)
   358 
   359 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   360   by (rule split_conv [THEN iffD2])
   361 
   362 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   363   by (rule split_conv [THEN iffD1])
   364 
   365 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   366   by (simp add: fun_eq_iff split: prod.split)
   367 
   368 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   369   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   370   by (simp add: fun_eq_iff split: prod.split)
   371 
   372 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   373   by (cases x) simp
   374 
   375 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   376   by (cases p) simp
   377 
   378 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   379   by (simp add: prod_case_unfold)
   380 
   381 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   382   -- {* Prevents simplification of @{term c}: much faster *}
   383   by (fact prod.weak_case_cong)
   384 
   385 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   386   by (simp add: split_eta)
   387 
   388 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   389 proof
   390   fix a b
   391   assume "!!x. PROP P x"
   392   then show "PROP P (a, b)" .
   393 next
   394   fix x
   395   assume "!!a b. PROP P (a, b)"
   396   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   397 qed
   398 
   399 text {*
   400   The rule @{thm [source] split_paired_all} does not work with the
   401   Simplifier because it also affects premises in congrence rules,
   402   where this can lead to premises of the form @{text "!!a b. ... =
   403   ?P(a, b)"} which cannot be solved by reflexivity.
   404 *}
   405 
   406 lemmas split_tupled_all = split_paired_all unit_all_eq2
   407 
   408 ML {*
   409   (* replace parameters of product type by individual component parameters *)
   410   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   411   local (* filtering with exists_paired_all is an essential optimization *)
   412     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   413           can HOLogic.dest_prodT T orelse exists_paired_all t
   414       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   415       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   416       | exists_paired_all _ = false;
   417     val ss = HOL_basic_ss
   418       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   419       addsimprocs [@{simproc unit_eq}];
   420   in
   421     val split_all_tac = SUBGOAL (fn (t, i) =>
   422       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   423     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   424       if exists_paired_all t then full_simp_tac ss i else no_tac);
   425     fun split_all th =
   426    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   427   end;
   428 *}
   429 
   430 declaration {* fn _ =>
   431   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   432 *}
   433 
   434 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   435   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   436   by fast
   437 
   438 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   439   by fast
   440 
   441 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   442   -- {* Can't be added to simpset: loops! *}
   443   by (simp add: split_eta)
   444 
   445 text {*
   446   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   447   @{thm [source] split_eta} as a rewrite rule is not general enough,
   448   and using @{thm [source] cond_split_eta} directly would render some
   449   existing proofs very inefficient; similarly for @{text
   450   split_beta}.
   451 *}
   452 
   453 ML {*
   454 local
   455   val cond_split_eta_ss = HOL_basic_ss addsimps @{thms cond_split_eta};
   456   fun Pair_pat k 0 (Bound m) = (m = k)
   457     | Pair_pat k i (Const (@{const_name Pair},  _) $ Bound m $ t) =
   458         i > 0 andalso m = k + i andalso Pair_pat k (i - 1) t
   459     | Pair_pat _ _ _ = false;
   460   fun no_args k i (Abs (_, _, t)) = no_args (k + 1) i t
   461     | no_args k i (t $ u) = no_args k i t andalso no_args k i u
   462     | no_args k i (Bound m) = m < k orelse m > k + i
   463     | no_args _ _ _ = true;
   464   fun split_pat tp i (Abs  (_, _, t)) = if tp 0 i t then SOME (i, t) else NONE
   465     | split_pat tp i (Const (@{const_name prod_case}, _) $ Abs (_, _, t)) = split_pat tp (i + 1) t
   466     | split_pat tp i _ = NONE;
   467   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   468         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs)))
   469         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   470 
   471   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k + 1) i t
   472     | beta_term_pat k i (t $ u) =
   473         Pair_pat k i (t $ u) orelse (beta_term_pat k i t andalso beta_term_pat k i u)
   474     | beta_term_pat k i t = no_args k i t;
   475   fun eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   476     | eta_term_pat _ _ _ = false;
   477   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   478     | subst arg k i (t $ u) =
   479         if Pair_pat k i (t $ u) then incr_boundvars k arg
   480         else (subst arg k i t $ subst arg k i u)
   481     | subst arg k i t = t;
   482 in
   483   fun beta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t) $ arg) =
   484         (case split_pat beta_term_pat 1 t of
   485           SOME (i, f) => SOME (metaeq ss s (subst arg 0 i f))
   486         | NONE => NONE)
   487     | beta_proc _ _ = NONE;
   488   fun eta_proc ss (s as Const (@{const_name prod_case}, _) $ Abs (_, _, t)) =
   489         (case split_pat eta_term_pat 1 t of
   490           SOME (_, ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   491         | NONE => NONE)
   492     | eta_proc _ _ = NONE;
   493 end;
   494 *}
   495 simproc_setup split_beta ("split f z") = {* fn _ => fn ss => fn ct => beta_proc ss (term_of ct) *}
   496 simproc_setup split_eta ("split f") = {* fn _ => fn ss => fn ct => eta_proc ss (term_of ct) *}
   497 
   498 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   499   by (subst surjective_pairing, rule split_conv)
   500 
   501 lemma split_split [no_atp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   502   -- {* For use with @{text split} and the Simplifier. *}
   503   by (insert surj_pair [of p], clarify, simp)
   504 
   505 text {*
   506   @{thm [source] split_split} could be declared as @{text "[split]"}
   507   done after the Splitter has been speeded up significantly;
   508   precompute the constants involved and don't do anything unless the
   509   current goal contains one of those constants.
   510 *}
   511 
   512 lemma split_split_asm [no_atp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   513 by (subst split_split, simp)
   514 
   515 text {*
   516   \medskip @{term split} used as a logical connective or set former.
   517 
   518   \medskip These rules are for use with @{text blast}; could instead
   519   call @{text simp} using @{thm [source] prod.split} as rewrite. *}
   520 
   521 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   522   apply (simp only: split_tupled_all)
   523   apply (simp (no_asm_simp))
   524   done
   525 
   526 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   527   apply (simp only: split_tupled_all)
   528   apply (simp (no_asm_simp))
   529   done
   530 
   531 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   532   by (induct p) auto
   533 
   534 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   535   by (induct p) auto
   536 
   537 lemma splitE2:
   538   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   539 proof -
   540   assume q: "Q (split P z)"
   541   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   542   show R
   543     apply (rule r surjective_pairing)+
   544     apply (rule split_beta [THEN subst], rule q)
   545     done
   546 qed
   547 
   548 lemma splitD': "split R (a,b) c ==> R a b c"
   549   by simp
   550 
   551 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   552   by simp
   553 
   554 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   555 by (simp only: split_tupled_all, simp)
   556 
   557 lemma mem_splitE:
   558   assumes major: "z \<in> split c p"
   559     and cases: "\<And>x y. p = (x, y) \<Longrightarrow> z \<in> c x y \<Longrightarrow> Q"
   560   shows Q
   561   by (rule major [unfolded prod_case_unfold] cases surjective_pairing)+
   562 
   563 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   564 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   565 
   566 ML {*
   567 local (* filtering with exists_p_split is an essential optimization *)
   568   fun exists_p_split (Const (@{const_name prod_case},_) $ _ $ (Const (@{const_name Pair},_)$_$_)) = true
   569     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   570     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   571     | exists_p_split _ = false;
   572   val ss = HOL_basic_ss addsimps @{thms split_conv};
   573 in
   574 val split_conv_tac = SUBGOAL (fn (t, i) =>
   575     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   576 end;
   577 *}
   578 
   579 (* This prevents applications of splitE for already splitted arguments leading
   580    to quite time-consuming computations (in particular for nested tuples) *)
   581 declaration {* fn _ =>
   582   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   583 *}
   584 
   585 lemma split_eta_SetCompr [simp,no_atp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   586   by (rule ext) fast
   587 
   588 lemma split_eta_SetCompr2 [simp,no_atp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   589   by (rule ext) fast
   590 
   591 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   592   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   593   by (rule ext) blast
   594 
   595 (* Do NOT make this a simp rule as it
   596    a) only helps in special situations
   597    b) can lead to nontermination in the presence of split_def
   598 *)
   599 lemma split_comp_eq: 
   600   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   601   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   602   by (rule ext) auto
   603 
   604 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   605   apply (rule_tac x = "(a, b)" in image_eqI)
   606    apply auto
   607   done
   608 
   609 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   610   by blast
   611 
   612 (*
   613 the following  would be slightly more general,
   614 but cannot be used as rewrite rule:
   615 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   616 ### ?y = .x
   617 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   618 by (rtac some_equality 1)
   619 by ( Simp_tac 1)
   620 by (split_all_tac 1)
   621 by (Asm_full_simp_tac 1)
   622 qed "The_split_eq";
   623 *)
   624 
   625 text {*
   626   Setup of internal @{text split_rule}.
   627 *}
   628 
   629 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   630 
   631 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   632   by (fact splitI2)
   633 
   634 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   635   by (fact splitI2')
   636 
   637 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   638   by (fact splitE)
   639 
   640 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   641   by (fact splitE')
   642 
   643 declare prod_caseI [intro!]
   644 
   645 lemma prod_case_beta:
   646   "prod_case f p = f (fst p) (snd p)"
   647   by (fact split_beta)
   648 
   649 lemma prod_cases3 [cases type]:
   650   obtains (fields) a b c where "y = (a, b, c)"
   651   by (cases y, case_tac b) blast
   652 
   653 lemma prod_induct3 [case_names fields, induct type]:
   654     "(!!a b c. P (a, b, c)) ==> P x"
   655   by (cases x) blast
   656 
   657 lemma prod_cases4 [cases type]:
   658   obtains (fields) a b c d where "y = (a, b, c, d)"
   659   by (cases y, case_tac c) blast
   660 
   661 lemma prod_induct4 [case_names fields, induct type]:
   662     "(!!a b c d. P (a, b, c, d)) ==> P x"
   663   by (cases x) blast
   664 
   665 lemma prod_cases5 [cases type]:
   666   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   667   by (cases y, case_tac d) blast
   668 
   669 lemma prod_induct5 [case_names fields, induct type]:
   670     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   671   by (cases x) blast
   672 
   673 lemma prod_cases6 [cases type]:
   674   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   675   by (cases y, case_tac e) blast
   676 
   677 lemma prod_induct6 [case_names fields, induct type]:
   678     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   679   by (cases x) blast
   680 
   681 lemma prod_cases7 [cases type]:
   682   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   683   by (cases y, case_tac f) blast
   684 
   685 lemma prod_induct7 [case_names fields, induct type]:
   686     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   687   by (cases x) blast
   688 
   689 lemma split_def:
   690   "split = (\<lambda>c p. c (fst p) (snd p))"
   691   by (fact prod_case_unfold)
   692 
   693 definition internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c" where
   694   "internal_split == split"
   695 
   696 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   697   by (simp only: internal_split_def split_conv)
   698 
   699 use "Tools/split_rule.ML"
   700 setup Split_Rule.setup
   701 
   702 hide_const internal_split
   703 
   704 
   705 subsubsection {* Derived operations *}
   706 
   707 definition curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c" where
   708   "curry = (\<lambda>c x y. c (x, y))"
   709 
   710 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   711   by (simp add: curry_def)
   712 
   713 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   714   by (simp add: curry_def)
   715 
   716 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   717   by (simp add: curry_def)
   718 
   719 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   720   by (simp add: curry_def)
   721 
   722 lemma curry_split [simp]: "curry (split f) = f"
   723   by (simp add: curry_def split_def)
   724 
   725 lemma split_curry [simp]: "split (curry f) = f"
   726   by (simp add: curry_def split_def)
   727 
   728 text {*
   729   The composition-uncurry combinator.
   730 *}
   731 
   732 notation fcomp (infixl "\<circ>>" 60)
   733 
   734 definition scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "\<circ>\<rightarrow>" 60) where
   735   "f \<circ>\<rightarrow> g = (\<lambda>x. prod_case g (f x))"
   736 
   737 lemma scomp_unfold: "scomp = (\<lambda>f g x. g (fst (f x)) (snd (f x)))"
   738   by (simp add: fun_eq_iff scomp_def prod_case_unfold)
   739 
   740 lemma scomp_apply [simp]: "(f \<circ>\<rightarrow> g) x = prod_case g (f x)"
   741   by (simp add: scomp_unfold prod_case_unfold)
   742 
   743 lemma Pair_scomp: "Pair x \<circ>\<rightarrow> f = f x"
   744   by (simp add: fun_eq_iff)
   745 
   746 lemma scomp_Pair: "x \<circ>\<rightarrow> Pair = x"
   747   by (simp add: fun_eq_iff)
   748 
   749 lemma scomp_scomp: "(f \<circ>\<rightarrow> g) \<circ>\<rightarrow> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>\<rightarrow> h)"
   750   by (simp add: fun_eq_iff scomp_unfold)
   751 
   752 lemma scomp_fcomp: "(f \<circ>\<rightarrow> g) \<circ>> h = f \<circ>\<rightarrow> (\<lambda>x. g x \<circ>> h)"
   753   by (simp add: fun_eq_iff scomp_unfold fcomp_def)
   754 
   755 lemma fcomp_scomp: "(f \<circ>> g) \<circ>\<rightarrow> h = f \<circ>> (g \<circ>\<rightarrow> h)"
   756   by (simp add: fun_eq_iff scomp_unfold)
   757 
   758 code_const scomp
   759   (Eval infixl 3 "#->")
   760 
   761 no_notation fcomp (infixl "\<circ>>" 60)
   762 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
   763 
   764 text {*
   765   @{term map_pair} --- action of the product functor upon
   766   functions.
   767 *}
   768 
   769 definition map_pair :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   770   "map_pair f g = (\<lambda>(x, y). (f x, g y))"
   771 
   772 lemma map_pair_simp [simp, code]:
   773   "map_pair f g (a, b) = (f a, g b)"
   774   by (simp add: map_pair_def)
   775 
   776 enriched_type map_pair: map_pair
   777   by (auto simp add: split_paired_all)
   778 
   779 lemma fst_map_pair [simp]:
   780   "fst (map_pair f g x) = f (fst x)"
   781   by (cases x) simp_all
   782 
   783 lemma snd_prod_fun [simp]:
   784   "snd (map_pair f g x) = g (snd x)"
   785   by (cases x) simp_all
   786 
   787 lemma fst_comp_map_pair [simp]:
   788   "fst \<circ> map_pair f g = f \<circ> fst"
   789   by (rule ext) simp_all
   790 
   791 lemma snd_comp_map_pair [simp]:
   792   "snd \<circ> map_pair f g = g \<circ> snd"
   793   by (rule ext) simp_all
   794 
   795 lemma map_pair_compose:
   796   "map_pair (f1 o f2) (g1 o g2) = (map_pair f1 g1 o map_pair f2 g2)"
   797   by (rule ext) (simp add: map_pair.compositionality comp_def)
   798 
   799 lemma map_pair_ident [simp]:
   800   "map_pair (%x. x) (%y. y) = (%z. z)"
   801   by (rule ext) (simp add: map_pair.identity)
   802 
   803 lemma map_pair_imageI [intro]:
   804   "(a, b) \<in> R \<Longrightarrow> (f a, g b) \<in> map_pair f g ` R"
   805   by (rule image_eqI) simp_all
   806 
   807 lemma prod_fun_imageE [elim!]:
   808   assumes major: "c \<in> map_pair f g ` R"
   809     and cases: "\<And>x y. c = (f x, g y) \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> P"
   810   shows P
   811   apply (rule major [THEN imageE])
   812   apply (case_tac x)
   813   apply (rule cases)
   814   apply simp_all
   815   done
   816 
   817 definition apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b" where
   818   "apfst f = map_pair f id"
   819 
   820 definition apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c" where
   821   "apsnd f = map_pair id f"
   822 
   823 lemma apfst_conv [simp, code]:
   824   "apfst f (x, y) = (f x, y)" 
   825   by (simp add: apfst_def)
   826 
   827 lemma apsnd_conv [simp, code]:
   828   "apsnd f (x, y) = (x, f y)" 
   829   by (simp add: apsnd_def)
   830 
   831 lemma fst_apfst [simp]:
   832   "fst (apfst f x) = f (fst x)"
   833   by (cases x) simp
   834 
   835 lemma fst_apsnd [simp]:
   836   "fst (apsnd f x) = fst x"
   837   by (cases x) simp
   838 
   839 lemma snd_apfst [simp]:
   840   "snd (apfst f x) = snd x"
   841   by (cases x) simp
   842 
   843 lemma snd_apsnd [simp]:
   844   "snd (apsnd f x) = f (snd x)"
   845   by (cases x) simp
   846 
   847 lemma apfst_compose:
   848   "apfst f (apfst g x) = apfst (f \<circ> g) x"
   849   by (cases x) simp
   850 
   851 lemma apsnd_compose:
   852   "apsnd f (apsnd g x) = apsnd (f \<circ> g) x"
   853   by (cases x) simp
   854 
   855 lemma apfst_apsnd [simp]:
   856   "apfst f (apsnd g x) = (f (fst x), g (snd x))"
   857   by (cases x) simp
   858 
   859 lemma apsnd_apfst [simp]:
   860   "apsnd f (apfst g x) = (g (fst x), f (snd x))"
   861   by (cases x) simp
   862 
   863 lemma apfst_id [simp] :
   864   "apfst id = id"
   865   by (simp add: fun_eq_iff)
   866 
   867 lemma apsnd_id [simp] :
   868   "apsnd id = id"
   869   by (simp add: fun_eq_iff)
   870 
   871 lemma apfst_eq_conv [simp]:
   872   "apfst f x = apfst g x \<longleftrightarrow> f (fst x) = g (fst x)"
   873   by (cases x) simp
   874 
   875 lemma apsnd_eq_conv [simp]:
   876   "apsnd f x = apsnd g x \<longleftrightarrow> f (snd x) = g (snd x)"
   877   by (cases x) simp
   878 
   879 lemma apsnd_apfst_commute:
   880   "apsnd f (apfst g p) = apfst g (apsnd f p)"
   881   by simp
   882 
   883 text {*
   884   Disjoint union of a family of sets -- Sigma.
   885 *}
   886 
   887 definition Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   888   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   889 
   890 abbreviation
   891   Times :: "['a set, 'b set] => ('a * 'b) set"
   892     (infixr "<*>" 80) where
   893   "A <*> B == Sigma A (%_. B)"
   894 
   895 notation (xsymbols)
   896   Times  (infixr "\<times>" 80)
   897 
   898 notation (HTML output)
   899   Times  (infixr "\<times>" 80)
   900 
   901 syntax
   902   "_Sigma" :: "[pttrn, 'a set, 'b set] => ('a * 'b) set"  ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   903 translations
   904   "SIGMA x:A. B" == "CONST Sigma A (%x. B)"
   905 
   906 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   907   by (unfold Sigma_def) blast
   908 
   909 lemma SigmaE [elim!]:
   910     "[| c: Sigma A B;
   911         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   912      |] ==> P"
   913   -- {* The general elimination rule. *}
   914   by (unfold Sigma_def) blast
   915 
   916 text {*
   917   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   918   eigenvariables.
   919 *}
   920 
   921 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   922   by blast
   923 
   924 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   925   by blast
   926 
   927 lemma SigmaE2:
   928     "[| (a, b) : Sigma A B;
   929         [| a:A;  b:B(a) |] ==> P
   930      |] ==> P"
   931   by blast
   932 
   933 lemma Sigma_cong:
   934      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   935       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   936   by auto
   937 
   938 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   939   by blast
   940 
   941 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   942   by blast
   943 
   944 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   945   by blast
   946 
   947 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   948   by auto
   949 
   950 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   951   by auto
   952 
   953 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   954   by auto
   955 
   956 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   957   by blast
   958 
   959 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   960   by blast
   961 
   962 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   963   by (blast elim: equalityE)
   964 
   965 lemma SetCompr_Sigma_eq:
   966     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   967   by blast
   968 
   969 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   970   by blast
   971 
   972 lemma UN_Times_distrib:
   973   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   974   -- {* Suggested by Pierre Chartier *}
   975   by blast
   976 
   977 lemma split_paired_Ball_Sigma [simp,no_atp]:
   978     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   979   by blast
   980 
   981 lemma split_paired_Bex_Sigma [simp,no_atp]:
   982     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   983   by blast
   984 
   985 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   986   by blast
   987 
   988 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   989   by blast
   990 
   991 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   992   by blast
   993 
   994 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   995   by blast
   996 
   997 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   998   by blast
   999 
  1000 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
  1001   by blast
  1002 
  1003 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
  1004   by blast
  1005 
  1006 text {*
  1007   Non-dependent versions are needed to avoid the need for higher-order
  1008   matching, especially when the rules are re-oriented.
  1009 *}
  1010 
  1011 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
  1012 by blast
  1013 
  1014 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
  1015 by blast
  1016 
  1017 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
  1018 by blast
  1019 
  1020 lemma Times_empty[simp]: "A \<times> B = {} \<longleftrightarrow> A = {} \<or> B = {}"
  1021   by auto
  1022 
  1023 lemma fst_image_times[simp]: "fst ` (A \<times> B) = (if B = {} then {} else A)"
  1024   by force
  1025 
  1026 lemma snd_image_times[simp]: "snd ` (A \<times> B) = (if A = {} then {} else B)"
  1027   by force
  1028 
  1029 lemma insert_times_insert[simp]:
  1030   "insert a A \<times> insert b B =
  1031    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
  1032 by blast
  1033 
  1034 lemma vimage_Times: "f -` (A \<times> B) = ((fst \<circ> f) -` A) \<inter> ((snd \<circ> f) -` B)"
  1035   by (auto, case_tac "f x", auto)
  1036 
  1037 lemma swap_inj_on:
  1038   "inj_on (\<lambda>(i, j). (j, i)) A"
  1039   by (auto intro!: inj_onI)
  1040 
  1041 lemma swap_product:
  1042   "(%(i, j). (j, i)) ` (A \<times> B) = B \<times> A"
  1043   by (simp add: split_def image_def) blast
  1044 
  1045 lemma image_split_eq_Sigma:
  1046   "(\<lambda>x. (f x, g x)) ` A = Sigma (f ` A) (\<lambda>x. g ` (f -` {x} \<inter> A))"
  1047 proof (safe intro!: imageI vimageI)
  1048   fix a b assume *: "a \<in> A" "b \<in> A" and eq: "f a = f b"
  1049   show "(f b, g a) \<in> (\<lambda>x. (f x, g x)) ` A"
  1050     using * eq[symmetric] by auto
  1051 qed simp_all
  1052 
  1053 text {* The following @{const map_pair} lemmas are due to Joachim Breitner: *}
  1054 
  1055 lemma map_pair_inj_on:
  1056   assumes "inj_on f A" and "inj_on g B"
  1057   shows "inj_on (map_pair f g) (A \<times> B)"
  1058 proof (rule inj_onI)
  1059   fix x :: "'a \<times> 'c" and y :: "'a \<times> 'c"
  1060   assume "x \<in> A \<times> B" hence "fst x \<in> A" and "snd x \<in> B" by auto
  1061   assume "y \<in> A \<times> B" hence "fst y \<in> A" and "snd y \<in> B" by auto
  1062   assume "map_pair f g x = map_pair f g y"
  1063   hence "fst (map_pair f g x) = fst (map_pair f g y)" by (auto)
  1064   hence "f (fst x) = f (fst y)" by (cases x,cases y,auto)
  1065   with `inj_on f A` and `fst x \<in> A` and `fst y \<in> A`
  1066   have "fst x = fst y" by (auto dest:dest:inj_onD)
  1067   moreover from `map_pair f g x = map_pair f g y`
  1068   have "snd (map_pair f g x) = snd (map_pair f g y)" by (auto)
  1069   hence "g (snd x) = g (snd y)" by (cases x,cases y,auto)
  1070   with `inj_on g B` and `snd x \<in> B` and `snd y \<in> B`
  1071   have "snd x = snd y" by (auto dest:dest:inj_onD)
  1072   ultimately show "x = y" by(rule prod_eqI)
  1073 qed
  1074 
  1075 lemma map_pair_surj:
  1076   fixes f :: "'a \<Rightarrow> 'b" and g :: "'c \<Rightarrow> 'd"
  1077   assumes "surj f" and "surj g"
  1078   shows "surj (map_pair f g)"
  1079 unfolding surj_def
  1080 proof
  1081   fix y :: "'b \<times> 'd"
  1082   from `surj f` obtain a where "fst y = f a" by (auto elim:surjE)
  1083   moreover
  1084   from `surj g` obtain b where "snd y = g b" by (auto elim:surjE)
  1085   ultimately have "(fst y, snd y) = map_pair f g (a,b)" by auto
  1086   thus "\<exists>x. y = map_pair f g x" by auto
  1087 qed
  1088 
  1089 lemma map_pair_surj_on:
  1090   assumes "f ` A = A'" and "g ` B = B'"
  1091   shows "map_pair f g ` (A \<times> B) = A' \<times> B'"
  1092 unfolding image_def
  1093 proof(rule set_eqI,rule iffI)
  1094   fix x :: "'a \<times> 'c"
  1095   assume "x \<in> {y\<Colon>'a \<times> 'c. \<exists>x\<Colon>'b \<times> 'd\<in>A \<times> B. y = map_pair f g x}"
  1096   then obtain y where "y \<in> A \<times> B" and "x = map_pair f g y" by blast
  1097   from `image f A = A'` and `y \<in> A \<times> B` have "f (fst y) \<in> A'" by auto
  1098   moreover from `image g B = B'` and `y \<in> A \<times> B` have "g (snd y) \<in> B'" by auto
  1099   ultimately have "(f (fst y), g (snd y)) \<in> (A' \<times> B')" by auto
  1100   with `x = map_pair f g y` show "x \<in> A' \<times> B'" by (cases y, auto)
  1101 next
  1102   fix x :: "'a \<times> 'c"
  1103   assume "x \<in> A' \<times> B'" hence "fst x \<in> A'" and "snd x \<in> B'" by auto
  1104   from `image f A = A'` and `fst x \<in> A'` have "fst x \<in> image f A" by auto
  1105   then obtain a where "a \<in> A" and "fst x = f a" by (rule imageE)
  1106   moreover from `image g B = B'` and `snd x \<in> B'`
  1107   obtain b where "b \<in> B" and "snd x = g b" by auto
  1108   ultimately have "(fst x, snd x) = map_pair f g (a,b)" by auto
  1109   moreover from `a \<in> A` and  `b \<in> B` have "(a , b) \<in> A \<times> B" by auto
  1110   ultimately have "\<exists>y \<in> A \<times> B. x = map_pair f g y" by auto
  1111   thus "x \<in> {x. \<exists>y \<in> A \<times> B. x = map_pair f g y}" by auto
  1112 qed
  1113 
  1114 
  1115 subsection {* Inductively defined sets *}
  1116 
  1117 use "Tools/inductive_codegen.ML"
  1118 setup Inductive_Codegen.setup
  1119 
  1120 use "Tools/inductive_set.ML"
  1121 setup Inductive_Set.setup
  1122 
  1123 
  1124 subsection {* Legacy theorem bindings and duplicates *}
  1125 
  1126 lemma PairE:
  1127   obtains x y where "p = (x, y)"
  1128   by (fact prod.exhaust)
  1129 
  1130 lemma Pair_inject:
  1131   assumes "(a, b) = (a', b')"
  1132     and "a = a' ==> b = b' ==> R"
  1133   shows R
  1134   using assms by simp
  1135 
  1136 lemmas Pair_eq = prod.inject
  1137 
  1138 lemmas split = split_conv  -- {* for backwards compatibility *}
  1139 
  1140 lemmas Pair_fst_snd_eq = prod_eq_iff
  1141 
  1142 end