src/Pure/variable.ML
author wenzelm
Tue Nov 28 00:35:21 2006 +0100 (2006-11-28)
changeset 21566 af2932baf068
parent 21522 bd641d927437
child 21571 6096c956a11f
permissions -rw-r--r--
dest_term: strip_imp_concl;
     1 (*  Title:      Pure/variable.ML
     2     ID:         $Id$
     3     Author:     Makarius
     4 
     5 Fixed type/term variables and polymorphic term abbreviations.
     6 *)
     7 
     8 signature VARIABLE =
     9 sig
    10   val is_body: Proof.context -> bool
    11   val set_body: bool -> Proof.context -> Proof.context
    12   val restore_body: Proof.context -> Proof.context -> Proof.context
    13   val names_of: Proof.context -> Name.context
    14   val fixes_of: Proof.context -> (string * string) list
    15   val binds_of: Proof.context -> (typ * term) Vartab.table
    16   val constraints_of: Proof.context -> typ Vartab.table * sort Vartab.table
    17   val is_declared: Proof.context -> string -> bool
    18   val is_fixed: Proof.context -> string -> bool
    19   val newly_fixed: Proof.context -> Proof.context -> string -> bool
    20   val default_type: Proof.context -> string -> typ option
    21   val def_type: Proof.context -> bool -> indexname -> typ option
    22   val def_sort: Proof.context -> indexname -> sort option
    23   val declare_constraints: term -> Proof.context -> Proof.context
    24   val declare_internal: term -> Proof.context -> Proof.context
    25   val declare_term: term -> Proof.context -> Proof.context
    26   val declare_prf: Proofterm.proof -> Proof.context -> Proof.context
    27   val declare_thm: thm -> Proof.context -> Proof.context
    28   val thm_context: thm -> Proof.context
    29   val variant_frees: Proof.context -> term list -> (string * 'a) list -> (string * 'a) list
    30   val hidden_polymorphism: term -> typ -> (indexname * sort) list
    31   val add_binds: (indexname * term option) list -> Proof.context -> Proof.context
    32   val expand_binds: Proof.context -> term -> term
    33   val add_fixes: string list -> Proof.context -> string list * Proof.context
    34   val add_fixes_direct: string list -> Proof.context -> Proof.context
    35   val auto_fixes: term -> Proof.context -> Proof.context
    36   val variant_fixes: string list -> Proof.context -> string list * Proof.context
    37   val invent_types: sort list -> Proof.context -> (string * sort) list * Proof.context
    38   val export_inst: Proof.context -> Proof.context -> string list * string list
    39   val exportT_inst: Proof.context -> Proof.context -> string list
    40   val export_terms: Proof.context -> Proof.context -> term list -> term list
    41   val exportT_terms: Proof.context -> Proof.context -> term list -> term list
    42   val exportT: Proof.context -> Proof.context -> thm list -> thm list
    43   val export_prf: Proof.context -> Proof.context -> Proofterm.proof -> Proofterm.proof
    44   val export: Proof.context -> Proof.context -> thm list -> thm list
    45   val export_morphism: Proof.context -> Proof.context -> morphism
    46   val importT_inst: term list -> Proof.context -> ((indexname * sort) * typ) list * Proof.context
    47   val import_inst: bool -> term list -> Proof.context ->
    48     (((indexname * sort) * typ) list * ((indexname * typ) * term) list) * Proof.context
    49   val importT_terms: term list -> Proof.context -> term list * Proof.context
    50   val import_terms: bool -> term list -> Proof.context -> term list * Proof.context
    51   val importT: thm list -> Proof.context -> (ctyp list * thm list) * Proof.context
    52   val import_prf: bool -> Proofterm.proof -> Proof.context -> Proofterm.proof * Proof.context
    53   val import: bool -> thm list -> Proof.context ->
    54     ((ctyp list * cterm list) * thm list) * Proof.context
    55   val tradeT: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    56   val trade: (Proof.context -> thm list -> thm list) -> Proof.context -> thm list -> thm list
    57   val focus: cterm -> Proof.context -> (cterm list * cterm) * Proof.context
    58   val focus_subgoal: int -> thm -> Proof.context -> (cterm list * cterm) * Proof.context
    59   val warn_extra_tfrees: Proof.context -> Proof.context -> unit
    60   val polymorphic: Proof.context -> term list -> term list
    61 end;
    62 
    63 structure Variable: VARIABLE =
    64 struct
    65 
    66 (** local context data **)
    67 
    68 datatype data = Data of
    69  {is_body: bool,                        (*inner body mode*)
    70   names: Name.context,                  (*type/term variable names*)
    71   fixes: (string * string) list,        (*term fixes -- extern/intern*)
    72   binds: (typ * term) Vartab.table,     (*term bindings*)
    73   type_occs: string list Symtab.table,  (*type variables -- possibly within term variables*)
    74   constraints:
    75     typ Vartab.table *                  (*type constraints*)
    76     sort Vartab.table};                 (*default sorts*)
    77 
    78 fun make_data (is_body, names, fixes, binds, type_occs, constraints) =
    79   Data {is_body = is_body, names = names, fixes = fixes, binds = binds,
    80     type_occs = type_occs, constraints = constraints};
    81 
    82 structure Data = ProofDataFun
    83 (
    84   val name = "Pure/variable";
    85   type T = data;
    86   fun init thy =
    87     make_data (false, Name.context, [], Vartab.empty, Symtab.empty, (Vartab.empty, Vartab.empty));
    88   fun print _ _ = ();
    89 );
    90 
    91 val _ = Context.add_setup Data.init;
    92 
    93 fun map_data f =
    94   Data.map (fn Data {is_body, names, fixes, binds, type_occs, constraints} =>
    95     make_data (f (is_body, names, fixes, binds, type_occs, constraints)));
    96 
    97 fun map_names f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
    98   (is_body, f names, fixes, binds, type_occs, constraints));
    99 
   100 fun map_fixes f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   101   (is_body, names, f fixes, binds, type_occs, constraints));
   102 
   103 fun map_binds f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   104   (is_body, names, fixes, f binds, type_occs, constraints));
   105 
   106 fun map_type_occs f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   107   (is_body, names, fixes, binds, f type_occs, constraints));
   108 
   109 fun map_constraints f = map_data (fn (is_body, names, fixes, binds, type_occs, constraints) =>
   110   (is_body, names, fixes, binds, type_occs, f constraints));
   111 
   112 fun rep_data ctxt = Data.get ctxt |> (fn Data args => args);
   113 
   114 val is_body = #is_body o rep_data;
   115 fun set_body b = map_data (fn (_, names, fixes, binds, type_occs, constraints) =>
   116   (b, names, fixes, binds, type_occs, constraints));
   117 fun restore_body ctxt = set_body (is_body ctxt);
   118 
   119 val names_of = #names o rep_data;
   120 val fixes_of = #fixes o rep_data;
   121 val binds_of = #binds o rep_data;
   122 val type_occs_of = #type_occs o rep_data;
   123 val constraints_of = #constraints o rep_data;
   124 
   125 val is_declared = Name.is_declared o names_of;
   126 fun is_fixed ctxt x = exists (fn (_, y) => x = y) (fixes_of ctxt);
   127 fun newly_fixed inner outer x = is_fixed inner x andalso not (is_fixed outer x);
   128 
   129 
   130 
   131 (** declarations **)
   132 
   133 (* default sorts and types *)
   134 
   135 fun default_type ctxt x = Vartab.lookup (#1 (constraints_of ctxt)) (x, ~1);
   136 
   137 fun def_type ctxt pattern xi =
   138   let val {binds, constraints = (types, _), ...} = rep_data ctxt in
   139     (case Vartab.lookup types xi of
   140       NONE =>
   141         if pattern then NONE
   142         else Vartab.lookup binds xi |> Option.map (TypeInfer.polymorphicT o #1)
   143     | some => some)
   144   end;
   145 
   146 val def_sort = Vartab.lookup o #2 o constraints_of;
   147 
   148 
   149 (* names *)
   150 
   151 val declare_type_names = map_names o
   152   fold_types (fold_atyps (fn TFree (a, _) => Name.declare a | _ => I));
   153 
   154 fun declare_names t =
   155   declare_type_names t #>
   156   map_names (fold_aterms (fn Free (x, _) => Name.declare x | _ => I) t);
   157 
   158 
   159 (* type occurrences *)
   160 
   161 val declare_type_occs = map_type_occs o fold_term_types
   162   (fn Free (x, _) => fold_atyps (fn TFree (a, _) => Symtab.insert_list (op =) (a, x) | _ => I)
   163     | _ => fold_atyps (fn TFree (a, _) => Symtab.default (a, []) | _ => I));
   164 
   165 
   166 (* constraints *)
   167 
   168 fun redeclare_skolems ctxt = ctxt |> map_constraints (apfst (fn types =>
   169   let
   170     fun decl (x, x') =
   171       (case default_type ctxt x' of
   172         SOME T => Vartab.update ((x, ~1), T)
   173       | NONE => I);
   174   in fold_rev decl (fixes_of ctxt) types end));
   175 
   176 fun constrain_tvar (xi, S) =
   177   if S = dummyS then Vartab.delete_safe xi else Vartab.update (xi, S);
   178 
   179 fun declare_constraints t = map_constraints (fn (types, sorts) =>
   180   let
   181     val types' = fold_aterms
   182       (fn Free (x, T) => Vartab.update ((x, ~1), T)
   183         | Var v => Vartab.update v
   184         | _ => I) t types;
   185     val sorts' = fold_types (fold_atyps
   186       (fn TFree (x, S) => constrain_tvar ((x, ~1), S)
   187         | TVar v => constrain_tvar v
   188         | _ => I)) t sorts;
   189   in (types', sorts') end)
   190   #> declare_type_names t
   191   #> redeclare_skolems;
   192 
   193 
   194 (* common declarations *)
   195 
   196 fun declare_internal t =
   197   declare_names t #>
   198   declare_type_occs t;
   199 
   200 fun declare_term t =
   201   declare_internal t #>
   202   declare_constraints t;
   203 
   204 val declare_prf = Proofterm.fold_proof_terms declare_internal (declare_internal o Logic.mk_type);
   205 
   206 val declare_thm = Drule.fold_terms declare_internal;
   207 fun thm_context th = declare_thm th (ProofContext.init (Thm.theory_of_thm th));
   208 
   209 
   210 (* renaming term/type frees *)
   211 
   212 fun variant_frees ctxt ts frees =
   213   let
   214     val names = names_of (fold declare_names ts ctxt);
   215     val xs = fst (Name.variants (map #1 frees) names);
   216   in xs ~~ map snd frees end;
   217 
   218 
   219 
   220 (** term bindings **)
   221 
   222 fun hidden_polymorphism t T =
   223   let
   224     val tvarsT = Term.add_tvarsT T [];
   225     val extra_tvars = Term.fold_types (Term.fold_atyps
   226       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   227   in extra_tvars end;
   228 
   229 fun add_bind (xi, NONE) = map_binds (Vartab.delete_safe xi)
   230   | add_bind ((x, i), SOME t) =
   231       let
   232         val T = Term.fastype_of t;
   233         val t' =
   234           if null (hidden_polymorphism t T) then t
   235           else Var ((x ^ "_has_extra_type_vars_on_rhs", i), T);
   236       in declare_term t' #> map_binds (Vartab.update ((x, i), (T, t'))) end;
   237 
   238 val add_binds = fold add_bind;
   239 
   240 fun expand_binds ctxt =
   241   let
   242     val binds = binds_of ctxt;
   243     fun expand (t as Var (xi, T)) =
   244           (case Vartab.lookup binds xi of
   245             SOME u => Envir.expand_atom T u
   246           | NONE => t)
   247       | expand t = t;
   248   in Envir.beta_norm o Term.map_aterms expand end;
   249 
   250 
   251 
   252 (** fixes **)
   253 
   254 local
   255 
   256 fun no_dups [] = ()
   257   | no_dups dups = error ("Duplicate fixed variable(s): " ^ commas_quote dups);
   258 
   259 fun new_fixes names' xs xs' =
   260   map_names (K names') #>
   261   map_fixes (fn fixes => (rev (xs ~~ xs') @ fixes)) #>
   262   fold (declare_constraints o Syntax.free) xs' #>
   263   pair xs';
   264 
   265 in
   266 
   267 fun add_fixes xs ctxt =
   268   let
   269     val _ =
   270       (case filter (can Name.dest_skolem) xs of [] => ()
   271       | bads => error ("Illegal internal Skolem constant(s): " ^ commas_quote bads));
   272     val _ = no_dups (duplicates (op =) xs);
   273     val (ys, zs) = split_list (fixes_of ctxt);
   274     val names = names_of ctxt;
   275     val (xs', names') =
   276       if is_body ctxt then Name.variants xs names |>> map Name.skolem
   277       else (no_dups (xs inter_string ys); no_dups (xs inter_string zs);
   278         (xs, fold Name.declare xs names));
   279   in ctxt |> new_fixes names' xs xs' end;
   280 
   281 fun variant_fixes raw_xs ctxt =
   282   let
   283     val names = names_of ctxt;
   284     val xs = map Name.clean raw_xs;
   285     val (xs', names') = Name.variants xs names |>> map Name.skolem;
   286   in ctxt |> new_fixes names' xs xs' end;
   287 
   288 end;
   289 
   290 
   291 fun add_fixes_direct xs ctxt = ctxt
   292   |> set_body false
   293   |> (snd o add_fixes xs)
   294   |> restore_body ctxt;
   295 
   296 fun fix_frees t ctxt = ctxt
   297   |> add_fixes_direct
   298       (rev (fold_aterms (fn Free (x, _) =>
   299         if is_fixed ctxt x then I else insert (op =) x | _ => I) t []));
   300 
   301 fun auto_fixes t ctxt =
   302   (if is_body ctxt then ctxt else fix_frees t ctxt)
   303   |> declare_term t;
   304 
   305 fun invent_types Ss ctxt =
   306   let
   307     val tfrees = Name.invents (names_of ctxt) "'a" (length Ss) ~~ Ss;
   308     val ctxt' = fold (declare_constraints o Logic.mk_type o TFree) tfrees ctxt;
   309   in (tfrees, ctxt') end;
   310 
   311 
   312 
   313 (** export -- generalize type/term variables **)
   314 
   315 fun export_inst inner outer =
   316   let
   317     val declared_outer = is_declared outer;
   318     val fixes_inner = fixes_of inner;
   319     val fixes_outer = fixes_of outer;
   320 
   321     val gen_fixes = map #2 (Library.take (length fixes_inner - length fixes_outer, fixes_inner));
   322     val still_fixed = not o member (op =) gen_fixes;
   323     val gen_fixesT =
   324       Symtab.fold (fn (a, xs) =>
   325         if declared_outer a orelse exists still_fixed xs
   326         then I else cons a) (type_occs_of inner) [];
   327   in (gen_fixesT, gen_fixes) end;
   328 
   329 fun exportT_inst inner outer = #1 (export_inst inner outer);
   330 
   331 fun exportT_terms inner outer ts =
   332   map (TermSubst.generalize (exportT_inst (fold declare_type_occs ts inner) outer, [])
   333     (fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1)) ts;
   334 
   335 fun export_terms inner outer ts =
   336   map (TermSubst.generalize (export_inst (fold declare_type_occs ts inner) outer)
   337     (fold Term.maxidx_term ts ~1 + 1)) ts;
   338 
   339 fun export_prf inner outer prf =
   340   let
   341     val insts = export_inst (declare_prf prf inner) outer;
   342     val idx = Proofterm.maxidx_proof prf ~1 + 1;
   343     val gen_term = TermSubst.generalize_option insts idx;
   344     val gen_typ = TermSubst.generalizeT_option (#1 insts) idx;
   345   in Proofterm.map_proof_terms_option gen_term gen_typ prf end;
   346 
   347 fun gen_export inst inner outer ths =
   348   let
   349     val inner' = fold (declare_type_occs o Thm.full_prop_of) ths inner;
   350   in map (Thm.generalize (inst inner' outer) (fold Thm.maxidx_thm ths ~1 + 1)) ths end;
   351 
   352 val exportT = gen_export (rpair [] oo exportT_inst);
   353 val export = gen_export export_inst;
   354 
   355 fun export_morphism inner outer =
   356   let
   357     val fact = export inner outer;
   358     val term = singleton (export_terms inner outer);
   359     val typ = Logic.type_map term;
   360   in Morphism.morphism {name = I, var = I, typ = typ, term = term, fact = fact} end;
   361 
   362 
   363 (** import -- fix schematic type/term variables **)
   364 
   365 fun importT_inst ts ctxt =
   366   let
   367     val tvars = rev (fold Term.add_tvars ts []);
   368     val (tfrees, ctxt') = invent_types (map #2 tvars) ctxt;
   369   in (tvars ~~ map TFree tfrees, ctxt') end;
   370 
   371 fun import_inst is_open ts ctxt =
   372   let
   373     val ren = if is_open then I else Name.internal;
   374     val (instT, ctxt') = importT_inst ts ctxt;
   375     val vars = map (apsnd (TermSubst.instantiateT instT)) (rev (fold Term.add_vars ts []));
   376     val (xs, ctxt'') = variant_fixes (map (ren o #1 o #1) vars) ctxt';
   377     val inst = vars ~~ map Free (xs ~~ map #2 vars);
   378   in ((instT, inst), ctxt'') end;
   379 
   380 fun importT_terms ts ctxt =
   381   let val (instT, ctxt') = importT_inst ts ctxt
   382   in (map (TermSubst.instantiate (instT, [])) ts, ctxt') end;
   383 
   384 fun import_terms is_open ts ctxt =
   385   let val (inst, ctxt') = import_inst is_open ts ctxt
   386   in (map (TermSubst.instantiate inst) ts, ctxt') end;
   387 
   388 fun importT ths ctxt =
   389   let
   390     val thy = ProofContext.theory_of ctxt;
   391     val certT = Thm.ctyp_of thy;
   392     val (instT, ctxt') = importT_inst (map Thm.full_prop_of ths) ctxt;
   393     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   394     val ths' = map (Thm.instantiate (instT', [])) ths;
   395   in ((map #2 instT', ths'), ctxt') end;
   396 
   397 fun import_prf is_open prf ctxt =
   398   let
   399     val ts = rev (Proofterm.fold_proof_terms cons (cons o Logic.mk_type) prf []);
   400     val (insts, ctxt') = import_inst is_open ts ctxt;
   401   in (Proofterm.instantiate insts prf, ctxt') end;
   402 
   403 fun import is_open ths ctxt =
   404   let
   405     val thy = ProofContext.theory_of ctxt;
   406     val cert = Thm.cterm_of thy;
   407     val certT = Thm.ctyp_of thy;
   408     val ((instT, inst), ctxt') = import_inst is_open (map Thm.full_prop_of ths) ctxt;
   409     val instT' = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   410     val inst' = map (fn (v, t) => (cert (Var v), cert t)) inst;
   411     val ths' = map (Thm.instantiate (instT', inst')) ths;
   412   in (((map #2 instT', map #2 inst'), ths'), ctxt') end;
   413 
   414 
   415 (* import/export *)
   416 
   417 fun gen_trade imp exp f ctxt ths =
   418   let val ((_, ths'), ctxt') = imp ths ctxt
   419   in exp ctxt' ctxt (f ctxt' ths') end;
   420 
   421 val tradeT = gen_trade importT exportT;
   422 val trade = gen_trade (import true) export;
   423 
   424 
   425 (* focus on outermost parameters *)
   426 
   427 fun forall_elim_prop t prop =
   428   Thm.beta_conversion false (Thm.capply (Thm.dest_arg prop) t)
   429   |> Thm.cprop_of |> Thm.dest_arg;
   430 
   431 fun focus goal ctxt =
   432   let
   433     val cert = Thm.cterm_of (Thm.theory_of_cterm goal);
   434     val t = Thm.term_of goal;
   435     val ps = Term.variant_frees t (Term.strip_all_vars t);   (*as they are printed :-*)
   436     val (xs, Ts) = split_list ps;
   437     val (xs', ctxt') = variant_fixes xs ctxt;
   438     val ps' = ListPair.map (cert o Free) (xs', Ts);
   439     val goal' = fold forall_elim_prop ps' goal;
   440   in ((ps', goal'), ctxt') end;
   441 
   442 fun focus_subgoal i st =
   443   let
   444     val all_vars = Drule.fold_terms Term.add_vars st [];
   445     val no_binds = map (fn (xi, _) => (xi, NONE)) all_vars;
   446   in
   447     add_binds no_binds #>
   448     fold (declare_constraints o Var) all_vars #>
   449     focus (Thm.cprem_of st i)
   450   end;
   451 
   452 
   453 
   454 (** implicit polymorphism **)
   455 
   456 (* warn_extra_tfrees *)
   457 
   458 fun warn_extra_tfrees ctxt1 ctxt2 =
   459   let
   460     fun occs_typ a = Term.exists_subtype (fn TFree (b, _) => a = b | _ => false);
   461     fun occs_free a x =
   462       (case def_type ctxt1 false (x, ~1) of
   463         SOME T => if occs_typ a T then I else cons (a, x)
   464       | NONE => cons (a, x));
   465 
   466     val occs1 = type_occs_of ctxt1;
   467     val occs2 = type_occs_of ctxt2;
   468     val extras = Symtab.fold (fn (a, xs) =>
   469       if Symtab.defined occs1 a then I else fold (occs_free a) xs) occs2 [];
   470     val tfrees = map #1 extras |> sort_distinct string_ord;
   471     val frees = map #2 extras |> sort_distinct string_ord;
   472   in
   473     if null extras then ()
   474     else warning ("Introduced fixed type variable(s): " ^ commas tfrees ^ " in " ^
   475       space_implode " or " (map quote frees))
   476   end;
   477 
   478 
   479 (* polymorphic terms *)
   480 
   481 fun polymorphic ctxt ts =
   482   let
   483     val ctxt' = fold declare_term ts ctxt;
   484     val occs = type_occs_of ctxt;
   485     val occs' = type_occs_of ctxt';
   486     val types = Symtab.fold (fn (a, _) => if Symtab.defined occs a then I else cons a) occs' [];
   487     val idx = fold (Term.fold_types Term.maxidx_typ) ts ~1 + 1;
   488   in map (TermSubst.generalize (types, []) idx) ts end;
   489 
   490 end;