src/HOL/Product_Type.thy
author wenzelm
Thu Oct 15 23:28:10 2009 +0200 (2009-10-15)
changeset 32952 aeb1e44fbc19
parent 32010 cb1a1c94b4cd
child 33089 4e33c819fced
permissions -rw-r--r--
replaced String.concat by implode;
replaced String.concatWith by space_implode;
replaced (Seq.flat o Seq.map) by Seq.maps;
replaced List.mapPartial by map_filter;
replaced List.concat by flat;
replaced (flat o map) by maps, which produces less garbage;
     1 (*  Title:      HOL/Product_Type.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Cartesian products *}
     7 
     8 theory Product_Type
     9 imports Inductive
    10 uses
    11   ("Tools/split_rule.ML")
    12   ("Tools/inductive_set.ML")
    13   ("Tools/inductive_realizer.ML")
    14   ("Tools/Datatype/datatype_realizer.ML")
    15 begin
    16 
    17 subsection {* @{typ bool} is a datatype *}
    18 
    19 rep_datatype True False by (auto intro: bool_induct)
    20 
    21 declare case_split [cases type: bool]
    22   -- "prefer plain propositional version"
    23 
    24 lemma
    25   shows [code]: "eq_class.eq False P \<longleftrightarrow> \<not> P"
    26     and [code]: "eq_class.eq True P \<longleftrightarrow> P" 
    27     and [code]: "eq_class.eq P False \<longleftrightarrow> \<not> P" 
    28     and [code]: "eq_class.eq P True \<longleftrightarrow> P"
    29     and [code nbe]: "eq_class.eq P P \<longleftrightarrow> True"
    30   by (simp_all add: eq)
    31 
    32 code_const "eq_class.eq \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    33   (Haskell infixl 4 "==")
    34 
    35 code_instance bool :: eq
    36   (Haskell -)
    37 
    38 
    39 subsection {* Unit *}
    40 
    41 typedef unit = "{True}"
    42 proof
    43   show "True : ?unit" ..
    44 qed
    45 
    46 definition
    47   Unity :: unit    ("'(')")
    48 where
    49   "() = Abs_unit True"
    50 
    51 lemma unit_eq [noatp]: "u = ()"
    52   by (induct u) (simp add: unit_def Unity_def)
    53 
    54 text {*
    55   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    56   this rule directly --- it loops!
    57 *}
    58 
    59 ML {*
    60   val unit_eq_proc =
    61     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    62       Simplifier.simproc @{theory} "unit_eq" ["x::unit"]
    63       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    64     end;
    65 
    66   Addsimprocs [unit_eq_proc];
    67 *}
    68 
    69 rep_datatype "()" by simp
    70 
    71 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    72   by simp
    73 
    74 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    75   by (rule triv_forall_equality)
    76 
    77 text {*
    78   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    79   [source] "%u::unit. f u"}, replacing it by @{term [source]
    80   f} rather than by @{term [source] "%u. f ()"}.
    81 *}
    82 
    83 lemma unit_abs_eta_conv [simp,noatp]: "(%u::unit. f ()) = f"
    84   by (rule ext) simp
    85 
    86 instantiation unit :: default
    87 begin
    88 
    89 definition "default = ()"
    90 
    91 instance ..
    92 
    93 end
    94 
    95 text {* code generator setup *}
    96 
    97 instance unit :: eq ..
    98 
    99 lemma [code]:
   100   "eq_class.eq (u\<Colon>unit) v \<longleftrightarrow> True" unfolding eq unit_eq [of u] unit_eq [of v] by rule+
   101 
   102 code_type unit
   103   (SML "unit")
   104   (OCaml "unit")
   105   (Haskell "()")
   106 
   107 code_instance unit :: eq
   108   (Haskell -)
   109 
   110 code_const "eq_class.eq \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   111   (Haskell infixl 4 "==")
   112 
   113 code_const Unity
   114   (SML "()")
   115   (OCaml "()")
   116   (Haskell "()")
   117 
   118 code_reserved SML
   119   unit
   120 
   121 code_reserved OCaml
   122   unit
   123 
   124 
   125 subsection {* Pairs *}
   126 
   127 subsubsection {* Product type, basic operations and concrete syntax *}
   128 
   129 definition
   130   Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
   131 where
   132   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   133 
   134 global
   135 
   136 typedef (Prod)
   137   ('a, 'b) "*"    (infixr "*" 20)
   138     = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   139 proof
   140   fix a b show "Pair_Rep a b \<in> ?Prod"
   141     by rule+
   142 qed
   143 
   144 syntax (xsymbols)
   145   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   146 syntax (HTML output)
   147   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   148 
   149 consts
   150   Pair     :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b"
   151   fst      :: "'a \<times> 'b \<Rightarrow> 'a"
   152   snd      :: "'a \<times> 'b \<Rightarrow> 'b"
   153   split    :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   154   curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c"
   155 
   156 local
   157 
   158 defs
   159   Pair_def:     "Pair a b == Abs_Prod (Pair_Rep a b)"
   160   fst_def:      "fst p == THE a. EX b. p = Pair a b"
   161   snd_def:      "snd p == THE b. EX a. p = Pair a b"
   162   split_def:    "split == (%c p. c (fst p) (snd p))"
   163   curry_def:    "curry == (%c x y. c (Pair x y))"
   164 
   165 text {*
   166   Patterns -- extends pre-defined type @{typ pttrn} used in
   167   abstractions.
   168 *}
   169 
   170 nonterminals
   171   tuple_args patterns
   172 
   173 syntax
   174   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   175   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   176   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   177   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   178   ""            :: "pttrn => patterns"                  ("_")
   179   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   180 
   181 translations
   182   "(x, y)"       == "Pair x y"
   183   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   184   "%(x,y,zs).b"  == "split(%x (y,zs).b)"
   185   "%(x,y).b"     == "split(%x y. b)"
   186   "_abs (Pair x y) t" => "%(x,y).t"
   187   (* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   188      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *)
   189 
   190 (* reconstructs pattern from (nested) splits, avoiding eta-contraction of body*)
   191 (* works best with enclosing "let", if "let" does not avoid eta-contraction   *)
   192 print_translation {*
   193 let fun split_tr' [Abs (x,T,t as (Abs abs))] =
   194       (* split (%x y. t) => %(x,y) t *)
   195       let val (y,t') = atomic_abs_tr' abs;
   196           val (x',t'') = atomic_abs_tr' (x,T,t');
   197     
   198       in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end
   199     | split_tr' [Abs (x,T,(s as Const ("split",_)$t))] =
   200        (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   201        let val (Const ("_abs",_)$(Const ("_pattern",_)$y$z)$t') = split_tr' [t];
   202            val (x',t'') = atomic_abs_tr' (x,T,t');
   203        in Syntax.const "_abs"$ 
   204            (Syntax.const "_pattern"$x'$(Syntax.const "_patterns"$y$z))$t'' end
   205     | split_tr' [Const ("split",_)$t] =
   206        (* split (split (%x y z. t)) => %((x,y),z). t *)   
   207        split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   208     | split_tr' [Const ("_abs",_)$x_y$(Abs abs)] =
   209        (* split (%pttrn z. t) => %(pttrn,z). t *)
   210        let val (z,t) = atomic_abs_tr' abs;
   211        in Syntax.const "_abs" $ (Syntax.const "_pattern" $x_y$z) $ t end
   212     | split_tr' _ =  raise Match;
   213 in [("split", split_tr')]
   214 end
   215 *}
   216 
   217 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   218 typed_print_translation {*
   219 let
   220   fun split_guess_names_tr' _ T [Abs (x,_,Abs _)] = raise Match
   221     | split_guess_names_tr' _ T  [Abs (x,xT,t)] =
   222         (case (head_of t) of
   223            Const ("split",_) => raise Match
   224          | _ => let 
   225                   val (_::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   226                   val (y,t') = atomic_abs_tr' ("y",yT,(incr_boundvars 1 t)$Bound 0); 
   227                   val (x',t'') = atomic_abs_tr' (x,xT,t');
   228                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   229     | split_guess_names_tr' _ T [t] =
   230        (case (head_of t) of
   231            Const ("split",_) => raise Match 
   232          | _ => let 
   233                   val (xT::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   234                   val (y,t') = 
   235                         atomic_abs_tr' ("y",yT,(incr_boundvars 2 t)$Bound 1$Bound 0); 
   236                   val (x',t'') = atomic_abs_tr' ("x",xT,t');
   237                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   238     | split_guess_names_tr' _ _ _ = raise Match;
   239 in [("split", split_guess_names_tr')]
   240 end 
   241 *}
   242 
   243 
   244 text {* Towards a datatype declaration *}
   245 
   246 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   247   apply (unfold Pair_def)
   248   apply (rule Rep_Prod [unfolded Prod_def, THEN CollectE])
   249   apply (erule exE, erule exE, rule exI, rule exI)
   250   apply (rule Rep_Prod_inverse [symmetric, THEN trans])
   251   apply (erule arg_cong)
   252   done
   253 
   254 lemma PairE [cases type: *]:
   255   obtains x y where "p = (x, y)"
   256   using surj_pair [of p] by blast
   257 
   258 lemma ProdI: "Pair_Rep a b \<in> Prod"
   259   unfolding Prod_def by rule+
   260 
   261 lemma Pair_Rep_inject: "Pair_Rep a b = Pair_Rep a' b' \<Longrightarrow> a = a' \<and> b = b'"
   262   unfolding Pair_Rep_def by (drule fun_cong, drule fun_cong) blast
   263 
   264 lemma inj_on_Abs_Prod: "inj_on Abs_Prod Prod"
   265   apply (rule inj_on_inverseI)
   266   apply (erule Abs_Prod_inverse)
   267   done
   268 
   269 lemma Pair_inject:
   270   assumes "(a, b) = (a', b')"
   271     and "a = a' ==> b = b' ==> R"
   272   shows R
   273   apply (insert prems [unfolded Pair_def])
   274   apply (rule inj_on_Abs_Prod [THEN inj_onD, THEN Pair_Rep_inject, THEN conjE])
   275   apply (assumption | rule ProdI)+
   276   done
   277 
   278 rep_datatype (prod) Pair
   279 proof -
   280   fix P p
   281   assume "\<And>x y. P (x, y)"
   282   then show "P p" by (cases p) simp
   283 qed (auto elim: Pair_inject)
   284 
   285 lemmas Pair_eq = prod.inject
   286 
   287 lemma fst_conv [simp, code]: "fst (a, b) = a"
   288   unfolding fst_def by blast
   289 
   290 lemma snd_conv [simp, code]: "snd (a, b) = b"
   291   unfolding snd_def by blast
   292 
   293 
   294 subsubsection {* Basic rules and proof tools *}
   295 
   296 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   297   by simp
   298 
   299 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   300   by simp
   301 
   302 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   303   by (cases p) simp
   304 
   305 lemmas surjective_pairing = pair_collapse [symmetric]
   306 
   307 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   308 proof
   309   fix a b
   310   assume "!!x. PROP P x"
   311   then show "PROP P (a, b)" .
   312 next
   313   fix x
   314   assume "!!a b. PROP P (a, b)"
   315   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   316 qed
   317 
   318 text {*
   319   The rule @{thm [source] split_paired_all} does not work with the
   320   Simplifier because it also affects premises in congrence rules,
   321   where this can lead to premises of the form @{text "!!a b. ... =
   322   ?P(a, b)"} which cannot be solved by reflexivity.
   323 *}
   324 
   325 lemmas split_tupled_all = split_paired_all unit_all_eq2
   326 
   327 ML {*
   328   (* replace parameters of product type by individual component parameters *)
   329   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   330   local (* filtering with exists_paired_all is an essential optimization *)
   331     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   332           can HOLogic.dest_prodT T orelse exists_paired_all t
   333       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   334       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   335       | exists_paired_all _ = false;
   336     val ss = HOL_basic_ss
   337       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   338       addsimprocs [unit_eq_proc];
   339   in
   340     val split_all_tac = SUBGOAL (fn (t, i) =>
   341       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   342     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   343       if exists_paired_all t then full_simp_tac ss i else no_tac);
   344     fun split_all th =
   345    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   346   end;
   347 *}
   348 
   349 declaration {* fn _ =>
   350   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   351 *}
   352 
   353 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   354   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   355   by fast
   356 
   357 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   358   by fast
   359 
   360 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   361   by (cases s, cases t) simp
   362 
   363 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   364   by (simp add: Pair_fst_snd_eq)
   365 
   366 
   367 subsubsection {* @{text split} and @{text curry} *}
   368 
   369 lemma split_conv [simp, code]: "split f (a, b) = f a b"
   370   by (simp add: split_def)
   371 
   372 lemma curry_conv [simp, code]: "curry f a b = f (a, b)"
   373   by (simp add: curry_def)
   374 
   375 lemmas split = split_conv  -- {* for backwards compatibility *}
   376 
   377 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   378   by (rule split_conv [THEN iffD2])
   379 
   380 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   381   by (rule split_conv [THEN iffD1])
   382 
   383 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   384   by (simp add: curry_def)
   385 
   386 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   387   by (simp add: curry_def)
   388 
   389 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   390   by (simp add: curry_def)
   391 
   392 lemma curry_split [simp]: "curry (split f) = f"
   393   by (simp add: curry_def split_def)
   394 
   395 lemma split_curry [simp]: "split (curry f) = f"
   396   by (simp add: curry_def split_def)
   397 
   398 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   399   by (simp add: split_def id_def)
   400 
   401 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   402   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity Datatype. *}
   403   by (rule ext) auto
   404 
   405 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   406   by (cases x) simp
   407 
   408 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   409   unfolding split_def ..
   410 
   411 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   412   -- {* Can't be added to simpset: loops! *}
   413   by (simp add: split_eta)
   414 
   415 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   416   by (simp add: split_def)
   417 
   418 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   419   -- {* Prevents simplification of @{term c}: much faster *}
   420   by (erule arg_cong)
   421 
   422 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   423   by (simp add: split_eta)
   424 
   425 text {*
   426   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   427   @{thm [source] split_eta} as a rewrite rule is not general enough,
   428   and using @{thm [source] cond_split_eta} directly would render some
   429   existing proofs very inefficient; similarly for @{text
   430   split_beta}.
   431 *}
   432 
   433 ML {*
   434 
   435 local
   436   val cond_split_eta_ss = HOL_basic_ss addsimps [thm "cond_split_eta"]
   437   fun  Pair_pat k 0 (Bound m) = (m = k)
   438   |    Pair_pat k i (Const ("Pair",  _) $ Bound m $ t) = i > 0 andalso
   439                         m = k+i andalso Pair_pat k (i-1) t
   440   |    Pair_pat _ _ _ = false;
   441   fun no_args k i (Abs (_, _, t)) = no_args (k+1) i t
   442   |   no_args k i (t $ u) = no_args k i t andalso no_args k i u
   443   |   no_args k i (Bound m) = m < k orelse m > k+i
   444   |   no_args _ _ _ = true;
   445   fun split_pat tp i (Abs  (_,_,t)) = if tp 0 i t then SOME (i,t) else NONE
   446   |   split_pat tp i (Const ("split", _) $ Abs (_, _, t)) = split_pat tp (i+1) t
   447   |   split_pat tp i _ = NONE;
   448   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   449         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs,rhs)))
   450         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   451 
   452   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k+1) i t
   453   |   beta_term_pat k i (t $ u) = Pair_pat k i (t $ u) orelse
   454                         (beta_term_pat k i t andalso beta_term_pat k i u)
   455   |   beta_term_pat k i t = no_args k i t;
   456   fun  eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   457   |    eta_term_pat _ _ _ = false;
   458   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   459   |   subst arg k i (t $ u) = if Pair_pat k i (t $ u) then incr_boundvars k arg
   460                               else (subst arg k i t $ subst arg k i u)
   461   |   subst arg k i t = t;
   462   fun beta_proc ss (s as Const ("split", _) $ Abs (_, _, t) $ arg) =
   463         (case split_pat beta_term_pat 1 t of
   464         SOME (i,f) => SOME (metaeq ss s (subst arg 0 i f))
   465         | NONE => NONE)
   466   |   beta_proc _ _ = NONE;
   467   fun eta_proc ss (s as Const ("split", _) $ Abs (_, _, t)) =
   468         (case split_pat eta_term_pat 1 t of
   469           SOME (_,ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   470         | NONE => NONE)
   471   |   eta_proc _ _ = NONE;
   472 in
   473   val split_beta_proc = Simplifier.simproc @{theory} "split_beta" ["split f z"] (K beta_proc);
   474   val split_eta_proc = Simplifier.simproc @{theory} "split_eta" ["split f"] (K eta_proc);
   475 end;
   476 
   477 Addsimprocs [split_beta_proc, split_eta_proc];
   478 *}
   479 
   480 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   481   by (subst surjective_pairing, rule split_conv)
   482 
   483 lemma split_split [noatp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   484   -- {* For use with @{text split} and the Simplifier. *}
   485   by (insert surj_pair [of p], clarify, simp)
   486 
   487 text {*
   488   @{thm [source] split_split} could be declared as @{text "[split]"}
   489   done after the Splitter has been speeded up significantly;
   490   precompute the constants involved and don't do anything unless the
   491   current goal contains one of those constants.
   492 *}
   493 
   494 lemma split_split_asm [noatp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   495 by (subst split_split, simp)
   496 
   497 
   498 text {*
   499   \medskip @{term split} used as a logical connective or set former.
   500 
   501   \medskip These rules are for use with @{text blast}; could instead
   502   call @{text simp} using @{thm [source] split} as rewrite. *}
   503 
   504 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   505   apply (simp only: split_tupled_all)
   506   apply (simp (no_asm_simp))
   507   done
   508 
   509 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   510   apply (simp only: split_tupled_all)
   511   apply (simp (no_asm_simp))
   512   done
   513 
   514 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   515   by (induct p) (auto simp add: split_def)
   516 
   517 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   518   by (induct p) (auto simp add: split_def)
   519 
   520 lemma splitE2:
   521   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   522 proof -
   523   assume q: "Q (split P z)"
   524   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   525   show R
   526     apply (rule r surjective_pairing)+
   527     apply (rule split_beta [THEN subst], rule q)
   528     done
   529 qed
   530 
   531 lemma splitD': "split R (a,b) c ==> R a b c"
   532   by simp
   533 
   534 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   535   by simp
   536 
   537 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   538 by (simp only: split_tupled_all, simp)
   539 
   540 lemma mem_splitE:
   541   assumes major: "z: split c p"
   542     and cases: "!!x y. [| p = (x,y); z: c x y |] ==> Q"
   543   shows Q
   544   by (rule major [unfolded split_def] cases surjective_pairing)+
   545 
   546 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   547 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   548 
   549 ML {*
   550 local (* filtering with exists_p_split is an essential optimization *)
   551   fun exists_p_split (Const ("split",_) $ _ $ (Const ("Pair",_)$_$_)) = true
   552     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   553     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   554     | exists_p_split _ = false;
   555   val ss = HOL_basic_ss addsimps [thm "split_conv"];
   556 in
   557 val split_conv_tac = SUBGOAL (fn (t, i) =>
   558     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   559 end;
   560 *}
   561 
   562 (* This prevents applications of splitE for already splitted arguments leading
   563    to quite time-consuming computations (in particular for nested tuples) *)
   564 declaration {* fn _ =>
   565   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   566 *}
   567 
   568 lemma split_eta_SetCompr [simp,noatp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   569   by (rule ext) fast
   570 
   571 lemma split_eta_SetCompr2 [simp,noatp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   572   by (rule ext) fast
   573 
   574 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   575   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   576   by (rule ext) blast
   577 
   578 (* Do NOT make this a simp rule as it
   579    a) only helps in special situations
   580    b) can lead to nontermination in the presence of split_def
   581 *)
   582 lemma split_comp_eq: 
   583   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   584   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   585   by (rule ext) auto
   586 
   587 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   588   apply (rule_tac x = "(a, b)" in image_eqI)
   589    apply auto
   590   done
   591 
   592 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   593   by blast
   594 
   595 (*
   596 the following  would be slightly more general,
   597 but cannot be used as rewrite rule:
   598 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   599 ### ?y = .x
   600 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   601 by (rtac some_equality 1)
   602 by ( Simp_tac 1)
   603 by (split_all_tac 1)
   604 by (Asm_full_simp_tac 1)
   605 qed "The_split_eq";
   606 *)
   607 
   608 text {*
   609   Setup of internal @{text split_rule}.
   610 *}
   611 
   612 definition
   613   internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   614 where
   615   "internal_split == split"
   616 
   617 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   618   by (simp only: internal_split_def split_conv)
   619 
   620 hide const internal_split
   621 
   622 use "Tools/split_rule.ML"
   623 setup SplitRule.setup
   624 
   625 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   626 
   627 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   628   by auto
   629 
   630 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   631   by (auto simp: split_tupled_all)
   632 
   633 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   634   by (induct p) auto
   635 
   636 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   637   by (induct p) auto
   638 
   639 lemma prod_case_unfold: "prod_case = (%c p. c (fst p) (snd p))"
   640   by (simp add: expand_fun_eq)
   641 
   642 declare prod_caseI2' [intro!] prod_caseI2 [intro!] prod_caseI [intro!]
   643 declare prod_caseE' [elim!] prod_caseE [elim!]
   644 
   645 lemma prod_case_split:
   646   "prod_case = split"
   647   by (auto simp add: expand_fun_eq)
   648 
   649 lemma prod_case_beta:
   650   "prod_case f p = f (fst p) (snd p)"
   651   unfolding prod_case_split split_beta ..
   652 
   653 
   654 subsection {* Further cases/induct rules for tuples *}
   655 
   656 lemma prod_cases3 [cases type]:
   657   obtains (fields) a b c where "y = (a, b, c)"
   658   by (cases y, case_tac b) blast
   659 
   660 lemma prod_induct3 [case_names fields, induct type]:
   661     "(!!a b c. P (a, b, c)) ==> P x"
   662   by (cases x) blast
   663 
   664 lemma prod_cases4 [cases type]:
   665   obtains (fields) a b c d where "y = (a, b, c, d)"
   666   by (cases y, case_tac c) blast
   667 
   668 lemma prod_induct4 [case_names fields, induct type]:
   669     "(!!a b c d. P (a, b, c, d)) ==> P x"
   670   by (cases x) blast
   671 
   672 lemma prod_cases5 [cases type]:
   673   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   674   by (cases y, case_tac d) blast
   675 
   676 lemma prod_induct5 [case_names fields, induct type]:
   677     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   678   by (cases x) blast
   679 
   680 lemma prod_cases6 [cases type]:
   681   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   682   by (cases y, case_tac e) blast
   683 
   684 lemma prod_induct6 [case_names fields, induct type]:
   685     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   686   by (cases x) blast
   687 
   688 lemma prod_cases7 [cases type]:
   689   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   690   by (cases y, case_tac f) blast
   691 
   692 lemma prod_induct7 [case_names fields, induct type]:
   693     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   694   by (cases x) blast
   695 
   696 
   697 subsubsection {* Derived operations *}
   698 
   699 text {*
   700   The composition-uncurry combinator.
   701 *}
   702 
   703 notation fcomp (infixl "o>" 60)
   704 
   705 definition
   706   scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "o\<rightarrow>" 60)
   707 where
   708   "f o\<rightarrow> g = (\<lambda>x. split g (f x))"
   709 
   710 lemma scomp_apply:  "(f o\<rightarrow> g) x = split g (f x)"
   711   by (simp add: scomp_def)
   712 
   713 lemma Pair_scomp: "Pair x o\<rightarrow> f = f x"
   714   by (simp add: expand_fun_eq scomp_apply)
   715 
   716 lemma scomp_Pair: "x o\<rightarrow> Pair = x"
   717   by (simp add: expand_fun_eq scomp_apply)
   718 
   719 lemma scomp_scomp: "(f o\<rightarrow> g) o\<rightarrow> h = f o\<rightarrow> (\<lambda>x. g x o\<rightarrow> h)"
   720   by (simp add: expand_fun_eq split_twice scomp_def)
   721 
   722 lemma scomp_fcomp: "(f o\<rightarrow> g) o> h = f o\<rightarrow> (\<lambda>x. g x o> h)"
   723   by (simp add: expand_fun_eq scomp_apply fcomp_def split_def)
   724 
   725 lemma fcomp_scomp: "(f o> g) o\<rightarrow> h = f o> (g o\<rightarrow> h)"
   726   by (simp add: expand_fun_eq scomp_apply fcomp_apply)
   727 
   728 code_const scomp
   729   (Eval infixl 3 "#->")
   730 
   731 no_notation fcomp (infixl "o>" 60)
   732 no_notation scomp (infixl "o\<rightarrow>" 60)
   733 
   734 
   735 text {*
   736   @{term prod_fun} --- action of the product functor upon
   737   Datatypes.
   738 *}
   739 
   740 definition prod_fun :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   741   [code del]: "prod_fun f g = (\<lambda>(x, y). (f x, g y))"
   742 
   743 lemma prod_fun [simp, code]: "prod_fun f g (a, b) = (f a, g b)"
   744   by (simp add: prod_fun_def)
   745 
   746 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   747   by (rule ext) auto
   748 
   749 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   750   by (rule ext) auto
   751 
   752 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   753   apply (rule image_eqI)
   754   apply (rule prod_fun [symmetric], assumption)
   755   done
   756 
   757 lemma prod_fun_imageE [elim!]:
   758   assumes major: "c: (prod_fun f g)`r"
   759     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   760   shows P
   761   apply (rule major [THEN imageE])
   762   apply (rule_tac p = x in PairE)
   763   apply (rule cases)
   764    apply (blast intro: prod_fun)
   765   apply blast
   766   done
   767 
   768 definition
   769   apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b"
   770 where
   771   [code del]: "apfst f = prod_fun f id"
   772 
   773 definition
   774   apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c"
   775 where
   776   [code del]: "apsnd f = prod_fun id f"
   777 
   778 lemma apfst_conv [simp, code]:
   779   "apfst f (x, y) = (f x, y)" 
   780   by (simp add: apfst_def)
   781 
   782 lemma upd_snd_conv [simp, code]:
   783   "apsnd f (x, y) = (x, f y)" 
   784   by (simp add: apsnd_def)
   785 
   786 
   787 text {*
   788   Disjoint union of a family of sets -- Sigma.
   789 *}
   790 
   791 definition  Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   792   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   793 
   794 abbreviation
   795   Times :: "['a set, 'b set] => ('a * 'b) set"
   796     (infixr "<*>" 80) where
   797   "A <*> B == Sigma A (%_. B)"
   798 
   799 notation (xsymbols)
   800   Times  (infixr "\<times>" 80)
   801 
   802 notation (HTML output)
   803   Times  (infixr "\<times>" 80)
   804 
   805 syntax
   806   "@Sigma" ::"[pttrn, 'a set, 'b set] => ('a * 'b) set" ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   807 
   808 translations
   809   "SIGMA x:A. B" == "Product_Type.Sigma A (%x. B)"
   810 
   811 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   812   by (unfold Sigma_def) blast
   813 
   814 lemma SigmaE [elim!]:
   815     "[| c: Sigma A B;
   816         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   817      |] ==> P"
   818   -- {* The general elimination rule. *}
   819   by (unfold Sigma_def) blast
   820 
   821 text {*
   822   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   823   eigenvariables.
   824 *}
   825 
   826 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   827   by blast
   828 
   829 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   830   by blast
   831 
   832 lemma SigmaE2:
   833     "[| (a, b) : Sigma A B;
   834         [| a:A;  b:B(a) |] ==> P
   835      |] ==> P"
   836   by blast
   837 
   838 lemma Sigma_cong:
   839      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   840       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   841   by auto
   842 
   843 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   844   by blast
   845 
   846 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   847   by blast
   848 
   849 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   850   by blast
   851 
   852 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   853   by auto
   854 
   855 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   856   by auto
   857 
   858 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   859   by auto
   860 
   861 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   862   by blast
   863 
   864 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   865   by blast
   866 
   867 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   868   by (blast elim: equalityE)
   869 
   870 lemma SetCompr_Sigma_eq:
   871     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   872   by blast
   873 
   874 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   875   by blast
   876 
   877 lemma UN_Times_distrib:
   878   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   879   -- {* Suggested by Pierre Chartier *}
   880   by blast
   881 
   882 lemma split_paired_Ball_Sigma [simp,noatp]:
   883     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   884   by blast
   885 
   886 lemma split_paired_Bex_Sigma [simp,noatp]:
   887     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   888   by blast
   889 
   890 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   891   by blast
   892 
   893 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   894   by blast
   895 
   896 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   897   by blast
   898 
   899 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   900   by blast
   901 
   902 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   903   by blast
   904 
   905 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   906   by blast
   907 
   908 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   909   by blast
   910 
   911 text {*
   912   Non-dependent versions are needed to avoid the need for higher-order
   913   matching, especially when the rules are re-oriented.
   914 *}
   915 
   916 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
   917 by blast
   918 
   919 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
   920 by blast
   921 
   922 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
   923 by blast
   924 
   925 lemma insert_times_insert[simp]:
   926   "insert a A \<times> insert b B =
   927    insert (a,b) (A \<times> insert b B \<union> insert a A \<times> B)"
   928 by blast
   929 
   930 subsubsection {* Code generator setup *}
   931 
   932 instance * :: (eq, eq) eq ..
   933 
   934 lemma [code]:
   935   "eq_class.eq (x1\<Colon>'a\<Colon>eq, y1\<Colon>'b\<Colon>eq) (x2, y2) \<longleftrightarrow> x1 = x2 \<and> y1 = y2" by (simp add: eq)
   936 
   937 lemma split_case_cert:
   938   assumes "CASE \<equiv> split f"
   939   shows "CASE (a, b) \<equiv> f a b"
   940   using assms by simp
   941 
   942 setup {*
   943   Code.add_case @{thm split_case_cert}
   944 *}
   945 
   946 code_type *
   947   (SML infix 2 "*")
   948   (OCaml infix 2 "*")
   949   (Haskell "!((_),/ (_))")
   950 
   951 code_instance * :: eq
   952   (Haskell -)
   953 
   954 code_const "eq_class.eq \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   955   (Haskell infixl 4 "==")
   956 
   957 code_const Pair
   958   (SML "!((_),/ (_))")
   959   (OCaml "!((_),/ (_))")
   960   (Haskell "!((_),/ (_))")
   961 
   962 code_const fst and snd
   963   (Haskell "fst" and "snd")
   964 
   965 types_code
   966   "*"     ("(_ */ _)")
   967 attach (term_of) {*
   968 fun term_of_id_42 aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   969 *}
   970 attach (test) {*
   971 fun gen_id_42 aG aT bG bT i =
   972   let
   973     val (x, t) = aG i;
   974     val (y, u) = bG i
   975   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   976 *}
   977 
   978 consts_code
   979   "Pair"    ("(_,/ _)")
   980 
   981 setup {*
   982 
   983 let
   984 
   985 fun strip_abs_split 0 t = ([], t)
   986   | strip_abs_split i (Abs (s, T, t)) =
   987       let
   988         val s' = Codegen.new_name t s;
   989         val v = Free (s', T)
   990       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   991   | strip_abs_split i (u as Const ("split", _) $ t) = (case strip_abs_split (i+1) t of
   992         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   993       | _ => ([], u))
   994   | strip_abs_split i t =
   995       strip_abs_split i (Abs ("x", hd (binder_types (fastype_of t)), t $ Bound 0));
   996 
   997 fun let_codegen thy defs dep thyname brack t gr = (case strip_comb t of
   998     (t1 as Const ("Let", _), t2 :: t3 :: ts) =>
   999     let
  1000       fun dest_let (l as Const ("Let", _) $ t $ u) =
  1001           (case strip_abs_split 1 u of
  1002              ([p], u') => apfst (cons (p, t)) (dest_let u')
  1003            | _ => ([], l))
  1004         | dest_let t = ([], t);
  1005       fun mk_code (l, r) gr =
  1006         let
  1007           val (pl, gr1) = Codegen.invoke_codegen thy defs dep thyname false l gr;
  1008           val (pr, gr2) = Codegen.invoke_codegen thy defs dep thyname false r gr1;
  1009         in ((pl, pr), gr2) end
  1010     in case dest_let (t1 $ t2 $ t3) of
  1011         ([], _) => NONE
  1012       | (ps, u) =>
  1013           let
  1014             val (qs, gr1) = fold_map mk_code ps gr;
  1015             val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
  1016             val (pargs, gr3) = fold_map
  1017               (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
  1018           in
  1019             SOME (Codegen.mk_app brack
  1020               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, flat
  1021                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
  1022                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
  1023                        Pretty.brk 1, pr]]) qs))),
  1024                 Pretty.brk 1, Codegen.str "in ", pu,
  1025                 Pretty.brk 1, Codegen.str "end"])) pargs, gr3)
  1026           end
  1027     end
  1028   | _ => NONE);
  1029 
  1030 fun split_codegen thy defs dep thyname brack t gr = (case strip_comb t of
  1031     (t1 as Const ("split", _), t2 :: ts) =>
  1032       let
  1033         val ([p], u) = strip_abs_split 1 (t1 $ t2);
  1034         val (q, gr1) = Codegen.invoke_codegen thy defs dep thyname false p gr;
  1035         val (pu, gr2) = Codegen.invoke_codegen thy defs dep thyname false u gr1;
  1036         val (pargs, gr3) = fold_map
  1037           (Codegen.invoke_codegen thy defs dep thyname true) ts gr2
  1038       in
  1039         SOME (Codegen.mk_app brack
  1040           (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
  1041             Pretty.brk 1, pu, Codegen.str ")"]) pargs, gr2)
  1042       end
  1043   | _ => NONE);
  1044 
  1045 in
  1046 
  1047   Codegen.add_codegen "let_codegen" let_codegen
  1048   #> Codegen.add_codegen "split_codegen" split_codegen
  1049 
  1050 end
  1051 *}
  1052 
  1053 
  1054 subsection {* Legacy bindings *}
  1055 
  1056 ML {*
  1057 val Collect_split = thm "Collect_split";
  1058 val Compl_Times_UNIV1 = thm "Compl_Times_UNIV1";
  1059 val Compl_Times_UNIV2 = thm "Compl_Times_UNIV2";
  1060 val PairE = thm "PairE";
  1061 val Pair_Rep_inject = thm "Pair_Rep_inject";
  1062 val Pair_def = thm "Pair_def";
  1063 val Pair_eq = @{thm "prod.inject"};
  1064 val Pair_fst_snd_eq = thm "Pair_fst_snd_eq";
  1065 val ProdI = thm "ProdI";
  1066 val SetCompr_Sigma_eq = thm "SetCompr_Sigma_eq";
  1067 val SigmaD1 = thm "SigmaD1";
  1068 val SigmaD2 = thm "SigmaD2";
  1069 val SigmaE = thm "SigmaE";
  1070 val SigmaE2 = thm "SigmaE2";
  1071 val SigmaI = thm "SigmaI";
  1072 val Sigma_Diff_distrib1 = thm "Sigma_Diff_distrib1";
  1073 val Sigma_Diff_distrib2 = thm "Sigma_Diff_distrib2";
  1074 val Sigma_Int_distrib1 = thm "Sigma_Int_distrib1";
  1075 val Sigma_Int_distrib2 = thm "Sigma_Int_distrib2";
  1076 val Sigma_Un_distrib1 = thm "Sigma_Un_distrib1";
  1077 val Sigma_Un_distrib2 = thm "Sigma_Un_distrib2";
  1078 val Sigma_Union = thm "Sigma_Union";
  1079 val Sigma_def = thm "Sigma_def";
  1080 val Sigma_empty1 = thm "Sigma_empty1";
  1081 val Sigma_empty2 = thm "Sigma_empty2";
  1082 val Sigma_mono = thm "Sigma_mono";
  1083 val The_split = thm "The_split";
  1084 val The_split_eq = thm "The_split_eq";
  1085 val The_split_eq = thm "The_split_eq";
  1086 val Times_Diff_distrib1 = thm "Times_Diff_distrib1";
  1087 val Times_Int_distrib1 = thm "Times_Int_distrib1";
  1088 val Times_Un_distrib1 = thm "Times_Un_distrib1";
  1089 val Times_eq_cancel2 = thm "Times_eq_cancel2";
  1090 val Times_subset_cancel2 = thm "Times_subset_cancel2";
  1091 val UNIV_Times_UNIV = thm "UNIV_Times_UNIV";
  1092 val UN_Times_distrib = thm "UN_Times_distrib";
  1093 val Unity_def = thm "Unity_def";
  1094 val cond_split_eta = thm "cond_split_eta";
  1095 val fst_conv = thm "fst_conv";
  1096 val fst_def = thm "fst_def";
  1097 val fst_eqD = thm "fst_eqD";
  1098 val inj_on_Abs_Prod = thm "inj_on_Abs_Prod";
  1099 val mem_Sigma_iff = thm "mem_Sigma_iff";
  1100 val mem_splitE = thm "mem_splitE";
  1101 val mem_splitI = thm "mem_splitI";
  1102 val mem_splitI2 = thm "mem_splitI2";
  1103 val prod_eqI = thm "prod_eqI";
  1104 val prod_fun = thm "prod_fun";
  1105 val prod_fun_compose = thm "prod_fun_compose";
  1106 val prod_fun_def = thm "prod_fun_def";
  1107 val prod_fun_ident = thm "prod_fun_ident";
  1108 val prod_fun_imageE = thm "prod_fun_imageE";
  1109 val prod_fun_imageI = thm "prod_fun_imageI";
  1110 val prod_induct = thm "prod.induct";
  1111 val snd_conv = thm "snd_conv";
  1112 val snd_def = thm "snd_def";
  1113 val snd_eqD = thm "snd_eqD";
  1114 val split = thm "split";
  1115 val splitD = thm "splitD";
  1116 val splitD' = thm "splitD'";
  1117 val splitE = thm "splitE";
  1118 val splitE' = thm "splitE'";
  1119 val splitE2 = thm "splitE2";
  1120 val splitI = thm "splitI";
  1121 val splitI2 = thm "splitI2";
  1122 val splitI2' = thm "splitI2'";
  1123 val split_beta = thm "split_beta";
  1124 val split_conv = thm "split_conv";
  1125 val split_def = thm "split_def";
  1126 val split_eta = thm "split_eta";
  1127 val split_eta_SetCompr = thm "split_eta_SetCompr";
  1128 val split_eta_SetCompr2 = thm "split_eta_SetCompr2";
  1129 val split_paired_All = thm "split_paired_All";
  1130 val split_paired_Ball_Sigma = thm "split_paired_Ball_Sigma";
  1131 val split_paired_Bex_Sigma = thm "split_paired_Bex_Sigma";
  1132 val split_paired_Ex = thm "split_paired_Ex";
  1133 val split_paired_The = thm "split_paired_The";
  1134 val split_paired_all = thm "split_paired_all";
  1135 val split_part = thm "split_part";
  1136 val split_split = thm "split_split";
  1137 val split_split_asm = thm "split_split_asm";
  1138 val split_tupled_all = thms "split_tupled_all";
  1139 val split_weak_cong = thm "split_weak_cong";
  1140 val surj_pair = thm "surj_pair";
  1141 val surjective_pairing = thm "surjective_pairing";
  1142 val unit_abs_eta_conv = thm "unit_abs_eta_conv";
  1143 val unit_all_eq1 = thm "unit_all_eq1";
  1144 val unit_all_eq2 = thm "unit_all_eq2";
  1145 val unit_eq = thm "unit_eq";
  1146 *}
  1147 
  1148 
  1149 subsection {* Further inductive packages *}
  1150 
  1151 use "Tools/inductive_realizer.ML"
  1152 setup InductiveRealizer.setup
  1153 
  1154 use "Tools/inductive_set.ML"
  1155 setup Inductive_Set.setup
  1156 
  1157 use "Tools/Datatype/datatype_realizer.ML"
  1158 setup DatatypeRealizer.setup
  1159 
  1160 end