src/HOL/Groebner_Basis.thy
author haftmann
Thu May 06 18:16:07 2010 +0200 (2010-05-06)
changeset 36716 b09f3ad3208f
parent 36714 ae84ddf03c58
child 36720 41da7025e59c
permissions -rw-r--r--
moved generic lemmas to appropriate places
     1 (*  Title:      HOL/Groebner_Basis.thy
     2     Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 header {* Semiring normalization and Groebner Bases *}
     6 
     7 theory Groebner_Basis
     8 imports Numeral_Simprocs Nat_Transfer
     9 uses
    10   "Tools/Groebner_Basis/normalizer.ML"
    11   ("Tools/Groebner_Basis/groebner.ML")
    12 begin
    13 
    14 subsection {* Semiring normalization *}
    15 
    16 setup Normalizer.setup
    17 
    18 locale normalizing_semiring =
    19   fixes add mul pwr r0 r1
    20   assumes add_a:"(add x (add y z) = add (add x y) z)"
    21     and add_c: "add x y = add y x" and add_0:"add r0 x = x"
    22     and mul_a:"mul x (mul y z) = mul (mul x y) z" and mul_c:"mul x y = mul y x"
    23     and mul_1:"mul r1 x = x" and  mul_0:"mul r0 x = r0"
    24     and mul_d:"mul x (add y z) = add (mul x y) (mul x z)"
    25     and pwr_0:"pwr x 0 = r1" and pwr_Suc:"pwr x (Suc n) = mul x (pwr x n)"
    26 begin
    27 
    28 lemma mul_pwr:"mul (pwr x p) (pwr x q) = pwr x (p + q)"
    29 proof (induct p)
    30   case 0
    31   then show ?case by (auto simp add: pwr_0 mul_1)
    32 next
    33   case Suc
    34   from this [symmetric] show ?case
    35     by (auto simp add: pwr_Suc mul_1 mul_a)
    36 qed
    37 
    38 lemma pwr_mul: "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    39 proof (induct q arbitrary: x y, auto simp add:pwr_0 pwr_Suc mul_1)
    40   fix q x y
    41   assume "\<And>x y. pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    42   have "mul (mul x y) (mul (pwr x q) (pwr y q)) = mul x (mul y (mul (pwr x q) (pwr y q)))"
    43     by (simp add: mul_a)
    44   also have "\<dots> = (mul (mul y (mul (pwr y q) (pwr x q))) x)" by (simp add: mul_c)
    45   also have "\<dots> = (mul (mul y (pwr y q)) (mul (pwr x q) x))" by (simp add: mul_a)
    46   finally show "mul (mul x y) (mul (pwr x q) (pwr y q)) =
    47     mul (mul x (pwr x q)) (mul y (pwr y q))" by (simp add: mul_c)
    48 qed
    49 
    50 lemma pwr_pwr: "pwr (pwr x p) q = pwr x (p * q)"
    51 proof (induct p arbitrary: q)
    52   case 0
    53   show ?case using pwr_Suc mul_1 pwr_0 by (induct q) auto
    54 next
    55   case Suc
    56   thus ?case by (auto simp add: mul_pwr [symmetric] pwr_mul pwr_Suc)
    57 qed
    58 
    59 lemma semiring_ops:
    60   shows "TERM (add x y)" and "TERM (mul x y)" and "TERM (pwr x n)"
    61     and "TERM r0" and "TERM r1" .
    62 
    63 lemma semiring_rules:
    64   "add (mul a m) (mul b m) = mul (add a b) m"
    65   "add (mul a m) m = mul (add a r1) m"
    66   "add m (mul a m) = mul (add a r1) m"
    67   "add m m = mul (add r1 r1) m"
    68   "add r0 a = a"
    69   "add a r0 = a"
    70   "mul a b = mul b a"
    71   "mul (add a b) c = add (mul a c) (mul b c)"
    72   "mul r0 a = r0"
    73   "mul a r0 = r0"
    74   "mul r1 a = a"
    75   "mul a r1 = a"
    76   "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
    77   "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
    78   "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
    79   "mul (mul lx ly) rx = mul (mul lx rx) ly"
    80   "mul (mul lx ly) rx = mul lx (mul ly rx)"
    81   "mul lx (mul rx ry) = mul (mul lx rx) ry"
    82   "mul lx (mul rx ry) = mul rx (mul lx ry)"
    83   "add (add a b) (add c d) = add (add a c) (add b d)"
    84   "add (add a b) c = add a (add b c)"
    85   "add a (add c d) = add c (add a d)"
    86   "add (add a b) c = add (add a c) b"
    87   "add a c = add c a"
    88   "add a (add c d) = add (add a c) d"
    89   "mul (pwr x p) (pwr x q) = pwr x (p + q)"
    90   "mul x (pwr x q) = pwr x (Suc q)"
    91   "mul (pwr x q) x = pwr x (Suc q)"
    92   "mul x x = pwr x 2"
    93   "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    94   "pwr (pwr x p) q = pwr x (p * q)"
    95   "pwr x 0 = r1"
    96   "pwr x 1 = x"
    97   "mul x (add y z) = add (mul x y) (mul x z)"
    98   "pwr x (Suc q) = mul x (pwr x q)"
    99   "pwr x (2*n) = mul (pwr x n) (pwr x n)"
   100   "pwr x (Suc (2*n)) = mul x (mul (pwr x n) (pwr x n))"
   101 proof -
   102   show "add (mul a m) (mul b m) = mul (add a b) m" using mul_d mul_c by simp
   103 next show"add (mul a m) m = mul (add a r1) m" using mul_d mul_c mul_1 by simp
   104 next show "add m (mul a m) = mul (add a r1) m" using mul_c mul_d mul_1 add_c by simp
   105 next show "add m m = mul (add r1 r1) m" using mul_c mul_d mul_1 by simp
   106 next show "add r0 a = a" using add_0 by simp
   107 next show "add a r0 = a" using add_0 add_c by simp
   108 next show "mul a b = mul b a" using mul_c by simp
   109 next show "mul (add a b) c = add (mul a c) (mul b c)" using mul_c mul_d by simp
   110 next show "mul r0 a = r0" using mul_0 by simp
   111 next show "mul a r0 = r0" using mul_0 mul_c by simp
   112 next show "mul r1 a = a" using mul_1 by simp
   113 next show "mul a r1 = a" using mul_1 mul_c by simp
   114 next show "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
   115     using mul_c mul_a by simp
   116 next show "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
   117     using mul_a by simp
   118 next
   119   have "mul (mul lx ly) (mul rx ry) = mul (mul rx ry) (mul lx ly)" by (rule mul_c)
   120   also have "\<dots> = mul rx (mul ry (mul lx ly))" using mul_a by simp
   121   finally
   122   show "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
   123     using mul_c by simp
   124 next show "mul (mul lx ly) rx = mul (mul lx rx) ly" using mul_c mul_a by simp
   125 next
   126   show "mul (mul lx ly) rx = mul lx (mul ly rx)" by (simp add: mul_a)
   127 next show "mul lx (mul rx ry) = mul (mul lx rx) ry" by (simp add: mul_a )
   128 next show "mul lx (mul rx ry) = mul rx (mul lx ry)" by (simp add: mul_a,simp add: mul_c)
   129 next show "add (add a b) (add c d) = add (add a c) (add b d)"
   130     using add_c add_a by simp
   131 next show "add (add a b) c = add a (add b c)" using add_a by simp
   132 next show "add a (add c d) = add c (add a d)"
   133     apply (simp add: add_a) by (simp only: add_c)
   134 next show "add (add a b) c = add (add a c) b" using add_a add_c by simp
   135 next show "add a c = add c a" by (rule add_c)
   136 next show "add a (add c d) = add (add a c) d" using add_a by simp
   137 next show "mul (pwr x p) (pwr x q) = pwr x (p + q)" by (rule mul_pwr)
   138 next show "mul x (pwr x q) = pwr x (Suc q)" using pwr_Suc by simp
   139 next show "mul (pwr x q) x = pwr x (Suc q)" using pwr_Suc mul_c by simp
   140 next show "mul x x = pwr x 2" by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   141 next show "pwr (mul x y) q = mul (pwr x q) (pwr y q)" by (rule pwr_mul)
   142 next show "pwr (pwr x p) q = pwr x (p * q)" by (rule pwr_pwr)
   143 next show "pwr x 0 = r1" using pwr_0 .
   144 next show "pwr x 1 = x" unfolding One_nat_def by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   145 next show "mul x (add y z) = add (mul x y) (mul x z)" using mul_d by simp
   146 next show "pwr x (Suc q) = mul x (pwr x q)" using pwr_Suc by simp
   147 next show "pwr x (2 * n) = mul (pwr x n) (pwr x n)" by (simp add: nat_number' mul_pwr)
   148 next show "pwr x (Suc (2 * n)) = mul x (mul (pwr x n) (pwr x n))"
   149     by (simp add: nat_number' pwr_Suc mul_pwr)
   150 qed
   151 
   152 
   153 lemmas normalizing_semiring_axioms' =
   154   normalizing_semiring_axioms [normalizer
   155     semiring ops: semiring_ops
   156     semiring rules: semiring_rules]
   157 
   158 end
   159 
   160 sublocale comm_semiring_1
   161   < normalizing!: normalizing_semiring plus times power zero one
   162 proof
   163 qed (simp_all add: algebra_simps)
   164 
   165 ML {*
   166 local
   167 
   168 fun numeral_is_const ct = can HOLogic.dest_number (Thm.term_of ct);
   169 
   170 fun int_of_rat x =
   171   (case Rat.quotient_of_rat x of (i, 1) => i
   172   | _ => error "int_of_rat: bad int");
   173 
   174 val numeral_conv =
   175   Simplifier.rewrite (HOL_basic_ss addsimps @{thms semiring_norm}) then_conv
   176   Simplifier.rewrite (HOL_basic_ss addsimps
   177     (@{thms numeral_1_eq_1} @ @{thms numeral_0_eq_0} @ @{thms numerals(1-2)}));
   178 
   179 in
   180 
   181 fun normalizer_funs' key =
   182   Normalizer.funs key
   183    {is_const = fn phi => numeral_is_const,
   184     dest_const = fn phi => fn ct =>
   185       Rat.rat_of_int (snd
   186         (HOLogic.dest_number (Thm.term_of ct)
   187           handle TERM _ => error "ring_dest_const")),
   188     mk_const = fn phi => fn cT => fn x => Numeral.mk_cnumber cT (int_of_rat x),
   189     conv = fn phi => K numeral_conv}
   190 
   191 end
   192 *}
   193 
   194 declaration {* normalizer_funs' @{thm normalizing.normalizing_semiring_axioms'} *}
   195 
   196 locale normalizing_ring = normalizing_semiring +
   197   fixes sub :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   198     and neg :: "'a \<Rightarrow> 'a"
   199   assumes neg_mul: "neg x = mul (neg r1) x"
   200     and sub_add: "sub x y = add x (neg y)"
   201 begin
   202 
   203 lemma ring_ops: shows "TERM (sub x y)" and "TERM (neg x)" .
   204 
   205 lemmas ring_rules = neg_mul sub_add
   206 
   207 lemmas normalizing_ring_axioms' =
   208   normalizing_ring_axioms [normalizer
   209     semiring ops: semiring_ops
   210     semiring rules: semiring_rules
   211     ring ops: ring_ops
   212     ring rules: ring_rules]
   213 
   214 end
   215 
   216 (*FIXME add class*)
   217 interpretation normalizing!: normalizing_ring plus times power
   218   "0::'a::{comm_semiring_1,number_ring}" 1 minus uminus proof
   219 qed simp_all
   220 
   221 declaration {* normalizer_funs' @{thm normalizing.normalizing_ring_axioms'} *}
   222 
   223 locale normalizing_field = normalizing_ring +
   224   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   225     and inverse:: "'a \<Rightarrow> 'a"
   226   assumes divide_inverse: "divide x y = mul x (inverse y)"
   227      and inverse_divide: "inverse x = divide r1 x"
   228 begin
   229 
   230 lemma field_ops: shows "TERM (divide x y)" and "TERM (inverse x)" .
   231 
   232 lemmas field_rules = divide_inverse inverse_divide
   233 
   234 lemmas normalizing_field_axioms' =
   235   normalizing_field_axioms [normalizer
   236     semiring ops: semiring_ops
   237     semiring rules: semiring_rules
   238     ring ops: ring_ops
   239     ring rules: ring_rules
   240     field ops: field_ops
   241     field rules: field_rules]
   242 
   243 end
   244 
   245 locale normalizing_semiring_cancel = normalizing_semiring +
   246   assumes add_cancel: "add (x::'a) y = add x z \<longleftrightarrow> y = z"
   247   and add_mul_solve: "add (mul w y) (mul x z) =
   248     add (mul w z) (mul x y) \<longleftrightarrow> w = x \<or> y = z"
   249 begin
   250 
   251 lemma noteq_reduce: "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   252 proof-
   253   have "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> \<not> (a = b \<or> c = d)" by simp
   254   also have "\<dots> \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   255     using add_mul_solve by blast
   256   finally show "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   257     by simp
   258 qed
   259 
   260 lemma add_scale_eq_noteq: "\<lbrakk>r \<noteq> r0 ; (a = b) \<and> ~(c = d)\<rbrakk>
   261   \<Longrightarrow> add a (mul r c) \<noteq> add b (mul r d)"
   262 proof(clarify)
   263   assume nz: "r\<noteq> r0" and cnd: "c\<noteq>d"
   264     and eq: "add b (mul r c) = add b (mul r d)"
   265   hence "mul r c = mul r d" using cnd add_cancel by simp
   266   hence "add (mul r0 d) (mul r c) = add (mul r0 c) (mul r d)"
   267     using mul_0 add_cancel by simp
   268   thus "False" using add_mul_solve nz cnd by simp
   269 qed
   270 
   271 lemma add_r0_iff: " x = add x a \<longleftrightarrow> a = r0"
   272 proof-
   273   have "a = r0 \<longleftrightarrow> add x a = add x r0" by (simp add: add_cancel)
   274   thus "x = add x a \<longleftrightarrow> a = r0" by (auto simp add: add_c add_0)
   275 qed
   276 
   277 declare normalizing_semiring_axioms' [normalizer del]
   278 
   279 lemmas normalizing_semiring_cancel_axioms' =
   280   normalizing_semiring_cancel_axioms [normalizer
   281     semiring ops: semiring_ops
   282     semiring rules: semiring_rules
   283     idom rules: noteq_reduce add_scale_eq_noteq]
   284 
   285 end
   286 
   287 locale normalizing_ring_cancel = normalizing_semiring_cancel + normalizing_ring + 
   288   assumes subr0_iff: "sub x y = r0 \<longleftrightarrow> x = y"
   289 begin
   290 
   291 declare normalizing_ring_axioms' [normalizer del]
   292 
   293 lemmas normalizing_ring_cancel_axioms' = normalizing_ring_cancel_axioms [normalizer
   294   semiring ops: semiring_ops
   295   semiring rules: semiring_rules
   296   ring ops: ring_ops
   297   ring rules: ring_rules
   298   idom rules: noteq_reduce add_scale_eq_noteq
   299   ideal rules: subr0_iff add_r0_iff]
   300 
   301 end
   302 
   303 lemma (in no_zero_divisors) prod_eq_zero_eq_zero:
   304   assumes "a * b = 0" and "a \<noteq> 0"
   305   shows "b = 0"
   306 proof (rule classical)
   307   assume "b \<noteq> 0" with `a \<noteq> 0` no_zero_divisors have "a * b \<noteq> 0" by blast
   308   with `a * b = 0` show ?thesis by simp
   309 qed
   310 
   311 (*FIXME introduce class*)
   312 interpretation normalizing!: normalizing_ring_cancel
   313   "op +" "op *" "op ^" "0::'a::{idom,number_ring}" "1" "op -" "uminus"
   314 proof(unfold_locales, simp add: algebra_simps, auto)
   315   fix w x y z ::"'a::{idom,number_ring}"
   316   assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   317   hence ynz': "y - z \<noteq> 0" by simp
   318   from p have "w * y + x* z - w*z - x*y = 0" by simp
   319   hence "w* (y - z) - x * (y - z) = 0" by (simp add: algebra_simps)
   320   hence "(y - z) * (w - x) = 0" by (simp add: algebra_simps)
   321   with  prod_eq_zero_eq_zero [OF _ ynz']
   322   have "w - x = 0" by blast
   323   thus "w = x"  by simp
   324 qed
   325 
   326 declaration {* normalizer_funs' @{thm normalizing.normalizing_ring_cancel_axioms'} *}
   327 
   328 interpretation normalizing_nat!: normalizing_semiring_cancel
   329   "op +" "op *" "op ^" "0::nat" "1"
   330 proof (unfold_locales, simp add: algebra_simps)
   331   fix w x y z ::"nat"
   332   { assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   333     hence "y < z \<or> y > z" by arith
   334     moreover {
   335       assume lt:"y <z" hence "\<exists>k. z = y + k \<and> k > 0" by (rule_tac x="z - y" in exI, auto)
   336       then obtain k where kp: "k>0" and yz:"z = y + k" by blast
   337       from p have "(w * y + x *y) + x*k = (w * y + x*y) + w*k" by (simp add: yz algebra_simps)
   338       hence "x*k = w*k" by simp
   339       hence "w = x" using kp by simp }
   340     moreover {
   341       assume lt: "y >z" hence "\<exists>k. y = z + k \<and> k>0" by (rule_tac x="y - z" in exI, auto)
   342       then obtain k where kp: "k>0" and yz:"y = z + k" by blast
   343       from p have "(w * z + x *z) + w*k = (w * z + x*z) + x*k" by (simp add: yz algebra_simps)
   344       hence "w*k = x*k" by simp
   345       hence "w = x" using kp by simp }
   346     ultimately have "w=x" by blast }
   347   thus "(w * y + x * z = w * z + x * y) = (w = x \<or> y = z)" by auto
   348 qed
   349 
   350 declaration {* normalizer_funs' @{thm normalizing_nat.normalizing_semiring_cancel_axioms'} *}
   351 
   352 locale normalizing_field_cancel = normalizing_ring_cancel + normalizing_field
   353 begin
   354 
   355 declare normalizing_field_axioms' [normalizer del]
   356 
   357 lemmas normalizing_field_cancel_axioms' = normalizing_field_cancel_axioms [normalizer
   358   semiring ops: semiring_ops
   359   semiring rules: semiring_rules
   360   ring ops: ring_ops
   361   ring rules: ring_rules
   362   field ops: field_ops
   363   field rules: field_rules
   364   idom rules: noteq_reduce add_scale_eq_noteq
   365   ideal rules: subr0_iff add_r0_iff]
   366 
   367 end
   368 
   369 (*FIXME introduce class*)
   370 interpretation normalizing!: normalizing_field_cancel "op +" "op *" "op ^"
   371   "0::'a::{field,number_ring}" "1" "op -" "uminus" "op /" "inverse"
   372 apply (unfold_locales) by (simp_all add: divide_inverse)
   373 
   374 lemma divide_Numeral1: "(x::'a::{field, number_ring}) / Numeral1 = x" by simp
   375 lemma divide_Numeral0: "(x::'a::{field_inverse_zero, number_ring}) / Numeral0 = 0"
   376   by simp
   377 lemma mult_frac_frac: "((x::'a::field_inverse_zero) / y) * (z / w) = (x*z) / (y*w)"
   378   by simp
   379 lemma mult_frac_num: "((x::'a::field_inverse_zero) / y) * z  = (x*z) / y"
   380   by (fact times_divide_eq_left)
   381 lemma mult_num_frac: "((x::'a::field_inverse_zero) / y) * z  = (x*z) / y"
   382   by (fact times_divide_eq_left)
   383 
   384 lemma Numeral1_eq1_nat: "(1::nat) = Numeral1" by simp
   385 
   386 lemma add_frac_num: "y\<noteq> 0 \<Longrightarrow> (x::'a::field_inverse_zero) / y + z = (x + z*y) / y"
   387   by (simp add: add_divide_distrib)
   388 lemma add_num_frac: "y\<noteq> 0 \<Longrightarrow> z + (x::'a::field_inverse_zero) / y = (x + z*y) / y"
   389   by (simp add: add_divide_distrib)
   390 
   391 ML {* 
   392 local
   393  val zr = @{cpat "0"}
   394  val zT = ctyp_of_term zr
   395  val geq = @{cpat "op ="}
   396  val eqT = Thm.dest_ctyp (ctyp_of_term geq) |> hd
   397  val add_frac_eq = mk_meta_eq @{thm "add_frac_eq"}
   398  val add_frac_num = mk_meta_eq @{thm "add_frac_num"}
   399  val add_num_frac = mk_meta_eq @{thm "add_num_frac"}
   400 
   401  fun prove_nz ss T t =
   402     let
   403       val z = instantiate_cterm ([(zT,T)],[]) zr
   404       val eq = instantiate_cterm ([(eqT,T)],[]) geq
   405       val th = Simplifier.rewrite (ss addsimps @{thms simp_thms})
   406            (Thm.capply @{cterm "Trueprop"} (Thm.capply @{cterm "Not"}
   407                   (Thm.capply (Thm.capply eq t) z)))
   408     in equal_elim (symmetric th) TrueI
   409     end
   410 
   411  fun proc phi ss ct =
   412   let
   413     val ((x,y),(w,z)) =
   414          (Thm.dest_binop #> (fn (a,b) => (Thm.dest_binop a, Thm.dest_binop b))) ct
   415     val _ = map (HOLogic.dest_number o term_of) [x,y,z,w]
   416     val T = ctyp_of_term x
   417     val [y_nz, z_nz] = map (prove_nz ss T) [y, z]
   418     val th = instantiate' [SOME T] (map SOME [y,z,x,w]) add_frac_eq
   419   in SOME (implies_elim (implies_elim th y_nz) z_nz)
   420   end
   421   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   422 
   423  fun proc2 phi ss ct =
   424   let
   425     val (l,r) = Thm.dest_binop ct
   426     val T = ctyp_of_term l
   427   in (case (term_of l, term_of r) of
   428       (Const(@{const_name Rings.divide},_)$_$_, _) =>
   429         let val (x,y) = Thm.dest_binop l val z = r
   430             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   431             val ynz = prove_nz ss T y
   432         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,x,z]) add_frac_num) ynz)
   433         end
   434      | (_, Const (@{const_name Rings.divide},_)$_$_) =>
   435         let val (x,y) = Thm.dest_binop r val z = l
   436             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   437             val ynz = prove_nz ss T y
   438         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,z,x]) add_num_frac) ynz)
   439         end
   440      | _ => NONE)
   441   end
   442   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   443 
   444  fun is_number (Const(@{const_name Rings.divide},_)$a$b) = is_number a andalso is_number b
   445    | is_number t = can HOLogic.dest_number t
   446 
   447  val is_number = is_number o term_of
   448 
   449  fun proc3 phi ss ct =
   450   (case term_of ct of
   451     Const(@{const_name Orderings.less},_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   452       let
   453         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   454         val _ = map is_number [a,b,c]
   455         val T = ctyp_of_term c
   456         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_less_eq"}
   457       in SOME (mk_meta_eq th) end
   458   | Const(@{const_name Orderings.less_eq},_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   459       let
   460         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   461         val _ = map is_number [a,b,c]
   462         val T = ctyp_of_term c
   463         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_le_eq"}
   464       in SOME (mk_meta_eq th) end
   465   | Const("op =",_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   466       let
   467         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   468         val _ = map is_number [a,b,c]
   469         val T = ctyp_of_term c
   470         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_eq_eq"}
   471       in SOME (mk_meta_eq th) end
   472   | Const(@{const_name Orderings.less},_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   473     let
   474       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   475         val _ = map is_number [a,b,c]
   476         val T = ctyp_of_term c
   477         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "less_divide_eq"}
   478       in SOME (mk_meta_eq th) end
   479   | Const(@{const_name Orderings.less_eq},_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   480     let
   481       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   482         val _ = map is_number [a,b,c]
   483         val T = ctyp_of_term c
   484         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "le_divide_eq"}
   485       in SOME (mk_meta_eq th) end
   486   | Const("op =",_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   487     let
   488       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   489         val _ = map is_number [a,b,c]
   490         val T = ctyp_of_term c
   491         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "eq_divide_eq"}
   492       in SOME (mk_meta_eq th) end
   493   | _ => NONE)
   494   handle TERM _ => NONE | CTERM _ => NONE | THM _ => NONE
   495 
   496 val add_frac_frac_simproc =
   497        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + (?w::?'a::field)/?z"}],
   498                      name = "add_frac_frac_simproc",
   499                      proc = proc, identifier = []}
   500 
   501 val add_frac_num_simproc =
   502        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + ?z"}, @{cpat "?z + (?x::?'a::field)/?y"}],
   503                      name = "add_frac_num_simproc",
   504                      proc = proc2, identifier = []}
   505 
   506 val ord_frac_simproc =
   507   make_simproc
   508     {lhss = [@{cpat "(?a::(?'a::{field, ord}))/?b < ?c"},
   509              @{cpat "(?a::(?'a::{field, ord}))/?b \<le> ?c"},
   510              @{cpat "?c < (?a::(?'a::{field, ord}))/?b"},
   511              @{cpat "?c \<le> (?a::(?'a::{field, ord}))/?b"},
   512              @{cpat "?c = ((?a::(?'a::{field, ord}))/?b)"},
   513              @{cpat "((?a::(?'a::{field, ord}))/ ?b) = ?c"}],
   514              name = "ord_frac_simproc", proc = proc3, identifier = []}
   515 
   516 val ths = [@{thm "mult_numeral_1"}, @{thm "mult_numeral_1_right"},
   517            @{thm "divide_Numeral1"},
   518            @{thm "divide_zero"}, @{thm "divide_Numeral0"},
   519            @{thm "divide_divide_eq_left"}, @{thm "mult_frac_frac"},
   520            @{thm "mult_num_frac"}, @{thm "mult_frac_num"},
   521            @{thm "mult_frac_frac"}, @{thm "times_divide_eq_right"},
   522            @{thm "times_divide_eq_left"}, @{thm "divide_divide_eq_right"},
   523            @{thm "diff_def"}, @{thm "minus_divide_left"},
   524            @{thm "Numeral1_eq1_nat"}, @{thm "add_divide_distrib"} RS sym,
   525            @{thm field_divide_inverse} RS sym, @{thm inverse_divide}, 
   526            Conv.fconv_rule (Conv.arg_conv (Conv.arg1_conv (Conv.rewr_conv (mk_meta_eq @{thm mult_commute}))))   
   527            (@{thm field_divide_inverse} RS sym)]
   528 
   529 in
   530 
   531 val field_comp_conv = (Simplifier.rewrite
   532 (HOL_basic_ss addsimps @{thms "semiring_norm"}
   533               addsimps ths addsimps @{thms simp_thms}
   534               addsimprocs Numeral_Simprocs.field_cancel_numeral_factors
   535                addsimprocs [add_frac_frac_simproc, add_frac_num_simproc,
   536                             ord_frac_simproc]
   537                 addcongs [@{thm "if_weak_cong"}]))
   538 then_conv (Simplifier.rewrite (HOL_basic_ss addsimps
   539   [@{thm numeral_1_eq_1},@{thm numeral_0_eq_0}] @ @{thms numerals(1-2)}))
   540 
   541 end
   542 *}
   543 
   544 declaration {*
   545 let
   546 
   547 fun numeral_is_const ct =
   548   case term_of ct of
   549    Const (@{const_name Rings.divide},_) $ a $ b =>
   550      can HOLogic.dest_number a andalso can HOLogic.dest_number b
   551  | Const (@{const_name Rings.inverse},_)$t => can HOLogic.dest_number t
   552  | t => can HOLogic.dest_number t
   553 
   554 fun dest_const ct = ((case term_of ct of
   555    Const (@{const_name Rings.divide},_) $ a $ b=>
   556     Rat.rat_of_quotient (snd (HOLogic.dest_number a), snd (HOLogic.dest_number b))
   557  | Const (@{const_name Rings.inverse},_)$t => 
   558                Rat.inv (Rat.rat_of_int (snd (HOLogic.dest_number t)))
   559  | t => Rat.rat_of_int (snd (HOLogic.dest_number t))) 
   560    handle TERM _ => error "ring_dest_const")
   561 
   562 fun mk_const phi cT x =
   563  let val (a, b) = Rat.quotient_of_rat x
   564  in if b = 1 then Numeral.mk_cnumber cT a
   565     else Thm.capply
   566          (Thm.capply (Drule.cterm_rule (instantiate' [SOME cT] []) @{cpat "op /"})
   567                      (Numeral.mk_cnumber cT a))
   568          (Numeral.mk_cnumber cT b)
   569   end
   570 
   571 in
   572  
   573   Normalizer.funs @{thm normalizing.normalizing_field_cancel_axioms'}
   574    {is_const = K numeral_is_const,
   575     dest_const = K dest_const,
   576     mk_const = mk_const,
   577     conv = K (K field_comp_conv)}
   578 
   579 end
   580 *}
   581 
   582 lemmas comp_arith = semiring_norm (*FIXME*)
   583 
   584 
   585 subsection {* Groebner Bases *}
   586 
   587 lemmas bool_simps = simp_thms(1-34)
   588 
   589 lemma dnf:
   590     "(P & (Q | R)) = ((P&Q) | (P&R))" "((Q | R) & P) = ((Q&P) | (R&P))"
   591     "(P \<and> Q) = (Q \<and> P)" "(P \<or> Q) = (Q \<or> P)"
   592   by blast+
   593 
   594 lemmas weak_dnf_simps = dnf bool_simps
   595 
   596 lemma nnf_simps:
   597     "(\<not>(P \<and> Q)) = (\<not>P \<or> \<not>Q)" "(\<not>(P \<or> Q)) = (\<not>P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
   598     "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not> \<not>(P)) = P"
   599   by blast+
   600 
   601 lemma PFalse:
   602     "P \<equiv> False \<Longrightarrow> \<not> P"
   603     "\<not> P \<Longrightarrow> (P \<equiv> False)"
   604   by auto
   605 
   606 ML {*
   607 structure Algebra_Simplification = Named_Thms(
   608   val name = "algebra"
   609   val description = "pre-simplification rules for algebraic methods"
   610 )
   611 *}
   612 
   613 setup Algebra_Simplification.setup
   614 
   615 declare dvd_def[algebra]
   616 declare dvd_eq_mod_eq_0[symmetric, algebra]
   617 declare mod_div_trivial[algebra]
   618 declare mod_mod_trivial[algebra]
   619 declare conjunct1[OF DIVISION_BY_ZERO, algebra]
   620 declare conjunct2[OF DIVISION_BY_ZERO, algebra]
   621 declare zmod_zdiv_equality[symmetric,algebra]
   622 declare zdiv_zmod_equality[symmetric, algebra]
   623 declare zdiv_zminus_zminus[algebra]
   624 declare zmod_zminus_zminus[algebra]
   625 declare zdiv_zminus2[algebra]
   626 declare zmod_zminus2[algebra]
   627 declare zdiv_zero[algebra]
   628 declare zmod_zero[algebra]
   629 declare mod_by_1[algebra]
   630 declare div_by_1[algebra]
   631 declare zmod_minus1_right[algebra]
   632 declare zdiv_minus1_right[algebra]
   633 declare mod_div_trivial[algebra]
   634 declare mod_mod_trivial[algebra]
   635 declare mod_mult_self2_is_0[algebra]
   636 declare mod_mult_self1_is_0[algebra]
   637 declare zmod_eq_0_iff[algebra]
   638 declare dvd_0_left_iff[algebra]
   639 declare zdvd1_eq[algebra]
   640 declare zmod_eq_dvd_iff[algebra]
   641 declare nat_mod_eq_iff[algebra]
   642 
   643 use "Tools/Groebner_Basis/groebner.ML"
   644 
   645 method_setup algebra =
   646 {*
   647 let
   648  fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   649  val addN = "add"
   650  val delN = "del"
   651  val any_keyword = keyword addN || keyword delN
   652  val thms = Scan.repeat (Scan.unless any_keyword Attrib.multi_thm) >> flat;
   653 in
   654   ((Scan.optional (keyword addN |-- thms) []) -- 
   655    (Scan.optional (keyword delN |-- thms) [])) >>
   656   (fn (add_ths, del_ths) => fn ctxt =>
   657        SIMPLE_METHOD' (Groebner.algebra_tac add_ths del_ths ctxt))
   658 end
   659 *} "solve polynomial equations over (semi)rings and ideal membership problems using Groebner bases"
   660 
   661 end