src/HOL/Power.thy
author haftmann
Tue Oct 16 23:12:45 2007 +0200 (2007-10-16)
changeset 25062 af5ef0d4d655
parent 24996 ebd5f4cc7118
child 25134 3d4953e88449
permissions -rw-r--r--
global class syntax
     1 (*  Title:      HOL/Power.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1997  University of Cambridge
     5 
     6 *)
     7 
     8 header{*Exponentiation*}
     9 
    10 theory Power
    11 imports Nat
    12 begin
    13 
    14 class power = type +
    15   fixes power :: "'a \<Rightarrow> nat \<Rightarrow> 'a"            (infixr "^" 80)
    16 
    17 subsection{*Powers for Arbitrary Monoids*}
    18 
    19 class recpower = monoid_mult + power +
    20   assumes power_0 [simp]: "a ^ 0       = 1"
    21   assumes power_Suc:      "a ^ Suc n = a * (a ^ n)"
    22 
    23 lemma power_0_Suc [simp]: "(0::'a::{recpower,semiring_0}) ^ (Suc n) = 0"
    24   by (simp add: power_Suc)
    25 
    26 text{*It looks plausible as a simprule, but its effect can be strange.*}
    27 lemma power_0_left: "0^n = (if n=0 then 1 else (0::'a::{recpower,semiring_0}))"
    28   by (induct n) simp_all
    29 
    30 lemma power_one [simp]: "1^n = (1::'a::recpower)"
    31   by (induct n) (simp_all add: power_Suc)
    32 
    33 lemma power_one_right [simp]: "(a::'a::recpower) ^ 1 = a"
    34   by (simp add: power_Suc)
    35 
    36 lemma power_commutes: "(a::'a::recpower) ^ n * a = a * a ^ n"
    37   by (induct n) (simp_all add: power_Suc mult_assoc)
    38 
    39 lemma power_add: "(a::'a::recpower) ^ (m+n) = (a^m) * (a^n)"
    40   by (induct m) (simp_all add: power_Suc mult_ac)
    41 
    42 lemma power_mult: "(a::'a::recpower) ^ (m*n) = (a^m) ^ n"
    43   by (induct n) (simp_all add: power_Suc power_add)
    44 
    45 lemma power_mult_distrib: "((a::'a::{recpower,comm_monoid_mult}) * b) ^ n = (a^n) * (b^n)"
    46   by (induct n) (simp_all add: power_Suc mult_ac)
    47 
    48 lemma zero_less_power:
    49      "0 < (a::'a::{ordered_semidom,recpower}) ==> 0 < a^n"
    50 apply (induct "n")
    51 apply (simp_all add: power_Suc zero_less_one mult_pos_pos)
    52 done
    53 
    54 lemma zero_le_power:
    55      "0 \<le> (a::'a::{ordered_semidom,recpower}) ==> 0 \<le> a^n"
    56 apply (simp add: order_le_less)
    57 apply (erule disjE)
    58 apply (simp_all add: zero_less_power zero_less_one power_0_left)
    59 done
    60 
    61 lemma one_le_power:
    62      "1 \<le> (a::'a::{ordered_semidom,recpower}) ==> 1 \<le> a^n"
    63 apply (induct "n")
    64 apply (simp_all add: power_Suc)
    65 apply (rule order_trans [OF _ mult_mono [of 1 _ 1]])
    66 apply (simp_all add: zero_le_one order_trans [OF zero_le_one])
    67 done
    68 
    69 lemma gt1_imp_ge0: "1 < a ==> 0 \<le> (a::'a::ordered_semidom)"
    70   by (simp add: order_trans [OF zero_le_one order_less_imp_le])
    71 
    72 lemma power_gt1_lemma:
    73   assumes gt1: "1 < (a::'a::{ordered_semidom,recpower})"
    74   shows "1 < a * a^n"
    75 proof -
    76   have "1*1 < a*1" using gt1 by simp
    77   also have "\<dots> \<le> a * a^n" using gt1
    78     by (simp only: mult_mono gt1_imp_ge0 one_le_power order_less_imp_le
    79         zero_le_one order_refl)
    80   finally show ?thesis by simp
    81 qed
    82 
    83 lemma one_less_power:
    84   "\<lbrakk>1 < (a::'a::{ordered_semidom,recpower}); 0 < n\<rbrakk> \<Longrightarrow> 1 < a ^ n"
    85 by (cases n, simp_all add: power_gt1_lemma power_Suc)
    86 
    87 lemma power_gt1:
    88      "1 < (a::'a::{ordered_semidom,recpower}) ==> 1 < a ^ (Suc n)"
    89 by (simp add: power_gt1_lemma power_Suc)
    90 
    91 lemma power_le_imp_le_exp:
    92   assumes gt1: "(1::'a::{recpower,ordered_semidom}) < a"
    93   shows "!!n. a^m \<le> a^n ==> m \<le> n"
    94 proof (induct m)
    95   case 0
    96   show ?case by simp
    97 next
    98   case (Suc m)
    99   show ?case
   100   proof (cases n)
   101     case 0
   102     from prems have "a * a^m \<le> 1" by (simp add: power_Suc)
   103     with gt1 show ?thesis
   104       by (force simp only: power_gt1_lemma
   105           linorder_not_less [symmetric])
   106   next
   107     case (Suc n)
   108     from prems show ?thesis
   109       by (force dest: mult_left_le_imp_le
   110           simp add: power_Suc order_less_trans [OF zero_less_one gt1])
   111   qed
   112 qed
   113 
   114 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   115 lemma power_inject_exp [simp]:
   116      "1 < (a::'a::{ordered_semidom,recpower}) ==> (a^m = a^n) = (m=n)"
   117   by (force simp add: order_antisym power_le_imp_le_exp)
   118 
   119 text{*Can relax the first premise to @{term "0<a"} in the case of the
   120 natural numbers.*}
   121 lemma power_less_imp_less_exp:
   122      "[| (1::'a::{recpower,ordered_semidom}) < a; a^m < a^n |] ==> m < n"
   123 by (simp add: order_less_le [of m n] order_less_le [of "a^m" "a^n"]
   124               power_le_imp_le_exp)
   125 
   126 
   127 lemma power_mono:
   128      "[|a \<le> b; (0::'a::{recpower,ordered_semidom}) \<le> a|] ==> a^n \<le> b^n"
   129 apply (induct "n")
   130 apply (simp_all add: power_Suc)
   131 apply (auto intro: mult_mono zero_le_power order_trans [of 0 a b])
   132 done
   133 
   134 lemma power_strict_mono [rule_format]:
   135      "[|a < b; (0::'a::{recpower,ordered_semidom}) \<le> a|]
   136       ==> 0 < n --> a^n < b^n"
   137 apply (induct "n")
   138 apply (auto simp add: mult_strict_mono zero_le_power power_Suc
   139                       order_le_less_trans [of 0 a b])
   140 done
   141 
   142 lemma power_eq_0_iff [simp]:
   143      "(a^n = 0) = (a = (0::'a::{ring_1_no_zero_divisors,recpower}) & 0<n)"
   144 apply (induct "n")
   145 apply (auto simp add: power_Suc zero_neq_one [THEN not_sym])
   146 done
   147 
   148 lemma field_power_eq_0_iff:
   149      "(a^n = 0) = (a = (0::'a::{division_ring,recpower}) & 0<n)"
   150 by simp (* TODO: delete *)
   151 
   152 lemma field_power_not_zero: "a \<noteq> (0::'a::{ring_1_no_zero_divisors,recpower}) ==> a^n \<noteq> 0"
   153 by force
   154 
   155 lemma nonzero_power_inverse:
   156   fixes a :: "'a::{division_ring,recpower}"
   157   shows "a \<noteq> 0 ==> inverse (a ^ n) = (inverse a) ^ n"
   158 apply (induct "n")
   159 apply (auto simp add: power_Suc nonzero_inverse_mult_distrib power_commutes)
   160 done (* TODO: reorient or rename to nonzero_inverse_power *)
   161 
   162 text{*Perhaps these should be simprules.*}
   163 lemma power_inverse:
   164   fixes a :: "'a::{division_ring,division_by_zero,recpower}"
   165   shows "inverse (a ^ n) = (inverse a) ^ n"
   166 apply (cases "a = 0")
   167 apply (simp add: power_0_left)
   168 apply (simp add: nonzero_power_inverse)
   169 done (* TODO: reorient or rename to inverse_power *)
   170 
   171 lemma power_one_over: "1 / (a::'a::{field,division_by_zero,recpower})^n = 
   172     (1 / a)^n"
   173 apply (simp add: divide_inverse)
   174 apply (rule power_inverse)
   175 done
   176 
   177 lemma nonzero_power_divide:
   178     "b \<noteq> 0 ==> (a/b) ^ n = ((a::'a::{field,recpower}) ^ n) / (b ^ n)"
   179 by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   180 
   181 lemma power_divide:
   182     "(a/b) ^ n = ((a::'a::{field,division_by_zero,recpower}) ^ n / b ^ n)"
   183 apply (case_tac "b=0", simp add: power_0_left)
   184 apply (rule nonzero_power_divide)
   185 apply assumption
   186 done
   187 
   188 lemma power_abs: "abs(a ^ n) = abs(a::'a::{ordered_idom,recpower}) ^ n"
   189 apply (induct "n")
   190 apply (auto simp add: power_Suc abs_mult)
   191 done
   192 
   193 lemma zero_less_power_abs_iff [simp,noatp]:
   194      "(0 < (abs a)^n) = (a \<noteq> (0::'a::{ordered_idom,recpower}) | n=0)"
   195 proof (induct "n")
   196   case 0
   197     show ?case by (simp add: zero_less_one)
   198 next
   199   case (Suc n)
   200     show ?case by (force simp add: prems power_Suc zero_less_mult_iff)
   201 qed
   202 
   203 lemma zero_le_power_abs [simp]:
   204      "(0::'a::{ordered_idom,recpower}) \<le> (abs a)^n"
   205 by (rule zero_le_power [OF abs_ge_zero])
   206 
   207 lemma power_minus: "(-a) ^ n = (- 1)^n * (a::'a::{comm_ring_1,recpower}) ^ n"
   208 proof -
   209   have "-a = (- 1) * a"  by (simp add: minus_mult_left [symmetric])
   210   thus ?thesis by (simp only: power_mult_distrib)
   211 qed
   212 
   213 text{*Lemma for @{text power_strict_decreasing}*}
   214 lemma power_Suc_less:
   215      "[|(0::'a::{ordered_semidom,recpower}) < a; a < 1|]
   216       ==> a * a^n < a^n"
   217 apply (induct n)
   218 apply (auto simp add: power_Suc mult_strict_left_mono)
   219 done
   220 
   221 lemma power_strict_decreasing:
   222      "[|n < N; 0 < a; a < (1::'a::{ordered_semidom,recpower})|]
   223       ==> a^N < a^n"
   224 apply (erule rev_mp)
   225 apply (induct "N")
   226 apply (auto simp add: power_Suc power_Suc_less less_Suc_eq)
   227 apply (rename_tac m)
   228 apply (subgoal_tac "a * a^m < 1 * a^n", simp)
   229 apply (rule mult_strict_mono)
   230 apply (auto simp add: zero_le_power zero_less_one order_less_imp_le)
   231 done
   232 
   233 text{*Proof resembles that of @{text power_strict_decreasing}*}
   234 lemma power_decreasing:
   235      "[|n \<le> N; 0 \<le> a; a \<le> (1::'a::{ordered_semidom,recpower})|]
   236       ==> a^N \<le> a^n"
   237 apply (erule rev_mp)
   238 apply (induct "N")
   239 apply (auto simp add: power_Suc  le_Suc_eq)
   240 apply (rename_tac m)
   241 apply (subgoal_tac "a * a^m \<le> 1 * a^n", simp)
   242 apply (rule mult_mono)
   243 apply (auto simp add: zero_le_power zero_le_one)
   244 done
   245 
   246 lemma power_Suc_less_one:
   247      "[| 0 < a; a < (1::'a::{ordered_semidom,recpower}) |] ==> a ^ Suc n < 1"
   248 apply (insert power_strict_decreasing [of 0 "Suc n" a], simp)
   249 done
   250 
   251 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   252 lemma power_increasing:
   253      "[|n \<le> N; (1::'a::{ordered_semidom,recpower}) \<le> a|] ==> a^n \<le> a^N"
   254 apply (erule rev_mp)
   255 apply (induct "N")
   256 apply (auto simp add: power_Suc le_Suc_eq)
   257 apply (rename_tac m)
   258 apply (subgoal_tac "1 * a^n \<le> a * a^m", simp)
   259 apply (rule mult_mono)
   260 apply (auto simp add: order_trans [OF zero_le_one] zero_le_power)
   261 done
   262 
   263 text{*Lemma for @{text power_strict_increasing}*}
   264 lemma power_less_power_Suc:
   265      "(1::'a::{ordered_semidom,recpower}) < a ==> a^n < a * a^n"
   266 apply (induct n)
   267 apply (auto simp add: power_Suc mult_strict_left_mono order_less_trans [OF zero_less_one])
   268 done
   269 
   270 lemma power_strict_increasing:
   271      "[|n < N; (1::'a::{ordered_semidom,recpower}) < a|] ==> a^n < a^N"
   272 apply (erule rev_mp)
   273 apply (induct "N")
   274 apply (auto simp add: power_less_power_Suc power_Suc less_Suc_eq)
   275 apply (rename_tac m)
   276 apply (subgoal_tac "1 * a^n < a * a^m", simp)
   277 apply (rule mult_strict_mono)
   278 apply (auto simp add: order_less_trans [OF zero_less_one] zero_le_power
   279                  order_less_imp_le)
   280 done
   281 
   282 lemma power_increasing_iff [simp]: 
   283      "1 < (b::'a::{ordered_semidom,recpower}) ==> (b ^ x \<le> b ^ y) = (x \<le> y)"
   284   by (blast intro: power_le_imp_le_exp power_increasing order_less_imp_le) 
   285 
   286 lemma power_strict_increasing_iff [simp]:
   287      "1 < (b::'a::{ordered_semidom,recpower}) ==> (b ^ x < b ^ y) = (x < y)"
   288   by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   289 
   290 lemma power_le_imp_le_base:
   291   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   292       and ynonneg: "(0::'a::{ordered_semidom,recpower}) \<le> b"
   293   shows "a \<le> b"
   294  proof (rule ccontr)
   295    assume "~ a \<le> b"
   296    then have "b < a" by (simp only: linorder_not_le)
   297    then have "b ^ Suc n < a ^ Suc n"
   298      by (simp only: prems power_strict_mono)
   299    from le and this show "False"
   300       by (simp add: linorder_not_less [symmetric])
   301  qed
   302 
   303 lemma power_less_imp_less_base:
   304   fixes a b :: "'a::{ordered_semidom,recpower}"
   305   assumes less: "a ^ n < b ^ n"
   306   assumes nonneg: "0 \<le> b"
   307   shows "a < b"
   308 proof (rule contrapos_pp [OF less])
   309   assume "~ a < b"
   310   hence "b \<le> a" by (simp only: linorder_not_less)
   311   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   312   thus "~ a ^ n < b ^ n" by (simp only: linorder_not_less)
   313 qed
   314 
   315 lemma power_inject_base:
   316      "[| a ^ Suc n = b ^ Suc n; 0 \<le> a; 0 \<le> b |]
   317       ==> a = (b::'a::{ordered_semidom,recpower})"
   318 by (blast intro: power_le_imp_le_base order_antisym order_eq_refl sym)
   319 
   320 lemma power_eq_imp_eq_base:
   321   fixes a b :: "'a::{ordered_semidom,recpower}"
   322   shows "\<lbrakk>a ^ n = b ^ n; 0 \<le> a; 0 \<le> b; 0 < n\<rbrakk> \<Longrightarrow> a = b"
   323 by (cases n, simp_all, rule power_inject_base)
   324 
   325 
   326 subsection{*Exponentiation for the Natural Numbers*}
   327 
   328 instance nat :: power ..
   329 
   330 primrec (power)
   331   "p ^ 0 = 1"
   332   "p ^ (Suc n) = (p::nat) * (p ^ n)"
   333 
   334 instance nat :: recpower
   335 proof
   336   fix z n :: nat
   337   show "z^0 = 1" by simp
   338   show "z^(Suc n) = z * (z^n)" by simp
   339 qed
   340 
   341 lemma of_nat_power:
   342   "of_nat (m ^ n) = (of_nat m::'a::{semiring_1,recpower}) ^ n"
   343 by (induct n, simp_all add: power_Suc of_nat_mult)
   344 
   345 lemma nat_one_le_power [simp]: "1 \<le> i ==> Suc 0 \<le> i^n"
   346 by (insert one_le_power [of i n], simp)
   347 
   348 lemma nat_zero_less_power_iff [simp]: "(0 < x^n) = (x \<noteq> (0::nat) | n=0)"
   349 by (induct "n", auto)
   350 
   351 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   352 Premises cannot be weakened: consider the case where @{term "i=0"},
   353 @{term "m=1"} and @{term "n=0"}.*}
   354 lemma nat_power_less_imp_less:
   355   assumes nonneg: "0 < (i\<Colon>nat)"
   356   assumes less: "i^m < i^n"
   357   shows "m < n"
   358 proof (cases "i = 1")
   359   case True with less power_one [where 'a = nat] show ?thesis by simp
   360 next
   361   case False with nonneg have "1 < i" by auto
   362   from power_strict_increasing_iff [OF this] less show ?thesis ..
   363 qed
   364 
   365 lemma power_diff:
   366   assumes nz: "a ~= 0"
   367   shows "n <= m ==> (a::'a::{recpower, field}) ^ (m-n) = (a^m) / (a^n)"
   368   by (induct m n rule: diff_induct)
   369     (simp_all add: power_Suc nonzero_mult_divide_cancel_left nz)
   370 
   371 
   372 text{*ML bindings for the general exponentiation theorems*}
   373 ML
   374 {*
   375 val power_0 = thm"power_0";
   376 val power_Suc = thm"power_Suc";
   377 val power_0_Suc = thm"power_0_Suc";
   378 val power_0_left = thm"power_0_left";
   379 val power_one = thm"power_one";
   380 val power_one_right = thm"power_one_right";
   381 val power_add = thm"power_add";
   382 val power_mult = thm"power_mult";
   383 val power_mult_distrib = thm"power_mult_distrib";
   384 val zero_less_power = thm"zero_less_power";
   385 val zero_le_power = thm"zero_le_power";
   386 val one_le_power = thm"one_le_power";
   387 val gt1_imp_ge0 = thm"gt1_imp_ge0";
   388 val power_gt1_lemma = thm"power_gt1_lemma";
   389 val power_gt1 = thm"power_gt1";
   390 val power_le_imp_le_exp = thm"power_le_imp_le_exp";
   391 val power_inject_exp = thm"power_inject_exp";
   392 val power_less_imp_less_exp = thm"power_less_imp_less_exp";
   393 val power_mono = thm"power_mono";
   394 val power_strict_mono = thm"power_strict_mono";
   395 val power_eq_0_iff = thm"power_eq_0_iff";
   396 val field_power_eq_0_iff = thm"field_power_eq_0_iff";
   397 val field_power_not_zero = thm"field_power_not_zero";
   398 val power_inverse = thm"power_inverse";
   399 val nonzero_power_divide = thm"nonzero_power_divide";
   400 val power_divide = thm"power_divide";
   401 val power_abs = thm"power_abs";
   402 val zero_less_power_abs_iff = thm"zero_less_power_abs_iff";
   403 val zero_le_power_abs = thm "zero_le_power_abs";
   404 val power_minus = thm"power_minus";
   405 val power_Suc_less = thm"power_Suc_less";
   406 val power_strict_decreasing = thm"power_strict_decreasing";
   407 val power_decreasing = thm"power_decreasing";
   408 val power_Suc_less_one = thm"power_Suc_less_one";
   409 val power_increasing = thm"power_increasing";
   410 val power_strict_increasing = thm"power_strict_increasing";
   411 val power_le_imp_le_base = thm"power_le_imp_le_base";
   412 val power_inject_base = thm"power_inject_base";
   413 *}
   414 
   415 text{*ML bindings for the remaining theorems*}
   416 ML
   417 {*
   418 val nat_one_le_power = thm"nat_one_le_power";
   419 val nat_power_less_imp_less = thm"nat_power_less_imp_less";
   420 val nat_zero_less_power_iff = thm"nat_zero_less_power_iff";
   421 *}
   422 
   423 end
   424