src/Pure/sign.ML
author wenzelm
Tue Nov 28 00:35:21 2006 +0100 (2006-11-28)
changeset 21566 af2932baf068
parent 21269 c605503bb4ef
child 21661 e070569dd638
permissions -rw-r--r--
dest_term: strip_imp_concl;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN_THEORY =
    10 sig
    11   val add_defsort: string -> theory -> theory
    12   val add_defsort_i: sort -> theory -> theory
    13   val add_types: (bstring * int * mixfix) list -> theory -> theory
    14   val add_typedecls: (bstring * string list * mixfix) list -> theory -> theory
    15   val add_nonterminals: bstring list -> theory -> theory
    16   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    17   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    18   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    19   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    20   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    21   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    22   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    23   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    24   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    25   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    26   val add_const_constraint: xstring * string option -> theory -> theory
    27   val add_const_constraint_i: string * typ option -> theory -> theory
    28   val primitive_class: string * class list -> theory -> theory
    29   val primitive_classrel: class * class -> theory -> theory
    30   val primitive_arity: arity -> theory -> theory
    31   val add_trfuns:
    32     (string * (ast list -> ast)) list *
    33     (string * (term list -> term)) list *
    34     (string * (term list -> term)) list *
    35     (string * (ast list -> ast)) list -> theory -> theory
    36   val add_trfunsT:
    37     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    38   val add_advanced_trfuns:
    39     (string * (Context.generic -> ast list -> ast)) list *
    40     (string * (Context.generic -> term list -> term)) list *
    41     (string * (Context.generic -> term list -> term)) list *
    42     (string * (Context.generic -> ast list -> ast)) list -> theory -> theory
    43   val add_advanced_trfunsT:
    44     (string * (Context.generic -> bool -> typ -> term list -> term)) list -> theory -> theory
    45   val add_tokentrfuns:
    46     (string * string * (string -> string * real)) list -> theory -> theory
    47   val add_mode_tokentrfuns: string -> (string * (string -> string * real)) list
    48     -> theory -> theory
    49   val parse_ast_translation: bool * string -> theory -> theory
    50   val parse_translation: bool * string -> theory -> theory
    51   val print_translation: bool * string -> theory -> theory
    52   val typed_print_translation: bool * string -> theory -> theory
    53   val print_ast_translation: bool * string -> theory -> theory
    54   val token_translation: string -> theory -> theory
    55   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    56   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
    57   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
    58   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
    59   val add_path: string -> theory -> theory
    60   val parent_path: theory -> theory
    61   val root_path: theory -> theory
    62   val absolute_path: theory -> theory
    63   val local_path: theory -> theory
    64   val no_base_names: theory -> theory
    65   val qualified_names: theory -> theory
    66   val sticky_prefix: string -> theory -> theory
    67   val set_policy: (string -> bstring -> string) * (string list -> string list list) ->
    68     theory -> theory
    69   val restore_naming: theory -> theory -> theory
    70   val hide_classes: bool -> xstring list -> theory -> theory
    71   val hide_classes_i: bool -> string list -> theory -> theory
    72   val hide_types: bool -> xstring list -> theory -> theory
    73   val hide_types_i: bool -> string list -> theory -> theory
    74   val hide_consts: bool -> xstring list -> theory -> theory
    75   val hide_consts_i: bool -> string list -> theory -> theory
    76   val hide_names: bool -> string * xstring list -> theory -> theory
    77   val hide_names_i: bool -> string * string list -> theory -> theory
    78 end
    79 
    80 signature SIGN =
    81 sig
    82   val init_data: theory -> theory
    83   val rep_sg: theory ->
    84    {naming: NameSpace.naming,
    85     syn: Syntax.syntax,
    86     tsig: Type.tsig,
    87     consts: Consts.T}
    88   val naming_of: theory -> NameSpace.naming
    89   val base_name: string -> bstring
    90   val full_name: theory -> bstring -> string
    91   val full_name_path: theory -> string -> bstring -> string
    92   val declare_name: theory -> string -> NameSpace.T -> NameSpace.T
    93   val syn_of: theory -> Syntax.syntax
    94   val tsig_of: theory -> Type.tsig
    95   val classes_of: theory -> Sorts.algebra
    96   val classes: theory -> class list
    97   val super_classes: theory -> class -> class list
    98   val defaultS: theory -> sort
    99   val subsort: theory -> sort * sort -> bool
   100   val of_sort: theory -> typ * sort -> bool
   101   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
   102   val universal_witness: theory -> (typ * sort) option
   103   val all_sorts_nonempty: theory -> bool
   104   val typ_instance: theory -> typ * typ -> bool
   105   val typ_equiv: theory -> typ * typ -> bool
   106   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
   107   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
   108   val is_logtype: theory -> string -> bool
   109   val consts_of: theory -> Consts.T
   110   val const_constraint: theory -> string -> typ option
   111   val the_const_constraint: theory -> string -> typ
   112   val const_type: theory -> string -> typ option
   113   val the_const_type: theory -> string -> typ
   114   val declared_tyname: theory -> string -> bool
   115   val declared_const: theory -> string -> bool
   116   val const_monomorphic: theory -> string -> bool
   117   val const_syntax_name: theory -> string -> string
   118   val const_typargs: theory -> string * typ -> typ list
   119   val const_instance: theory -> string * typ list -> typ
   120   val class_space: theory -> NameSpace.T
   121   val type_space: theory -> NameSpace.T
   122   val const_space: theory -> NameSpace.T
   123   val intern_class: theory -> xstring -> string
   124   val extern_class: theory -> string -> xstring
   125   val intern_type: theory -> xstring -> string
   126   val extern_type: theory -> string -> xstring
   127   val intern_const: theory -> xstring -> string
   128   val extern_const: theory -> string -> xstring
   129   val intern_sort: theory -> sort -> sort
   130   val extern_sort: theory -> sort -> sort
   131   val intern_typ: theory -> typ -> typ
   132   val extern_typ: theory -> typ -> typ
   133   val intern_term: theory -> term -> term
   134   val extern_term: (string -> xstring) -> theory -> term -> term
   135   val intern_tycons: theory -> typ -> typ
   136   val pretty_term': Context.generic -> Syntax.syntax -> (string -> xstring) -> term -> Pretty.T
   137   val pretty_term: theory -> term -> Pretty.T
   138   val pretty_typ: theory -> typ -> Pretty.T
   139   val pretty_sort: theory -> sort -> Pretty.T
   140   val pretty_classrel: theory -> class list -> Pretty.T
   141   val pretty_arity: theory -> arity -> Pretty.T
   142   val string_of_term: theory -> term -> string
   143   val string_of_typ: theory -> typ -> string
   144   val string_of_sort: theory -> sort -> string
   145   val string_of_classrel: theory -> class list -> string
   146   val string_of_arity: theory -> arity -> string
   147   val pp: theory -> Pretty.pp
   148   val arity_number: theory -> string -> int
   149   val arity_sorts: theory -> string -> sort -> sort list
   150   val certify_class: theory -> class -> class
   151   val certify_sort: theory -> sort -> sort
   152   val certify_typ: theory -> typ -> typ
   153   val certify_typ_syntax: theory -> typ -> typ
   154   val certify_typ_abbrev: theory -> typ -> typ
   155   val certify': bool -> bool -> Pretty.pp -> Consts.T -> theory -> term -> term * typ * int
   156   val certify_term: theory -> term -> term * typ * int
   157   val certify_prop: theory -> term -> term * typ * int
   158   val cert_term: theory -> term -> term
   159   val cert_prop: theory -> term -> term
   160   val no_vars: Pretty.pp -> term -> term
   161   val cert_def: Pretty.pp -> term -> (string * typ) * term
   162   val read_class: theory -> xstring -> class
   163   val read_sort': Syntax.syntax -> Context.generic -> string -> sort
   164   val read_sort: theory -> string -> sort
   165   val read_arity: theory -> xstring * string list * string -> arity
   166   val cert_arity: theory -> arity -> arity
   167   val read_typ': Syntax.syntax -> Context.generic ->
   168     (indexname -> sort option) -> string -> typ
   169   val read_typ_syntax': Syntax.syntax -> Context.generic ->
   170     (indexname -> sort option) -> string -> typ
   171   val read_typ_abbrev': Syntax.syntax -> Context.generic ->
   172     (indexname -> sort option) -> string -> typ
   173   val read_typ: theory * (indexname -> sort option) -> string -> typ
   174   val read_typ_syntax: theory * (indexname -> sort option) -> string -> typ
   175   val read_typ_abbrev: theory * (indexname -> sort option) -> string -> typ
   176   val read_tyname: theory -> string -> typ
   177   val read_const: theory -> string -> term
   178   val infer_types_simult: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   179     (indexname -> sort option) -> Name.context -> bool
   180     -> (term list * typ) list -> term list * (indexname * typ) list
   181   val infer_types: Pretty.pp -> theory -> Consts.T -> (indexname -> typ option) ->
   182     (indexname -> sort option) -> Name.context -> bool
   183     -> term list * typ -> term * (indexname * typ) list
   184   val read_def_terms': Pretty.pp -> (string -> bool) -> Syntax.syntax -> Consts.T ->
   185     Context.generic -> (indexname -> typ option) * (indexname -> sort option) ->
   186     Name.context -> bool -> (string * typ) list -> term list * (indexname * typ) list
   187   val read_def_terms:
   188     theory * (indexname -> typ option) * (indexname -> sort option) ->
   189     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   190   val simple_read_term: theory -> typ -> string -> term
   191   val read_term: theory -> string -> term
   192   val read_prop: theory -> string -> term
   193   val add_consts_authentic: (bstring * typ * mixfix) list -> theory -> theory
   194   val add_notation: Syntax.mode -> (term * mixfix) list -> theory -> theory
   195   val add_abbrevs: Syntax.mode -> ((bstring * mixfix) * term) list -> theory ->
   196     (term * term) list * theory
   197   include SIGN_THEORY
   198 end
   199 
   200 structure Sign: SIGN =
   201 struct
   202 
   203 
   204 (** datatype sign **)
   205 
   206 datatype sign = Sign of
   207  {naming: NameSpace.naming,     (*common naming conventions*)
   208   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   209   tsig: Type.tsig,              (*order-sorted signature of types*)
   210   consts: Consts.T};            (*polymorphic constants*)
   211 
   212 fun make_sign (naming, syn, tsig, consts) =
   213   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   214 
   215 structure SignData = TheoryDataFun
   216 (struct
   217   val name = "Pure/sign";
   218   type T = sign;
   219   val copy = I;
   220   fun extend (Sign {syn, tsig, consts, ...}) =
   221     make_sign (NameSpace.default_naming, syn, tsig, consts);
   222 
   223   val empty =
   224     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   225 
   226   fun merge pp (sign1, sign2) =
   227     let
   228       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   229       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   230 
   231       val naming = NameSpace.default_naming;
   232       val syn = Syntax.merge_syntaxes syn1 syn2;
   233       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   234       val consts = Consts.merge (consts1, consts2);
   235     in make_sign (naming, syn, tsig, consts) end;
   236 
   237   fun print _ _ = ();
   238 end);
   239 
   240 val init_data = SignData.init;
   241 
   242 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   243 
   244 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   245   make_sign (f (naming, syn, tsig, consts)));
   246 
   247 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   248 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   249 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   250 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   251 
   252 
   253 (* naming *)
   254 
   255 val naming_of = #naming o rep_sg;
   256 val base_name = NameSpace.base;
   257 val full_name = NameSpace.full o naming_of;
   258 fun full_name_path thy elems = NameSpace.full (NameSpace.add_path elems (naming_of thy));
   259 val declare_name = NameSpace.declare o naming_of;
   260 
   261 
   262 (* syntax *)
   263 
   264 val syn_of = #syn o rep_sg;
   265 
   266 
   267 (* type signature *)
   268 
   269 val tsig_of = #tsig o rep_sg;
   270 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   271 val classes = Sorts.classes o classes_of;
   272 val super_classes = Sorts.super_classes o classes_of;
   273 val defaultS = Type.defaultS o tsig_of;
   274 val subsort = Type.subsort o tsig_of;
   275 val of_sort = Type.of_sort o tsig_of;
   276 val witness_sorts = Type.witness_sorts o tsig_of;
   277 val universal_witness = Type.universal_witness o tsig_of;
   278 val all_sorts_nonempty = is_some o universal_witness;
   279 val typ_instance = Type.typ_instance o tsig_of;
   280 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   281 val typ_match = Type.typ_match o tsig_of;
   282 val typ_unify = Type.unify o tsig_of;
   283 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   284 
   285 
   286 (* polymorphic constants *)
   287 
   288 val consts_of = #consts o rep_sg;
   289 val the_const_constraint = Consts.constraint o consts_of;
   290 val const_constraint = try o the_const_constraint;
   291 val the_const_type = Consts.declaration o consts_of;
   292 val const_type = try o the_const_type;
   293 val const_monomorphic = Consts.monomorphic o consts_of;
   294 val const_syntax_name = Consts.syntax_name o consts_of;
   295 val const_typargs = Consts.typargs o consts_of;
   296 val const_instance = Consts.instance o consts_of;
   297 
   298 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   299 val declared_const = is_some oo const_constraint;
   300 
   301 
   302 
   303 (** intern / extern names **)
   304 
   305 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   306 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   307 val const_space = Consts.space_of o consts_of;
   308 
   309 val intern_class = NameSpace.intern o class_space;
   310 val extern_class = NameSpace.extern o class_space;
   311 val intern_type = NameSpace.intern o type_space;
   312 val extern_type = NameSpace.extern o type_space;
   313 val intern_const = NameSpace.intern o const_space;
   314 val extern_const = NameSpace.extern o const_space;
   315 
   316 val intern_sort = map o intern_class;
   317 val extern_sort = map o extern_class;
   318 
   319 local
   320 
   321 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   322   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   323   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   324 
   325 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   326   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   327   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   328   | map_term _ _ _ (t as Bound _) = t
   329   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   330   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   331 
   332 val add_classesT = Term.fold_atyps
   333   (fn TFree (_, S) => fold (insert (op =)) S
   334     | TVar (_, S) => fold (insert (op =)) S
   335     | _ => I);
   336 
   337 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   338   | add_tyconsT _ = I;
   339 
   340 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   341 
   342 fun mapping add_names f t =
   343   let
   344     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   345     val tab = map_filter f' (add_names t []);
   346     fun get x = the_default x (AList.lookup (op =) tab x);
   347   in get end;
   348 
   349 fun typ_mapping f g thy T =
   350   T |> map_typ
   351     (mapping add_classesT (f thy) T)
   352     (mapping add_tyconsT (g thy) T);
   353 
   354 fun term_mapping f g h thy t =
   355   t |> map_term
   356     (mapping (Term.fold_types add_classesT) (f thy) t)
   357     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   358     (mapping add_consts (h thy) t);
   359 
   360 in
   361 
   362 val intern_typ = typ_mapping intern_class intern_type;
   363 val extern_typ = typ_mapping extern_class extern_type;
   364 val intern_term = term_mapping intern_class intern_type intern_const;
   365 fun extern_term h = term_mapping extern_class extern_type (K h);
   366 val intern_tycons = typ_mapping (K I) intern_type;
   367 
   368 end;
   369 
   370 
   371 
   372 (** pretty printing of terms, types etc. **)
   373 
   374 fun pretty_term' context syn ext t =
   375   let val curried = Context.exists_name Context.CPureN (Context.theory_of context)
   376   in Syntax.pretty_term ext context syn curried t end;
   377 
   378 fun pretty_term thy t =
   379   pretty_term' (Context.Theory thy) (syn_of thy) (Consts.extern (consts_of thy))
   380     (extern_term (Consts.extern_early (consts_of thy)) thy t);
   381 
   382 fun pretty_typ thy T = Syntax.pretty_typ (Context.Theory thy) (syn_of thy) (extern_typ thy T);
   383 fun pretty_sort thy S = Syntax.pretty_sort (Context.Theory thy) (syn_of thy) (extern_sort thy S);
   384 
   385 fun pretty_classrel thy cs = Pretty.block (flat
   386   (separate [Pretty.str " <", Pretty.brk 1] (map (single o pretty_sort thy o single) cs)));
   387 
   388 fun pretty_arity thy (a, Ss, S) =
   389   let
   390     val a' = extern_type thy a;
   391     val dom =
   392       if null Ss then []
   393       else [Pretty.list "(" ")" (map (pretty_sort thy) Ss), Pretty.brk 1];
   394   in Pretty.block ([Pretty.str (a' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort thy S]) end;
   395 
   396 val string_of_term = Pretty.string_of oo pretty_term;
   397 val string_of_typ = Pretty.string_of oo pretty_typ;
   398 val string_of_sort = Pretty.string_of oo pretty_sort;
   399 val string_of_classrel = Pretty.string_of oo pretty_classrel;
   400 val string_of_arity = Pretty.string_of oo pretty_arity;
   401 
   402 fun pp thy = Pretty.pp (pretty_term thy, pretty_typ thy, pretty_sort thy,
   403   pretty_classrel thy, pretty_arity thy);
   404 
   405 
   406 
   407 (** certify entities **)    (*exception TYPE*)
   408 
   409 (* certify wrt. type signature *)
   410 
   411 val arity_number = Type.arity_number o tsig_of;
   412 fun arity_sorts thy = Type.arity_sorts (pp thy) (tsig_of thy);
   413 
   414 fun certify cert = cert o tsig_of o Context.check_thy;
   415 
   416 val certify_class      = certify Type.cert_class;
   417 val certify_sort       = certify Type.cert_sort;
   418 val certify_typ        = certify Type.cert_typ;
   419 val certify_typ_syntax = certify Type.cert_typ_syntax;
   420 val certify_typ_abbrev = certify Type.cert_typ_abbrev;
   421 
   422 
   423 (* certify term/prop *)
   424 
   425 local
   426 
   427 fun type_check pp tm =
   428   let
   429     fun err_appl why bs t T u U =
   430       let
   431         val xs = map Free bs;           (*we do not rename here*)
   432         val t' = subst_bounds (xs, t);
   433         val u' = subst_bounds (xs, u);
   434         val msg = cat_lines
   435           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   436       in raise TYPE (msg, [T, U], [t', u']) end;
   437 
   438     fun typ_of (_, Const (_, T)) = T
   439       | typ_of (_, Free  (_, T)) = T
   440       | typ_of (_, Var (_, T)) = T
   441       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   442           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   443       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   444       | typ_of (bs, t $ u) =
   445           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   446             (case T of
   447               Type ("fun", [T1, T2]) =>
   448                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   449             | _ => err_appl "Operator not of function type" bs t T u U)
   450           end;
   451   in typ_of ([], tm) end;
   452 
   453 fun err msg = raise TYPE (msg, [], []);
   454 
   455 fun check_vars (t $ u) = (check_vars t; check_vars u)
   456   | check_vars (Abs (_, _, t)) = check_vars t
   457   | check_vars (Var (xi as (_, i), _)) =
   458       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   459   | check_vars _ = ();
   460 
   461 in
   462 
   463 fun certify' normalize prop pp consts thy tm =
   464   let
   465     val _ = Context.check_thy thy;
   466     val _ = check_vars tm;
   467     val tm' = Term.map_types (certify_typ thy) tm;
   468     val T = type_check pp tm';
   469     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   470     val tm'' = Consts.certify pp (tsig_of thy) consts tm';
   471     val tm'' = if normalize then tm'' else tm';
   472   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   473 
   474 fun certify_term thy = certify' true false (pp thy) (consts_of thy) thy;
   475 fun certify_prop thy = certify' true true (pp thy) (consts_of thy) thy;
   476 
   477 fun cert_term_abbrev thy = #1 o certify' false false (pp thy) (consts_of thy) thy;
   478 val cert_term = #1 oo certify_term;
   479 val cert_prop = #1 oo certify_prop;
   480 
   481 end;
   482 
   483 
   484 (* specifications *)
   485 
   486 fun no_vars pp tm =
   487   (case (Term.add_vars tm [], Term.add_tvars tm []) of
   488     ([], []) => tm
   489   | (vars, tvars) => error (Pretty.string_of (Pretty.block (Pretty.breaks
   490       (Pretty.str "Illegal schematic variable(s) in term:" ::
   491        map (Pretty.term pp o Var) vars @ map (Pretty.typ pp o TVar) tvars)))));
   492 
   493 fun cert_def pp tm =
   494   let val ((lhs, rhs), _) = tm
   495     |> no_vars pp
   496     |> Logic.strip_imp_concl
   497     |> Logic.dest_def pp Term.is_Const (K false) (K false)
   498   in (Term.dest_Const (Term.head_of lhs), rhs) end
   499   handle TERM (msg, _) => error msg;
   500 
   501 
   502 
   503 (** read and certify entities **)    (*exception ERROR*)
   504 
   505 (* classes and sorts *)
   506 
   507 fun read_class thy c = certify_class thy (intern_class thy c)
   508   handle TYPE (msg, _, _) => error msg;
   509 
   510 fun read_sort' syn context str =
   511   let
   512     val thy = Context.theory_of context;
   513     val _ = Context.check_thy thy;
   514     val S = intern_sort thy (Syntax.read_sort context syn str);
   515   in certify_sort thy S handle TYPE (msg, _, _) => error msg end;
   516 
   517 fun read_sort thy str = read_sort' (syn_of thy) (Context.Theory thy) str;
   518 
   519 
   520 (* type arities *)
   521 
   522 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   523   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   524   in Type.add_arity (pp thy) arity (tsig_of thy); arity end;
   525 
   526 val read_arity = prep_arity intern_type read_sort;
   527 val cert_arity = prep_arity (K I) certify_sort;
   528 
   529 
   530 (* types *)
   531 
   532 local
   533 
   534 fun gen_read_typ' cert syn context def_sort str =
   535   let
   536     val thy = Context.theory_of context;
   537     val _ = Context.check_thy thy;
   538     val get_sort = TypeInfer.get_sort (tsig_of thy) def_sort (intern_sort thy);
   539     val T = intern_tycons thy (Syntax.read_typ context syn get_sort (intern_sort thy) str);
   540   in cert thy T handle TYPE (msg, _, _) => error msg end
   541   handle ERROR msg => cat_error msg ("The error(s) above occurred in type " ^ quote str);
   542 
   543 fun gen_read_typ cert (thy, def_sort) str =
   544   gen_read_typ' cert (syn_of thy) (Context.Theory thy) def_sort str;
   545 
   546 in
   547 
   548 fun no_def_sort thy = (thy: theory, K NONE);
   549 
   550 val read_typ'        = gen_read_typ' certify_typ;
   551 val read_typ_syntax' = gen_read_typ' certify_typ_syntax;
   552 val read_typ_abbrev' = gen_read_typ' certify_typ_abbrev;
   553 val read_typ         = gen_read_typ certify_typ;
   554 val read_typ_syntax  = gen_read_typ certify_typ_syntax;
   555 val read_typ_abbrev  = gen_read_typ certify_typ_abbrev;
   556 
   557 end;
   558 
   559 
   560 (* type and constant names *)
   561 
   562 fun read_tyname thy raw_c =
   563   let val c = intern_type thy raw_c
   564   in Type (c, replicate (arity_number thy c) dummyT) end;
   565 
   566 val read_const = Consts.read_const o consts_of;
   567 
   568 
   569 
   570 (** infer_types **)         (*exception ERROR*)
   571 
   572 (*
   573   def_type: partial map from indexnames to types (constrains Frees and Vars)
   574   def_sort: partial map from indexnames to sorts (constrains TFrees and TVars)
   575   used: context of already used type variables
   576   freeze: if true then generated parameters are turned into TFrees, else TVars
   577 
   578   termss: lists of alternative parses (only one combination should be type-correct)
   579   typs: expected types
   580 *)
   581 
   582 fun infer_types_simult pp thy consts def_type def_sort used freeze args =
   583   let
   584     val termss = fold_rev (multiply o fst) args [[]];
   585     val typs =
   586       map (fn (_, T) => certify_typ thy T handle TYPE (msg, _, _) => error msg) args;
   587 
   588     fun infer ts = Result (TypeInfer.infer_types (Syntax.pp_show_brackets pp) (tsig_of thy)
   589         (try (Consts.constraint consts)) def_type def_sort (Consts.intern consts)
   590         (intern_tycons thy) (intern_sort thy) used freeze typs ts)
   591       handle TYPE (msg, _, _) => Exn (ERROR msg);
   592 
   593     val err_results = map infer termss;
   594     val errs = map_filter (fn Exn (ERROR msg) => SOME msg | _ => NONE) err_results;
   595     val results = map_filter get_result err_results;
   596 
   597     val ambiguity = length termss;
   598     fun ambig_msg () =
   599       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level then
   600         "Got more than one parse tree.\n\
   601         \Retry with smaller Syntax.ambiguity_level for more information."
   602       else "";
   603   in
   604     if null results then (cat_error (ambig_msg ()) (cat_lines errs))
   605     else if length results = 1 then
   606       (if ambiguity > ! Syntax.ambiguity_level then
   607         warning "Fortunately, only one parse tree is type correct.\n\
   608           \You may still want to disambiguate your grammar or your input."
   609       else (); hd results)
   610     else (cat_error (ambig_msg ()) ("More than one term is type correct:\n" ^
   611       cat_lines (map (Pretty.string_of_term pp) (maps fst results))))
   612   end;
   613 
   614 fun infer_types pp thy consts def_type def_sort used freeze tsT =
   615   apfst hd (infer_types_simult pp thy consts def_type def_sort used freeze [tsT]);
   616 
   617 
   618 (* read_def_terms -- read terms and infer types *)    (*exception ERROR*)
   619 
   620 fun read_def_terms' pp is_logtype syn consts context (types, sorts) used freeze sTs =
   621   let
   622     val thy = Context.theory_of context;
   623     fun read (s, T) =
   624       let val T' = certify_typ thy T handle TYPE (msg, _, _) => error msg
   625       in (Syntax.read context is_logtype syn T' s, T') end;
   626   in infer_types_simult pp thy consts types sorts used freeze (map read sTs) end;
   627 
   628 fun read_def_terms (thy, types, sorts) used freeze sTs =
   629   let
   630     val pp = pp thy;
   631     val consts = consts_of thy;
   632     val cert_consts = Consts.certify pp (tsig_of thy) consts;
   633     val (ts, inst) =
   634       read_def_terms' pp (is_logtype thy) (syn_of thy) consts
   635         (Context.Theory thy) (types, sorts) (Name.make_context used) freeze sTs;
   636   in (map cert_consts ts, inst) end;
   637 
   638 fun simple_read_term thy T s =
   639   let val ([t], _) = read_def_terms (thy, K NONE, K NONE) [] true [(s, T)]
   640   in t end handle ERROR msg => cat_error msg ("The error(s) above occurred for term " ^ s);
   641 
   642 fun read_term thy = simple_read_term thy TypeInfer.logicT;
   643 fun read_prop thy = simple_read_term thy propT;
   644 
   645 
   646 
   647 (** signature extension functions **)  (*exception ERROR/TYPE*)
   648 
   649 (* add default sort *)
   650 
   651 fun gen_add_defsort prep_sort s thy =
   652   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   653 
   654 val add_defsort = gen_add_defsort read_sort;
   655 val add_defsort_i = gen_add_defsort certify_sort;
   656 
   657 
   658 (* add type constructors *)
   659 
   660 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   661   let
   662     val syn' = Syntax.extend_type_gram types syn;
   663     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   664     val tsig' = Type.add_types naming decls tsig;
   665   in (naming, syn', tsig', consts) end);
   666 
   667 fun add_typedecls decls thy =
   668   let
   669     fun type_of (a, vs: string list, mx) =
   670       if not (has_duplicates (op =) vs) then (a, length vs, mx)
   671       else error ("Duplicate parameters in type declaration: " ^ quote a);
   672   in add_types (map type_of decls) thy end;
   673 
   674 
   675 (* add nonterminals *)
   676 
   677 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   678   let
   679     val syn' = Syntax.extend_consts ns syn;
   680     val tsig' = Type.add_nonterminals naming ns tsig;
   681   in (naming, syn', tsig', consts) end);
   682 
   683 
   684 (* add type abbreviations *)
   685 
   686 fun gen_add_tyabbr prep_typ (a, vs, rhs, mx) thy =
   687   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   688     let
   689       val syn' = Syntax.extend_type_gram [(a, length vs, mx)] syn;
   690       val a' = Syntax.type_name a mx;
   691       val abbr = (a', vs, prep_typ thy rhs)
   692         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   693       val tsig' = Type.add_abbrevs naming [abbr] tsig;
   694     in (naming, syn', tsig', consts) end);
   695 
   696 val add_tyabbrs = fold (gen_add_tyabbr (read_typ_syntax o no_def_sort));
   697 val add_tyabbrs_i = fold (gen_add_tyabbr certify_typ_syntax);
   698 
   699 
   700 (* modify syntax *)
   701 
   702 fun gen_syntax change_gram prep_typ mode args thy =
   703   let
   704     fun prep (c, T, mx) = (c, prep_typ thy T, mx) handle ERROR msg =>
   705       cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   706   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   707 
   708 fun gen_add_syntax x = gen_syntax Syntax.extend_const_gram x;
   709 
   710 val add_modesyntax = gen_add_syntax (read_typ_syntax o no_def_sort);
   711 val add_modesyntax_i = gen_add_syntax certify_typ_syntax;
   712 val add_syntax = add_modesyntax Syntax.default_mode;
   713 val add_syntax_i = add_modesyntax_i Syntax.default_mode;
   714 val del_modesyntax = gen_syntax Syntax.remove_const_gram (read_typ_syntax o no_def_sort);
   715 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram certify_typ_syntax;
   716 
   717 fun const_syntax thy (Const (c, _), mx) = SOME (Consts.syntax (consts_of thy) (c, mx))
   718   | const_syntax _ _ = NONE;
   719 
   720 fun add_notation mode args thy =
   721   thy |> add_modesyntax_i mode (map_filter (const_syntax thy) args);
   722 
   723 
   724 (* add constants *)
   725 
   726 local
   727 
   728 fun gen_add_consts prep_typ authentic raw_args thy =
   729   let
   730     val prepT = Compress.typ thy o Logic.varifyT o Type.no_tvars o Term.no_dummyT o prep_typ thy;
   731     fun prep (raw_c, raw_T, raw_mx) =
   732       let
   733         val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   734         val c' = if authentic then Syntax.constN ^ full_name thy c else c;
   735         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   736           cat_error msg ("in declaration of constant " ^ quote c);
   737       in (((c, T), authentic), (c', T, mx)) end;
   738     val args = map prep raw_args;
   739   in
   740     thy
   741     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   742     |> add_syntax_i (map #2 args)
   743   end;
   744 
   745 in
   746 
   747 val add_consts = gen_add_consts (read_typ o no_def_sort) false;
   748 val add_consts_i = gen_add_consts certify_typ false;
   749 val add_consts_authentic = gen_add_consts certify_typ true;
   750 
   751 end;
   752 
   753 
   754 (* add abbreviations *)
   755 
   756 fun add_abbrevs prmode = fold_map (fn ((raw_c, raw_mx), raw_t) => fn thy =>
   757   let
   758     val prep_tm = Compress.term thy o Logic.varify o no_vars (pp thy) o
   759       Term.no_dummy_patterns o cert_term_abbrev thy;
   760 
   761     val (c, mx) = Syntax.const_mixfix raw_c raw_mx;
   762     val full_c = full_name thy c;
   763     val c' = Syntax.constN ^ full_c;
   764     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   765       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote c);
   766     val T = Term.fastype_of t;
   767   in
   768     thy
   769     |> map_consts
   770       (Consts.abbreviate (pp thy) (tsig_of thy) (naming_of thy) (#1 prmode) ((c, t), true))
   771     |> add_modesyntax_i prmode [(c', T, mx)]
   772     |> pair (Const (full_c, T), t)
   773   end);
   774 
   775 
   776 (* add constraints *)
   777 
   778 fun gen_add_constraint int_const prep_typ (raw_c, opt_T) thy =
   779   let
   780     val c = int_const thy raw_c;
   781     fun prepT raw_T =
   782       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (prep_typ thy raw_T)))
   783       in cert_term thy (Const (c, T)); T end
   784       handle TYPE (msg, _, _) => error msg;
   785   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   786 
   787 val add_const_constraint = gen_add_constraint intern_const (read_typ o no_def_sort);
   788 val add_const_constraint_i = gen_add_constraint (K I) certify_typ;
   789 
   790 
   791 (* primitive classes and arities *)
   792 
   793 fun primitive_class (bclass, classes) thy =
   794   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   795     let
   796       val syn' = Syntax.extend_consts [bclass] syn;
   797       val tsig' = Type.add_class (pp thy) naming (bclass, classes) tsig;
   798     in (naming, syn', tsig', consts) end)
   799   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   800 
   801 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (pp thy) arg);
   802 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (pp thy) arg);
   803 
   804 
   805 (* add translation functions *)
   806 
   807 local
   808 
   809 fun mk trs = map Syntax.mk_trfun trs;
   810 
   811 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   812   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   813 
   814 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   815 
   816 in
   817 
   818 val add_trfuns = gen_add_trfuns Syntax.extend_trfuns Syntax.non_typed_tr';
   819 val add_trfunsT = gen_add_trfunsT Syntax.extend_trfuns;
   820 val add_advanced_trfuns = gen_add_trfuns Syntax.extend_advanced_trfuns Syntax.non_typed_tr'';
   821 val add_advanced_trfunsT = gen_add_trfunsT Syntax.extend_advanced_trfuns;
   822 
   823 end;
   824 
   825 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   826 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   827 
   828 
   829 (* compile translation functions *)
   830 
   831 local
   832 
   833 fun advancedT false = ""
   834   | advancedT true = "Context.generic -> ";
   835 
   836 fun advancedN false = ""
   837   | advancedN true = "advanced_";
   838 
   839 in
   840 
   841 fun parse_ast_translation (a, txt) =
   842   txt |> Context.use_let ("val parse_ast_translation: (string * (" ^ advancedT a ^
   843       "Syntax.ast list -> Syntax.ast)) list")
   844     ("Sign.add_" ^ advancedN a ^ "trfuns (parse_ast_translation, [], [], [])");
   845 
   846 fun parse_translation (a, txt) =
   847   txt |> Context.use_let ("val parse_translation: (string * (" ^ advancedT a ^
   848       "term list -> term)) list")
   849     ("Sign.add_" ^ advancedN a ^ "trfuns ([], parse_translation, [], [])");
   850 
   851 fun print_translation (a, txt) =
   852   txt |> Context.use_let ("val print_translation: (string * (" ^ advancedT a ^
   853       "term list -> term)) list")
   854     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], print_translation, [])");
   855 
   856 fun print_ast_translation (a, txt) =
   857   txt |> Context.use_let ("val print_ast_translation: (string * (" ^ advancedT a ^
   858       "Syntax.ast list -> Syntax.ast)) list")
   859     ("Sign.add_" ^ advancedN a ^ "trfuns ([], [], [], print_ast_translation)");
   860 
   861 fun typed_print_translation (a, txt) =
   862   txt |> Context.use_let ("val typed_print_translation: (string * (" ^ advancedT a ^
   863       "bool -> typ -> term list -> term)) list")
   864     ("Sign.add_" ^ advancedN a ^ "trfunsT typed_print_translation");
   865 
   866 val token_translation =
   867   Context.use_let "val token_translation: (string * string * (string -> string * real)) list"
   868     "Sign.add_tokentrfuns token_translation";
   869 
   870 end;
   871 
   872 
   873 (* translation rules *)
   874 
   875 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   876   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   877   in f (Context.Theory thy) (is_logtype thy) syn rules syn end);
   878 
   879 val add_trrules = gen_trrules Syntax.extend_trrules;
   880 val del_trrules = gen_trrules Syntax.remove_trrules;
   881 val add_trrules_i = map_syn o Syntax.extend_trrules_i;
   882 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   883 
   884 
   885 (* modify naming *)
   886 
   887 val add_path        = map_naming o NameSpace.add_path;
   888 val no_base_names   = map_naming NameSpace.no_base_names;
   889 val qualified_names = map_naming NameSpace.qualified_names;
   890 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   891 val set_policy      = map_naming o NameSpace.set_policy;
   892 val restore_naming  = map_naming o K o naming_of;
   893 
   894 val parent_path   = add_path "..";
   895 val root_path     = add_path "/";
   896 val absolute_path = add_path "//";
   897 
   898 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   899 
   900 
   901 (* hide names *)
   902 
   903 fun hide_classes b xs thy = thy |> map_tsig (Type.hide_classes b (map (intern_class thy) xs));
   904 val hide_classes_i = map_tsig oo Type.hide_classes;
   905 fun hide_types b xs thy = thy |> map_tsig (Type.hide_types b (map (intern_type thy) xs));
   906 val hide_types_i = map_tsig oo Type.hide_types;
   907 fun hide_consts b xs thy = thy |> map_consts (fold (Consts.hide b o intern_const thy) xs);
   908 val hide_consts_i = map_consts oo (fold o Consts.hide);
   909 
   910 local
   911 
   912 val kinds =
   913  [("class", (intern_class, can o certify_class, hide_classes_i)),
   914   ("type", (intern_type, declared_tyname, hide_types_i)),
   915   ("const", (intern_const, declared_const, hide_consts_i))];
   916 
   917 fun gen_hide int b (kind, xnames) thy =
   918   (case AList.lookup (op =) kinds kind of
   919     SOME (intern, check, hide) =>
   920       let
   921         val names = if int then map (intern thy) xnames else xnames;
   922         val bads = filter_out (check thy) names;
   923       in
   924         if null bads then hide b names thy
   925         else error ("Attempt to hide undeclared item(s): " ^ commas_quote bads)
   926       end
   927   | NONE => error ("Bad name space specification: " ^ quote kind));
   928 
   929 in
   930 
   931 val hide_names = gen_hide true;
   932 val hide_names_i = gen_hide false;
   933 
   934 end;
   935 
   936 end;