src/HOL/Limits.thy
author hoelzl
Mon Dec 03 18:18:59 2012 +0100 (2012-12-03)
changeset 50322 b06b95a5fda2
parent 50247 491c5c81c2e8
child 50323 3764d4620fb3
permissions -rw-r--r--
rename filter_lim to filterlim to be consistent with filtermap
     1 (*  Title       : Limits.thy
     2     Author      : Brian Huffman
     3 *)
     4 
     5 header {* Filters and Limits *}
     6 
     7 theory Limits
     8 imports RealVector
     9 begin
    10 
    11 subsection {* Filters *}
    12 
    13 text {*
    14   This definition also allows non-proper filters.
    15 *}
    16 
    17 locale is_filter =
    18   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
    19   assumes True: "F (\<lambda>x. True)"
    20   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
    21   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
    22 
    23 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
    24 proof
    25   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
    26 qed
    27 
    28 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
    29   using Rep_filter [of F] by simp
    30 
    31 lemma Abs_filter_inverse':
    32   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
    33   using assms by (simp add: Abs_filter_inverse)
    34 
    35 
    36 subsection {* Eventually *}
    37 
    38 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
    39   where "eventually P F \<longleftrightarrow> Rep_filter F P"
    40 
    41 lemma eventually_Abs_filter:
    42   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
    43   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
    44 
    45 lemma filter_eq_iff:
    46   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
    47   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
    48 
    49 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
    50   unfolding eventually_def
    51   by (rule is_filter.True [OF is_filter_Rep_filter])
    52 
    53 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
    54 proof -
    55   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
    56   thus "eventually P F" by simp
    57 qed
    58 
    59 lemma eventually_mono:
    60   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
    61   unfolding eventually_def
    62   by (rule is_filter.mono [OF is_filter_Rep_filter])
    63 
    64 lemma eventually_conj:
    65   assumes P: "eventually (\<lambda>x. P x) F"
    66   assumes Q: "eventually (\<lambda>x. Q x) F"
    67   shows "eventually (\<lambda>x. P x \<and> Q x) F"
    68   using assms unfolding eventually_def
    69   by (rule is_filter.conj [OF is_filter_Rep_filter])
    70 
    71 lemma eventually_mp:
    72   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    73   assumes "eventually (\<lambda>x. P x) F"
    74   shows "eventually (\<lambda>x. Q x) F"
    75 proof (rule eventually_mono)
    76   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
    77   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
    78     using assms by (rule eventually_conj)
    79 qed
    80 
    81 lemma eventually_rev_mp:
    82   assumes "eventually (\<lambda>x. P x) F"
    83   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
    84   shows "eventually (\<lambda>x. Q x) F"
    85 using assms(2) assms(1) by (rule eventually_mp)
    86 
    87 lemma eventually_conj_iff:
    88   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
    89   by (auto intro: eventually_conj elim: eventually_rev_mp)
    90 
    91 lemma eventually_elim1:
    92   assumes "eventually (\<lambda>i. P i) F"
    93   assumes "\<And>i. P i \<Longrightarrow> Q i"
    94   shows "eventually (\<lambda>i. Q i) F"
    95   using assms by (auto elim!: eventually_rev_mp)
    96 
    97 lemma eventually_elim2:
    98   assumes "eventually (\<lambda>i. P i) F"
    99   assumes "eventually (\<lambda>i. Q i) F"
   100   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   101   shows "eventually (\<lambda>i. R i) F"
   102   using assms by (auto elim!: eventually_rev_mp)
   103 
   104 lemma eventually_subst:
   105   assumes "eventually (\<lambda>n. P n = Q n) F"
   106   shows "eventually P F = eventually Q F" (is "?L = ?R")
   107 proof -
   108   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   109       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   110     by (auto elim: eventually_elim1)
   111   then show ?thesis by (auto elim: eventually_elim2)
   112 qed
   113 
   114 ML {*
   115   fun eventually_elim_tac ctxt thms thm =
   116     let
   117       val thy = Proof_Context.theory_of ctxt
   118       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   119       val raw_elim_thm =
   120         (@{thm allI} RS @{thm always_eventually})
   121         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   122         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   123       val cases_prop = prop_of (raw_elim_thm RS thm)
   124       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   125     in
   126       CASES cases (rtac raw_elim_thm 1) thm
   127     end
   128 *}
   129 
   130 method_setup eventually_elim = {*
   131   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   132 *} "elimination of eventually quantifiers"
   133 
   134 
   135 subsection {* Finer-than relation *}
   136 
   137 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   138 filter @{term F'}. *}
   139 
   140 instantiation filter :: (type) complete_lattice
   141 begin
   142 
   143 definition le_filter_def:
   144   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   145 
   146 definition
   147   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   148 
   149 definition
   150   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   151 
   152 definition
   153   "bot = Abs_filter (\<lambda>P. True)"
   154 
   155 definition
   156   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   157 
   158 definition
   159   "inf F F' = Abs_filter
   160       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   161 
   162 definition
   163   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   164 
   165 definition
   166   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   167 
   168 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   169   unfolding top_filter_def
   170   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   171 
   172 lemma eventually_bot [simp]: "eventually P bot"
   173   unfolding bot_filter_def
   174   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   175 
   176 lemma eventually_sup:
   177   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   178   unfolding sup_filter_def
   179   by (rule eventually_Abs_filter, rule is_filter.intro)
   180      (auto elim!: eventually_rev_mp)
   181 
   182 lemma eventually_inf:
   183   "eventually P (inf F F') \<longleftrightarrow>
   184    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   185   unfolding inf_filter_def
   186   apply (rule eventually_Abs_filter, rule is_filter.intro)
   187   apply (fast intro: eventually_True)
   188   apply clarify
   189   apply (intro exI conjI)
   190   apply (erule (1) eventually_conj)
   191   apply (erule (1) eventually_conj)
   192   apply simp
   193   apply auto
   194   done
   195 
   196 lemma eventually_Sup:
   197   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   198   unfolding Sup_filter_def
   199   apply (rule eventually_Abs_filter, rule is_filter.intro)
   200   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   201   done
   202 
   203 instance proof
   204   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   205   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   206     by (rule less_filter_def) }
   207   { show "F \<le> F"
   208     unfolding le_filter_def by simp }
   209   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   210     unfolding le_filter_def by simp }
   211   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   212     unfolding le_filter_def filter_eq_iff by fast }
   213   { show "F \<le> top"
   214     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
   215   { show "bot \<le> F"
   216     unfolding le_filter_def by simp }
   217   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   218     unfolding le_filter_def eventually_sup by simp_all }
   219   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   220     unfolding le_filter_def eventually_sup by simp }
   221   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   222     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   223   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   224     unfolding le_filter_def eventually_inf
   225     by (auto elim!: eventually_mono intro: eventually_conj) }
   226   { assume "F \<in> S" thus "F \<le> Sup S"
   227     unfolding le_filter_def eventually_Sup by simp }
   228   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   229     unfolding le_filter_def eventually_Sup by simp }
   230   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   231     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   232   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   233     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   234 qed
   235 
   236 end
   237 
   238 lemma filter_leD:
   239   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   240   unfolding le_filter_def by simp
   241 
   242 lemma filter_leI:
   243   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   244   unfolding le_filter_def by simp
   245 
   246 lemma eventually_False:
   247   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   248   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   249 
   250 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   251   where "trivial_limit F \<equiv> F = bot"
   252 
   253 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   254   by (rule eventually_False [symmetric])
   255 
   256 
   257 subsection {* Map function for filters *}
   258 
   259 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   260   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   261 
   262 lemma eventually_filtermap:
   263   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   264   unfolding filtermap_def
   265   apply (rule eventually_Abs_filter)
   266   apply (rule is_filter.intro)
   267   apply (auto elim!: eventually_rev_mp)
   268   done
   269 
   270 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   271   by (simp add: filter_eq_iff eventually_filtermap)
   272 
   273 lemma filtermap_filtermap:
   274   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   275   by (simp add: filter_eq_iff eventually_filtermap)
   276 
   277 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   278   unfolding le_filter_def eventually_filtermap by simp
   279 
   280 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   281   by (simp add: filter_eq_iff eventually_filtermap)
   282 
   283 subsection {* Order filters *}
   284 
   285 definition at_top :: "('a::order) filter"
   286   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   287 
   288 lemma eventually_at_top_linorder:
   289   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_top \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   290   unfolding at_top_def
   291 proof (rule eventually_Abs_filter, rule is_filter.intro)
   292   fix P Q :: "'a \<Rightarrow> bool"
   293   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   294   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   295   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   296   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   297 qed auto
   298 
   299 lemma eventually_at_top_dense:
   300   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_top \<longleftrightarrow> (\<exists>N. \<forall>n>N. P n)"
   301   unfolding eventually_at_top_linorder
   302 proof safe
   303   fix N assume "\<forall>n\<ge>N. P n" then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   304 next
   305   fix N assume "\<forall>n>N. P n" 
   306   moreover from gt_ex[of N] guess y ..
   307   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   308 qed
   309 
   310 definition at_bot :: "('a::order) filter"
   311   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   312 
   313 lemma eventually_at_bot_linorder:
   314   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   315   unfolding at_bot_def
   316 proof (rule eventually_Abs_filter, rule is_filter.intro)
   317   fix P Q :: "'a \<Rightarrow> bool"
   318   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   319   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   320   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   321   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   322 qed auto
   323 
   324 lemma eventually_at_bot_dense:
   325   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   326   unfolding eventually_at_bot_linorder
   327 proof safe
   328   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   329 next
   330   fix N assume "\<forall>n<N. P n" 
   331   moreover from lt_ex[of N] guess y ..
   332   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   333 qed
   334 
   335 subsection {* Sequentially *}
   336 
   337 abbreviation sequentially :: "nat filter"
   338   where "sequentially == at_top"
   339 
   340 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   341   unfolding at_top_def by simp
   342 
   343 lemma eventually_sequentially:
   344   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   345   by (rule eventually_at_top_linorder)
   346 
   347 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   348   unfolding filter_eq_iff eventually_sequentially by auto
   349 
   350 lemmas trivial_limit_sequentially = sequentially_bot
   351 
   352 lemma eventually_False_sequentially [simp]:
   353   "\<not> eventually (\<lambda>n. False) sequentially"
   354   by (simp add: eventually_False)
   355 
   356 lemma le_sequentially:
   357   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   358   unfolding le_filter_def eventually_sequentially
   359   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   360 
   361 lemma eventually_sequentiallyI:
   362   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   363   shows "eventually P sequentially"
   364 using assms by (auto simp: eventually_sequentially)
   365 
   366 
   367 subsection {* Standard filters *}
   368 
   369 definition within :: "'a filter \<Rightarrow> 'a set \<Rightarrow> 'a filter" (infixr "within" 70)
   370   where "F within S = Abs_filter (\<lambda>P. eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F)"
   371 
   372 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   373   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   374 
   375 definition (in topological_space) at :: "'a \<Rightarrow> 'a filter"
   376   where "at a = nhds a within - {a}"
   377 
   378 lemma eventually_within:
   379   "eventually P (F within S) = eventually (\<lambda>x. x \<in> S \<longrightarrow> P x) F"
   380   unfolding within_def
   381   by (rule eventually_Abs_filter, rule is_filter.intro)
   382      (auto elim!: eventually_rev_mp)
   383 
   384 lemma within_UNIV [simp]: "F within UNIV = F"
   385   unfolding filter_eq_iff eventually_within by simp
   386 
   387 lemma within_empty [simp]: "F within {} = bot"
   388   unfolding filter_eq_iff eventually_within by simp
   389 
   390 lemma within_le: "F within S \<le> F"
   391   unfolding le_filter_def eventually_within by (auto elim: eventually_elim1)
   392 
   393 lemma eventually_nhds:
   394   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   395 unfolding nhds_def
   396 proof (rule eventually_Abs_filter, rule is_filter.intro)
   397   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   398   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" by - rule
   399 next
   400   fix P Q
   401   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   402      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   403   then obtain S T where
   404     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   405     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   406   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   407     by (simp add: open_Int)
   408   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" by - rule
   409 qed auto
   410 
   411 lemma eventually_nhds_metric:
   412   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
   413 unfolding eventually_nhds open_dist
   414 apply safe
   415 apply fast
   416 apply (rule_tac x="{x. dist x a < d}" in exI, simp)
   417 apply clarsimp
   418 apply (rule_tac x="d - dist x a" in exI, clarsimp)
   419 apply (simp only: less_diff_eq)
   420 apply (erule le_less_trans [OF dist_triangle])
   421 done
   422 
   423 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   424   unfolding trivial_limit_def eventually_nhds by simp
   425 
   426 lemma eventually_at_topological:
   427   "eventually P (at a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> P x))"
   428 unfolding at_def eventually_within eventually_nhds by simp
   429 
   430 lemma eventually_at:
   431   fixes a :: "'a::metric_space"
   432   shows "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
   433 unfolding at_def eventually_within eventually_nhds_metric by auto
   434 
   435 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   436   unfolding trivial_limit_def eventually_at_topological
   437   by (safe, case_tac "S = {a}", simp, fast, fast)
   438 
   439 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   440   by (simp add: at_eq_bot_iff not_open_singleton)
   441 
   442 
   443 subsection {* Boundedness *}
   444 
   445 definition Bfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   446   where "Bfun f F = (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
   447 
   448 lemma BfunI:
   449   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
   450 unfolding Bfun_def
   451 proof (intro exI conjI allI)
   452   show "0 < max K 1" by simp
   453 next
   454   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
   455     using K by (rule eventually_elim1, simp)
   456 qed
   457 
   458 lemma BfunE:
   459   assumes "Bfun f F"
   460   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   461 using assms unfolding Bfun_def by fast
   462 
   463 
   464 subsection {* Convergence to Zero *}
   465 
   466 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   467   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   468 
   469 lemma ZfunI:
   470   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   471   unfolding Zfun_def by simp
   472 
   473 lemma ZfunD:
   474   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   475   unfolding Zfun_def by simp
   476 
   477 lemma Zfun_ssubst:
   478   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   479   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   480 
   481 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   482   unfolding Zfun_def by simp
   483 
   484 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   485   unfolding Zfun_def by simp
   486 
   487 lemma Zfun_imp_Zfun:
   488   assumes f: "Zfun f F"
   489   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   490   shows "Zfun (\<lambda>x. g x) F"
   491 proof (cases)
   492   assume K: "0 < K"
   493   show ?thesis
   494   proof (rule ZfunI)
   495     fix r::real assume "0 < r"
   496     hence "0 < r / K"
   497       using K by (rule divide_pos_pos)
   498     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   499       using ZfunD [OF f] by fast
   500     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   501     proof eventually_elim
   502       case (elim x)
   503       hence "norm (f x) * K < r"
   504         by (simp add: pos_less_divide_eq K)
   505       thus ?case
   506         by (simp add: order_le_less_trans [OF elim(1)])
   507     qed
   508   qed
   509 next
   510   assume "\<not> 0 < K"
   511   hence K: "K \<le> 0" by (simp only: not_less)
   512   show ?thesis
   513   proof (rule ZfunI)
   514     fix r :: real
   515     assume "0 < r"
   516     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   517     proof eventually_elim
   518       case (elim x)
   519       also have "norm (f x) * K \<le> norm (f x) * 0"
   520         using K norm_ge_zero by (rule mult_left_mono)
   521       finally show ?case
   522         using `0 < r` by simp
   523     qed
   524   qed
   525 qed
   526 
   527 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   528   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   529 
   530 lemma Zfun_add:
   531   assumes f: "Zfun f F" and g: "Zfun g F"
   532   shows "Zfun (\<lambda>x. f x + g x) F"
   533 proof (rule ZfunI)
   534   fix r::real assume "0 < r"
   535   hence r: "0 < r / 2" by simp
   536   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   537     using f r by (rule ZfunD)
   538   moreover
   539   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   540     using g r by (rule ZfunD)
   541   ultimately
   542   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   543   proof eventually_elim
   544     case (elim x)
   545     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   546       by (rule norm_triangle_ineq)
   547     also have "\<dots> < r/2 + r/2"
   548       using elim by (rule add_strict_mono)
   549     finally show ?case
   550       by simp
   551   qed
   552 qed
   553 
   554 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   555   unfolding Zfun_def by simp
   556 
   557 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   558   by (simp only: diff_minus Zfun_add Zfun_minus)
   559 
   560 lemma (in bounded_linear) Zfun:
   561   assumes g: "Zfun g F"
   562   shows "Zfun (\<lambda>x. f (g x)) F"
   563 proof -
   564   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   565     using bounded by fast
   566   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   567     by simp
   568   with g show ?thesis
   569     by (rule Zfun_imp_Zfun)
   570 qed
   571 
   572 lemma (in bounded_bilinear) Zfun:
   573   assumes f: "Zfun f F"
   574   assumes g: "Zfun g F"
   575   shows "Zfun (\<lambda>x. f x ** g x) F"
   576 proof (rule ZfunI)
   577   fix r::real assume r: "0 < r"
   578   obtain K where K: "0 < K"
   579     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   580     using pos_bounded by fast
   581   from K have K': "0 < inverse K"
   582     by (rule positive_imp_inverse_positive)
   583   have "eventually (\<lambda>x. norm (f x) < r) F"
   584     using f r by (rule ZfunD)
   585   moreover
   586   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   587     using g K' by (rule ZfunD)
   588   ultimately
   589   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   590   proof eventually_elim
   591     case (elim x)
   592     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   593       by (rule norm_le)
   594     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   595       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   596     also from K have "r * inverse K * K = r"
   597       by simp
   598     finally show ?case .
   599   qed
   600 qed
   601 
   602 lemma (in bounded_bilinear) Zfun_left:
   603   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   604   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   605 
   606 lemma (in bounded_bilinear) Zfun_right:
   607   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   608   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   609 
   610 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   611 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   612 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   613 
   614 
   615 subsection {* Limits *}
   616 
   617 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   618   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   619 
   620 syntax
   621   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   622 
   623 translations
   624   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   625 
   626 lemma filterlimE: "(LIM x F1. f x :> F2) \<Longrightarrow> eventually P F2 \<Longrightarrow> eventually (\<lambda>x. P (f x)) F1"
   627   by (auto simp: filterlim_def eventually_filtermap le_filter_def)
   628 
   629 lemma filterlimI: "(\<And>P. eventually P F2 \<Longrightarrow> eventually (\<lambda>x. P (f x)) F1) \<Longrightarrow> (LIM x F1. f x :> F2)"
   630   by (auto simp: filterlim_def eventually_filtermap le_filter_def)
   631 
   632 abbreviation (in topological_space)
   633   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   634   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   635 
   636 ML {*
   637 structure Tendsto_Intros = Named_Thms
   638 (
   639   val name = @{binding tendsto_intros}
   640   val description = "introduction rules for tendsto"
   641 )
   642 *}
   643 
   644 setup Tendsto_Intros.setup
   645 
   646 lemma tendsto_def: "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   647   unfolding filterlim_def
   648 proof safe
   649   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   650   then show "eventually (\<lambda>x. f x \<in> S) F"
   651     unfolding eventually_nhds eventually_filtermap le_filter_def
   652     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   653 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   654 
   655 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   656   unfolding tendsto_def le_filter_def by fast
   657 
   658 lemma topological_tendstoI:
   659   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F)
   660     \<Longrightarrow> (f ---> l) F"
   661   unfolding tendsto_def by auto
   662 
   663 lemma topological_tendstoD:
   664   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   665   unfolding tendsto_def by auto
   666 
   667 lemma tendstoI:
   668   assumes "\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   669   shows "(f ---> l) F"
   670   apply (rule topological_tendstoI)
   671   apply (simp add: open_dist)
   672   apply (drule (1) bspec, clarify)
   673   apply (drule assms)
   674   apply (erule eventually_elim1, simp)
   675   done
   676 
   677 lemma tendstoD:
   678   "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
   679   apply (drule_tac S="{x. dist x l < e}" in topological_tendstoD)
   680   apply (clarsimp simp add: open_dist)
   681   apply (rule_tac x="e - dist x l" in exI, clarsimp)
   682   apply (simp only: less_diff_eq)
   683   apply (erule le_less_trans [OF dist_triangle])
   684   apply simp
   685   apply simp
   686   done
   687 
   688 lemma tendsto_iff:
   689   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
   690   using tendstoI tendstoD by fast
   691 
   692 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   693   by (simp only: tendsto_iff Zfun_def dist_norm)
   694 
   695 lemma tendsto_bot [simp]: "(f ---> a) bot"
   696   unfolding tendsto_def by simp
   697 
   698 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a)"
   699   unfolding tendsto_def eventually_at_topological by auto
   700 
   701 lemma tendsto_ident_at_within [tendsto_intros]:
   702   "((\<lambda>x. x) ---> a) (at a within S)"
   703   unfolding tendsto_def eventually_within eventually_at_topological by auto
   704 
   705 lemma tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   706   by (simp add: tendsto_def)
   707 
   708 lemma tendsto_unique:
   709   fixes f :: "'a \<Rightarrow> 'b::t2_space"
   710   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   711   shows "a = b"
   712 proof (rule ccontr)
   713   assume "a \<noteq> b"
   714   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   715     using hausdorff [OF `a \<noteq> b`] by fast
   716   have "eventually (\<lambda>x. f x \<in> U) F"
   717     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   718   moreover
   719   have "eventually (\<lambda>x. f x \<in> V) F"
   720     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   721   ultimately
   722   have "eventually (\<lambda>x. False) F"
   723   proof eventually_elim
   724     case (elim x)
   725     hence "f x \<in> U \<inter> V" by simp
   726     with `U \<inter> V = {}` show ?case by simp
   727   qed
   728   with `\<not> trivial_limit F` show "False"
   729     by (simp add: trivial_limit_def)
   730 qed
   731 
   732 lemma tendsto_const_iff:
   733   fixes a b :: "'a::t2_space"
   734   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a) ---> b) F \<longleftrightarrow> a = b"
   735   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   736 
   737 lemma tendsto_compose:
   738   assumes g: "(g ---> g l) (at l)"
   739   assumes f: "(f ---> l) F"
   740   shows "((\<lambda>x. g (f x)) ---> g l) F"
   741 proof (rule topological_tendstoI)
   742   fix B assume B: "open B" "g l \<in> B"
   743   obtain A where A: "open A" "l \<in> A"
   744     and gB: "\<forall>y. y \<in> A \<longrightarrow> g y \<in> B"
   745     using topological_tendstoD [OF g B] B(2)
   746     unfolding eventually_at_topological by fast
   747   hence "\<forall>x. f x \<in> A \<longrightarrow> g (f x) \<in> B" by simp
   748   from this topological_tendstoD [OF f A]
   749   show "eventually (\<lambda>x. g (f x) \<in> B) F"
   750     by (rule eventually_mono)
   751 qed
   752 
   753 lemma tendsto_compose_eventually:
   754   assumes g: "(g ---> m) (at l)"
   755   assumes f: "(f ---> l) F"
   756   assumes inj: "eventually (\<lambda>x. f x \<noteq> l) F"
   757   shows "((\<lambda>x. g (f x)) ---> m) F"
   758 proof (rule topological_tendstoI)
   759   fix B assume B: "open B" "m \<in> B"
   760   obtain A where A: "open A" "l \<in> A"
   761     and gB: "\<And>y. y \<in> A \<Longrightarrow> y \<noteq> l \<Longrightarrow> g y \<in> B"
   762     using topological_tendstoD [OF g B]
   763     unfolding eventually_at_topological by fast
   764   show "eventually (\<lambda>x. g (f x) \<in> B) F"
   765     using topological_tendstoD [OF f A] inj
   766     by (rule eventually_elim2) (simp add: gB)
   767 qed
   768 
   769 lemma metric_tendsto_imp_tendsto:
   770   assumes f: "(f ---> a) F"
   771   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
   772   shows "(g ---> b) F"
   773 proof (rule tendstoI)
   774   fix e :: real assume "0 < e"
   775   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
   776   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
   777     using le_less_trans by (rule eventually_elim2)
   778 qed
   779 
   780 subsubsection {* Distance and norms *}
   781 
   782 lemma tendsto_dist [tendsto_intros]:
   783   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   784   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   785 proof (rule tendstoI)
   786   fix e :: real assume "0 < e"
   787   hence e2: "0 < e/2" by simp
   788   from tendstoD [OF f e2] tendstoD [OF g e2]
   789   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   790   proof (eventually_elim)
   791     case (elim x)
   792     then show "dist (dist (f x) (g x)) (dist l m) < e"
   793       unfolding dist_real_def
   794       using dist_triangle2 [of "f x" "g x" "l"]
   795       using dist_triangle2 [of "g x" "l" "m"]
   796       using dist_triangle3 [of "l" "m" "f x"]
   797       using dist_triangle [of "f x" "m" "g x"]
   798       by arith
   799   qed
   800 qed
   801 
   802 lemma norm_conv_dist: "norm x = dist x 0"
   803   unfolding dist_norm by simp
   804 
   805 lemma tendsto_norm [tendsto_intros]:
   806   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   807   unfolding norm_conv_dist by (intro tendsto_intros)
   808 
   809 lemma tendsto_norm_zero:
   810   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   811   by (drule tendsto_norm, simp)
   812 
   813 lemma tendsto_norm_zero_cancel:
   814   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   815   unfolding tendsto_iff dist_norm by simp
   816 
   817 lemma tendsto_norm_zero_iff:
   818   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   819   unfolding tendsto_iff dist_norm by simp
   820 
   821 lemma tendsto_rabs [tendsto_intros]:
   822   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   823   by (fold real_norm_def, rule tendsto_norm)
   824 
   825 lemma tendsto_rabs_zero:
   826   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   827   by (fold real_norm_def, rule tendsto_norm_zero)
   828 
   829 lemma tendsto_rabs_zero_cancel:
   830   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   831   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   832 
   833 lemma tendsto_rabs_zero_iff:
   834   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   835   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   836 
   837 subsubsection {* Addition and subtraction *}
   838 
   839 lemma tendsto_add [tendsto_intros]:
   840   fixes a b :: "'a::real_normed_vector"
   841   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   842   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   843 
   844 lemma tendsto_add_zero:
   845   fixes f g :: "'a::type \<Rightarrow> 'b::real_normed_vector"
   846   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   847   by (drule (1) tendsto_add, simp)
   848 
   849 lemma tendsto_minus [tendsto_intros]:
   850   fixes a :: "'a::real_normed_vector"
   851   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   852   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   853 
   854 lemma tendsto_minus_cancel:
   855   fixes a :: "'a::real_normed_vector"
   856   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   857   by (drule tendsto_minus, simp)
   858 
   859 lemma tendsto_diff [tendsto_intros]:
   860   fixes a b :: "'a::real_normed_vector"
   861   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   862   by (simp add: diff_minus tendsto_add tendsto_minus)
   863 
   864 lemma tendsto_setsum [tendsto_intros]:
   865   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   866   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   867   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   868 proof (cases "finite S")
   869   assume "finite S" thus ?thesis using assms
   870     by (induct, simp add: tendsto_const, simp add: tendsto_add)
   871 next
   872   assume "\<not> finite S" thus ?thesis
   873     by (simp add: tendsto_const)
   874 qed
   875 
   876 lemma real_tendsto_sandwich:
   877   fixes f g h :: "'a \<Rightarrow> real"
   878   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   879   assumes lim: "(f ---> c) net" "(h ---> c) net"
   880   shows "(g ---> c) net"
   881 proof -
   882   have "((\<lambda>n. g n - f n) ---> 0) net"
   883   proof (rule metric_tendsto_imp_tendsto)
   884     show "eventually (\<lambda>n. dist (g n - f n) 0 \<le> dist (h n - f n) 0) net"
   885       using ev by (rule eventually_elim2) (simp add: dist_real_def)
   886     show "((\<lambda>n. h n - f n) ---> 0) net"
   887       using tendsto_diff[OF lim(2,1)] by simp
   888   qed
   889   from tendsto_add[OF this lim(1)] show ?thesis by simp
   890 qed
   891 
   892 subsubsection {* Linear operators and multiplication *}
   893 
   894 lemma (in bounded_linear) tendsto:
   895   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   896   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   897 
   898 lemma (in bounded_linear) tendsto_zero:
   899   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   900   by (drule tendsto, simp only: zero)
   901 
   902 lemma (in bounded_bilinear) tendsto:
   903   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   904   by (simp only: tendsto_Zfun_iff prod_diff_prod
   905                  Zfun_add Zfun Zfun_left Zfun_right)
   906 
   907 lemma (in bounded_bilinear) tendsto_zero:
   908   assumes f: "(f ---> 0) F"
   909   assumes g: "(g ---> 0) F"
   910   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   911   using tendsto [OF f g] by (simp add: zero_left)
   912 
   913 lemma (in bounded_bilinear) tendsto_left_zero:
   914   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   915   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   916 
   917 lemma (in bounded_bilinear) tendsto_right_zero:
   918   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   919   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   920 
   921 lemmas tendsto_of_real [tendsto_intros] =
   922   bounded_linear.tendsto [OF bounded_linear_of_real]
   923 
   924 lemmas tendsto_scaleR [tendsto_intros] =
   925   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   926 
   927 lemmas tendsto_mult [tendsto_intros] =
   928   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   929 
   930 lemmas tendsto_mult_zero =
   931   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   932 
   933 lemmas tendsto_mult_left_zero =
   934   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   935 
   936 lemmas tendsto_mult_right_zero =
   937   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   938 
   939 lemma tendsto_power [tendsto_intros]:
   940   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   941   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   942   by (induct n) (simp_all add: tendsto_const tendsto_mult)
   943 
   944 lemma tendsto_setprod [tendsto_intros]:
   945   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   946   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   947   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   948 proof (cases "finite S")
   949   assume "finite S" thus ?thesis using assms
   950     by (induct, simp add: tendsto_const, simp add: tendsto_mult)
   951 next
   952   assume "\<not> finite S" thus ?thesis
   953     by (simp add: tendsto_const)
   954 qed
   955 
   956 subsubsection {* Inverse and division *}
   957 
   958 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   959   assumes f: "Zfun f F"
   960   assumes g: "Bfun g F"
   961   shows "Zfun (\<lambda>x. f x ** g x) F"
   962 proof -
   963   obtain K where K: "0 \<le> K"
   964     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   965     using nonneg_bounded by fast
   966   obtain B where B: "0 < B"
   967     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   968     using g by (rule BfunE)
   969   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   970   using norm_g proof eventually_elim
   971     case (elim x)
   972     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   973       by (rule norm_le)
   974     also have "\<dots> \<le> norm (f x) * B * K"
   975       by (intro mult_mono' order_refl norm_g norm_ge_zero
   976                 mult_nonneg_nonneg K elim)
   977     also have "\<dots> = norm (f x) * (B * K)"
   978       by (rule mult_assoc)
   979     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   980   qed
   981   with f show ?thesis
   982     by (rule Zfun_imp_Zfun)
   983 qed
   984 
   985 lemma (in bounded_bilinear) flip:
   986   "bounded_bilinear (\<lambda>x y. y ** x)"
   987   apply default
   988   apply (rule add_right)
   989   apply (rule add_left)
   990   apply (rule scaleR_right)
   991   apply (rule scaleR_left)
   992   apply (subst mult_commute)
   993   using bounded by fast
   994 
   995 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   996   assumes f: "Bfun f F"
   997   assumes g: "Zfun g F"
   998   shows "Zfun (\<lambda>x. f x ** g x) F"
   999   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
  1000 
  1001 lemma Bfun_inverse_lemma:
  1002   fixes x :: "'a::real_normed_div_algebra"
  1003   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1004   apply (subst nonzero_norm_inverse, clarsimp)
  1005   apply (erule (1) le_imp_inverse_le)
  1006   done
  1007 
  1008 lemma Bfun_inverse:
  1009   fixes a :: "'a::real_normed_div_algebra"
  1010   assumes f: "(f ---> a) F"
  1011   assumes a: "a \<noteq> 0"
  1012   shows "Bfun (\<lambda>x. inverse (f x)) F"
  1013 proof -
  1014   from a have "0 < norm a" by simp
  1015   hence "\<exists>r>0. r < norm a" by (rule dense)
  1016   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
  1017   have "eventually (\<lambda>x. dist (f x) a < r) F"
  1018     using tendstoD [OF f r1] by fast
  1019   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
  1020   proof eventually_elim
  1021     case (elim x)
  1022     hence 1: "norm (f x - a) < r"
  1023       by (simp add: dist_norm)
  1024     hence 2: "f x \<noteq> 0" using r2 by auto
  1025     hence "norm (inverse (f x)) = inverse (norm (f x))"
  1026       by (rule nonzero_norm_inverse)
  1027     also have "\<dots> \<le> inverse (norm a - r)"
  1028     proof (rule le_imp_inverse_le)
  1029       show "0 < norm a - r" using r2 by simp
  1030     next
  1031       have "norm a - norm (f x) \<le> norm (a - f x)"
  1032         by (rule norm_triangle_ineq2)
  1033       also have "\<dots> = norm (f x - a)"
  1034         by (rule norm_minus_commute)
  1035       also have "\<dots> < r" using 1 .
  1036       finally show "norm a - r \<le> norm (f x)" by simp
  1037     qed
  1038     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
  1039   qed
  1040   thus ?thesis by (rule BfunI)
  1041 qed
  1042 
  1043 lemma tendsto_inverse [tendsto_intros]:
  1044   fixes a :: "'a::real_normed_div_algebra"
  1045   assumes f: "(f ---> a) F"
  1046   assumes a: "a \<noteq> 0"
  1047   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
  1048 proof -
  1049   from a have "0 < norm a" by simp
  1050   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
  1051     by (rule tendstoD)
  1052   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
  1053     unfolding dist_norm by (auto elim!: eventually_elim1)
  1054   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
  1055     - (inverse (f x) * (f x - a) * inverse a)) F"
  1056     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
  1057   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
  1058     by (intro Zfun_minus Zfun_mult_left
  1059       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
  1060       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
  1061   ultimately show ?thesis
  1062     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
  1063 qed
  1064 
  1065 lemma tendsto_divide [tendsto_intros]:
  1066   fixes a b :: "'a::real_normed_field"
  1067   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
  1068     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
  1069   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
  1070 
  1071 lemma tendsto_sgn [tendsto_intros]:
  1072   fixes l :: "'a::real_normed_vector"
  1073   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
  1074   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1075 
  1076 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1077 
  1078 lemma filterlim_at_top:
  1079   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1080   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1081   by (safe elim!: filterlimE intro!: filterlimI)
  1082      (auto simp: eventually_at_top_dense elim!: eventually_elim1)
  1083 
  1084 lemma filterlim_at_bot: 
  1085   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1086   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
  1087   by (safe elim!: filterlimE intro!: filterlimI)
  1088      (auto simp: eventually_at_bot_dense elim!: eventually_elim1)
  1089 
  1090 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1091   unfolding filterlim_at_top
  1092   apply (intro allI)
  1093   apply (rule_tac c="natceiling (Z + 1)" in eventually_sequentiallyI)
  1094   apply (auto simp: natceiling_le_eq)
  1095   done
  1096 
  1097 end