src/Pure/pattern.ML
author berghofe
Fri Apr 04 17:00:25 2003 +0200 (2003-04-04)
changeset 13891 ae9a2a433388
parent 13645 430310b12c5b
child 13998 75a399c2781f
permissions -rw-r--r--
type_of_G now applies type substitution before decomposing type.
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 
     6 Unification of Higher-Order Patterns.
     7 
     8 See also:
     9 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
    10 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    11 
    12 TODO: optimize red by special-casing it
    13 *)
    14 
    15 infix aeconv;
    16 
    17 signature PATTERN =
    18   sig
    19   type type_sig
    20   type sg
    21   type env
    22   val trace_unify_fail  : bool ref
    23   val aeconv            : term * term -> bool
    24   val eta_contract      : term -> term
    25   val beta_eta_contract : term -> term
    26   val eta_contract_atom : term -> term
    27   val match             : type_sig -> term * term
    28                           -> (indexname*typ)list * (indexname*term)list
    29   val first_order_match : type_sig -> term * term
    30                           -> (indexname*typ)list * (indexname*term)list
    31   val matches           : type_sig -> term * term -> bool
    32   val matches_subterm   : type_sig -> term * term -> bool
    33   val unify             : sg * env * (term * term)list -> env
    34   val first_order       : term -> bool
    35   val pattern           : term -> bool
    36   val rewrite_term      : type_sig -> (term * term) list -> (term -> term option) list
    37                           -> term -> term
    38   exception Unif
    39   exception MATCH
    40   exception Pattern
    41   end;
    42 
    43 structure Pattern : PATTERN =
    44 struct
    45 
    46 type type_sig = Type.type_sig
    47 type sg = Sign.sg
    48 type env = Envir.env
    49 
    50 exception Unif;
    51 exception Pattern;
    52 
    53 val trace_unify_fail = ref false;
    54 
    55 (* Only for communication between unification and error message printing *)
    56 val sgr = ref Sign.pre_pure
    57 
    58 fun string_of_term env binders t = Sign.string_of_term (!sgr)
    59   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    60 
    61 fun bname binders i = fst(nth_elem(i,binders));
    62 fun bnames binders is = space_implode " " (map (bname binders) is);
    63 
    64 fun typ_clash(tye,T,U) =
    65   if !trace_unify_fail
    66   then let val t = Sign.string_of_typ (!sgr) (Envir.norm_type tye T)
    67            and u = Sign.string_of_typ (!sgr) (Envir.norm_type tye U)
    68        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    69   else ()
    70 
    71 fun clash a b =
    72   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    73 
    74 fun boundVar binders i =
    75   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    76 
    77 fun clashBB binders i j =
    78   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    79   else ()
    80 
    81 fun clashB binders i s =
    82   if !trace_unify_fail then clash (boundVar binders i) s
    83   else ()
    84 
    85 fun proj_fail(env,binders,F,is,t) =
    86   if !trace_unify_fail
    87   then let val f = Syntax.string_of_vname F
    88            val xs = bnames binders is
    89            val u = string_of_term env binders t
    90            val ys = bnames binders (loose_bnos t \\ is)
    91        in tracing("Cannot unify variable " ^ f ^
    92                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    93                "\nTerm contains additional bound variable(s) " ^ ys)
    94        end
    95   else ()
    96 
    97 fun ocheck_fail(F,t,binders,env) =
    98   if !trace_unify_fail
    99   then let val f = Syntax.string_of_vname F
   100            val u = string_of_term env binders t
   101        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
   102                   "\nCannot unify!\n")
   103        end
   104   else ()
   105 
   106 fun occurs(F,t,env) =
   107     let fun occ(Var(G,_))   = (case Envir.lookup(env,G) of
   108                                  Some(t) => occ t
   109                                | None    => F=G)
   110           | occ(t1$t2)      = occ t1 orelse occ t2
   111           | occ(Abs(_,_,t)) = occ t
   112           | occ _           = false
   113     in occ t end;
   114 
   115 
   116 fun mapbnd f =
   117     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   118           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   119           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   120           | mpb _ atom           = atom
   121     in mpb 0 end;
   122 
   123 fun idx [] j     = ~10000
   124   | idx(i::is) j = if i=j then length is else idx is j;
   125 
   126 fun at xs i = nth_elem (i,xs);
   127 
   128 fun mkabs (binders,is,t)  =
   129     let fun mk(i::is) = let val (x,T) = nth_elem(i,binders)
   130                         in Abs(x,T,mk is) end
   131           | mk []     = t
   132     in mk is end;
   133 
   134 val incr = mapbnd (fn i => i+1);
   135 
   136 fun ints_of []             = []
   137   | ints_of (Bound i ::bs) =
   138       let val is = ints_of bs
   139       in if i mem_int is then raise Pattern else i::is end
   140   | ints_of _              = raise Pattern;
   141 
   142 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   143 
   144 
   145 fun app (s,(i::is)) = app (s$Bound(i),is)
   146   | app (s,[])      = s;
   147 
   148 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   149   | red t            []      [] = t
   150   | red t            is      jn = app (mapbnd (at jn) t,is);
   151 
   152 
   153 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   154 fun split_type (T,0,Ts)                    = (Ts,T)
   155   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   156   | split_type _                           = error("split_type");
   157 
   158 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   159   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   160   in map (at Ts) is ---> U end;
   161 
   162 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   163 
   164 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   165   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   166   in Envir.update((F,mkhnf(binders,is,G,js)),env') end;
   167 
   168 
   169 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   170 fun mk_proj_list is =
   171     let fun mk(i::is,j) = if i >= 0 then j :: mk(is,j-1) else mk(is,j-1)
   172           | mk([],_)    = []
   173     in mk(is,length is - 1) end;
   174 
   175 fun proj(s,env,binders,is) =
   176     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   177         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   178               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   179                             in (Abs(a,T,t'),env') end
   180             | t => (case strip_comb t of
   181                 (c as Const _,ts) =>
   182                          let val (ts',env') = prs(ts,env,d,binders)
   183                          in (list_comb(c,ts'),env') end
   184                  | (f as Free _,ts) =>
   185                          let val (ts',env') = prs(ts,env,d,binders)
   186                          in (list_comb(f,ts'),env') end
   187                  | (Bound(i),ts) =>
   188                          let val j = trans d i
   189                          in if j < 0 then raise Unif
   190                             else let val (ts',env') = prs(ts,env,d,binders)
   191                                  in (list_comb(Bound j,ts'),env') end
   192                          end
   193                  | (Var(F as (a,_),Fty),ts) =>
   194                       let val js = ints_of' env ts;
   195                           val js' = map (trans d) js;
   196                           val ks = mk_proj_list js';
   197                           val ls = filter (fn i => i >= 0) js'
   198                           val Hty = type_of_G env (Fty,length js,ks)
   199                           val (env',H) = Envir.genvar a (env,Hty)
   200                           val env'' =
   201                                 Envir.update((F,mkhnf(binders,js,H,ks)),env')
   202                       in (app(H,ls),env'') end
   203                  | _  => raise Pattern))
   204         and prs(s::ss,env,d,binders) =
   205               let val (s',env1) = pr(s,env,d,binders)
   206                   val (ss',env2) = prs(ss,env1,d,binders)
   207               in (s'::ss',env2) end
   208           | prs([],env,_,_) = ([],env)
   209    in if downto0(is,length binders - 1) then (s,env)
   210       else pr(s,env,0,binders)
   211    end;
   212 
   213 
   214 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   215 fun mk_ff_list(is,js) =
   216     let fun mk([],[],_)        = []
   217           | mk(i::is,j::js, k) = if i=j then k :: mk(is,js,k-1)
   218                                         else mk(is,js,k-1)
   219           | mk _               = error"mk_ff_list"
   220     in mk(is,js,length is-1) end;
   221 
   222 fun flexflex1(env,binders,F,Fty,is,js) =
   223   if is=js then env
   224   else let val ks = mk_ff_list(is,js)
   225        in mknewhnf(env,binders,is,F,Fty,ks) end;
   226 
   227 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   228   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   229             if js subset_int is
   230             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   231                  in Envir.update((F,t),env) end
   232             else let val ks = is inter_int js
   233                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   234                      val (env',H) = Envir.genvar a (env,Hty)
   235                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   236                  in Envir.update((G,lam js), Envir.update((F,lam is),env'))
   237                  end;
   238   in if xless(G,F) then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   239 
   240 val tsgr = ref(Type.tsig0);
   241 
   242 fun unify_types(T,U, env as Envir.Envir{asol,iTs,maxidx}) =
   243   if T=U then env
   244   else let val (iTs',maxidx') = Type.unify (!tsgr) (iTs, maxidx) (U, T)
   245        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   246        handle Type.TUNIFY => (typ_clash(iTs,T,U); raise Unif);
   247 
   248 fun unif binders (env,(s,t)) = case (Envir.head_norm env s, Envir.head_norm env t) of
   249       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   250          let val name = if ns = "" then nt else ns
   251          in unif ((name,Ts)::binders) (env,(ts,tt)) end
   252     | (Abs(ns,Ts,ts),t) => unif ((ns,Ts)::binders) (env,(ts,(incr t)$Bound(0)))
   253     | (t,Abs(nt,Tt,tt)) => unif ((nt,Tt)::binders) (env,((incr t)$Bound(0),tt))
   254     | p => cases(binders,env,p)
   255 
   256 and cases(binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   257        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   258          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   259                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   260       | ((Var(F,_),ss),_)             => flexrigid(env,binders,F,ints_of' env ss,t)
   261       | (_,(Var(F,_),ts))             => flexrigid(env,binders,F,ints_of' env ts,s)
   262       | ((Const c,ss),(Const d,ts))   => rigidrigid(env,binders,c,d,ss,ts)
   263       | ((Free(f),ss),(Free(g),ts))   => rigidrigid(env,binders,f,g,ss,ts)
   264       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB (env,binders,i,j,ss,ts)
   265       | ((Abs(_),_),_)                => raise Pattern
   266       | (_,(Abs(_),_))                => raise Pattern
   267       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   268       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   269       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   270       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   271       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   272       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   273 
   274 
   275 and rigidrigid (env,binders,(a,Ta),(b,Tb),ss,ts) =
   276       if a<>b then (clash a b; raise Unif)
   277       else foldl (unif binders) (unify_types(Ta,Tb,env), ss~~ts)
   278 
   279 and rigidrigidB (env,binders,i,j,ss,ts) =
   280      if i <> j then (clashBB binders i j; raise Unif)
   281      else foldl (unif binders) (env ,ss~~ts)
   282 
   283 and flexrigid (params as (env,binders,F,is,t)) =
   284       if occurs(F,t,env) then (ocheck_fail(F,t,binders,env); raise Unif)
   285       else (let val (u,env') = proj(t,env,binders,is)
   286             in Envir.update((F,mkabs(binders,is,u)),env') end
   287             handle Unif => (proj_fail params; raise Unif));
   288 
   289 fun unify(sg,env,tus) = (sgr := sg; tsgr := #tsig(Sign.rep_sg sg);
   290                          foldl (unif []) (env,tus));
   291 
   292 
   293 (*Eta-contract a term (fully)*)
   294 
   295 fun eta_contract t =
   296   let
   297     exception SAME;
   298     fun eta (Abs (a, T, body)) = 
   299       ((case eta body of
   300           body' as (f $ Bound 0) => 
   301 	    if loose_bvar1 (f, 0) then Abs(a, T, body')
   302 	    else incr_boundvars ~1 f
   303         | body' => Abs (a, T, body')) handle SAME =>
   304        (case body of
   305           (f $ Bound 0) => 
   306 	    if loose_bvar1 (f, 0) then raise SAME
   307 	    else incr_boundvars ~1 f
   308         | _ => raise SAME))
   309       | eta (f $ t) =
   310           (let val f' = eta f
   311            in f' $ etah t end handle SAME => f $ eta t)
   312       | eta _ = raise SAME
   313     and etah t = (eta t handle SAME => t)
   314   in etah t end;
   315 
   316 val beta_eta_contract = eta_contract o Envir.beta_norm;
   317 
   318 (*Eta-contract a term from outside: just enough to reduce it to an atom
   319 DOESN'T QUITE WORK!
   320 *)
   321 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   322       (case  eta_contract2 body  of
   323         body' as (f $ Bound 0) =>
   324             if loose_bvar1(f,0) then Abs(a,T,body')
   325             else eta_contract_atom (incr_boundvars ~1 f)
   326       | _ => t0)
   327   | eta_contract_atom t = t
   328 and eta_contract2 (f$t) = f $ eta_contract_atom t
   329   | eta_contract2 t     = eta_contract_atom t;
   330 
   331 
   332 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   333   Note that Consts and Vars may have more than one type.*)
   334 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   335 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   336   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   337   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   338   | aconv_aux (Bound i,    Bound j)    = i=j
   339   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   340   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   341   | aconv_aux _ =  false;
   342 
   343 
   344 (*** Matching ***)
   345 
   346 exception MATCH;
   347 
   348 fun typ_match tsig args = (Type.typ_match tsig args)
   349                           handle Type.TYPE_MATCH => raise MATCH;
   350 
   351 (*First-order matching;
   352   fomatch tsig (pattern, object) returns a (tyvar,typ)list and (var,term)list.
   353   The pattern and object may have variables in common.
   354   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   355   Object is eta-contracted on the fly (by eta-expanding the pattern).
   356   Precondition: the pattern is already eta-contracted!
   357   Note: types are matched on the fly *)
   358 fun fomatch tsig =
   359   let
   360     fun mtch (instsp as (tyinsts,insts)) = fn
   361         (Var(ixn,T), t)  =>
   362           if loose_bvar(t,0) then raise MATCH
   363           else (case assoc_string_int(insts,ixn) of
   364                   None => (typ_match tsig (tyinsts, (T, fastype_of t)),
   365                            (ixn,t)::insts)
   366                 | Some u => if t aeconv u then instsp else raise MATCH)
   367       | (Free (a,T), Free (b,U)) =>
   368           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   369       | (Const (a,T), Const (b,U))  =>
   370           if a=b then (typ_match tsig (tyinsts,(T,U)), insts) else raise MATCH
   371       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   372       | (Abs(_,T,t), Abs(_,U,u))  =>
   373           mtch (typ_match tsig (tyinsts,(T,U)),insts) (t,u)
   374       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   375       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   376       | _ => raise MATCH
   377   in mtch end;
   378 
   379 fun first_order_match tsig = apfst Vartab.dest o fomatch tsig (Vartab.empty, []);
   380 
   381 (* Matching of higher-order patterns *)
   382 
   383 fun match_bind(itms,binders,ixn,is,t) =
   384   let val js = loose_bnos t
   385   in if null is
   386      then if null js then (ixn,t)::itms else raise MATCH
   387      else if js subset_int is
   388           then let val t' = if downto0(is,length binders - 1) then t
   389                             else mapbnd (idx is) t
   390                in (ixn, mkabs(binders,is,t')) :: itms end
   391           else raise MATCH
   392   end;
   393 
   394 fun match tsg (po as (pat,obj)) =
   395 let
   396   (* Pre: pat and obj have same type *)
   397   fun mtch binders (env as (iTs,itms),(pat,obj)) =
   398     case pat of
   399       Abs(ns,Ts,ts) =>
   400         (case obj of
   401            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (env,(ts,tt))
   402          | _ => let val Tt = typ_subst_TVars_Vartab iTs Ts
   403                 in mtch((ns,Tt)::binders)(env,(ts,(incr obj)$Bound(0))) end)
   404     | _ => (case obj of
   405               Abs(nt,Tt,tt) =>
   406                 mtch((nt,Tt)::binders)(env,((incr pat)$Bound(0),tt))
   407             | _ => cases(binders,env,pat,obj))
   408 
   409   and cases(binders,env as (iTs,itms),pat,obj) =
   410     let val (ph,pargs) = strip_comb pat
   411         fun rigrig1(iTs,oargs) =
   412               foldl (mtch binders) ((iTs,itms), pargs~~oargs)
   413         fun rigrig2((a,Ta),(b,Tb),oargs) =
   414               if a<> b then raise MATCH
   415               else rigrig1(typ_match tsg (iTs,(Ta,Tb)), oargs)
   416     in case ph of
   417          Var(ixn,_) =>
   418            let val is = ints_of pargs
   419            in case assoc_string_int(itms,ixn) of
   420                 None => (iTs,match_bind(itms,binders,ixn,is,obj))
   421               | Some u => if obj aeconv (red u is []) then env
   422                           else raise MATCH
   423            end
   424        | _ =>
   425            let val (oh,oargs) = strip_comb obj
   426            in case (ph,oh) of
   427                 (Const c,Const d) => rigrig2(c,d,oargs)
   428               | (Free f,Free g)   => rigrig2(f,g,oargs)
   429               | (Bound i,Bound j) => if i<>j then raise MATCH
   430                                      else rigrig1(iTs,oargs)
   431               | (Abs _, _)        => raise Pattern
   432               | (_, Abs _)        => raise Pattern
   433               | _                 => raise MATCH
   434            end
   435     end;
   436 
   437   val pT = fastype_of pat
   438   and oT = fastype_of obj
   439   val iTs = typ_match tsg (Vartab.empty, (pT,oT))
   440   val insts2 = (iTs,[])
   441 
   442 in apfst Vartab.dest (mtch [] (insts2, po)
   443    handle Pattern => fomatch tsg insts2 po)
   444 end;
   445 
   446 (*Predicate: does the pattern match the object?*)
   447 fun matches tsig po = (match tsig po; true) handle MATCH => false;
   448 
   449 (* Does pat match a subterm of obj? *)
   450 fun matches_subterm tsig (pat,obj) =
   451   let fun msub(bounds,obj) = matches tsig (pat,obj) orelse
   452             case obj of
   453               Abs(x,T,t) => let val y = variant bounds x
   454                                 val f = Free(":" ^ y,T)
   455                             in msub(x::bounds,subst_bound(f,t)) end
   456             | s$t => msub(bounds,s) orelse msub(bounds,t)
   457             | _ => false
   458   in msub([],obj) end;
   459 
   460 fun first_order(Abs(_,_,t)) = first_order t
   461   | first_order(t $ u) = first_order t andalso first_order u andalso
   462                          not(is_Var t)
   463   | first_order _ = true;
   464 
   465 fun pattern(Abs(_,_,t)) = pattern t
   466   | pattern(t) = let val (head,args) = strip_comb t
   467                  in if is_Var head
   468                     then let val _ = ints_of args in true end
   469                          handle Pattern => false
   470                     else forall pattern args
   471                  end;
   472 
   473 
   474 (* rewriting -- simple but fast *)
   475 
   476 fun rewrite_term tsig rules procs tm =
   477   let
   478     val skel0 = Bound 0;
   479 
   480     val rhs_names =
   481       foldr (fn ((_, rhs), names) => add_term_free_names (rhs, names)) (rules, []);
   482 
   483     fun variant_absfree (x, T, t) =
   484       let
   485         val x' = variant (add_term_free_names (t, rhs_names)) x;
   486         val t' = subst_bound (Free (x', T), t);
   487       in (fn u => Abs (x, T, abstract_over (Free (x', T), u)), t') end;
   488 
   489     fun match_rew tm (tm1, tm2) =
   490       let val rtm = if_none (Term.rename_abs tm1 tm tm2) tm2
   491       in Some (subst_vars (match tsig (tm1, tm)) rtm, rtm)
   492         handle MATCH => None
   493       end;
   494 
   495     fun rew (Abs (_, _, body) $ t) = Some (subst_bound (t, body), skel0)
   496       | rew tm = (case get_first (match_rew tm) rules of
   497           None => apsome (rpair skel0) (get_first (fn p => p tm) procs)
   498         | x => x);
   499 
   500     fun rew1 (Var _) _ = None
   501       | rew1 skel tm = (case rew2 skel tm of
   502           Some tm1 => (case rew tm1 of
   503               Some (tm2, skel') => Some (if_none (rew1 skel' tm2) tm2)
   504             | None => Some tm1)
   505         | None => (case rew tm of
   506               Some (tm1, skel') => Some (if_none (rew1 skel' tm1) tm1)
   507             | None => None))
   508 
   509     and rew2 skel (tm1 $ tm2) = (case tm1 of
   510             Abs (_, _, body) =>
   511               let val tm' = subst_bound (tm2, body)
   512               in Some (if_none (rew2 skel0 tm') tm') end
   513           | _ => 
   514             let val (skel1, skel2) = (case skel of
   515                 skel1 $ skel2 => (skel1, skel2)
   516               | _ => (skel0, skel0))
   517             in case rew1 skel1 tm1 of
   518                 Some tm1' => (case rew1 skel2 tm2 of
   519                     Some tm2' => Some (tm1' $ tm2')
   520                   | None => Some (tm1' $ tm2))
   521               | None => (case rew1 skel2 tm2 of
   522                     Some tm2' => Some (tm1 $ tm2')
   523                   | None => None)
   524             end)
   525       | rew2 skel (Abs (x, T, tm)) =
   526           let
   527             val (abs, tm') = variant_absfree (x, T, tm);
   528             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   529           in case rew1 skel' tm' of
   530               Some tm'' => Some (abs tm'')
   531             | None => None
   532           end
   533       | rew2 _ _ = None
   534 
   535   in if_none (rew1 skel0 tm) tm end;
   536 
   537 end;
   538 
   539 val trace_unify_fail = Pattern.trace_unify_fail;