src/ZF/Constructible/Rec_Separation.thy
author ballarin
Mon Apr 18 15:54:23 2005 +0200 (2005-04-18)
changeset 15766 b08feb003f3c
parent 13807 a28a8fbc76d4
child 16417 9bc16273c2d4
permissions -rw-r--r--
Cleaned up, now use interpretation.
     1 (*  Title:      ZF/Constructible/Rec_Separation.thy
     2     ID:   $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4 *)
     5 
     6 header {*Separation for Facts About Recursion*}
     7 
     8 theory Rec_Separation = Separation + Internalize:
     9 
    10 text{*This theory proves all instances needed for locales @{text
    11 "M_trancl"} and @{text "M_datatypes"}*}
    12 
    13 lemma eq_succ_imp_lt: "[|i = succ(j); Ord(i)|] ==> j<i"
    14 by simp
    15 
    16 
    17 subsection{*The Locale @{text "M_trancl"}*}
    18 
    19 subsubsection{*Separation for Reflexive/Transitive Closure*}
    20 
    21 text{*First, The Defining Formula*}
    22 
    23 (* "rtran_closure_mem(M,A,r,p) ==
    24       \<exists>nnat[M]. \<exists>n[M]. \<exists>n'[M].
    25        omega(M,nnat) & n\<in>nnat & successor(M,n,n') &
    26        (\<exists>f[M]. typed_function(M,n',A,f) &
    27         (\<exists>x[M]. \<exists>y[M]. \<exists>zero[M]. pair(M,x,y,p) & empty(M,zero) &
    28           fun_apply(M,f,zero,x) & fun_apply(M,f,n,y)) &
    29         (\<forall>j[M]. j\<in>n -->
    30           (\<exists>fj[M]. \<exists>sj[M]. \<exists>fsj[M]. \<exists>ffp[M].
    31             fun_apply(M,f,j,fj) & successor(M,j,sj) &
    32             fun_apply(M,f,sj,fsj) & pair(M,fj,fsj,ffp) & ffp \<in> r)))"*)
    33 constdefs rtran_closure_mem_fm :: "[i,i,i]=>i"
    34  "rtran_closure_mem_fm(A,r,p) ==
    35    Exists(Exists(Exists(
    36     And(omega_fm(2),
    37      And(Member(1,2),
    38       And(succ_fm(1,0),
    39        Exists(And(typed_function_fm(1, A#+4, 0),
    40         And(Exists(Exists(Exists(
    41               And(pair_fm(2,1,p#+7),
    42                And(empty_fm(0),
    43                 And(fun_apply_fm(3,0,2), fun_apply_fm(3,5,1))))))),
    44             Forall(Implies(Member(0,3),
    45              Exists(Exists(Exists(Exists(
    46               And(fun_apply_fm(5,4,3),
    47                And(succ_fm(4,2),
    48                 And(fun_apply_fm(5,2,1),
    49                  And(pair_fm(3,1,0), Member(0,r#+9))))))))))))))))))))"
    50 
    51 
    52 lemma rtran_closure_mem_type [TC]:
    53  "[| x \<in> nat; y \<in> nat; z \<in> nat |] ==> rtran_closure_mem_fm(x,y,z) \<in> formula"
    54 by (simp add: rtran_closure_mem_fm_def)
    55 
    56 lemma sats_rtran_closure_mem_fm [simp]:
    57    "[| x \<in> nat; y \<in> nat; z \<in> nat; env \<in> list(A)|]
    58     ==> sats(A, rtran_closure_mem_fm(x,y,z), env) <->
    59         rtran_closure_mem(##A, nth(x,env), nth(y,env), nth(z,env))"
    60 by (simp add: rtran_closure_mem_fm_def rtran_closure_mem_def)
    61 
    62 lemma rtran_closure_mem_iff_sats:
    63       "[| nth(i,env) = x; nth(j,env) = y; nth(k,env) = z;
    64           i \<in> nat; j \<in> nat; k \<in> nat; env \<in> list(A)|]
    65        ==> rtran_closure_mem(##A, x, y, z) <-> sats(A, rtran_closure_mem_fm(i,j,k), env)"
    66 by (simp add: sats_rtran_closure_mem_fm)
    67 
    68 lemma rtran_closure_mem_reflection:
    69      "REFLECTS[\<lambda>x. rtran_closure_mem(L,f(x),g(x),h(x)),
    70                \<lambda>i x. rtran_closure_mem(##Lset(i),f(x),g(x),h(x))]"
    71 apply (simp only: rtran_closure_mem_def)
    72 apply (intro FOL_reflections function_reflections fun_plus_reflections)
    73 done
    74 
    75 text{*Separation for @{term "rtrancl(r)"}.*}
    76 lemma rtrancl_separation:
    77      "[| L(r); L(A) |] ==> separation (L, rtran_closure_mem(L,A,r))"
    78 apply (rule gen_separation_multi [OF rtran_closure_mem_reflection, of "{r,A}"],
    79        auto)
    80 apply (rule_tac env="[r,A]" in DPow_LsetI)
    81 apply (rule rtran_closure_mem_iff_sats sep_rules | simp)+
    82 done
    83 
    84 
    85 subsubsection{*Reflexive/Transitive Closure, Internalized*}
    86 
    87 (*  "rtran_closure(M,r,s) ==
    88         \<forall>A[M]. is_field(M,r,A) -->
    89          (\<forall>p[M]. p \<in> s <-> rtran_closure_mem(M,A,r,p))" *)
    90 constdefs rtran_closure_fm :: "[i,i]=>i"
    91  "rtran_closure_fm(r,s) ==
    92    Forall(Implies(field_fm(succ(r),0),
    93                   Forall(Iff(Member(0,succ(succ(s))),
    94                              rtran_closure_mem_fm(1,succ(succ(r)),0)))))"
    95 
    96 lemma rtran_closure_type [TC]:
    97      "[| x \<in> nat; y \<in> nat |] ==> rtran_closure_fm(x,y) \<in> formula"
    98 by (simp add: rtran_closure_fm_def)
    99 
   100 lemma sats_rtran_closure_fm [simp]:
   101    "[| x \<in> nat; y \<in> nat; env \<in> list(A)|]
   102     ==> sats(A, rtran_closure_fm(x,y), env) <->
   103         rtran_closure(##A, nth(x,env), nth(y,env))"
   104 by (simp add: rtran_closure_fm_def rtran_closure_def)
   105 
   106 lemma rtran_closure_iff_sats:
   107       "[| nth(i,env) = x; nth(j,env) = y;
   108           i \<in> nat; j \<in> nat; env \<in> list(A)|]
   109        ==> rtran_closure(##A, x, y) <-> sats(A, rtran_closure_fm(i,j), env)"
   110 by simp
   111 
   112 theorem rtran_closure_reflection:
   113      "REFLECTS[\<lambda>x. rtran_closure(L,f(x),g(x)),
   114                \<lambda>i x. rtran_closure(##Lset(i),f(x),g(x))]"
   115 apply (simp only: rtran_closure_def)
   116 apply (intro FOL_reflections function_reflections rtran_closure_mem_reflection)
   117 done
   118 
   119 
   120 subsubsection{*Transitive Closure of a Relation, Internalized*}
   121 
   122 (*  "tran_closure(M,r,t) ==
   123          \<exists>s[M]. rtran_closure(M,r,s) & composition(M,r,s,t)" *)
   124 constdefs tran_closure_fm :: "[i,i]=>i"
   125  "tran_closure_fm(r,s) ==
   126    Exists(And(rtran_closure_fm(succ(r),0), composition_fm(succ(r),0,succ(s))))"
   127 
   128 lemma tran_closure_type [TC]:
   129      "[| x \<in> nat; y \<in> nat |] ==> tran_closure_fm(x,y) \<in> formula"
   130 by (simp add: tran_closure_fm_def)
   131 
   132 lemma sats_tran_closure_fm [simp]:
   133    "[| x \<in> nat; y \<in> nat; env \<in> list(A)|]
   134     ==> sats(A, tran_closure_fm(x,y), env) <->
   135         tran_closure(##A, nth(x,env), nth(y,env))"
   136 by (simp add: tran_closure_fm_def tran_closure_def)
   137 
   138 lemma tran_closure_iff_sats:
   139       "[| nth(i,env) = x; nth(j,env) = y;
   140           i \<in> nat; j \<in> nat; env \<in> list(A)|]
   141        ==> tran_closure(##A, x, y) <-> sats(A, tran_closure_fm(i,j), env)"
   142 by simp
   143 
   144 theorem tran_closure_reflection:
   145      "REFLECTS[\<lambda>x. tran_closure(L,f(x),g(x)),
   146                \<lambda>i x. tran_closure(##Lset(i),f(x),g(x))]"
   147 apply (simp only: tran_closure_def)
   148 apply (intro FOL_reflections function_reflections
   149              rtran_closure_reflection composition_reflection)
   150 done
   151 
   152 
   153 subsubsection{*Separation for the Proof of @{text "wellfounded_on_trancl"}*}
   154 
   155 lemma wellfounded_trancl_reflects:
   156   "REFLECTS[\<lambda>x. \<exists>w[L]. \<exists>wx[L]. \<exists>rp[L].
   157                  w \<in> Z & pair(L,w,x,wx) & tran_closure(L,r,rp) & wx \<in> rp,
   158    \<lambda>i x. \<exists>w \<in> Lset(i). \<exists>wx \<in> Lset(i). \<exists>rp \<in> Lset(i).
   159        w \<in> Z & pair(##Lset(i),w,x,wx) & tran_closure(##Lset(i),r,rp) &
   160        wx \<in> rp]"
   161 by (intro FOL_reflections function_reflections fun_plus_reflections
   162           tran_closure_reflection)
   163 
   164 lemma wellfounded_trancl_separation:
   165          "[| L(r); L(Z) |] ==>
   166           separation (L, \<lambda>x.
   167               \<exists>w[L]. \<exists>wx[L]. \<exists>rp[L].
   168                w \<in> Z & pair(L,w,x,wx) & tran_closure(L,r,rp) & wx \<in> rp)"
   169 apply (rule gen_separation_multi [OF wellfounded_trancl_reflects, of "{r,Z}"],
   170        auto)
   171 apply (rule_tac env="[r,Z]" in DPow_LsetI)
   172 apply (rule sep_rules tran_closure_iff_sats | simp)+
   173 done
   174 
   175 
   176 subsubsection{*Instantiating the locale @{text M_trancl}*}
   177 
   178 lemma M_trancl_axioms_L: "M_trancl_axioms(L)"
   179   apply (rule M_trancl_axioms.intro)
   180    apply (assumption | rule rtrancl_separation wellfounded_trancl_separation)+
   181   done
   182 
   183 theorem M_trancl_L: "PROP M_trancl(L)"
   184 by (rule M_trancl.intro
   185          [OF M_trivial_L M_basic_axioms_L M_trancl_axioms_L])
   186 
   187 interpretation M_trancl [L] by (rule M_trancl_axioms_L)
   188 
   189 
   190 subsection{*@{term L} is Closed Under the Operator @{term list}*}
   191 
   192 subsubsection{*Instances of Replacement for Lists*}
   193 
   194 lemma list_replacement1_Reflects:
   195  "REFLECTS
   196    [\<lambda>x. \<exists>u[L]. u \<in> B \<and> (\<exists>y[L]. pair(L,u,y,x) \<and>
   197          is_wfrec(L, iterates_MH(L, is_list_functor(L,A), 0), memsn, u, y)),
   198     \<lambda>i x. \<exists>u \<in> Lset(i). u \<in> B \<and> (\<exists>y \<in> Lset(i). pair(##Lset(i), u, y, x) \<and>
   199          is_wfrec(##Lset(i),
   200                   iterates_MH(##Lset(i),
   201                           is_list_functor(##Lset(i), A), 0), memsn, u, y))]"
   202 by (intro FOL_reflections function_reflections is_wfrec_reflection
   203           iterates_MH_reflection list_functor_reflection)
   204 
   205 
   206 lemma list_replacement1:
   207    "L(A) ==> iterates_replacement(L, is_list_functor(L,A), 0)"
   208 apply (unfold iterates_replacement_def wfrec_replacement_def, clarify)
   209 apply (rule strong_replacementI)
   210 apply (rule_tac u="{B,A,n,0,Memrel(succ(n))}" 
   211          in gen_separation_multi [OF list_replacement1_Reflects], 
   212        auto simp add: nonempty)
   213 apply (rule_tac env="[B,A,n,0,Memrel(succ(n))]" in DPow_LsetI)
   214 apply (rule sep_rules is_nat_case_iff_sats list_functor_iff_sats
   215             is_wfrec_iff_sats iterates_MH_iff_sats quasinat_iff_sats | simp)+
   216 done
   217 
   218 
   219 lemma list_replacement2_Reflects:
   220  "REFLECTS
   221    [\<lambda>x. \<exists>u[L]. u \<in> B & u \<in> nat &
   222                 is_iterates(L, is_list_functor(L, A), 0, u, x),
   223     \<lambda>i x. \<exists>u \<in> Lset(i). u \<in> B & u \<in> nat &
   224                is_iterates(##Lset(i), is_list_functor(##Lset(i), A), 0, u, x)]"
   225 by (intro FOL_reflections 
   226           is_iterates_reflection list_functor_reflection)
   227 
   228 lemma list_replacement2:
   229    "L(A) ==> strong_replacement(L,
   230          \<lambda>n y. n\<in>nat & is_iterates(L, is_list_functor(L,A), 0, n, y))"
   231 apply (rule strong_replacementI)
   232 apply (rule_tac u="{A,B,0,nat}" 
   233          in gen_separation_multi [OF list_replacement2_Reflects], 
   234        auto simp add: L_nat nonempty)
   235 apply (rule_tac env="[A,B,0,nat]" in DPow_LsetI)
   236 apply (rule sep_rules list_functor_iff_sats is_iterates_iff_sats | simp)+
   237 done
   238 
   239 
   240 subsection{*@{term L} is Closed Under the Operator @{term formula}*}
   241 
   242 subsubsection{*Instances of Replacement for Formulas*}
   243 
   244 (*FIXME: could prove a lemma iterates_replacementI to eliminate the 
   245 need to expand iterates_replacement and wfrec_replacement*)
   246 lemma formula_replacement1_Reflects:
   247  "REFLECTS
   248    [\<lambda>x. \<exists>u[L]. u \<in> B & (\<exists>y[L]. pair(L,u,y,x) &
   249          is_wfrec(L, iterates_MH(L, is_formula_functor(L), 0), memsn, u, y)),
   250     \<lambda>i x. \<exists>u \<in> Lset(i). u \<in> B & (\<exists>y \<in> Lset(i). pair(##Lset(i), u, y, x) &
   251          is_wfrec(##Lset(i),
   252                   iterates_MH(##Lset(i),
   253                           is_formula_functor(##Lset(i)), 0), memsn, u, y))]"
   254 by (intro FOL_reflections function_reflections is_wfrec_reflection
   255           iterates_MH_reflection formula_functor_reflection)
   256 
   257 lemma formula_replacement1:
   258    "iterates_replacement(L, is_formula_functor(L), 0)"
   259 apply (unfold iterates_replacement_def wfrec_replacement_def, clarify)
   260 apply (rule strong_replacementI)
   261 apply (rule_tac u="{B,n,0,Memrel(succ(n))}" 
   262          in gen_separation_multi [OF formula_replacement1_Reflects], 
   263        auto simp add: nonempty)
   264 apply (rule_tac env="[n,B,0,Memrel(succ(n))]" in DPow_LsetI)
   265 apply (rule sep_rules is_nat_case_iff_sats formula_functor_iff_sats
   266             is_wfrec_iff_sats iterates_MH_iff_sats quasinat_iff_sats | simp)+
   267 done
   268 
   269 lemma formula_replacement2_Reflects:
   270  "REFLECTS
   271    [\<lambda>x. \<exists>u[L]. u \<in> B & u \<in> nat &
   272                 is_iterates(L, is_formula_functor(L), 0, u, x),
   273     \<lambda>i x. \<exists>u \<in> Lset(i). u \<in> B & u \<in> nat &
   274                is_iterates(##Lset(i), is_formula_functor(##Lset(i)), 0, u, x)]"
   275 by (intro FOL_reflections 
   276           is_iterates_reflection formula_functor_reflection)
   277 
   278 lemma formula_replacement2:
   279    "strong_replacement(L,
   280          \<lambda>n y. n\<in>nat & is_iterates(L, is_formula_functor(L), 0, n, y))"
   281 apply (rule strong_replacementI)
   282 apply (rule_tac u="{B,0,nat}" 
   283          in gen_separation_multi [OF formula_replacement2_Reflects], 
   284        auto simp add: nonempty L_nat)
   285 apply (rule_tac env="[B,0,nat]" in DPow_LsetI)
   286 apply (rule sep_rules formula_functor_iff_sats is_iterates_iff_sats | simp)+
   287 done
   288 
   289 text{*NB The proofs for type @{term formula} are virtually identical to those
   290 for @{term "list(A)"}.  It was a cut-and-paste job! *}
   291 
   292 
   293 subsubsection{*The Formula @{term is_nth}, Internalized*}
   294 
   295 (* "is_nth(M,n,l,Z) ==
   296       \<exists>X[M]. is_iterates(M, is_tl(M), l, n, X) & is_hd(M,X,Z)" *)
   297 constdefs nth_fm :: "[i,i,i]=>i"
   298     "nth_fm(n,l,Z) == 
   299        Exists(And(is_iterates_fm(tl_fm(1,0), succ(l), succ(n), 0), 
   300               hd_fm(0,succ(Z))))"
   301 
   302 lemma nth_fm_type [TC]:
   303  "[| x \<in> nat; y \<in> nat; z \<in> nat |] ==> nth_fm(x,y,z) \<in> formula"
   304 by (simp add: nth_fm_def)
   305 
   306 lemma sats_nth_fm [simp]:
   307    "[| x < length(env); y \<in> nat; z \<in> nat; env \<in> list(A)|]
   308     ==> sats(A, nth_fm(x,y,z), env) <->
   309         is_nth(##A, nth(x,env), nth(y,env), nth(z,env))"
   310 apply (frule lt_length_in_nat, assumption)  
   311 apply (simp add: nth_fm_def is_nth_def sats_is_iterates_fm) 
   312 done
   313 
   314 lemma nth_iff_sats:
   315       "[| nth(i,env) = x; nth(j,env) = y; nth(k,env) = z;
   316           i < length(env); j \<in> nat; k \<in> nat; env \<in> list(A)|]
   317        ==> is_nth(##A, x, y, z) <-> sats(A, nth_fm(i,j,k), env)"
   318 by (simp add: sats_nth_fm)
   319 
   320 theorem nth_reflection:
   321      "REFLECTS[\<lambda>x. is_nth(L, f(x), g(x), h(x)),  
   322                \<lambda>i x. is_nth(##Lset(i), f(x), g(x), h(x))]"
   323 apply (simp only: is_nth_def)
   324 apply (intro FOL_reflections is_iterates_reflection
   325              hd_reflection tl_reflection) 
   326 done
   327 
   328 
   329 subsubsection{*An Instance of Replacement for @{term nth}*}
   330 
   331 (*FIXME: could prove a lemma iterates_replacementI to eliminate the 
   332 need to expand iterates_replacement and wfrec_replacement*)
   333 lemma nth_replacement_Reflects:
   334  "REFLECTS
   335    [\<lambda>x. \<exists>u[L]. u \<in> B & (\<exists>y[L]. pair(L,u,y,x) &
   336          is_wfrec(L, iterates_MH(L, is_tl(L), z), memsn, u, y)),
   337     \<lambda>i x. \<exists>u \<in> Lset(i). u \<in> B & (\<exists>y \<in> Lset(i). pair(##Lset(i), u, y, x) &
   338          is_wfrec(##Lset(i),
   339                   iterates_MH(##Lset(i),
   340                           is_tl(##Lset(i)), z), memsn, u, y))]"
   341 by (intro FOL_reflections function_reflections is_wfrec_reflection
   342           iterates_MH_reflection tl_reflection)
   343 
   344 lemma nth_replacement:
   345    "L(w) ==> iterates_replacement(L, is_tl(L), w)"
   346 apply (unfold iterates_replacement_def wfrec_replacement_def, clarify)
   347 apply (rule strong_replacementI)
   348 apply (rule_tac u="{B,w,Memrel(succ(n))}" 
   349          in gen_separation_multi [OF nth_replacement_Reflects], 
   350        auto)
   351 apply (rule_tac env="[B,w,Memrel(succ(n))]" in DPow_LsetI)
   352 apply (rule sep_rules is_nat_case_iff_sats tl_iff_sats
   353             is_wfrec_iff_sats iterates_MH_iff_sats quasinat_iff_sats | simp)+
   354 done
   355 
   356 
   357 subsubsection{*Instantiating the locale @{text M_datatypes}*}
   358 
   359 lemma M_datatypes_axioms_L: "M_datatypes_axioms(L)"
   360   apply (rule M_datatypes_axioms.intro)
   361       apply (assumption | rule
   362         list_replacement1 list_replacement2
   363         formula_replacement1 formula_replacement2
   364         nth_replacement)+
   365   done
   366 
   367 theorem M_datatypes_L: "PROP M_datatypes(L)"
   368   apply (rule M_datatypes.intro)
   369       apply (rule M_trancl.axioms [OF M_trancl_L])+
   370  apply (rule M_datatypes_axioms_L) 
   371  done
   372 
   373 interpretation M_datatypes [L] by (rule M_datatypes_axioms_L)
   374 
   375 
   376 subsection{*@{term L} is Closed Under the Operator @{term eclose}*}
   377 
   378 subsubsection{*Instances of Replacement for @{term eclose}*}
   379 
   380 lemma eclose_replacement1_Reflects:
   381  "REFLECTS
   382    [\<lambda>x. \<exists>u[L]. u \<in> B & (\<exists>y[L]. pair(L,u,y,x) &
   383          is_wfrec(L, iterates_MH(L, big_union(L), A), memsn, u, y)),
   384     \<lambda>i x. \<exists>u \<in> Lset(i). u \<in> B & (\<exists>y \<in> Lset(i). pair(##Lset(i), u, y, x) &
   385          is_wfrec(##Lset(i),
   386                   iterates_MH(##Lset(i), big_union(##Lset(i)), A),
   387                   memsn, u, y))]"
   388 by (intro FOL_reflections function_reflections is_wfrec_reflection
   389           iterates_MH_reflection)
   390 
   391 lemma eclose_replacement1:
   392    "L(A) ==> iterates_replacement(L, big_union(L), A)"
   393 apply (unfold iterates_replacement_def wfrec_replacement_def, clarify)
   394 apply (rule strong_replacementI)
   395 apply (rule_tac u="{B,A,n,Memrel(succ(n))}" 
   396          in gen_separation_multi [OF eclose_replacement1_Reflects], auto)
   397 apply (rule_tac env="[B,A,n,Memrel(succ(n))]" in DPow_LsetI)
   398 apply (rule sep_rules iterates_MH_iff_sats is_nat_case_iff_sats
   399              is_wfrec_iff_sats big_union_iff_sats quasinat_iff_sats | simp)+
   400 done
   401 
   402 
   403 lemma eclose_replacement2_Reflects:
   404  "REFLECTS
   405    [\<lambda>x. \<exists>u[L]. u \<in> B & u \<in> nat &
   406                 is_iterates(L, big_union(L), A, u, x),
   407     \<lambda>i x. \<exists>u \<in> Lset(i). u \<in> B & u \<in> nat &
   408                is_iterates(##Lset(i), big_union(##Lset(i)), A, u, x)]"
   409 by (intro FOL_reflections function_reflections is_iterates_reflection)
   410 
   411 lemma eclose_replacement2:
   412    "L(A) ==> strong_replacement(L,
   413          \<lambda>n y. n\<in>nat & is_iterates(L, big_union(L), A, n, y))"
   414 apply (rule strong_replacementI)
   415 apply (rule_tac u="{A,B,nat}" 
   416          in gen_separation_multi [OF eclose_replacement2_Reflects],
   417        auto simp add: L_nat)
   418 apply (rule_tac env="[A,B,nat]" in DPow_LsetI)
   419 apply (rule sep_rules is_iterates_iff_sats big_union_iff_sats | simp)+
   420 done
   421 
   422 
   423 subsubsection{*Instantiating the locale @{text M_eclose}*}
   424 
   425 lemma M_eclose_axioms_L: "M_eclose_axioms(L)"
   426   apply (rule M_eclose_axioms.intro)
   427    apply (assumption | rule eclose_replacement1 eclose_replacement2)+
   428   done
   429 
   430 theorem M_eclose_L: "PROP M_eclose(L)"
   431   apply (rule M_eclose.intro)
   432        apply (rule M_datatypes.axioms [OF M_datatypes_L])+
   433   apply (rule M_eclose_axioms_L)
   434   done
   435 
   436 interpretation M_eclose [L] by (rule M_eclose_axioms_L)
   437 
   438 
   439 end