src/HOL/Tools/res_hol_clause.ML
author blanchet
Wed Mar 04 11:05:29 2009 +0100 (2009-03-04)
changeset 30242 aea5d7fa7ef5
parent 30240 5b25fee0362c
parent 30190 479806475f3c
child 31409 d8537ba165b5
permissions -rw-r--r--
Merge.
     1 (*
     2    Author: Jia Meng, NICTA
     3 
     4 FOL clauses translated from HOL formulae.
     5 *)
     6 
     7 signature RES_HOL_CLAUSE =
     8 sig
     9   val ext: thm
    10   val comb_I: thm
    11   val comb_K: thm
    12   val comb_B: thm
    13   val comb_C: thm
    14   val comb_S: thm
    15   datatype type_level = T_FULL | T_CONST
    16   val typ_level: type_level
    17   val minimize_applies: bool
    18   type axiom_name = string
    19   type polarity = bool
    20   type clause_id = int
    21   datatype combterm =
    22       CombConst of string * ResClause.fol_type * ResClause.fol_type list (*Const and Free*)
    23     | CombVar of string * ResClause.fol_type
    24     | CombApp of combterm * combterm
    25   datatype literal = Literal of polarity * combterm
    26   val strip_comb: combterm -> combterm * combterm list
    27   val literals_of_term: theory -> term -> literal list * typ list
    28   exception TOO_TRIVIAL
    29   val tptp_write_file: theory -> bool -> thm list -> string ->
    30     (thm * (axiom_name * clause_id)) list * ResClause.classrelClause list *
    31       ResClause.arityClause list -> string list -> axiom_name list
    32   val dfg_write_file: theory -> bool -> thm list -> string ->
    33     (thm * (axiom_name * clause_id)) list * ResClause.classrelClause list *
    34       ResClause.arityClause list -> string list -> axiom_name list
    35 end
    36 
    37 structure ResHolClause: RES_HOL_CLAUSE =
    38 struct
    39 
    40 structure RC = ResClause;
    41 
    42 (* theorems for combinators and function extensionality *)
    43 val ext = thm "HOL.ext";
    44 val comb_I = thm "ATP_Linkup.COMBI_def";
    45 val comb_K = thm "ATP_Linkup.COMBK_def";
    46 val comb_B = thm "ATP_Linkup.COMBB_def";
    47 val comb_C = thm "ATP_Linkup.COMBC_def";
    48 val comb_S = thm "ATP_Linkup.COMBS_def";
    49 val fequal_imp_equal = thm "ATP_Linkup.fequal_imp_equal";
    50 val equal_imp_fequal = thm "ATP_Linkup.equal_imp_fequal";
    51 
    52 
    53 (*The different translations of types*)
    54 datatype type_level = T_FULL | T_CONST;
    55 
    56 val typ_level = T_CONST;
    57 
    58 (*If true, each function will be directly applied to as many arguments as possible, avoiding
    59   use of the "apply" operator. Use of hBOOL is also minimized.*)
    60 val minimize_applies = true;
    61 
    62 fun min_arity_of const_min_arity c = getOpt (Symtab.lookup const_min_arity c, 0);
    63 
    64 (*True if the constant ever appears outside of the top-level position in literals.
    65   If false, the constant always receives all of its arguments and is used as a predicate.*)
    66 fun needs_hBOOL const_needs_hBOOL c = not minimize_applies orelse
    67                     getOpt (Symtab.lookup const_needs_hBOOL c, false);
    68 
    69 
    70 (******************************************************)
    71 (* data types for typed combinator expressions        *)
    72 (******************************************************)
    73 
    74 type axiom_name = string;
    75 type polarity = bool;
    76 type clause_id = int;
    77 
    78 datatype combterm = CombConst of string * RC.fol_type * RC.fol_type list (*Const and Free*)
    79                   | CombVar of string * RC.fol_type
    80                   | CombApp of combterm * combterm
    81 
    82 datatype literal = Literal of polarity * combterm;
    83 
    84 datatype clause =
    85          Clause of {clause_id: clause_id,
    86                     axiom_name: axiom_name,
    87                     th: thm,
    88                     kind: RC.kind,
    89                     literals: literal list,
    90                     ctypes_sorts: typ list};
    91 
    92 
    93 (*********************************************************************)
    94 (* convert a clause with type Term.term to a clause with type clause *)
    95 (*********************************************************************)
    96 
    97 fun isFalse (Literal(pol, CombConst(c,_,_))) =
    98       (pol andalso c = "c_False") orelse
    99       (not pol andalso c = "c_True")
   100   | isFalse _ = false;
   101 
   102 fun isTrue (Literal (pol, CombConst(c,_,_))) =
   103       (pol andalso c = "c_True") orelse
   104       (not pol andalso c = "c_False")
   105   | isTrue _ = false;
   106 
   107 fun isTaut (Clause {literals,...}) = exists isTrue literals;
   108 
   109 fun type_of dfg (Type (a, Ts)) =
   110       let val (folTypes,ts) = types_of dfg Ts
   111       in  (RC.Comp(RC.make_fixed_type_const dfg a, folTypes), ts)  end
   112   | type_of dfg (tp as (TFree(a,s))) =
   113       (RC.AtomF (RC.make_fixed_type_var a), [tp])
   114   | type_of dfg (tp as (TVar(v,s))) =
   115       (RC.AtomV (RC.make_schematic_type_var v), [tp])
   116 and types_of dfg Ts =
   117       let val (folTyps,ts) = ListPair.unzip (map (type_of dfg) Ts)
   118       in  (folTyps, RC.union_all ts)  end;
   119 
   120 (* same as above, but no gathering of sort information *)
   121 fun simp_type_of dfg (Type (a, Ts)) =
   122       RC.Comp(RC.make_fixed_type_const dfg a, map (simp_type_of dfg) Ts)
   123   | simp_type_of dfg (TFree (a,s)) = RC.AtomF(RC.make_fixed_type_var a)
   124   | simp_type_of dfg (TVar (v,s)) = RC.AtomV(RC.make_schematic_type_var v);
   125 
   126 
   127 fun const_type_of dfg thy (c,t) =
   128       let val (tp,ts) = type_of dfg t
   129       in  (tp, ts, map (simp_type_of dfg) (Sign.const_typargs thy (c,t))) end;
   130 
   131 (* convert a Term.term (with combinators) into a combterm, also accummulate sort info *)
   132 fun combterm_of dfg thy (Const(c,t)) =
   133       let val (tp,ts,tvar_list) = const_type_of dfg thy (c,t)
   134           val c' = CombConst(RC.make_fixed_const dfg c, tp, tvar_list)
   135       in  (c',ts)  end
   136   | combterm_of dfg thy (Free(v,t)) =
   137       let val (tp,ts) = type_of dfg t
   138           val v' = CombConst(RC.make_fixed_var v, tp, [])
   139       in  (v',ts)  end
   140   | combterm_of dfg thy (Var(v,t)) =
   141       let val (tp,ts) = type_of dfg t
   142           val v' = CombVar(RC.make_schematic_var v,tp)
   143       in  (v',ts)  end
   144   | combterm_of dfg thy (P $ Q) =
   145       let val (P',tsP) = combterm_of dfg thy P
   146           val (Q',tsQ) = combterm_of dfg thy Q
   147       in  (CombApp(P',Q'), tsP union tsQ)  end
   148   | combterm_of _ thy (t as Abs _) = raise RC.CLAUSE("HOL CLAUSE",t);
   149 
   150 fun predicate_of dfg thy ((Const("Not",_) $ P), polarity) = predicate_of dfg thy (P, not polarity)
   151   | predicate_of dfg thy (t,polarity) = (combterm_of dfg thy (Envir.eta_contract t), polarity);
   152 
   153 fun literals_of_term1 dfg thy args (Const("Trueprop",_) $ P) = literals_of_term1 dfg thy args P
   154   | literals_of_term1 dfg thy args (Const("op |",_) $ P $ Q) =
   155       literals_of_term1 dfg thy (literals_of_term1 dfg thy args P) Q
   156   | literals_of_term1 dfg thy (lits,ts) P =
   157       let val ((pred,ts'),pol) = predicate_of dfg thy (P,true)
   158       in
   159           (Literal(pol,pred)::lits, ts union ts')
   160       end;
   161 
   162 fun literals_of_term_dfg dfg thy P = literals_of_term1 dfg thy ([],[]) P;
   163 val literals_of_term = literals_of_term_dfg false;
   164 
   165 (* Problem too trivial for resolution (empty clause) *)
   166 exception TOO_TRIVIAL;
   167 
   168 (* making axiom and conjecture clauses *)
   169 fun make_clause dfg thy (clause_id,axiom_name,kind,th) =
   170     let val (lits,ctypes_sorts) = literals_of_term_dfg dfg thy (prop_of th)
   171     in
   172         if forall isFalse lits
   173         then raise TOO_TRIVIAL
   174         else
   175             Clause {clause_id = clause_id, axiom_name = axiom_name, th = th, kind = kind,
   176                     literals = lits, ctypes_sorts = ctypes_sorts}
   177     end;
   178 
   179 
   180 fun add_axiom_clause dfg thy ((th,(name,id)), pairs) =
   181   let val cls = make_clause dfg thy (id, name, RC.Axiom, th)
   182   in
   183       if isTaut cls then pairs else (name,cls)::pairs
   184   end;
   185 
   186 fun make_axiom_clauses dfg thy = List.foldl (add_axiom_clause dfg thy) [];
   187 
   188 fun make_conjecture_clauses_aux dfg _ _ [] = []
   189   | make_conjecture_clauses_aux dfg thy n (th::ths) =
   190       make_clause dfg thy (n,"conjecture", RC.Conjecture, th) ::
   191       make_conjecture_clauses_aux dfg thy (n+1) ths;
   192 
   193 fun make_conjecture_clauses dfg thy = make_conjecture_clauses_aux dfg thy 0;
   194 
   195 
   196 (**********************************************************************)
   197 (* convert clause into ATP specific formats:                          *)
   198 (* TPTP used by Vampire and E                                         *)
   199 (* DFG used by SPASS                                                  *)
   200 (**********************************************************************)
   201 
   202 (*Result of a function type; no need to check that the argument type matches.*)
   203 fun result_type (RC.Comp ("tc_fun", [_, tp2])) = tp2
   204   | result_type _ = error "result_type"
   205 
   206 fun type_of_combterm (CombConst(c,tp,_)) = tp
   207   | type_of_combterm (CombVar(v,tp)) = tp
   208   | type_of_combterm (CombApp(t1,t2)) = result_type (type_of_combterm t1);
   209 
   210 (*gets the head of a combinator application, along with the list of arguments*)
   211 fun strip_comb u =
   212     let fun stripc (CombApp(t,u), ts) = stripc (t, u::ts)
   213         |   stripc  x =  x
   214     in  stripc(u,[])  end;
   215 
   216 val type_wrapper = "ti";
   217 
   218 fun head_needs_hBOOL const_needs_hBOOL (CombConst(c,_,_)) = needs_hBOOL const_needs_hBOOL c
   219   | head_needs_hBOOL const_needs_hBOOL _ = true;
   220 
   221 fun wrap_type (s, tp) =
   222   if typ_level=T_FULL then
   223       type_wrapper ^ RC.paren_pack [s, RC.string_of_fol_type tp]
   224   else s;
   225 
   226 fun apply ss = "hAPP" ^ RC.paren_pack ss;
   227 
   228 fun rev_apply (v, []) = v
   229   | rev_apply (v, arg::args) = apply [rev_apply (v, args), arg];
   230 
   231 fun string_apply (v, args) = rev_apply (v, rev args);
   232 
   233 (*Apply an operator to the argument strings, using either the "apply" operator or
   234   direct function application.*)
   235 fun string_of_applic cma (CombConst(c,tp,tvars), args) =
   236       let val c = if c = "equal" then "c_fequal" else c
   237           val nargs = min_arity_of cma c
   238           val args1 = List.take(args, nargs)
   239             handle Subscript => error ("string_of_applic: " ^ c ^ " has arity " ^
   240                                          Int.toString nargs ^ " but is applied to " ^
   241                                          space_implode ", " args)
   242           val args2 = List.drop(args, nargs)
   243           val targs = if typ_level = T_CONST then map RC.string_of_fol_type tvars
   244                       else []
   245       in
   246           string_apply (c ^ RC.paren_pack (args1@targs), args2)
   247       end
   248   | string_of_applic cma (CombVar(v,tp), args) = string_apply (v, args)
   249   | string_of_applic _ _ = error "string_of_applic";
   250 
   251 fun wrap_type_if cnh (head, s, tp) = if head_needs_hBOOL cnh head then wrap_type (s, tp) else s;
   252 
   253 fun string_of_combterm cma cnh t =
   254   let val (head, args) = strip_comb t
   255   in  wrap_type_if cnh (head,
   256                     string_of_applic cma (head, map (string_of_combterm cma cnh) args),
   257                     type_of_combterm t)
   258   end;
   259 
   260 (*Boolean-valued terms are here converted to literals.*)
   261 fun boolify cma cnh t = "hBOOL" ^ RC.paren_pack [string_of_combterm cma cnh t];
   262 
   263 fun string_of_predicate cma cnh t =
   264   case t of
   265       (CombApp(CombApp(CombConst("equal",_,_), t1), t2)) =>
   266           (*DFG only: new TPTP prefers infix equality*)
   267           ("equal" ^ RC.paren_pack [string_of_combterm cma cnh t1, string_of_combterm cma cnh t2])
   268     | _ =>
   269           case #1 (strip_comb t) of
   270               CombConst(c,_,_) => if needs_hBOOL cnh c then boolify cma cnh t else string_of_combterm cma cnh t
   271             | _ => boolify cma cnh t;
   272 
   273 fun string_of_clausename (cls_id,ax_name) =
   274     RC.clause_prefix ^ RC.ascii_of ax_name ^ "_" ^ Int.toString cls_id;
   275 
   276 fun string_of_type_clsname (cls_id,ax_name,idx) =
   277     string_of_clausename (cls_id,ax_name) ^ "_tcs" ^ (Int.toString idx);
   278 
   279 
   280 (*** tptp format ***)
   281 
   282 fun tptp_of_equality cma cnh pol (t1,t2) =
   283   let val eqop = if pol then " = " else " != "
   284   in  string_of_combterm cma cnh t1 ^ eqop ^ string_of_combterm cma cnh t2  end;
   285 
   286 fun tptp_literal cma cnh (Literal(pol, CombApp(CombApp(CombConst("equal",_,_), t1), t2))) =
   287       tptp_of_equality cma cnh pol (t1,t2)
   288   | tptp_literal cma cnh (Literal(pol,pred)) =
   289       RC.tptp_sign pol (string_of_predicate cma cnh pred);
   290 
   291 (*Given a clause, returns its literals paired with a list of literals concerning TFrees;
   292   the latter should only occur in conjecture clauses.*)
   293 fun tptp_type_lits cma cnh pos (Clause{literals, ctypes_sorts, ...}) =
   294       (map (tptp_literal cma cnh) literals, 
   295        map (RC.tptp_of_typeLit pos) (RC.add_typs ctypes_sorts));
   296 
   297 fun clause2tptp cma cnh (cls as Clause{axiom_name,clause_id,kind,ctypes_sorts,...}) =
   298   let val (lits,tylits) = tptp_type_lits cma cnh (kind = RC.Conjecture) cls
   299   in
   300       (RC.gen_tptp_cls(clause_id,axiom_name,kind,lits,tylits), tylits)
   301   end;
   302 
   303 
   304 (*** dfg format ***)
   305 
   306 fun dfg_literal cma cnh (Literal(pol,pred)) = RC.dfg_sign pol (string_of_predicate cma cnh pred);
   307 
   308 fun dfg_type_lits cma cnh pos (Clause{literals, ctypes_sorts, ...}) =
   309       (map (dfg_literal cma cnh) literals, 
   310        map (RC.dfg_of_typeLit pos) (RC.add_typs ctypes_sorts));
   311 
   312 fun get_uvars (CombConst _) vars = vars
   313   | get_uvars (CombVar(v,_)) vars = (v::vars)
   314   | get_uvars (CombApp(P,Q)) vars = get_uvars P (get_uvars Q vars);
   315 
   316 fun get_uvars_l (Literal(_,c)) = get_uvars c [];
   317 
   318 fun dfg_vars (Clause {literals,...}) = RC.union_all (map get_uvars_l literals);
   319 
   320 fun clause2dfg cma cnh (cls as Clause{axiom_name,clause_id,kind,ctypes_sorts,...}) =
   321   let val (lits,tylits) = dfg_type_lits cma cnh (kind = RC.Conjecture) cls
   322       val vars = dfg_vars cls
   323       val tvars = RC.get_tvar_strs ctypes_sorts
   324   in
   325       (RC.gen_dfg_cls(clause_id, axiom_name, kind, lits, tylits, tvars@vars), tylits)
   326   end;
   327 
   328 
   329 (** For DFG format: accumulate function and predicate declarations **)
   330 
   331 fun addtypes tvars tab = List.foldl RC.add_foltype_funcs tab tvars;
   332 
   333 fun add_decls cma cnh (CombConst(c,tp,tvars), (funcs,preds)) =
   334       if c = "equal" then (addtypes tvars funcs, preds)
   335       else
   336 	let val arity = min_arity_of cma c
   337 	    val ntys = if typ_level = T_CONST then length tvars else 0
   338 	    val addit = Symtab.update(c, arity+ntys)
   339 	in
   340 	    if needs_hBOOL cnh c then (addtypes tvars (addit funcs), preds)
   341 	    else (addtypes tvars funcs, addit preds)
   342 	end
   343   | add_decls _ _ (CombVar(_,ctp), (funcs,preds)) =
   344       (RC.add_foltype_funcs (ctp,funcs), preds)
   345   | add_decls cma cnh (CombApp(P,Q),decls) = add_decls cma cnh (P,add_decls cma cnh (Q,decls));
   346 
   347 fun add_literal_decls cma cnh (Literal(_,c), decls) = add_decls cma cnh (c,decls);
   348 
   349 fun add_clause_decls cma cnh (Clause {literals, ...}, decls) =
   350     List.foldl (add_literal_decls cma cnh) decls literals
   351     handle Symtab.DUP a => error ("function " ^ a ^ " has multiple arities")
   352 
   353 fun decls_of_clauses cma cnh clauses arity_clauses =
   354   let val init_functab = Symtab.update (type_wrapper,2) (Symtab.update ("hAPP",2) RC.init_functab)
   355       val init_predtab = Symtab.update ("hBOOL",1) Symtab.empty
   356       val (functab,predtab) = (List.foldl (add_clause_decls cma cnh) (init_functab, init_predtab) clauses)
   357   in
   358       (Symtab.dest (List.foldl RC.add_arityClause_funcs functab arity_clauses),
   359        Symtab.dest predtab)
   360   end;
   361 
   362 fun add_clause_preds (Clause {ctypes_sorts, ...}, preds) =
   363   List.foldl RC.add_type_sort_preds preds ctypes_sorts
   364   handle Symtab.DUP a => error ("predicate " ^ a ^ " has multiple arities")
   365 
   366 (*Higher-order clauses have only the predicates hBOOL and type classes.*)
   367 fun preds_of_clauses clauses clsrel_clauses arity_clauses =
   368     Symtab.dest
   369         (List.foldl RC.add_classrelClause_preds
   370                (List.foldl RC.add_arityClause_preds
   371                       (List.foldl add_clause_preds Symtab.empty clauses)
   372                       arity_clauses)
   373                clsrel_clauses)
   374 
   375 
   376 (**********************************************************************)
   377 (* write clauses to files                                             *)
   378 (**********************************************************************)
   379 
   380 val init_counters =
   381     Symtab.make [("c_COMBI", 0), ("c_COMBK", 0),
   382                  ("c_COMBB", 0), ("c_COMBC", 0),
   383                  ("c_COMBS", 0)];
   384 
   385 fun count_combterm (CombConst(c,tp,_), ct) =
   386      (case Symtab.lookup ct c of NONE => ct  (*no counter*)
   387                                | SOME n => Symtab.update (c,n+1) ct)
   388   | count_combterm (CombVar(v,tp), ct) = ct
   389   | count_combterm (CombApp(t1,t2), ct) = count_combterm(t1, count_combterm(t2, ct));
   390 
   391 fun count_literal (Literal(_,t), ct) = count_combterm(t,ct);
   392 
   393 fun count_clause (Clause{literals,...}, ct) = List.foldl count_literal ct literals;
   394 
   395 fun count_user_clause user_lemmas (Clause{axiom_name,literals,...}, ct) =
   396   if axiom_name mem_string user_lemmas then List.foldl count_literal ct literals
   397   else ct;
   398 
   399 fun cnf_helper_thms thy =
   400   ResAxioms.cnf_rules_pairs thy o map ResAxioms.pairname
   401 
   402 fun get_helper_clauses dfg thy isFO (conjectures, axclauses, user_lemmas) =
   403   if isFO then []  (*first-order*)
   404   else
   405     let val ct0 = List.foldl count_clause init_counters conjectures
   406         val ct = List.foldl (count_user_clause user_lemmas) ct0 axclauses
   407         fun needed c = valOf (Symtab.lookup ct c) > 0
   408         val IK = if needed "c_COMBI" orelse needed "c_COMBK"
   409                  then (Output.debug (fn () => "Include combinator I K"); cnf_helper_thms thy [comb_I,comb_K])
   410                  else []
   411         val BC = if needed "c_COMBB" orelse needed "c_COMBC"
   412                  then (Output.debug (fn () => "Include combinator B C"); cnf_helper_thms thy [comb_B,comb_C])
   413                  else []
   414         val S = if needed "c_COMBS"
   415                 then (Output.debug (fn () => "Include combinator S"); cnf_helper_thms thy [comb_S])
   416                 else []
   417         val other = cnf_helper_thms thy [ext,fequal_imp_equal,equal_imp_fequal]
   418     in
   419         map #2 (make_axiom_clauses dfg thy (other @ IK @ BC @ S))
   420     end;
   421 
   422 (*Find the minimal arity of each function mentioned in the term. Also, note which uses
   423   are not at top level, to see if hBOOL is needed.*)
   424 fun count_constants_term toplev t (const_min_arity, const_needs_hBOOL) =
   425   let val (head, args) = strip_comb t
   426       val n = length args
   427       val (const_min_arity, const_needs_hBOOL) = fold (count_constants_term false) args (const_min_arity, const_needs_hBOOL)
   428   in
   429       case head of
   430           CombConst (a,_,_) => (*predicate or function version of "equal"?*)
   431             let val a = if a="equal" andalso not toplev then "c_fequal" else a
   432             val const_min_arity = Symtab.map_default (a,n) (curry Int.min n) const_min_arity
   433             in
   434               if toplev then (const_min_arity, const_needs_hBOOL)
   435               else (const_min_arity, Symtab.update (a,true) (const_needs_hBOOL))
   436             end
   437         | ts => (const_min_arity, const_needs_hBOOL)
   438   end;
   439 
   440 (*A literal is a top-level term*)
   441 fun count_constants_lit (Literal (_,t)) (const_min_arity, const_needs_hBOOL) =
   442   count_constants_term true t (const_min_arity, const_needs_hBOOL);
   443 
   444 fun count_constants_clause (Clause{literals,...}) (const_min_arity, const_needs_hBOOL) =
   445   fold count_constants_lit literals (const_min_arity, const_needs_hBOOL);
   446 
   447 fun display_arity const_needs_hBOOL (c,n) =
   448   Output.debug (fn () => "Constant: " ^ c ^ " arity:\t" ^ Int.toString n ^
   449                 (if needs_hBOOL const_needs_hBOOL c then " needs hBOOL" else ""));
   450 
   451 fun count_constants (conjectures, axclauses, helper_clauses) =
   452   if minimize_applies then
   453      let val (const_min_arity, const_needs_hBOOL) =
   454           fold count_constants_clause conjectures (Symtab.empty, Symtab.empty)
   455        |> fold count_constants_clause axclauses
   456        |> fold count_constants_clause helper_clauses
   457      val _ = List.app (display_arity const_needs_hBOOL) (Symtab.dest (const_min_arity))
   458      in (const_min_arity, const_needs_hBOOL) end
   459   else (Symtab.empty, Symtab.empty);
   460 
   461 (* tptp format *)
   462 
   463 (* write TPTP format to a single file *)
   464 fun tptp_write_file thy isFO thms filename (ax_tuples,classrel_clauses,arity_clauses) user_lemmas =
   465     let val _ = Output.debug (fn () => ("Preparing to write the TPTP file " ^ filename))
   466         val conjectures = make_conjecture_clauses false thy thms
   467         val (clnames,axclauses) = ListPair.unzip (make_axiom_clauses false thy ax_tuples)
   468         val helper_clauses = get_helper_clauses false thy isFO (conjectures, axclauses, user_lemmas)
   469         val (const_min_arity, const_needs_hBOOL) = count_constants (conjectures, axclauses, helper_clauses);
   470         val (tptp_clss,tfree_litss) = ListPair.unzip (map (clause2tptp const_min_arity const_needs_hBOOL) conjectures)
   471         val tfree_clss = map RC.tptp_tfree_clause (List.foldl (op union_string) [] tfree_litss)
   472         val out = TextIO.openOut filename
   473     in
   474         List.app (curry TextIO.output out o #1 o (clause2tptp const_min_arity const_needs_hBOOL)) axclauses;
   475         RC.writeln_strs out tfree_clss;
   476         RC.writeln_strs out tptp_clss;
   477         List.app (curry TextIO.output out o RC.tptp_classrelClause) classrel_clauses;
   478         List.app (curry TextIO.output out o RC.tptp_arity_clause) arity_clauses;
   479         List.app (curry TextIO.output out o #1 o (clause2tptp const_min_arity const_needs_hBOOL)) helper_clauses;
   480         TextIO.closeOut out;
   481         clnames
   482     end;
   483 
   484 
   485 (* dfg format *)
   486 
   487 fun dfg_write_file thy isFO thms filename (ax_tuples,classrel_clauses,arity_clauses) user_lemmas =
   488     let val _ = Output.debug (fn () => ("Preparing to write the DFG file " ^ filename))
   489         val conjectures = make_conjecture_clauses true thy thms
   490         val (clnames,axclauses) = ListPair.unzip (make_axiom_clauses true thy ax_tuples)
   491         val helper_clauses = get_helper_clauses true thy isFO (conjectures, axclauses, user_lemmas)
   492         val (const_min_arity, const_needs_hBOOL) = count_constants (conjectures, axclauses, helper_clauses);
   493         val (dfg_clss, tfree_litss) = ListPair.unzip (map (clause2dfg const_min_arity const_needs_hBOOL) conjectures)
   494         and probname = Path.implode (Path.base (Path.explode filename))
   495         val axstrs = map (#1 o (clause2dfg const_min_arity const_needs_hBOOL)) axclauses
   496         val tfree_clss = map RC.dfg_tfree_clause (RC.union_all tfree_litss)
   497         val out = TextIO.openOut filename
   498         val helper_clauses_strs = map (#1 o (clause2dfg const_min_arity const_needs_hBOOL)) helper_clauses
   499         val (funcs,cl_preds) = decls_of_clauses const_min_arity const_needs_hBOOL (helper_clauses @ conjectures @ axclauses) arity_clauses
   500         and ty_preds = preds_of_clauses axclauses classrel_clauses arity_clauses
   501     in
   502         TextIO.output (out, RC.string_of_start probname);
   503         TextIO.output (out, RC.string_of_descrip probname);
   504         TextIO.output (out, RC.string_of_symbols
   505                               (RC.string_of_funcs funcs)
   506                               (RC.string_of_preds (cl_preds @ ty_preds)));
   507         TextIO.output (out, "list_of_clauses(axioms,cnf).\n");
   508         RC.writeln_strs out axstrs;
   509         List.app (curry TextIO.output out o RC.dfg_classrelClause) classrel_clauses;
   510         List.app (curry TextIO.output out o RC.dfg_arity_clause) arity_clauses;
   511         RC.writeln_strs out helper_clauses_strs;
   512         TextIO.output (out, "end_of_list.\n\nlist_of_clauses(conjectures,cnf).\n");
   513         RC.writeln_strs out tfree_clss;
   514         RC.writeln_strs out dfg_clss;
   515         TextIO.output (out, "end_of_list.\n\n");
   516         (*VarWeight=3 helps the HO problems, probably by counteracting the presence of hAPP*)
   517         TextIO.output (out, "list_of_settings(SPASS).\n{*\nset_flag(VarWeight,3).\n*}\nend_of_list.\n\n");
   518         TextIO.output (out, "end_problem.\n");
   519         TextIO.closeOut out;
   520         clnames
   521     end;
   522 
   523 end