src/HOL/Library/Multiset.thy
author chaieb
Mon Feb 09 17:21:46 2009 +0000 (2009-02-09)
changeset 29847 af32126ee729
parent 29509 1ff0f3f08a7b
child 29901 f4b3f8fbf599
permissions -rw-r--r--
added Determinants to Library
     1 (*  Title:      HOL/Library/Multiset.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, Lawrence C Paulson, Norbert Voelker
     3 *)
     4 
     5 header {* Multisets *}
     6 
     7 theory Multiset
     8 imports Plain "~~/src/HOL/List"
     9 begin
    10 
    11 subsection {* The type of multisets *}
    12 
    13 typedef 'a multiset = "{f::'a => nat. finite {x . f x > 0}}"
    14 proof
    15   show "(\<lambda>x. 0::nat) \<in> ?multiset" by simp
    16 qed
    17 
    18 lemmas multiset_typedef [simp] =
    19     Abs_multiset_inverse Rep_multiset_inverse Rep_multiset
    20   and [simp] = Rep_multiset_inject [symmetric]
    21 
    22 definition Mempty :: "'a multiset"  ("{#}") where
    23   [code del]: "{#} = Abs_multiset (\<lambda>a. 0)"
    24 
    25 definition single :: "'a => 'a multiset" where
    26   [code del]: "single a = Abs_multiset (\<lambda>b. if b = a then 1 else 0)"
    27 
    28 definition count :: "'a multiset => 'a => nat" where
    29   "count = Rep_multiset"
    30 
    31 definition MCollect :: "'a multiset => ('a => bool) => 'a multiset" where
    32   "MCollect M P = Abs_multiset (\<lambda>x. if P x then Rep_multiset M x else 0)"
    33 
    34 abbreviation Melem :: "'a => 'a multiset => bool"  ("(_/ :# _)" [50, 51] 50) where
    35   "a :# M == 0 < count M a"
    36 
    37 notation (xsymbols)
    38   Melem (infix "\<in>#" 50)
    39 
    40 syntax
    41   "_MCollect" :: "pttrn => 'a multiset => bool => 'a multiset"    ("(1{# _ :# _./ _#})")
    42 translations
    43   "{#x :# M. P#}" == "CONST MCollect M (\<lambda>x. P)"
    44 
    45 definition set_of :: "'a multiset => 'a set" where
    46   "set_of M = {x. x :# M}"
    47 
    48 instantiation multiset :: (type) "{plus, minus, zero, size}" 
    49 begin
    50 
    51 definition union_def [code del]:
    52   "M + N = Abs_multiset (\<lambda>a. Rep_multiset M a + Rep_multiset N a)"
    53 
    54 definition diff_def [code del]:
    55   "M - N = Abs_multiset (\<lambda>a. Rep_multiset M a - Rep_multiset N a)"
    56 
    57 definition Zero_multiset_def [simp]:
    58   "0 = {#}"
    59 
    60 definition size_def:
    61   "size M = setsum (count M) (set_of M)"
    62 
    63 instance ..
    64 
    65 end
    66 
    67 definition
    68   multiset_inter :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> 'a multiset"  (infixl "#\<inter>" 70) where
    69   "multiset_inter A B = A - (A - B)"
    70 
    71 text {* Multiset Enumeration *}
    72 syntax
    73   "_multiset" :: "args => 'a multiset"    ("{#(_)#}")
    74 translations
    75   "{#x, xs#}" == "{#x#} + {#xs#}"
    76   "{#x#}" == "CONST single x"
    77 
    78 
    79 text {*
    80  \medskip Preservation of the representing set @{term multiset}.
    81 *}
    82 
    83 lemma const0_in_multiset: "(\<lambda>a. 0) \<in> multiset"
    84 by (simp add: multiset_def)
    85 
    86 lemma only1_in_multiset: "(\<lambda>b. if b = a then 1 else 0) \<in> multiset"
    87 by (simp add: multiset_def)
    88 
    89 lemma union_preserves_multiset:
    90   "M \<in> multiset ==> N \<in> multiset ==> (\<lambda>a. M a + N a) \<in> multiset"
    91 apply (simp add: multiset_def)
    92 apply (drule (1) finite_UnI)
    93 apply (simp del: finite_Un add: Un_def)
    94 done
    95 
    96 lemma diff_preserves_multiset:
    97   "M \<in> multiset ==> (\<lambda>a. M a - N a) \<in> multiset"
    98 apply (simp add: multiset_def)
    99 apply (rule finite_subset)
   100  apply auto
   101 done
   102 
   103 lemma MCollect_preserves_multiset:
   104   "M \<in> multiset ==> (\<lambda>x. if P x then M x else 0) \<in> multiset"
   105 apply (simp add: multiset_def)
   106 apply (rule finite_subset, auto)
   107 done
   108 
   109 lemmas in_multiset = const0_in_multiset only1_in_multiset
   110   union_preserves_multiset diff_preserves_multiset MCollect_preserves_multiset
   111 
   112 
   113 subsection {* Algebraic properties *}
   114 
   115 subsubsection {* Union *}
   116 
   117 lemma union_empty [simp]: "M + {#} = M \<and> {#} + M = M"
   118 by (simp add: union_def Mempty_def in_multiset)
   119 
   120 lemma union_commute: "M + N = N + (M::'a multiset)"
   121 by (simp add: union_def add_ac in_multiset)
   122 
   123 lemma union_assoc: "(M + N) + K = M + (N + (K::'a multiset))"
   124 by (simp add: union_def add_ac in_multiset)
   125 
   126 lemma union_lcomm: "M + (N + K) = N + (M + (K::'a multiset))"
   127 proof -
   128   have "M + (N + K) = (N + K) + M" by (rule union_commute)
   129   also have "\<dots> = N + (K + M)" by (rule union_assoc)
   130   also have "K + M = M + K" by (rule union_commute)
   131   finally show ?thesis .
   132 qed
   133 
   134 lemmas union_ac = union_assoc union_commute union_lcomm
   135 
   136 instance multiset :: (type) comm_monoid_add
   137 proof
   138   fix a b c :: "'a multiset"
   139   show "(a + b) + c = a + (b + c)" by (rule union_assoc)
   140   show "a + b = b + a" by (rule union_commute)
   141   show "0 + a = a" by simp
   142 qed
   143 
   144 
   145 subsubsection {* Difference *}
   146 
   147 lemma diff_empty [simp]: "M - {#} = M \<and> {#} - M = {#}"
   148 by (simp add: Mempty_def diff_def in_multiset)
   149 
   150 lemma diff_union_inverse2 [simp]: "M + {#a#} - {#a#} = M"
   151 by (simp add: union_def diff_def in_multiset)
   152 
   153 lemma diff_cancel: "A - A = {#}"
   154 by (simp add: diff_def Mempty_def)
   155 
   156 
   157 subsubsection {* Count of elements *}
   158 
   159 lemma count_empty [simp]: "count {#} a = 0"
   160 by (simp add: count_def Mempty_def in_multiset)
   161 
   162 lemma count_single [simp]: "count {#b#} a = (if b = a then 1 else 0)"
   163 by (simp add: count_def single_def in_multiset)
   164 
   165 lemma count_union [simp]: "count (M + N) a = count M a + count N a"
   166 by (simp add: count_def union_def in_multiset)
   167 
   168 lemma count_diff [simp]: "count (M - N) a = count M a - count N a"
   169 by (simp add: count_def diff_def in_multiset)
   170 
   171 lemma count_MCollect [simp]:
   172   "count {# x:#M. P x #} a = (if P a then count M a else 0)"
   173 by (simp add: count_def MCollect_def in_multiset)
   174 
   175 
   176 subsubsection {* Set of elements *}
   177 
   178 lemma set_of_empty [simp]: "set_of {#} = {}"
   179 by (simp add: set_of_def)
   180 
   181 lemma set_of_single [simp]: "set_of {#b#} = {b}"
   182 by (simp add: set_of_def)
   183 
   184 lemma set_of_union [simp]: "set_of (M + N) = set_of M \<union> set_of N"
   185 by (auto simp add: set_of_def)
   186 
   187 lemma set_of_eq_empty_iff [simp]: "(set_of M = {}) = (M = {#})"
   188 by (auto simp: set_of_def Mempty_def in_multiset count_def expand_fun_eq [where f="Rep_multiset M"])
   189 
   190 lemma mem_set_of_iff [simp]: "(x \<in> set_of M) = (x :# M)"
   191 by (auto simp add: set_of_def)
   192 
   193 lemma set_of_MCollect [simp]: "set_of {# x:#M. P x #} = set_of M \<inter> {x. P x}"
   194 by (auto simp add: set_of_def)
   195 
   196 
   197 subsubsection {* Size *}
   198 
   199 lemma size_empty [simp]: "size {#} = 0"
   200 by (simp add: size_def)
   201 
   202 lemma size_single [simp]: "size {#b#} = 1"
   203 by (simp add: size_def)
   204 
   205 lemma finite_set_of [iff]: "finite (set_of M)"
   206 using Rep_multiset [of M] by (simp add: multiset_def set_of_def count_def)
   207 
   208 lemma setsum_count_Int:
   209   "finite A ==> setsum (count N) (A \<inter> set_of N) = setsum (count N) A"
   210 apply (induct rule: finite_induct)
   211  apply simp
   212 apply (simp add: Int_insert_left set_of_def)
   213 done
   214 
   215 lemma size_union [simp]: "size (M + N::'a multiset) = size M + size N"
   216 apply (unfold size_def)
   217 apply (subgoal_tac "count (M + N) = (\<lambda>a. count M a + count N a)")
   218  prefer 2
   219  apply (rule ext, simp)
   220 apply (simp (no_asm_simp) add: setsum_Un_nat setsum_addf setsum_count_Int)
   221 apply (subst Int_commute)
   222 apply (simp (no_asm_simp) add: setsum_count_Int)
   223 done
   224 
   225 lemma size_eq_0_iff_empty [iff]: "(size M = 0) = (M = {#})"
   226 apply (unfold size_def Mempty_def count_def, auto simp: in_multiset)
   227 apply (simp add: set_of_def count_def in_multiset expand_fun_eq)
   228 done
   229 
   230 lemma nonempty_has_size: "(S \<noteq> {#}) = (0 < size S)"
   231 by (metis gr0I gr_implies_not0 size_empty size_eq_0_iff_empty)
   232 
   233 lemma size_eq_Suc_imp_elem: "size M = Suc n ==> \<exists>a. a :# M"
   234 apply (unfold size_def)
   235 apply (drule setsum_SucD)
   236 apply auto
   237 done
   238 
   239 
   240 subsubsection {* Equality of multisets *}
   241 
   242 lemma multiset_eq_conv_count_eq: "(M = N) = (\<forall>a. count M a = count N a)"
   243 by (simp add: count_def expand_fun_eq)
   244 
   245 lemma single_not_empty [simp]: "{#a#} \<noteq> {#} \<and> {#} \<noteq> {#a#}"
   246 by (simp add: single_def Mempty_def in_multiset expand_fun_eq)
   247 
   248 lemma single_eq_single [simp]: "({#a#} = {#b#}) = (a = b)"
   249 by (auto simp add: single_def in_multiset expand_fun_eq)
   250 
   251 lemma union_eq_empty [iff]: "(M + N = {#}) = (M = {#} \<and> N = {#})"
   252 by (auto simp add: union_def Mempty_def in_multiset expand_fun_eq)
   253 
   254 lemma empty_eq_union [iff]: "({#} = M + N) = (M = {#} \<and> N = {#})"
   255 by (auto simp add: union_def Mempty_def in_multiset expand_fun_eq)
   256 
   257 lemma union_right_cancel [simp]: "(M + K = N + K) = (M = (N::'a multiset))"
   258 by (simp add: union_def in_multiset expand_fun_eq)
   259 
   260 lemma union_left_cancel [simp]: "(K + M = K + N) = (M = (N::'a multiset))"
   261 by (simp add: union_def in_multiset expand_fun_eq)
   262 
   263 lemma union_is_single:
   264   "(M + N = {#a#}) = (M = {#a#} \<and> N={#} \<or> M = {#} \<and> N = {#a#})"
   265 apply (simp add: Mempty_def single_def union_def in_multiset add_is_1 expand_fun_eq)
   266 apply blast
   267 done
   268 
   269 lemma single_is_union:
   270   "({#a#} = M + N) \<longleftrightarrow> ({#a#} = M \<and> N = {#} \<or> M = {#} \<and> {#a#} = N)"
   271 apply (unfold Mempty_def single_def union_def)
   272 apply (simp add: add_is_1 one_is_add in_multiset expand_fun_eq)
   273 apply (blast dest: sym)
   274 done
   275 
   276 lemma add_eq_conv_diff:
   277   "(M + {#a#} = N + {#b#}) =
   278    (M = N \<and> a = b \<or> M = N - {#a#} + {#b#} \<and> N = M - {#b#} + {#a#})"
   279 using [[simproc del: neq]]
   280 apply (unfold single_def union_def diff_def)
   281 apply (simp (no_asm) add: in_multiset expand_fun_eq)
   282 apply (rule conjI, force, safe, simp_all)
   283 apply (simp add: eq_sym_conv)
   284 done
   285 
   286 declare Rep_multiset_inject [symmetric, simp del]
   287 
   288 instance multiset :: (type) cancel_ab_semigroup_add
   289 proof
   290   fix a b c :: "'a multiset"
   291   show "a + b = a + c \<Longrightarrow> b = c" by simp
   292 qed
   293 
   294 lemma insert_DiffM:
   295   "x \<in># M \<Longrightarrow> {#x#} + (M - {#x#}) = M"
   296 by (clarsimp simp: multiset_eq_conv_count_eq)
   297 
   298 lemma insert_DiffM2[simp]:
   299   "x \<in># M \<Longrightarrow> M - {#x#} + {#x#} = M"
   300 by (clarsimp simp: multiset_eq_conv_count_eq)
   301 
   302 lemma multi_union_self_other_eq: 
   303   "(A::'a multiset) + X = A + Y \<Longrightarrow> X = Y"
   304 by (induct A arbitrary: X Y) auto
   305 
   306 lemma multi_self_add_other_not_self[simp]: "(A = A + {#x#}) = False"
   307 by (metis single_not_empty union_empty union_left_cancel)
   308 
   309 lemma insert_noteq_member: 
   310   assumes BC: "B + {#b#} = C + {#c#}"
   311    and bnotc: "b \<noteq> c"
   312   shows "c \<in># B"
   313 proof -
   314   have "c \<in># C + {#c#}" by simp
   315   have nc: "\<not> c \<in># {#b#}" using bnotc by simp
   316   then have "c \<in># B + {#b#}" using BC by simp
   317   then show "c \<in># B" using nc by simp
   318 qed
   319 
   320 
   321 lemma add_eq_conv_ex:
   322   "(M + {#a#} = N + {#b#}) =
   323     (M = N \<and> a = b \<or> (\<exists>K. M = K + {#b#} \<and> N = K + {#a#}))"
   324 by (auto simp add: add_eq_conv_diff)
   325 
   326 
   327 lemma empty_multiset_count:
   328   "(\<forall>x. count A x = 0) = (A = {#})"
   329 by (metis count_empty multiset_eq_conv_count_eq)
   330 
   331 
   332 subsubsection {* Intersection *}
   333 
   334 lemma multiset_inter_count:
   335   "count (A #\<inter> B) x = min (count A x) (count B x)"
   336 by (simp add: multiset_inter_def min_def)
   337 
   338 lemma multiset_inter_commute: "A #\<inter> B = B #\<inter> A"
   339 by (simp add: multiset_eq_conv_count_eq multiset_inter_count
   340     min_max.inf_commute)
   341 
   342 lemma multiset_inter_assoc: "A #\<inter> (B #\<inter> C) = A #\<inter> B #\<inter> C"
   343 by (simp add: multiset_eq_conv_count_eq multiset_inter_count
   344     min_max.inf_assoc)
   345 
   346 lemma multiset_inter_left_commute: "A #\<inter> (B #\<inter> C) = B #\<inter> (A #\<inter> C)"
   347 by (simp add: multiset_eq_conv_count_eq multiset_inter_count min_def)
   348 
   349 lemmas multiset_inter_ac =
   350   multiset_inter_commute
   351   multiset_inter_assoc
   352   multiset_inter_left_commute
   353 
   354 lemma multiset_inter_single: "a \<noteq> b \<Longrightarrow> {#a#} #\<inter> {#b#} = {#}"
   355 by (simp add: multiset_eq_conv_count_eq multiset_inter_count)
   356 
   357 lemma multiset_union_diff_commute: "B #\<inter> C = {#} \<Longrightarrow> A + B - C = A - C + B"
   358 apply (simp add: multiset_eq_conv_count_eq multiset_inter_count min_def
   359     split: split_if_asm)
   360 apply clarsimp
   361 apply (erule_tac x = a in allE)
   362 apply auto
   363 done
   364 
   365 
   366 subsubsection {* Comprehension (filter) *}
   367 
   368 lemma MCollect_empty [simp]: "MCollect {#} P = {#}"
   369 by (simp add: MCollect_def Mempty_def Abs_multiset_inject
   370     in_multiset expand_fun_eq)
   371 
   372 lemma MCollect_single [simp]:
   373   "MCollect {#x#} P = (if P x then {#x#} else {#})"
   374 by (simp add: MCollect_def Mempty_def single_def Abs_multiset_inject
   375     in_multiset expand_fun_eq)
   376 
   377 lemma MCollect_union [simp]:
   378   "MCollect (M+N) f = MCollect M f + MCollect N f"
   379 by (simp add: MCollect_def union_def Abs_multiset_inject
   380     in_multiset expand_fun_eq)
   381 
   382 
   383 subsection {* Induction and case splits *}
   384 
   385 lemma setsum_decr:
   386   "finite F ==> (0::nat) < f a ==>
   387     setsum (f (a := f a - 1)) F = (if a\<in>F then setsum f F - 1 else setsum f F)"
   388 apply (induct rule: finite_induct)
   389  apply auto
   390 apply (drule_tac a = a in mk_disjoint_insert, auto)
   391 done
   392 
   393 lemma rep_multiset_induct_aux:
   394 assumes 1: "P (\<lambda>a. (0::nat))"
   395   and 2: "!!f b. f \<in> multiset ==> P f ==> P (f (b := f b + 1))"
   396 shows "\<forall>f. f \<in> multiset --> setsum f {x. f x \<noteq> 0} = n --> P f"
   397 apply (unfold multiset_def)
   398 apply (induct_tac n, simp, clarify)
   399  apply (subgoal_tac "f = (\<lambda>a.0)")
   400   apply simp
   401   apply (rule 1)
   402  apply (rule ext, force, clarify)
   403 apply (frule setsum_SucD, clarify)
   404 apply (rename_tac a)
   405 apply (subgoal_tac "finite {x. (f (a := f a - 1)) x > 0}")
   406  prefer 2
   407  apply (rule finite_subset)
   408   prefer 2
   409   apply assumption
   410  apply simp
   411  apply blast
   412 apply (subgoal_tac "f = (f (a := f a - 1))(a := (f (a := f a - 1)) a + 1)")
   413  prefer 2
   414  apply (rule ext)
   415  apply (simp (no_asm_simp))
   416  apply (erule ssubst, rule 2 [unfolded multiset_def], blast)
   417 apply (erule allE, erule impE, erule_tac [2] mp, blast)
   418 apply (simp (no_asm_simp) add: setsum_decr del: fun_upd_apply One_nat_def)
   419 apply (subgoal_tac "{x. x \<noteq> a --> f x \<noteq> 0} = {x. f x \<noteq> 0}")
   420  prefer 2
   421  apply blast
   422 apply (subgoal_tac "{x. x \<noteq> a \<and> f x \<noteq> 0} = {x. f x \<noteq> 0} - {a}")
   423  prefer 2
   424  apply blast
   425 apply (simp add: le_imp_diff_is_add setsum_diff1_nat cong: conj_cong)
   426 done
   427 
   428 theorem rep_multiset_induct:
   429   "f \<in> multiset ==> P (\<lambda>a. 0) ==>
   430     (!!f b. f \<in> multiset ==> P f ==> P (f (b := f b + 1))) ==> P f"
   431 using rep_multiset_induct_aux by blast
   432 
   433 theorem multiset_induct [case_names empty add, induct type: multiset]:
   434 assumes empty: "P {#}"
   435   and add: "!!M x. P M ==> P (M + {#x#})"
   436 shows "P M"
   437 proof -
   438   note defns = union_def single_def Mempty_def
   439   show ?thesis
   440     apply (rule Rep_multiset_inverse [THEN subst])
   441     apply (rule Rep_multiset [THEN rep_multiset_induct])
   442      apply (rule empty [unfolded defns])
   443     apply (subgoal_tac "f(b := f b + 1) = (\<lambda>a. f a + (if a=b then 1 else 0))")
   444      prefer 2
   445      apply (simp add: expand_fun_eq)
   446     apply (erule ssubst)
   447     apply (erule Abs_multiset_inverse [THEN subst])
   448     apply (drule add [unfolded defns, simplified])
   449     apply(simp add:in_multiset)
   450     done
   451 qed
   452 
   453 lemma multi_nonempty_split: "M \<noteq> {#} \<Longrightarrow> \<exists>A a. M = A + {#a#}"
   454 by (induct M) auto
   455 
   456 lemma multiset_cases [cases type, case_names empty add]:
   457 assumes em:  "M = {#} \<Longrightarrow> P"
   458 assumes add: "\<And>N x. M = N + {#x#} \<Longrightarrow> P"
   459 shows "P"
   460 proof (cases "M = {#}")
   461   assume "M = {#}" then show ?thesis using em by simp
   462 next
   463   assume "M \<noteq> {#}"
   464   then obtain M' m where "M = M' + {#m#}" 
   465     by (blast dest: multi_nonempty_split)
   466   then show ?thesis using add by simp
   467 qed
   468 
   469 lemma multi_member_split: "x \<in># M \<Longrightarrow> \<exists>A. M = A + {#x#}"
   470 apply (cases M)
   471  apply simp
   472 apply (rule_tac x="M - {#x#}" in exI, simp)
   473 done
   474 
   475 lemma multiset_partition: "M = {# x:#M. P x #} + {# x:#M. \<not> P x #}"
   476 apply (subst multiset_eq_conv_count_eq)
   477 apply auto
   478 done
   479 
   480 declare multiset_typedef [simp del]
   481 
   482 lemma multi_drop_mem_not_eq: "c \<in># B \<Longrightarrow> B - {#c#} \<noteq> B"
   483 by (cases "B = {#}") (auto dest: multi_member_split)
   484 
   485 
   486 subsection {* Orderings *}
   487 
   488 subsubsection {* Well-foundedness *}
   489 
   490 definition mult1 :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
   491   [code del]: "mult1 r = {(N, M). \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and>
   492       (\<forall>b. b :# K --> (b, a) \<in> r)}"
   493 
   494 definition mult :: "('a \<times> 'a) set => ('a multiset \<times> 'a multiset) set" where
   495   "mult r = (mult1 r)\<^sup>+"
   496 
   497 lemma not_less_empty [iff]: "(M, {#}) \<notin> mult1 r"
   498 by (simp add: mult1_def)
   499 
   500 lemma less_add: "(N, M0 + {#a#}) \<in> mult1 r ==>
   501     (\<exists>M. (M, M0) \<in> mult1 r \<and> N = M + {#a#}) \<or>
   502     (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K)"
   503   (is "_ \<Longrightarrow> ?case1 (mult1 r) \<or> ?case2")
   504 proof (unfold mult1_def)
   505   let ?r = "\<lambda>K a. \<forall>b. b :# K --> (b, a) \<in> r"
   506   let ?R = "\<lambda>N M. \<exists>a M0 K. M = M0 + {#a#} \<and> N = M0 + K \<and> ?r K a"
   507   let ?case1 = "?case1 {(N, M). ?R N M}"
   508 
   509   assume "(N, M0 + {#a#}) \<in> {(N, M). ?R N M}"
   510   then have "\<exists>a' M0' K.
   511       M0 + {#a#} = M0' + {#a'#} \<and> N = M0' + K \<and> ?r K a'" by simp
   512   then show "?case1 \<or> ?case2"
   513   proof (elim exE conjE)
   514     fix a' M0' K
   515     assume N: "N = M0' + K" and r: "?r K a'"
   516     assume "M0 + {#a#} = M0' + {#a'#}"
   517     then have "M0 = M0' \<and> a = a' \<or>
   518         (\<exists>K'. M0 = K' + {#a'#} \<and> M0' = K' + {#a#})"
   519       by (simp only: add_eq_conv_ex)
   520     then show ?thesis
   521     proof (elim disjE conjE exE)
   522       assume "M0 = M0'" "a = a'"
   523       with N r have "?r K a \<and> N = M0 + K" by simp
   524       then have ?case2 .. then show ?thesis ..
   525     next
   526       fix K'
   527       assume "M0' = K' + {#a#}"
   528       with N have n: "N = K' + K + {#a#}" by (simp add: union_ac)
   529 
   530       assume "M0 = K' + {#a'#}"
   531       with r have "?R (K' + K) M0" by blast
   532       with n have ?case1 by simp then show ?thesis ..
   533     qed
   534   qed
   535 qed
   536 
   537 lemma all_accessible: "wf r ==> \<forall>M. M \<in> acc (mult1 r)"
   538 proof
   539   let ?R = "mult1 r"
   540   let ?W = "acc ?R"
   541   {
   542     fix M M0 a
   543     assume M0: "M0 \<in> ?W"
   544       and wf_hyp: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
   545       and acc_hyp: "\<forall>M. (M, M0) \<in> ?R --> M + {#a#} \<in> ?W"
   546     have "M0 + {#a#} \<in> ?W"
   547     proof (rule accI [of "M0 + {#a#}"])
   548       fix N
   549       assume "(N, M0 + {#a#}) \<in> ?R"
   550       then have "((\<exists>M. (M, M0) \<in> ?R \<and> N = M + {#a#}) \<or>
   551           (\<exists>K. (\<forall>b. b :# K --> (b, a) \<in> r) \<and> N = M0 + K))"
   552         by (rule less_add)
   553       then show "N \<in> ?W"
   554       proof (elim exE disjE conjE)
   555         fix M assume "(M, M0) \<in> ?R" and N: "N = M + {#a#}"
   556         from acc_hyp have "(M, M0) \<in> ?R --> M + {#a#} \<in> ?W" ..
   557         from this and `(M, M0) \<in> ?R` have "M + {#a#} \<in> ?W" ..
   558         then show "N \<in> ?W" by (simp only: N)
   559       next
   560         fix K
   561         assume N: "N = M0 + K"
   562         assume "\<forall>b. b :# K --> (b, a) \<in> r"
   563         then have "M0 + K \<in> ?W"
   564         proof (induct K)
   565           case empty
   566           from M0 show "M0 + {#} \<in> ?W" by simp
   567         next
   568           case (add K x)
   569           from add.prems have "(x, a) \<in> r" by simp
   570           with wf_hyp have "\<forall>M \<in> ?W. M + {#x#} \<in> ?W" by blast
   571           moreover from add have "M0 + K \<in> ?W" by simp
   572           ultimately have "(M0 + K) + {#x#} \<in> ?W" ..
   573           then show "M0 + (K + {#x#}) \<in> ?W" by (simp only: union_assoc)
   574         qed
   575         then show "N \<in> ?W" by (simp only: N)
   576       qed
   577     qed
   578   } note tedious_reasoning = this
   579 
   580   assume wf: "wf r"
   581   fix M
   582   show "M \<in> ?W"
   583   proof (induct M)
   584     show "{#} \<in> ?W"
   585     proof (rule accI)
   586       fix b assume "(b, {#}) \<in> ?R"
   587       with not_less_empty show "b \<in> ?W" by contradiction
   588     qed
   589 
   590     fix M a assume "M \<in> ?W"
   591     from wf have "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
   592     proof induct
   593       fix a
   594       assume r: "!!b. (b, a) \<in> r ==> (\<forall>M \<in> ?W. M + {#b#} \<in> ?W)"
   595       show "\<forall>M \<in> ?W. M + {#a#} \<in> ?W"
   596       proof
   597         fix M assume "M \<in> ?W"
   598         then show "M + {#a#} \<in> ?W"
   599           by (rule acc_induct) (rule tedious_reasoning [OF _ r])
   600       qed
   601     qed
   602     from this and `M \<in> ?W` show "M + {#a#} \<in> ?W" ..
   603   qed
   604 qed
   605 
   606 theorem wf_mult1: "wf r ==> wf (mult1 r)"
   607 by (rule acc_wfI) (rule all_accessible)
   608 
   609 theorem wf_mult: "wf r ==> wf (mult r)"
   610 unfolding mult_def by (rule wf_trancl) (rule wf_mult1)
   611 
   612 
   613 subsubsection {* Closure-free presentation *}
   614 
   615 (*Badly needed: a linear arithmetic procedure for multisets*)
   616 
   617 lemma diff_union_single_conv: "a :# J ==> I + J - {#a#} = I + (J - {#a#})"
   618 by (simp add: multiset_eq_conv_count_eq)
   619 
   620 text {* One direction. *}
   621 
   622 lemma mult_implies_one_step:
   623   "trans r ==> (M, N) \<in> mult r ==>
   624     \<exists>I J K. N = I + J \<and> M = I + K \<and> J \<noteq> {#} \<and>
   625     (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r)"
   626 apply (unfold mult_def mult1_def set_of_def)
   627 apply (erule converse_trancl_induct, clarify)
   628  apply (rule_tac x = M0 in exI, simp, clarify)
   629 apply (case_tac "a :# K")
   630  apply (rule_tac x = I in exI)
   631  apply (simp (no_asm))
   632  apply (rule_tac x = "(K - {#a#}) + Ka" in exI)
   633  apply (simp (no_asm_simp) add: union_assoc [symmetric])
   634  apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong)
   635  apply (simp add: diff_union_single_conv)
   636  apply (simp (no_asm_use) add: trans_def)
   637  apply blast
   638 apply (subgoal_tac "a :# I")
   639  apply (rule_tac x = "I - {#a#}" in exI)
   640  apply (rule_tac x = "J + {#a#}" in exI)
   641  apply (rule_tac x = "K + Ka" in exI)
   642  apply (rule conjI)
   643   apply (simp add: multiset_eq_conv_count_eq split: nat_diff_split)
   644  apply (rule conjI)
   645   apply (drule_tac f = "\<lambda>M. M - {#a#}" in arg_cong, simp)
   646   apply (simp add: multiset_eq_conv_count_eq split: nat_diff_split)
   647  apply (simp (no_asm_use) add: trans_def)
   648  apply blast
   649 apply (subgoal_tac "a :# (M0 + {#a#})")
   650  apply simp
   651 apply (simp (no_asm))
   652 done
   653 
   654 lemma elem_imp_eq_diff_union: "a :# M ==> M = M - {#a#} + {#a#}"
   655 by (simp add: multiset_eq_conv_count_eq)
   656 
   657 lemma size_eq_Suc_imp_eq_union: "size M = Suc n ==> \<exists>a N. M = N + {#a#}"
   658 apply (erule size_eq_Suc_imp_elem [THEN exE])
   659 apply (drule elem_imp_eq_diff_union, auto)
   660 done
   661 
   662 lemma one_step_implies_mult_aux:
   663   "trans r ==>
   664     \<forall>I J K. (size J = n \<and> J \<noteq> {#} \<and> (\<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r))
   665       --> (I + K, I + J) \<in> mult r"
   666 apply (induct_tac n, auto)
   667 apply (frule size_eq_Suc_imp_eq_union, clarify)
   668 apply (rename_tac "J'", simp)
   669 apply (erule notE, auto)
   670 apply (case_tac "J' = {#}")
   671  apply (simp add: mult_def)
   672  apply (rule r_into_trancl)
   673  apply (simp add: mult1_def set_of_def, blast)
   674 txt {* Now we know @{term "J' \<noteq> {#}"}. *}
   675 apply (cut_tac M = K and P = "\<lambda>x. (x, a) \<in> r" in multiset_partition)
   676 apply (erule_tac P = "\<forall>k \<in> set_of K. ?P k" in rev_mp)
   677 apply (erule ssubst)
   678 apply (simp add: Ball_def, auto)
   679 apply (subgoal_tac
   680   "((I + {# x :# K. (x, a) \<in> r #}) + {# x :# K. (x, a) \<notin> r #},
   681     (I + {# x :# K. (x, a) \<in> r #}) + J') \<in> mult r")
   682  prefer 2
   683  apply force
   684 apply (simp (no_asm_use) add: union_assoc [symmetric] mult_def)
   685 apply (erule trancl_trans)
   686 apply (rule r_into_trancl)
   687 apply (simp add: mult1_def set_of_def)
   688 apply (rule_tac x = a in exI)
   689 apply (rule_tac x = "I + J'" in exI)
   690 apply (simp add: union_ac)
   691 done
   692 
   693 lemma one_step_implies_mult:
   694   "trans r ==> J \<noteq> {#} ==> \<forall>k \<in> set_of K. \<exists>j \<in> set_of J. (k, j) \<in> r
   695     ==> (I + K, I + J) \<in> mult r"
   696 using one_step_implies_mult_aux by blast
   697 
   698 
   699 subsubsection {* Partial-order properties *}
   700 
   701 instantiation multiset :: (order) order
   702 begin
   703 
   704 definition less_multiset_def [code del]:
   705   "M' < M \<longleftrightarrow> (M', M) \<in> mult {(x', x). x' < x}"
   706 
   707 definition le_multiset_def [code del]:
   708   "M' <= M \<longleftrightarrow> M' = M \<or> M' < (M::'a multiset)"
   709 
   710 lemma trans_base_order: "trans {(x', x). x' < (x::'a::order)}"
   711 unfolding trans_def by (blast intro: order_less_trans)
   712 
   713 text {*
   714  \medskip Irreflexivity.
   715 *}
   716 
   717 lemma mult_irrefl_aux:
   718   "finite A ==> (\<forall>x \<in> A. \<exists>y \<in> A. x < (y::'a::order)) \<Longrightarrow> A = {}"
   719 by (induct rule: finite_induct) (auto intro: order_less_trans)
   720 
   721 lemma mult_less_not_refl: "\<not> M < (M::'a::order multiset)"
   722 apply (unfold less_multiset_def, auto)
   723 apply (drule trans_base_order [THEN mult_implies_one_step], auto)
   724 apply (drule finite_set_of [THEN mult_irrefl_aux [rule_format (no_asm)]])
   725 apply (simp add: set_of_eq_empty_iff)
   726 done
   727 
   728 lemma mult_less_irrefl [elim!]: "M < (M::'a::order multiset) ==> R"
   729 using insert mult_less_not_refl by fast
   730 
   731 
   732 text {* Transitivity. *}
   733 
   734 theorem mult_less_trans: "K < M ==> M < N ==> K < (N::'a::order multiset)"
   735 unfolding less_multiset_def mult_def by (blast intro: trancl_trans)
   736 
   737 text {* Asymmetry. *}
   738 
   739 theorem mult_less_not_sym: "M < N ==> \<not> N < (M::'a::order multiset)"
   740 apply auto
   741 apply (rule mult_less_not_refl [THEN notE])
   742 apply (erule mult_less_trans, assumption)
   743 done
   744 
   745 theorem mult_less_asym:
   746   "M < N ==> (\<not> P ==> N < (M::'a::order multiset)) ==> P"
   747 using mult_less_not_sym by blast
   748 
   749 theorem mult_le_refl [iff]: "M <= (M::'a::order multiset)"
   750 unfolding le_multiset_def by auto
   751 
   752 text {* Anti-symmetry. *}
   753 
   754 theorem mult_le_antisym:
   755   "M <= N ==> N <= M ==> M = (N::'a::order multiset)"
   756 unfolding le_multiset_def by (blast dest: mult_less_not_sym)
   757 
   758 text {* Transitivity. *}
   759 
   760 theorem mult_le_trans:
   761   "K <= M ==> M <= N ==> K <= (N::'a::order multiset)"
   762 unfolding le_multiset_def by (blast intro: mult_less_trans)
   763 
   764 theorem mult_less_le: "(M < N) = (M <= N \<and> M \<noteq> (N::'a::order multiset))"
   765 unfolding le_multiset_def by auto
   766 
   767 instance proof
   768 qed (auto simp add: mult_less_le dest: mult_le_antisym elim: mult_le_trans)
   769 
   770 end
   771 
   772 
   773 subsubsection {* Monotonicity of multiset union *}
   774 
   775 lemma mult1_union:
   776   "(B, D) \<in> mult1 r ==> trans r ==> (C + B, C + D) \<in> mult1 r"
   777 apply (unfold mult1_def)
   778 apply auto
   779 apply (rule_tac x = a in exI)
   780 apply (rule_tac x = "C + M0" in exI)
   781 apply (simp add: union_assoc)
   782 done
   783 
   784 lemma union_less_mono2: "B < D ==> C + B < C + (D::'a::order multiset)"
   785 apply (unfold less_multiset_def mult_def)
   786 apply (erule trancl_induct)
   787  apply (blast intro: mult1_union transI order_less_trans r_into_trancl)
   788 apply (blast intro: mult1_union transI order_less_trans r_into_trancl trancl_trans)
   789 done
   790 
   791 lemma union_less_mono1: "B < D ==> B + C < D + (C::'a::order multiset)"
   792 apply (subst union_commute [of B C])
   793 apply (subst union_commute [of D C])
   794 apply (erule union_less_mono2)
   795 done
   796 
   797 lemma union_less_mono:
   798   "A < C ==> B < D ==> A + B < C + (D::'a::order multiset)"
   799 by (blast intro!: union_less_mono1 union_less_mono2 mult_less_trans)
   800 
   801 lemma union_le_mono:
   802   "A <= C ==> B <= D ==> A + B <= C + (D::'a::order multiset)"
   803 unfolding le_multiset_def
   804 by (blast intro: union_less_mono union_less_mono1 union_less_mono2)
   805 
   806 lemma empty_leI [iff]: "{#} <= (M::'a::order multiset)"
   807 apply (unfold le_multiset_def less_multiset_def)
   808 apply (case_tac "M = {#}")
   809  prefer 2
   810  apply (subgoal_tac "({#} + {#}, {#} + M) \<in> mult (Collect (split op <))")
   811   prefer 2
   812   apply (rule one_step_implies_mult)
   813     apply (simp only: trans_def)
   814     apply auto
   815 done
   816 
   817 lemma union_upper1: "A <= A + (B::'a::order multiset)"
   818 proof -
   819   have "A + {#} <= A + B" by (blast intro: union_le_mono)
   820   then show ?thesis by simp
   821 qed
   822 
   823 lemma union_upper2: "B <= A + (B::'a::order multiset)"
   824 by (subst union_commute) (rule union_upper1)
   825 
   826 instance multiset :: (order) pordered_ab_semigroup_add
   827 apply intro_classes
   828 apply (erule union_le_mono[OF mult_le_refl])
   829 done
   830 
   831 
   832 subsection {* Link with lists *}
   833 
   834 primrec multiset_of :: "'a list \<Rightarrow> 'a multiset" where
   835   "multiset_of [] = {#}" |
   836   "multiset_of (a # x) = multiset_of x + {# a #}"
   837 
   838 lemma multiset_of_zero_iff[simp]: "(multiset_of x = {#}) = (x = [])"
   839 by (induct x) auto
   840 
   841 lemma multiset_of_zero_iff_right[simp]: "({#} = multiset_of x) = (x = [])"
   842 by (induct x) auto
   843 
   844 lemma set_of_multiset_of[simp]: "set_of(multiset_of x) = set x"
   845 by (induct x) auto
   846 
   847 lemma mem_set_multiset_eq: "x \<in> set xs = (x :# multiset_of xs)"
   848 by (induct xs) auto
   849 
   850 lemma multiset_of_append [simp]:
   851   "multiset_of (xs @ ys) = multiset_of xs + multiset_of ys"
   852 by (induct xs arbitrary: ys) (auto simp: union_ac)
   853 
   854 lemma surj_multiset_of: "surj multiset_of"
   855 apply (unfold surj_def)
   856 apply (rule allI)
   857 apply (rule_tac M = y in multiset_induct)
   858  apply auto
   859 apply (rule_tac x = "x # xa" in exI)
   860 apply auto
   861 done
   862 
   863 lemma set_count_greater_0: "set x = {a. count (multiset_of x) a > 0}"
   864 by (induct x) auto
   865 
   866 lemma distinct_count_atmost_1:
   867   "distinct x = (! a. count (multiset_of x) a = (if a \<in> set x then 1 else 0))"
   868 apply (induct x, simp, rule iffI, simp_all)
   869 apply (rule conjI)
   870 apply (simp_all add: set_of_multiset_of [THEN sym] del: set_of_multiset_of)
   871 apply (erule_tac x = a in allE, simp, clarify)
   872 apply (erule_tac x = aa in allE, simp)
   873 done
   874 
   875 lemma multiset_of_eq_setD:
   876   "multiset_of xs = multiset_of ys \<Longrightarrow> set xs = set ys"
   877 by (rule) (auto simp add:multiset_eq_conv_count_eq set_count_greater_0)
   878 
   879 lemma set_eq_iff_multiset_of_eq_distinct:
   880   "distinct x \<Longrightarrow> distinct y \<Longrightarrow>
   881     (set x = set y) = (multiset_of x = multiset_of y)"
   882 by (auto simp: multiset_eq_conv_count_eq distinct_count_atmost_1)
   883 
   884 lemma set_eq_iff_multiset_of_remdups_eq:
   885    "(set x = set y) = (multiset_of (remdups x) = multiset_of (remdups y))"
   886 apply (rule iffI)
   887 apply (simp add: set_eq_iff_multiset_of_eq_distinct[THEN iffD1])
   888 apply (drule distinct_remdups [THEN distinct_remdups
   889       [THEN set_eq_iff_multiset_of_eq_distinct [THEN iffD2]]])
   890 apply simp
   891 done
   892 
   893 lemma multiset_of_compl_union [simp]:
   894   "multiset_of [x\<leftarrow>xs. P x] + multiset_of [x\<leftarrow>xs. \<not>P x] = multiset_of xs"
   895 by (induct xs) (auto simp: union_ac)
   896 
   897 lemma count_filter:
   898   "count (multiset_of xs) x = length [y \<leftarrow> xs. y = x]"
   899 by (induct xs) auto
   900 
   901 lemma nth_mem_multiset_of: "i < length ls \<Longrightarrow> (ls ! i) :# multiset_of ls"
   902 apply (induct ls arbitrary: i)
   903  apply simp
   904 apply (case_tac i)
   905  apply auto
   906 done
   907 
   908 lemma multiset_of_remove1: "multiset_of (remove1 a xs) = multiset_of xs - {#a#}"
   909 by (induct xs) (auto simp add: multiset_eq_conv_count_eq)
   910 
   911 lemma multiset_of_eq_length:
   912 assumes "multiset_of xs = multiset_of ys"
   913 shows "length xs = length ys"
   914 using assms
   915 proof (induct arbitrary: ys rule: length_induct)
   916   case (1 xs ys)
   917   show ?case
   918   proof (cases xs)
   919     case Nil with "1.prems" show ?thesis by simp
   920   next
   921     case (Cons x xs')
   922     note xCons = Cons
   923     show ?thesis
   924     proof (cases ys)
   925       case Nil
   926       with "1.prems" Cons show ?thesis by simp
   927     next
   928       case (Cons y ys')
   929       have x_in_ys: "x = y \<or> x \<in> set ys'"
   930       proof (cases "x = y")
   931 	case True then show ?thesis ..
   932       next
   933 	case False
   934 	from "1.prems" [symmetric] xCons Cons have "x :# multiset_of ys' + {#y#}" by simp
   935 	with False show ?thesis by (simp add: mem_set_multiset_eq)
   936       qed
   937       from "1.hyps" have IH: "length xs' < length xs \<longrightarrow>
   938 	(\<forall>x. multiset_of xs' = multiset_of x \<longrightarrow> length xs' = length x)" by blast
   939       from "1.prems" x_in_ys Cons xCons have "multiset_of xs' = multiset_of (remove1 x (y#ys'))"
   940 	apply -
   941 	apply (simp add: multiset_of_remove1, simp only: add_eq_conv_diff)
   942 	apply fastsimp
   943 	done
   944       with IH xCons have IH': "length xs' = length (remove1 x (y#ys'))" by fastsimp
   945       from x_in_ys have "x \<noteq> y \<Longrightarrow> length ys' > 0" by auto
   946       with Cons xCons x_in_ys IH' show ?thesis by (auto simp add: length_remove1)
   947     qed
   948   qed
   949 qed
   950 
   951 text {*
   952   This lemma shows which properties suffice to show that a function
   953   @{text "f"} with @{text "f xs = ys"} behaves like sort.
   954 *}
   955 lemma properties_for_sort:
   956   "multiset_of ys = multiset_of xs \<Longrightarrow> sorted ys \<Longrightarrow> sort xs = ys"
   957 proof (induct xs arbitrary: ys)
   958   case Nil then show ?case by simp
   959 next
   960   case (Cons x xs)
   961   then have "x \<in> set ys"
   962     by (auto simp add:  mem_set_multiset_eq intro!: ccontr)
   963   with Cons.prems Cons.hyps [of "remove1 x ys"] show ?case
   964     by (simp add: sorted_remove1 multiset_of_remove1 insort_remove1)
   965 qed
   966 
   967 
   968 subsection {* Pointwise ordering induced by count *}
   969 
   970 definition mset_le :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "\<le>#" 50) where
   971   [code del]: "A \<le># B \<longleftrightarrow> (\<forall>a. count A a \<le> count B a)"
   972 
   973 definition mset_less :: "'a multiset \<Rightarrow> 'a multiset \<Rightarrow> bool"  (infix "<#" 50) where
   974   [code del]: "A <# B \<longleftrightarrow> A \<le># B \<and> A \<noteq> B"
   975 
   976 notation mset_le  (infix "\<subseteq>#" 50)
   977 notation mset_less  (infix "\<subset>#" 50)
   978 
   979 lemma mset_le_refl[simp]: "A \<le># A"
   980 unfolding mset_le_def by auto
   981 
   982 lemma mset_le_trans: "A \<le># B \<Longrightarrow> B \<le># C \<Longrightarrow> A \<le># C"
   983 unfolding mset_le_def by (fast intro: order_trans)
   984 
   985 lemma mset_le_antisym: "A \<le># B \<Longrightarrow> B \<le># A \<Longrightarrow> A = B"
   986 apply (unfold mset_le_def)
   987 apply (rule multiset_eq_conv_count_eq [THEN iffD2])
   988 apply (blast intro: order_antisym)
   989 done
   990 
   991 lemma mset_le_exists_conv: "(A \<le># B) = (\<exists>C. B = A + C)"
   992 apply (unfold mset_le_def, rule iffI, rule_tac x = "B - A" in exI)
   993 apply (auto intro: multiset_eq_conv_count_eq [THEN iffD2])
   994 done
   995 
   996 lemma mset_le_mono_add_right_cancel[simp]: "(A + C \<le># B + C) = (A \<le># B)"
   997 unfolding mset_le_def by auto
   998 
   999 lemma mset_le_mono_add_left_cancel[simp]: "(C + A \<le># C + B) = (A \<le># B)"
  1000 unfolding mset_le_def by auto
  1001 
  1002 lemma mset_le_mono_add: "\<lbrakk> A \<le># B; C \<le># D \<rbrakk> \<Longrightarrow> A + C \<le># B + D"
  1003 apply (unfold mset_le_def)
  1004 apply auto
  1005 apply (erule_tac x = a in allE)+
  1006 apply auto
  1007 done
  1008 
  1009 lemma mset_le_add_left[simp]: "A \<le># A + B"
  1010 unfolding mset_le_def by auto
  1011 
  1012 lemma mset_le_add_right[simp]: "B \<le># A + B"
  1013 unfolding mset_le_def by auto
  1014 
  1015 lemma mset_le_single: "a :# B \<Longrightarrow> {#a#} \<le># B"
  1016 by (simp add: mset_le_def)
  1017 
  1018 lemma multiset_diff_union_assoc: "C \<le># B \<Longrightarrow> A + B - C = A + (B - C)"
  1019 by (simp add: multiset_eq_conv_count_eq mset_le_def)
  1020 
  1021 lemma mset_le_multiset_union_diff_commute:
  1022 assumes "B \<le># A"
  1023 shows "A - B + C = A + C - B"
  1024 proof -
  1025   from mset_le_exists_conv [of "B" "A"] assms have "\<exists>D. A = B + D" ..
  1026   from this obtain D where "A = B + D" ..
  1027   then show ?thesis
  1028     apply simp
  1029     apply (subst union_commute)
  1030     apply (subst multiset_diff_union_assoc)
  1031     apply simp
  1032     apply (simp add: diff_cancel)
  1033     apply (subst union_assoc)
  1034     apply (subst union_commute[of "B" _])
  1035     apply (subst multiset_diff_union_assoc)
  1036     apply simp
  1037     apply (simp add: diff_cancel)
  1038     done
  1039 qed
  1040 
  1041 lemma multiset_of_remdups_le: "multiset_of (remdups xs) \<le># multiset_of xs"
  1042 apply (induct xs)
  1043  apply auto
  1044 apply (rule mset_le_trans)
  1045  apply auto
  1046 done
  1047 
  1048 lemma multiset_of_update:
  1049   "i < length ls \<Longrightarrow> multiset_of (ls[i := v]) = multiset_of ls - {#ls ! i#} + {#v#}"
  1050 proof (induct ls arbitrary: i)
  1051   case Nil then show ?case by simp
  1052 next
  1053   case (Cons x xs)
  1054   show ?case
  1055   proof (cases i)
  1056     case 0 then show ?thesis by simp
  1057   next
  1058     case (Suc i')
  1059     with Cons show ?thesis
  1060       apply simp
  1061       apply (subst union_assoc)
  1062       apply (subst union_commute [where M = "{#v#}" and N = "{#x#}"])
  1063       apply (subst union_assoc [symmetric])
  1064       apply simp
  1065       apply (rule mset_le_multiset_union_diff_commute)
  1066       apply (simp add: mset_le_single nth_mem_multiset_of)
  1067       done
  1068   qed
  1069 qed
  1070 
  1071 lemma multiset_of_swap:
  1072   "i < length ls \<Longrightarrow> j < length ls \<Longrightarrow>
  1073     multiset_of (ls[j := ls ! i, i := ls ! j]) = multiset_of ls"
  1074 apply (case_tac "i = j")
  1075  apply simp
  1076 apply (simp add: multiset_of_update)
  1077 apply (subst elem_imp_eq_diff_union[symmetric])
  1078  apply (simp add: nth_mem_multiset_of)
  1079 apply simp
  1080 done
  1081 
  1082 interpretation mset_order!: order "op \<le>#" "op <#"
  1083 proof qed (auto intro: order.intro mset_le_refl mset_le_antisym
  1084   mset_le_trans simp: mset_less_def)
  1085 
  1086 interpretation mset_order_cancel_semigroup!:
  1087   pordered_cancel_ab_semigroup_add "op +" "op \<le>#" "op <#"
  1088 proof qed (erule mset_le_mono_add [OF mset_le_refl])
  1089 
  1090 interpretation mset_order_semigroup_cancel!:
  1091   pordered_ab_semigroup_add_imp_le "op +" "op \<le>#" "op <#"
  1092 proof qed simp
  1093 
  1094 
  1095 lemma mset_lessD: "A \<subset># B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
  1096 apply (clarsimp simp: mset_le_def mset_less_def)
  1097 apply (erule_tac x=x in allE)
  1098 apply auto
  1099 done
  1100 
  1101 lemma mset_leD: "A \<subseteq># B \<Longrightarrow> x \<in># A \<Longrightarrow> x \<in># B"
  1102 apply (clarsimp simp: mset_le_def mset_less_def)
  1103 apply (erule_tac x = x in allE)
  1104 apply auto
  1105 done
  1106   
  1107 lemma mset_less_insertD: "(A + {#x#} \<subset># B) \<Longrightarrow> (x \<in># B \<and> A \<subset># B)"
  1108 apply (rule conjI)
  1109  apply (simp add: mset_lessD)
  1110 apply (clarsimp simp: mset_le_def mset_less_def)
  1111 apply safe
  1112  apply (erule_tac x = a in allE)
  1113  apply (auto split: split_if_asm)
  1114 done
  1115 
  1116 lemma mset_le_insertD: "(A + {#x#} \<subseteq># B) \<Longrightarrow> (x \<in># B \<and> A \<subseteq># B)"
  1117 apply (rule conjI)
  1118  apply (simp add: mset_leD)
  1119 apply (force simp: mset_le_def mset_less_def split: split_if_asm)
  1120 done
  1121 
  1122 lemma mset_less_of_empty[simp]: "A \<subset># {#} = False" 
  1123 by (induct A) (auto simp: mset_le_def mset_less_def)
  1124 
  1125 lemma multi_psub_of_add_self[simp]: "A \<subset># A + {#x#}"
  1126 by (auto simp: mset_le_def mset_less_def)
  1127 
  1128 lemma multi_psub_self[simp]: "A \<subset># A = False"
  1129 by (auto simp: mset_le_def mset_less_def)
  1130 
  1131 lemma mset_less_add_bothsides:
  1132   "T + {#x#} \<subset># S + {#x#} \<Longrightarrow> T \<subset># S"
  1133 by (auto simp: mset_le_def mset_less_def)
  1134 
  1135 lemma mset_less_empty_nonempty: "({#} \<subset># S) = (S \<noteq> {#})"
  1136 by (auto simp: mset_le_def mset_less_def)
  1137 
  1138 lemma mset_less_size: "A \<subset># B \<Longrightarrow> size A < size B"
  1139 proof (induct A arbitrary: B)
  1140   case (empty M)
  1141   then have "M \<noteq> {#}" by (simp add: mset_less_empty_nonempty)
  1142   then obtain M' x where "M = M' + {#x#}" 
  1143     by (blast dest: multi_nonempty_split)
  1144   then show ?case by simp
  1145 next
  1146   case (add S x T)
  1147   have IH: "\<And>B. S \<subset># B \<Longrightarrow> size S < size B" by fact
  1148   have SxsubT: "S + {#x#} \<subset># T" by fact
  1149   then have "x \<in># T" and "S \<subset># T" by (auto dest: mset_less_insertD)
  1150   then obtain T' where T: "T = T' + {#x#}" 
  1151     by (blast dest: multi_member_split)
  1152   then have "S \<subset># T'" using SxsubT 
  1153     by (blast intro: mset_less_add_bothsides)
  1154   then have "size S < size T'" using IH by simp
  1155   then show ?case using T by simp
  1156 qed
  1157 
  1158 lemmas mset_less_trans = mset_order.less_trans
  1159 
  1160 lemma mset_less_diff_self: "c \<in># B \<Longrightarrow> B - {#c#} \<subset># B"
  1161 by (auto simp: mset_le_def mset_less_def multi_drop_mem_not_eq)
  1162 
  1163 
  1164 subsection {* Strong induction and subset induction for multisets *}
  1165 
  1166 text {* Well-foundedness of proper subset operator: *}
  1167 
  1168 text {* proper multiset subset *}
  1169 definition
  1170   mset_less_rel :: "('a multiset * 'a multiset) set" where
  1171   "mset_less_rel = {(A,B). A \<subset># B}"
  1172 
  1173 lemma multiset_add_sub_el_shuffle: 
  1174   assumes "c \<in># B" and "b \<noteq> c" 
  1175   shows "B - {#c#} + {#b#} = B + {#b#} - {#c#}"
  1176 proof -
  1177   from `c \<in># B` obtain A where B: "B = A + {#c#}" 
  1178     by (blast dest: multi_member_split)
  1179   have "A + {#b#} = A + {#b#} + {#c#} - {#c#}" by simp
  1180   then have "A + {#b#} = A + {#c#} + {#b#} - {#c#}" 
  1181     by (simp add: union_ac)
  1182   then show ?thesis using B by simp
  1183 qed
  1184 
  1185 lemma wf_mset_less_rel: "wf mset_less_rel"
  1186 apply (unfold mset_less_rel_def)
  1187 apply (rule wf_measure [THEN wf_subset, where f1=size])
  1188 apply (clarsimp simp: measure_def inv_image_def mset_less_size)
  1189 done
  1190 
  1191 text {* The induction rules: *}
  1192 
  1193 lemma full_multiset_induct [case_names less]:
  1194 assumes ih: "\<And>B. \<forall>A. A \<subset># B \<longrightarrow> P A \<Longrightarrow> P B"
  1195 shows "P B"
  1196 apply (rule wf_mset_less_rel [THEN wf_induct])
  1197 apply (rule ih, auto simp: mset_less_rel_def)
  1198 done
  1199 
  1200 lemma multi_subset_induct [consumes 2, case_names empty add]:
  1201 assumes "F \<subseteq># A"
  1202   and empty: "P {#}"
  1203   and insert: "\<And>a F. a \<in># A \<Longrightarrow> P F \<Longrightarrow> P (F + {#a#})"
  1204 shows "P F"
  1205 proof -
  1206   from `F \<subseteq># A`
  1207   show ?thesis
  1208   proof (induct F)
  1209     show "P {#}" by fact
  1210   next
  1211     fix x F
  1212     assume P: "F \<subseteq># A \<Longrightarrow> P F" and i: "F + {#x#} \<subseteq># A"
  1213     show "P (F + {#x#})"
  1214     proof (rule insert)
  1215       from i show "x \<in># A" by (auto dest: mset_le_insertD)
  1216       from i have "F \<subseteq># A" by (auto dest: mset_le_insertD)
  1217       with P show "P F" .
  1218     qed
  1219   qed
  1220 qed 
  1221 
  1222 text{* A consequence: Extensionality. *}
  1223 
  1224 lemma multi_count_eq: "(\<forall>x. count A x = count B x) = (A = B)"
  1225 apply (rule iffI)
  1226  prefer 2
  1227  apply clarsimp 
  1228 apply (induct A arbitrary: B rule: full_multiset_induct)
  1229 apply (rename_tac C)
  1230 apply (case_tac B rule: multiset_cases)
  1231  apply (simp add: empty_multiset_count)
  1232 apply simp
  1233 apply (case_tac "x \<in># C")
  1234  apply (force dest: multi_member_split)
  1235 apply (erule_tac x = x in allE)
  1236 apply simp
  1237 done
  1238 
  1239 lemmas multi_count_ext = multi_count_eq [THEN iffD1, rule_format]
  1240 
  1241 
  1242 subsection {* The fold combinator *}
  1243 
  1244 text {*
  1245   The intended behaviour is
  1246   @{text "fold_mset f z {#x\<^isub>1, ..., x\<^isub>n#} = f x\<^isub>1 (\<dots> (f x\<^isub>n z)\<dots>)"}
  1247   if @{text f} is associative-commutative. 
  1248 *}
  1249 
  1250 text {*
  1251   The graph of @{text "fold_mset"}, @{text "z"}: the start element,
  1252   @{text "f"}: folding function, @{text "A"}: the multiset, @{text
  1253   "y"}: the result.
  1254 *}
  1255 inductive 
  1256   fold_msetG :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b \<Rightarrow> bool" 
  1257   for f :: "'a \<Rightarrow> 'b \<Rightarrow> 'b" 
  1258   and z :: 'b
  1259 where
  1260   emptyI [intro]:  "fold_msetG f z {#} z"
  1261 | insertI [intro]: "fold_msetG f z A y \<Longrightarrow> fold_msetG f z (A + {#x#}) (f x y)"
  1262 
  1263 inductive_cases empty_fold_msetGE [elim!]: "fold_msetG f z {#} x"
  1264 inductive_cases insert_fold_msetGE: "fold_msetG f z (A + {#}) y" 
  1265 
  1266 definition
  1267   fold_mset :: "('a \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'b \<Rightarrow> 'a multiset \<Rightarrow> 'b" where
  1268   "fold_mset f z A = (THE x. fold_msetG f z A x)"
  1269 
  1270 lemma Diff1_fold_msetG:
  1271   "fold_msetG f z (A - {#x#}) y \<Longrightarrow> x \<in># A \<Longrightarrow> fold_msetG f z A (f x y)"
  1272 apply (frule_tac x = x in fold_msetG.insertI)
  1273 apply auto
  1274 done
  1275 
  1276 lemma fold_msetG_nonempty: "\<exists>x. fold_msetG f z A x"
  1277 apply (induct A)
  1278  apply blast
  1279 apply clarsimp
  1280 apply (drule_tac x = x in fold_msetG.insertI)
  1281 apply auto
  1282 done
  1283 
  1284 lemma fold_mset_empty[simp]: "fold_mset f z {#} = z"
  1285 unfolding fold_mset_def by blast
  1286 
  1287 locale left_commutative = 
  1288 fixes f :: "'a => 'b => 'b"
  1289 assumes left_commute: "f x (f y z) = f y (f x z)"
  1290 begin
  1291 
  1292 lemma fold_msetG_determ:
  1293   "fold_msetG f z A x \<Longrightarrow> fold_msetG f z A y \<Longrightarrow> y = x"
  1294 proof (induct arbitrary: x y z rule: full_multiset_induct)
  1295   case (less M x\<^isub>1 x\<^isub>2 Z)
  1296   have IH: "\<forall>A. A \<subset># M \<longrightarrow> 
  1297     (\<forall>x x' x''. fold_msetG f x'' A x \<longrightarrow> fold_msetG f x'' A x'
  1298                \<longrightarrow> x' = x)" by fact
  1299   have Mfoldx\<^isub>1: "fold_msetG f Z M x\<^isub>1" and Mfoldx\<^isub>2: "fold_msetG f Z M x\<^isub>2" by fact+
  1300   show ?case
  1301   proof (rule fold_msetG.cases [OF Mfoldx\<^isub>1])
  1302     assume "M = {#}" and "x\<^isub>1 = Z"
  1303     then show ?case using Mfoldx\<^isub>2 by auto 
  1304   next
  1305     fix B b u
  1306     assume "M = B + {#b#}" and "x\<^isub>1 = f b u" and Bu: "fold_msetG f Z B u"
  1307     then have MBb: "M = B + {#b#}" and x\<^isub>1: "x\<^isub>1 = f b u" by auto
  1308     show ?case
  1309     proof (rule fold_msetG.cases [OF Mfoldx\<^isub>2])
  1310       assume "M = {#}" "x\<^isub>2 = Z"
  1311       then show ?case using Mfoldx\<^isub>1 by auto
  1312     next
  1313       fix C c v
  1314       assume "M = C + {#c#}" and "x\<^isub>2 = f c v" and Cv: "fold_msetG f Z C v"
  1315       then have MCc: "M = C + {#c#}" and x\<^isub>2: "x\<^isub>2 = f c v" by auto
  1316       then have CsubM: "C \<subset># M" by simp
  1317       from MBb have BsubM: "B \<subset># M" by simp
  1318       show ?case
  1319       proof cases
  1320         assume "b=c"
  1321         then moreover have "B = C" using MBb MCc by auto
  1322         ultimately show ?thesis using Bu Cv x\<^isub>1 x\<^isub>2 CsubM IH by auto
  1323       next
  1324         assume diff: "b \<noteq> c"
  1325         let ?D = "B - {#c#}"
  1326         have cinB: "c \<in># B" and binC: "b \<in># C" using MBb MCc diff
  1327           by (auto intro: insert_noteq_member dest: sym)
  1328         have "B - {#c#} \<subset># B" using cinB by (rule mset_less_diff_self)
  1329         then have DsubM: "?D \<subset># M" using BsubM by (blast intro: mset_less_trans)
  1330         from MBb MCc have "B + {#b#} = C + {#c#}" by blast
  1331         then have [simp]: "B + {#b#} - {#c#} = C"
  1332           using MBb MCc binC cinB by auto
  1333         have B: "B = ?D + {#c#}" and C: "C = ?D + {#b#}"
  1334           using MBb MCc diff binC cinB
  1335           by (auto simp: multiset_add_sub_el_shuffle)
  1336         then obtain d where Dfoldd: "fold_msetG f Z ?D d"
  1337           using fold_msetG_nonempty by iprover
  1338         then have "fold_msetG f Z B (f c d)" using cinB
  1339           by (rule Diff1_fold_msetG)
  1340         then have "f c d = u" using IH BsubM Bu by blast
  1341         moreover 
  1342         have "fold_msetG f Z C (f b d)" using binC cinB diff Dfoldd
  1343           by (auto simp: multiset_add_sub_el_shuffle 
  1344             dest: fold_msetG.insertI [where x=b])
  1345         then have "f b d = v" using IH CsubM Cv by blast
  1346         ultimately show ?thesis using x\<^isub>1 x\<^isub>2
  1347           by (auto simp: left_commute)
  1348       qed
  1349     qed
  1350   qed
  1351 qed
  1352         
  1353 lemma fold_mset_insert_aux:
  1354   "(fold_msetG f z (A + {#x#}) v) =
  1355     (\<exists>y. fold_msetG f z A y \<and> v = f x y)"
  1356 apply (rule iffI)
  1357  prefer 2
  1358  apply blast
  1359 apply (rule_tac A=A and f=f in fold_msetG_nonempty [THEN exE, standard])
  1360 apply (blast intro: fold_msetG_determ)
  1361 done
  1362 
  1363 lemma fold_mset_equality: "fold_msetG f z A y \<Longrightarrow> fold_mset f z A = y"
  1364 unfolding fold_mset_def by (blast intro: fold_msetG_determ)
  1365 
  1366 lemma fold_mset_insert:
  1367   "fold_mset f z (A + {#x#}) = f x (fold_mset f z A)"
  1368 apply (simp add: fold_mset_def fold_mset_insert_aux union_commute)  
  1369 apply (rule the_equality)
  1370  apply (auto cong add: conj_cong 
  1371      simp add: fold_mset_def [symmetric] fold_mset_equality fold_msetG_nonempty)
  1372 done
  1373 
  1374 lemma fold_mset_insert_idem:
  1375   "fold_mset f z (A + {#a#}) = f a (fold_mset f z A)"
  1376 apply (simp add: fold_mset_def fold_mset_insert_aux)
  1377 apply (rule the_equality)
  1378  apply (auto cong add: conj_cong 
  1379      simp add: fold_mset_def [symmetric] fold_mset_equality fold_msetG_nonempty)
  1380 done
  1381 
  1382 lemma fold_mset_commute: "f x (fold_mset f z A) = fold_mset f (f x z) A"
  1383 by (induct A) (auto simp: fold_mset_insert left_commute [of x])
  1384 
  1385 lemma fold_mset_single [simp]: "fold_mset f z {#x#} = f x z"
  1386 using fold_mset_insert [of z "{#}"] by simp
  1387 
  1388 lemma fold_mset_union [simp]:
  1389   "fold_mset f z (A+B) = fold_mset f (fold_mset f z A) B"
  1390 proof (induct A)
  1391   case empty then show ?case by simp
  1392 next
  1393   case (add A x)
  1394   have "A + {#x#} + B = (A+B) + {#x#}" by(simp add:union_ac)
  1395   then have "fold_mset f z (A + {#x#} + B) = f x (fold_mset f z (A + B))" 
  1396     by (simp add: fold_mset_insert)
  1397   also have "\<dots> = fold_mset f (fold_mset f z (A + {#x#})) B"
  1398     by (simp add: fold_mset_commute[of x,symmetric] add fold_mset_insert)
  1399   finally show ?case .
  1400 qed
  1401 
  1402 lemma fold_mset_fusion:
  1403   assumes "left_commutative g"
  1404   shows "(\<And>x y. h (g x y) = f x (h y)) \<Longrightarrow> h (fold_mset g w A) = fold_mset f (h w) A" (is "PROP ?P")
  1405 proof -
  1406   interpret left_commutative g by fact
  1407   show "PROP ?P" by (induct A) auto
  1408 qed
  1409 
  1410 lemma fold_mset_rec:
  1411   assumes "a \<in># A" 
  1412   shows "fold_mset f z A = f a (fold_mset f z (A - {#a#}))"
  1413 proof -
  1414   from assms obtain A' where "A = A' + {#a#}"
  1415     by (blast dest: multi_member_split)
  1416   then show ?thesis by simp
  1417 qed
  1418 
  1419 end
  1420 
  1421 text {*
  1422   A note on code generation: When defining some function containing a
  1423   subterm @{term"fold_mset F"}, code generation is not automatic. When
  1424   interpreting locale @{text left_commutative} with @{text F}, the
  1425   would be code thms for @{const fold_mset} become thms like
  1426   @{term"fold_mset F z {#} = z"} where @{text F} is not a pattern but
  1427   contains defined symbols, i.e.\ is not a code thm. Hence a separate
  1428   constant with its own code thms needs to be introduced for @{text
  1429   F}. See the image operator below.
  1430 *}
  1431 
  1432 
  1433 subsection {* Image *}
  1434 
  1435 definition [code del]:
  1436  "image_mset f = fold_mset (op + o single o f) {#}"
  1437 
  1438 interpretation image_left_comm!: left_commutative "op + o single o f"
  1439   proof qed (simp add:union_ac)
  1440 
  1441 lemma image_mset_empty [simp]: "image_mset f {#} = {#}"
  1442 by (simp add: image_mset_def)
  1443 
  1444 lemma image_mset_single [simp]: "image_mset f {#x#} = {#f x#}"
  1445 by (simp add: image_mset_def)
  1446 
  1447 lemma image_mset_insert:
  1448   "image_mset f (M + {#a#}) = image_mset f M + {#f a#}"
  1449 by (simp add: image_mset_def add_ac)
  1450 
  1451 lemma image_mset_union [simp]:
  1452   "image_mset f (M+N) = image_mset f M + image_mset f N"
  1453 apply (induct N)
  1454  apply simp
  1455 apply (simp add: union_assoc [symmetric] image_mset_insert)
  1456 done
  1457 
  1458 lemma size_image_mset [simp]: "size (image_mset f M) = size M"
  1459 by (induct M) simp_all
  1460 
  1461 lemma image_mset_is_empty_iff [simp]: "image_mset f M = {#} \<longleftrightarrow> M = {#}"
  1462 by (cases M) auto
  1463 
  1464 syntax
  1465   comprehension1_mset :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> 'a multiset"
  1466       ("({#_/. _ :# _#})")
  1467 translations
  1468   "{#e. x:#M#}" == "CONST image_mset (%x. e) M"
  1469 
  1470 syntax
  1471   comprehension2_mset :: "'a \<Rightarrow> 'b \<Rightarrow> 'b multiset \<Rightarrow> bool \<Rightarrow> 'a multiset"
  1472       ("({#_/ | _ :# _./ _#})")
  1473 translations
  1474   "{#e | x:#M. P#}" => "{#e. x :# {# x:#M. P#}#}"
  1475 
  1476 text {*
  1477   This allows to write not just filters like @{term "{#x:#M. x<c#}"}
  1478   but also images like @{term "{#x+x. x:#M #}"} and @{term [source]
  1479   "{#x+x|x:#M. x<c#}"}, where the latter is currently displayed as
  1480   @{term "{#x+x|x:#M. x<c#}"}.
  1481 *}
  1482 
  1483 
  1484 subsection {* Termination proofs with multiset orders *}
  1485 
  1486 lemma multi_member_skip: "x \<in># XS \<Longrightarrow> x \<in># {# y #} + XS"
  1487   and multi_member_this: "x \<in># {# x #} + XS"
  1488   and multi_member_last: "x \<in># {# x #}"
  1489   by auto
  1490 
  1491 definition "ms_strict = mult pair_less"
  1492 definition "ms_weak = ms_strict \<union> Id"
  1493 
  1494 lemma ms_reduction_pair: "reduction_pair (ms_strict, ms_weak)"
  1495 unfolding reduction_pair_def ms_strict_def ms_weak_def pair_less_def
  1496 by (auto intro: wf_mult1 wf_trancl simp: mult_def)
  1497 
  1498 lemma smsI:
  1499   "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z + B) \<in> ms_strict"
  1500   unfolding ms_strict_def
  1501 by (rule one_step_implies_mult) (auto simp add: max_strict_def pair_less_def elim!:max_ext.cases)
  1502 
  1503 lemma wmsI:
  1504   "(set_of A, set_of B) \<in> max_strict \<or> A = {#} \<and> B = {#}
  1505   \<Longrightarrow> (Z + A, Z + B) \<in> ms_weak"
  1506 unfolding ms_weak_def ms_strict_def
  1507 by (auto simp add: pair_less_def max_strict_def elim!:max_ext.cases intro: one_step_implies_mult)
  1508 
  1509 inductive pw_leq
  1510 where
  1511   pw_leq_empty: "pw_leq {#} {#}"
  1512 | pw_leq_step:  "\<lbrakk>(x,y) \<in> pair_leq; pw_leq X Y \<rbrakk> \<Longrightarrow> pw_leq ({#x#} + X) ({#y#} + Y)"
  1513 
  1514 lemma pw_leq_lstep:
  1515   "(x, y) \<in> pair_leq \<Longrightarrow> pw_leq {#x#} {#y#}"
  1516 by (drule pw_leq_step) (rule pw_leq_empty, simp)
  1517 
  1518 lemma pw_leq_split:
  1519   assumes "pw_leq X Y"
  1520   shows "\<exists>A B Z. X = A + Z \<and> Y = B + Z \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1521   using assms
  1522 proof (induct)
  1523   case pw_leq_empty thus ?case by auto
  1524 next
  1525   case (pw_leq_step x y X Y)
  1526   then obtain A B Z where
  1527     [simp]: "X = A + Z" "Y = B + Z" 
  1528       and 1[simp]: "(set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#})" 
  1529     by auto
  1530   from pw_leq_step have "x = y \<or> (x, y) \<in> pair_less" 
  1531     unfolding pair_leq_def by auto
  1532   thus ?case
  1533   proof
  1534     assume [simp]: "x = y"
  1535     have
  1536       "{#x#} + X = A + ({#y#}+Z) 
  1537       \<and> {#y#} + Y = B + ({#y#}+Z)
  1538       \<and> ((set_of A, set_of B) \<in> max_strict \<or> (B = {#} \<and> A = {#}))"
  1539       by (auto simp: add_ac)
  1540     thus ?case by (intro exI)
  1541   next
  1542     assume A: "(x, y) \<in> pair_less"
  1543     let ?A' = "{#x#} + A" and ?B' = "{#y#} + B"
  1544     have "{#x#} + X = ?A' + Z"
  1545       "{#y#} + Y = ?B' + Z"
  1546       by (auto simp add: add_ac)
  1547     moreover have 
  1548       "(set_of ?A', set_of ?B') \<in> max_strict"
  1549       using 1 A unfolding max_strict_def 
  1550       by (auto elim!: max_ext.cases)
  1551     ultimately show ?thesis by blast
  1552   qed
  1553 qed
  1554 
  1555 lemma 
  1556   assumes pwleq: "pw_leq Z Z'"
  1557   shows ms_strictI: "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_strict"
  1558   and   ms_weakI1:  "(set_of A, set_of B) \<in> max_strict \<Longrightarrow> (Z + A, Z' + B) \<in> ms_weak"
  1559   and   ms_weakI2:  "(Z + {#}, Z' + {#}) \<in> ms_weak"
  1560 proof -
  1561   from pw_leq_split[OF pwleq] 
  1562   obtain A' B' Z''
  1563     where [simp]: "Z = A' + Z''" "Z' = B' + Z''"
  1564     and mx_or_empty: "(set_of A', set_of B') \<in> max_strict \<or> (A' = {#} \<and> B' = {#})"
  1565     by blast
  1566   {
  1567     assume max: "(set_of A, set_of B) \<in> max_strict"
  1568     from mx_or_empty
  1569     have "(Z'' + (A + A'), Z'' + (B + B')) \<in> ms_strict"
  1570     proof
  1571       assume max': "(set_of A', set_of B') \<in> max_strict"
  1572       with max have "(set_of (A + A'), set_of (B + B')) \<in> max_strict"
  1573         by (auto simp: max_strict_def intro: max_ext_additive)
  1574       thus ?thesis by (rule smsI) 
  1575     next
  1576       assume [simp]: "A' = {#} \<and> B' = {#}"
  1577       show ?thesis by (rule smsI) (auto intro: max)
  1578     qed
  1579     thus "(Z + A, Z' + B) \<in> ms_strict" by (simp add:add_ac)
  1580     thus "(Z + A, Z' + B) \<in> ms_weak" by (simp add: ms_weak_def)
  1581   }
  1582   from mx_or_empty
  1583   have "(Z'' + A', Z'' + B') \<in> ms_weak" by (rule wmsI)
  1584   thus "(Z + {#}, Z' + {#}) \<in> ms_weak" by (simp add:add_ac)
  1585 qed
  1586 
  1587 lemma empty_idemp: "{#} + x = x" "x + {#} = x"
  1588 and nonempty_plus: "{# x #} + rs \<noteq> {#}"
  1589 and nonempty_single: "{# x #} \<noteq> {#}"
  1590 by auto
  1591 
  1592 setup {*
  1593 let
  1594   fun msetT T = Type ("Multiset.multiset", [T]);
  1595 
  1596   fun mk_mset T [] = Const (@{const_name Mempty}, msetT T)
  1597     | mk_mset T [x] = Const (@{const_name single}, T --> msetT T) $ x
  1598     | mk_mset T (x :: xs) =
  1599           Const (@{const_name plus}, msetT T --> msetT T --> msetT T) $
  1600                 mk_mset T [x] $ mk_mset T xs
  1601 
  1602   fun mset_member_tac m i =
  1603       (if m <= 0 then
  1604            rtac @{thm multi_member_this} i ORELSE rtac @{thm multi_member_last} i
  1605        else
  1606            rtac @{thm multi_member_skip} i THEN mset_member_tac (m - 1) i)
  1607 
  1608   val mset_nonempty_tac =
  1609       rtac @{thm nonempty_plus} ORELSE' rtac @{thm nonempty_single}
  1610 
  1611   val regroup_munion_conv =
  1612       FundefLib.regroup_conv @{const_name Multiset.Mempty} @{const_name plus}
  1613         (map (fn t => t RS eq_reflection) (@{thms union_ac} @ @{thms empty_idemp}))
  1614 
  1615   fun unfold_pwleq_tac i =
  1616     (rtac @{thm pw_leq_step} i THEN (fn st => unfold_pwleq_tac (i + 1) st))
  1617       ORELSE (rtac @{thm pw_leq_lstep} i)
  1618       ORELSE (rtac @{thm pw_leq_empty} i)
  1619 
  1620   val set_of_simps = [@{thm set_of_empty}, @{thm set_of_single}, @{thm set_of_union},
  1621                       @{thm Un_insert_left}, @{thm Un_empty_left}]
  1622 in
  1623   ScnpReconstruct.multiset_setup (ScnpReconstruct.Multiset 
  1624   {
  1625     msetT=msetT, mk_mset=mk_mset, mset_regroup_conv=regroup_munion_conv,
  1626     mset_member_tac=mset_member_tac, mset_nonempty_tac=mset_nonempty_tac,
  1627     mset_pwleq_tac=unfold_pwleq_tac, set_of_simps=set_of_simps,
  1628     smsI'=@{thm ms_strictI}, wmsI2''=@{thm ms_weakI2}, wmsI1=@{thm ms_weakI1},
  1629     reduction_pair=@{thm ms_reduction_pair}
  1630   })
  1631 end
  1632 *}
  1633 
  1634 end