src/ZF/Constructible/Datatype_absolute.thy
author paulson
Thu Jul 25 10:56:35 2002 +0200 (2002-07-25)
changeset 13422 af9bc8d87a75
parent 13418 7c0ba9dba978
child 13423 7ec771711c09
permissions -rw-r--r--
Added the assumption nth_replacement to locale M_datatypes.
Moved up its proof to make it available for the instantiation of that locale.
     1 header {*Absoluteness Properties for Recursive Datatypes*}
     2 
     3 theory Datatype_absolute = Formula + WF_absolute:
     4 
     5 
     6 subsection{*The lfp of a continuous function can be expressed as a union*}
     7 
     8 constdefs
     9   directed :: "i=>o"
    10    "directed(A) == A\<noteq>0 & (\<forall>x\<in>A. \<forall>y\<in>A. x \<union> y \<in> A)"
    11 
    12   contin :: "(i=>i) => o"
    13    "contin(h) == (\<forall>A. directed(A) --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    14 
    15 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    16 apply (induct_tac n) 
    17  apply (simp_all add: bnd_mono_def, blast) 
    18 done
    19 
    20 lemma bnd_mono_increasing [rule_format]:
    21      "[|i \<in> nat; j \<in> nat; bnd_mono(D,h)|] ==> i \<le> j --> h^i(0) \<subseteq> h^j(0)"
    22 apply (rule_tac m=i and n=j in diff_induct, simp_all)
    23 apply (blast del: subsetI
    24 	     intro: bnd_mono_iterates_subset bnd_monoD2 [of concl: h]) 
    25 done
    26 
    27 lemma directed_iterates: "bnd_mono(D,h) ==> directed({h^n (0). n\<in>nat})"
    28 apply (simp add: directed_def, clarify) 
    29 apply (rename_tac i j)
    30 apply (rule_tac x="i \<union> j" in bexI) 
    31 apply (rule_tac i = i and j = j in Ord_linear_le)
    32 apply (simp_all add: subset_Un_iff [THEN iffD1] le_imp_subset
    33                      subset_Un_iff2 [THEN iffD1])
    34 apply (simp_all add: subset_Un_iff [THEN iff_sym] bnd_mono_increasing
    35                      subset_Un_iff2 [THEN iff_sym])
    36 done
    37 
    38 
    39 lemma contin_iterates_eq: 
    40     "[|bnd_mono(D, h); contin(h)|] 
    41      ==> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    42 apply (simp add: contin_def directed_iterates) 
    43 apply (rule trans) 
    44 apply (rule equalityI) 
    45  apply (simp_all add: UN_subset_iff)
    46  apply safe
    47  apply (erule_tac [2] natE) 
    48   apply (rule_tac a="succ(x)" in UN_I) 
    49    apply simp_all 
    50 apply blast 
    51 done
    52 
    53 lemma lfp_subset_Union:
    54      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    55 apply (rule lfp_lowerbound) 
    56  apply (simp add: contin_iterates_eq) 
    57 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    58 done
    59 
    60 lemma Union_subset_lfp:
    61      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    62 apply (simp add: UN_subset_iff)
    63 apply (rule ballI)  
    64 apply (induct_tac n, simp_all) 
    65 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    66  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset])  
    67 apply (erule lfp_lemma2) 
    68 done
    69 
    70 lemma lfp_eq_Union:
    71      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    72 by (blast del: subsetI 
    73           intro: lfp_subset_Union Union_subset_lfp)
    74 
    75 
    76 subsubsection{*Some Standard Datatype Constructions Preserve Continuity*}
    77 
    78 lemma contin_imp_mono: "[|X\<subseteq>Y; contin(F)|] ==> F(X) \<subseteq> F(Y)"
    79 apply (simp add: contin_def) 
    80 apply (drule_tac x="{X,Y}" in spec) 
    81 apply (simp add: directed_def subset_Un_iff2 Un_commute) 
    82 done
    83 
    84 lemma sum_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) + G(X))"
    85 by (simp add: contin_def, blast)
    86 
    87 lemma prod_contin: "[|contin(F); contin(G)|] ==> contin(\<lambda>X. F(X) * G(X))" 
    88 apply (subgoal_tac "\<forall>B C. F(B) \<subseteq> F(B \<union> C)")
    89  prefer 2 apply (simp add: Un_upper1 contin_imp_mono) 
    90 apply (subgoal_tac "\<forall>B C. G(C) \<subseteq> G(B \<union> C)")
    91  prefer 2 apply (simp add: Un_upper2 contin_imp_mono) 
    92 apply (simp add: contin_def, clarify) 
    93 apply (rule equalityI) 
    94  prefer 2 apply blast 
    95 apply clarify 
    96 apply (rename_tac B C) 
    97 apply (rule_tac a="B \<union> C" in UN_I) 
    98  apply (simp add: directed_def, blast)  
    99 done
   100 
   101 lemma const_contin: "contin(\<lambda>X. A)"
   102 by (simp add: contin_def directed_def)
   103 
   104 lemma id_contin: "contin(\<lambda>X. X)"
   105 by (simp add: contin_def)
   106 
   107 
   108 
   109 subsection {*Absoluteness for "Iterates"*}
   110 
   111 constdefs
   112 
   113   iterates_MH :: "[i=>o, [i,i]=>o, i, i, i, i] => o"
   114    "iterates_MH(M,isF,v,n,g,z) ==
   115         is_nat_case(M, v, \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & isF(gm,u),
   116                     n, z)"
   117 
   118   iterates_replacement :: "[i=>o, [i,i]=>o, i] => o"
   119    "iterates_replacement(M,isF,v) ==
   120       \<forall>n[M]. n\<in>nat --> 
   121          wfrec_replacement(M, iterates_MH(M,isF,v), Memrel(succ(n)))"
   122 
   123 lemma (in M_axioms) iterates_MH_abs:
   124   "[| relativize1(M,isF,F); M(n); M(g); M(z) |] 
   125    ==> iterates_MH(M,isF,v,n,g,z) <-> z = nat_case(v, \<lambda>m. F(g`m), n)"
   126 by (simp add: nat_case_abs [of _ "\<lambda>m. F(g ` m)"]
   127               relativize1_def iterates_MH_def)  
   128 
   129 lemma (in M_axioms) iterates_imp_wfrec_replacement:
   130   "[|relativize1(M,isF,F); n \<in> nat; iterates_replacement(M,isF,v)|] 
   131    ==> wfrec_replacement(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   132                        Memrel(succ(n)))" 
   133 by (simp add: iterates_replacement_def iterates_MH_abs)
   134 
   135 theorem (in M_trancl) iterates_abs:
   136   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   137       n \<in> nat; M(v); M(z); \<forall>x[M]. M(F(x)) |] 
   138    ==> is_wfrec(M, iterates_MH(M,isF,v), Memrel(succ(n)), n, z) <->
   139        z = iterates(F,n,v)" 
   140 apply (frule iterates_imp_wfrec_replacement, assumption+)
   141 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   142                  relativize2_def iterates_MH_abs 
   143                  iterates_nat_def recursor_def transrec_def 
   144                  eclose_sing_Ord_eq nat_into_M
   145          trans_wfrec_abs [of _ _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   146 done
   147 
   148 
   149 lemma (in M_wfrank) iterates_closed [intro,simp]:
   150   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   151       n \<in> nat; M(v); \<forall>x[M]. M(F(x)) |] 
   152    ==> M(iterates(F,n,v))"
   153 apply (frule iterates_imp_wfrec_replacement, assumption+)
   154 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   155                  relativize2_def iterates_MH_abs 
   156                  iterates_nat_def recursor_def transrec_def 
   157                  eclose_sing_Ord_eq nat_into_M
   158          trans_wfrec_closed [of _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   159 done
   160 
   161 
   162 subsection {*lists without univ*}
   163 
   164 lemmas datatype_univs = Inl_in_univ Inr_in_univ 
   165                         Pair_in_univ nat_into_univ A_into_univ 
   166 
   167 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
   168 apply (rule bnd_monoI)
   169  apply (intro subset_refl zero_subset_univ A_subset_univ 
   170 	      sum_subset_univ Sigma_subset_univ) 
   171 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   172 done
   173 
   174 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
   175 by (intro sum_contin prod_contin id_contin const_contin) 
   176 
   177 text{*Re-expresses lists using sum and product*}
   178 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
   179 apply (simp add: list_def) 
   180 apply (rule equalityI) 
   181  apply (rule lfp_lowerbound) 
   182   prefer 2 apply (rule lfp_subset)
   183  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
   184  apply (simp add: Nil_def Cons_def)
   185  apply blast 
   186 txt{*Opposite inclusion*}
   187 apply (rule lfp_lowerbound) 
   188  prefer 2 apply (rule lfp_subset) 
   189 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
   190 apply (simp add: Nil_def Cons_def)
   191 apply (blast intro: datatype_univs
   192              dest: lfp_subset [THEN subsetD])
   193 done
   194 
   195 text{*Re-expresses lists using "iterates", no univ.*}
   196 lemma list_eq_Union:
   197      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
   198 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
   199 
   200 
   201 constdefs
   202   is_list_functor :: "[i=>o,i,i,i] => o"
   203     "is_list_functor(M,A,X,Z) == 
   204         \<exists>n1[M]. \<exists>AX[M]. 
   205          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   206 
   207 lemma (in M_axioms) list_functor_abs [simp]: 
   208      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   209 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   210 
   211 
   212 subsection {*formulas without univ*}
   213 
   214 lemma formula_fun_bnd_mono:
   215      "bnd_mono(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   216 apply (rule bnd_monoI)
   217  apply (intro subset_refl zero_subset_univ A_subset_univ 
   218 	      sum_subset_univ Sigma_subset_univ nat_subset_univ) 
   219 apply (rule subset_refl sum_mono Sigma_mono | assumption)+
   220 done
   221 
   222 lemma formula_fun_contin:
   223      "contin(\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   224 by (intro sum_contin prod_contin id_contin const_contin) 
   225 
   226 
   227 text{*Re-expresses formulas using sum and product*}
   228 lemma formula_eq_lfp2:
   229     "formula = lfp(univ(0), \<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))"
   230 apply (simp add: formula_def) 
   231 apply (rule equalityI) 
   232  apply (rule lfp_lowerbound) 
   233   prefer 2 apply (rule lfp_subset)
   234  apply (clarify, subst lfp_unfold [OF formula_fun_bnd_mono])
   235  apply (simp add: Member_def Equal_def Nand_def Forall_def)
   236  apply blast 
   237 txt{*Opposite inclusion*}
   238 apply (rule lfp_lowerbound) 
   239  prefer 2 apply (rule lfp_subset, clarify) 
   240 apply (subst lfp_unfold [OF formula.bnd_mono, simplified]) 
   241 apply (simp add: Member_def Equal_def Nand_def Forall_def)  
   242 apply (elim sumE SigmaE, simp_all) 
   243 apply (blast intro: datatype_univs dest: lfp_subset [THEN subsetD])+  
   244 done
   245 
   246 text{*Re-expresses formulas using "iterates", no univ.*}
   247 lemma formula_eq_Union:
   248      "formula = 
   249       (\<Union>n\<in>nat. (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0))"
   250 by (simp add: formula_eq_lfp2 lfp_eq_Union formula_fun_bnd_mono 
   251               formula_fun_contin)
   252 
   253 
   254 constdefs
   255   is_formula_functor :: "[i=>o,i,i] => o"
   256     "is_formula_functor(M,X,Z) == 
   257         \<exists>nat'[M]. \<exists>natnat[M]. \<exists>natnatsum[M]. \<exists>XX[M]. \<exists>X3[M]. 
   258           omega(M,nat') & cartprod(M,nat',nat',natnat) & 
   259           is_sum(M,natnat,natnat,natnatsum) &
   260           cartprod(M,X,X,XX) & is_sum(M,XX,X,X3) & 
   261           is_sum(M,natnatsum,X3,Z)"
   262 
   263 lemma (in M_axioms) formula_functor_abs [simp]: 
   264      "[| M(X); M(Z) |] 
   265       ==> is_formula_functor(M,X,Z) <-> 
   266           Z = ((nat*nat) + (nat*nat)) + (X*X + X)"
   267 by (simp add: is_formula_functor_def) 
   268 
   269 
   270 subsection{*@{term M} Contains the List and Formula Datatypes*}
   271 
   272 constdefs
   273   list_N :: "[i,i] => i"
   274     "list_N(A,n) == (\<lambda>X. {0} + A * X)^n (0)"
   275 
   276 lemma Nil_in_list_N [simp]: "[] \<in> list_N(A,succ(n))"
   277 by (simp add: list_N_def Nil_def)
   278 
   279 lemma Cons_in_list_N [simp]:
   280      "Cons(a,l) \<in> list_N(A,succ(n)) <-> a\<in>A & l \<in> list_N(A,n)"
   281 by (simp add: list_N_def Cons_def) 
   282 
   283 text{*These two aren't simprules because they reveal the underlying
   284 list representation.*}
   285 lemma list_N_0: "list_N(A,0) = 0"
   286 by (simp add: list_N_def)
   287 
   288 lemma list_N_succ: "list_N(A,succ(n)) = {0} + A * (list_N(A,n))"
   289 by (simp add: list_N_def)
   290 
   291 lemma list_N_imp_list:
   292   "[| l \<in> list_N(A,n); n \<in> nat |] ==> l \<in> list(A)"
   293 by (force simp add: list_eq_Union list_N_def)
   294 
   295 lemma list_N_imp_length_lt [rule_format]:
   296      "n \<in> nat ==> \<forall>l \<in> list_N(A,n). length(l) < n"
   297 apply (induct_tac n)  
   298 apply (auto simp add: list_N_0 list_N_succ 
   299                       Nil_def [symmetric] Cons_def [symmetric]) 
   300 done
   301 
   302 lemma list_imp_list_N [rule_format]:
   303      "l \<in> list(A) ==> \<forall>n\<in>nat. length(l) < n --> l \<in> list_N(A, n)"
   304 apply (induct_tac l)
   305 apply (force elim: natE)+
   306 done
   307 
   308 lemma list_N_imp_eq_length:
   309       "[|n \<in> nat; l \<notin> list_N(A, n); l \<in> list_N(A, succ(n))|] 
   310        ==> n = length(l)"
   311 apply (rule le_anti_sym) 
   312  prefer 2 apply (simp add: list_N_imp_length_lt) 
   313 apply (frule list_N_imp_list, simp)
   314 apply (simp add: not_lt_iff_le [symmetric]) 
   315 apply (blast intro: list_imp_list_N) 
   316 done
   317   
   318 text{*Express @{term list_rec} without using @{term rank} or @{term Vset},
   319 neither of which is absolute.*}
   320 lemma (in M_triv_axioms) list_rec_eq:
   321   "l \<in> list(A) ==>
   322    list_rec(a,g,l) = 
   323    transrec (succ(length(l)),
   324       \<lambda>x h. Lambda (list(A),
   325                     list_case' (a, 
   326                            \<lambda>a l. g(a, l, h ` succ(length(l)) ` l)))) ` l"
   327 apply (induct_tac l) 
   328 apply (subst transrec, simp) 
   329 apply (subst transrec) 
   330 apply (simp add: list_imp_list_N) 
   331 done
   332 
   333 constdefs
   334   is_list_N :: "[i=>o,i,i,i] => o"
   335     "is_list_N(M,A,n,Z) == 
   336       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   337        empty(M,zero) & 
   338        successor(M,n,sn) & membership(M,sn,msn) &
   339        is_wfrec(M, iterates_MH(M, is_list_functor(M,A),zero), msn, n, Z)"
   340   
   341   mem_list :: "[i=>o,i,i] => o"
   342     "mem_list(M,A,l) == 
   343       \<exists>n[M]. \<exists>listn[M]. 
   344        finite_ordinal(M,n) & is_list_N(M,A,n,listn) & l \<in> listn"
   345 
   346   is_list :: "[i=>o,i,i] => o"
   347     "is_list(M,A,Z) == \<forall>l[M]. l \<in> Z <-> mem_list(M,A,l)"
   348 
   349 constdefs
   350   is_formula_n :: "[i=>o,i,i] => o"
   351     "is_formula_n(M,n,Z) == 
   352       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   353        empty(M,zero) & 
   354        successor(M,n,sn) & membership(M,sn,msn) &
   355        is_wfrec(M, iterates_MH(M, is_formula_functor(M),zero), msn, n, Z)"
   356   
   357   mem_formula :: "[i=>o,i] => o"
   358     "mem_formula(M,p) == 
   359       \<exists>n[M]. \<exists>formn[M]. 
   360        finite_ordinal(M,n) & is_formula_n(M,n,formn) & p \<in> formn"
   361 
   362   is_formula :: "[i=>o,i] => o"
   363     "is_formula(M,Z) == \<forall>p[M]. p \<in> Z <-> mem_formula(M,p)"
   364 
   365 locale (open) M_datatypes = M_wfrank +
   366  assumes list_replacement1: 
   367    "M(A) ==> iterates_replacement(M, is_list_functor(M,A), 0)"
   368   and list_replacement2: 
   369    "M(A) ==> strong_replacement(M, 
   370          \<lambda>n y. n\<in>nat & 
   371                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   372                is_wfrec(M, iterates_MH(M,is_list_functor(M,A), 0), 
   373                         msn, n, y)))"
   374   and formula_replacement1: 
   375    "iterates_replacement(M, is_formula_functor(M), 0)"
   376   and formula_replacement2: 
   377    "strong_replacement(M, 
   378          \<lambda>n y. n\<in>nat & 
   379                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   380                is_wfrec(M, iterates_MH(M,is_formula_functor(M), 0), 
   381                         msn, n, y)))"
   382   and nth_replacement:
   383    "M(l) ==> iterates_replacement(M, %l t. is_tl(M,l,t), l)"
   384         
   385 
   386 subsubsection{*Absoluteness of the List Construction*}
   387 
   388 lemma (in M_datatypes) list_replacement2': 
   389   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. {0} + A * X)^n (0))"
   390 apply (insert list_replacement2 [of A]) 
   391 apply (rule strong_replacement_cong [THEN iffD1])  
   392 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_list_functor(M,A)"]]) 
   393 apply (simp_all add: list_replacement1 relativize1_def) 
   394 done
   395 
   396 lemma (in M_datatypes) list_closed [intro,simp]:
   397      "M(A) ==> M(list(A))"
   398 apply (insert list_replacement1)
   399 by  (simp add: RepFun_closed2 list_eq_Union 
   400                list_replacement2' relativize1_def
   401                iterates_closed [of "is_list_functor(M,A)"])
   402 
   403 lemma (in M_datatypes) list_N_abs [simp]:
   404      "[|M(A); n\<in>nat; M(Z)|] 
   405       ==> is_list_N(M,A,n,Z) <-> Z = list_N(A,n)"
   406 apply (insert list_replacement1)
   407 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   408                  iterates_abs [of "is_list_functor(M,A)" _ "\<lambda>X. {0} + A*X"])
   409 done
   410 
   411 lemma (in M_datatypes) list_N_closed [intro,simp]:
   412      "[|M(A); n\<in>nat|] ==> M(list_N(A,n))"
   413 apply (insert list_replacement1)
   414 apply (simp add: is_list_N_def list_N_def relativize1_def nat_into_M
   415                  iterates_closed [of "is_list_functor(M,A)"])
   416 done
   417 
   418 lemma (in M_datatypes) mem_list_abs [simp]:
   419      "M(A) ==> mem_list(M,A,l) <-> l \<in> list(A)"
   420 apply (insert list_replacement1)
   421 apply (simp add: mem_list_def list_N_def relativize1_def list_eq_Union
   422                  iterates_closed [of "is_list_functor(M,A)"]) 
   423 done
   424 
   425 lemma (in M_datatypes) list_abs [simp]:
   426      "[|M(A); M(Z)|] ==> is_list(M,A,Z) <-> Z = list(A)"
   427 apply (simp add: is_list_def, safe)
   428 apply (rule M_equalityI, simp_all)
   429 done
   430 
   431 subsubsection{*Absoluteness of Formulas*}
   432 
   433 lemma (in M_datatypes) formula_replacement2': 
   434   "strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))^n (0))"
   435 apply (insert formula_replacement2) 
   436 apply (rule strong_replacement_cong [THEN iffD1])  
   437 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_formula_functor(M)"]]) 
   438 apply (simp_all add: formula_replacement1 relativize1_def) 
   439 done
   440 
   441 lemma (in M_datatypes) formula_closed [intro,simp]:
   442      "M(formula)"
   443 apply (insert formula_replacement1)
   444 apply  (simp add: RepFun_closed2 formula_eq_Union 
   445                   formula_replacement2' relativize1_def
   446                   iterates_closed [of "is_formula_functor(M)"])
   447 done
   448 
   449 lemma (in M_datatypes) is_formula_n_abs [simp]:
   450      "[|n\<in>nat; M(Z)|] 
   451       ==> is_formula_n(M,n,Z) <-> 
   452           Z = (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X))^n (0)"
   453 apply (insert formula_replacement1)
   454 apply (simp add: is_formula_n_def relativize1_def nat_into_M
   455                  iterates_abs [of "is_formula_functor(M)" _ 
   456                         "\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)"])
   457 done
   458 
   459 lemma (in M_datatypes) mem_formula_abs [simp]:
   460      "mem_formula(M,l) <-> l \<in> formula"
   461 apply (insert formula_replacement1)
   462 apply (simp add: mem_formula_def relativize1_def formula_eq_Union
   463                  iterates_closed [of "is_formula_functor(M)"]) 
   464 done
   465 
   466 lemma (in M_datatypes) formula_abs [simp]:
   467      "[|M(Z)|] ==> is_formula(M,Z) <-> Z = formula"
   468 apply (simp add: is_formula_def, safe)
   469 apply (rule M_equalityI, simp_all)
   470 done
   471 
   472 
   473 subsection{*Absoluteness for Some List Operators*}
   474 
   475 subsection{*Absoluteness for @{text \<epsilon>}-Closure: the @{term eclose} Operator*}
   476 
   477 text{*Re-expresses eclose using "iterates"*}
   478 lemma eclose_eq_Union:
   479      "eclose(A) = (\<Union>n\<in>nat. Union^n (A))"
   480 apply (simp add: eclose_def) 
   481 apply (rule UN_cong) 
   482 apply (rule refl)
   483 apply (induct_tac n)
   484 apply (simp add: nat_rec_0)  
   485 apply (simp add: nat_rec_succ) 
   486 done
   487 
   488 constdefs
   489   is_eclose_n :: "[i=>o,i,i,i] => o"
   490     "is_eclose_n(M,A,n,Z) == 
   491       \<exists>sn[M]. \<exists>msn[M]. 
   492        successor(M,n,sn) & membership(M,sn,msn) &
   493        is_wfrec(M, iterates_MH(M, big_union(M), A), msn, n, Z)"
   494   
   495   mem_eclose :: "[i=>o,i,i] => o"
   496     "mem_eclose(M,A,l) == 
   497       \<exists>n[M]. \<exists>eclosen[M]. 
   498        finite_ordinal(M,n) & is_eclose_n(M,A,n,eclosen) & l \<in> eclosen"
   499 
   500   is_eclose :: "[i=>o,i,i] => o"
   501     "is_eclose(M,A,Z) == \<forall>u[M]. u \<in> Z <-> mem_eclose(M,A,u)"
   502 
   503 
   504 locale (open) M_eclose = M_datatypes +
   505  assumes eclose_replacement1: 
   506    "M(A) ==> iterates_replacement(M, big_union(M), A)"
   507   and eclose_replacement2: 
   508    "M(A) ==> strong_replacement(M, 
   509          \<lambda>n y. n\<in>nat & 
   510                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   511                is_wfrec(M, iterates_MH(M,big_union(M), A), 
   512                         msn, n, y)))"
   513 
   514 lemma (in M_eclose) eclose_replacement2': 
   515   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = Union^n (A))"
   516 apply (insert eclose_replacement2 [of A]) 
   517 apply (rule strong_replacement_cong [THEN iffD1])  
   518 apply (rule conj_cong [OF iff_refl iterates_abs [of "big_union(M)"]]) 
   519 apply (simp_all add: eclose_replacement1 relativize1_def) 
   520 done
   521 
   522 lemma (in M_eclose) eclose_closed [intro,simp]:
   523      "M(A) ==> M(eclose(A))"
   524 apply (insert eclose_replacement1)
   525 by  (simp add: RepFun_closed2 eclose_eq_Union 
   526                eclose_replacement2' relativize1_def
   527                iterates_closed [of "big_union(M)"])
   528 
   529 lemma (in M_eclose) is_eclose_n_abs [simp]:
   530      "[|M(A); n\<in>nat; M(Z)|] ==> is_eclose_n(M,A,n,Z) <-> Z = Union^n (A)"
   531 apply (insert eclose_replacement1)
   532 apply (simp add: is_eclose_n_def relativize1_def nat_into_M
   533                  iterates_abs [of "big_union(M)" _ "Union"])
   534 done
   535 
   536 lemma (in M_eclose) mem_eclose_abs [simp]:
   537      "M(A) ==> mem_eclose(M,A,l) <-> l \<in> eclose(A)"
   538 apply (insert eclose_replacement1)
   539 apply (simp add: mem_eclose_def relativize1_def eclose_eq_Union
   540                  iterates_closed [of "big_union(M)"]) 
   541 done
   542 
   543 lemma (in M_eclose) eclose_abs [simp]:
   544      "[|M(A); M(Z)|] ==> is_eclose(M,A,Z) <-> Z = eclose(A)"
   545 apply (simp add: is_eclose_def, safe)
   546 apply (rule M_equalityI, simp_all)
   547 done
   548 
   549 
   550 
   551 
   552 subsection {*Absoluteness for @{term transrec}*}
   553 
   554 
   555 text{* @{term "transrec(a,H) \<equiv> wfrec(Memrel(eclose({a})), a, H)"} *}
   556 constdefs
   557 
   558   is_transrec :: "[i=>o, [i,i,i]=>o, i, i] => o"
   559    "is_transrec(M,MH,a,z) == 
   560       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   561        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   562        is_wfrec(M,MH,mesa,a,z)"
   563 
   564   transrec_replacement :: "[i=>o, [i,i,i]=>o, i] => o"
   565    "transrec_replacement(M,MH,a) ==
   566       \<exists>sa[M]. \<exists>esa[M]. \<exists>mesa[M]. 
   567        upair(M,a,a,sa) & is_eclose(M,sa,esa) & membership(M,esa,mesa) &
   568        wfrec_replacement(M,MH,mesa)"
   569 
   570 text{*The condition @{term "Ord(i)"} lets us use the simpler 
   571   @{text "trans_wfrec_abs"} rather than @{text "trans_wfrec_abs"},
   572   which I haven't even proved yet. *}
   573 theorem (in M_eclose) transrec_abs:
   574   "[|transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   575      Ord(i);  M(i);  M(z);
   576      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   577    ==> is_transrec(M,MH,i,z) <-> z = transrec(i,H)" 
   578 apply (rotate_tac 2) 
   579 apply (simp add: trans_wfrec_abs transrec_replacement_def is_transrec_def
   580        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   581 done
   582 
   583 
   584 theorem (in M_eclose) transrec_closed:
   585      "[|transrec_replacement(M,MH,i);  relativize2(M,MH,H);
   586 	Ord(i);  M(i);  
   587 	\<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   588       ==> M(transrec(i,H))"
   589 apply (rotate_tac 2) 
   590 apply (simp add: trans_wfrec_closed transrec_replacement_def is_transrec_def
   591        transrec_def eclose_sing_Ord_eq wf_Memrel trans_Memrel relation_Memrel)
   592 done
   593 
   594 
   595 subsection{*Absoluteness for the List Operator @{term length}*}
   596 constdefs
   597 
   598   is_length :: "[i=>o,i,i,i] => o"
   599     "is_length(M,A,l,n) == 
   600        \<exists>sn[M]. \<exists>list_n[M]. \<exists>list_sn[M]. 
   601         is_list_N(M,A,n,list_n) & l \<notin> list_n &
   602         successor(M,n,sn) & is_list_N(M,A,sn,list_sn) & l \<in> list_sn"
   603 
   604 
   605 lemma (in M_datatypes) length_abs [simp]:
   606      "[|M(A); l \<in> list(A); n \<in> nat|] ==> is_length(M,A,l,n) <-> n = length(l)"
   607 apply (subgoal_tac "M(l) & M(n)")
   608  prefer 2 apply (blast dest: transM)  
   609 apply (simp add: is_length_def)
   610 apply (blast intro: list_imp_list_N nat_into_Ord list_N_imp_eq_length
   611              dest: list_N_imp_length_lt)
   612 done
   613 
   614 text{*Proof is trivial since @{term length} returns natural numbers.*}
   615 lemma (in M_triv_axioms) length_closed [intro,simp]:
   616      "l \<in> list(A) ==> M(length(l))"
   617 by (simp add: nat_into_M) 
   618 
   619 
   620 subsection {*Absoluteness for @{term nth}*}
   621 
   622 lemma nth_eq_hd_iterates_tl [rule_format]:
   623      "xs \<in> list(A) ==> \<forall>n \<in> nat. nth(n,xs) = hd' (tl'^n (xs))"
   624 apply (induct_tac xs) 
   625 apply (simp add: iterates_tl_Nil hd'_Nil, clarify) 
   626 apply (erule natE)
   627 apply (simp add: hd'_Cons) 
   628 apply (simp add: tl'_Cons iterates_commute) 
   629 done
   630 
   631 lemma (in M_axioms) iterates_tl'_closed:
   632      "[|n \<in> nat; M(x)|] ==> M(tl'^n (x))"
   633 apply (induct_tac n, simp) 
   634 apply (simp add: tl'_Cons tl'_closed) 
   635 done
   636 
   637 text{*Immediate by type-checking*}
   638 lemma (in M_datatypes) nth_closed [intro,simp]:
   639      "[|xs \<in> list(A); n \<in> nat; M(A)|] ==> M(nth(n,xs))" 
   640 apply (case_tac "n < length(xs)")
   641  apply (blast intro: nth_type transM)
   642 apply (simp add: not_lt_iff_le nth_eq_0)
   643 done
   644 
   645 constdefs
   646   is_nth :: "[i=>o,i,i,i] => o"
   647     "is_nth(M,n,l,Z) == 
   648       \<exists>X[M]. \<exists>sn[M]. \<exists>msn[M]. 
   649        successor(M,n,sn) & membership(M,sn,msn) &
   650        is_wfrec(M, iterates_MH(M, is_tl(M), l), msn, n, X) &
   651        is_hd(M,X,Z)"
   652  
   653 lemma (in M_datatypes) nth_abs [simp]:
   654      "[|M(A); n \<in> nat; l \<in> list(A); M(Z)|] 
   655       ==> is_nth(M,n,l,Z) <-> Z = nth(n,l)"
   656 apply (subgoal_tac "M(l)") 
   657  prefer 2 apply (blast intro: transM)
   658 apply (simp add: is_nth_def nth_eq_hd_iterates_tl nat_into_M
   659                  tl'_closed iterates_tl'_closed 
   660                  iterates_abs [OF _ relativize1_tl] nth_replacement)
   661 done
   662 
   663 
   664 subsection{*Relativization and Absoluteness for the @{term formula} Constructors*}
   665 
   666 constdefs
   667   is_Member :: "[i=>o,i,i,i] => o"
   668      --{* because @{term "Member(x,y) \<equiv> Inl(Inl(\<langle>x,y\<rangle>))"}*}
   669     "is_Member(M,x,y,Z) ==
   670 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inl(M,u,Z)"
   671 
   672 lemma (in M_triv_axioms) Member_abs [simp]:
   673      "[|M(x); M(y); M(Z)|] ==> is_Member(M,x,y,Z) <-> (Z = Member(x,y))"
   674 by (simp add: is_Member_def Member_def)
   675 
   676 lemma (in M_triv_axioms) Member_in_M_iff [iff]:
   677      "M(Member(x,y)) <-> M(x) & M(y)"
   678 by (simp add: Member_def) 
   679 
   680 constdefs
   681   is_Equal :: "[i=>o,i,i,i] => o"
   682      --{* because @{term "Equal(x,y) \<equiv> Inl(Inr(\<langle>x,y\<rangle>))"}*}
   683     "is_Equal(M,x,y,Z) ==
   684 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inr(M,p,u) & is_Inl(M,u,Z)"
   685 
   686 lemma (in M_triv_axioms) Equal_abs [simp]:
   687      "[|M(x); M(y); M(Z)|] ==> is_Equal(M,x,y,Z) <-> (Z = Equal(x,y))"
   688 by (simp add: is_Equal_def Equal_def)
   689 
   690 lemma (in M_triv_axioms) Equal_in_M_iff [iff]: "M(Equal(x,y)) <-> M(x) & M(y)"
   691 by (simp add: Equal_def) 
   692 
   693 constdefs
   694   is_Nand :: "[i=>o,i,i,i] => o"
   695      --{* because @{term "Nand(x,y) \<equiv> Inr(Inl(\<langle>x,y\<rangle>))"}*}
   696     "is_Nand(M,x,y,Z) ==
   697 	\<exists>p[M]. \<exists>u[M]. pair(M,x,y,p) & is_Inl(M,p,u) & is_Inr(M,u,Z)"
   698 
   699 lemma (in M_triv_axioms) Nand_abs [simp]:
   700      "[|M(x); M(y); M(Z)|] ==> is_Nand(M,x,y,Z) <-> (Z = Nand(x,y))"
   701 by (simp add: is_Nand_def Nand_def)
   702 
   703 lemma (in M_triv_axioms) Nand_in_M_iff [iff]: "M(Nand(x,y)) <-> M(x) & M(y)"
   704 by (simp add: Nand_def) 
   705 
   706 constdefs
   707   is_Forall :: "[i=>o,i,i] => o"
   708      --{* because @{term "Forall(x) \<equiv> Inr(Inr(p))"}*}
   709     "is_Forall(M,p,Z) == \<exists>u[M]. is_Inr(M,p,u) & is_Inr(M,u,Z)"
   710 
   711 lemma (in M_triv_axioms) Forall_abs [simp]:
   712      "[|M(x); M(Z)|] ==> is_Forall(M,x,Z) <-> (Z = Forall(x))"
   713 by (simp add: is_Forall_def Forall_def)
   714 
   715 lemma (in M_triv_axioms) Forall_in_M_iff [iff]: "M(Forall(x)) <-> M(x)"
   716 by (simp add: Forall_def)
   717 
   718 
   719 subsection {*Absoluteness for @{term formula_rec}*}
   720 
   721 subsubsection{*@{term quasiformula}: For Case-Splitting with @{term formula_case'}*}
   722 
   723 constdefs
   724 
   725   quasiformula :: "i => o"
   726     "quasiformula(p) == 
   727 	(\<exists>x y. p = Member(x,y)) |
   728 	(\<exists>x y. p = Equal(x,y)) |
   729 	(\<exists>x y. p = Nand(x,y)) |
   730 	(\<exists>x. p = Forall(x))"
   731 
   732   is_quasiformula :: "[i=>o,i] => o"
   733     "is_quasiformula(M,p) == 
   734 	(\<exists>x[M]. \<exists>y[M]. is_Member(M,x,y,p)) |
   735 	(\<exists>x[M]. \<exists>y[M]. is_Equal(M,x,y,p)) |
   736 	(\<exists>x[M]. \<exists>y[M]. is_Nand(M,x,y,p)) |
   737 	(\<exists>x[M]. is_Forall(M,x,p))"
   738 
   739 lemma [iff]: "quasiformula(Member(x,y))"
   740 by (simp add: quasiformula_def)
   741 
   742 lemma [iff]: "quasiformula(Equal(x,y))"
   743 by (simp add: quasiformula_def)
   744 
   745 lemma [iff]: "quasiformula(Nand(x,y))"
   746 by (simp add: quasiformula_def)
   747 
   748 lemma [iff]: "quasiformula(Forall(x))"
   749 by (simp add: quasiformula_def)
   750 
   751 lemma formula_imp_quasiformula: "p \<in> formula ==> quasiformula(p)"
   752 by (erule formula.cases, simp_all)
   753 
   754 lemma (in M_triv_axioms) quasiformula_abs [simp]: 
   755      "M(z) ==> is_quasiformula(M,z) <-> quasiformula(z)"
   756 by (auto simp add: is_quasiformula_def quasiformula_def)
   757 
   758 constdefs
   759 
   760   formula_case' :: "[[i,i]=>i, [i,i]=>i, [i,i]=>i, i=>i, i] => i"
   761     --{*A version of @{term formula_case} that's always defined.*}
   762     "formula_case'(a,b,c,d,p) == 
   763        if quasiformula(p) then formula_case(a,b,c,d,p) else 0"  
   764 
   765   is_formula_case :: 
   766       "[i=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i,i]=>o, [i,i]=>o, i, i] => o"
   767     --{*Returns 0 for non-formulas*}
   768     "is_formula_case(M, is_a, is_b, is_c, is_d, p, z) == 
   769 	(\<forall>x[M]. \<forall>y[M]. is_Member(M,x,y,p) --> is_a(x,y,z)) &
   770 	(\<forall>x[M]. \<forall>y[M]. is_Equal(M,x,y,p) --> is_b(x,y,z)) &
   771 	(\<forall>x[M]. \<forall>y[M]. is_Nand(M,x,y,p) --> is_c(x,y,z)) &
   772 	(\<forall>x[M]. is_Forall(M,x,p) --> is_d(x,z)) &
   773         (is_quasiformula(M,p) | empty(M,z))"
   774 
   775 subsubsection{*@{term formula_case'}, the Modified Version of @{term formula_case}*}
   776 
   777 lemma formula_case'_Member [simp]:
   778      "formula_case'(a,b,c,d,Member(x,y)) = a(x,y)"
   779 by (simp add: formula_case'_def)
   780 
   781 lemma formula_case'_Equal [simp]:
   782      "formula_case'(a,b,c,d,Equal(x,y)) = b(x,y)"
   783 by (simp add: formula_case'_def)
   784 
   785 lemma formula_case'_Nand [simp]:
   786      "formula_case'(a,b,c,d,Nand(x,y)) = c(x,y)"
   787 by (simp add: formula_case'_def)
   788 
   789 lemma formula_case'_Forall [simp]:
   790      "formula_case'(a,b,c,d,Forall(x)) = d(x)"
   791 by (simp add: formula_case'_def)
   792 
   793 lemma non_formula_case: "~ quasiformula(x) ==> formula_case'(a,b,c,d,x) = 0" 
   794 by (simp add: quasiformula_def formula_case'_def) 
   795 
   796 lemma formula_case'_eq_formula_case [simp]:
   797      "p \<in> formula ==>formula_case'(a,b,c,d,p) = formula_case(a,b,c,d,p)"
   798 by (erule formula.cases, simp_all)
   799 
   800 lemma (in M_axioms) formula_case'_closed [intro,simp]:
   801   "[|M(p); \<forall>x[M]. \<forall>y[M]. M(a(x,y)); 
   802            \<forall>x[M]. \<forall>y[M]. M(b(x,y)); 
   803            \<forall>x[M]. \<forall>y[M]. M(c(x,y)); 
   804            \<forall>x[M]. M(d(x))|] ==> M(formula_case'(a,b,c,d,p))"
   805 apply (case_tac "quasiformula(p)") 
   806  apply (simp add: quasiformula_def, force) 
   807 apply (simp add: non_formula_case) 
   808 done
   809 
   810 text{*Compared with @{text formula_case_closed'}, the premise on @{term p} is
   811       stronger while the other premises are weaker, incorporating typing 
   812       information.*}
   813 lemma (in M_datatypes) formula_case_closed [intro,simp]:
   814   "[|p \<in> formula; 
   815      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(a(x,y)); 
   816      \<forall>x[M]. \<forall>y[M]. x\<in>nat --> y\<in>nat --> M(b(x,y)); 
   817      \<forall>x[M]. \<forall>y[M]. x\<in>formula --> y\<in>formula --> M(c(x,y)); 
   818      \<forall>x[M]. x\<in>formula --> M(d(x))|] ==> M(formula_case(a,b,c,d,p))"
   819 by (erule formula.cases, simp_all) 
   820 
   821 lemma (in M_triv_axioms) formula_case_abs [simp]: 
   822      "[| relativize2(M,is_a,a); relativize2(M,is_b,b); 
   823          relativize2(M,is_c,c); relativize1(M,is_d,d); M(p); M(z) |] 
   824       ==> is_formula_case(M,is_a,is_b,is_c,is_d,p,z) <-> 
   825           z = formula_case'(a,b,c,d,p)"
   826 apply (case_tac "quasiformula(p)") 
   827  prefer 2 
   828  apply (simp add: is_formula_case_def non_formula_case) 
   829  apply (force simp add: quasiformula_def) 
   830 apply (simp add: quasiformula_def is_formula_case_def)
   831 apply (elim disjE exE) 
   832  apply (simp_all add: relativize1_def relativize2_def) 
   833 done
   834 
   835 
   836 subsubsection{*Towards Absoluteness of @{term formula_rec}*}
   837 
   838 consts   depth :: "i=>i"
   839 primrec
   840   "depth(Member(x,y)) = 0"
   841   "depth(Equal(x,y))  = 0"
   842   "depth(Nand(p,q)) = succ(depth(p) \<union> depth(q))"
   843   "depth(Forall(p)) = succ(depth(p))"
   844 
   845 lemma depth_type [TC]: "p \<in> formula ==> depth(p) \<in> nat"
   846 by (induct_tac p, simp_all) 
   847 
   848 
   849 constdefs
   850   formula_N :: "i => i"
   851     "formula_N(n) == (\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)) ^ n (0)"
   852 
   853 lemma Member_in_formula_N [simp]:
   854      "Member(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   855 by (simp add: formula_N_def Member_def) 
   856 
   857 lemma Equal_in_formula_N [simp]:
   858      "Equal(x,y) \<in> formula_N(succ(n)) <-> x \<in> nat & y \<in> nat"
   859 by (simp add: formula_N_def Equal_def) 
   860 
   861 lemma Nand_in_formula_N [simp]:
   862      "Nand(x,y) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n) & y \<in> formula_N(n)"
   863 by (simp add: formula_N_def Nand_def) 
   864 
   865 lemma Forall_in_formula_N [simp]:
   866      "Forall(x) \<in> formula_N(succ(n)) <-> x \<in> formula_N(n)"
   867 by (simp add: formula_N_def Forall_def) 
   868 
   869 text{*These two aren't simprules because they reveal the underlying
   870 formula representation.*}
   871 lemma formula_N_0: "formula_N(0) = 0"
   872 by (simp add: formula_N_def)
   873 
   874 lemma formula_N_succ:
   875      "formula_N(succ(n)) = 
   876       ((nat*nat) + (nat*nat)) + (formula_N(n) * formula_N(n) + formula_N(n))"
   877 by (simp add: formula_N_def)
   878 
   879 lemma formula_N_imp_formula:
   880   "[| p \<in> formula_N(n); n \<in> nat |] ==> p \<in> formula"
   881 by (force simp add: formula_eq_Union formula_N_def)
   882 
   883 lemma formula_N_imp_depth_lt [rule_format]:
   884      "n \<in> nat ==> \<forall>p \<in> formula_N(n). depth(p) < n"
   885 apply (induct_tac n)  
   886 apply (auto simp add: formula_N_0 formula_N_succ 
   887                       depth_type formula_N_imp_formula Un_least_lt_iff
   888                       Member_def [symmetric] Equal_def [symmetric]
   889                       Nand_def [symmetric] Forall_def [symmetric]) 
   890 done
   891 
   892 lemma formula_imp_formula_N [rule_format]:
   893      "p \<in> formula ==> \<forall>n\<in>nat. depth(p) < n --> p \<in> formula_N(n)"
   894 apply (induct_tac p)
   895 apply (simp_all add: succ_Un_distrib Un_least_lt_iff) 
   896 apply (force elim: natE)+
   897 done
   898 
   899 lemma formula_N_imp_eq_depth:
   900       "[|n \<in> nat; p \<notin> formula_N(n); p \<in> formula_N(succ(n))|] 
   901        ==> n = depth(p)"
   902 apply (rule le_anti_sym) 
   903  prefer 2 apply (simp add: formula_N_imp_depth_lt) 
   904 apply (frule formula_N_imp_formula, simp)
   905 apply (simp add: not_lt_iff_le [symmetric]) 
   906 apply (blast intro: formula_imp_formula_N) 
   907 done
   908 
   909 
   910 
   911 lemma formula_N_mono [rule_format]:
   912   "[| m \<in> nat; n \<in> nat |] ==> m\<le>n --> formula_N(m) \<subseteq> formula_N(n)"
   913 apply (rule_tac m = m and n = n in diff_induct)
   914 apply (simp_all add: formula_N_0 formula_N_succ, blast) 
   915 done
   916 
   917 lemma formula_N_distrib:
   918   "[| m \<in> nat; n \<in> nat |] ==> formula_N(m \<union> n) = formula_N(m) \<union> formula_N(n)"
   919 apply (rule_tac i = m and j = n in Ord_linear_le, auto) 
   920 apply (simp_all add: subset_Un_iff [THEN iffD1] subset_Un_iff2 [THEN iffD1] 
   921                      le_imp_subset formula_N_mono)
   922 done
   923 
   924 text{*Express @{term formula_rec} without using @{term rank} or @{term Vset},
   925 neither of which is absolute.*}
   926 lemma (in M_triv_axioms) formula_rec_eq:
   927   "p \<in> formula ==>
   928    formula_rec(a,b,c,d,p) = 
   929    transrec (succ(depth(p)),
   930       \<lambda>x h. Lambda (formula,
   931              formula_case' (a, b,
   932                 \<lambda>u v. c(u, v, h ` succ(depth(u)) ` u, 
   933                               h ` succ(depth(v)) ` v),
   934                 \<lambda>u. d(u, h ` succ(depth(u)) ` u)))) 
   935    ` p"
   936 apply (induct_tac p)
   937    txt{*Base case for @{term Member}*}
   938    apply (subst transrec, simp add: formula.intros) 
   939   txt{*Base case for @{term Equal}*}
   940   apply (subst transrec, simp add: formula.intros)
   941  txt{*Inductive step for @{term Nand}*}
   942  apply (subst transrec) 
   943  apply (simp add: succ_Un_distrib formula.intros)
   944 txt{*Inductive step for @{term Forall}*}
   945 apply (subst transrec) 
   946 apply (simp add: formula_imp_formula_N formula.intros) 
   947 done
   948 
   949 
   950 constdefs
   951   is_formula_N :: "[i=>o,i,i] => o"
   952     "is_formula_N(M,n,Z) == 
   953       \<exists>zero[M]. \<exists>sn[M]. \<exists>msn[M]. 
   954        empty(M,zero) & 
   955        successor(M,n,sn) & membership(M,sn,msn) &
   956        is_wfrec(M, iterates_MH(M, is_formula_functor(M),zero), msn, n, Z)"
   957   
   958 
   959 lemma (in M_datatypes) formula_N_abs [simp]:
   960      "[|n\<in>nat; M(Z)|] 
   961       ==> is_formula_N(M,n,Z) <-> Z = formula_N(n)"
   962 apply (insert formula_replacement1)
   963 apply (simp add: is_formula_N_def formula_N_def relativize1_def nat_into_M
   964                  iterates_abs [of "is_formula_functor(M)" _ 
   965                                   "\<lambda>X. ((nat*nat) + (nat*nat)) + (X*X + X)"])
   966 done
   967 
   968 lemma (in M_datatypes) formula_N_closed [intro,simp]:
   969      "n\<in>nat ==> M(formula_N(n))"
   970 apply (insert formula_replacement1)
   971 apply (simp add: is_formula_N_def formula_N_def relativize1_def nat_into_M
   972                  iterates_closed [of "is_formula_functor(M)"])
   973 done
   974 
   975 subsection{*Absoluteness for the Formula Operator @{term depth}*}
   976 constdefs
   977 
   978   is_depth :: "[i=>o,i,i] => o"
   979     "is_depth(M,p,n) == 
   980        \<exists>sn[M]. \<exists>formula_n[M]. \<exists>formula_sn[M]. 
   981         is_formula_N(M,n,formula_n) & p \<notin> formula_n &
   982         successor(M,n,sn) & is_formula_N(M,sn,formula_sn) & p \<in> formula_sn"
   983 
   984 
   985 lemma (in M_datatypes) depth_abs [simp]:
   986      "[|p \<in> formula; n \<in> nat|] ==> is_depth(M,p,n) <-> n = depth(p)"
   987 apply (subgoal_tac "M(p) & M(n)")
   988  prefer 2 apply (blast dest: transM)  
   989 apply (simp add: is_depth_def)
   990 apply (blast intro: formula_imp_formula_N nat_into_Ord formula_N_imp_eq_depth
   991              dest: formula_N_imp_depth_lt)
   992 done
   993 
   994 text{*Proof is trivial since @{term depth} returns natural numbers.*}
   995 lemma (in M_triv_axioms) depth_closed [intro,simp]:
   996      "p \<in> formula ==> M(depth(p))"
   997 by (simp add: nat_into_M) 
   998 
   999 end