src/HOL/Library/Multiset.thy
 author haftmann Thu Nov 18 17:01:16 2010 +0100 (2010-11-18) changeset 40606 af1a0b0c6202 parent 40347 429bf4388b2f child 40950 a370b0fb6f09 permissions -rw-r--r--
mapper for mulitset type
```     1 (*  Title:      HOL/Library/Multiset.thy
```
```     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
```
```     3 *)
```
```     4
```
```     5 header {* (Finite) multisets *}
```
```     6
```
```     7 theory Multiset
```
```     8 imports Main
```
```     9 begin
```
```    10
```
```    11 subsection {* The type of multisets *}
```
```    12
```
```    13 typedef 'a multiset = "{f :: 'a => nat. finite {x. f x > 0}}"
```
```    14   morphisms count Abs_multiset
```
```    15 proof
```
```    16   show "(\<lambda>x. 0::nat) \<in> ?multiset" by simp
```
```    17 qed
```
```    18
```
```    19 lemmas multiset_typedef = Abs_multiset_inverse count_inverse count
```
```    20
```
```    21 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
```
```    22   "a :# M == 0 < count M a"
```
```    23
```
```    24 notation (xsymbols)
```
```    25   Melem (infix "\<in>#" 50)
```
```    26
```
```    27 lemma multiset_eq_iff:
```
```    28   "M = N \<longleftrightarrow> (\<forall>a. count M a = count N a)"
```
```    29   by (simp only: count_inject [symmetric] fun_eq_iff)
```
```    30
```
```    31 lemma multiset_eqI:
```
```    32   "(\<And>x. count A x = count B x) \<Longrightarrow> A = B"
```
```    33   using multiset_eq_iff by auto
```
```    34
```
```    35 text {*
```
```    36  \medskip Preservation of the representing set @{term multiset}.
```
```    37 *}
```
```    38
```
```    39 lemma const0_in_multiset:
```
```    40   "(\<lambda>a. 0) \<in> multiset"
```
```    41   by (simp add: multiset_def)
```
```    42
```
```    43 lemma only1_in_multiset:
```
```    44   "(\<lambda>b. if b = a then n else 0) \<in> multiset"
```
```    45   by (simp add: multiset_def)
```
```    46
```
```    47 lemma union_preserves_multiset:
```
```    48   "M \<in> multiset \<Longrightarrow> N \<in> multiset \<Longrightarrow> (\<lambda>a. M a + N a) \<in> multiset"
```
```    49   by (simp add: multiset_def)
```
```    50
```
```    51 lemma diff_preserves_multiset:
```
```    52   assumes "M \<in> multiset"
```
```    53   shows "(\<lambda>a. M a - N a) \<in> multiset"
```
```    54 proof -
```
```    55   have "{x. N x < M x} \<subseteq> {x. 0 < M x}"
```
```    56     by auto
```
```    57   with assms show ?thesis
```
```    58     by (auto simp add: multiset_def intro: finite_subset)
```
```    59 qed
```
```    60
```
```    61 lemma MCollect_preserves_multiset:
```
```    62   assumes "M \<in> multiset"
```
```    63   shows "(\<lambda>x. if P x then M x else 0) \<in> multiset"
```
```    64 proof -
```
```    65   have "{x. (P x \<longrightarrow> 0 < M x) \<and> P x} \<subseteq> {x. 0 < M x}"
```
```    66     by auto
```
```    67   with assms show ?thesis
```
```    68     by (auto simp add: multiset_def intro: finite_subset)
```
```    69 qed
```
```    70
```
```    71 lemmas in_multiset = const0_in_multiset only1_in_multiset
```
```    72   union_preserves_multiset diff_preserves_multiset MCollect_preserves_multiset
```
```    73
```
```    74
```
```    75 subsection {* Representing multisets *}
```
```    76
```
```    77 text {* Multiset comprehension *}
```
```    78
```
```    79 definition MCollect :: "'a multiset => ('a => bool) => 'a multiset" where
```
```    80   "MCollect M P = Abs_multiset (\<lambda>x. if P x then count M x else 0)"
```
```    81
```
```    82 syntax
```
```    83   "_MCollect" :: "pttrn => 'a multiset => bool => 'a multiset"    ("(1{# _ :# _./ _#})")
```
```    84 translations
```
```    85   "{#x :# M. P#}" == "CONST MCollect M (\<lambda>x. P)"
```
```    86
```
```    87
```
```    88 text {* Multiset enumeration *}
```
```    89
```
```    90 instantiation multiset :: (type) "{zero, plus}"
```
```    91 begin
```
```    92
```
```    93 definition Mempty_def:
```
```    94   "0 = Abs_multiset (\<lambda>a. 0)"
```
```    95
```
```    96 abbreviation Mempty :: "'a multiset" ("{#}") where
```
```    97   "Mempty \<equiv> 0"
```
```    98
```
```    99 definition union_def:
```
```   100   "M + N = Abs_multiset (\<lambda>a. count M a + count N a)"
```
```   101
```
```   102 instance ..
```
```   103
```
```   104 end
```
```   105
```
```   106 definition single :: "'a => 'a multiset" where
```
```   107   "single a = Abs_multiset (\<lambda>b. if b = a then 1 else 0)"
```
```   108
```
```   109 syntax
```
```   110   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
```
```   111 translations
```
```   112   "{#x, xs#}" == "{#x#} + {#xs#}"
```
```   113   "{#x#}" == "CONST single x"
```
```   114
```
```   115 lemma count_empty [simp]: "count {#} a = 0"
```
```   116   by (simp add: Mempty_def in_multiset multiset_typedef)
```
```   117
```
```   118 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
```
```   119   by (simp add: single_def in_multiset multiset_typedef)
```
```   120
```
```   121
```
```   122 subsection {* Basic operations *}
```
```   123
```
```   124 subsubsection {* Union *}
```
```   125
```
```   126 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
```
```   127   by (simp add: union_def in_multiset multiset_typedef)
```
```   128
```
```   129 instance multiset :: (type) cancel_comm_monoid_add proof
```
```   130 qed (simp_all add: multiset_eq_iff)
```
```   131
```
```   132
```
```   133 subsubsection {* Difference *}
```
```   134
```
```   135 instantiation multiset :: (type) minus
```
```   136 begin
```
```   137
```
```   138 definition diff_def:
```
```   139   "M - N = Abs_multiset (\<lambda>a. count M a - count N a)"
```
```   140
```
```   141 instance ..
```
```   142
```
```   143 end
```
```   144
```
```   145 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
```
```   146   by (simp add: diff_def in_multiset multiset_typedef)
```
```   147
```
```   148 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
```
```   149 by(simp add: multiset_eq_iff)
```
```   150
```
```   151 lemma diff_cancel[simp]: "A - A = {#}"
```
```   152 by (rule multiset_eqI) simp
```
```   153
```
```   154 lemma diff_union_cancelR [simp]: "M + N - N = (M::'a multiset)"
```
```   155 by(simp add: multiset_eq_iff)
```
```   156
```
```   157 lemma diff_union_cancelL [simp]: "N + M - N = (M::'a multiset)"
```
```   158 by(simp add: multiset_eq_iff)
```
```   159
```
```   160 lemma insert_DiffM:
```
```   161   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
```
```   162   by (clarsimp simp: multiset_eq_iff)
```
```   163
```
```   164 lemma insert_DiffM2 [simp]:
```
```   165   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
```
```   166   by (clarsimp simp: multiset_eq_iff)
```
```   167
```
```   168 lemma diff_right_commute:
```
```   169   "(M::'a multiset) - N - Q = M - Q - N"
```
```   170   by (auto simp add: multiset_eq_iff)
```
```   171
```
```   172 lemma diff_add:
```
```   173   "(M::'a multiset) - (N + Q) = M - N - Q"
```
```   174 by (simp add: multiset_eq_iff)
```
```   175
```
```   176 lemma diff_union_swap:
```
```   177   "a \<noteq> b \<Longrightarrow> M - {#a#} + {#b#} = M + {#b#} - {#a#}"
```
```   178   by (auto simp add: multiset_eq_iff)
```
```   179
```
```   180 lemma diff_union_single_conv:
```
```   181   "a \<in># J \<Longrightarrow> I + J - {#a#} = I + (J - {#a#})"
```
```   182   by (simp add: multiset_eq_iff)
```
```   183
```
```   184
```
```   185 subsubsection {* Equality of multisets *}
```
```   186
```
```   187 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
```
```   188   by (simp add: multiset_eq_iff)
```
```   189
```
```   190 lemma single_eq_single [simp]: "{#a#} = {#b#} \<longleftrightarrow> a = b"
```
```   191   by (auto simp add: multiset_eq_iff)
```
```   192
```
```   193 lemma union_eq_empty [iff]: "M + N = {#} \<longleftrightarrow> M = {#} \<and> N = {#}"
```
```   194   by (auto simp add: multiset_eq_iff)
```
```   195
```
```   196 lemma empty_eq_union [iff]: "{#} = M + N \<longleftrightarrow> M = {#} \<and> N = {#}"
```
```   197   by (auto simp add: multiset_eq_iff)
```
```   198
```
```   199 lemma multi_self_add_other_not_self [simp]: "M = M + {#x#} \<longleftrightarrow> False"
```
```   200   by (auto simp add: multiset_eq_iff)
```
```   201
```
```   202 lemma diff_single_trivial:
```
```   203   "\<not> x \<in># M \<Longrightarrow> M - {#x#} = M"
```
```   204   by (auto simp add: multiset_eq_iff)
```
```   205
```
```   206 lemma diff_single_eq_union:
```
```   207   "x \<in># M \<Longrightarrow> M - {#x#} = N \<longleftrightarrow> M = N + {#x#}"
```
```   208   by auto
```
```   209
```
```   210 lemma union_single_eq_diff:
```
```   211   "M + {#x#} = N \<Longrightarrow> M = N - {#x#}"
```
```   212   by (auto dest: sym)
```
```   213
```
```   214 lemma union_single_eq_member:
```
```   215   "M + {#x#} = N \<Longrightarrow> x \<in># N"
```
```   216   by auto
```
```   217
```
```   218 lemma union_is_single:
```
```   219   "M + N = {#a#} \<longleftrightarrow> M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#}" (is "?lhs = ?rhs")proof
```
```   220   assume ?rhs then show ?lhs by auto
```
```   221 next
```
```   222   assume ?lhs thus ?rhs
```
```   223     by(simp add: multiset_eq_iff split:if_splits) (metis add_is_1)
```
```   224 qed
```
```   225
```
```   226 lemma single_is_union:
```
```   227   "{#a#} = M + N \<longleftrightarrow> {#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N"
```
```   228   by (auto simp add: eq_commute [of "{#a#}" "M + N"] union_is_single)
```
```   229
```
```   230 lemma add_eq_conv_diff:
```
```   231   "M + {#a#} = N + {#b#} \<longleftrightarrow> M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#}"  (is "?lhs = ?rhs")
```
```   232 (* shorter: by (simp add: multiset_eq_iff) fastsimp *)
```
```   233 proof
```
```   234   assume ?rhs then show ?lhs
```
```   235   by (auto simp add: add_assoc add_commute [of "{#b#}"])
```
```   236     (drule sym, simp add: add_assoc [symmetric])
```
```   237 next
```
```   238   assume ?lhs
```
```   239   show ?rhs
```
```   240   proof (cases "a = b")
```
```   241     case True with `?lhs` show ?thesis by simp
```
```   242   next
```
```   243     case False
```
```   244     from `?lhs` have "a \<in># N + {#b#}" by (rule union_single_eq_member)
```
```   245     with False have "a \<in># N" by auto
```
```   246     moreover from `?lhs` have "M = N + {#b#} - {#a#}" by (rule union_single_eq_diff)
```
```   247     moreover note False
```
```   248     ultimately show ?thesis by (auto simp add: diff_right_commute [of _ "{#a#}"] diff_union_swap)
```
```   249   qed
```
```   250 qed
```
```   251
```
```   252 lemma insert_noteq_member:
```
```   253   assumes BC: "B + {#b#} = C + {#c#}"
```
```   254    and bnotc: "b \<noteq> c"
```
```   255   shows "c \<in># B"
```
```   256 proof -
```
```   257   have "c \<in># C + {#c#}" by simp
```
```   258   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
```
```   259   then have "c \<in># B + {#b#}" using BC by simp
```
```   260   then show "c \<in># B" using nc by simp
```
```   261 qed
```
```   262
```
```   263 lemma add_eq_conv_ex:
```
```   264   "(M + {#a#} = N + {#b#}) =
```
```   265     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
```
```   266   by (auto simp add: add_eq_conv_diff)
```
```   267
```
```   268
```
```   269 subsubsection {* Pointwise ordering induced by count *}
```
```   270
```
```   271 instantiation multiset :: (type) ordered_ab_semigroup_add_imp_le
```
```   272 begin
```
```   273
```
```   274 definition less_eq_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
```
```   275   mset_le_def: "A \<le> B \<longleftrightarrow> (\<forall>a. count A a \<le> count B a)"
```
```   276
```
```   277 definition less_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" where
```
```   278   mset_less_def: "(A::'a multiset) < B \<longleftrightarrow> A \<le> B \<and> A \<noteq> B"
```
```   279
```
```   280 instance proof
```
```   281 qed (auto simp add: mset_le_def mset_less_def multiset_eq_iff intro: order_trans antisym)
```
```   282
```
```   283 end
```
```   284
```
```   285 lemma mset_less_eqI:
```
```   286   "(\<And>x. count A x \<le> count B x) \<Longrightarrow> A \<le> B"
```
```   287   by (simp add: mset_le_def)
```
```   288
```
```   289 lemma mset_le_exists_conv:
```
```   290   "(A::'a multiset) \<le> B \<longleftrightarrow> (\<exists>C. B = A + C)"
```
```   291 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
```
```   292 apply (auto intro: multiset_eq_iff [THEN iffD2])
```
```   293 done
```
```   294
```
```   295 lemma mset_le_mono_add_right_cancel [simp]:
```
```   296   "(A::'a multiset) + C \<le> B + C \<longleftrightarrow> A \<le> B"
```
```   297   by (fact add_le_cancel_right)
```
```   298
```
```   299 lemma mset_le_mono_add_left_cancel [simp]:
```
```   300   "C + (A::'a multiset) \<le> C + B \<longleftrightarrow> A \<le> B"
```
```   301   by (fact add_le_cancel_left)
```
```   302
```
```   303 lemma mset_le_mono_add:
```
```   304   "(A::'a multiset) \<le> B \<Longrightarrow> C \<le> D \<Longrightarrow> A + C \<le> B + D"
```
```   305   by (fact add_mono)
```
```   306
```
```   307 lemma mset_le_add_left [simp]:
```
```   308   "(A::'a multiset) \<le> A + B"
```
```   309   unfolding mset_le_def by auto
```
```   310
```
```   311 lemma mset_le_add_right [simp]:
```
```   312   "B \<le> (A::'a multiset) + B"
```
```   313   unfolding mset_le_def by auto
```
```   314
```
```   315 lemma mset_le_single:
```
```   316   "a :# B \<Longrightarrow> {#a#} \<le> B"
```
```   317   by (simp add: mset_le_def)
```
```   318
```
```   319 lemma multiset_diff_union_assoc:
```
```   320   "C \<le> B \<Longrightarrow> (A::'a multiset) + B - C = A + (B - C)"
```
```   321   by (simp add: multiset_eq_iff mset_le_def)
```
```   322
```
```   323 lemma mset_le_multiset_union_diff_commute:
```
```   324   "B \<le> A \<Longrightarrow> (A::'a multiset) - B + C = A + C - B"
```
```   325 by (simp add: multiset_eq_iff mset_le_def)
```
```   326
```
```   327 lemma diff_le_self[simp]: "(M::'a multiset) - N \<le> M"
```
```   328 by(simp add: mset_le_def)
```
```   329
```
```   330 lemma mset_lessD: "A < B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
```
```   331 apply (clarsimp simp: mset_le_def mset_less_def)
```
```   332 apply (erule_tac x=x in allE)
```
```   333 apply auto
```
```   334 done
```
```   335
```
```   336 lemma mset_leD: "A \<le> B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
```
```   337 apply (clarsimp simp: mset_le_def mset_less_def)
```
```   338 apply (erule_tac x = x in allE)
```
```   339 apply auto
```
```   340 done
```
```   341
```
```   342 lemma mset_less_insertD: "(A + {#x#} < B) \<Longrightarrow> (x \<in># B \<and> A < B)"
```
```   343 apply (rule conjI)
```
```   344  apply (simp add: mset_lessD)
```
```   345 apply (clarsimp simp: mset_le_def mset_less_def)
```
```   346 apply safe
```
```   347  apply (erule_tac x = a in allE)
```
```   348  apply (auto split: split_if_asm)
```
```   349 done
```
```   350
```
```   351 lemma mset_le_insertD: "(A + {#x#} \<le> B) \<Longrightarrow> (x \<in># B \<and> A \<le> B)"
```
```   352 apply (rule conjI)
```
```   353  apply (simp add: mset_leD)
```
```   354 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
```
```   355 done
```
```   356
```
```   357 lemma mset_less_of_empty[simp]: "A < {#} \<longleftrightarrow> False"
```
```   358   by (auto simp add: mset_less_def mset_le_def multiset_eq_iff)
```
```   359
```
```   360 lemma multi_psub_of_add_self[simp]: "A < A + {#x#}"
```
```   361   by (auto simp: mset_le_def mset_less_def)
```
```   362
```
```   363 lemma multi_psub_self[simp]: "(A::'a multiset) < A = False"
```
```   364   by simp
```
```   365
```
```   366 lemma mset_less_add_bothsides:
```
```   367   "T + {#x#} < S + {#x#} \<Longrightarrow> T < S"
```
```   368   by (fact add_less_imp_less_right)
```
```   369
```
```   370 lemma mset_less_empty_nonempty:
```
```   371   "{#} < S \<longleftrightarrow> S \<noteq> {#}"
```
```   372   by (auto simp: mset_le_def mset_less_def)
```
```   373
```
```   374 lemma mset_less_diff_self:
```
```   375   "c \<in># B \<Longrightarrow> B - {#c#} < B"
```
```   376   by (auto simp: mset_le_def mset_less_def multiset_eq_iff)
```
```   377
```
```   378
```
```   379 subsubsection {* Intersection *}
```
```   380
```
```   381 instantiation multiset :: (type) semilattice_inf
```
```   382 begin
```
```   383
```
```   384 definition inf_multiset :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" where
```
```   385   multiset_inter_def: "inf_multiset A B = A - (A - B)"
```
```   386
```
```   387 instance proof -
```
```   388   have aux: "\<And>m n q :: nat. m \<le> n \<Longrightarrow> m \<le> q \<Longrightarrow> m \<le> n - (n - q)" by arith
```
```   389   show "OFCLASS('a multiset, semilattice_inf_class)" proof
```
```   390   qed (auto simp add: multiset_inter_def mset_le_def aux)
```
```   391 qed
```
```   392
```
```   393 end
```
```   394
```
```   395 abbreviation multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset" (infixl "#\<inter>" 70) where
```
```   396   "multiset_inter \<equiv> inf"
```
```   397
```
```   398 lemma multiset_inter_count:
```
```   399   "count (A #\<inter> B) x = min (count A x) (count B x)"
```
```   400   by (simp add: multiset_inter_def multiset_typedef)
```
```   401
```
```   402 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
```
```   403   by (rule multiset_eqI) (auto simp add: multiset_inter_count)
```
```   404
```
```   405 lemma multiset_union_diff_commute:
```
```   406   assumes "B #\<inter> C = {#}"
```
```   407   shows "A + B - C = A - C + B"
```
```   408 proof (rule multiset_eqI)
```
```   409   fix x
```
```   410   from assms have "min (count B x) (count C x) = 0"
```
```   411     by (auto simp add: multiset_inter_count multiset_eq_iff)
```
```   412   then have "count B x = 0 \<or> count C x = 0"
```
```   413     by auto
```
```   414   then show "count (A + B - C) x = count (A - C + B) x"
```
```   415     by auto
```
```   416 qed
```
```   417
```
```   418
```
```   419 subsubsection {* Comprehension (filter) *}
```
```   420
```
```   421 lemma count_MCollect [simp]:
```
```   422   "count {# x:#M. P x #} a = (if P a then count M a else 0)"
```
```   423   by (simp add: MCollect_def in_multiset multiset_typedef)
```
```   424
```
```   425 lemma MCollect_empty [simp]: "MCollect {#} P = {#}"
```
```   426   by (rule multiset_eqI) simp
```
```   427
```
```   428 lemma MCollect_single [simp]:
```
```   429   "MCollect {#x#} P = (if P x then {#x#} else {#})"
```
```   430   by (rule multiset_eqI) simp
```
```   431
```
```   432 lemma MCollect_union [simp]:
```
```   433   "MCollect (M + N) f = MCollect M f + MCollect N f"
```
```   434   by (rule multiset_eqI) simp
```
```   435
```
```   436
```
```   437 subsubsection {* Set of elements *}
```
```   438
```
```   439 definition set_of :: "'a multiset => 'a set" where
```
```   440   "set_of M = {x. x :# M}"
```
```   441
```
```   442 lemma set_of_empty [simp]: "set_of {#} = {}"
```
```   443 by (simp add: set_of_def)
```
```   444
```
```   445 lemma set_of_single [simp]: "set_of {#b#} = {b}"
```
```   446 by (simp add: set_of_def)
```
```   447
```
```   448 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
```
```   449 by (auto simp add: set_of_def)
```
```   450
```
```   451 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
```
```   452 by (auto simp add: set_of_def multiset_eq_iff)
```
```   453
```
```   454 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
```
```   455 by (auto simp add: set_of_def)
```
```   456
```
```   457 lemma set_of_MCollect [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
```
```   458 by (auto simp add: set_of_def)
```
```   459
```
```   460 lemma finite_set_of [iff]: "finite (set_of M)"
```
```   461   using count [of M] by (simp add: multiset_def set_of_def)
```
```   462
```
```   463
```
```   464 subsubsection {* Size *}
```
```   465
```
```   466 instantiation multiset :: (type) size
```
```   467 begin
```
```   468
```
```   469 definition size_def:
```
```   470   "size M = setsum (count M) (set_of M)"
```
```   471
```
```   472 instance ..
```
```   473
```
```   474 end
```
```   475
```
```   476 lemma size_empty [simp]: "size {#} = 0"
```
```   477 by (simp add: size_def)
```
```   478
```
```   479 lemma size_single [simp]: "size {#b#} = 1"
```
```   480 by (simp add: size_def)
```
```   481
```
```   482 lemma setsum_count_Int:
```
```   483   "finite A ==> setsum (count N) (A \<inter> set_of N) = setsum (count N) A"
```
```   484 apply (induct rule: finite_induct)
```
```   485  apply simp
```
```   486 apply (simp add: Int_insert_left set_of_def)
```
```   487 done
```
```   488
```
```   489 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
```
```   490 apply (unfold size_def)
```
```   491 apply (subgoal_tac "count (M + N) = (\<lambda>a. count M a + count N a)")
```
```   492  prefer 2
```
```   493  apply (rule ext, simp)
```
```   494 apply (simp (no_asm_simp) add: setsum_Un_nat setsum_addf setsum_count_Int)
```
```   495 apply (subst Int_commute)
```
```   496 apply (simp (no_asm_simp) add: setsum_count_Int)
```
```   497 done
```
```   498
```
```   499 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
```
```   500 by (auto simp add: size_def multiset_eq_iff)
```
```   501
```
```   502 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
```
```   503 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
```
```   504
```
```   505 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
```
```   506 apply (unfold size_def)
```
```   507 apply (drule setsum_SucD)
```
```   508 apply auto
```
```   509 done
```
```   510
```
```   511 lemma size_eq_Suc_imp_eq_union:
```
```   512   assumes "size M = Suc n"
```
```   513   shows "\<exists>a N. M = N + {#a#}"
```
```   514 proof -
```
```   515   from assms obtain a where "a \<in># M"
```
```   516     by (erule size_eq_Suc_imp_elem [THEN exE])
```
```   517   then have "M = M - {#a#} + {#a#}" by simp
```
```   518   then show ?thesis by blast
```
```   519 qed
```
```   520
```
```   521
```
```   522 subsection {* Induction and case splits *}
```
```   523
```
```   524 lemma setsum_decr:
```
```   525   "finite F ==> (0::nat) < f a ==>
```
```   526     setsum (f (a := f a - 1)) F = (if a\<in>F then setsum f F - 1 else setsum f F)"
```
```   527 apply (induct rule: finite_induct)
```
```   528  apply auto
```
```   529 apply (drule_tac a = a in mk_disjoint_insert, auto)
```
```   530 done
```
```   531
```
```   532 lemma rep_multiset_induct_aux:
```
```   533 assumes 1: "P (\<lambda>a. (0::nat))"
```
```   534   and 2: "!!f b. f \<in> multiset ==> P f ==> P (f (b := f b + 1))"
```
```   535 shows "\<forall>f. f \<in> multiset --> setsum f {x. f x \<noteq> 0} = n --> P f"
```
```   536 apply (unfold multiset_def)
```
```   537 apply (induct_tac n, simp, clarify)
```
```   538  apply (subgoal_tac "f = (\<lambda>a.0)")
```
```   539   apply simp
```
```   540   apply (rule 1)
```
```   541  apply (rule ext, force, clarify)
```
```   542 apply (frule setsum_SucD, clarify)
```
```   543 apply (rename_tac a)
```
```   544 apply (subgoal_tac "finite {x. (f (a := f a - 1)) x > 0}")
```
```   545  prefer 2
```
```   546  apply (rule finite_subset)
```
```   547   prefer 2
```
```   548   apply assumption
```
```   549  apply simp
```
```   550  apply blast
```
```   551 apply (subgoal_tac "f = (f (a := f a - 1))(a := (f (a := f a - 1)) a + 1)")
```
```   552  prefer 2
```
```   553  apply (rule ext)
```
```   554  apply (simp (no_asm_simp))
```
```   555  apply (erule ssubst, rule 2 [unfolded multiset_def], blast)
```
```   556 apply (erule allE, erule impE, erule_tac  mp, blast)
```
```   557 apply (simp (no_asm_simp) add: setsum_decr del: fun_upd_apply One_nat_def)
```
```   558 apply (subgoal_tac "{x. x \<noteq> a --> f x \<noteq> 0} = {x. f x \<noteq> 0}")
```
```   559  prefer 2
```
```   560  apply blast
```
```   561 apply (subgoal_tac "{x. x \<noteq> a \<and> f x \<noteq> 0} = {x. f x \<noteq> 0} - {a}")
```
```   562  prefer 2
```
```   563  apply blast
```
```   564 apply (simp add: le_imp_diff_is_add setsum_diff1_nat cong: conj_cong)
```
```   565 done
```
```   566
```
```   567 theorem rep_multiset_induct:
```
```   568   "f \<in> multiset ==> P (\<lambda>a. 0) ==>
```
```   569     (!!f b. f \<in> multiset ==> P f ==> P (f (b := f b + 1))) ==> P f"
```
```   570 using rep_multiset_induct_aux by blast
```
```   571
```
```   572 theorem multiset_induct [case_names empty add, induct type: multiset]:
```
```   573 assumes empty: "P {#}"
```
```   574   and add: "!!M x. P M ==> P (M + {#x#})"
```
```   575 shows "P M"
```
```   576 proof -
```
```   577   note defns = union_def single_def Mempty_def
```
```   578   note add' = add [unfolded defns, simplified]
```
```   579   have aux: "\<And>a::'a. count (Abs_multiset (\<lambda>b. if b = a then 1 else 0)) =
```
```   580     (\<lambda>b. if b = a then 1 else 0)" by (simp add: Abs_multiset_inverse in_multiset)
```
```   581   show ?thesis
```
```   582     apply (rule count_inverse [THEN subst])
```
```   583     apply (rule count [THEN rep_multiset_induct])
```
```   584      apply (rule empty [unfolded defns])
```
```   585     apply (subgoal_tac "f(b := f b + 1) = (\<lambda>a. f a + (if a=b then 1 else 0))")
```
```   586      prefer 2
```
```   587      apply (simp add: fun_eq_iff)
```
```   588     apply (erule ssubst)
```
```   589     apply (erule Abs_multiset_inverse [THEN subst])
```
```   590     apply (drule add')
```
```   591     apply (simp add: aux)
```
```   592     done
```
```   593 qed
```
```   594
```
```   595 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
```
```   596 by (induct M) auto
```
```   597
```
```   598 lemma multiset_cases [cases type, case_names empty add]:
```
```   599 assumes em:  "M = {#} \<Longrightarrow> P"
```
```   600 assumes add: "\<And>N x. M = N + {#x#} \<Longrightarrow> P"
```
```   601 shows "P"
```
```   602 proof (cases "M = {#}")
```
```   603   assume "M = {#}" then show ?thesis using em by simp
```
```   604 next
```
```   605   assume "M \<noteq> {#}"
```
```   606   then obtain M' m where "M = M' + {#m#}"
```
```   607     by (blast dest: multi_nonempty_split)
```
```   608   then show ?thesis using add by simp
```
```   609 qed
```
```   610
```
```   611 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
```
```   612 apply (cases M)
```
```   613  apply simp
```
```   614 apply (rule_tac x="M - {#x#}" in exI, simp)
```
```   615 done
```
```   616
```
```   617 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
```
```   618 by (cases "B = {#}") (auto dest: multi_member_split)
```
```   619
```
```   620 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
```
```   621 apply (subst multiset_eq_iff)
```
```   622 apply auto
```
```   623 done
```
```   624
```
```   625 lemma mset_less_size: "(A::'a multiset) < B \<Longrightarrow> size A < size B"
```
```   626 proof (induct A arbitrary: B)
```
```   627   case (empty M)
```
```   628   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
```
```   629   then obtain M' x where "M = M' + {#x#}"
```
```   630     by (blast dest: multi_nonempty_split)
```
```   631   then show ?case by simp
```
```   632 next
```
```   633   case (add S x T)
```
```   634   have IH: "\<And>B. S < B \<Longrightarrow> size S < size B" by fact
```
```   635   have SxsubT: "S + {#x#} < T" by fact
```
```   636   then have "x \<in># T" and "S < T" by (auto dest: mset_less_insertD)
```
```   637   then obtain T' where T: "T = T' + {#x#}"
```
```   638     by (blast dest: multi_member_split)
```
```   639   then have "S < T'" using SxsubT
```
```   640     by (blast intro: mset_less_add_bothsides)
```
```   641   then have "size S < size T'" using IH by simp
```
```   642   then show ?case using T by simp
```
```   643 qed
```
```   644
```
```   645
```
```   646 subsubsection {* Strong induction and subset induction for multisets *}
```
```   647
```
```   648 text {* Well-foundedness of proper subset operator: *}
```
```   649
```
```   650 text {* proper multiset subset *}
```
```   651
```
```   652 definition
```
```   653   mset_less_rel :: "('a multiset * 'a multiset) set" where
```
```   654   "mset_less_rel = {(A,B). A < B}"
```
```   655
```
```   656 lemma multiset_add_sub_el_shuffle:
```
```   657   assumes "c \<in># B" and "b \<noteq> c"
```
```   658   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
```
```   659 proof -
```
```   660   from `c \<in># B` obtain A where B: "B = A + {#c#}"
```
```   661     by (blast dest: multi_member_split)
```
```   662   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
```
```   663   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}"
```
```   664     by (simp add: add_ac)
```
```   665   then show ?thesis using B by simp
```
```   666 qed
```
```   667
```
```   668 lemma wf_mset_less_rel: "wf mset_less_rel"
```
```   669 apply (unfold mset_less_rel_def)
```
```   670 apply (rule wf_measure [THEN wf_subset, where f1=size])
```
```   671 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
```
```   672 done
```
```   673
```
```   674 text {* The induction rules: *}
```
```   675
```
```   676 lemma full_multiset_induct [case_names less]:
```
```   677 assumes ih: "\<And>B. \<forall>(A::'a multiset). A < B \<longrightarrow> P A \<Longrightarrow> P B"
```
```   678 shows "P B"
```
```   679 apply (rule wf_mset_less_rel [THEN wf_induct])
```
```   680 apply (rule ih, auto simp: mset_less_rel_def)
```
```   681 done
```
```   682
```
```   683 lemma multi_subset_induct [consumes 2, case_names empty add]:
```
```   684 assumes "F \<le> A"
```
```   685   and empty: "P {#}"
```
```   686   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
```
```   687 shows "P F"
```
```   688 proof -
```
```   689   from `F \<le> A`
```
```   690   show ?thesis
```
```   691   proof (induct F)
```
```   692     show "P {#}" by fact
```
```   693   next
```
```   694     fix x F
```
```   695     assume P: "F \<le> A \<Longrightarrow> P F" and i: "F + {#x#} \<le> A"
```
```   696     show "P (F + {#x#})"
```
```   697     proof (rule insert)
```
```   698       from i show "x \<in># A" by (auto dest: mset_le_insertD)
```
```   699       from i have "F \<le> A" by (auto dest: mset_le_insertD)
```
```   700       with P show "P F" .
```
```   701     qed
```
```   702   qed
```
```   703 qed
```
```   704
```
```   705
```
```   706 subsection {* Alternative representations *}
```
```   707
```
```   708 subsubsection {* Lists *}
```
```   709
```
```   710 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
```
```   711   "multiset_of [] = {#}" |
```
```   712   "multiset_of (a # x) = multiset_of x + {# a #}"
```
```   713
```
```   714 lemma in_multiset_in_set:
```
```   715   "x \<in># multiset_of xs \<longleftrightarrow> x \<in> set xs"
```
```   716   by (induct xs) simp_all
```
```   717
```
```   718 lemma count_multiset_of:
```
```   719   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
```
```   720   by (induct xs) simp_all
```
```   721
```
```   722 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
```
```   723 by (induct x) auto
```
```   724
```
```   725 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
```
```   726 by (induct x) auto
```
```   727
```
```   728 lemma set_of_multiset_of[simp]: "set_of(multiset_of x) = set x"
```
```   729 by (induct x) auto
```
```   730
```
```   731 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
```
```   732 by (induct xs) auto
```
```   733
```
```   734 lemma multiset_of_append [simp]:
```
```   735   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
```
```   736   by (induct xs arbitrary: ys) (auto simp: add_ac)
```
```   737
```
```   738 lemma multiset_of_filter:
```
```   739   "multiset_of (filter P xs) = {#x :# multiset_of xs. P x #}"
```
```   740   by (induct xs) simp_all
```
```   741
```
```   742 lemma surj_multiset_of: "surj multiset_of"
```
```   743 apply (unfold surj_def)
```
```   744 apply (rule allI)
```
```   745 apply (rule_tac M = y in multiset_induct)
```
```   746  apply auto
```
```   747 apply (rule_tac x = "x # xa" in exI)
```
```   748 apply auto
```
```   749 done
```
```   750
```
```   751 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
```
```   752 by (induct x) auto
```
```   753
```
```   754 lemma distinct_count_atmost_1:
```
```   755   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
```
```   756 apply (induct x, simp, rule iffI, simp_all)
```
```   757 apply (rule conjI)
```
```   758 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
```
```   759 apply (erule_tac x = a in allE, simp, clarify)
```
```   760 apply (erule_tac x = aa in allE, simp)
```
```   761 done
```
```   762
```
```   763 lemma multiset_of_eq_setD:
```
```   764   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
```
```   765 by (rule) (auto simp add:multiset_eq_iff set_count_greater_0)
```
```   766
```
```   767 lemma set_eq_iff_multiset_of_eq_distinct:
```
```   768   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
```
```   769     (set x = set y) = (multiset_of x = multiset_of y)"
```
```   770 by (auto simp: multiset_eq_iff distinct_count_atmost_1)
```
```   771
```
```   772 lemma set_eq_iff_multiset_of_remdups_eq:
```
```   773    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
```
```   774 apply (rule iffI)
```
```   775 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
```
```   776 apply (drule distinct_remdups [THEN distinct_remdups
```
```   777       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
```
```   778 apply simp
```
```   779 done
```
```   780
```
```   781 lemma multiset_of_compl_union [simp]:
```
```   782   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
```
```   783   by (induct xs) (auto simp: add_ac)
```
```   784
```
```   785 lemma count_filter:
```
```   786   "count (multiset_of xs) x = length (filter (\<lambda>y. x = y) xs)"
```
```   787   by (induct xs) auto
```
```   788
```
```   789 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
```
```   790 apply (induct ls arbitrary: i)
```
```   791  apply simp
```
```   792 apply (case_tac i)
```
```   793  apply auto
```
```   794 done
```
```   795
```
```   796 lemma multiset_of_remove1[simp]:
```
```   797   "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
```
```   798 by (induct xs) (auto simp add: multiset_eq_iff)
```
```   799
```
```   800 lemma multiset_of_eq_length:
```
```   801   assumes "multiset_of xs = multiset_of ys"
```
```   802   shows "length xs = length ys"
```
```   803 using assms proof (induct xs arbitrary: ys)
```
```   804   case Nil then show ?case by simp
```
```   805 next
```
```   806   case (Cons x xs)
```
```   807   then have "x \<in># multiset_of ys" by (simp add: union_single_eq_member)
```
```   808   then have "x \<in> set ys" by (simp add: in_multiset_in_set)
```
```   809   from Cons.prems [symmetric] have "multiset_of xs = multiset_of (remove1 x ys)"
```
```   810     by simp
```
```   811   with Cons.hyps have "length xs = length (remove1 x ys)" .
```
```   812   with `x \<in> set ys` show ?case
```
```   813     by (auto simp add: length_remove1 dest: length_pos_if_in_set)
```
```   814 qed
```
```   815
```
```   816 lemma multiset_of_eq_length_filter:
```
```   817   assumes "multiset_of xs = multiset_of ys"
```
```   818   shows "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) ys)"
```
```   819 proof (cases "z \<in># multiset_of xs")
```
```   820   case False
```
```   821   moreover have "\<not> z \<in># multiset_of ys" using assms False by simp
```
```   822   ultimately show ?thesis by (simp add: count_filter)
```
```   823 next
```
```   824   case True
```
```   825   moreover have "z \<in># multiset_of ys" using assms True by simp
```
```   826   show ?thesis using assms proof (induct xs arbitrary: ys)
```
```   827     case Nil then show ?case by simp
```
```   828   next
```
```   829     case (Cons x xs)
```
```   830     from `multiset_of (x # xs) = multiset_of ys` [symmetric]
```
```   831       have *: "multiset_of xs = multiset_of (remove1 x ys)"
```
```   832       and "x \<in> set ys"
```
```   833       by (auto simp add: mem_set_multiset_eq)
```
```   834     from * have "length (filter (\<lambda>x. z = x) xs) = length (filter (\<lambda>y. z = y) (remove1 x ys))" by (rule Cons.hyps)
```
```   835     moreover from `x \<in> set ys` have "length (filter (\<lambda>y. x = y) ys) > 0" by (simp add: filter_empty_conv)
```
```   836     ultimately show ?case using `x \<in> set ys`
```
```   837       by (simp add: filter_remove1) (auto simp add: length_remove1)
```
```   838   qed
```
```   839 qed
```
```   840
```
```   841 context linorder
```
```   842 begin
```
```   843
```
```   844 lemma multiset_of_insort [simp]:
```
```   845   "multiset_of (insort_key k x xs) = {#x#} + multiset_of xs"
```
```   846   by (induct xs) (simp_all add: ac_simps)
```
```   847
```
```   848 lemma multiset_of_sort [simp]:
```
```   849   "multiset_of (sort_key k xs) = multiset_of xs"
```
```   850   by (induct xs) (simp_all add: ac_simps)
```
```   851
```
```   852 text {*
```
```   853   This lemma shows which properties suffice to show that a function
```
```   854   @{text "f"} with @{text "f xs = ys"} behaves like sort.
```
```   855 *}
```
```   856
```
```   857 lemma properties_for_sort_key:
```
```   858   assumes "multiset_of ys = multiset_of xs"
```
```   859   and "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>x. f k = f x) ys = filter (\<lambda>x. f k = f x) xs"
```
```   860   and "sorted (map f ys)"
```
```   861   shows "sort_key f xs = ys"
```
```   862 using assms proof (induct xs arbitrary: ys)
```
```   863   case Nil then show ?case by simp
```
```   864 next
```
```   865   case (Cons x xs)
```
```   866   from Cons.prems(2) have
```
```   867     "\<forall>k \<in> set ys. filter (\<lambda>x. f k = f x) (remove1 x ys) = filter (\<lambda>x. f k = f x) xs"
```
```   868     by (simp add: filter_remove1)
```
```   869   with Cons.prems have "sort_key f xs = remove1 x ys"
```
```   870     by (auto intro!: Cons.hyps simp add: sorted_map_remove1)
```
```   871   moreover from Cons.prems have "x \<in> set ys"
```
```   872     by (auto simp add: mem_set_multiset_eq intro!: ccontr)
```
```   873   ultimately show ?case using Cons.prems by (simp add: insort_key_remove1)
```
```   874 qed
```
```   875
```
```   876 lemma properties_for_sort:
```
```   877   assumes multiset: "multiset_of ys = multiset_of xs"
```
```   878   and "sorted ys"
```
```   879   shows "sort xs = ys"
```
```   880 proof (rule properties_for_sort_key)
```
```   881   from multiset show "multiset_of ys = multiset_of xs" .
```
```   882   from `sorted ys` show "sorted (map (\<lambda>x. x) ys)" by simp
```
```   883   from multiset have "\<And>k. length (filter (\<lambda>y. k = y) ys) = length (filter (\<lambda>x. k = x) xs)"
```
```   884     by (rule multiset_of_eq_length_filter)
```
```   885   then have "\<And>k. replicate (length (filter (\<lambda>y. k = y) ys)) k = replicate (length (filter (\<lambda>x. k = x) xs)) k"
```
```   886     by simp
```
```   887   then show "\<And>k. k \<in> set ys \<Longrightarrow> filter (\<lambda>y. k = y) ys = filter (\<lambda>x. k = x) xs"
```
```   888     by (simp add: replicate_length_filter)
```
```   889 qed
```
```   890
```
```   891 lemma sort_key_by_quicksort:
```
```   892   "sort_key f xs = sort_key f [x\<leftarrow>xs. f x < f (xs ! (length xs div 2))]
```
```   893     @ [x\<leftarrow>xs. f x = f (xs ! (length xs div 2))]
```
```   894     @ sort_key f [x\<leftarrow>xs. f x > f (xs ! (length xs div 2))]" (is "sort_key f ?lhs = ?rhs")
```
```   895 proof (rule properties_for_sort_key)
```
```   896   show "multiset_of ?rhs = multiset_of ?lhs"
```
```   897     by (rule multiset_eqI) (auto simp add: multiset_of_filter)
```
```   898 next
```
```   899   show "sorted (map f ?rhs)"
```
```   900     by (auto simp add: sorted_append intro: sorted_map_same)
```
```   901 next
```
```   902   fix l
```
```   903   assume "l \<in> set ?rhs"
```
```   904   let ?pivot = "f (xs ! (length xs div 2))"
```
```   905   have *: "\<And>x. f l = f x \<longleftrightarrow> f x = f l" by auto
```
```   906   have "[x \<leftarrow> sort_key f xs . f x = f l] = [x \<leftarrow> xs. f x = f l]"
```
```   907     unfolding filter_sort by (rule properties_for_sort_key) (auto intro: sorted_map_same)
```
```   908   with * have **: "[x \<leftarrow> sort_key f xs . f l = f x] = [x \<leftarrow> xs. f l = f x]" by simp
```
```   909   have "\<And>x P. P (f x) ?pivot \<and> f l = f x \<longleftrightarrow> P (f l) ?pivot \<and> f l = f x" by auto
```
```   910   then have "\<And>P. [x \<leftarrow> sort_key f xs . P (f x) ?pivot \<and> f l = f x] =
```
```   911     [x \<leftarrow> sort_key f xs. P (f l) ?pivot \<and> f l = f x]" by simp
```
```   912   note *** = this [of "op <"] this [of "op >"] this [of "op ="]
```
```   913   show "[x \<leftarrow> ?rhs. f l = f x] = [x \<leftarrow> ?lhs. f l = f x]"
```
```   914   proof (cases "f l" ?pivot rule: linorder_cases)
```
```   915     case less then moreover have "f l \<noteq> ?pivot" and "\<not> f l > ?pivot" by auto
```
```   916     ultimately show ?thesis
```
```   917       by (simp add: filter_sort [symmetric] ** ***)
```
```   918   next
```
```   919     case equal then show ?thesis
```
```   920       by (simp add: * less_le)
```
```   921   next
```
```   922     case greater then moreover have "f l \<noteq> ?pivot" and "\<not> f l < ?pivot" by auto
```
```   923     ultimately show ?thesis
```
```   924       by (simp add: filter_sort [symmetric] ** ***)
```
```   925   qed
```
```   926 qed
```
```   927
```
```   928 lemma sort_by_quicksort:
```
```   929   "sort xs = sort [x\<leftarrow>xs. x < xs ! (length xs div 2)]
```
```   930     @ [x\<leftarrow>xs. x = xs ! (length xs div 2)]
```
```   931     @ sort [x\<leftarrow>xs. x > xs ! (length xs div 2)]" (is "sort ?lhs = ?rhs")
```
```   932   using sort_key_by_quicksort [of "\<lambda>x. x", symmetric] by simp
```
```   933
```
```   934 text {* A stable parametrized quicksort *}
```
```   935
```
```   936 definition part :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b list \<Rightarrow> 'b list \<times> 'b list \<times> 'b list" where
```
```   937   "part f pivot xs = ([x \<leftarrow> xs. f x < pivot], [x \<leftarrow> xs. f x = pivot], [x \<leftarrow> xs. pivot < f x])"
```
```   938
```
```   939 lemma part_code [code]:
```
```   940   "part f pivot [] = ([], [], [])"
```
```   941   "part f pivot (x # xs) = (let (lts, eqs, gts) = part f pivot xs; x' = f x in
```
```   942      if x' < pivot then (x # lts, eqs, gts)
```
```   943      else if x' > pivot then (lts, eqs, x # gts)
```
```   944      else (lts, x # eqs, gts))"
```
```   945   by (auto simp add: part_def Let_def split_def)
```
```   946
```
```   947 lemma sort_key_by_quicksort_code [code]:
```
```   948   "sort_key f xs = (case xs of [] \<Rightarrow> []
```
```   949     | [x] \<Rightarrow> xs
```
```   950     | [x, y] \<Rightarrow> (if f x \<le> f y then xs else [y, x])
```
```   951     | _ \<Rightarrow> (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
```
```   952        in sort_key f lts @ eqs @ sort_key f gts))"
```
```   953 proof (cases xs)
```
```   954   case Nil then show ?thesis by simp
```
```   955 next
```
```   956   case (Cons _ ys) note hyps = Cons show ?thesis proof (cases ys)
```
```   957     case Nil with hyps show ?thesis by simp
```
```   958   next
```
```   959     case (Cons _ zs) note hyps = hyps Cons show ?thesis proof (cases zs)
```
```   960       case Nil with hyps show ?thesis by auto
```
```   961     next
```
```   962       case Cons
```
```   963       from sort_key_by_quicksort [of f xs]
```
```   964       have "sort_key f xs = (let (lts, eqs, gts) = part f (f (xs ! (length xs div 2))) xs
```
```   965         in sort_key f lts @ eqs @ sort_key f gts)"
```
```   966       by (simp only: split_def Let_def part_def fst_conv snd_conv)
```
```   967       with hyps Cons show ?thesis by (simp only: list.cases)
```
```   968     qed
```
```   969   qed
```
```   970 qed
```
```   971
```
```   972 end
```
```   973
```
```   974 hide_const (open) part
```
```   975
```
```   976 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le> multiset_of xs"
```
```   977   by (induct xs) (auto intro: order_trans)
```
```   978
```
```   979 lemma multiset_of_update:
```
```   980   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
```
```   981 proof (induct ls arbitrary: i)
```
```   982   case Nil then show ?case by simp
```
```   983 next
```
```   984   case (Cons x xs)
```
```   985   show ?case
```
```   986   proof (cases i)
```
```   987     case 0 then show ?thesis by simp
```
```   988   next
```
```   989     case (Suc i')
```
```   990     with Cons show ?thesis
```
```   991       apply simp
```
```   992       apply (subst add_assoc)
```
```   993       apply (subst add_commute [of "{#v#}" "{#x#}"])
```
```   994       apply (subst add_assoc [symmetric])
```
```   995       apply simp
```
```   996       apply (rule mset_le_multiset_union_diff_commute)
```
```   997       apply (simp add: mset_le_single nth_mem_multiset_of)
```
```   998       done
```
```   999   qed
```
```  1000 qed
```
```  1001
```
```  1002 lemma multiset_of_swap:
```
```  1003   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
```
```  1004     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
```
```  1005   by (cases "i = j") (simp_all add: multiset_of_update nth_mem_multiset_of)
```
```  1006
```
```  1007
```
```  1008 subsubsection {* Association lists -- including rudimentary code generation *}
```
```  1009
```
```  1010 definition count_of :: "('a \<times> nat) list \<Rightarrow> 'a \<Rightarrow> nat" where
```
```  1011   "count_of xs x = (case map_of xs x of None \<Rightarrow> 0 | Some n \<Rightarrow> n)"
```
```  1012
```
```  1013 lemma count_of_multiset:
```
```  1014   "count_of xs \<in> multiset"
```
```  1015 proof -
```
```  1016   let ?A = "{x::'a. 0 < (case map_of xs x of None \<Rightarrow> 0\<Colon>nat | Some (n\<Colon>nat) \<Rightarrow> n)}"
```
```  1017   have "?A \<subseteq> dom (map_of xs)"
```
```  1018   proof
```
```  1019     fix x
```
```  1020     assume "x \<in> ?A"
```
```  1021     then have "0 < (case map_of xs x of None \<Rightarrow> 0\<Colon>nat | Some (n\<Colon>nat) \<Rightarrow> n)" by simp
```
```  1022     then have "map_of xs x \<noteq> None" by (cases "map_of xs x") auto
```
```  1023     then show "x \<in> dom (map_of xs)" by auto
```
```  1024   qed
```
```  1025   with finite_dom_map_of [of xs] have "finite ?A"
```
```  1026     by (auto intro: finite_subset)
```
```  1027   then show ?thesis
```
```  1028     by (simp add: count_of_def fun_eq_iff multiset_def)
```
```  1029 qed
```
```  1030
```
```  1031 lemma count_simps [simp]:
```
```  1032   "count_of [] = (\<lambda>_. 0)"
```
```  1033   "count_of ((x, n) # xs) = (\<lambda>y. if x = y then n else count_of xs y)"
```
```  1034   by (simp_all add: count_of_def fun_eq_iff)
```
```  1035
```
```  1036 lemma count_of_empty:
```
```  1037   "x \<notin> fst ` set xs \<Longrightarrow> count_of xs x = 0"
```
```  1038   by (induct xs) (simp_all add: count_of_def)
```
```  1039
```
```  1040 lemma count_of_filter:
```
```  1041   "count_of (filter (P \<circ> fst) xs) x = (if P x then count_of xs x else 0)"
```
```  1042   by (induct xs) auto
```
```  1043
```
```  1044 definition Bag :: "('a \<times> nat) list \<Rightarrow> 'a multiset" where
```
```  1045   "Bag xs = Abs_multiset (count_of xs)"
```
```  1046
```
```  1047 code_datatype Bag
```
```  1048
```
```  1049 lemma count_Bag [simp, code]:
```
```  1050   "count (Bag xs) = count_of xs"
```
```  1051   by (simp add: Bag_def count_of_multiset Abs_multiset_inverse)
```
```  1052
```
```  1053 lemma Mempty_Bag [code]:
```
```  1054   "{#} = Bag []"
```
```  1055   by (simp add: multiset_eq_iff)
```
```  1056
```
```  1057 lemma single_Bag [code]:
```
```  1058   "{#x#} = Bag [(x, 1)]"
```
```  1059   by (simp add: multiset_eq_iff)
```
```  1060
```
```  1061 lemma MCollect_Bag [code]:
```
```  1062   "MCollect (Bag xs) P = Bag (filter (P \<circ> fst) xs)"
```
```  1063   by (simp add: multiset_eq_iff count_of_filter)
```
```  1064
```
```  1065 lemma mset_less_eq_Bag [code]:
```
```  1066   "Bag xs \<le> A \<longleftrightarrow> (\<forall>(x, n) \<in> set xs. count_of xs x \<le> count A x)"
```
```  1067     (is "?lhs \<longleftrightarrow> ?rhs")
```
```  1068 proof
```
```  1069   assume ?lhs then show ?rhs
```
```  1070     by (auto simp add: mset_le_def count_Bag)
```
```  1071 next
```
```  1072   assume ?rhs
```
```  1073   show ?lhs
```
```  1074   proof (rule mset_less_eqI)
```
```  1075     fix x
```
```  1076     from `?rhs` have "count_of xs x \<le> count A x"
```
```  1077       by (cases "x \<in> fst ` set xs") (auto simp add: count_of_empty)
```
```  1078     then show "count (Bag xs) x \<le> count A x"
```
```  1079       by (simp add: mset_le_def count_Bag)
```
```  1080   qed
```
```  1081 qed
```
```  1082
```
```  1083 instantiation multiset :: (equal) equal
```
```  1084 begin
```
```  1085
```
```  1086 definition
```
```  1087   "HOL.equal A B \<longleftrightarrow> (A::'a multiset) \<le> B \<and> B \<le> A"
```
```  1088
```
```  1089 instance proof
```
```  1090 qed (simp add: equal_multiset_def eq_iff)
```
```  1091
```
```  1092 end
```
```  1093
```
```  1094 lemma [code nbe]:
```
```  1095   "HOL.equal (A :: 'a::equal multiset) A \<longleftrightarrow> True"
```
```  1096   by (fact equal_refl)
```
```  1097
```
```  1098 definition (in term_syntax)
```
```  1099   bagify :: "('a\<Colon>typerep \<times> nat) list \<times> (unit \<Rightarrow> Code_Evaluation.term)
```
```  1100     \<Rightarrow> 'a multiset \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
```
```  1101   [code_unfold]: "bagify xs = Code_Evaluation.valtermify Bag {\<cdot>} xs"
```
```  1102
```
```  1103 notation fcomp (infixl "\<circ>>" 60)
```
```  1104 notation scomp (infixl "\<circ>\<rightarrow>" 60)
```
```  1105
```
```  1106 instantiation multiset :: (random) random
```
```  1107 begin
```
```  1108
```
```  1109 definition
```
```  1110   "Quickcheck.random i = Quickcheck.random i \<circ>\<rightarrow> (\<lambda>xs. Pair (bagify xs))"
```
```  1111
```
```  1112 instance ..
```
```  1113
```
```  1114 end
```
```  1115
```
```  1116 no_notation fcomp (infixl "\<circ>>" 60)
```
```  1117 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
```
```  1118
```
```  1119 hide_const (open) bagify
```
```  1120
```
```  1121
```
```  1122 subsection {* The multiset order *}
```
```  1123
```
```  1124 subsubsection {* Well-foundedness *}
```
```  1125
```
```  1126 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
```
```  1127   "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
```
```  1128       (\<forall>b. b :# K --> (b, a) \<in> r)}"
```
```  1129
```
```  1130 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
```
```  1131   "mult r = (mult1 r)\<^sup>+"
```
```  1132
```
```  1133 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
```
```  1134 by (simp add: mult1_def)
```
```  1135
```
```  1136 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
```
```  1137     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
```
```  1138     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
```
```  1139   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
```
```  1140 proof (unfold mult1_def)
```
```  1141   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
```
```  1142   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
```
```  1143   let ?case1 = "?case1 {(N, M). ?R N M}"
```
```  1144
```
```  1145   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
```
```  1146   then have "\<exists>a' M0' K.
```
```  1147       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
```
```  1148   then show "?case1 \<or> ?case2"
```
```  1149   proof (elim exE conjE)
```
```  1150     fix a' M0' K
```
```  1151     assume N: "N = M0' + K" and r: "?r K a'"
```
```  1152     assume "M0 + {#a#} = M0' + {#a'#}"
```
```  1153     then have "M0 = M0' \<and> a = a' \<or>
```
```  1154         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
```
```  1155       by (simp only: add_eq_conv_ex)
```
```  1156     then show ?thesis
```
```  1157     proof (elim disjE conjE exE)
```
```  1158       assume "M0 = M0'" "a = a'"
```
```  1159       with N r have "?r K a \<and> N = M0 + K" by simp
```
```  1160       then have ?case2 .. then show ?thesis ..
```
```  1161     next
```
```  1162       fix K'
```
```  1163       assume "M0' = K' + {#a#}"
```
```  1164       with N have n: "N = K' + K + {#a#}" by (simp add: add_ac)
```
```  1165
```
```  1166       assume "M0 = K' + {#a'#}"
```
```  1167       with r have "?R (K' + K) M0" by blast
```
```  1168       with n have ?case1 by simp then show ?thesis ..
```
```  1169     qed
```
```  1170   qed
```
```  1171 qed
```
```  1172
```
```  1173 lemma all_accessible: "wf r ==> \<forall>M. M \<in> acc (mult1 r)"
```
```  1174 proof
```
```  1175   let ?R = "mult1 r"
```
```  1176   let ?W = "acc ?R"
```
```  1177   {
```
```  1178     fix M M0 a
```
```  1179     assume M0: "M0 \<in> ?W"
```
```  1180       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
```
```  1181       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
```
```  1182     have "M0 + {#a#} \<in> ?W"
```
```  1183     proof (rule accI [of "M0 + {#a#}"])
```
```  1184       fix N
```
```  1185       assume "(N, M0 + {#a#}) \<in> ?R"
```
```  1186       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
```
```  1187           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
```
```  1188         by (rule less_add)
```
```  1189       then show "N \<in> ?W"
```
```  1190       proof (elim exE disjE conjE)
```
```  1191         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
```
```  1192         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
```
```  1193         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
```
```  1194         then show "N \<in> ?W" by (simp only: N)
```
```  1195       next
```
```  1196         fix K
```
```  1197         assume N: "N = M0 + K"
```
```  1198         assume "\<forall>b. b :# K --> (b, a) \<in> r"
```
```  1199         then have "M0 + K \<in> ?W"
```
```  1200         proof (induct K)
```
```  1201           case empty
```
```  1202           from M0 show "M0 + {#} \<in> ?W" by simp
```
```  1203         next
```
```  1204           case (add K x)
```
```  1205           from add.prems have "(x, a) \<in> r" by simp
```
```  1206           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
```
```  1207           moreover from add have "M0 + K \<in> ?W" by simp
```
```  1208           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
```
```  1209           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: add_assoc)
```
```  1210         qed
```
```  1211         then show "N \<in> ?W" by (simp only: N)
```
```  1212       qed
```
```  1213     qed
```
```  1214   } note tedious_reasoning = this
```
```  1215
```
```  1216   assume wf: "wf r"
```
```  1217   fix M
```
```  1218   show "M \<in> ?W"
```
```  1219   proof (induct M)
```
```  1220     show "{#} \<in> ?W"
```
```  1221     proof (rule accI)
```
```  1222       fix b assume "(b, {#}) \<in> ?R"
```
```  1223       with not_less_empty show "b \<in> ?W" by contradiction
```
```  1224     qed
```
```  1225
```
```  1226     fix M a assume "M \<in> ?W"
```
```  1227     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
```
```  1228     proof induct
```
```  1229       fix a
```
```  1230       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
```
```  1231       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
```
```  1232       proof
```
```  1233         fix M assume "M \<in> ?W"
```
```  1234         then show "M + {#a#} \<in> ?W"
```
```  1235           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
```
```  1236       qed
```
```  1237     qed
```
```  1238     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
```
```  1239   qed
```
```  1240 qed
```
```  1241
```
```  1242 theorem wf_mult1: "wf r ==> wf (mult1 r)"
```
```  1243 by (rule acc_wfI) (rule all_accessible)
```
```  1244
```
```  1245 theorem wf_mult: "wf r ==> wf (mult r)"
```
```  1246 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
```
```  1247
```
```  1248
```
```  1249 subsubsection {* Closure-free presentation *}
```
```  1250
```
```  1251 text {* One direction. *}
```
```  1252
```
```  1253 lemma mult_implies_one_step:
```
```  1254   "trans r ==> (M, N) \<in> mult r ==>
```
```  1255     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
```
```  1256     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
```
```  1257 apply (unfold mult_def mult1_def set_of_def)
```
```  1258 apply (erule converse_trancl_induct, clarify)
```
```  1259  apply (rule_tac x = M0 in exI, simp, clarify)
```
```  1260 apply (case_tac "a :# K")
```
```  1261  apply (rule_tac x = I in exI)
```
```  1262  apply (simp (no_asm))
```
```  1263  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
```
```  1264  apply (simp (no_asm_simp) add: add_assoc [symmetric])
```
```  1265  apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong)
```
```  1266  apply (simp add: diff_union_single_conv)
```
```  1267  apply (simp (no_asm_use) add: trans_def)
```
```  1268  apply blast
```
```  1269 apply (subgoal_tac "a :# I")
```
```  1270  apply (rule_tac x = "I - {#a#}" in exI)
```
```  1271  apply (rule_tac x = "J + {#a#}" in exI)
```
```  1272  apply (rule_tac x = "K + Ka" in exI)
```
```  1273  apply (rule conjI)
```
```  1274   apply (simp add: multiset_eq_iff split: nat_diff_split)
```
```  1275  apply (rule conjI)
```
```  1276   apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong, simp)
```
```  1277   apply (simp add: multiset_eq_iff split: nat_diff_split)
```
```  1278  apply (simp (no_asm_use) add: trans_def)
```
```  1279  apply blast
```
```  1280 apply (subgoal_tac "a :# (M0 + {#a#})")
```
```  1281  apply simp
```
```  1282 apply (simp (no_asm))
```
```  1283 done
```
```  1284
```
```  1285 lemma one_step_implies_mult_aux:
```
```  1286   "trans r ==>
```
```  1287     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
```
```  1288       --> (I + K, I + J) \<in> mult r"
```
```  1289 apply (induct_tac n, auto)
```
```  1290 apply (frule size_eq_Suc_imp_eq_union, clarify)
```
```  1291 apply (rename_tac "J'", simp)
```
```  1292 apply (erule notE, auto)
```
```  1293 apply (case_tac "J' = {#}")
```
```  1294  apply (simp add: mult_def)
```
```  1295  apply (rule r_into_trancl)
```
```  1296  apply (simp add: mult1_def set_of_def, blast)
```
```  1297 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
```
```  1298 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
```
```  1299 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
```
```  1300 apply (erule ssubst)
```
```  1301 apply (simp add: Ball_def, auto)
```
```  1302 apply (subgoal_tac
```
```  1303   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
```
```  1304     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
```
```  1305  prefer 2
```
```  1306  apply force
```
```  1307 apply (simp (no_asm_use) add: add_assoc [symmetric] mult_def)
```
```  1308 apply (erule trancl_trans)
```
```  1309 apply (rule r_into_trancl)
```
```  1310 apply (simp add: mult1_def set_of_def)
```
```  1311 apply (rule_tac x = a in exI)
```
```  1312 apply (rule_tac x = "I + J'" in exI)
```
```  1313 apply (simp add: add_ac)
```
```  1314 done
```
```  1315
```
```  1316 lemma one_step_implies_mult:
```
```  1317   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
```
```  1318     ==> (I + K, I + J) \<in> mult r"
```
```  1319 using one_step_implies_mult_aux by blast
```
```  1320
```
```  1321
```
```  1322 subsubsection {* Partial-order properties *}
```
```  1323
```
```  1324 definition less_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<#" 50) where
```
```  1325   "M' <# M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
```
```  1326
```
```  1327 definition le_multiset :: "'a\<Colon>order multiset \<Rightarrow> 'a multiset \<Rightarrow> bool" (infix "<=#" 50) where
```
```  1328   "M' <=# M \<longleftrightarrow> M' <# M \<or> M' = M"
```
```  1329
```
```  1330 notation (xsymbols) less_multiset (infix "\<subset>#" 50)
```
```  1331 notation (xsymbols) le_multiset (infix "\<subseteq>#" 50)
```
```  1332
```
```  1333 interpretation multiset_order: order le_multiset less_multiset
```
```  1334 proof -
```
```  1335   have irrefl: "\<And>M :: 'a multiset. \<not> M \<subset># M"
```
```  1336   proof
```
```  1337     fix M :: "'a multiset"
```
```  1338     assume "M \<subset># M"
```
```  1339     then have MM: "(M, M) \<in> mult {(x, y). x < y}" by (simp add: less_multiset_def)
```
```  1340     have "trans {(x'::'a, x). x' < x}"
```
```  1341       by (rule transI) simp
```
```  1342     moreover note MM
```
```  1343     ultimately have "\<exists>I J K. M = I + J \<and> M = I + K
```
```  1344       \<and> J \<noteq> {#} \<and> (\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})"
```
```  1345       by (rule mult_implies_one_step)
```
```  1346     then obtain I J K where "M = I + J" and "M = I + K"
```
```  1347       and "J \<noteq> {#}" and "(\<forall>k\<in>set_of K. \<exists>j\<in>set_of J. (k, j) \<in> {(x, y). x < y})" by blast
```
```  1348     then have aux1: "K \<noteq> {#}" and aux2: "\<forall>k\<in>set_of K. \<exists>j\<in>set_of K. k < j" by auto
```
```  1349     have "finite (set_of K)" by simp
```
```  1350     moreover note aux2
```
```  1351     ultimately have "set_of K = {}"
```
```  1352       by (induct rule: finite_induct) (auto intro: order_less_trans)
```
```  1353     with aux1 show False by simp
```
```  1354   qed
```
```  1355   have trans: "\<And>K M N :: 'a multiset. K \<subset># M \<Longrightarrow> M \<subset># N \<Longrightarrow> K \<subset># N"
```
```  1356     unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
```
```  1357   show "class.order (le_multiset :: 'a multiset \<Rightarrow> _) less_multiset" proof
```
```  1358   qed (auto simp add: le_multiset_def irrefl dest: trans)
```
```  1359 qed
```
```  1360
```
```  1361 lemma mult_less_irrefl [elim!]:
```
```  1362   "M \<subset># (M::'a::order multiset) ==> R"
```
```  1363   by (simp add: multiset_order.less_irrefl)
```
```  1364
```
```  1365
```
```  1366 subsubsection {* Monotonicity of multiset union *}
```
```  1367
```
```  1368 lemma mult1_union:
```
```  1369   "(B, D) \<in> mult1 r ==> (C + B, C + D) \<in> mult1 r"
```
```  1370 apply (unfold mult1_def)
```
```  1371 apply auto
```
```  1372 apply (rule_tac x = a in exI)
```
```  1373 apply (rule_tac x = "C + M0" in exI)
```
```  1374 apply (simp add: add_assoc)
```
```  1375 done
```
```  1376
```
```  1377 lemma union_less_mono2: "B \<subset># D ==> C + B \<subset># C + (D::'a::order multiset)"
```
```  1378 apply (unfold less_multiset_def mult_def)
```
```  1379 apply (erule trancl_induct)
```
```  1380  apply (blast intro: mult1_union)
```
```  1381 apply (blast intro: mult1_union trancl_trans)
```
```  1382 done
```
```  1383
```
```  1384 lemma union_less_mono1: "B \<subset># D ==> B + C \<subset># D + (C::'a::order multiset)"
```
```  1385 apply (subst add_commute [of B C])
```
```  1386 apply (subst add_commute [of D C])
```
```  1387 apply (erule union_less_mono2)
```
```  1388 done
```
```  1389
```
```  1390 lemma union_less_mono:
```
```  1391   "A \<subset># C ==> B \<subset># D ==> A + B \<subset># C + (D::'a::order multiset)"
```
```  1392   by (blast intro!: union_less_mono1 union_less_mono2 multiset_order.less_trans)
```
```  1393
```
```  1394 interpretation multiset_order: ordered_ab_semigroup_add plus le_multiset less_multiset
```
```  1395 proof
```
```  1396 qed (auto simp add: le_multiset_def intro: union_less_mono2)
```
```  1397
```
```  1398
```
```  1399 subsection {* The fold combinator *}
```
```  1400
```
```  1401 text {*
```
```  1402   The intended behaviour is
```
```  1403   @{text "fold_mset f z {#x\<^isub>1, ..., x\<^isub>n#} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
```
```  1404   if @{text f} is associative-commutative.
```
```  1405 *}
```
```  1406
```
```  1407 text {*
```
```  1408   The graph of @{text "fold_mset"}, @{text "z"}: the start element,
```
```  1409   @{text "f"}: folding function, @{text "A"}: the multiset, @{text
```
```  1410   "y"}: the result.
```
```  1411 *}
```
```  1412 inductive
```
```  1413   fold_msetG :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b \<Rightarrow> bool"
```
```  1414   for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b"
```
```  1415   and z :: 'b
```
```  1416 where
```
```  1417   emptyI [intro]:  "fold_msetG f z {#} z"
```
```  1418 | insertI [intro]: "fold_msetG f z A y \<Longrightarrow> fold_msetG f z (A + {#x#}) (f x y)"
```
```  1419
```
```  1420 inductive_cases empty_fold_msetGE [elim!]: "fold_msetG f z {#} x"
```
```  1421 inductive_cases insert_fold_msetGE: "fold_msetG f z (A + {#}) y"
```
```  1422
```
```  1423 definition
```
```  1424   fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b" where
```
```  1425   "fold_mset f z A = (THE x. fold_msetG f z A x)"
```
```  1426
```
```  1427 lemma Diff1_fold_msetG:
```
```  1428   "fold_msetG f z (A - {#x#}) y \<Longrightarrow> x \<in># A \<Longrightarrow> fold_msetG f z A (f x y)"
```
```  1429 apply (frule_tac x = x in fold_msetG.insertI)
```
```  1430 apply auto
```
```  1431 done
```
```  1432
```
```  1433 lemma fold_msetG_nonempty: "\<exists>x. fold_msetG f z A x"
```
```  1434 apply (induct A)
```
```  1435  apply blast
```
```  1436 apply clarsimp
```
```  1437 apply (drule_tac x = x in fold_msetG.insertI)
```
```  1438 apply auto
```
```  1439 done
```
```  1440
```
```  1441 lemma fold_mset_empty[simp]: "fold_mset f z {#} = z"
```
```  1442 unfolding fold_mset_def by blast
```
```  1443
```
```  1444 context fun_left_comm
```
```  1445 begin
```
```  1446
```
```  1447 lemma fold_msetG_determ:
```
```  1448   "fold_msetG f z A x \<Longrightarrow> fold_msetG f z A y \<Longrightarrow> y = x"
```
```  1449 proof (induct arbitrary: x y z rule: full_multiset_induct)
```
```  1450   case (less M x\<^isub>1 x\<^isub>2 Z)
```
```  1451   have IH: "\<forall>A. A < M \<longrightarrow>
```
```  1452     (\<forall>x x' x''. fold_msetG f x'' A x \<longrightarrow> fold_msetG f x'' A x'
```
```  1453                \<longrightarrow> x' = x)" by fact
```
```  1454   have Mfoldx\<^isub>1: "fold_msetG f Z M x\<^isub>1" and Mfoldx\<^isub>2: "fold_msetG f Z M x\<^isub>2" by fact+
```
```  1455   show ?case
```
```  1456   proof (rule fold_msetG.cases [OF Mfoldx\<^isub>1])
```
```  1457     assume "M = {#}" and "x\<^isub>1 = Z"
```
```  1458     then show ?case using Mfoldx\<^isub>2 by auto
```
```  1459   next
```
```  1460     fix B b u
```
```  1461     assume "M = B + {#b#}" and "x\<^isub>1 = f b u" and Bu: "fold_msetG f Z B u"
```
```  1462     then have MBb: "M = B + {#b#}" and x\<^isub>1: "x\<^isub>1 = f b u" by auto
```
```  1463     show ?case
```
```  1464     proof (rule fold_msetG.cases [OF Mfoldx\<^isub>2])
```
```  1465       assume "M = {#}" "x\<^isub>2 = Z"
```
```  1466       then show ?case using Mfoldx\<^isub>1 by auto
```
```  1467     next
```
```  1468       fix C c v
```
```  1469       assume "M = C + {#c#}" and "x\<^isub>2 = f c v" and Cv: "fold_msetG f Z C v"
```
```  1470       then have MCc: "M = C + {#c#}" and x\<^isub>2: "x\<^isub>2 = f c v" by auto
```
```  1471       then have CsubM: "C < M" by simp
```
```  1472       from MBb have BsubM: "B < M" by simp
```
```  1473       show ?case
```
```  1474       proof cases
```
```  1475         assume "b=c"
```
```  1476         then moreover have "B = C" using MBb MCc by auto
```
```  1477         ultimately show ?thesis using Bu Cv x\<^isub>1 x\<^isub>2 CsubM IH by auto
```
```  1478       next
```
```  1479         assume diff: "b \<noteq> c"
```
```  1480         let ?D = "B - {#c#}"
```
```  1481         have cinB: "c \<in># B" and binC: "b \<in># C" using MBb MCc diff
```
```  1482           by (auto intro: insert_noteq_member dest: sym)
```
```  1483         have "B - {#c#} < B" using cinB by (rule mset_less_diff_self)
```
```  1484         then have DsubM: "?D < M" using BsubM by (blast intro: order_less_trans)
```
```  1485         from MBb MCc have "B + {#b#} = C + {#c#}" by blast
```
```  1486         then have [simp]: "B + {#b#} - {#c#} = C"
```
```  1487           using MBb MCc binC cinB by auto
```
```  1488         have B: "B = ?D + {#c#}" and C: "C = ?D + {#b#}"
```
```  1489           using MBb MCc diff binC cinB
```
```  1490           by (auto simp: multiset_add_sub_el_shuffle)
```
```  1491         then obtain d where Dfoldd: "fold_msetG f Z ?D d"
```
```  1492           using fold_msetG_nonempty by iprover
```
```  1493         then have "fold_msetG f Z B (f c d)" using cinB
```
```  1494           by (rule Diff1_fold_msetG)
```
```  1495         then have "f c d = u" using IH BsubM Bu by blast
```
```  1496         moreover
```
```  1497         have "fold_msetG f Z C (f b d)" using binC cinB diff Dfoldd
```
```  1498           by (auto simp: multiset_add_sub_el_shuffle
```
```  1499             dest: fold_msetG.insertI [where x=b])
```
```  1500         then have "f b d = v" using IH CsubM Cv by blast
```
```  1501         ultimately show ?thesis using x\<^isub>1 x\<^isub>2
```
```  1502           by (auto simp: fun_left_comm)
```
```  1503       qed
```
```  1504     qed
```
```  1505   qed
```
```  1506 qed
```
```  1507
```
```  1508 lemma fold_mset_insert_aux:
```
```  1509   "(fold_msetG f z (A + {#x#}) v) =
```
```  1510     (\<exists>y. fold_msetG f z A y \<and> v = f x y)"
```
```  1511 apply (rule iffI)
```
```  1512  prefer 2
```
```  1513  apply blast
```
```  1514 apply (rule_tac A=A and f=f in fold_msetG_nonempty [THEN exE, standard])
```
```  1515 apply (blast intro: fold_msetG_determ)
```
```  1516 done
```
```  1517
```
```  1518 lemma fold_mset_equality: "fold_msetG f z A y \<Longrightarrow> fold_mset f z A = y"
```
```  1519 unfolding fold_mset_def by (blast intro: fold_msetG_determ)
```
```  1520
```
```  1521 lemma fold_mset_insert:
```
```  1522   "fold_mset f z (A + {#x#}) = f x (fold_mset f z A)"
```
```  1523 apply (simp add: fold_mset_def fold_mset_insert_aux)
```
```  1524 apply (rule the_equality)
```
```  1525  apply (auto cong add: conj_cong
```
```  1526      simp add: fold_mset_def [symmetric] fold_mset_equality fold_msetG_nonempty)
```
```  1527 done
```
```  1528
```
```  1529 lemma fold_mset_commute: "f x (fold_mset f z A) = fold_mset f (f x z) A"
```
```  1530 by (induct A) (auto simp: fold_mset_insert fun_left_comm [of x])
```
```  1531
```
```  1532 lemma fold_mset_single [simp]: "fold_mset f z {#x#} = f x z"
```
```  1533 using fold_mset_insert [of z "{#}"] by simp
```
```  1534
```
```  1535 lemma fold_mset_union [simp]:
```
```  1536   "fold_mset f z (A+B) = fold_mset f (fold_mset f z A) B"
```
```  1537 proof (induct A)
```
```  1538   case empty then show ?case by simp
```
```  1539 next
```
```  1540   case (add A x)
```
```  1541   have "A + {#x#} + B = (A+B) + {#x#}" by (simp add: add_ac)
```
```  1542   then have "fold_mset f z (A + {#x#} + B) = f x (fold_mset f z (A + B))"
```
```  1543     by (simp add: fold_mset_insert)
```
```  1544   also have "\<dots> = fold_mset f (fold_mset f z (A + {#x#})) B"
```
```  1545     by (simp add: fold_mset_commute[of x,symmetric] add fold_mset_insert)
```
```  1546   finally show ?case .
```
```  1547 qed
```
```  1548
```
```  1549 lemma fold_mset_fusion:
```
```  1550   assumes "fun_left_comm g"
```
```  1551   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold_mset g w A) = fold_mset f (h w) A" (is "PROP ?P")
```
```  1552 proof -
```
```  1553   interpret fun_left_comm g by (fact assms)
```
```  1554   show "PROP ?P" by (induct A) auto
```
```  1555 qed
```
```  1556
```
```  1557 lemma fold_mset_rec:
```
```  1558   assumes "a \<in># A"
```
```  1559   shows "fold_mset f z A = f a (fold_mset f z (A - {#a#}))"
```
```  1560 proof -
```
```  1561   from assms obtain A' where "A = A' + {#a#}"
```
```  1562     by (blast dest: multi_member_split)
```
```  1563   then show ?thesis by simp
```
```  1564 qed
```
```  1565
```
```  1566 end
```
```  1567
```
```  1568 text {*
```
```  1569   A note on code generation: When defining some function containing a
```
```  1570   subterm @{term"fold_mset F"}, code generation is not automatic. When
```
```  1571   interpreting locale @{text left_commutative} with @{text F}, the
```
```  1572   would be code thms for @{const fold_mset} become thms like
```
```  1573   @{term"fold_mset F z {#} = z"} where @{text F} is not a pattern but
```
```  1574   contains defined symbols, i.e.\ is not a code thm. Hence a separate
```
```  1575   constant with its own code thms needs to be introduced for @{text
```
```  1576   F}. See the image operator below.
```
```  1577 *}
```
```  1578
```
```  1579
```
```  1580 subsection {* Image *}
```
```  1581
```
```  1582 definition image_mset :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a multiset \<Rightarrow> 'b multiset" where
```
```  1583   "image_mset f = fold_mset (op + o single o f) {#}"
```
```  1584
```
```  1585 interpretation image_left_comm: fun_left_comm "op + o single o f"
```
```  1586 proof qed (simp add: add_ac)
```
```  1587
```
```  1588 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
```
```  1589 by (simp add: image_mset_def)
```
```  1590
```
```  1591 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
```
```  1592 by (simp add: image_mset_def)
```
```  1593
```
```  1594 lemma image_mset_insert:
```
```  1595   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
```
```  1596 by (simp add: image_mset_def add_ac)
```
```  1597
```
```  1598 lemma image_mset_union [simp]:
```
```  1599   "image_mset f (M+N) = image_mset f M + image_mset f N"
```
```  1600 apply (induct N)
```
```  1601  apply simp
```
```  1602 apply (simp add: add_assoc [symmetric] image_mset_insert)
```
```  1603 done
```
```  1604
```
```  1605 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
```
```  1606 by (induct M) simp_all
```
```  1607
```
```  1608 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
```
```  1609 by (cases M) auto
```
```  1610
```
```  1611 syntax
```
```  1612   "_comprehension1_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
```
```  1613       ("({#_/. _ :# _#})")
```
```  1614 translations
```
```  1615   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
```
```  1616
```
```  1617 syntax
```
```  1618   "_comprehension2_mset" :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
```
```  1619       ("({#_/ | _ :# _./ _#})")
```
```  1620 translations
```
```  1621   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
```
```  1622
```
```  1623 text {*
```
```  1624   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
```
```  1625   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
```
```  1626   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
```
```  1627   @{term "{#x+x|x:#M. x<c#}"}.
```
```  1628 *}
```
```  1629
```
```  1630 type_mapper image_mset proof -
```
```  1631   fix f g A show "image_mset f (image_mset g A) = image_mset (\<lambda>x. f (g x)) A"
```
```  1632     by (induct A) simp_all
```
```  1633 next
```
```  1634   fix A show "image_mset (\<lambda>x. x) A = A"
```
```  1635     by (induct A) simp_all
```
```  1636 qed
```
```  1637
```
```  1638
```
```  1639 subsection {* Termination proofs with multiset orders *}
```
```  1640
```
```  1641 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
```
```  1642   and multi_member_this: "x \<in># {# x #} + XS"
```
```  1643   and multi_member_last: "x \<in># {# x #}"
```
```  1644   by auto
```
```  1645
```
```  1646 definition "ms_strict = mult pair_less"
```
```  1647 definition "ms_weak = ms_strict \<union> Id"
```
```  1648
```
```  1649 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
```
```  1650 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
```
```  1651 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
```
```  1652
```
```  1653 lemma smsI:
```
```  1654   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
```
```  1655   unfolding ms_strict_def
```
```  1656 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
```
```  1657
```
```  1658 lemma wmsI:
```
```  1659   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
```
```  1660   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
```
```  1661 unfolding ms_weak_def ms_strict_def
```
```  1662 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
```
```  1663
```
```  1664 inductive pw_leq
```
```  1665 where
```
```  1666   pw_leq_empty: "pw_leq {#} {#}"
```
```  1667 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
```
```  1668
```
```  1669 lemma pw_leq_lstep:
```
```  1670   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
```
```  1671 by (drule pw_leq_step) (rule pw_leq_empty, simp)
```
```  1672
```
```  1673 lemma pw_leq_split:
```
```  1674   assumes "pw_leq X Y"
```
```  1675   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
```
```  1676   using assms
```
```  1677 proof (induct)
```
```  1678   case pw_leq_empty thus ?case by auto
```
```  1679 next
```
```  1680   case (pw_leq_step x y X Y)
```
```  1681   then obtain A B Z where
```
```  1682     [simp]: "X = A + Z" "Y = B + Z"
```
```  1683       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})"
```
```  1684     by auto
```
```  1685   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less"
```
```  1686     unfolding pair_leq_def by auto
```
```  1687   thus ?case
```
```  1688   proof
```
```  1689     assume [simp]: "x = y"
```
```  1690     have
```
```  1691       "{#x#} + X = A + ({#y#}+Z)
```
```  1692       \<and> {#y#} + Y = B + ({#y#}+Z)
```
```  1693       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
```
```  1694       by (auto simp: add_ac)
```
```  1695     thus ?case by (intro exI)
```
```  1696   next
```
```  1697     assume A: "(x, y) \<in> pair_less"
```
```  1698     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
```
```  1699     have "{#x#} + X = ?A' + Z"
```
```  1700       "{#y#} + Y = ?B' + Z"
```
```  1701       by (auto simp add: add_ac)
```
```  1702     moreover have
```
```  1703       "(set_of ?A', set_of ?B') \<in> max_strict"
```
```  1704       using 1 A unfolding max_strict_def
```
```  1705       by (auto elim!: max_ext.cases)
```
```  1706     ultimately show ?thesis by blast
```
```  1707   qed
```
```  1708 qed
```
```  1709
```
```  1710 lemma
```
```  1711   assumes pwleq: "pw_leq Z Z'"
```
```  1712   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
```
```  1713   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
```
```  1714   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
```
```  1715 proof -
```
```  1716   from pw_leq_split[OF pwleq]
```
```  1717   obtain A' B' Z''
```
```  1718     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
```
```  1719     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
```
```  1720     by blast
```
```  1721   {
```
```  1722     assume max: "(set_of A, set_of B) \<in> max_strict"
```
```  1723     from mx_or_empty
```
```  1724     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
```
```  1725     proof
```
```  1726       assume max': "(set_of A', set_of B') \<in> max_strict"
```
```  1727       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
```
```  1728         by (auto simp: max_strict_def intro: max_ext_additive)
```
```  1729       thus ?thesis by (rule smsI)
```
```  1730     next
```
```  1731       assume [simp]: "A' = {#} \<and> B' = {#}"
```
```  1732       show ?thesis by (rule smsI) (auto intro: max)
```
```  1733     qed
```
```  1734     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:add_ac)
```
```  1735     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
```
```  1736   }
```
```  1737   from mx_or_empty
```
```  1738   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
```
```  1739   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:add_ac)
```
```  1740 qed
```
```  1741
```
```  1742 lemma empty_neutral: "{#} + x = x" "x + {#} = x"
```
```  1743 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
```
```  1744 and nonempty_single: "{# x #} \<noteq> {#}"
```
```  1745 by auto
```
```  1746
```
```  1747 setup {*
```
```  1748 let
```
```  1749   fun msetT T = Type (@{type_name multiset}, [T]);
```
```  1750
```
```  1751   fun mk_mset T [] = Const (@{const_abbrev Mempty}, msetT T)
```
```  1752     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) \$ x
```
```  1753     | mk_mset T (x :: xs) =
```
```  1754           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) \$
```
```  1755                 mk_mset T [x] \$ mk_mset T xs
```
```  1756
```
```  1757   fun mset_member_tac m i =
```
```  1758       (if m <= 0 then
```
```  1759            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
```
```  1760        else
```
```  1761            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
```
```  1762
```
```  1763   val mset_nonempty_tac =
```
```  1764       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
```
```  1765
```
```  1766   val regroup_munion_conv =
```
```  1767       Function_Lib.regroup_conv @{const_abbrev Mempty} @{const_name plus}
```
```  1768         (map (fn t => t RS eq_reflection) (@{thms add_ac} @ @{thms empty_neutral}))
```
```  1769
```
```  1770   fun unfold_pwleq_tac i =
```
```  1771     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
```
```  1772       ORELSE (rtac @{thm pw_leq_lstep} i)
```
```  1773       ORELSE (rtac @{thm pw_leq_empty} i)
```
```  1774
```
```  1775   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
```
```  1776                       @{thm Un_insert_left}, @{thm Un_empty_left}]
```
```  1777 in
```
```  1778   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset
```
```  1779   {
```
```  1780     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
```
```  1781     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
```
```  1782     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
```
```  1783     smsI'= @{thm ms_strictI}, wmsI2''= @{thm ms_weakI2}, wmsI1= @{thm ms_weakI1},
```
```  1784     reduction_pair= @{thm ms_reduction_pair}
```
```  1785   })
```
```  1786 end
```
```  1787 *}
```
```  1788
```
```  1789
```
```  1790 subsection {* Legacy theorem bindings *}
```
```  1791
```
```  1792 lemmas multi_count_eq = multiset_eq_iff [symmetric]
```
```  1793
```
```  1794 lemma union_commute: "M + N = N + (M::'a multiset)"
```
```  1795   by (fact add_commute)
```
```  1796
```
```  1797 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
```
```  1798   by (fact add_assoc)
```
```  1799
```
```  1800 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
```
```  1801   by (fact add_left_commute)
```
```  1802
```
```  1803 lemmas union_ac = union_assoc union_commute union_lcomm
```
```  1804
```
```  1805 lemma union_right_cancel: "M + K = N + K \<longleftrightarrow> M = (N::'a multiset)"
```
```  1806   by (fact add_right_cancel)
```
```  1807
```
```  1808 lemma union_left_cancel: "K + M = K + N \<longleftrightarrow> M = (N::'a multiset)"
```
```  1809   by (fact add_left_cancel)
```
```  1810
```
```  1811 lemma multi_union_self_other_eq: "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
```
```  1812   by (fact add_imp_eq)
```
```  1813
```
```  1814 lemma mset_less_trans: "(M::'a multiset) < K \<Longrightarrow> K < N \<Longrightarrow> M < N"
```
```  1815   by (fact order_less_trans)
```
```  1816
```
```  1817 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
```
```  1818   by (fact inf.commute)
```
```  1819
```
```  1820 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
```
```  1821   by (fact inf.assoc [symmetric])
```
```  1822
```
```  1823 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
```
```  1824   by (fact inf.left_commute)
```
```  1825
```
```  1826 lemmas multiset_inter_ac =
```
```  1827   multiset_inter_commute
```
```  1828   multiset_inter_assoc
```
```  1829   multiset_inter_left_commute
```
```  1830
```
```  1831 lemma mult_less_not_refl:
```
```  1832   "\<not> M \<subset># (M::'a::order multiset)"
```
```  1833   by (fact multiset_order.less_irrefl)
```
```  1834
```
```  1835 lemma mult_less_trans:
```
```  1836   "K \<subset># M ==> M \<subset># N ==> K \<subset># (N::'a::order multiset)"
```
```  1837   by (fact multiset_order.less_trans)
```
```  1838
```
```  1839 lemma mult_less_not_sym:
```
```  1840   "M \<subset># N ==> \<not> N \<subset># (M::'a::order multiset)"
```
```  1841   by (fact multiset_order.less_not_sym)
```
```  1842
```
```  1843 lemma mult_less_asym:
```
```  1844   "M \<subset># N ==> (\<not> P ==> N \<subset># (M::'a::order multiset)) ==> P"
```
```  1845   by (fact multiset_order.less_asym)
```
```  1846
```
```  1847 ML {*
```
```  1848 fun multiset_postproc _ maybe_name all_values (T as Type (_, [elem_T]))
```
```  1849                       (Const _ \$ t') =
```
```  1850     let
```
```  1851       val (maybe_opt, ps) =
```
```  1852         Nitpick_Model.dest_plain_fun t' ||> op ~~
```
```  1853         ||> map (apsnd (snd o HOLogic.dest_number))
```
```  1854       fun elems_for t =
```
```  1855         case AList.lookup (op =) ps t of
```
```  1856           SOME n => replicate n t
```
```  1857         | NONE => [Const (maybe_name, elem_T --> elem_T) \$ t]
```
```  1858     in
```
```  1859       case maps elems_for (all_values elem_T) @
```
```  1860            (if maybe_opt then [Const (Nitpick_Model.unrep (), elem_T)]
```
```  1861             else []) of
```
```  1862         [] => Const (@{const_name zero_class.zero}, T)
```
```  1863       | ts => foldl1 (fn (t1, t2) =>
```
```  1864                          Const (@{const_name plus_class.plus}, T --> T --> T)
```
```  1865                          \$ t1 \$ t2)
```
```  1866                      (map (curry (op \$) (Const (@{const_name single},
```
```  1867                                                 elem_T --> T))) ts)
```
```  1868     end
```
```  1869   | multiset_postproc _ _ _ _ t = t
```
```  1870 *}
```
```  1871
```
```  1872 declaration {*
```
```  1873 Nitpick_Model.register_term_postprocessor @{typ "'a multiset"}
```
```  1874     multiset_postproc
```
```  1875 *}
```
```  1876
```
```  1877 end
```