src/HOL/Library/Primes.thy
author chaieb
Mon Feb 09 17:21:46 2009 +0000 (2009-02-09)
changeset 29847 af32126ee729
parent 29667 53103fc8ffa3
child 30042 31039ee583fa
child 30240 5b25fee0362c
permissions -rw-r--r--
added Determinants to Library
     1 (*  Title:      HOL/Library/Primes.thy
     2     Author:     Amine Chaieb, Christophe Tabacznyj and Lawrence C Paulson
     3     Copyright   1996  University of Cambridge
     4 *)
     5 
     6 header {* Primality on nat *}
     7 
     8 theory Primes
     9 imports Plain "~~/src/HOL/ATP_Linkup" "~~/src/HOL/GCD" "~~/src/HOL/Parity"
    10 begin
    11 
    12 definition
    13   coprime :: "nat => nat => bool" where
    14   "coprime m n \<longleftrightarrow> gcd m n = 1"
    15 
    16 definition
    17   prime :: "nat \<Rightarrow> bool" where
    18   [code del]: "prime p \<longleftrightarrow> (1 < p \<and> (\<forall>m. m dvd p --> m = 1 \<or> m = p))"
    19 
    20 
    21 lemma two_is_prime: "prime 2"
    22   apply (auto simp add: prime_def)
    23   apply (case_tac m)
    24    apply (auto dest!: dvd_imp_le)
    25   done
    26 
    27 lemma prime_imp_relprime: "prime p ==> \<not> p dvd n ==> gcd p n = 1"
    28   apply (auto simp add: prime_def)
    29   apply (metis One_nat_def gcd_dvd1 gcd_dvd2)
    30   done
    31 
    32 text {*
    33   This theorem leads immediately to a proof of the uniqueness of
    34   factorization.  If @{term p} divides a product of primes then it is
    35   one of those primes.
    36 *}
    37 
    38 lemma prime_dvd_mult: "prime p ==> p dvd m * n ==> p dvd m \<or> p dvd n"
    39   by (blast intro: relprime_dvd_mult prime_imp_relprime)
    40 
    41 lemma prime_dvd_square: "prime p ==> p dvd m^Suc (Suc 0) ==> p dvd m"
    42   by (auto dest: prime_dvd_mult)
    43 
    44 lemma prime_dvd_power_two: "prime p ==> p dvd m\<twosuperior> ==> p dvd m"
    45   by (rule prime_dvd_square) (simp_all add: power2_eq_square)
    46 
    47 
    48 lemma exp_eq_1:"(x::nat)^n = 1 \<longleftrightarrow> x = 1 \<or> n = 0" by (induct n, auto)
    49 lemma exp_mono_lt: "(x::nat) ^ (Suc n) < y ^ (Suc n) \<longleftrightarrow> x < y"
    50   using power_less_imp_less_base[of x "Suc n" y] power_strict_mono[of x y "Suc n"]
    51     by auto
    52 lemma exp_mono_le: "(x::nat) ^ (Suc n) \<le> y ^ (Suc n) \<longleftrightarrow> x \<le> y"
    53   by (simp only: linorder_not_less[symmetric] exp_mono_lt)
    54 
    55 lemma exp_mono_eq: "(x::nat) ^ Suc n = y ^ Suc n \<longleftrightarrow> x = y"
    56 using power_inject_base[of x n y] by auto
    57 
    58 
    59 lemma even_square: assumes e: "even (n::nat)" shows "\<exists>x. n ^ 2 = 4*x"
    60 proof-
    61   from e have "2 dvd n" by presburger
    62   then obtain k where k: "n = 2*k" using dvd_def by auto
    63   hence "n^2 = 4* (k^2)" by (simp add: power2_eq_square)
    64   thus ?thesis by blast
    65 qed
    66 
    67 lemma odd_square: assumes e: "odd (n::nat)" shows "\<exists>x. n ^ 2 = 4*x + 1"
    68 proof-
    69   from e have np: "n > 0" by presburger
    70   from e have "2 dvd (n - 1)" by presburger
    71   then obtain k where "n - 1 = 2*k" using dvd_def by auto
    72   hence k: "n = 2*k + 1"  using e by presburger 
    73   hence "n^2 = 4* (k^2 + k) + 1" by algebra   
    74   thus ?thesis by blast
    75 qed
    76 
    77 lemma diff_square: "(x::nat)^2 - y^2 = (x+y)*(x - y)" 
    78 proof-
    79   have "x \<le> y \<or> y \<le> x" by (rule nat_le_linear)
    80   moreover
    81   {assume le: "x \<le> y"
    82     hence "x ^2 \<le> y^2" by (simp only: numeral_2_eq_2 exp_mono_le Let_def)
    83     with le have ?thesis by simp }
    84   moreover
    85   {assume le: "y \<le> x"
    86     hence le2: "y ^2 \<le> x^2" by (simp only: numeral_2_eq_2 exp_mono_le Let_def)
    87     from le have "\<exists>z. y + z = x" by presburger
    88     then obtain z where z: "x = y + z" by blast 
    89     from le2 have "\<exists>z. x^2 = y^2 + z" by presburger
    90     then obtain z2 where z2: "x^2 = y^2 + z2"  by blast
    91     from z z2 have ?thesis apply simp by algebra }
    92   ultimately show ?thesis by blast  
    93 qed
    94 
    95 text {* Elementary theory of divisibility *}
    96 lemma divides_ge: "(a::nat) dvd b \<Longrightarrow> b = 0 \<or> a \<le> b" unfolding dvd_def by auto
    97 lemma divides_antisym: "(x::nat) dvd y \<and> y dvd x \<longleftrightarrow> x = y"
    98   using dvd_anti_sym[of x y] by auto
    99 
   100 lemma divides_add_revr: assumes da: "(d::nat) dvd a" and dab:"d dvd (a + b)"
   101   shows "d dvd b"
   102 proof-
   103   from da obtain k where k:"a = d*k" by (auto simp add: dvd_def)
   104   from dab obtain k' where k': "a + b = d*k'" by (auto simp add: dvd_def)
   105   from k k' have "b = d *(k' - k)" by (simp add : diff_mult_distrib2)
   106   thus ?thesis unfolding dvd_def by blast
   107 qed
   108 
   109 declare nat_mult_dvd_cancel_disj[presburger]
   110 lemma nat_mult_dvd_cancel_disj'[presburger]: 
   111   "(m\<Colon>nat)*k dvd n*k \<longleftrightarrow> k = 0 \<or> m dvd n" unfolding mult_commute[of m k] mult_commute[of n k] by presburger 
   112 
   113 lemma divides_mul_l: "(a::nat) dvd b ==> (c * a) dvd (c * b)"
   114   by presburger
   115 
   116 lemma divides_mul_r: "(a::nat) dvd b ==> (a * c) dvd (b * c)" by presburger
   117 lemma divides_cases: "(n::nat) dvd m ==> m = 0 \<or> m = n \<or> 2 * n <= m" 
   118   by (auto simp add: dvd_def)
   119 
   120 lemma divides_div_not: "(x::nat) = (q * n) + r \<Longrightarrow> 0 < r \<Longrightarrow> r < n ==> ~(n dvd x)"
   121 proof(auto simp add: dvd_def)
   122   fix k assume H: "0 < r" "r < n" "q * n + r = n * k"
   123   from H(3) have r: "r = n* (k -q)" by(simp add: diff_mult_distrib2 mult_commute)
   124   {assume "k - q = 0" with r H(1) have False by simp}
   125   moreover
   126   {assume "k - q \<noteq> 0" with r have "r \<ge> n" by auto
   127     with H(2) have False by simp}
   128   ultimately show False by blast
   129 qed
   130 lemma divides_exp: "(x::nat) dvd y ==> x ^ n dvd y ^ n"
   131   by (auto simp add: power_mult_distrib dvd_def)
   132 
   133 lemma divides_exp2: "n \<noteq> 0 \<Longrightarrow> (x::nat) ^ n dvd y \<Longrightarrow> x dvd y" 
   134   by (induct n ,auto simp add: dvd_def)
   135 
   136 fun fact :: "nat \<Rightarrow> nat" where
   137   "fact 0 = 1"
   138 | "fact (Suc n) = Suc n * fact n"	
   139 
   140 lemma fact_lt: "0 < fact n" by(induct n, simp_all)
   141 lemma fact_le: "fact n \<ge> 1" using fact_lt[of n] by simp 
   142 lemma fact_mono: assumes le: "m \<le> n" shows "fact m \<le> fact n"
   143 proof-
   144   from le have "\<exists>i. n = m+i" by presburger
   145   then obtain i where i: "n = m+i" by blast 
   146   have "fact m \<le> fact (m + i)"
   147   proof(induct m)
   148     case 0 thus ?case using fact_le[of i] by simp
   149   next
   150     case (Suc m)
   151     have "fact (Suc m) = Suc m * fact m" by simp
   152     have th1: "Suc m \<le> Suc (m + i)" by simp
   153     from mult_le_mono[of "Suc m" "Suc (m+i)" "fact m" "fact (m+i)", OF th1 Suc.hyps]
   154     show ?case by simp
   155   qed
   156   thus ?thesis using i by simp
   157 qed
   158 
   159 lemma divides_fact: "1 <= p \<Longrightarrow> p <= n ==> p dvd fact n"
   160 proof(induct n arbitrary: p)
   161   case 0 thus ?case by simp
   162 next
   163   case (Suc n p)
   164   from Suc.prems have "p = Suc n \<or> p \<le> n" by presburger 
   165   moreover
   166   {assume "p = Suc n" hence ?case  by (simp only: fact.simps dvd_triv_left)}
   167   moreover
   168   {assume "p \<le> n"
   169     with Suc.prems(1) Suc.hyps have th: "p dvd fact n" by simp
   170     from dvd_mult[OF th] have ?case by (simp only: fact.simps) }
   171   ultimately show ?case by blast
   172 qed
   173 
   174 declare dvd_triv_left[presburger]
   175 declare dvd_triv_right[presburger]
   176 lemma divides_rexp: 
   177   "x dvd y \<Longrightarrow> (x::nat) dvd (y^(Suc n))" by (simp add: dvd_mult2[of x y])
   178 
   179 text {* Coprimality *}
   180 
   181 lemma coprime: "coprime a b \<longleftrightarrow> (\<forall>d. d dvd a \<and> d dvd b \<longleftrightarrow> d = 1)"
   182 using gcd_unique[of 1 a b, simplified] by (auto simp add: coprime_def)
   183 lemma coprime_commute: "coprime a b \<longleftrightarrow> coprime b a" by (simp add: coprime_def gcd_commute)
   184 
   185 lemma coprime_bezout: "coprime a b \<longleftrightarrow> (\<exists>x y. a * x - b * y = 1 \<or> b * x - a * y = 1)"
   186 using coprime_def gcd_bezout by auto
   187 
   188 lemma coprime_divprod: "d dvd a * b  \<Longrightarrow> coprime d a \<Longrightarrow> d dvd b"
   189   using relprime_dvd_mult_iff[of d a b] by (auto simp add: coprime_def mult_commute)
   190 
   191 lemma coprime_1[simp]: "coprime a 1" by (simp add: coprime_def)
   192 lemma coprime_1'[simp]: "coprime 1 a" by (simp add: coprime_def)
   193 lemma coprime_Suc0[simp]: "coprime a (Suc 0)" by (simp add: coprime_def)
   194 lemma coprime_Suc0'[simp]: "coprime (Suc 0) a" by (simp add: coprime_def)
   195 
   196 lemma gcd_coprime: 
   197   assumes z: "gcd a b \<noteq> 0" and a: "a = a' * gcd a b" and b: "b = b' * gcd a b" 
   198   shows    "coprime a' b'"
   199 proof-
   200   let ?g = "gcd a b"
   201   {assume bz: "a = 0" from b bz z a have ?thesis by (simp add: gcd_zero coprime_def)}
   202   moreover 
   203   {assume az: "a\<noteq> 0" 
   204     from z have z': "?g > 0" by simp
   205     from bezout_gcd_strong[OF az, of b] 
   206     obtain x y where xy: "a*x = b*y + ?g" by blast
   207     from xy a b have "?g * a'*x = ?g * (b'*y + 1)" by (simp add: algebra_simps)
   208     hence "?g * (a'*x) = ?g * (b'*y + 1)" by (simp add: mult_assoc)
   209     hence "a'*x = (b'*y + 1)"
   210       by (simp only: nat_mult_eq_cancel1[OF z']) 
   211     hence "a'*x - b'*y = 1" by simp
   212     with coprime_bezout[of a' b'] have ?thesis by auto}
   213   ultimately show ?thesis by blast
   214 qed
   215 lemma coprime_0: "coprime d 0 \<longleftrightarrow> d = 1" by (simp add: coprime_def)
   216 lemma coprime_mul: assumes da: "coprime d a" and db: "coprime d b"
   217   shows "coprime d (a * b)"
   218 proof-
   219   from da have th: "gcd a d = 1" by (simp add: coprime_def gcd_commute)
   220   from gcd_mult_cancel[of a d b, OF th] db[unfolded coprime_def] have "gcd d (a*b) = 1"
   221     by (simp add: gcd_commute)
   222   thus ?thesis unfolding coprime_def .
   223 qed
   224 lemma coprime_lmul2: assumes dab: "coprime d (a * b)" shows "coprime d b"
   225 using prems unfolding coprime_bezout
   226 apply clarsimp
   227 apply (case_tac "d * x - a * b * y = Suc 0 ", simp_all)
   228 apply (rule_tac x="x" in exI)
   229 apply (rule_tac x="a*y" in exI)
   230 apply (simp add: mult_ac)
   231 apply (rule_tac x="a*x" in exI)
   232 apply (rule_tac x="y" in exI)
   233 apply (simp add: mult_ac)
   234 done
   235 
   236 lemma coprime_rmul2: "coprime d (a * b) \<Longrightarrow> coprime d a"
   237 unfolding coprime_bezout
   238 apply clarsimp
   239 apply (case_tac "d * x - a * b * y = Suc 0 ", simp_all)
   240 apply (rule_tac x="x" in exI)
   241 apply (rule_tac x="b*y" in exI)
   242 apply (simp add: mult_ac)
   243 apply (rule_tac x="b*x" in exI)
   244 apply (rule_tac x="y" in exI)
   245 apply (simp add: mult_ac)
   246 done
   247 lemma coprime_mul_eq: "coprime d (a * b) \<longleftrightarrow> coprime d a \<and>  coprime d b"
   248   using coprime_rmul2[of d a b] coprime_lmul2[of d a b] coprime_mul[of d a b] 
   249   by blast
   250 
   251 lemma gcd_coprime_exists:
   252   assumes nz: "gcd a b \<noteq> 0" 
   253   shows "\<exists>a' b'. a = a' * gcd a b \<and> b = b' * gcd a b \<and> coprime a' b'"
   254 proof-
   255   let ?g = "gcd a b"
   256   from gcd_dvd1[of a b] gcd_dvd2[of a b] 
   257   obtain a' b' where "a = ?g*a'"  "b = ?g*b'" unfolding dvd_def by blast
   258   hence ab': "a = a'*?g" "b = b'*?g" by algebra+
   259   from ab' gcd_coprime[OF nz ab'] show ?thesis by blast
   260 qed
   261 
   262 lemma coprime_exp: "coprime d a ==> coprime d (a^n)" 
   263   by(induct n, simp_all add: coprime_mul)
   264 
   265 lemma coprime_exp_imp: "coprime a b ==> coprime (a ^n) (b ^n)"
   266   by (induct n, simp_all add: coprime_mul_eq coprime_commute coprime_exp)
   267 lemma coprime_refl[simp]: "coprime n n \<longleftrightarrow> n = 1" by (simp add: coprime_def)
   268 lemma coprime_plus1[simp]: "coprime (n + 1) n"
   269   apply (simp add: coprime_bezout)
   270   apply (rule exI[where x=1])
   271   apply (rule exI[where x=1])
   272   apply simp
   273   done
   274 lemma coprime_minus1: "n \<noteq> 0 ==> coprime (n - 1) n"
   275   using coprime_plus1[of "n - 1"] coprime_commute[of "n - 1" n] by auto
   276 
   277 lemma bezout_gcd_pow: "\<exists>x y. a ^n * x - b ^ n * y = gcd a b ^ n \<or> b ^ n * x - a ^ n * y = gcd a b ^ n"
   278 proof-
   279   let ?g = "gcd a b"
   280   {assume z: "?g = 0" hence ?thesis 
   281       apply (cases n, simp)
   282       apply arith
   283       apply (simp only: z power_0_Suc)
   284       apply (rule exI[where x=0])
   285       apply (rule exI[where x=0])
   286       by simp}
   287   moreover
   288   {assume z: "?g \<noteq> 0"
   289     from gcd_dvd1[of a b] gcd_dvd2[of a b] obtain a' b' where
   290       ab': "a = a'*?g" "b = b'*?g" unfolding dvd_def by (auto simp add: mult_ac)
   291     hence ab'': "?g*a' = a" "?g * b' = b" by algebra+
   292     from coprime_exp_imp[OF gcd_coprime[OF z ab'], unfolded coprime_bezout, of n]
   293     obtain x y where "a'^n * x - b'^n * y = 1 \<or> b'^n * x - a'^n * y = 1"  by blast
   294     hence "?g^n * (a'^n * x - b'^n * y) = ?g^n \<or> ?g^n*(b'^n * x - a'^n * y) = ?g^n"
   295       using z by auto 
   296     then have "a^n * x - b^n * y = ?g^n \<or> b^n * x - a^n * y = ?g^n"
   297       using z ab'' by (simp only: power_mult_distrib[symmetric] 
   298 	diff_mult_distrib2 mult_assoc[symmetric])
   299     hence  ?thesis by blast }
   300   ultimately show ?thesis by blast
   301 qed
   302 
   303 lemma gcd_exp: "gcd (a^n) (b^n) = gcd a b^n"
   304 proof-
   305   let ?g = "gcd (a^n) (b^n)"
   306   let ?gn = "gcd a b^n"
   307   {fix e assume H: "e dvd a^n" "e dvd b^n"
   308     from bezout_gcd_pow[of a n b] obtain x y 
   309       where xy: "a ^ n * x - b ^ n * y = ?gn \<or> b ^ n * x - a ^ n * y = ?gn" by blast
   310     from dvd_diff [OF dvd_mult2[OF H(1), of x] dvd_mult2[OF H(2), of y]]
   311       dvd_diff [OF dvd_mult2[OF H(2), of x] dvd_mult2[OF H(1), of y]] xy
   312     have "e dvd ?gn" by (cases "a ^ n * x - b ^ n * y = gcd a b ^ n", simp_all)}
   313   hence th:  "\<forall>e. e dvd a^n \<and> e dvd b^n \<longrightarrow> e dvd ?gn" by blast
   314   from divides_exp[OF gcd_dvd1[of a b], of n] divides_exp[OF gcd_dvd2[of a b], of n] th
   315     gcd_unique have "?gn = ?g" by blast thus ?thesis by simp 
   316 qed
   317 
   318 lemma coprime_exp2:  "coprime (a ^ Suc n) (b^ Suc n) \<longleftrightarrow> coprime a b"
   319 by (simp only: coprime_def gcd_exp exp_eq_1) simp
   320 
   321 lemma division_decomp: assumes dc: "(a::nat) dvd b * c"
   322   shows "\<exists>b' c'. a = b' * c' \<and> b' dvd b \<and> c' dvd c"
   323 proof-
   324   let ?g = "gcd a b"
   325   {assume "?g = 0" with dc have ?thesis apply (simp add: gcd_zero)
   326       apply (rule exI[where x="0"])
   327       by (rule exI[where x="c"], simp)}
   328   moreover
   329   {assume z: "?g \<noteq> 0"
   330     from gcd_coprime_exists[OF z]
   331     obtain a' b' where ab': "a = a' * ?g" "b = b' * ?g" "coprime a' b'" by blast
   332     from gcd_dvd2[of a b] have thb: "?g dvd b" .
   333     from ab'(1) have "a' dvd a"  unfolding dvd_def by blast  
   334     with dc have th0: "a' dvd b*c" using dvd_trans[of a' a "b*c"] by simp
   335     from dc ab'(1,2) have "a'*?g dvd (b'*?g) *c" by auto
   336     hence "?g*a' dvd ?g * (b' * c)" by (simp add: mult_assoc)
   337     with z have th_1: "a' dvd b'*c" by simp
   338     from coprime_divprod[OF th_1 ab'(3)] have thc: "a' dvd c" . 
   339     from ab' have "a = ?g*a'" by algebra
   340     with thb thc have ?thesis by blast }
   341   ultimately show ?thesis by blast
   342 qed
   343 
   344 lemma nat_power_eq_0_iff: "(m::nat) ^ n = 0 \<longleftrightarrow> n \<noteq> 0 \<and> m = 0" by (induct n, auto)
   345 
   346 lemma divides_rev: assumes ab: "(a::nat) ^ n dvd b ^n" and n:"n \<noteq> 0" shows "a dvd b"
   347 proof-
   348   let ?g = "gcd a b"
   349   from n obtain m where m: "n = Suc m" by (cases n, simp_all)
   350   {assume "?g = 0" with ab n have ?thesis by (simp add: gcd_zero)}
   351   moreover
   352   {assume z: "?g \<noteq> 0"
   353     hence zn: "?g ^ n \<noteq> 0" using n by (simp add: neq0_conv)
   354     from gcd_coprime_exists[OF z] 
   355     obtain a' b' where ab': "a = a' * ?g" "b = b' * ?g" "coprime a' b'" by blast
   356     from ab have "(a' * ?g) ^ n dvd (b' * ?g)^n" by (simp add: ab'(1,2)[symmetric])
   357     hence "?g^n*a'^n dvd ?g^n *b'^n" by (simp only: power_mult_distrib mult_commute)
   358     with zn z n have th0:"a'^n dvd b'^n" by (auto simp add: nat_power_eq_0_iff)
   359     have "a' dvd a'^n" by (simp add: m)
   360     with th0 have "a' dvd b'^n" using dvd_trans[of a' "a'^n" "b'^n"] by simp
   361     hence th1: "a' dvd b'^m * b'" by (simp add: m mult_commute)
   362     from coprime_divprod[OF th1 coprime_exp[OF ab'(3), of m]]
   363     have "a' dvd b'" .
   364     hence "a'*?g dvd b'*?g" by simp
   365     with ab'(1,2)  have ?thesis by simp }
   366   ultimately show ?thesis by blast
   367 qed
   368 
   369 lemma divides_mul: assumes mr: "m dvd r" and nr: "n dvd r" and mn:"coprime m n" 
   370   shows "m * n dvd r"
   371 proof-
   372   from mr nr obtain m' n' where m': "r = m*m'" and n': "r = n*n'"
   373     unfolding dvd_def by blast
   374   from mr n' have "m dvd n'*n" by (simp add: mult_commute)
   375   hence "m dvd n'" using relprime_dvd_mult_iff[OF mn[unfolded coprime_def]] by simp
   376   then obtain k where k: "n' = m*k" unfolding dvd_def by blast
   377   from n' k show ?thesis unfolding dvd_def by auto
   378 qed
   379 
   380 
   381 text {* A binary form of the Chinese Remainder Theorem. *}
   382 
   383 lemma chinese_remainder: assumes ab: "coprime a b" and a:"a \<noteq> 0" and b:"b \<noteq> 0"
   384   shows "\<exists>x q1 q2. x = u + q1 * a \<and> x = v + q2 * b"
   385 proof-
   386   from bezout_add_strong[OF a, of b] bezout_add_strong[OF b, of a]
   387   obtain d1 x1 y1 d2 x2 y2 where dxy1: "d1 dvd a" "d1 dvd b" "a * x1 = b * y1 + d1" 
   388     and dxy2: "d2 dvd b" "d2 dvd a" "b * x2 = a * y2 + d2" by blast
   389   from gcd_unique[of 1 a b, simplified ab[unfolded coprime_def], simplified] 
   390     dxy1(1,2) dxy2(1,2) have d12: "d1 = 1" "d2 =1" by auto
   391   let ?x = "v * a * x1 + u * b * x2"
   392   let ?q1 = "v * x1 + u * y2"
   393   let ?q2 = "v * y1 + u * x2"
   394   from dxy2(3)[simplified d12] dxy1(3)[simplified d12] 
   395   have "?x = u + ?q1 * a" "?x = v + ?q2 * b" by algebra+ 
   396   thus ?thesis by blast
   397 qed
   398 
   399 text {* Primality *}
   400 
   401 text {* A few useful theorems about primes *}
   402 
   403 lemma prime_0[simp]: "~prime 0" by (simp add: prime_def)
   404 lemma prime_1[simp]: "~ prime 1"  by (simp add: prime_def)
   405 lemma prime_Suc0[simp]: "~ prime (Suc 0)"  by (simp add: prime_def)
   406 
   407 lemma prime_ge_2: "prime p ==> p \<ge> 2" by (simp add: prime_def)
   408 lemma prime_factor: assumes n: "n \<noteq> 1" shows "\<exists> p. prime p \<and> p dvd n"
   409 using n
   410 proof(induct n rule: nat_less_induct)
   411   fix n
   412   assume H: "\<forall>m<n. m \<noteq> 1 \<longrightarrow> (\<exists>p. prime p \<and> p dvd m)" "n \<noteq> 1"
   413   let ?ths = "\<exists>p. prime p \<and> p dvd n"
   414   {assume "n=0" hence ?ths using two_is_prime by auto}
   415   moreover
   416   {assume nz: "n\<noteq>0" 
   417     {assume "prime n" hence ?ths by - (rule exI[where x="n"], simp)}
   418     moreover
   419     {assume n: "\<not> prime n"
   420       with nz H(2) 
   421       obtain k where k:"k dvd n" "k \<noteq> 1" "k \<noteq> n" by (auto simp add: prime_def) 
   422       from dvd_imp_le[OF k(1)] nz k(3) have kn: "k < n" by simp
   423       from H(1)[rule_format, OF kn k(2)] obtain p where p: "prime p" "p dvd k" by blast
   424       from dvd_trans[OF p(2) k(1)] p(1) have ?ths by blast}
   425     ultimately have ?ths by blast}
   426   ultimately show ?ths by blast
   427 qed
   428 
   429 lemma prime_factor_lt: assumes p: "prime p" and n: "n \<noteq> 0" and npm:"n = p * m"
   430   shows "m < n"
   431 proof-
   432   {assume "m=0" with n have ?thesis by simp}
   433   moreover
   434   {assume m: "m \<noteq> 0"
   435     from npm have mn: "m dvd n" unfolding dvd_def by auto
   436     from npm m have "n \<noteq> m" using p by auto
   437     with dvd_imp_le[OF mn] n have ?thesis by simp}
   438   ultimately show ?thesis by blast
   439 qed
   440 
   441 lemma euclid_bound: "\<exists>p. prime p \<and> n < p \<and>  p <= Suc (fact n)"
   442 proof-
   443   have f1: "fact n + 1 \<noteq> 1" using fact_le[of n] by arith 
   444   from prime_factor[OF f1] obtain p where p: "prime p" "p dvd fact n + 1" by blast
   445   from dvd_imp_le[OF p(2)] have pfn: "p \<le> fact n + 1" by simp
   446   {assume np: "p \<le> n"
   447     from p(1) have p1: "p \<ge> 1" by (cases p, simp_all)
   448     from divides_fact[OF p1 np] have pfn': "p dvd fact n" .
   449     from divides_add_revr[OF pfn' p(2)] p(1) have False by simp}
   450   hence "n < p" by arith
   451   with p(1) pfn show ?thesis by auto
   452 qed
   453 
   454 lemma euclid: "\<exists>p. prime p \<and> p > n" using euclid_bound by auto
   455 lemma primes_infinite: "\<not> (finite {p. prime p})"
   456 proof (auto simp add: finite_conv_nat_seg_image)
   457   fix n f 
   458   assume H: "Collect prime = f ` {i. i < (n::nat)}"
   459   let ?P = "Collect prime"
   460   let ?m = "Max ?P"
   461   have P0: "?P \<noteq> {}" using two_is_prime by auto
   462   from H have fP: "finite ?P" using finite_conv_nat_seg_image by blast 
   463   from Max_in [OF fP P0] have "?m \<in> ?P" . 
   464   from Max_ge [OF fP] have contr: "\<forall> p. prime p \<longrightarrow> p \<le> ?m" by blast
   465   from euclid [of ?m] obtain q where q: "prime q" "q > ?m" by blast
   466   with contr show False by auto
   467 qed
   468 
   469 lemma coprime_prime: assumes ab: "coprime a b"
   470   shows "~(prime p \<and> p dvd a \<and> p dvd b)"
   471 proof
   472   assume "prime p \<and> p dvd a \<and> p dvd b"
   473   thus False using ab gcd_greatest[of p a b] by (simp add: coprime_def)
   474 qed
   475 lemma coprime_prime_eq: "coprime a b \<longleftrightarrow> (\<forall>p. ~(prime p \<and> p dvd a \<and> p dvd b))" 
   476   (is "?lhs = ?rhs")
   477 proof-
   478   {assume "?lhs" with coprime_prime  have ?rhs by blast}
   479   moreover
   480   {assume r: "?rhs" and c: "\<not> ?lhs"
   481     then obtain g where g: "g\<noteq>1" "g dvd a" "g dvd b" unfolding coprime_def by blast
   482     from prime_factor[OF g(1)] obtain p where p: "prime p" "p dvd g" by blast
   483     from dvd_trans [OF p(2) g(2)] dvd_trans [OF p(2) g(3)] 
   484     have "p dvd a" "p dvd b" . with p(1) r have False by blast}
   485   ultimately show ?thesis by blast
   486 qed
   487 
   488 lemma prime_coprime: assumes p: "prime p" 
   489   shows "n = 1 \<or> p dvd n \<or> coprime p n"
   490 using p prime_imp_relprime[of p n] by (auto simp add: coprime_def)
   491 
   492 lemma prime_coprime_strong: "prime p \<Longrightarrow> p dvd n \<or> coprime p n"
   493   using prime_coprime[of p n] by auto
   494 
   495 declare  coprime_0[simp]
   496 
   497 lemma coprime_0'[simp]: "coprime 0 d \<longleftrightarrow> d = 1" by (simp add: coprime_commute[of 0 d])
   498 lemma coprime_bezout_strong: assumes ab: "coprime a b" and b: "b \<noteq> 1"
   499   shows "\<exists>x y. a * x = b * y + 1"
   500 proof-
   501   from ab b have az: "a \<noteq> 0" by - (rule ccontr, auto)
   502   from bezout_gcd_strong[OF az, of b] ab[unfolded coprime_def]
   503   show ?thesis by auto
   504 qed
   505 
   506 lemma bezout_prime: assumes p: "prime p"  and pa: "\<not> p dvd a"
   507   shows "\<exists>x y. a*x = p*y + 1"
   508 proof-
   509   from p have p1: "p \<noteq> 1" using prime_1 by blast 
   510   from prime_coprime[OF p, of a] p1 pa have ap: "coprime a p" 
   511     by (auto simp add: coprime_commute)
   512   from coprime_bezout_strong[OF ap p1] show ?thesis . 
   513 qed
   514 lemma prime_divprod: assumes p: "prime p" and pab: "p dvd a*b"
   515   shows "p dvd a \<or> p dvd b"
   516 proof-
   517   {assume "a=1" hence ?thesis using pab by simp }
   518   moreover
   519   {assume "p dvd a" hence ?thesis by blast}
   520   moreover
   521   {assume pa: "coprime p a" from coprime_divprod[OF pab pa]  have ?thesis .. }
   522   ultimately show ?thesis using prime_coprime[OF p, of a] by blast
   523 qed
   524 
   525 lemma prime_divprod_eq: assumes p: "prime p"
   526   shows "p dvd a*b \<longleftrightarrow> p dvd a \<or> p dvd b"
   527 using p prime_divprod dvd_mult dvd_mult2 by auto
   528 
   529 lemma prime_divexp: assumes p:"prime p" and px: "p dvd x^n"
   530   shows "p dvd x"
   531 using px
   532 proof(induct n)
   533   case 0 thus ?case by simp
   534 next
   535   case (Suc n) 
   536   hence th: "p dvd x*x^n" by simp
   537   {assume H: "p dvd x^n"
   538     from Suc.hyps[OF H] have ?case .}
   539   with prime_divprod[OF p th] show ?case by blast
   540 qed
   541 
   542 lemma prime_divexp_n: "prime p \<Longrightarrow> p dvd x^n \<Longrightarrow> p^n dvd x^n"
   543   using prime_divexp[of p x n] divides_exp[of p x n] by blast
   544 
   545 lemma coprime_prime_dvd_ex: assumes xy: "\<not>coprime x y"
   546   shows "\<exists>p. prime p \<and> p dvd x \<and> p dvd y"
   547 proof-
   548   from xy[unfolded coprime_def] obtain g where g: "g \<noteq> 1" "g dvd x" "g dvd y" 
   549     by blast
   550   from prime_factor[OF g(1)] obtain p where p: "prime p" "p dvd g" by blast
   551   from g(2,3) dvd_trans[OF p(2)] p(1) show ?thesis by auto
   552 qed
   553 lemma coprime_sos: assumes xy: "coprime x y" 
   554   shows "coprime (x * y) (x^2 + y^2)"
   555 proof-
   556   {assume c: "\<not> coprime (x * y) (x^2 + y^2)"
   557     from coprime_prime_dvd_ex[OF c] obtain p 
   558       where p: "prime p" "p dvd x*y" "p dvd x^2 + y^2" by blast
   559     {assume px: "p dvd x"
   560       from dvd_mult[OF px, of x] p(3) 
   561         obtain r s where "x * x = p * r" and "x^2 + y^2 = p * s"
   562           by (auto elim!: dvdE)
   563         then have "y^2 = p * (s - r)" 
   564           by (auto simp add: power2_eq_square diff_mult_distrib2)
   565         then have "p dvd y^2" ..
   566       with prime_divexp[OF p(1), of y 2] have py: "p dvd y" .
   567       from p(1) px py xy[unfolded coprime, rule_format, of p] prime_1  
   568       have False by simp }
   569     moreover
   570     {assume py: "p dvd y"
   571       from dvd_mult[OF py, of y] p(3)
   572         obtain r s where "y * y = p * r" and "x^2 + y^2 = p * s"
   573           by (auto elim!: dvdE)
   574         then have "x^2 = p * (s - r)" 
   575           by (auto simp add: power2_eq_square diff_mult_distrib2)
   576         then have "p dvd x^2" ..
   577       with prime_divexp[OF p(1), of x 2] have px: "p dvd x" .
   578       from p(1) px py xy[unfolded coprime, rule_format, of p] prime_1  
   579       have False by simp }
   580     ultimately have False using prime_divprod[OF p(1,2)] by blast}
   581   thus ?thesis by blast
   582 qed
   583 
   584 lemma distinct_prime_coprime: "prime p \<Longrightarrow> prime q \<Longrightarrow> p \<noteq> q \<Longrightarrow> coprime p q"
   585   unfolding prime_def coprime_prime_eq by blast
   586 
   587 lemma prime_coprime_lt: assumes p: "prime p" and x: "0 < x" and xp: "x < p"
   588   shows "coprime x p"
   589 proof-
   590   {assume c: "\<not> coprime x p"
   591     then obtain g where g: "g \<noteq> 1" "g dvd x" "g dvd p" unfolding coprime_def by blast
   592   from dvd_imp_le[OF g(2)] x xp have gp: "g < p" by arith
   593   from g(2) x have "g \<noteq> 0" by - (rule ccontr, simp)
   594   with g gp p[unfolded prime_def] have False by blast}
   595 thus ?thesis by blast
   596 qed
   597 
   598 lemma even_dvd[simp]: "even (n::nat) \<longleftrightarrow> 2 dvd n" by presburger
   599 lemma prime_odd: "prime p \<Longrightarrow> p = 2 \<or> odd p" unfolding prime_def by auto
   600 
   601 
   602 text {* One property of coprimality is easier to prove via prime factors. *}
   603 
   604 lemma prime_divprod_pow: 
   605   assumes p: "prime p" and ab: "coprime a b" and pab: "p^n dvd a * b"
   606   shows "p^n dvd a \<or> p^n dvd b"
   607 proof-
   608   {assume "n = 0 \<or> a = 1 \<or> b = 1" with pab have ?thesis 
   609       apply (cases "n=0", simp_all)
   610       apply (cases "a=1", simp_all) done}
   611   moreover
   612   {assume n: "n \<noteq> 0" and a: "a\<noteq>1" and b: "b\<noteq>1" 
   613     then obtain m where m: "n = Suc m" by (cases n, auto)
   614     from divides_exp2[OF n pab] have pab': "p dvd a*b" .
   615     from prime_divprod[OF p pab'] 
   616     have "p dvd a \<or> p dvd b" .
   617     moreover
   618     {assume pa: "p dvd a"
   619       have pnba: "p^n dvd b*a" using pab by (simp add: mult_commute)
   620       from coprime_prime[OF ab, of p] p pa have "\<not> p dvd b" by blast
   621       with prime_coprime[OF p, of b] b 
   622       have cpb: "coprime b p" using coprime_commute by blast 
   623       from coprime_exp[OF cpb] have pnb: "coprime (p^n) b" 
   624 	by (simp add: coprime_commute)
   625       from coprime_divprod[OF pnba pnb] have ?thesis by blast }
   626     moreover
   627     {assume pb: "p dvd b"
   628       have pnba: "p^n dvd b*a" using pab by (simp add: mult_commute)
   629       from coprime_prime[OF ab, of p] p pb have "\<not> p dvd a" by blast
   630       with prime_coprime[OF p, of a] a
   631       have cpb: "coprime a p" using coprime_commute by blast 
   632       from coprime_exp[OF cpb] have pnb: "coprime (p^n) a" 
   633 	by (simp add: coprime_commute)
   634       from coprime_divprod[OF pab pnb] have ?thesis by blast }
   635     ultimately have ?thesis by blast}
   636   ultimately show ?thesis by blast
   637 qed
   638 
   639 lemma nat_mult_eq_one: "(n::nat) * m = 1 \<longleftrightarrow> n = 1 \<and> m = 1" (is "?lhs \<longleftrightarrow> ?rhs")
   640 proof
   641   assume H: "?lhs"
   642   hence "n dvd 1" "m dvd 1" unfolding dvd_def by (auto simp add: mult_commute)
   643   thus ?rhs by auto
   644 next
   645   assume ?rhs then show ?lhs by auto
   646 qed
   647   
   648 lemma power_Suc0[simp]: "Suc 0 ^ n = Suc 0" 
   649   unfolding One_nat_def[symmetric] power_one ..
   650 lemma coprime_pow: assumes ab: "coprime a b" and abcn: "a * b = c ^n"
   651   shows "\<exists>r s. a = r^n  \<and> b = s ^n"
   652   using ab abcn
   653 proof(induct c arbitrary: a b rule: nat_less_induct)
   654   fix c a b
   655   assume H: "\<forall>m<c. \<forall>a b. coprime a b \<longrightarrow> a * b = m ^ n \<longrightarrow> (\<exists>r s. a = r ^ n \<and> b = s ^ n)" "coprime a b" "a * b = c ^ n" 
   656   let ?ths = "\<exists>r s. a = r^n  \<and> b = s ^n"
   657   {assume n: "n = 0"
   658     with H(3) power_one have "a*b = 1" by simp
   659     hence "a = 1 \<and> b = 1" by simp
   660     hence ?ths 
   661       apply -
   662       apply (rule exI[where x=1])
   663       apply (rule exI[where x=1])
   664       using power_one[of  n]
   665       by simp}
   666   moreover
   667   {assume n: "n \<noteq> 0" then obtain m where m: "n = Suc m" by (cases n, auto)
   668     {assume c: "c = 0"
   669       with H(3) m H(2) have ?ths apply simp 
   670 	apply (cases "a=0", simp_all) 
   671 	apply (rule exI[where x="0"], simp)
   672 	apply (rule exI[where x="0"], simp)
   673 	done}
   674     moreover
   675     {assume "c=1" with H(3) power_one have "a*b = 1" by simp 
   676 	hence "a = 1 \<and> b = 1" by simp
   677 	hence ?ths 
   678       apply -
   679       apply (rule exI[where x=1])
   680       apply (rule exI[where x=1])
   681       using power_one[of  n]
   682       by simp}
   683   moreover
   684   {assume c: "c\<noteq>1" "c \<noteq> 0"
   685     from prime_factor[OF c(1)] obtain p where p: "prime p" "p dvd c" by blast
   686     from prime_divprod_pow[OF p(1) H(2), unfolded H(3), OF divides_exp[OF p(2), of n]] 
   687     have pnab: "p ^ n dvd a \<or> p^n dvd b" . 
   688     from p(2) obtain l where l: "c = p*l" unfolding dvd_def by blast
   689     have pn0: "p^n \<noteq> 0" using n prime_ge_2 [OF p(1)] by (simp add: neq0_conv)
   690     {assume pa: "p^n dvd a"
   691       then obtain k where k: "a = p^n * k" unfolding dvd_def by blast
   692       from l have "l dvd c" by auto
   693       with dvd_imp_le[of l c] c have "l \<le> c" by auto
   694       moreover {assume "l = c" with l c  have "p = 1" by simp with p have False by simp}
   695       ultimately have lc: "l < c" by arith
   696       from coprime_lmul2 [OF H(2)[unfolded k coprime_commute[of "p^n*k" b]]]
   697       have kb: "coprime k b" by (simp add: coprime_commute) 
   698       from H(3) l k pn0 have kbln: "k * b = l ^ n" 
   699 	by (auto simp add: power_mult_distrib)
   700       from H(1)[rule_format, OF lc kb kbln]
   701       obtain r s where rs: "k = r ^n" "b = s^n" by blast
   702       from k rs(1) have "a = (p*r)^n" by (simp add: power_mult_distrib)
   703       with rs(2) have ?ths by blast }
   704     moreover
   705     {assume pb: "p^n dvd b"
   706       then obtain k where k: "b = p^n * k" unfolding dvd_def by blast
   707       from l have "l dvd c" by auto
   708       with dvd_imp_le[of l c] c have "l \<le> c" by auto
   709       moreover {assume "l = c" with l c  have "p = 1" by simp with p have False by simp}
   710       ultimately have lc: "l < c" by arith
   711       from coprime_lmul2 [OF H(2)[unfolded k coprime_commute[of "p^n*k" a]]]
   712       have kb: "coprime k a" by (simp add: coprime_commute) 
   713       from H(3) l k pn0 n have kbln: "k * a = l ^ n" 
   714 	by (simp add: power_mult_distrib mult_commute)
   715       from H(1)[rule_format, OF lc kb kbln]
   716       obtain r s where rs: "k = r ^n" "a = s^n" by blast
   717       from k rs(1) have "b = (p*r)^n" by (simp add: power_mult_distrib)
   718       with rs(2) have ?ths by blast }
   719     ultimately have ?ths using pnab by blast}
   720   ultimately have ?ths by blast}
   721 ultimately show ?ths by blast
   722 qed
   723 
   724 text {* More useful lemmas. *}
   725 lemma prime_product: 
   726   assumes "prime (p * q)"
   727   shows "p = 1 \<or> q = 1"
   728 proof -
   729   from assms have 
   730     "1 < p * q" and P: "\<And>m. m dvd p * q \<Longrightarrow> m = 1 \<or> m = p * q"
   731     unfolding prime_def by auto
   732   from `1 < p * q` have "p \<noteq> 0" by (cases p) auto
   733   then have Q: "p = p * q \<longleftrightarrow> q = 1" by auto
   734   have "p dvd p * q" by simp
   735   then have "p = 1 \<or> p = p * q" by (rule P)
   736   then show ?thesis by (simp add: Q)
   737 qed
   738 
   739 lemma prime_exp: "prime (p^n) \<longleftrightarrow> prime p \<and> n = 1"
   740 proof(induct n)
   741   case 0 thus ?case by simp
   742 next
   743   case (Suc n)
   744   {assume "p = 0" hence ?case by simp}
   745   moreover
   746   {assume "p=1" hence ?case by simp}
   747   moreover
   748   {assume p: "p \<noteq> 0" "p\<noteq>1"
   749     {assume pp: "prime (p^Suc n)"
   750       hence "p = 1 \<or> p^n = 1" using prime_product[of p "p^n"] by simp
   751       with p have n: "n = 0" 
   752 	by (simp only: exp_eq_1 ) simp
   753       with pp have "prime p \<and> Suc n = 1" by simp}
   754     moreover
   755     {assume n: "prime p \<and> Suc n = 1" hence "prime (p^Suc n)" by simp}
   756     ultimately have ?case by blast}
   757   ultimately show ?case by blast
   758 qed
   759 
   760 lemma prime_power_mult: 
   761   assumes p: "prime p" and xy: "x * y = p ^ k"
   762   shows "\<exists>i j. x = p ^i \<and> y = p^ j"
   763   using xy
   764 proof(induct k arbitrary: x y)
   765   case 0 thus ?case apply simp by (rule exI[where x="0"], simp)
   766 next
   767   case (Suc k x y)
   768   from Suc.prems have pxy: "p dvd x*y" by auto
   769   from prime_divprod[OF p pxy] have pxyc: "p dvd x \<or> p dvd y" .
   770   from p have p0: "p \<noteq> 0" by - (rule ccontr, simp) 
   771   {assume px: "p dvd x"
   772     then obtain d where d: "x = p*d" unfolding dvd_def by blast
   773     from Suc.prems d  have "p*d*y = p^Suc k" by simp
   774     hence th: "d*y = p^k" using p0 by simp
   775     from Suc.hyps[OF th] obtain i j where ij: "d = p^i" "y = p^j" by blast
   776     with d have "x = p^Suc i" by simp 
   777     with ij(2) have ?case by blast}
   778   moreover 
   779   {assume px: "p dvd y"
   780     then obtain d where d: "y = p*d" unfolding dvd_def by blast
   781     from Suc.prems d  have "p*d*x = p^Suc k" by (simp add: mult_commute)
   782     hence th: "d*x = p^k" using p0 by simp
   783     from Suc.hyps[OF th] obtain i j where ij: "d = p^i" "x = p^j" by blast
   784     with d have "y = p^Suc i" by simp 
   785     with ij(2) have ?case by blast}
   786   ultimately show ?case  using pxyc by blast
   787 qed
   788 
   789 lemma prime_power_exp: assumes p: "prime p" and n:"n \<noteq> 0" 
   790   and xn: "x^n = p^k" shows "\<exists>i. x = p^i"
   791   using n xn
   792 proof(induct n arbitrary: k)
   793   case 0 thus ?case by simp
   794 next
   795   case (Suc n k) hence th: "x*x^n = p^k" by simp
   796   {assume "n = 0" with prems have ?case apply simp 
   797       by (rule exI[where x="k"],simp)}
   798   moreover
   799   {assume n: "n \<noteq> 0"
   800     from prime_power_mult[OF p th] 
   801     obtain i j where ij: "x = p^i" "x^n = p^j"by blast
   802     from Suc.hyps[OF n ij(2)] have ?case .}
   803   ultimately show ?case by blast
   804 qed
   805 
   806 lemma divides_primepow: assumes p: "prime p" 
   807   shows "d dvd p^k \<longleftrightarrow> (\<exists> i. i \<le> k \<and> d = p ^i)"
   808 proof
   809   assume H: "d dvd p^k" then obtain e where e: "d*e = p^k" 
   810     unfolding dvd_def  apply (auto simp add: mult_commute) by blast
   811   from prime_power_mult[OF p e] obtain i j where ij: "d = p^i" "e=p^j" by blast
   812   from prime_ge_2[OF p] have p1: "p > 1" by arith
   813   from e ij have "p^(i + j) = p^k" by (simp add: power_add)
   814   hence "i + j = k" using power_inject_exp[of p "i+j" k, OF p1] by simp 
   815   hence "i \<le> k" by arith
   816   with ij(1) show "\<exists>i\<le>k. d = p ^ i" by blast
   817 next
   818   {fix i assume H: "i \<le> k" "d = p^i"
   819     hence "\<exists>j. k = i + j" by arith
   820     then obtain j where j: "k = i + j" by blast
   821     hence "p^k = p^j*d" using H(2) by (simp add: power_add)
   822     hence "d dvd p^k" unfolding dvd_def by auto}
   823   thus "\<exists>i\<le>k. d = p ^ i \<Longrightarrow> d dvd p ^ k" by blast
   824 qed
   825 
   826 lemma coprime_divisors: "d dvd a \<Longrightarrow> e dvd b \<Longrightarrow> coprime a b \<Longrightarrow> coprime d e"
   827   by (auto simp add: dvd_def coprime)
   828 
   829 declare power_Suc0[simp del]
   830 declare even_dvd[simp del]
   831 
   832 end