src/HOL/Groebner_Basis.thy
author haftmann
Thu May 06 17:59:19 2010 +0200 (2010-05-06)
changeset 36714 ae84ddf03c58
parent 36712 2f4c318861b3
child 36716 b09f3ad3208f
permissions -rw-r--r--
dropped duplicate comp_arith
     1 (*  Title:      HOL/Groebner_Basis.thy
     2     Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 header {* Semiring normalization and Groebner Bases *}
     6 
     7 theory Groebner_Basis
     8 imports Numeral_Simprocs Nat_Transfer
     9 uses
    10   "Tools/Groebner_Basis/normalizer.ML"
    11   ("Tools/Groebner_Basis/groebner.ML")
    12 begin
    13 
    14 subsection {* Semiring normalization *}
    15 
    16 setup Normalizer.setup
    17 
    18 locale normalizing_semiring =
    19   fixes add mul pwr r0 r1
    20   assumes add_a:"(add x (add y z) = add (add x y) z)"
    21     and add_c: "add x y = add y x" and add_0:"add r0 x = x"
    22     and mul_a:"mul x (mul y z) = mul (mul x y) z" and mul_c:"mul x y = mul y x"
    23     and mul_1:"mul r1 x = x" and  mul_0:"mul r0 x = r0"
    24     and mul_d:"mul x (add y z) = add (mul x y) (mul x z)"
    25     and pwr_0:"pwr x 0 = r1" and pwr_Suc:"pwr x (Suc n) = mul x (pwr x n)"
    26 begin
    27 
    28 lemma mul_pwr:"mul (pwr x p) (pwr x q) = pwr x (p + q)"
    29 proof (induct p)
    30   case 0
    31   then show ?case by (auto simp add: pwr_0 mul_1)
    32 next
    33   case Suc
    34   from this [symmetric] show ?case
    35     by (auto simp add: pwr_Suc mul_1 mul_a)
    36 qed
    37 
    38 lemma pwr_mul: "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    39 proof (induct q arbitrary: x y, auto simp add:pwr_0 pwr_Suc mul_1)
    40   fix q x y
    41   assume "\<And>x y. pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    42   have "mul (mul x y) (mul (pwr x q) (pwr y q)) = mul x (mul y (mul (pwr x q) (pwr y q)))"
    43     by (simp add: mul_a)
    44   also have "\<dots> = (mul (mul y (mul (pwr y q) (pwr x q))) x)" by (simp add: mul_c)
    45   also have "\<dots> = (mul (mul y (pwr y q)) (mul (pwr x q) x))" by (simp add: mul_a)
    46   finally show "mul (mul x y) (mul (pwr x q) (pwr y q)) =
    47     mul (mul x (pwr x q)) (mul y (pwr y q))" by (simp add: mul_c)
    48 qed
    49 
    50 lemma pwr_pwr: "pwr (pwr x p) q = pwr x (p * q)"
    51 proof (induct p arbitrary: q)
    52   case 0
    53   show ?case using pwr_Suc mul_1 pwr_0 by (induct q) auto
    54 next
    55   case Suc
    56   thus ?case by (auto simp add: mul_pwr [symmetric] pwr_mul pwr_Suc)
    57 qed
    58 
    59 lemma semiring_ops:
    60   shows "TERM (add x y)" and "TERM (mul x y)" and "TERM (pwr x n)"
    61     and "TERM r0" and "TERM r1" .
    62 
    63 lemma semiring_rules:
    64   "add (mul a m) (mul b m) = mul (add a b) m"
    65   "add (mul a m) m = mul (add a r1) m"
    66   "add m (mul a m) = mul (add a r1) m"
    67   "add m m = mul (add r1 r1) m"
    68   "add r0 a = a"
    69   "add a r0 = a"
    70   "mul a b = mul b a"
    71   "mul (add a b) c = add (mul a c) (mul b c)"
    72   "mul r0 a = r0"
    73   "mul a r0 = r0"
    74   "mul r1 a = a"
    75   "mul a r1 = a"
    76   "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
    77   "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
    78   "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
    79   "mul (mul lx ly) rx = mul (mul lx rx) ly"
    80   "mul (mul lx ly) rx = mul lx (mul ly rx)"
    81   "mul lx (mul rx ry) = mul (mul lx rx) ry"
    82   "mul lx (mul rx ry) = mul rx (mul lx ry)"
    83   "add (add a b) (add c d) = add (add a c) (add b d)"
    84   "add (add a b) c = add a (add b c)"
    85   "add a (add c d) = add c (add a d)"
    86   "add (add a b) c = add (add a c) b"
    87   "add a c = add c a"
    88   "add a (add c d) = add (add a c) d"
    89   "mul (pwr x p) (pwr x q) = pwr x (p + q)"
    90   "mul x (pwr x q) = pwr x (Suc q)"
    91   "mul (pwr x q) x = pwr x (Suc q)"
    92   "mul x x = pwr x 2"
    93   "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    94   "pwr (pwr x p) q = pwr x (p * q)"
    95   "pwr x 0 = r1"
    96   "pwr x 1 = x"
    97   "mul x (add y z) = add (mul x y) (mul x z)"
    98   "pwr x (Suc q) = mul x (pwr x q)"
    99   "pwr x (2*n) = mul (pwr x n) (pwr x n)"
   100   "pwr x (Suc (2*n)) = mul x (mul (pwr x n) (pwr x n))"
   101 proof -
   102   show "add (mul a m) (mul b m) = mul (add a b) m" using mul_d mul_c by simp
   103 next show"add (mul a m) m = mul (add a r1) m" using mul_d mul_c mul_1 by simp
   104 next show "add m (mul a m) = mul (add a r1) m" using mul_c mul_d mul_1 add_c by simp
   105 next show "add m m = mul (add r1 r1) m" using mul_c mul_d mul_1 by simp
   106 next show "add r0 a = a" using add_0 by simp
   107 next show "add a r0 = a" using add_0 add_c by simp
   108 next show "mul a b = mul b a" using mul_c by simp
   109 next show "mul (add a b) c = add (mul a c) (mul b c)" using mul_c mul_d by simp
   110 next show "mul r0 a = r0" using mul_0 by simp
   111 next show "mul a r0 = r0" using mul_0 mul_c by simp
   112 next show "mul r1 a = a" using mul_1 by simp
   113 next show "mul a r1 = a" using mul_1 mul_c by simp
   114 next show "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
   115     using mul_c mul_a by simp
   116 next show "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
   117     using mul_a by simp
   118 next
   119   have "mul (mul lx ly) (mul rx ry) = mul (mul rx ry) (mul lx ly)" by (rule mul_c)
   120   also have "\<dots> = mul rx (mul ry (mul lx ly))" using mul_a by simp
   121   finally
   122   show "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
   123     using mul_c by simp
   124 next show "mul (mul lx ly) rx = mul (mul lx rx) ly" using mul_c mul_a by simp
   125 next
   126   show "mul (mul lx ly) rx = mul lx (mul ly rx)" by (simp add: mul_a)
   127 next show "mul lx (mul rx ry) = mul (mul lx rx) ry" by (simp add: mul_a )
   128 next show "mul lx (mul rx ry) = mul rx (mul lx ry)" by (simp add: mul_a,simp add: mul_c)
   129 next show "add (add a b) (add c d) = add (add a c) (add b d)"
   130     using add_c add_a by simp
   131 next show "add (add a b) c = add a (add b c)" using add_a by simp
   132 next show "add a (add c d) = add c (add a d)"
   133     apply (simp add: add_a) by (simp only: add_c)
   134 next show "add (add a b) c = add (add a c) b" using add_a add_c by simp
   135 next show "add a c = add c a" by (rule add_c)
   136 next show "add a (add c d) = add (add a c) d" using add_a by simp
   137 next show "mul (pwr x p) (pwr x q) = pwr x (p + q)" by (rule mul_pwr)
   138 next show "mul x (pwr x q) = pwr x (Suc q)" using pwr_Suc by simp
   139 next show "mul (pwr x q) x = pwr x (Suc q)" using pwr_Suc mul_c by simp
   140 next show "mul x x = pwr x 2" by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   141 next show "pwr (mul x y) q = mul (pwr x q) (pwr y q)" by (rule pwr_mul)
   142 next show "pwr (pwr x p) q = pwr x (p * q)" by (rule pwr_pwr)
   143 next show "pwr x 0 = r1" using pwr_0 .
   144 next show "pwr x 1 = x" unfolding One_nat_def by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   145 next show "mul x (add y z) = add (mul x y) (mul x z)" using mul_d by simp
   146 next show "pwr x (Suc q) = mul x (pwr x q)" using pwr_Suc by simp
   147 next show "pwr x (2 * n) = mul (pwr x n) (pwr x n)" by (simp add: nat_number' mul_pwr)
   148 next show "pwr x (Suc (2 * n)) = mul x (mul (pwr x n) (pwr x n))"
   149     by (simp add: nat_number' pwr_Suc mul_pwr)
   150 qed
   151 
   152 
   153 lemmas normalizing_semiring_axioms' =
   154   normalizing_semiring_axioms [normalizer
   155     semiring ops: semiring_ops
   156     semiring rules: semiring_rules]
   157 
   158 end
   159 
   160 sublocale comm_semiring_1
   161   < normalizing!: normalizing_semiring plus times power zero one
   162 proof
   163 qed (simp_all add: algebra_simps)
   164 
   165 lemma not_iszero_Numeral1: "\<not> iszero (Numeral1::'a::number_ring)"
   166   by simp
   167 
   168 lemmas semiring_norm =
   169   Let_def arith_simps nat_arith rel_simps neg_simps if_False
   170   if_True add_0 add_Suc add_number_of_left mult_number_of_left
   171   numeral_1_eq_1[symmetric] Suc_eq_plus1
   172   numeral_0_eq_0[symmetric] numerals[symmetric]
   173   iszero_simps not_iszero_Numeral1
   174 
   175 ML {*
   176 local
   177 
   178 fun numeral_is_const ct = can HOLogic.dest_number (Thm.term_of ct);
   179 
   180 fun int_of_rat x =
   181   (case Rat.quotient_of_rat x of (i, 1) => i
   182   | _ => error "int_of_rat: bad int");
   183 
   184 val numeral_conv =
   185   Simplifier.rewrite (HOL_basic_ss addsimps @{thms semiring_norm}) then_conv
   186   Simplifier.rewrite (HOL_basic_ss addsimps
   187     (@{thms numeral_1_eq_1} @ @{thms numeral_0_eq_0} @ @{thms numerals(1-2)}));
   188 
   189 in
   190 
   191 fun normalizer_funs' key =
   192   Normalizer.funs key
   193    {is_const = fn phi => numeral_is_const,
   194     dest_const = fn phi => fn ct =>
   195       Rat.rat_of_int (snd
   196         (HOLogic.dest_number (Thm.term_of ct)
   197           handle TERM _ => error "ring_dest_const")),
   198     mk_const = fn phi => fn cT => fn x => Numeral.mk_cnumber cT (int_of_rat x),
   199     conv = fn phi => K numeral_conv}
   200 
   201 end
   202 *}
   203 
   204 declaration {* normalizer_funs' @{thm normalizing.normalizing_semiring_axioms'} *}
   205 
   206 locale normalizing_ring = normalizing_semiring +
   207   fixes sub :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   208     and neg :: "'a \<Rightarrow> 'a"
   209   assumes neg_mul: "neg x = mul (neg r1) x"
   210     and sub_add: "sub x y = add x (neg y)"
   211 begin
   212 
   213 lemma ring_ops: shows "TERM (sub x y)" and "TERM (neg x)" .
   214 
   215 lemmas ring_rules = neg_mul sub_add
   216 
   217 lemmas normalizing_ring_axioms' =
   218   normalizing_ring_axioms [normalizer
   219     semiring ops: semiring_ops
   220     semiring rules: semiring_rules
   221     ring ops: ring_ops
   222     ring rules: ring_rules]
   223 
   224 end
   225 
   226 (*FIXME add class*)
   227 interpretation normalizing!: normalizing_ring plus times power
   228   "0::'a::{comm_semiring_1,number_ring}" 1 minus uminus proof
   229 qed simp_all
   230 
   231 declaration {* normalizer_funs' @{thm normalizing.normalizing_ring_axioms'} *}
   232 
   233 locale normalizing_field = normalizing_ring +
   234   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   235     and inverse:: "'a \<Rightarrow> 'a"
   236   assumes divide_inverse: "divide x y = mul x (inverse y)"
   237      and inverse_divide: "inverse x = divide r1 x"
   238 begin
   239 
   240 lemma field_ops: shows "TERM (divide x y)" and "TERM (inverse x)" .
   241 
   242 lemmas field_rules = divide_inverse inverse_divide
   243 
   244 lemmas normalizing_field_axioms' =
   245   normalizing_field_axioms [normalizer
   246     semiring ops: semiring_ops
   247     semiring rules: semiring_rules
   248     ring ops: ring_ops
   249     ring rules: ring_rules
   250     field ops: field_ops
   251     field rules: field_rules]
   252 
   253 end
   254 
   255 locale normalizing_semiring_cancel = normalizing_semiring +
   256   assumes add_cancel: "add (x::'a) y = add x z \<longleftrightarrow> y = z"
   257   and add_mul_solve: "add (mul w y) (mul x z) =
   258     add (mul w z) (mul x y) \<longleftrightarrow> w = x \<or> y = z"
   259 begin
   260 
   261 lemma noteq_reduce: "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   262 proof-
   263   have "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> \<not> (a = b \<or> c = d)" by simp
   264   also have "\<dots> \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   265     using add_mul_solve by blast
   266   finally show "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   267     by simp
   268 qed
   269 
   270 lemma add_scale_eq_noteq: "\<lbrakk>r \<noteq> r0 ; (a = b) \<and> ~(c = d)\<rbrakk>
   271   \<Longrightarrow> add a (mul r c) \<noteq> add b (mul r d)"
   272 proof(clarify)
   273   assume nz: "r\<noteq> r0" and cnd: "c\<noteq>d"
   274     and eq: "add b (mul r c) = add b (mul r d)"
   275   hence "mul r c = mul r d" using cnd add_cancel by simp
   276   hence "add (mul r0 d) (mul r c) = add (mul r0 c) (mul r d)"
   277     using mul_0 add_cancel by simp
   278   thus "False" using add_mul_solve nz cnd by simp
   279 qed
   280 
   281 lemma add_r0_iff: " x = add x a \<longleftrightarrow> a = r0"
   282 proof-
   283   have "a = r0 \<longleftrightarrow> add x a = add x r0" by (simp add: add_cancel)
   284   thus "x = add x a \<longleftrightarrow> a = r0" by (auto simp add: add_c add_0)
   285 qed
   286 
   287 declare normalizing_semiring_axioms' [normalizer del]
   288 
   289 lemmas normalizing_semiring_cancel_axioms' =
   290   normalizing_semiring_cancel_axioms [normalizer
   291     semiring ops: semiring_ops
   292     semiring rules: semiring_rules
   293     idom rules: noteq_reduce add_scale_eq_noteq]
   294 
   295 end
   296 
   297 locale normalizing_ring_cancel = normalizing_semiring_cancel + normalizing_ring + 
   298   assumes subr0_iff: "sub x y = r0 \<longleftrightarrow> x = y"
   299 begin
   300 
   301 declare normalizing_ring_axioms' [normalizer del]
   302 
   303 lemmas normalizing_ring_cancel_axioms' = normalizing_ring_cancel_axioms [normalizer
   304   semiring ops: semiring_ops
   305   semiring rules: semiring_rules
   306   ring ops: ring_ops
   307   ring rules: ring_rules
   308   idom rules: noteq_reduce add_scale_eq_noteq
   309   ideal rules: subr0_iff add_r0_iff]
   310 
   311 end
   312 
   313 lemma (in no_zero_divisors) prod_eq_zero_eq_zero:
   314   assumes "a * b = 0" and "a \<noteq> 0"
   315   shows "b = 0"
   316 proof (rule classical)
   317   assume "b \<noteq> 0" with `a \<noteq> 0` no_zero_divisors have "a * b \<noteq> 0" by blast
   318   with `a * b = 0` show ?thesis by simp
   319 qed
   320 
   321 (*FIXME introduce class*)
   322 interpretation normalizing!: normalizing_ring_cancel
   323   "op +" "op *" "op ^" "0::'a::{idom,number_ring}" "1" "op -" "uminus"
   324 proof(unfold_locales, simp add: algebra_simps, auto)
   325   fix w x y z ::"'a::{idom,number_ring}"
   326   assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   327   hence ynz': "y - z \<noteq> 0" by simp
   328   from p have "w * y + x* z - w*z - x*y = 0" by simp
   329   hence "w* (y - z) - x * (y - z) = 0" by (simp add: algebra_simps)
   330   hence "(y - z) * (w - x) = 0" by (simp add: algebra_simps)
   331   with  prod_eq_zero_eq_zero [OF _ ynz']
   332   have "w - x = 0" by blast
   333   thus "w = x"  by simp
   334 qed
   335 
   336 declaration {* normalizer_funs' @{thm normalizing.normalizing_ring_cancel_axioms'} *}
   337 
   338 interpretation normalizing_nat!: normalizing_semiring_cancel
   339   "op +" "op *" "op ^" "0::nat" "1"
   340 proof (unfold_locales, simp add: algebra_simps)
   341   fix w x y z ::"nat"
   342   { assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   343     hence "y < z \<or> y > z" by arith
   344     moreover {
   345       assume lt:"y <z" hence "\<exists>k. z = y + k \<and> k > 0" by (rule_tac x="z - y" in exI, auto)
   346       then obtain k where kp: "k>0" and yz:"z = y + k" by blast
   347       from p have "(w * y + x *y) + x*k = (w * y + x*y) + w*k" by (simp add: yz algebra_simps)
   348       hence "x*k = w*k" by simp
   349       hence "w = x" using kp by simp }
   350     moreover {
   351       assume lt: "y >z" hence "\<exists>k. y = z + k \<and> k>0" by (rule_tac x="y - z" in exI, auto)
   352       then obtain k where kp: "k>0" and yz:"y = z + k" by blast
   353       from p have "(w * z + x *z) + w*k = (w * z + x*z) + x*k" by (simp add: yz algebra_simps)
   354       hence "w*k = x*k" by simp
   355       hence "w = x" using kp by simp }
   356     ultimately have "w=x" by blast }
   357   thus "(w * y + x * z = w * z + x * y) = (w = x \<or> y = z)" by auto
   358 qed
   359 
   360 declaration {* normalizer_funs' @{thm normalizing_nat.normalizing_semiring_cancel_axioms'} *}
   361 
   362 locale normalizing_field_cancel = normalizing_ring_cancel + normalizing_field
   363 begin
   364 
   365 declare normalizing_field_axioms' [normalizer del]
   366 
   367 lemmas normalizing_field_cancel_axioms' = normalizing_field_cancel_axioms [normalizer
   368   semiring ops: semiring_ops
   369   semiring rules: semiring_rules
   370   ring ops: ring_ops
   371   ring rules: ring_rules
   372   field ops: field_ops
   373   field rules: field_rules
   374   idom rules: noteq_reduce add_scale_eq_noteq
   375   ideal rules: subr0_iff add_r0_iff]
   376 
   377 end
   378 
   379 (*FIXME introduce class*)
   380 interpretation normalizing!: normalizing_field_cancel "op +" "op *" "op ^"
   381   "0::'a::{field,number_ring}" "1" "op -" "uminus" "op /" "inverse"
   382 apply (unfold_locales) by (simp_all add: divide_inverse)
   383 
   384 lemma divide_Numeral1: "(x::'a::{field, number_ring}) / Numeral1 = x" by simp
   385 lemma divide_Numeral0: "(x::'a::{field_inverse_zero, number_ring}) / Numeral0 = 0"
   386   by simp
   387 lemma mult_frac_frac: "((x::'a::field_inverse_zero) / y) * (z / w) = (x*z) / (y*w)"
   388   by simp
   389 lemma mult_frac_num: "((x::'a::field_inverse_zero) / y) * z  = (x*z) / y"
   390   by (fact times_divide_eq_left)
   391 lemma mult_num_frac: "((x::'a::field_inverse_zero) / y) * z  = (x*z) / y"
   392   by (fact times_divide_eq_left)
   393 
   394 lemma Numeral1_eq1_nat: "(1::nat) = Numeral1" by simp
   395 
   396 lemma add_frac_num: "y\<noteq> 0 \<Longrightarrow> (x::'a::field_inverse_zero) / y + z = (x + z*y) / y"
   397   by (simp add: add_divide_distrib)
   398 lemma add_num_frac: "y\<noteq> 0 \<Longrightarrow> z + (x::'a::field_inverse_zero) / y = (x + z*y) / y"
   399   by (simp add: add_divide_distrib)
   400 
   401 ML {* 
   402 local
   403  val zr = @{cpat "0"}
   404  val zT = ctyp_of_term zr
   405  val geq = @{cpat "op ="}
   406  val eqT = Thm.dest_ctyp (ctyp_of_term geq) |> hd
   407  val add_frac_eq = mk_meta_eq @{thm "add_frac_eq"}
   408  val add_frac_num = mk_meta_eq @{thm "add_frac_num"}
   409  val add_num_frac = mk_meta_eq @{thm "add_num_frac"}
   410 
   411  fun prove_nz ss T t =
   412     let
   413       val z = instantiate_cterm ([(zT,T)],[]) zr
   414       val eq = instantiate_cterm ([(eqT,T)],[]) geq
   415       val th = Simplifier.rewrite (ss addsimps @{thms simp_thms})
   416            (Thm.capply @{cterm "Trueprop"} (Thm.capply @{cterm "Not"}
   417                   (Thm.capply (Thm.capply eq t) z)))
   418     in equal_elim (symmetric th) TrueI
   419     end
   420 
   421  fun proc phi ss ct =
   422   let
   423     val ((x,y),(w,z)) =
   424          (Thm.dest_binop #> (fn (a,b) => (Thm.dest_binop a, Thm.dest_binop b))) ct
   425     val _ = map (HOLogic.dest_number o term_of) [x,y,z,w]
   426     val T = ctyp_of_term x
   427     val [y_nz, z_nz] = map (prove_nz ss T) [y, z]
   428     val th = instantiate' [SOME T] (map SOME [y,z,x,w]) add_frac_eq
   429   in SOME (implies_elim (implies_elim th y_nz) z_nz)
   430   end
   431   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   432 
   433  fun proc2 phi ss ct =
   434   let
   435     val (l,r) = Thm.dest_binop ct
   436     val T = ctyp_of_term l
   437   in (case (term_of l, term_of r) of
   438       (Const(@{const_name Rings.divide},_)$_$_, _) =>
   439         let val (x,y) = Thm.dest_binop l val z = r
   440             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   441             val ynz = prove_nz ss T y
   442         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,x,z]) add_frac_num) ynz)
   443         end
   444      | (_, Const (@{const_name Rings.divide},_)$_$_) =>
   445         let val (x,y) = Thm.dest_binop r val z = l
   446             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   447             val ynz = prove_nz ss T y
   448         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,z,x]) add_num_frac) ynz)
   449         end
   450      | _ => NONE)
   451   end
   452   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   453 
   454  fun is_number (Const(@{const_name Rings.divide},_)$a$b) = is_number a andalso is_number b
   455    | is_number t = can HOLogic.dest_number t
   456 
   457  val is_number = is_number o term_of
   458 
   459  fun proc3 phi ss ct =
   460   (case term_of ct of
   461     Const(@{const_name Orderings.less},_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   462       let
   463         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   464         val _ = map is_number [a,b,c]
   465         val T = ctyp_of_term c
   466         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_less_eq"}
   467       in SOME (mk_meta_eq th) end
   468   | Const(@{const_name Orderings.less_eq},_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   469       let
   470         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   471         val _ = map is_number [a,b,c]
   472         val T = ctyp_of_term c
   473         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_le_eq"}
   474       in SOME (mk_meta_eq th) end
   475   | Const("op =",_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   476       let
   477         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   478         val _ = map is_number [a,b,c]
   479         val T = ctyp_of_term c
   480         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_eq_eq"}
   481       in SOME (mk_meta_eq th) end
   482   | Const(@{const_name Orderings.less},_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   483     let
   484       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   485         val _ = map is_number [a,b,c]
   486         val T = ctyp_of_term c
   487         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "less_divide_eq"}
   488       in SOME (mk_meta_eq th) end
   489   | Const(@{const_name Orderings.less_eq},_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   490     let
   491       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   492         val _ = map is_number [a,b,c]
   493         val T = ctyp_of_term c
   494         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "le_divide_eq"}
   495       in SOME (mk_meta_eq th) end
   496   | Const("op =",_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   497     let
   498       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   499         val _ = map is_number [a,b,c]
   500         val T = ctyp_of_term c
   501         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "eq_divide_eq"}
   502       in SOME (mk_meta_eq th) end
   503   | _ => NONE)
   504   handle TERM _ => NONE | CTERM _ => NONE | THM _ => NONE
   505 
   506 val add_frac_frac_simproc =
   507        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + (?w::?'a::field)/?z"}],
   508                      name = "add_frac_frac_simproc",
   509                      proc = proc, identifier = []}
   510 
   511 val add_frac_num_simproc =
   512        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + ?z"}, @{cpat "?z + (?x::?'a::field)/?y"}],
   513                      name = "add_frac_num_simproc",
   514                      proc = proc2, identifier = []}
   515 
   516 val ord_frac_simproc =
   517   make_simproc
   518     {lhss = [@{cpat "(?a::(?'a::{field, ord}))/?b < ?c"},
   519              @{cpat "(?a::(?'a::{field, ord}))/?b \<le> ?c"},
   520              @{cpat "?c < (?a::(?'a::{field, ord}))/?b"},
   521              @{cpat "?c \<le> (?a::(?'a::{field, ord}))/?b"},
   522              @{cpat "?c = ((?a::(?'a::{field, ord}))/?b)"},
   523              @{cpat "((?a::(?'a::{field, ord}))/ ?b) = ?c"}],
   524              name = "ord_frac_simproc", proc = proc3, identifier = []}
   525 
   526 val ths = [@{thm "mult_numeral_1"}, @{thm "mult_numeral_1_right"},
   527            @{thm "divide_Numeral1"},
   528            @{thm "divide_zero"}, @{thm "divide_Numeral0"},
   529            @{thm "divide_divide_eq_left"}, @{thm "mult_frac_frac"},
   530            @{thm "mult_num_frac"}, @{thm "mult_frac_num"},
   531            @{thm "mult_frac_frac"}, @{thm "times_divide_eq_right"},
   532            @{thm "times_divide_eq_left"}, @{thm "divide_divide_eq_right"},
   533            @{thm "diff_def"}, @{thm "minus_divide_left"},
   534            @{thm "Numeral1_eq1_nat"}, @{thm "add_divide_distrib"} RS sym,
   535            @{thm field_divide_inverse} RS sym, @{thm inverse_divide}, 
   536            Conv.fconv_rule (Conv.arg_conv (Conv.arg1_conv (Conv.rewr_conv (mk_meta_eq @{thm mult_commute}))))   
   537            (@{thm field_divide_inverse} RS sym)]
   538 
   539 in
   540 
   541 val field_comp_conv = (Simplifier.rewrite
   542 (HOL_basic_ss addsimps @{thms "semiring_norm"}
   543               addsimps ths addsimps @{thms simp_thms}
   544               addsimprocs Numeral_Simprocs.field_cancel_numeral_factors
   545                addsimprocs [add_frac_frac_simproc, add_frac_num_simproc,
   546                             ord_frac_simproc]
   547                 addcongs [@{thm "if_weak_cong"}]))
   548 then_conv (Simplifier.rewrite (HOL_basic_ss addsimps
   549   [@{thm numeral_1_eq_1},@{thm numeral_0_eq_0}] @ @{thms numerals(1-2)}))
   550 
   551 end
   552 *}
   553 
   554 declaration {*
   555 let
   556 
   557 fun numeral_is_const ct =
   558   case term_of ct of
   559    Const (@{const_name Rings.divide},_) $ a $ b =>
   560      can HOLogic.dest_number a andalso can HOLogic.dest_number b
   561  | Const (@{const_name Rings.inverse},_)$t => can HOLogic.dest_number t
   562  | t => can HOLogic.dest_number t
   563 
   564 fun dest_const ct = ((case term_of ct of
   565    Const (@{const_name Rings.divide},_) $ a $ b=>
   566     Rat.rat_of_quotient (snd (HOLogic.dest_number a), snd (HOLogic.dest_number b))
   567  | Const (@{const_name Rings.inverse},_)$t => 
   568                Rat.inv (Rat.rat_of_int (snd (HOLogic.dest_number t)))
   569  | t => Rat.rat_of_int (snd (HOLogic.dest_number t))) 
   570    handle TERM _ => error "ring_dest_const")
   571 
   572 fun mk_const phi cT x =
   573  let val (a, b) = Rat.quotient_of_rat x
   574  in if b = 1 then Numeral.mk_cnumber cT a
   575     else Thm.capply
   576          (Thm.capply (Drule.cterm_rule (instantiate' [SOME cT] []) @{cpat "op /"})
   577                      (Numeral.mk_cnumber cT a))
   578          (Numeral.mk_cnumber cT b)
   579   end
   580 
   581 in
   582  
   583   Normalizer.funs @{thm normalizing.normalizing_field_cancel_axioms'}
   584    {is_const = K numeral_is_const,
   585     dest_const = K dest_const,
   586     mk_const = mk_const,
   587     conv = K (K field_comp_conv)}
   588 
   589 end
   590 *}
   591 
   592 
   593 subsection {* Groebner Bases *}
   594 
   595 lemmas bool_simps = simp_thms(1-34)
   596 
   597 lemma dnf:
   598     "(P & (Q | R)) = ((P&Q) | (P&R))" "((Q | R) & P) = ((Q&P) | (R&P))"
   599     "(P \<and> Q) = (Q \<and> P)" "(P \<or> Q) = (Q \<or> P)"
   600   by blast+
   601 
   602 lemmas weak_dnf_simps = dnf bool_simps
   603 
   604 lemma nnf_simps:
   605     "(\<not>(P \<and> Q)) = (\<not>P \<or> \<not>Q)" "(\<not>(P \<or> Q)) = (\<not>P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
   606     "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not> \<not>(P)) = P"
   607   by blast+
   608 
   609 lemma PFalse:
   610     "P \<equiv> False \<Longrightarrow> \<not> P"
   611     "\<not> P \<Longrightarrow> (P \<equiv> False)"
   612   by auto
   613 
   614 ML {*
   615 structure Algebra_Simplification = Named_Thms(
   616   val name = "algebra"
   617   val description = "pre-simplification rules for algebraic methods"
   618 )
   619 *}
   620 
   621 setup Algebra_Simplification.setup
   622 
   623 declare dvd_def[algebra]
   624 declare dvd_eq_mod_eq_0[symmetric, algebra]
   625 declare mod_div_trivial[algebra]
   626 declare mod_mod_trivial[algebra]
   627 declare conjunct1[OF DIVISION_BY_ZERO, algebra]
   628 declare conjunct2[OF DIVISION_BY_ZERO, algebra]
   629 declare zmod_zdiv_equality[symmetric,algebra]
   630 declare zdiv_zmod_equality[symmetric, algebra]
   631 declare zdiv_zminus_zminus[algebra]
   632 declare zmod_zminus_zminus[algebra]
   633 declare zdiv_zminus2[algebra]
   634 declare zmod_zminus2[algebra]
   635 declare zdiv_zero[algebra]
   636 declare zmod_zero[algebra]
   637 declare mod_by_1[algebra]
   638 declare div_by_1[algebra]
   639 declare zmod_minus1_right[algebra]
   640 declare zdiv_minus1_right[algebra]
   641 declare mod_div_trivial[algebra]
   642 declare mod_mod_trivial[algebra]
   643 declare mod_mult_self2_is_0[algebra]
   644 declare mod_mult_self1_is_0[algebra]
   645 declare zmod_eq_0_iff[algebra]
   646 declare dvd_0_left_iff[algebra]
   647 declare zdvd1_eq[algebra]
   648 declare zmod_eq_dvd_iff[algebra]
   649 declare nat_mod_eq_iff[algebra]
   650 
   651 use "Tools/Groebner_Basis/groebner.ML"
   652 
   653 method_setup algebra =
   654 {*
   655 let
   656  fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   657  val addN = "add"
   658  val delN = "del"
   659  val any_keyword = keyword addN || keyword delN
   660  val thms = Scan.repeat (Scan.unless any_keyword Attrib.multi_thm) >> flat;
   661 in
   662   ((Scan.optional (keyword addN |-- thms) []) -- 
   663    (Scan.optional (keyword delN |-- thms) [])) >>
   664   (fn (add_ths, del_ths) => fn ctxt =>
   665        SIMPLE_METHOD' (Groebner.algebra_tac add_ths del_ths ctxt))
   666 end
   667 *} "solve polynomial equations over (semi)rings and ideal membership problems using Groebner bases"
   668 
   669 end