src/HOL/Probability/Bochner_Integration.thy
author hoelzl
Thu Jun 12 15:47:36 2014 +0200 (2014-06-12)
changeset 57235 b0b9a10e4bf4
parent 57166 5cfcc616d485
child 57275 0ddb5b755cdc
permissions -rw-r--r--
properties of Erlang and exponentially distributed random variables (by Sudeep Kanav)
     1 (*  Title:      HOL/Probability/Bochner_Integration.thy
     2     Author:     Johannes Hölzl, TU München
     3 *)
     4 
     5 header {* Bochner Integration for Vector-Valued Functions *}
     6 
     7 theory Bochner_Integration
     8   imports Finite_Product_Measure
     9 begin
    10 
    11 text {*
    12 
    13 In the following development of the Bochner integral we use second countable topologies instead
    14 of separable spaces. A second countable topology is also separable.
    15 
    16 *}
    17 
    18 lemma borel_measurable_implies_sequence_metric:
    19   fixes f :: "'a \<Rightarrow> 'b :: {metric_space, second_countable_topology}"
    20   assumes [measurable]: "f \<in> borel_measurable M"
    21   shows "\<exists>F. (\<forall>i. simple_function M (F i)) \<and> (\<forall>x\<in>space M. (\<lambda>i. F i x) ----> f x) \<and>
    22     (\<forall>i. \<forall>x\<in>space M. dist (F i x) z \<le> 2 * dist (f x) z)"
    23 proof -
    24   obtain D :: "'b set" where "countable D" and D: "\<And>X. open X \<Longrightarrow> X \<noteq> {} \<Longrightarrow> \<exists>d\<in>D. d \<in> X"
    25     by (erule countable_dense_setE)
    26 
    27   def e \<equiv> "from_nat_into D"
    28   { fix n x
    29     obtain d where "d \<in> D" and d: "d \<in> ball x (1 / Suc n)"
    30       using D[of "ball x (1 / Suc n)"] by auto
    31     from `d \<in> D` D[of UNIV] `countable D` obtain i where "d = e i"
    32       unfolding e_def by (auto dest: from_nat_into_surj)
    33     with d have "\<exists>i. dist x (e i) < 1 / Suc n"
    34       by auto }
    35   note e = this
    36 
    37   def A \<equiv> "\<lambda>m n. {x\<in>space M. dist (f x) (e n) < 1 / (Suc m) \<and> 1 / (Suc m) \<le> dist (f x) z}"
    38   def B \<equiv> "\<lambda>m. disjointed (A m)"
    39   
    40   def m \<equiv> "\<lambda>N x. Max {m::nat. m \<le> N \<and> x \<in> (\<Union>n\<le>N. B m n)}"
    41   def F \<equiv> "\<lambda>N::nat. \<lambda>x. if (\<exists>m\<le>N. x \<in> (\<Union>n\<le>N. B m n)) \<and> (\<exists>n\<le>N. x \<in> B (m N x) n) 
    42     then e (LEAST n. x \<in> B (m N x) n) else z"
    43 
    44   have B_imp_A[intro, simp]: "\<And>x m n. x \<in> B m n \<Longrightarrow> x \<in> A m n"
    45     using disjointed_subset[of "A m" for m] unfolding B_def by auto
    46 
    47   { fix m
    48     have "\<And>n. A m n \<in> sets M"
    49       by (auto simp: A_def)
    50     then have "\<And>n. B m n \<in> sets M"
    51       using sets.range_disjointed_sets[of "A m" M] by (auto simp: B_def) }
    52   note this[measurable]
    53 
    54   { fix N i x assume "\<exists>m\<le>N. x \<in> (\<Union>n\<le>N. B m n)"
    55     then have "m N x \<in> {m::nat. m \<le> N \<and> x \<in> (\<Union>n\<le>N. B m n)}"
    56       unfolding m_def by (intro Max_in) auto
    57     then have "m N x \<le> N" "\<exists>n\<le>N. x \<in> B (m N x) n"
    58       by auto }
    59   note m = this
    60 
    61   { fix j N i x assume "j \<le> N" "i \<le> N" "x \<in> B j i"
    62     then have "j \<le> m N x"
    63       unfolding m_def by (intro Max_ge) auto }
    64   note m_upper = this
    65 
    66   show ?thesis
    67     unfolding simple_function_def
    68   proof (safe intro!: exI[of _ F])
    69     have [measurable]: "\<And>i. F i \<in> borel_measurable M"
    70       unfolding F_def m_def by measurable
    71     show "\<And>x i. F i -` {x} \<inter> space M \<in> sets M"
    72       by measurable
    73 
    74     { fix i
    75       { fix n x assume "x \<in> B (m i x) n"
    76         then have "(LEAST n. x \<in> B (m i x) n) \<le> n"
    77           by (intro Least_le)
    78         also assume "n \<le> i" 
    79         finally have "(LEAST n. x \<in> B (m i x) n) \<le> i" . }
    80       then have "F i ` space M \<subseteq> {z} \<union> e ` {.. i}"
    81         by (auto simp: F_def)
    82       then show "finite (F i ` space M)"
    83         by (rule finite_subset) auto }
    84     
    85     { fix N i n x assume "i \<le> N" "n \<le> N" "x \<in> B i n"
    86       then have 1: "\<exists>m\<le>N. x \<in> (\<Union> n\<le>N. B m n)" by auto
    87       from m[OF this] obtain n where n: "m N x \<le> N" "n \<le> N" "x \<in> B (m N x) n" by auto
    88       moreover
    89       def L \<equiv> "LEAST n. x \<in> B (m N x) n"
    90       have "dist (f x) (e L) < 1 / Suc (m N x)"
    91       proof -
    92         have "x \<in> B (m N x) L"
    93           using n(3) unfolding L_def by (rule LeastI)
    94         then have "x \<in> A (m N x) L"
    95           by auto
    96         then show ?thesis
    97           unfolding A_def by simp
    98       qed
    99       ultimately have "dist (f x) (F N x) < 1 / Suc (m N x)"
   100         by (auto simp add: F_def L_def) }
   101     note * = this
   102 
   103     fix x assume "x \<in> space M"
   104     show "(\<lambda>i. F i x) ----> f x"
   105     proof cases
   106       assume "f x = z"
   107       then have "\<And>i n. x \<notin> A i n"
   108         unfolding A_def by auto
   109       then have "\<And>i. F i x = z"
   110         by (auto simp: F_def)
   111       then show ?thesis
   112         using `f x = z` by auto
   113     next
   114       assume "f x \<noteq> z"
   115 
   116       show ?thesis
   117       proof (rule tendstoI)
   118         fix e :: real assume "0 < e"
   119         with `f x \<noteq> z` obtain n where "1 / Suc n < e" "1 / Suc n < dist (f x) z"
   120           by (metis dist_nz order_less_trans neq_iff nat_approx_posE)
   121         with `x\<in>space M` `f x \<noteq> z` have "x \<in> (\<Union>i. B n i)"
   122           unfolding A_def B_def UN_disjointed_eq using e by auto
   123         then obtain i where i: "x \<in> B n i" by auto
   124 
   125         show "eventually (\<lambda>i. dist (F i x) (f x) < e) sequentially"
   126           using eventually_ge_at_top[of "max n i"]
   127         proof eventually_elim
   128           fix j assume j: "max n i \<le> j"
   129           with i have "dist (f x) (F j x) < 1 / Suc (m j x)"
   130             by (intro *[OF _ _ i]) auto
   131           also have "\<dots> \<le> 1 / Suc n"
   132             using j m_upper[OF _ _ i]
   133             by (auto simp: field_simps)
   134           also note `1 / Suc n < e`
   135           finally show "dist (F j x) (f x) < e"
   136             by (simp add: less_imp_le dist_commute)
   137         qed
   138       qed
   139     qed
   140     fix i 
   141     { fix n m assume "x \<in> A n m"
   142       then have "dist (e m) (f x) + dist (f x) z \<le> 2 * dist (f x) z"
   143         unfolding A_def by (auto simp: dist_commute)
   144       also have "dist (e m) z \<le> dist (e m) (f x) + dist (f x) z"
   145         by (rule dist_triangle)
   146       finally (xtrans) have "dist (e m) z \<le> 2 * dist (f x) z" . }
   147     then show "dist (F i x) z \<le> 2 * dist (f x) z"
   148       unfolding F_def
   149       apply auto
   150       apply (rule LeastI2)
   151       apply auto
   152       done
   153   qed
   154 qed
   155 
   156 lemma real_indicator: "real (indicator A x :: ereal) = indicator A x"
   157   unfolding indicator_def by auto
   158 
   159 lemma split_indicator_asm:
   160   "P (indicator S x) \<longleftrightarrow> \<not> ((x \<in> S \<and> \<not> P 1) \<or> (x \<notin> S \<and> \<not> P 0))"
   161   unfolding indicator_def by auto
   162 
   163 lemma
   164   fixes f :: "'a \<Rightarrow> 'b::semiring_1" assumes "finite A"
   165   shows setsum_mult_indicator[simp]: "(\<Sum>x \<in> A. f x * indicator (B x) (g x)) = (\<Sum>x\<in>{x\<in>A. g x \<in> B x}. f x)"
   166   and setsum_indicator_mult[simp]: "(\<Sum>x \<in> A. indicator (B x) (g x) * f x) = (\<Sum>x\<in>{x\<in>A. g x \<in> B x}. f x)"
   167   unfolding indicator_def
   168   using assms by (auto intro!: setsum_mono_zero_cong_right split: split_if_asm)
   169 
   170 lemma borel_measurable_induct_real[consumes 2, case_names set mult add seq]:
   171   fixes P :: "('a \<Rightarrow> real) \<Rightarrow> bool"
   172   assumes u: "u \<in> borel_measurable M" "\<And>x. 0 \<le> u x"
   173   assumes set: "\<And>A. A \<in> sets M \<Longrightarrow> P (indicator A)"
   174   assumes mult: "\<And>u c. 0 \<le> c \<Longrightarrow> u \<in> borel_measurable M \<Longrightarrow> (\<And>x. 0 \<le> u x) \<Longrightarrow> P u \<Longrightarrow> P (\<lambda>x. c * u x)"
   175   assumes add: "\<And>u v. u \<in> borel_measurable M \<Longrightarrow> (\<And>x. 0 \<le> u x) \<Longrightarrow> P u \<Longrightarrow> v \<in> borel_measurable M \<Longrightarrow> (\<And>x. 0 \<le> v x) \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> u x = 0 \<or> v x = 0) \<Longrightarrow> P v \<Longrightarrow> P (\<lambda>x. v x + u x)"
   176   assumes seq: "\<And>U. (\<And>i. U i \<in> borel_measurable M) \<Longrightarrow> (\<And>i x. 0 \<le> U i x) \<Longrightarrow> (\<And>i. P (U i)) \<Longrightarrow> incseq U \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. U i x) ----> u x) \<Longrightarrow> P u"
   177   shows "P u"
   178 proof -
   179   have "(\<lambda>x. ereal (u x)) \<in> borel_measurable M" using u by auto
   180   from borel_measurable_implies_simple_function_sequence'[OF this]
   181   obtain U where U: "\<And>i. simple_function M (U i)" "incseq U" "\<And>i. \<infinity> \<notin> range (U i)" and
   182     sup: "\<And>x. (SUP i. U i x) = max 0 (ereal (u x))" and nn: "\<And>i x. 0 \<le> U i x"
   183     by blast
   184 
   185   def U' \<equiv> "\<lambda>i x. indicator (space M) x * real (U i x)"
   186   then have U'_sf[measurable]: "\<And>i. simple_function M (U' i)"
   187     using U by (auto intro!: simple_function_compose1[where g=real])
   188 
   189   show "P u"
   190   proof (rule seq)
   191     fix i show "U' i \<in> borel_measurable M" "\<And>x. 0 \<le> U' i x"
   192       using U nn by (auto
   193           intro: borel_measurable_simple_function 
   194           intro!: borel_measurable_real_of_ereal real_of_ereal_pos borel_measurable_times
   195           simp: U'_def zero_le_mult_iff)
   196     show "incseq U'"
   197       using U(2,3) nn
   198       by (auto simp: incseq_def le_fun_def image_iff eq_commute U'_def indicator_def
   199                intro!: real_of_ereal_positive_mono)
   200   next
   201     fix x assume x: "x \<in> space M"
   202     have "(\<lambda>i. U i x) ----> (SUP i. U i x)"
   203       using U(2) by (intro LIMSEQ_SUP) (auto simp: incseq_def le_fun_def)
   204     moreover have "(\<lambda>i. U i x) = (\<lambda>i. ereal (U' i x))"
   205       using x nn U(3) by (auto simp: fun_eq_iff U'_def ereal_real image_iff eq_commute)
   206     moreover have "(SUP i. U i x) = ereal (u x)"
   207       using sup u(2) by (simp add: max_def)
   208     ultimately show "(\<lambda>i. U' i x) ----> u x" 
   209       by simp
   210   next
   211     fix i
   212     have "U' i ` space M \<subseteq> real ` (U i ` space M)" "finite (U i ` space M)"
   213       unfolding U'_def using U(1) by (auto dest: simple_functionD)
   214     then have fin: "finite (U' i ` space M)"
   215       by (metis finite_subset finite_imageI)
   216     moreover have "\<And>z. {y. U' i z = y \<and> y \<in> U' i ` space M \<and> z \<in> space M} = (if z \<in> space M then {U' i z} else {})"
   217       by auto
   218     ultimately have U': "(\<lambda>z. \<Sum>y\<in>U' i`space M. y * indicator {x\<in>space M. U' i x = y} z) = U' i"
   219       by (simp add: U'_def fun_eq_iff)
   220     have "\<And>x. x \<in> U' i ` space M \<Longrightarrow> 0 \<le> x"
   221       using nn by (auto simp: U'_def real_of_ereal_pos)
   222     with fin have "P (\<lambda>z. \<Sum>y\<in>U' i`space M. y * indicator {x\<in>space M. U' i x = y} z)"
   223     proof induct
   224       case empty from set[of "{}"] show ?case
   225         by (simp add: indicator_def[abs_def])
   226     next
   227       case (insert x F)
   228       then show ?case
   229         by (auto intro!: add mult set setsum_nonneg split: split_indicator split_indicator_asm
   230                  simp del: setsum_mult_indicator simp: setsum_nonneg_eq_0_iff )
   231     qed
   232     with U' show "P (U' i)" by simp
   233   qed
   234 qed
   235 
   236 lemma scaleR_cong_right:
   237   fixes x :: "'a :: real_vector"
   238   shows "(x \<noteq> 0 \<Longrightarrow> r = p) \<Longrightarrow> r *\<^sub>R x = p *\<^sub>R x"
   239   by (cases "x = 0") auto
   240 
   241 inductive simple_bochner_integrable :: "'a measure \<Rightarrow> ('a \<Rightarrow> 'b::real_vector) \<Rightarrow> bool" for M f where
   242   "simple_function M f \<Longrightarrow> emeasure M {y\<in>space M. f y \<noteq> 0} \<noteq> \<infinity> \<Longrightarrow>
   243     simple_bochner_integrable M f"
   244 
   245 lemma simple_bochner_integrable_compose2:
   246   assumes p_0: "p 0 0 = 0"
   247   shows "simple_bochner_integrable M f \<Longrightarrow> simple_bochner_integrable M g \<Longrightarrow>
   248     simple_bochner_integrable M (\<lambda>x. p (f x) (g x))"
   249 proof (safe intro!: simple_bochner_integrable.intros elim!: simple_bochner_integrable.cases del: notI)
   250   assume sf: "simple_function M f" "simple_function M g"
   251   then show "simple_function M (\<lambda>x. p (f x) (g x))"
   252     by (rule simple_function_compose2)
   253 
   254   from sf have [measurable]:
   255       "f \<in> measurable M (count_space UNIV)"
   256       "g \<in> measurable M (count_space UNIV)"
   257     by (auto intro: measurable_simple_function)
   258 
   259   assume fin: "emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity>" "emeasure M {y \<in> space M. g y \<noteq> 0} \<noteq> \<infinity>"
   260    
   261   have "emeasure M {x\<in>space M. p (f x) (g x) \<noteq> 0} \<le>
   262       emeasure M ({x\<in>space M. f x \<noteq> 0} \<union> {x\<in>space M. g x \<noteq> 0})"
   263     by (intro emeasure_mono) (auto simp: p_0)
   264   also have "\<dots> \<le> emeasure M {x\<in>space M. f x \<noteq> 0} + emeasure M {x\<in>space M. g x \<noteq> 0}"
   265     by (intro emeasure_subadditive) auto
   266   finally show "emeasure M {y \<in> space M. p (f y) (g y) \<noteq> 0} \<noteq> \<infinity>"
   267     using fin by auto
   268 qed
   269 
   270 lemma simple_function_finite_support:
   271   assumes f: "simple_function M f" and fin: "(\<integral>\<^sup>+x. f x \<partial>M) < \<infinity>" and nn: "\<And>x. 0 \<le> f x"
   272   shows "emeasure M {x\<in>space M. f x \<noteq> 0} \<noteq> \<infinity>"
   273 proof cases
   274   from f have meas[measurable]: "f \<in> borel_measurable M"
   275     by (rule borel_measurable_simple_function)
   276 
   277   assume non_empty: "\<exists>x\<in>space M. f x \<noteq> 0"
   278 
   279   def m \<equiv> "Min (f`space M - {0})"
   280   have "m \<in> f`space M - {0}"
   281     unfolding m_def using f non_empty by (intro Min_in) (auto simp: simple_function_def)
   282   then have m: "0 < m"
   283     using nn by (auto simp: less_le)
   284 
   285   from m have "m * emeasure M {x\<in>space M. 0 \<noteq> f x} = 
   286     (\<integral>\<^sup>+x. m * indicator {x\<in>space M. 0 \<noteq> f x} x \<partial>M)"
   287     using f by (intro nn_integral_cmult_indicator[symmetric]) auto
   288   also have "\<dots> \<le> (\<integral>\<^sup>+x. f x \<partial>M)"
   289     using AE_space
   290   proof (intro nn_integral_mono_AE, eventually_elim)
   291     fix x assume "x \<in> space M"
   292     with nn show "m * indicator {x \<in> space M. 0 \<noteq> f x} x \<le> f x"
   293       using f by (auto split: split_indicator simp: simple_function_def m_def)
   294   qed
   295   also note `\<dots> < \<infinity>`
   296   finally show ?thesis
   297     using m by auto 
   298 next
   299   assume "\<not> (\<exists>x\<in>space M. f x \<noteq> 0)"
   300   with nn have *: "{x\<in>space M. f x \<noteq> 0} = {}"
   301     by auto
   302   show ?thesis unfolding * by simp
   303 qed
   304 
   305 lemma simple_bochner_integrableI_bounded:
   306   assumes f: "simple_function M f" and fin: "(\<integral>\<^sup>+x. norm (f x) \<partial>M) < \<infinity>"
   307   shows "simple_bochner_integrable M f"
   308 proof
   309   have "emeasure M {y \<in> space M. ereal (norm (f y)) \<noteq> 0} \<noteq> \<infinity>"
   310   proof (rule simple_function_finite_support)
   311     show "simple_function M (\<lambda>x. ereal (norm (f x)))"
   312       using f by (rule simple_function_compose1)
   313     show "(\<integral>\<^sup>+ y. ereal (norm (f y)) \<partial>M) < \<infinity>" by fact
   314   qed simp
   315   then show "emeasure M {y \<in> space M. f y \<noteq> 0} \<noteq> \<infinity>" by simp
   316 qed fact
   317 
   318 definition simple_bochner_integral :: "'a measure \<Rightarrow> ('a \<Rightarrow> 'b::real_vector) \<Rightarrow> 'b" where
   319   "simple_bochner_integral M f = (\<Sum>y\<in>f`space M. measure M {x\<in>space M. f x = y} *\<^sub>R y)"
   320 
   321 lemma simple_bochner_integral_partition:
   322   assumes f: "simple_bochner_integrable M f" and g: "simple_function M g"
   323   assumes sub: "\<And>x y. x \<in> space M \<Longrightarrow> y \<in> space M \<Longrightarrow> g x = g y \<Longrightarrow> f x = f y"
   324   assumes v: "\<And>x. x \<in> space M \<Longrightarrow> f x = v (g x)"
   325   shows "simple_bochner_integral M f = (\<Sum>y\<in>g ` space M. measure M {x\<in>space M. g x = y} *\<^sub>R v y)"
   326     (is "_ = ?r")
   327 proof -
   328   from f g have [simp]: "finite (f`space M)" "finite (g`space M)"
   329     by (auto simp: simple_function_def elim: simple_bochner_integrable.cases)
   330 
   331   from f have [measurable]: "f \<in> measurable M (count_space UNIV)"
   332     by (auto intro: measurable_simple_function elim: simple_bochner_integrable.cases)
   333 
   334   from g have [measurable]: "g \<in> measurable M (count_space UNIV)"
   335     by (auto intro: measurable_simple_function elim: simple_bochner_integrable.cases)
   336 
   337   { fix y assume "y \<in> space M"
   338     then have "f ` space M \<inter> {i. \<exists>x\<in>space M. i = f x \<and> g y = g x} = {v (g y)}"
   339       by (auto cong: sub simp: v[symmetric]) }
   340   note eq = this
   341 
   342   have "simple_bochner_integral M f =
   343     (\<Sum>y\<in>f`space M. (\<Sum>z\<in>g`space M. 
   344       if \<exists>x\<in>space M. y = f x \<and> z = g x then measure M {x\<in>space M. g x = z} else 0) *\<^sub>R y)"
   345     unfolding simple_bochner_integral_def
   346   proof (safe intro!: setsum_cong scaleR_cong_right)
   347     fix y assume y: "y \<in> space M" "f y \<noteq> 0"
   348     have [simp]: "g ` space M \<inter> {z. \<exists>x\<in>space M. f y = f x \<and> z = g x} = 
   349         {z. \<exists>x\<in>space M. f y = f x \<and> z = g x}"
   350       by auto
   351     have eq:"{x \<in> space M. f x = f y} =
   352         (\<Union>i\<in>{z. \<exists>x\<in>space M. f y = f x \<and> z = g x}. {x \<in> space M. g x = i})"
   353       by (auto simp: eq_commute cong: sub rev_conj_cong)
   354     have "finite (g`space M)" by simp
   355     then have "finite {z. \<exists>x\<in>space M. f y = f x \<and> z = g x}"
   356       by (rule rev_finite_subset) auto
   357     moreover
   358     { fix x assume "x \<in> space M" "f x = f y"
   359       then have "x \<in> space M" "f x \<noteq> 0"
   360         using y by auto
   361       then have "emeasure M {y \<in> space M. g y = g x} \<le> emeasure M {y \<in> space M. f y \<noteq> 0}"
   362         by (auto intro!: emeasure_mono cong: sub)
   363       then have "emeasure M {xa \<in> space M. g xa = g x} < \<infinity>"
   364         using f by (auto simp: simple_bochner_integrable.simps) }
   365     ultimately
   366     show "measure M {x \<in> space M. f x = f y} =
   367       (\<Sum>z\<in>g ` space M. if \<exists>x\<in>space M. f y = f x \<and> z = g x then measure M {x \<in> space M. g x = z} else 0)"
   368       apply (simp add: setsum_cases eq)
   369       apply (subst measure_finite_Union[symmetric])
   370       apply (auto simp: disjoint_family_on_def)
   371       done
   372   qed
   373   also have "\<dots> = (\<Sum>y\<in>f`space M. (\<Sum>z\<in>g`space M. 
   374       if \<exists>x\<in>space M. y = f x \<and> z = g x then measure M {x\<in>space M. g x = z} *\<^sub>R y else 0))"
   375     by (auto intro!: setsum_cong simp: scaleR_setsum_left)
   376   also have "\<dots> = ?r"
   377     by (subst setsum_commute)
   378        (auto intro!: setsum_cong simp: setsum_cases scaleR_setsum_right[symmetric] eq)
   379   finally show "simple_bochner_integral M f = ?r" .
   380 qed
   381 
   382 lemma simple_bochner_integral_add:
   383   assumes f: "simple_bochner_integrable M f" and g: "simple_bochner_integrable M g"
   384   shows "simple_bochner_integral M (\<lambda>x. f x + g x) =
   385     simple_bochner_integral M f + simple_bochner_integral M g"
   386 proof -
   387   from f g have "simple_bochner_integral M (\<lambda>x. f x + g x) =
   388     (\<Sum>y\<in>(\<lambda>x. (f x, g x)) ` space M. measure M {x \<in> space M. (f x, g x) = y} *\<^sub>R (fst y + snd y))"
   389     by (intro simple_bochner_integral_partition)
   390        (auto simp: simple_bochner_integrable_compose2 elim: simple_bochner_integrable.cases)
   391   moreover from f g have "simple_bochner_integral M f =
   392     (\<Sum>y\<in>(\<lambda>x. (f x, g x)) ` space M. measure M {x \<in> space M. (f x, g x) = y} *\<^sub>R fst y)"
   393     by (intro simple_bochner_integral_partition)
   394        (auto simp: simple_bochner_integrable_compose2 elim: simple_bochner_integrable.cases)
   395   moreover from f g have "simple_bochner_integral M g =
   396     (\<Sum>y\<in>(\<lambda>x. (f x, g x)) ` space M. measure M {x \<in> space M. (f x, g x) = y} *\<^sub>R snd y)"
   397     by (intro simple_bochner_integral_partition)
   398        (auto simp: simple_bochner_integrable_compose2 elim: simple_bochner_integrable.cases)
   399   ultimately show ?thesis
   400     by (simp add: setsum_addf[symmetric] scaleR_add_right)
   401 qed
   402 
   403 lemma (in linear) simple_bochner_integral_linear:
   404   assumes g: "simple_bochner_integrable M g"
   405   shows "simple_bochner_integral M (\<lambda>x. f (g x)) = f (simple_bochner_integral M g)"
   406 proof -
   407   from g have "simple_bochner_integral M (\<lambda>x. f (g x)) =
   408     (\<Sum>y\<in>g ` space M. measure M {x \<in> space M. g x = y} *\<^sub>R f y)"
   409     by (intro simple_bochner_integral_partition)
   410        (auto simp: simple_bochner_integrable_compose2[where p="\<lambda>x y. f x"] zero
   411              elim: simple_bochner_integrable.cases)
   412   also have "\<dots> = f (simple_bochner_integral M g)"
   413     by (simp add: simple_bochner_integral_def setsum scaleR)
   414   finally show ?thesis .
   415 qed
   416 
   417 lemma simple_bochner_integral_minus:
   418   assumes f: "simple_bochner_integrable M f"
   419   shows "simple_bochner_integral M (\<lambda>x. - f x) = - simple_bochner_integral M f"
   420 proof -
   421   interpret linear uminus by unfold_locales auto
   422   from f show ?thesis
   423     by (rule simple_bochner_integral_linear)
   424 qed
   425 
   426 lemma simple_bochner_integral_diff:
   427   assumes f: "simple_bochner_integrable M f" and g: "simple_bochner_integrable M g"
   428   shows "simple_bochner_integral M (\<lambda>x. f x - g x) =
   429     simple_bochner_integral M f - simple_bochner_integral M g"
   430   unfolding diff_conv_add_uminus using f g
   431   by (subst simple_bochner_integral_add)
   432      (auto simp: simple_bochner_integral_minus simple_bochner_integrable_compose2[where p="\<lambda>x y. - y"])
   433 
   434 lemma simple_bochner_integral_norm_bound:
   435   assumes f: "simple_bochner_integrable M f"
   436   shows "norm (simple_bochner_integral M f) \<le> simple_bochner_integral M (\<lambda>x. norm (f x))"
   437 proof -
   438   have "norm (simple_bochner_integral M f) \<le> 
   439     (\<Sum>y\<in>f ` space M. norm (measure M {x \<in> space M. f x = y} *\<^sub>R y))"
   440     unfolding simple_bochner_integral_def by (rule norm_setsum)
   441   also have "\<dots> = (\<Sum>y\<in>f ` space M. measure M {x \<in> space M. f x = y} *\<^sub>R norm y)"
   442     by (simp add: measure_nonneg)
   443   also have "\<dots> = simple_bochner_integral M (\<lambda>x. norm (f x))"
   444     using f
   445     by (intro simple_bochner_integral_partition[symmetric])
   446        (auto intro: f simple_bochner_integrable_compose2 elim: simple_bochner_integrable.cases)
   447   finally show ?thesis .
   448 qed
   449 
   450 lemma simple_bochner_integral_eq_nn_integral:
   451   assumes f: "simple_bochner_integrable M f" "\<And>x. 0 \<le> f x"
   452   shows "simple_bochner_integral M f = (\<integral>\<^sup>+x. f x \<partial>M)"
   453 proof -
   454   { fix x y z have "(x \<noteq> 0 \<Longrightarrow> y = z) \<Longrightarrow> ereal x * y = ereal x * z"
   455       by (cases "x = 0") (auto simp: zero_ereal_def[symmetric]) }
   456   note ereal_cong_mult = this
   457 
   458   have [measurable]: "f \<in> borel_measurable M"
   459     using f(1) by (auto intro: borel_measurable_simple_function elim: simple_bochner_integrable.cases)
   460 
   461   { fix y assume y: "y \<in> space M" "f y \<noteq> 0"
   462     have "ereal (measure M {x \<in> space M. f x = f y}) = emeasure M {x \<in> space M. f x = f y}"
   463     proof (rule emeasure_eq_ereal_measure[symmetric])
   464       have "emeasure M {x \<in> space M. f x = f y} \<le> emeasure M {x \<in> space M. f x \<noteq> 0}"
   465         using y by (intro emeasure_mono) auto
   466       with f show "emeasure M {x \<in> space M. f x = f y} \<noteq> \<infinity>"
   467         by (auto simp: simple_bochner_integrable.simps)
   468     qed
   469     moreover have "{x \<in> space M. f x = f y} = (\<lambda>x. ereal (f x)) -` {ereal (f y)} \<inter> space M"
   470       by auto
   471     ultimately have "ereal (measure M {x \<in> space M. f x = f y}) =
   472           emeasure M ((\<lambda>x. ereal (f x)) -` {ereal (f y)} \<inter> space M)" by simp }
   473   with f have "simple_bochner_integral M f = (\<integral>\<^sup>Sx. f x \<partial>M)"
   474     unfolding simple_integral_def
   475     by (subst simple_bochner_integral_partition[OF f(1), where g="\<lambda>x. ereal (f x)" and v=real])
   476        (auto intro: f simple_function_compose1 elim: simple_bochner_integrable.cases
   477              intro!: setsum_cong ereal_cong_mult
   478              simp: setsum_ereal[symmetric] times_ereal.simps(1)[symmetric] mult_ac
   479              simp del: setsum_ereal times_ereal.simps(1))
   480   also have "\<dots> = (\<integral>\<^sup>+x. f x \<partial>M)"
   481     using f
   482     by (intro nn_integral_eq_simple_integral[symmetric])
   483        (auto simp: simple_function_compose1 simple_bochner_integrable.simps)
   484   finally show ?thesis .
   485 qed
   486 
   487 lemma simple_bochner_integral_bounded:
   488   fixes f :: "'a \<Rightarrow> 'b::{real_normed_vector, second_countable_topology}"
   489   assumes f[measurable]: "f \<in> borel_measurable M"
   490   assumes s: "simple_bochner_integrable M s" and t: "simple_bochner_integrable M t"
   491   shows "ereal (norm (simple_bochner_integral M s - simple_bochner_integral M t)) \<le>
   492     (\<integral>\<^sup>+ x. norm (f x - s x) \<partial>M) + (\<integral>\<^sup>+ x. norm (f x - t x) \<partial>M)"
   493     (is "ereal (norm (?s - ?t)) \<le> ?S + ?T")
   494 proof -
   495   have [measurable]: "s \<in> borel_measurable M" "t \<in> borel_measurable M"
   496     using s t by (auto intro: borel_measurable_simple_function elim: simple_bochner_integrable.cases)
   497 
   498   have "ereal (norm (?s - ?t)) = norm (simple_bochner_integral M (\<lambda>x. s x - t x))"
   499     using s t by (subst simple_bochner_integral_diff) auto
   500   also have "\<dots> \<le> simple_bochner_integral M (\<lambda>x. norm (s x - t x))"
   501     using simple_bochner_integrable_compose2[of "op -" M "s" "t"] s t
   502     by (auto intro!: simple_bochner_integral_norm_bound)
   503   also have "\<dots> = (\<integral>\<^sup>+x. norm (s x - t x) \<partial>M)"
   504     using simple_bochner_integrable_compose2[of "\<lambda>x y. norm (x - y)" M "s" "t"] s t
   505     by (auto intro!: simple_bochner_integral_eq_nn_integral)
   506   also have "\<dots> \<le> (\<integral>\<^sup>+x. ereal (norm (f x - s x)) + ereal (norm (f x - t x)) \<partial>M)"
   507     by (auto intro!: nn_integral_mono)
   508        (metis (erased, hide_lams) add_diff_cancel_left add_diff_eq diff_add_eq order_trans
   509               norm_minus_commute norm_triangle_ineq4 order_refl)
   510   also have "\<dots> = ?S + ?T"
   511    by (rule nn_integral_add) auto
   512   finally show ?thesis .
   513 qed
   514 
   515 inductive has_bochner_integral :: "'a measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b::{real_normed_vector, second_countable_topology} \<Rightarrow> bool"
   516   for M f x where
   517   "f \<in> borel_measurable M \<Longrightarrow>
   518     (\<And>i. simple_bochner_integrable M (s i)) \<Longrightarrow>
   519     (\<lambda>i. \<integral>\<^sup>+x. norm (f x - s i x) \<partial>M) ----> 0 \<Longrightarrow>
   520     (\<lambda>i. simple_bochner_integral M (s i)) ----> x \<Longrightarrow>
   521     has_bochner_integral M f x"
   522 
   523 lemma has_bochner_integral_cong:
   524   assumes "M = N" "\<And>x. x \<in> space N \<Longrightarrow> f x = g x" "x = y"
   525   shows "has_bochner_integral M f x \<longleftrightarrow> has_bochner_integral N g y"
   526   unfolding has_bochner_integral.simps assms(1,3)
   527   using assms(2) by (simp cong: measurable_cong_strong nn_integral_cong_strong)
   528 
   529 lemma has_bochner_integral_cong_AE:
   530   "f \<in> borel_measurable M \<Longrightarrow> g \<in> borel_measurable M \<Longrightarrow> (AE x in M. f x = g x) \<Longrightarrow>
   531     has_bochner_integral M f x \<longleftrightarrow> has_bochner_integral M g x"
   532   unfolding has_bochner_integral.simps
   533   by (intro arg_cong[where f=Ex] ext conj_cong rev_conj_cong refl arg_cong[where f="\<lambda>x. x ----> 0"]
   534             nn_integral_cong_AE)
   535      auto
   536 
   537 lemma borel_measurable_has_bochner_integral[measurable_dest]:
   538   "has_bochner_integral M f x \<Longrightarrow> f \<in> borel_measurable M"
   539   by (auto elim: has_bochner_integral.cases)
   540 
   541 lemma has_bochner_integral_simple_bochner_integrable:
   542   "simple_bochner_integrable M f \<Longrightarrow> has_bochner_integral M f (simple_bochner_integral M f)"
   543   by (rule has_bochner_integral.intros[where s="\<lambda>_. f"])
   544      (auto intro: borel_measurable_simple_function 
   545            elim: simple_bochner_integrable.cases
   546            simp: zero_ereal_def[symmetric])
   547 
   548 lemma has_bochner_integral_real_indicator:
   549   assumes [measurable]: "A \<in> sets M" and A: "emeasure M A < \<infinity>"
   550   shows "has_bochner_integral M (indicator A) (measure M A)"
   551 proof -
   552   have sbi: "simple_bochner_integrable M (indicator A::'a \<Rightarrow> real)"
   553   proof
   554     have "{y \<in> space M. (indicator A y::real) \<noteq> 0} = A"
   555       using sets.sets_into_space[OF `A\<in>sets M`] by (auto split: split_indicator)
   556     then show "emeasure M {y \<in> space M. (indicator A y::real) \<noteq> 0} \<noteq> \<infinity>"
   557       using A by auto
   558   qed (rule simple_function_indicator assms)+
   559   moreover have "simple_bochner_integral M (indicator A) = measure M A"
   560     using simple_bochner_integral_eq_nn_integral[OF sbi] A
   561     by (simp add: ereal_indicator emeasure_eq_ereal_measure)
   562   ultimately show ?thesis
   563     by (metis has_bochner_integral_simple_bochner_integrable)
   564 qed
   565 
   566 lemma has_bochner_integral_add[intro]:
   567   "has_bochner_integral M f x \<Longrightarrow> has_bochner_integral M g y \<Longrightarrow>
   568     has_bochner_integral M (\<lambda>x. f x + g x) (x + y)"
   569 proof (safe intro!: has_bochner_integral.intros elim!: has_bochner_integral.cases)
   570   fix sf sg
   571   assume f_sf: "(\<lambda>i. \<integral>\<^sup>+ x. norm (f x - sf i x) \<partial>M) ----> 0"
   572   assume g_sg: "(\<lambda>i. \<integral>\<^sup>+ x. norm (g x - sg i x) \<partial>M) ----> 0"
   573 
   574   assume sf: "\<forall>i. simple_bochner_integrable M (sf i)"
   575     and sg: "\<forall>i. simple_bochner_integrable M (sg i)"
   576   then have [measurable]: "\<And>i. sf i \<in> borel_measurable M" "\<And>i. sg i \<in> borel_measurable M"
   577     by (auto intro: borel_measurable_simple_function elim: simple_bochner_integrable.cases)
   578   assume [measurable]: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
   579 
   580   show "\<And>i. simple_bochner_integrable M (\<lambda>x. sf i x + sg i x)"
   581     using sf sg by (simp add: simple_bochner_integrable_compose2)
   582 
   583   show "(\<lambda>i. \<integral>\<^sup>+ x. (norm (f x + g x - (sf i x + sg i x))) \<partial>M) ----> 0"
   584     (is "?f ----> 0")
   585   proof (rule tendsto_sandwich)
   586     show "eventually (\<lambda>n. 0 \<le> ?f n) sequentially" "(\<lambda>_. 0) ----> 0"
   587       by (auto simp: nn_integral_nonneg)
   588     show "eventually (\<lambda>i. ?f i \<le> (\<integral>\<^sup>+ x. (norm (f x - sf i x)) \<partial>M) + \<integral>\<^sup>+ x. (norm (g x - sg i x)) \<partial>M) sequentially"
   589       (is "eventually (\<lambda>i. ?f i \<le> ?g i) sequentially")
   590     proof (intro always_eventually allI)
   591       fix i have "?f i \<le> (\<integral>\<^sup>+ x. (norm (f x - sf i x)) + ereal (norm (g x - sg i x)) \<partial>M)"
   592         by (auto intro!: nn_integral_mono norm_diff_triangle_ineq)
   593       also have "\<dots> = ?g i"
   594         by (intro nn_integral_add) auto
   595       finally show "?f i \<le> ?g i" .
   596     qed
   597     show "?g ----> 0"
   598       using tendsto_add_ereal[OF _ _ f_sf g_sg] by simp
   599   qed
   600 qed (auto simp: simple_bochner_integral_add tendsto_add)
   601 
   602 lemma has_bochner_integral_bounded_linear:
   603   assumes "bounded_linear T"
   604   shows "has_bochner_integral M f x \<Longrightarrow> has_bochner_integral M (\<lambda>x. T (f x)) (T x)"
   605 proof (safe intro!: has_bochner_integral.intros elim!: has_bochner_integral.cases)
   606   interpret T: bounded_linear T by fact
   607   have [measurable]: "T \<in> borel_measurable borel"
   608     by (intro borel_measurable_continuous_on1 T.continuous_on continuous_on_id)
   609   assume [measurable]: "f \<in> borel_measurable M"
   610   then show "(\<lambda>x. T (f x)) \<in> borel_measurable M"
   611     by auto
   612 
   613   fix s assume f_s: "(\<lambda>i. \<integral>\<^sup>+ x. norm (f x - s i x) \<partial>M) ----> 0"
   614   assume s: "\<forall>i. simple_bochner_integrable M (s i)"
   615   then show "\<And>i. simple_bochner_integrable M (\<lambda>x. T (s i x))"
   616     by (auto intro: simple_bochner_integrable_compose2 T.zero)
   617 
   618   have [measurable]: "\<And>i. s i \<in> borel_measurable M"
   619     using s by (auto intro: borel_measurable_simple_function elim: simple_bochner_integrable.cases)
   620 
   621   obtain K where K: "K > 0" "\<And>x i. norm (T (f x) - T (s i x)) \<le> norm (f x - s i x) * K"
   622     using T.pos_bounded by (auto simp: T.diff[symmetric])
   623 
   624   show "(\<lambda>i. \<integral>\<^sup>+ x. norm (T (f x) - T (s i x)) \<partial>M) ----> 0"
   625     (is "?f ----> 0")
   626   proof (rule tendsto_sandwich)
   627     show "eventually (\<lambda>n. 0 \<le> ?f n) sequentially" "(\<lambda>_. 0) ----> 0"
   628       by (auto simp: nn_integral_nonneg)
   629 
   630     show "eventually (\<lambda>i. ?f i \<le> K * (\<integral>\<^sup>+ x. norm (f x - s i x) \<partial>M)) sequentially"
   631       (is "eventually (\<lambda>i. ?f i \<le> ?g i) sequentially")
   632     proof (intro always_eventually allI)
   633       fix i have "?f i \<le> (\<integral>\<^sup>+ x. ereal K * norm (f x - s i x) \<partial>M)"
   634         using K by (intro nn_integral_mono) (auto simp: mult_ac)
   635       also have "\<dots> = ?g i"
   636         using K by (intro nn_integral_cmult) auto
   637       finally show "?f i \<le> ?g i" .
   638     qed
   639     show "?g ----> 0"
   640       using ereal_lim_mult[OF f_s, of "ereal K"] by simp
   641   qed
   642 
   643   assume "(\<lambda>i. simple_bochner_integral M (s i)) ----> x"
   644   with s show "(\<lambda>i. simple_bochner_integral M (\<lambda>x. T (s i x))) ----> T x"
   645     by (auto intro!: T.tendsto simp: T.simple_bochner_integral_linear)
   646 qed
   647 
   648 lemma has_bochner_integral_zero[intro]: "has_bochner_integral M (\<lambda>x. 0) 0"
   649   by (auto intro!: has_bochner_integral.intros[where s="\<lambda>_ _. 0"]
   650            simp: zero_ereal_def[symmetric] simple_bochner_integrable.simps
   651                  simple_bochner_integral_def image_constant_conv)
   652 
   653 lemma has_bochner_integral_scaleR_left[intro]:
   654   "(c \<noteq> 0 \<Longrightarrow> has_bochner_integral M f x) \<Longrightarrow> has_bochner_integral M (\<lambda>x. f x *\<^sub>R c) (x *\<^sub>R c)"
   655   by (cases "c = 0") (auto simp add: has_bochner_integral_bounded_linear[OF bounded_linear_scaleR_left])
   656 
   657 lemma has_bochner_integral_scaleR_right[intro]:
   658   "(c \<noteq> 0 \<Longrightarrow> has_bochner_integral M f x) \<Longrightarrow> has_bochner_integral M (\<lambda>x. c *\<^sub>R f x) (c *\<^sub>R x)"
   659   by (cases "c = 0") (auto simp add: has_bochner_integral_bounded_linear[OF bounded_linear_scaleR_right])
   660 
   661 lemma has_bochner_integral_mult_left[intro]:
   662   fixes c :: "_::{real_normed_algebra,second_countable_topology}"
   663   shows "(c \<noteq> 0 \<Longrightarrow> has_bochner_integral M f x) \<Longrightarrow> has_bochner_integral M (\<lambda>x. f x * c) (x * c)"
   664   by (cases "c = 0") (auto simp add: has_bochner_integral_bounded_linear[OF bounded_linear_mult_left])
   665 
   666 lemma has_bochner_integral_mult_right[intro]:
   667   fixes c :: "_::{real_normed_algebra,second_countable_topology}"
   668   shows "(c \<noteq> 0 \<Longrightarrow> has_bochner_integral M f x) \<Longrightarrow> has_bochner_integral M (\<lambda>x. c * f x) (c * x)"
   669   by (cases "c = 0") (auto simp add: has_bochner_integral_bounded_linear[OF bounded_linear_mult_right])
   670 
   671 lemmas has_bochner_integral_divide = 
   672   has_bochner_integral_bounded_linear[OF bounded_linear_divide]
   673 
   674 lemma has_bochner_integral_divide_zero[intro]:
   675   fixes c :: "_::{real_normed_field, field_inverse_zero, second_countable_topology}"
   676   shows "(c \<noteq> 0 \<Longrightarrow> has_bochner_integral M f x) \<Longrightarrow> has_bochner_integral M (\<lambda>x. f x / c) (x / c)"
   677   using has_bochner_integral_divide by (cases "c = 0") auto
   678 
   679 lemma has_bochner_integral_inner_left[intro]:
   680   "(c \<noteq> 0 \<Longrightarrow> has_bochner_integral M f x) \<Longrightarrow> has_bochner_integral M (\<lambda>x. f x \<bullet> c) (x \<bullet> c)"
   681   by (cases "c = 0") (auto simp add: has_bochner_integral_bounded_linear[OF bounded_linear_inner_left])
   682 
   683 lemma has_bochner_integral_inner_right[intro]:
   684   "(c \<noteq> 0 \<Longrightarrow> has_bochner_integral M f x) \<Longrightarrow> has_bochner_integral M (\<lambda>x. c \<bullet> f x) (c \<bullet> x)"
   685   by (cases "c = 0") (auto simp add: has_bochner_integral_bounded_linear[OF bounded_linear_inner_right])
   686 
   687 lemmas has_bochner_integral_minus =
   688   has_bochner_integral_bounded_linear[OF bounded_linear_minus[OF bounded_linear_ident]]
   689 lemmas has_bochner_integral_Re =
   690   has_bochner_integral_bounded_linear[OF bounded_linear_Re]
   691 lemmas has_bochner_integral_Im =
   692   has_bochner_integral_bounded_linear[OF bounded_linear_Im]
   693 lemmas has_bochner_integral_cnj =
   694   has_bochner_integral_bounded_linear[OF bounded_linear_cnj]
   695 lemmas has_bochner_integral_of_real =
   696   has_bochner_integral_bounded_linear[OF bounded_linear_of_real]
   697 lemmas has_bochner_integral_fst =
   698   has_bochner_integral_bounded_linear[OF bounded_linear_fst]
   699 lemmas has_bochner_integral_snd =
   700   has_bochner_integral_bounded_linear[OF bounded_linear_snd]
   701 
   702 lemma has_bochner_integral_indicator:
   703   "A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow>
   704     has_bochner_integral M (\<lambda>x. indicator A x *\<^sub>R c) (measure M A *\<^sub>R c)"
   705   by (intro has_bochner_integral_scaleR_left has_bochner_integral_real_indicator)
   706 
   707 lemma has_bochner_integral_diff:
   708   "has_bochner_integral M f x \<Longrightarrow> has_bochner_integral M g y \<Longrightarrow>
   709     has_bochner_integral M (\<lambda>x. f x - g x) (x - y)"
   710   unfolding diff_conv_add_uminus
   711   by (intro has_bochner_integral_add has_bochner_integral_minus)
   712 
   713 lemma has_bochner_integral_setsum:
   714   "(\<And>i. i \<in> I \<Longrightarrow> has_bochner_integral M (f i) (x i)) \<Longrightarrow>
   715     has_bochner_integral M (\<lambda>x. \<Sum>i\<in>I. f i x) (\<Sum>i\<in>I. x i)"
   716   by (induct I rule: infinite_finite_induct) auto
   717 
   718 lemma has_bochner_integral_implies_finite_norm:
   719   "has_bochner_integral M f x \<Longrightarrow> (\<integral>\<^sup>+x. norm (f x) \<partial>M) < \<infinity>"
   720 proof (elim has_bochner_integral.cases)
   721   fix s v
   722   assume [measurable]: "f \<in> borel_measurable M" and s: "\<And>i. simple_bochner_integrable M (s i)" and
   723     lim_0: "(\<lambda>i. \<integral>\<^sup>+ x. ereal (norm (f x - s i x)) \<partial>M) ----> 0"
   724   from order_tendstoD[OF lim_0, of "\<infinity>"]
   725   obtain i where f_s_fin: "(\<integral>\<^sup>+ x. ereal (norm (f x - s i x)) \<partial>M) < \<infinity>"
   726     by (metis (mono_tags, lifting) eventually_False_sequentially eventually_elim1
   727               less_ereal.simps(4) zero_ereal_def)
   728 
   729   have [measurable]: "\<And>i. s i \<in> borel_measurable M"
   730     using s by (auto intro: borel_measurable_simple_function elim: simple_bochner_integrable.cases)
   731 
   732   def m \<equiv> "if space M = {} then 0 else Max ((\<lambda>x. norm (s i x))`space M)"
   733   have "finite (s i ` space M)"
   734     using s by (auto simp: simple_function_def simple_bochner_integrable.simps)
   735   then have "finite (norm ` s i ` space M)"
   736     by (rule finite_imageI)
   737   then have "\<And>x. x \<in> space M \<Longrightarrow> norm (s i x) \<le> m" "0 \<le> m"
   738     by (auto simp: m_def image_comp comp_def Max_ge_iff)
   739   then have "(\<integral>\<^sup>+x. norm (s i x) \<partial>M) \<le> (\<integral>\<^sup>+x. ereal m * indicator {x\<in>space M. s i x \<noteq> 0} x \<partial>M)"
   740     by (auto split: split_indicator intro!: Max_ge nn_integral_mono simp:)
   741   also have "\<dots> < \<infinity>"
   742     using s by (subst nn_integral_cmult_indicator) (auto simp: `0 \<le> m` simple_bochner_integrable.simps)
   743   finally have s_fin: "(\<integral>\<^sup>+x. norm (s i x) \<partial>M) < \<infinity>" .
   744 
   745   have "(\<integral>\<^sup>+ x. norm (f x) \<partial>M) \<le> (\<integral>\<^sup>+ x. ereal (norm (f x - s i x)) + ereal (norm (s i x)) \<partial>M)"
   746     by (auto intro!: nn_integral_mono) (metis add_commute norm_triangle_sub)
   747   also have "\<dots> = (\<integral>\<^sup>+x. norm (f x - s i x) \<partial>M) + (\<integral>\<^sup>+x. norm (s i x) \<partial>M)"
   748     by (rule nn_integral_add) auto
   749   also have "\<dots> < \<infinity>"
   750     using s_fin f_s_fin by auto
   751   finally show "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) < \<infinity>" .
   752 qed
   753 
   754 lemma has_bochner_integral_norm_bound:
   755   assumes i: "has_bochner_integral M f x"
   756   shows "norm x \<le> (\<integral>\<^sup>+x. norm (f x) \<partial>M)"
   757 using assms proof
   758   fix s assume
   759     x: "(\<lambda>i. simple_bochner_integral M (s i)) ----> x" (is "?s ----> x") and
   760     s[simp]: "\<And>i. simple_bochner_integrable M (s i)" and
   761     lim: "(\<lambda>i. \<integral>\<^sup>+ x. ereal (norm (f x - s i x)) \<partial>M) ----> 0" and
   762     f[measurable]: "f \<in> borel_measurable M"
   763 
   764   have [measurable]: "\<And>i. s i \<in> borel_measurable M"
   765     using s by (auto simp: simple_bochner_integrable.simps intro: borel_measurable_simple_function)
   766 
   767   show "norm x \<le> (\<integral>\<^sup>+x. norm (f x) \<partial>M)"
   768   proof (rule LIMSEQ_le)
   769     show "(\<lambda>i. ereal (norm (?s i))) ----> norm x"
   770       using x by (intro tendsto_intros lim_ereal[THEN iffD2])
   771     show "\<exists>N. \<forall>n\<ge>N. norm (?s n) \<le> (\<integral>\<^sup>+x. norm (f x - s n x) \<partial>M) + (\<integral>\<^sup>+x. norm (f x) \<partial>M)"
   772       (is "\<exists>N. \<forall>n\<ge>N. _ \<le> ?t n")
   773     proof (intro exI allI impI)
   774       fix n
   775       have "ereal (norm (?s n)) \<le> simple_bochner_integral M (\<lambda>x. norm (s n x))"
   776         by (auto intro!: simple_bochner_integral_norm_bound)
   777       also have "\<dots> = (\<integral>\<^sup>+x. norm (s n x) \<partial>M)"
   778         by (intro simple_bochner_integral_eq_nn_integral)
   779            (auto intro: s simple_bochner_integrable_compose2)
   780       also have "\<dots> \<le> (\<integral>\<^sup>+x. ereal (norm (f x - s n x)) + norm (f x) \<partial>M)"
   781         by (auto intro!: nn_integral_mono)
   782            (metis add_commute norm_minus_commute norm_triangle_sub)
   783       also have "\<dots> = ?t n" 
   784         by (rule nn_integral_add) auto
   785       finally show "norm (?s n) \<le> ?t n" .
   786     qed
   787     have "?t ----> 0 + (\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M)"
   788       using has_bochner_integral_implies_finite_norm[OF i]
   789       by (intro tendsto_add_ereal tendsto_const lim) auto
   790     then show "?t ----> \<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M"
   791       by simp
   792   qed
   793 qed
   794 
   795 lemma has_bochner_integral_eq:
   796   "has_bochner_integral M f x \<Longrightarrow> has_bochner_integral M f y \<Longrightarrow> x = y"
   797 proof (elim has_bochner_integral.cases)
   798   assume f[measurable]: "f \<in> borel_measurable M"
   799 
   800   fix s t
   801   assume "(\<lambda>i. \<integral>\<^sup>+ x. norm (f x - s i x) \<partial>M) ----> 0" (is "?S ----> 0")
   802   assume "(\<lambda>i. \<integral>\<^sup>+ x. norm (f x - t i x) \<partial>M) ----> 0" (is "?T ----> 0")
   803   assume s: "\<And>i. simple_bochner_integrable M (s i)"
   804   assume t: "\<And>i. simple_bochner_integrable M (t i)"
   805 
   806   have [measurable]: "\<And>i. s i \<in> borel_measurable M" "\<And>i. t i \<in> borel_measurable M"
   807     using s t by (auto intro: borel_measurable_simple_function elim: simple_bochner_integrable.cases)
   808 
   809   let ?s = "\<lambda>i. simple_bochner_integral M (s i)"
   810   let ?t = "\<lambda>i. simple_bochner_integral M (t i)"
   811   assume "?s ----> x" "?t ----> y"
   812   then have "(\<lambda>i. norm (?s i - ?t i)) ----> norm (x - y)"
   813     by (intro tendsto_intros)
   814   moreover
   815   have "(\<lambda>i. ereal (norm (?s i - ?t i))) ----> ereal 0"
   816   proof (rule tendsto_sandwich)
   817     show "eventually (\<lambda>i. 0 \<le> ereal (norm (?s i - ?t i))) sequentially" "(\<lambda>_. 0) ----> ereal 0"
   818       by (auto simp: nn_integral_nonneg zero_ereal_def[symmetric])
   819 
   820     show "eventually (\<lambda>i. norm (?s i - ?t i) \<le> ?S i + ?T i) sequentially"
   821       by (intro always_eventually allI simple_bochner_integral_bounded s t f)
   822     show "(\<lambda>i. ?S i + ?T i) ----> ereal 0"
   823       using tendsto_add_ereal[OF _ _ `?S ----> 0` `?T ----> 0`]
   824       by (simp add: zero_ereal_def[symmetric])
   825   qed
   826   then have "(\<lambda>i. norm (?s i - ?t i)) ----> 0"
   827     by simp
   828   ultimately have "norm (x - y) = 0"
   829     by (rule LIMSEQ_unique)
   830   then show "x = y" by simp
   831 qed
   832 
   833 lemma has_bochner_integralI_AE:
   834   assumes f: "has_bochner_integral M f x"
   835     and g: "g \<in> borel_measurable M"
   836     and ae: "AE x in M. f x = g x"
   837   shows "has_bochner_integral M g x"
   838   using f
   839 proof (safe intro!: has_bochner_integral.intros elim!: has_bochner_integral.cases)
   840   fix s assume "(\<lambda>i. \<integral>\<^sup>+ x. ereal (norm (f x - s i x)) \<partial>M) ----> 0"
   841   also have "(\<lambda>i. \<integral>\<^sup>+ x. ereal (norm (f x - s i x)) \<partial>M) = (\<lambda>i. \<integral>\<^sup>+ x. ereal (norm (g x - s i x)) \<partial>M)"
   842     using ae
   843     by (intro ext nn_integral_cong_AE, eventually_elim) simp
   844   finally show "(\<lambda>i. \<integral>\<^sup>+ x. ereal (norm (g x - s i x)) \<partial>M) ----> 0" .
   845 qed (auto intro: g)
   846 
   847 lemma has_bochner_integral_eq_AE:
   848   assumes f: "has_bochner_integral M f x"
   849     and g: "has_bochner_integral M g y"
   850     and ae: "AE x in M. f x = g x"
   851   shows "x = y"
   852 proof -
   853   from assms have "has_bochner_integral M g x"
   854     by (auto intro: has_bochner_integralI_AE)
   855   from this g show "x = y"
   856     by (rule has_bochner_integral_eq)
   857 qed
   858 
   859 lemma simple_bochner_integrable_restrict_space:
   860   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   861   assumes \<Omega>: "\<Omega> \<inter> space M \<in> sets M"
   862   shows "simple_bochner_integrable (restrict_space M \<Omega>) f \<longleftrightarrow>
   863     simple_bochner_integrable M (\<lambda>x. indicator \<Omega> x *\<^sub>R f x)"
   864   by (simp add: simple_bochner_integrable.simps space_restrict_space
   865     simple_function_restrict_space[OF \<Omega>] emeasure_restrict_space[OF \<Omega>] Collect_restrict
   866     indicator_eq_0_iff conj_ac)
   867 
   868 lemma simple_bochner_integral_restrict_space:
   869   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   870   assumes \<Omega>: "\<Omega> \<inter> space M \<in> sets M"
   871   assumes f: "simple_bochner_integrable (restrict_space M \<Omega>) f"
   872   shows "simple_bochner_integral (restrict_space M \<Omega>) f =
   873     simple_bochner_integral M (\<lambda>x. indicator \<Omega> x *\<^sub>R f x)"
   874 proof -
   875   have "finite ((\<lambda>x. indicator \<Omega> x *\<^sub>R f x)`space M)"
   876     using f simple_bochner_integrable_restrict_space[OF \<Omega>, of f]
   877     by (simp add: simple_bochner_integrable.simps simple_function_def)
   878   then show ?thesis
   879     by (auto simp: space_restrict_space measure_restrict_space[OF \<Omega>(1)] le_infI2
   880                    simple_bochner_integral_def Collect_restrict
   881              split: split_indicator split_indicator_asm
   882              intro!: setsum_mono_zero_cong_left arg_cong2[where f=measure])
   883 qed
   884 
   885 inductive integrable for M f where
   886   "has_bochner_integral M f x \<Longrightarrow> integrable M f"
   887 
   888 definition lebesgue_integral ("integral\<^sup>L") where
   889   "integral\<^sup>L M f = (if \<exists>x. has_bochner_integral M f x then THE x. has_bochner_integral M f x else 0)"
   890 
   891 syntax
   892   "_lebesgue_integral" :: "pttrn \<Rightarrow> real \<Rightarrow> 'a measure \<Rightarrow> real" ("\<integral> _. _ \<partial>_" [60,61] 110)
   893 
   894 translations
   895   "\<integral> x. f \<partial>M" == "CONST lebesgue_integral M (\<lambda>x. f)"
   896 
   897 lemma has_bochner_integral_integral_eq: "has_bochner_integral M f x \<Longrightarrow> integral\<^sup>L M f = x"
   898   by (metis the_equality has_bochner_integral_eq lebesgue_integral_def)
   899 
   900 lemma has_bochner_integral_integrable:
   901   "integrable M f \<Longrightarrow> has_bochner_integral M f (integral\<^sup>L M f)"
   902   by (auto simp: has_bochner_integral_integral_eq integrable.simps)
   903 
   904 lemma has_bochner_integral_iff:
   905   "has_bochner_integral M f x \<longleftrightarrow> integrable M f \<and> integral\<^sup>L M f = x"
   906   by (metis has_bochner_integral_integrable has_bochner_integral_integral_eq integrable.intros)
   907 
   908 lemma simple_bochner_integrable_eq_integral:
   909   "simple_bochner_integrable M f \<Longrightarrow> simple_bochner_integral M f = integral\<^sup>L M f"
   910   using has_bochner_integral_simple_bochner_integrable[of M f]
   911   by (simp add: has_bochner_integral_integral_eq)
   912 
   913 lemma not_integrable_integral_eq: "\<not> integrable M f \<Longrightarrow> integral\<^sup>L M f = 0"
   914   unfolding integrable.simps lebesgue_integral_def by (auto intro!: arg_cong[where f=The])
   915 
   916 lemma integral_eq_cases:
   917   "integrable M f \<longleftrightarrow> integrable N g \<Longrightarrow>
   918     (integrable M f \<Longrightarrow> integrable N g \<Longrightarrow> integral\<^sup>L M f = integral\<^sup>L N g) \<Longrightarrow>
   919     integral\<^sup>L M f = integral\<^sup>L N g"
   920   by (metis not_integrable_integral_eq)
   921 
   922 lemma borel_measurable_integrable[measurable_dest]: "integrable M f \<Longrightarrow> f \<in> borel_measurable M"
   923   by (auto elim: integrable.cases has_bochner_integral.cases)
   924 
   925 lemma integrable_cong:
   926   "M = N \<Longrightarrow> (\<And>x. x \<in> space N \<Longrightarrow> f x = g x) \<Longrightarrow> integrable M f \<longleftrightarrow> integrable N g"
   927   using assms by (simp cong: has_bochner_integral_cong add: integrable.simps)
   928 
   929 lemma integrable_cong_AE:
   930   "f \<in> borel_measurable M \<Longrightarrow> g \<in> borel_measurable M \<Longrightarrow> AE x in M. f x = g x \<Longrightarrow>
   931     integrable M f \<longleftrightarrow> integrable M g"
   932   unfolding integrable.simps
   933   by (intro has_bochner_integral_cong_AE arg_cong[where f=Ex] ext)
   934 
   935 lemma integral_cong:
   936   "M = N \<Longrightarrow> (\<And>x. x \<in> space N \<Longrightarrow> f x = g x) \<Longrightarrow> integral\<^sup>L M f = integral\<^sup>L N g"
   937   using assms by (simp cong: has_bochner_integral_cong cong del: if_cong add: lebesgue_integral_def)
   938 
   939 lemma integral_cong_AE:
   940   "f \<in> borel_measurable M \<Longrightarrow> g \<in> borel_measurable M \<Longrightarrow> AE x in M. f x = g x \<Longrightarrow>
   941     integral\<^sup>L M f = integral\<^sup>L M g"
   942   unfolding lebesgue_integral_def
   943   by (rule arg_cong[where x="has_bochner_integral M f"]) (intro has_bochner_integral_cong_AE ext)
   944 
   945 lemma integrable_add[simp, intro]: "integrable M f \<Longrightarrow> integrable M g \<Longrightarrow> integrable M (\<lambda>x. f x + g x)"
   946   by (auto simp: integrable.simps)
   947 
   948 lemma integrable_zero[simp, intro]: "integrable M (\<lambda>x. 0)"
   949   by (metis has_bochner_integral_zero integrable.simps) 
   950 
   951 lemma integrable_setsum[simp, intro]: "(\<And>i. i \<in> I \<Longrightarrow> integrable M (f i)) \<Longrightarrow> integrable M (\<lambda>x. \<Sum>i\<in>I. f i x)"
   952   by (metis has_bochner_integral_setsum integrable.simps) 
   953 
   954 lemma integrable_indicator[simp, intro]: "A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow>
   955   integrable M (\<lambda>x. indicator A x *\<^sub>R c)"
   956   by (metis has_bochner_integral_indicator integrable.simps) 
   957 
   958 lemma integrable_real_indicator[simp, intro]: "A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow>
   959   integrable M (indicator A :: 'a \<Rightarrow> real)"
   960   by (metis has_bochner_integral_real_indicator integrable.simps)
   961 
   962 lemma integrable_diff[simp, intro]: "integrable M f \<Longrightarrow> integrable M g \<Longrightarrow> integrable M (\<lambda>x. f x - g x)"
   963   by (auto simp: integrable.simps intro: has_bochner_integral_diff)
   964   
   965 lemma integrable_bounded_linear: "bounded_linear T \<Longrightarrow> integrable M f \<Longrightarrow> integrable M (\<lambda>x. T (f x))"
   966   by (auto simp: integrable.simps intro: has_bochner_integral_bounded_linear)
   967 
   968 lemma integrable_scaleR_left[simp, intro]: "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> integrable M (\<lambda>x. f x *\<^sub>R c)"
   969   unfolding integrable.simps by fastforce
   970 
   971 lemma integrable_scaleR_right[simp, intro]: "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> integrable M (\<lambda>x. c *\<^sub>R f x)"
   972   unfolding integrable.simps by fastforce
   973 
   974 lemma integrable_mult_left[simp, intro]:
   975   fixes c :: "_::{real_normed_algebra,second_countable_topology}"
   976   shows "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> integrable M (\<lambda>x. f x * c)"
   977   unfolding integrable.simps by fastforce
   978 
   979 lemma integrable_mult_right[simp, intro]:
   980   fixes c :: "_::{real_normed_algebra,second_countable_topology}"
   981   shows "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> integrable M (\<lambda>x. c * f x)"
   982   unfolding integrable.simps by fastforce
   983 
   984 lemma integrable_divide_zero[simp, intro]:
   985   fixes c :: "_::{real_normed_field, field_inverse_zero, second_countable_topology}"
   986   shows "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> integrable M (\<lambda>x. f x / c)"
   987   unfolding integrable.simps by fastforce
   988 
   989 lemma integrable_inner_left[simp, intro]:
   990   "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> integrable M (\<lambda>x. f x \<bullet> c)"
   991   unfolding integrable.simps by fastforce
   992 
   993 lemma integrable_inner_right[simp, intro]:
   994   "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> integrable M (\<lambda>x. c \<bullet> f x)"
   995   unfolding integrable.simps by fastforce
   996 
   997 lemmas integrable_minus[simp, intro] =
   998   integrable_bounded_linear[OF bounded_linear_minus[OF bounded_linear_ident]]
   999 lemmas integrable_divide[simp, intro] =
  1000   integrable_bounded_linear[OF bounded_linear_divide]
  1001 lemmas integrable_Re[simp, intro] =
  1002   integrable_bounded_linear[OF bounded_linear_Re]
  1003 lemmas integrable_Im[simp, intro] =
  1004   integrable_bounded_linear[OF bounded_linear_Im]
  1005 lemmas integrable_cnj[simp, intro] =
  1006   integrable_bounded_linear[OF bounded_linear_cnj]
  1007 lemmas integrable_of_real[simp, intro] =
  1008   integrable_bounded_linear[OF bounded_linear_of_real]
  1009 lemmas integrable_fst[simp, intro] =
  1010   integrable_bounded_linear[OF bounded_linear_fst]
  1011 lemmas integrable_snd[simp, intro] =
  1012   integrable_bounded_linear[OF bounded_linear_snd]
  1013 
  1014 lemma integral_zero[simp]: "integral\<^sup>L M (\<lambda>x. 0) = 0"
  1015   by (intro has_bochner_integral_integral_eq has_bochner_integral_zero)
  1016 
  1017 lemma integral_add[simp]: "integrable M f \<Longrightarrow> integrable M g \<Longrightarrow>
  1018     integral\<^sup>L M (\<lambda>x. f x + g x) = integral\<^sup>L M f + integral\<^sup>L M g"
  1019   by (intro has_bochner_integral_integral_eq has_bochner_integral_add has_bochner_integral_integrable)
  1020 
  1021 lemma integral_diff[simp]: "integrable M f \<Longrightarrow> integrable M g \<Longrightarrow>
  1022     integral\<^sup>L M (\<lambda>x. f x - g x) = integral\<^sup>L M f - integral\<^sup>L M g"
  1023   by (intro has_bochner_integral_integral_eq has_bochner_integral_diff has_bochner_integral_integrable)
  1024 
  1025 lemma integral_setsum[simp]: "(\<And>i. i \<in> I \<Longrightarrow> integrable M (f i)) \<Longrightarrow>
  1026   integral\<^sup>L M (\<lambda>x. \<Sum>i\<in>I. f i x) = (\<Sum>i\<in>I. integral\<^sup>L M (f i))"
  1027   by (intro has_bochner_integral_integral_eq has_bochner_integral_setsum has_bochner_integral_integrable)
  1028 
  1029 lemma integral_bounded_linear: "bounded_linear T \<Longrightarrow> integrable M f \<Longrightarrow>
  1030     integral\<^sup>L M (\<lambda>x. T (f x)) = T (integral\<^sup>L M f)"
  1031   by (metis has_bochner_integral_bounded_linear has_bochner_integral_integrable has_bochner_integral_integral_eq)
  1032 
  1033 lemma integral_bounded_linear':
  1034   assumes T: "bounded_linear T" and T': "bounded_linear T'"
  1035   assumes *: "\<not> (\<forall>x. T x = 0) \<Longrightarrow> (\<forall>x. T' (T x) = x)"
  1036   shows "integral\<^sup>L M (\<lambda>x. T (f x)) = T (integral\<^sup>L M f)"
  1037 proof cases
  1038   assume "(\<forall>x. T x = 0)" then show ?thesis
  1039     by simp
  1040 next
  1041   assume **: "\<not> (\<forall>x. T x = 0)"
  1042   show ?thesis
  1043   proof cases
  1044     assume "integrable M f" with T show ?thesis
  1045       by (rule integral_bounded_linear)
  1046   next
  1047     assume not: "\<not> integrable M f"
  1048     moreover have "\<not> integrable M (\<lambda>x. T (f x))"
  1049     proof
  1050       assume "integrable M (\<lambda>x. T (f x))"
  1051       from integrable_bounded_linear[OF T' this] not *[OF **]
  1052       show False
  1053         by auto
  1054     qed
  1055     ultimately show ?thesis
  1056       using T by (simp add: not_integrable_integral_eq linear_simps)
  1057   qed
  1058 qed
  1059 
  1060 lemma integral_scaleR_left[simp]: "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> (\<integral> x. f x *\<^sub>R c \<partial>M) = integral\<^sup>L M f *\<^sub>R c"
  1061   by (intro has_bochner_integral_integral_eq has_bochner_integral_integrable has_bochner_integral_scaleR_left)
  1062 
  1063 lemma integral_scaleR_right[simp]: "(\<integral> x. c *\<^sub>R f x \<partial>M) = c *\<^sub>R integral\<^sup>L M f"
  1064   by (rule integral_bounded_linear'[OF bounded_linear_scaleR_right bounded_linear_scaleR_right[of "1 / c"]]) simp
  1065 
  1066 lemma integral_mult_left[simp]:
  1067   fixes c :: "_::{real_normed_algebra,second_countable_topology}"
  1068   shows "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> (\<integral> x. f x * c \<partial>M) = integral\<^sup>L M f * c"
  1069   by (intro has_bochner_integral_integral_eq has_bochner_integral_integrable has_bochner_integral_mult_left)
  1070 
  1071 lemma integral_mult_right[simp]:
  1072   fixes c :: "_::{real_normed_algebra,second_countable_topology}"
  1073   shows "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> (\<integral> x. c * f x \<partial>M) = c * integral\<^sup>L M f"
  1074   by (intro has_bochner_integral_integral_eq has_bochner_integral_integrable has_bochner_integral_mult_right)
  1075 
  1076 lemma integral_mult_left_zero[simp]:
  1077   fixes c :: "_::{real_normed_field,second_countable_topology}"
  1078   shows "(\<integral> x. f x * c \<partial>M) = integral\<^sup>L M f * c"
  1079   by (rule integral_bounded_linear'[OF bounded_linear_mult_left bounded_linear_mult_left[of "1 / c"]]) simp
  1080 
  1081 lemma integral_mult_right_zero[simp]:
  1082   fixes c :: "_::{real_normed_field,second_countable_topology}"
  1083   shows "(\<integral> x. c * f x \<partial>M) = c * integral\<^sup>L M f"
  1084   by (rule integral_bounded_linear'[OF bounded_linear_mult_right bounded_linear_mult_right[of "1 / c"]]) simp
  1085 
  1086 lemma integral_inner_left[simp]: "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> (\<integral> x. f x \<bullet> c \<partial>M) = integral\<^sup>L M f \<bullet> c"
  1087   by (intro has_bochner_integral_integral_eq has_bochner_integral_integrable has_bochner_integral_inner_left)
  1088 
  1089 lemma integral_inner_right[simp]: "(c \<noteq> 0 \<Longrightarrow> integrable M f) \<Longrightarrow> (\<integral> x. c \<bullet> f x \<partial>M) = c \<bullet> integral\<^sup>L M f"
  1090   by (intro has_bochner_integral_integral_eq has_bochner_integral_integrable has_bochner_integral_inner_right)
  1091 
  1092 lemma integral_divide_zero[simp]:
  1093   fixes c :: "_::{real_normed_field, field_inverse_zero, second_countable_topology}"
  1094   shows "integral\<^sup>L M (\<lambda>x. f x / c) = integral\<^sup>L M f / c"
  1095   by (rule integral_bounded_linear'[OF bounded_linear_divide bounded_linear_mult_left[of c]]) simp
  1096 
  1097 lemma integral_minus[simp]: "integral\<^sup>L M (\<lambda>x. - f x) = - integral\<^sup>L M f"
  1098   by (rule integral_bounded_linear'[OF bounded_linear_minus[OF bounded_linear_ident] bounded_linear_minus[OF bounded_linear_ident]]) simp
  1099 
  1100 lemma integral_complex_of_real[simp]: "integral\<^sup>L M (\<lambda>x. complex_of_real (f x)) = of_real (integral\<^sup>L M f)"
  1101   by (rule integral_bounded_linear'[OF bounded_linear_of_real bounded_linear_Re]) simp
  1102 
  1103 lemma integral_cnj[simp]: "integral\<^sup>L M (\<lambda>x. cnj (f x)) = cnj (integral\<^sup>L M f)"
  1104   by (rule integral_bounded_linear'[OF bounded_linear_cnj bounded_linear_cnj]) simp
  1105 
  1106 lemmas integral_divide[simp] =
  1107   integral_bounded_linear[OF bounded_linear_divide]
  1108 lemmas integral_Re[simp] =
  1109   integral_bounded_linear[OF bounded_linear_Re]
  1110 lemmas integral_Im[simp] =
  1111   integral_bounded_linear[OF bounded_linear_Im]
  1112 lemmas integral_of_real[simp] =
  1113   integral_bounded_linear[OF bounded_linear_of_real]
  1114 lemmas integral_fst[simp] =
  1115   integral_bounded_linear[OF bounded_linear_fst]
  1116 lemmas integral_snd[simp] =
  1117   integral_bounded_linear[OF bounded_linear_snd]
  1118 
  1119 lemma integral_norm_bound_ereal:
  1120   "integrable M f \<Longrightarrow> norm (integral\<^sup>L M f) \<le> (\<integral>\<^sup>+x. norm (f x) \<partial>M)"
  1121   by (metis has_bochner_integral_integrable has_bochner_integral_norm_bound)
  1122 
  1123 lemma integrableI_sequence:
  1124   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1125   assumes f[measurable]: "f \<in> borel_measurable M"
  1126   assumes s: "\<And>i. simple_bochner_integrable M (s i)"
  1127   assumes lim: "(\<lambda>i. \<integral>\<^sup>+x. norm (f x - s i x) \<partial>M) ----> 0" (is "?S ----> 0")
  1128   shows "integrable M f"
  1129 proof -
  1130   let ?s = "\<lambda>n. simple_bochner_integral M (s n)"
  1131 
  1132   have "\<exists>x. ?s ----> x"
  1133     unfolding convergent_eq_cauchy
  1134   proof (rule metric_CauchyI)
  1135     fix e :: real assume "0 < e"
  1136     then have "0 < ereal (e / 2)" by auto
  1137     from order_tendstoD(2)[OF lim this]
  1138     obtain M where M: "\<And>n. M \<le> n \<Longrightarrow> ?S n < e / 2"
  1139       by (auto simp: eventually_sequentially)
  1140     show "\<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (?s m) (?s n) < e"
  1141     proof (intro exI allI impI)
  1142       fix m n assume m: "M \<le> m" and n: "M \<le> n"
  1143       have "?S n \<noteq> \<infinity>"
  1144         using M[OF n] by auto
  1145       have "norm (?s n - ?s m) \<le> ?S n + ?S m"
  1146         by (intro simple_bochner_integral_bounded s f)
  1147       also have "\<dots> < ereal (e / 2) + e / 2"
  1148         using ereal_add_strict_mono[OF less_imp_le[OF M[OF n]] _ `?S n \<noteq> \<infinity>` M[OF m]]
  1149         by (auto simp: nn_integral_nonneg)
  1150       also have "\<dots> = e" by simp
  1151       finally show "dist (?s n) (?s m) < e"
  1152         by (simp add: dist_norm)
  1153     qed
  1154   qed
  1155   then obtain x where "?s ----> x" ..
  1156   show ?thesis
  1157     by (rule, rule) fact+
  1158 qed
  1159 
  1160 lemma nn_integral_dominated_convergence_norm:
  1161   fixes u' :: "_ \<Rightarrow> _::{real_normed_vector, second_countable_topology}"
  1162   assumes [measurable]:
  1163        "\<And>i. u i \<in> borel_measurable M" "u' \<in> borel_measurable M" "w \<in> borel_measurable M"
  1164     and bound: "\<And>j. AE x in M. norm (u j x) \<le> w x"
  1165     and w: "(\<integral>\<^sup>+x. w x \<partial>M) < \<infinity>"
  1166     and u': "AE x in M. (\<lambda>i. u i x) ----> u' x"
  1167   shows "(\<lambda>i. (\<integral>\<^sup>+x. norm (u' x - u i x) \<partial>M)) ----> 0"
  1168 proof -
  1169   have "AE x in M. \<forall>j. norm (u j x) \<le> w x"
  1170     unfolding AE_all_countable by rule fact
  1171   with u' have bnd: "AE x in M. \<forall>j. norm (u' x - u j x) \<le> 2 * w x"
  1172   proof (eventually_elim, intro allI)
  1173     fix i x assume "(\<lambda>i. u i x) ----> u' x" "\<forall>j. norm (u j x) \<le> w x" "\<forall>j. norm (u j x) \<le> w x"
  1174     then have "norm (u' x) \<le> w x" "norm (u i x) \<le> w x"
  1175       by (auto intro: LIMSEQ_le_const2 tendsto_norm)
  1176     then have "norm (u' x) + norm (u i x) \<le> 2 * w x"
  1177       by simp
  1178     also have "norm (u' x - u i x) \<le> norm (u' x) + norm (u i x)"
  1179       by (rule norm_triangle_ineq4)
  1180     finally (xtrans) show "norm (u' x - u i x) \<le> 2 * w x" .
  1181   qed
  1182   
  1183   have "(\<lambda>i. (\<integral>\<^sup>+x. norm (u' x - u i x) \<partial>M)) ----> (\<integral>\<^sup>+x. 0 \<partial>M)"
  1184   proof (rule nn_integral_dominated_convergence)  
  1185     show "(\<integral>\<^sup>+x. 2 * w x \<partial>M) < \<infinity>"
  1186       by (rule nn_integral_mult_bounded_inf[OF _ w, of 2]) auto
  1187     show "AE x in M. (\<lambda>i. ereal (norm (u' x - u i x))) ----> 0"
  1188       using u' 
  1189     proof eventually_elim
  1190       fix x assume "(\<lambda>i. u i x) ----> u' x"
  1191       from tendsto_diff[OF tendsto_const[of "u' x"] this]
  1192       show "(\<lambda>i. ereal (norm (u' x - u i x))) ----> 0"
  1193         by (simp add: zero_ereal_def tendsto_norm_zero_iff)
  1194     qed
  1195   qed (insert bnd, auto)
  1196   then show ?thesis by simp
  1197 qed
  1198 
  1199 lemma integrableI_bounded:
  1200   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1201   assumes f[measurable]: "f \<in> borel_measurable M" and fin: "(\<integral>\<^sup>+x. norm (f x) \<partial>M) < \<infinity>"
  1202   shows "integrable M f"
  1203 proof -
  1204   from borel_measurable_implies_sequence_metric[OF f, of 0] obtain s where
  1205     s: "\<And>i. simple_function M (s i)" and
  1206     pointwise: "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) ----> f x" and
  1207     bound: "\<And>i x. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)"
  1208     by (simp add: norm_conv_dist) metis
  1209   
  1210   show ?thesis
  1211   proof (rule integrableI_sequence)
  1212     { fix i
  1213       have "(\<integral>\<^sup>+x. norm (s i x) \<partial>M) \<le> (\<integral>\<^sup>+x. 2 * ereal (norm (f x)) \<partial>M)"
  1214         by (intro nn_integral_mono) (simp add: bound)
  1215       also have "\<dots> = 2 * (\<integral>\<^sup>+x. ereal (norm (f x)) \<partial>M)"
  1216         by (rule nn_integral_cmult) auto
  1217       finally have "(\<integral>\<^sup>+x. norm (s i x) \<partial>M) < \<infinity>"
  1218         using fin by auto }
  1219     note fin_s = this
  1220 
  1221     show "\<And>i. simple_bochner_integrable M (s i)"
  1222       by (rule simple_bochner_integrableI_bounded) fact+
  1223 
  1224     show "(\<lambda>i. \<integral>\<^sup>+ x. ereal (norm (f x - s i x)) \<partial>M) ----> 0"
  1225     proof (rule nn_integral_dominated_convergence_norm)
  1226       show "\<And>j. AE x in M. norm (s j x) \<le> 2 * norm (f x)"
  1227         using bound by auto
  1228       show "\<And>i. s i \<in> borel_measurable M" "(\<lambda>x. 2 * norm (f x)) \<in> borel_measurable M"
  1229         using s by (auto intro: borel_measurable_simple_function)
  1230       show "(\<integral>\<^sup>+ x. ereal (2 * norm (f x)) \<partial>M) < \<infinity>"
  1231         using fin unfolding times_ereal.simps(1)[symmetric] by (subst nn_integral_cmult) auto
  1232       show "AE x in M. (\<lambda>i. s i x) ----> f x"
  1233         using pointwise by auto
  1234     qed fact
  1235   qed fact
  1236 qed
  1237 
  1238 lemma integrableI_nonneg:
  1239   fixes f :: "'a \<Rightarrow> real"
  1240   assumes "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x" "(\<integral>\<^sup>+x. f x \<partial>M) < \<infinity>"
  1241   shows "integrable M f"
  1242 proof -
  1243   have "(\<integral>\<^sup>+x. norm (f x) \<partial>M) = (\<integral>\<^sup>+x. f x \<partial>M)"
  1244     using assms by (intro nn_integral_cong_AE) auto
  1245   then show ?thesis
  1246     using assms by (intro integrableI_bounded) auto
  1247 qed
  1248 
  1249 lemma integrable_iff_bounded:
  1250   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1251   shows "integrable M f \<longleftrightarrow> f \<in> borel_measurable M \<and> (\<integral>\<^sup>+x. norm (f x) \<partial>M) < \<infinity>"
  1252   using integrableI_bounded[of f M] has_bochner_integral_implies_finite_norm[of M f]
  1253   unfolding integrable.simps has_bochner_integral.simps[abs_def] by auto
  1254 
  1255 lemma integrable_bound:
  1256   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1257     and g :: "'a \<Rightarrow> 'c::{banach, second_countable_topology}"
  1258   shows "integrable M f \<Longrightarrow> g \<in> borel_measurable M \<Longrightarrow> (AE x in M. norm (g x) \<le> norm (f x)) \<Longrightarrow>
  1259     integrable M g"
  1260   unfolding integrable_iff_bounded
  1261 proof safe
  1262   assume "f \<in> borel_measurable M" "g \<in> borel_measurable M"
  1263   assume "AE x in M. norm (g x) \<le> norm (f x)"
  1264   then have "(\<integral>\<^sup>+ x. ereal (norm (g x)) \<partial>M) \<le> (\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M)"
  1265     by  (intro nn_integral_mono_AE) auto
  1266   also assume "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) < \<infinity>"
  1267   finally show "(\<integral>\<^sup>+ x. ereal (norm (g x)) \<partial>M) < \<infinity>" .
  1268 qed 
  1269 
  1270 lemma integrable_abs[simp, intro]:
  1271   fixes f :: "'a \<Rightarrow> real"
  1272   assumes [measurable]: "integrable M f" shows "integrable M (\<lambda>x. \<bar>f x\<bar>)"
  1273   using assms by (rule integrable_bound) auto
  1274 
  1275 lemma integrable_norm[simp, intro]:
  1276   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1277   assumes [measurable]: "integrable M f" shows "integrable M (\<lambda>x. norm (f x))"
  1278   using assms by (rule integrable_bound) auto
  1279   
  1280 lemma integrable_norm_cancel:
  1281   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1282   assumes [measurable]: "integrable M (\<lambda>x. norm (f x))" "f \<in> borel_measurable M" shows "integrable M f"
  1283   using assms by (rule integrable_bound) auto
  1284 
  1285 lemma integrable_abs_cancel:
  1286   fixes f :: "'a \<Rightarrow> real"
  1287   assumes [measurable]: "integrable M (\<lambda>x. \<bar>f x\<bar>)" "f \<in> borel_measurable M" shows "integrable M f"
  1288   using assms by (rule integrable_bound) auto
  1289 
  1290 lemma integrable_max[simp, intro]:
  1291   fixes f :: "'a \<Rightarrow> real"
  1292   assumes fg[measurable]: "integrable M f" "integrable M g"
  1293   shows "integrable M (\<lambda>x. max (f x) (g x))"
  1294   using integrable_add[OF integrable_norm[OF fg(1)] integrable_norm[OF fg(2)]]
  1295   by (rule integrable_bound) auto
  1296 
  1297 lemma integrable_min[simp, intro]:
  1298   fixes f :: "'a \<Rightarrow> real"
  1299   assumes fg[measurable]: "integrable M f" "integrable M g"
  1300   shows "integrable M (\<lambda>x. min (f x) (g x))"
  1301   using integrable_add[OF integrable_norm[OF fg(1)] integrable_norm[OF fg(2)]]
  1302   by (rule integrable_bound) auto
  1303 
  1304 lemma integral_minus_iff[simp]:
  1305   "integrable M (\<lambda>x. - f x ::'a::{banach, second_countable_topology}) \<longleftrightarrow> integrable M f"
  1306   unfolding integrable_iff_bounded
  1307   by (auto intro: borel_measurable_uminus[of "\<lambda>x. - f x" M, simplified])
  1308 
  1309 lemma integrable_indicator_iff:
  1310   "integrable M (indicator A::_ \<Rightarrow> real) \<longleftrightarrow> A \<inter> space M \<in> sets M \<and> emeasure M (A \<inter> space M) < \<infinity>"
  1311   by (simp add: integrable_iff_bounded borel_measurable_indicator_iff ereal_indicator nn_integral_indicator'
  1312            cong: conj_cong)
  1313 
  1314 lemma integral_indicator[simp]: "integral\<^sup>L M (indicator A) = measure M (A \<inter> space M)"
  1315 proof cases
  1316   assume *: "A \<inter> space M \<in> sets M \<and> emeasure M (A \<inter> space M) < \<infinity>"
  1317   have "integral\<^sup>L M (indicator A) = integral\<^sup>L M (indicator (A \<inter> space M))"
  1318     by (intro integral_cong) (auto split: split_indicator)
  1319   also have "\<dots> = measure M (A \<inter> space M)"
  1320     using * by (intro has_bochner_integral_integral_eq has_bochner_integral_real_indicator) auto
  1321   finally show ?thesis .
  1322 next
  1323   assume *: "\<not> (A \<inter> space M \<in> sets M \<and> emeasure M (A \<inter> space M) < \<infinity>)"
  1324   have "integral\<^sup>L M (indicator A) = integral\<^sup>L M (indicator (A \<inter> space M) :: _ \<Rightarrow> real)"
  1325     by (intro integral_cong) (auto split: split_indicator)
  1326   also have "\<dots> = 0"
  1327     using * by (subst not_integrable_integral_eq) (auto simp: integrable_indicator_iff)
  1328   also have "\<dots> = measure M (A \<inter> space M)"
  1329     using * by (auto simp: measure_def emeasure_notin_sets)
  1330   finally show ?thesis .
  1331 qed
  1332 
  1333 lemma
  1334   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}" and w :: "'a \<Rightarrow> real"
  1335   assumes "f \<in> borel_measurable M" "\<And>i. s i \<in> borel_measurable M" "integrable M w"
  1336   assumes lim: "AE x in M. (\<lambda>i. s i x) ----> f x"
  1337   assumes bound: "\<And>i. AE x in M. norm (s i x) \<le> w x"
  1338   shows integrable_dominated_convergence: "integrable M f"
  1339     and integrable_dominated_convergence2: "\<And>i. integrable M (s i)"
  1340     and integral_dominated_convergence: "(\<lambda>i. integral\<^sup>L M (s i)) ----> integral\<^sup>L M f"
  1341 proof -
  1342   have "AE x in M. 0 \<le> w x"
  1343     using bound[of 0] by eventually_elim (auto intro: norm_ge_zero order_trans)
  1344   then have "(\<integral>\<^sup>+x. w x \<partial>M) = (\<integral>\<^sup>+x. norm (w x) \<partial>M)"
  1345     by (intro nn_integral_cong_AE) auto
  1346   with `integrable M w` have w: "w \<in> borel_measurable M" "(\<integral>\<^sup>+x. w x \<partial>M) < \<infinity>"
  1347     unfolding integrable_iff_bounded by auto
  1348 
  1349   show int_s: "\<And>i. integrable M (s i)"
  1350     unfolding integrable_iff_bounded
  1351   proof
  1352     fix i 
  1353     have "(\<integral>\<^sup>+ x. ereal (norm (s i x)) \<partial>M) \<le> (\<integral>\<^sup>+x. w x \<partial>M)"
  1354       using bound by (intro nn_integral_mono_AE) auto
  1355     with w show "(\<integral>\<^sup>+ x. ereal (norm (s i x)) \<partial>M) < \<infinity>" by auto
  1356   qed fact
  1357 
  1358   have all_bound: "AE x in M. \<forall>i. norm (s i x) \<le> w x"
  1359     using bound unfolding AE_all_countable by auto
  1360 
  1361   show int_f: "integrable M f"
  1362     unfolding integrable_iff_bounded
  1363   proof
  1364     have "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) \<le> (\<integral>\<^sup>+x. w x \<partial>M)"
  1365       using all_bound lim
  1366     proof (intro nn_integral_mono_AE, eventually_elim)
  1367       fix x assume "\<forall>i. norm (s i x) \<le> w x" "(\<lambda>i. s i x) ----> f x"
  1368       then show "ereal (norm (f x)) \<le> ereal (w x)"
  1369         by (intro LIMSEQ_le_const2[where X="\<lambda>i. ereal (norm (s i x))"] tendsto_intros lim_ereal[THEN iffD2]) auto
  1370     qed
  1371     with w show "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) < \<infinity>" by auto
  1372   qed fact
  1373 
  1374   have "(\<lambda>n. ereal (norm (integral\<^sup>L M (s n) - integral\<^sup>L M f))) ----> ereal 0" (is "?d ----> ereal 0")
  1375   proof (rule tendsto_sandwich)
  1376     show "eventually (\<lambda>n. ereal 0 \<le> ?d n) sequentially" "(\<lambda>_. ereal 0) ----> ereal 0" by auto
  1377     show "eventually (\<lambda>n. ?d n \<le> (\<integral>\<^sup>+x. norm (s n x - f x) \<partial>M)) sequentially"
  1378     proof (intro always_eventually allI)
  1379       fix n
  1380       have "?d n = norm (integral\<^sup>L M (\<lambda>x. s n x - f x))"
  1381         using int_f int_s by simp
  1382       also have "\<dots> \<le> (\<integral>\<^sup>+x. norm (s n x - f x) \<partial>M)"
  1383         by (intro int_f int_s integrable_diff integral_norm_bound_ereal)
  1384       finally show "?d n \<le> (\<integral>\<^sup>+x. norm (s n x - f x) \<partial>M)" .
  1385     qed
  1386     show "(\<lambda>n. \<integral>\<^sup>+x. norm (s n x - f x) \<partial>M) ----> ereal 0"
  1387       unfolding zero_ereal_def[symmetric]
  1388       apply (subst norm_minus_commute)
  1389     proof (rule nn_integral_dominated_convergence_norm[where w=w])
  1390       show "\<And>n. s n \<in> borel_measurable M"
  1391         using int_s unfolding integrable_iff_bounded by auto
  1392     qed fact+
  1393   qed
  1394   then have "(\<lambda>n. integral\<^sup>L M (s n) - integral\<^sup>L M f) ----> 0"
  1395     unfolding lim_ereal tendsto_norm_zero_iff .
  1396   from tendsto_add[OF this tendsto_const[of "integral\<^sup>L M f"]]
  1397   show "(\<lambda>i. integral\<^sup>L M (s i)) ----> integral\<^sup>L M f"  by simp
  1398 qed
  1399 
  1400 lemma integrable_mult_left_iff:
  1401   fixes f :: "'a \<Rightarrow> real"
  1402   shows "integrable M (\<lambda>x. c * f x) \<longleftrightarrow> c = 0 \<or> integrable M f"
  1403   using integrable_mult_left[of c M f] integrable_mult_left[of "1 / c" M "\<lambda>x. c * f x"]
  1404   by (cases "c = 0") auto
  1405 
  1406 lemma nn_integral_eq_integral:
  1407   assumes f: "integrable M f"
  1408   assumes nonneg: "AE x in M. 0 \<le> f x" 
  1409   shows "(\<integral>\<^sup>+ x. f x \<partial>M) = integral\<^sup>L M f"
  1410 proof -
  1411   { fix f :: "'a \<Rightarrow> real" assume f: "f \<in> borel_measurable M" "\<And>x. 0 \<le> f x" "integrable M f"
  1412     then have "(\<integral>\<^sup>+ x. f x \<partial>M) = integral\<^sup>L M f"
  1413     proof (induct rule: borel_measurable_induct_real)
  1414       case (set A) then show ?case
  1415         by (simp add: integrable_indicator_iff ereal_indicator emeasure_eq_ereal_measure)
  1416     next
  1417       case (mult f c) then show ?case
  1418         unfolding times_ereal.simps(1)[symmetric]
  1419         by (subst nn_integral_cmult)
  1420            (auto simp add: integrable_mult_left_iff zero_ereal_def[symmetric])
  1421     next
  1422       case (add g f)
  1423       then have "integrable M f" "integrable M g"
  1424         by (auto intro!: integrable_bound[OF add(8)])
  1425       with add show ?case
  1426         unfolding plus_ereal.simps(1)[symmetric]
  1427         by (subst nn_integral_add) auto
  1428     next
  1429       case (seq s)
  1430       { fix i x assume "x \<in> space M" with seq(4) have "s i x \<le> f x"
  1431           by (intro LIMSEQ_le_const[OF seq(5)] exI[of _ i]) (auto simp: incseq_def le_fun_def) }
  1432       note s_le_f = this
  1433 
  1434       show ?case
  1435       proof (rule LIMSEQ_unique)
  1436         show "(\<lambda>i. ereal (integral\<^sup>L M (s i))) ----> ereal (integral\<^sup>L M f)"
  1437           unfolding lim_ereal
  1438         proof (rule integral_dominated_convergence[where w=f])
  1439           show "integrable M f" by fact
  1440           from s_le_f seq show "\<And>i. AE x in M. norm (s i x) \<le> f x"
  1441             by auto
  1442         qed (insert seq, auto)
  1443         have int_s: "\<And>i. integrable M (s i)"
  1444           using seq f s_le_f by (intro integrable_bound[OF f(3)]) auto
  1445         have "(\<lambda>i. \<integral>\<^sup>+ x. s i x \<partial>M) ----> \<integral>\<^sup>+ x. f x \<partial>M"
  1446           using seq s_le_f f
  1447           by (intro nn_integral_dominated_convergence[where w=f])
  1448              (auto simp: integrable_iff_bounded)
  1449         also have "(\<lambda>i. \<integral>\<^sup>+x. s i x \<partial>M) = (\<lambda>i. \<integral>x. s i x \<partial>M)"
  1450           using seq int_s by simp
  1451         finally show "(\<lambda>i. \<integral>x. s i x \<partial>M) ----> \<integral>\<^sup>+x. f x \<partial>M"
  1452           by simp
  1453       qed
  1454     qed }
  1455   from this[of "\<lambda>x. max 0 (f x)"] assms have "(\<integral>\<^sup>+ x. max 0 (f x) \<partial>M) = integral\<^sup>L M (\<lambda>x. max 0 (f x))"
  1456     by simp
  1457   also have "\<dots> = integral\<^sup>L M f"
  1458     using assms by (auto intro!: integral_cong_AE)
  1459   also have "(\<integral>\<^sup>+ x. max 0 (f x) \<partial>M) = (\<integral>\<^sup>+ x. f x \<partial>M)"
  1460     using assms by (auto intro!: nn_integral_cong_AE simp: max_def)
  1461   finally show ?thesis .
  1462 qed
  1463 
  1464 lemma
  1465   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> 'a :: {banach, second_countable_topology}"
  1466   assumes integrable[measurable]: "\<And>i. integrable M (f i)"
  1467   and summable: "AE x in M. summable (\<lambda>i. norm (f i x))"
  1468   and sums: "summable (\<lambda>i. (\<integral>x. norm (f i x) \<partial>M))"
  1469   shows integrable_suminf: "integrable M (\<lambda>x. (\<Sum>i. f i x))" (is "integrable M ?S")
  1470     and sums_integral: "(\<lambda>i. integral\<^sup>L M (f i)) sums (\<integral>x. (\<Sum>i. f i x) \<partial>M)" (is "?f sums ?x")
  1471     and integral_suminf: "(\<integral>x. (\<Sum>i. f i x) \<partial>M) = (\<Sum>i. integral\<^sup>L M (f i))"
  1472     and summable_integral: "summable (\<lambda>i. integral\<^sup>L M (f i))"
  1473 proof -
  1474   have 1: "integrable M (\<lambda>x. \<Sum>i. norm (f i x))"
  1475   proof (rule integrableI_bounded)
  1476     have "(\<integral>\<^sup>+ x. ereal (norm (\<Sum>i. norm (f i x))) \<partial>M) = (\<integral>\<^sup>+ x. (\<Sum>i. ereal (norm (f i x))) \<partial>M)"
  1477       apply (intro nn_integral_cong_AE) 
  1478       using summable
  1479       apply eventually_elim
  1480       apply (simp add: suminf_ereal' suminf_nonneg)
  1481       done
  1482     also have "\<dots> = (\<Sum>i. \<integral>\<^sup>+ x. norm (f i x) \<partial>M)"
  1483       by (intro nn_integral_suminf) auto
  1484     also have "\<dots> = (\<Sum>i. ereal (\<integral>x. norm (f i x) \<partial>M))"
  1485       by (intro arg_cong[where f=suminf] ext nn_integral_eq_integral integrable_norm integrable) auto
  1486     finally show "(\<integral>\<^sup>+ x. ereal (norm (\<Sum>i. norm (f i x))) \<partial>M) < \<infinity>"
  1487       by (simp add: suminf_ereal' sums)
  1488   qed simp
  1489 
  1490   have 2: "AE x in M. (\<lambda>n. \<Sum>i<n. f i x) ----> (\<Sum>i. f i x)"
  1491     using summable by eventually_elim (auto intro: summable_LIMSEQ summable_norm_cancel)
  1492 
  1493   have 3: "\<And>j. AE x in M. norm (\<Sum>i<j. f i x) \<le> (\<Sum>i. norm (f i x))"
  1494     using summable
  1495   proof eventually_elim
  1496     fix j x assume [simp]: "summable (\<lambda>i. norm (f i x))"
  1497     have "norm (\<Sum>i<j. f i x) \<le> (\<Sum>i<j. norm (f i x))" by (rule norm_setsum)
  1498     also have "\<dots> \<le> (\<Sum>i. norm (f i x))"
  1499       using setsum_le_suminf[of "\<lambda>i. norm (f i x)"] unfolding sums_iff by auto
  1500     finally show "norm (\<Sum>i<j. f i x) \<le> (\<Sum>i. norm (f i x))" by simp
  1501   qed
  1502 
  1503   note ibl = integrable_dominated_convergence[OF _ _ 1 2 3]
  1504   note int = integral_dominated_convergence[OF _ _ 1 2 3]
  1505 
  1506   show "integrable M ?S"
  1507     by (rule ibl) measurable
  1508 
  1509   show "?f sums ?x" unfolding sums_def
  1510     using int by (simp add: integrable)
  1511   then show "?x = suminf ?f" "summable ?f"
  1512     unfolding sums_iff by auto
  1513 qed
  1514 
  1515 lemma integral_norm_bound:
  1516   fixes f :: "_ \<Rightarrow> 'a :: {banach, second_countable_topology}"
  1517   shows "integrable M f \<Longrightarrow> norm (integral\<^sup>L M f) \<le> (\<integral>x. norm (f x) \<partial>M)"
  1518   using nn_integral_eq_integral[of M "\<lambda>x. norm (f x)"]
  1519   using integral_norm_bound_ereal[of M f] by simp
  1520   
  1521 lemma integrableI_nn_integral_finite:
  1522   assumes [measurable]: "f \<in> borel_measurable M"
  1523     and nonneg: "AE x in M. 0 \<le> f x"
  1524     and finite: "(\<integral>\<^sup>+x. f x \<partial>M) = ereal x"
  1525   shows "integrable M f"
  1526 proof (rule integrableI_bounded)
  1527   have "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) = (\<integral>\<^sup>+ x. ereal (f x) \<partial>M)"
  1528     using nonneg by (intro nn_integral_cong_AE) auto
  1529   with finite show "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) < \<infinity>"
  1530     by auto
  1531 qed simp
  1532 
  1533 lemma integral_eq_nn_integral:
  1534   assumes [measurable]: "f \<in> borel_measurable M"
  1535   assumes nonneg: "AE x in M. 0 \<le> f x"
  1536   shows "integral\<^sup>L M f = real (\<integral>\<^sup>+ x. ereal (f x) \<partial>M)"
  1537 proof cases
  1538   assume *: "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) = \<infinity>"
  1539   also have "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) = (\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M)"
  1540     using nonneg by (intro nn_integral_cong_AE) auto
  1541   finally have "\<not> integrable M f"
  1542     by (auto simp: integrable_iff_bounded)
  1543   then show ?thesis
  1544     by (simp add: * not_integrable_integral_eq)
  1545 next
  1546   assume "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<noteq> \<infinity>"
  1547   then have "integrable M f"
  1548     by (cases "\<integral>\<^sup>+ x. ereal (f x) \<partial>M") (auto intro!: integrableI_nn_integral_finite assms)
  1549   from nn_integral_eq_integral[OF this nonneg] show ?thesis
  1550     by simp
  1551 qed
  1552   
  1553 lemma integrableI_simple_bochner_integrable:
  1554   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1555   shows "simple_bochner_integrable M f \<Longrightarrow> integrable M f"
  1556   by (intro integrableI_sequence[where s="\<lambda>_. f"] borel_measurable_simple_function)
  1557      (auto simp: zero_ereal_def[symmetric] simple_bochner_integrable.simps)
  1558 
  1559 lemma integrable_induct[consumes 1, case_names base add lim, induct pred: integrable]:
  1560   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1561   assumes "integrable M f"
  1562   assumes base: "\<And>A c. A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow> P (\<lambda>x. indicator A x *\<^sub>R c)"
  1563   assumes add: "\<And>f g. integrable M f \<Longrightarrow> P f \<Longrightarrow> integrable M g \<Longrightarrow> P g \<Longrightarrow> P (\<lambda>x. f x + g x)"
  1564   assumes lim: "\<And>f s. (\<And>i. integrable M (s i)) \<Longrightarrow> (\<And>i. P (s i)) \<Longrightarrow>
  1565    (\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) ----> f x) \<Longrightarrow>
  1566    (\<And>i x. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)) \<Longrightarrow> integrable M f \<Longrightarrow> P f"
  1567   shows "P f"
  1568 proof -
  1569   from `integrable M f` have f: "f \<in> borel_measurable M" "(\<integral>\<^sup>+x. norm (f x) \<partial>M) < \<infinity>"
  1570     unfolding integrable_iff_bounded by auto
  1571   from borel_measurable_implies_sequence_metric[OF f(1)]
  1572   obtain s where s: "\<And>i. simple_function M (s i)" "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. s i x) ----> f x"
  1573     "\<And>i x. x \<in> space M \<Longrightarrow> norm (s i x) \<le> 2 * norm (f x)"
  1574     unfolding norm_conv_dist by metis
  1575 
  1576   { fix f A 
  1577     have [simp]: "P (\<lambda>x. 0)"
  1578       using base[of "{}" undefined] by simp
  1579     have "(\<And>i::'b. i \<in> A \<Longrightarrow> integrable M (f i::'a \<Rightarrow> 'b)) \<Longrightarrow>
  1580     (\<And>i. i \<in> A \<Longrightarrow> P (f i)) \<Longrightarrow> P (\<lambda>x. \<Sum>i\<in>A. f i x)"
  1581     by (induct A rule: infinite_finite_induct) (auto intro!: add) }
  1582   note setsum = this
  1583 
  1584   def s' \<equiv> "\<lambda>i z. indicator (space M) z *\<^sub>R s i z"
  1585   then have s'_eq_s: "\<And>i x. x \<in> space M \<Longrightarrow> s' i x = s i x"
  1586     by simp
  1587 
  1588   have sf[measurable]: "\<And>i. simple_function M (s' i)"
  1589     unfolding s'_def using s(1)
  1590     by (intro simple_function_compose2[where h="op *\<^sub>R"] simple_function_indicator) auto
  1591 
  1592   { fix i 
  1593     have "\<And>z. {y. s' i z = y \<and> y \<in> s' i ` space M \<and> y \<noteq> 0 \<and> z \<in> space M} =
  1594         (if z \<in> space M \<and> s' i z \<noteq> 0 then {s' i z} else {})"
  1595       by (auto simp add: s'_def split: split_indicator)
  1596     then have "\<And>z. s' i = (\<lambda>z. \<Sum>y\<in>s' i`space M - {0}. indicator {x\<in>space M. s' i x = y} z *\<^sub>R y)"
  1597       using sf by (auto simp: fun_eq_iff simple_function_def s'_def) }
  1598   note s'_eq = this
  1599 
  1600   show "P f"
  1601   proof (rule lim)
  1602     fix i
  1603 
  1604     have "(\<integral>\<^sup>+x. norm (s' i x) \<partial>M) \<le> (\<integral>\<^sup>+x. 2 * ereal (norm (f x)) \<partial>M)"
  1605       using s by (intro nn_integral_mono) (auto simp: s'_eq_s)
  1606     also have "\<dots> < \<infinity>"
  1607       using f by (subst nn_integral_cmult) auto
  1608     finally have sbi: "simple_bochner_integrable M (s' i)"
  1609       using sf by (intro simple_bochner_integrableI_bounded) auto
  1610     then show "integrable M (s' i)"
  1611       by (rule integrableI_simple_bochner_integrable)
  1612 
  1613     { fix x assume"x \<in> space M" "s' i x \<noteq> 0"
  1614       then have "emeasure M {y \<in> space M. s' i y = s' i x} \<le> emeasure M {y \<in> space M. s' i y \<noteq> 0}"
  1615         by (intro emeasure_mono) auto
  1616       also have "\<dots> < \<infinity>"
  1617         using sbi by (auto elim: simple_bochner_integrable.cases)
  1618       finally have "emeasure M {y \<in> space M. s' i y = s' i x} \<noteq> \<infinity>" by simp }
  1619     then show "P (s' i)"
  1620       by (subst s'_eq) (auto intro!: setsum base)
  1621 
  1622     fix x assume "x \<in> space M" with s show "(\<lambda>i. s' i x) ----> f x"
  1623       by (simp add: s'_eq_s)
  1624     show "norm (s' i x) \<le> 2 * norm (f x)"
  1625       using `x \<in> space M` s by (simp add: s'_eq_s)
  1626   qed fact
  1627 qed
  1628 
  1629 lemma integral_nonneg_AE:
  1630   fixes f :: "'a \<Rightarrow> real"
  1631   assumes [measurable]: "AE x in M. 0 \<le> f x"
  1632   shows "0 \<le> integral\<^sup>L M f"
  1633 proof cases
  1634   assume [measurable]: "integrable M f"
  1635   then have "0 \<le> ereal (integral\<^sup>L M (\<lambda>x. max 0 (f x)))"
  1636     by (subst integral_eq_nn_integral) (auto intro: real_of_ereal_pos nn_integral_nonneg assms)
  1637   also have "integral\<^sup>L M (\<lambda>x. max 0 (f x)) = integral\<^sup>L M f"
  1638     using assms by (intro integral_cong_AE assms integrable_max) auto
  1639   finally show ?thesis
  1640     by simp
  1641 qed (simp add: not_integrable_integral_eq)
  1642 
  1643 lemma integral_eq_zero_AE:
  1644   "(AE x in M. f x = 0) \<Longrightarrow> integral\<^sup>L M f = 0"
  1645   using integral_cong_AE[of f M "\<lambda>_. 0"]
  1646   by (cases "integrable M f") (simp_all add: not_integrable_integral_eq)
  1647 
  1648 lemma integral_nonneg_eq_0_iff_AE:
  1649   fixes f :: "_ \<Rightarrow> real"
  1650   assumes f[measurable]: "integrable M f" and nonneg: "AE x in M. 0 \<le> f x"
  1651   shows "integral\<^sup>L M f = 0 \<longleftrightarrow> (AE x in M. f x = 0)"
  1652 proof
  1653   assume "integral\<^sup>L M f = 0"
  1654   then have "integral\<^sup>N M f = 0"
  1655     using nn_integral_eq_integral[OF f nonneg] by simp
  1656   then have "AE x in M. ereal (f x) \<le> 0"
  1657     by (simp add: nn_integral_0_iff_AE)
  1658   with nonneg show "AE x in M. f x = 0"
  1659     by auto
  1660 qed (auto simp add: integral_eq_zero_AE)
  1661 
  1662 lemma integral_mono_AE:
  1663   fixes f :: "'a \<Rightarrow> real"
  1664   assumes "integrable M f" "integrable M g" "AE x in M. f x \<le> g x"
  1665   shows "integral\<^sup>L M f \<le> integral\<^sup>L M g"
  1666 proof -
  1667   have "0 \<le> integral\<^sup>L M (\<lambda>x. g x - f x)"
  1668     using assms by (intro integral_nonneg_AE integrable_diff assms) auto
  1669   also have "\<dots> = integral\<^sup>L M g - integral\<^sup>L M f"
  1670     by (intro integral_diff assms)
  1671   finally show ?thesis by simp
  1672 qed
  1673 
  1674 lemma integral_mono:
  1675   fixes f :: "'a \<Rightarrow> real"
  1676   shows "integrable M f \<Longrightarrow> integrable M g \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x \<le> g x) \<Longrightarrow> 
  1677     integral\<^sup>L M f \<le> integral\<^sup>L M g"
  1678   by (intro integral_mono_AE) auto
  1679 
  1680 lemma (in finite_measure) integrable_measure: 
  1681   assumes I: "disjoint_family_on X I" "countable I"
  1682   shows "integrable (count_space I) (\<lambda>i. measure M (X i))"
  1683 proof -
  1684   have "(\<integral>\<^sup>+i. measure M (X i) \<partial>count_space I) = (\<integral>\<^sup>+i. measure M (if X i \<in> sets M then X i else {}) \<partial>count_space I)"
  1685     by (auto intro!: nn_integral_cong measure_notin_sets)
  1686   also have "\<dots> = measure M (\<Union>i\<in>I. if X i \<in> sets M then X i else {})"
  1687     using I unfolding emeasure_eq_measure[symmetric]
  1688     by (subst emeasure_UN_countable) (auto simp: disjoint_family_on_def)
  1689   finally show ?thesis
  1690     by (auto intro!: integrableI_bounded simp: measure_nonneg)
  1691 qed
  1692 
  1693 lemma integrableI_real_bounded:
  1694   assumes f: "f \<in> borel_measurable M" and ae: "AE x in M. 0 \<le> f x" and fin: "integral\<^sup>N M f < \<infinity>"
  1695   shows "integrable M f"
  1696 proof (rule integrableI_bounded)
  1697   have "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) = \<integral>\<^sup>+ x. ereal (f x) \<partial>M"
  1698     using ae by (auto intro: nn_integral_cong_AE)
  1699   also note fin
  1700   finally show "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) < \<infinity>" .
  1701 qed fact
  1702 
  1703 lemma integral_real_bounded:
  1704   assumes "AE x in M. 0 \<le> f x" "integral\<^sup>N M f \<le> ereal r"
  1705   shows "integral\<^sup>L M f \<le> r"
  1706 proof cases
  1707   assume "integrable M f" from nn_integral_eq_integral[OF this] assms show ?thesis
  1708     by simp
  1709 next
  1710   assume "\<not> integrable M f"
  1711   moreover have "0 \<le> ereal r"
  1712     using nn_integral_nonneg assms(2) by (rule order_trans)
  1713   ultimately show ?thesis
  1714     by (simp add: not_integrable_integral_eq)
  1715 qed
  1716 
  1717 subsection {* Restricted measure spaces *}
  1718 
  1719 lemma integrable_restrict_space:
  1720   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1721   assumes \<Omega>[simp]: "\<Omega> \<inter> space M \<in> sets M"
  1722   shows "integrable (restrict_space M \<Omega>) f \<longleftrightarrow> integrable M (\<lambda>x. indicator \<Omega> x *\<^sub>R f x)"
  1723   unfolding integrable_iff_bounded
  1724     borel_measurable_restrict_space_iff[OF \<Omega>]
  1725     nn_integral_restrict_space[OF \<Omega>]
  1726   by (simp add: ac_simps ereal_indicator times_ereal.simps(1)[symmetric] del: times_ereal.simps)
  1727 
  1728 lemma integral_restrict_space:
  1729   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1730   assumes \<Omega>[simp]: "\<Omega> \<inter> space M \<in> sets M"
  1731   shows "integral\<^sup>L (restrict_space M \<Omega>) f = integral\<^sup>L M (\<lambda>x. indicator \<Omega> x *\<^sub>R f x)"
  1732 proof (rule integral_eq_cases)
  1733   assume "integrable (restrict_space M \<Omega>) f"
  1734   then show ?thesis
  1735   proof induct
  1736     case (base A c) then show ?case
  1737       by (simp add: indicator_inter_arith[symmetric] sets_restrict_space_iff
  1738                     emeasure_restrict_space Int_absorb1 measure_restrict_space)
  1739   next
  1740     case (add g f) then show ?case
  1741       by (simp add: scaleR_add_right integrable_restrict_space)
  1742   next
  1743     case (lim f s)
  1744     show ?case
  1745     proof (rule LIMSEQ_unique)
  1746       show "(\<lambda>i. integral\<^sup>L (restrict_space M \<Omega>) (s i)) ----> integral\<^sup>L (restrict_space M \<Omega>) f"
  1747         using lim by (intro integral_dominated_convergence[where w="\<lambda>x. 2 * norm (f x)"]) simp_all
  1748       
  1749       show "(\<lambda>i. integral\<^sup>L (restrict_space M \<Omega>) (s i)) ----> (\<integral> x. indicator \<Omega> x *\<^sub>R f x \<partial>M)"
  1750         unfolding lim
  1751         using lim
  1752         by (intro integral_dominated_convergence[where w="\<lambda>x. 2 * norm (indicator \<Omega> x *\<^sub>R f x)"])
  1753            (auto simp add: space_restrict_space integrable_restrict_space
  1754                  simp del: norm_scaleR
  1755                  split: split_indicator)
  1756     qed
  1757   qed
  1758 qed (simp add: integrable_restrict_space)
  1759 
  1760 subsection {* Measure spaces with an associated density *}
  1761 
  1762 lemma integrable_density:
  1763   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}" and g :: "'a \<Rightarrow> real"
  1764   assumes [measurable]: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
  1765     and nn: "AE x in M. 0 \<le> g x"
  1766   shows "integrable (density M g) f \<longleftrightarrow> integrable M (\<lambda>x. g x *\<^sub>R f x)"
  1767   unfolding integrable_iff_bounded using nn
  1768   apply (simp add: nn_integral_density )
  1769   apply (intro arg_cong2[where f="op ="] refl nn_integral_cong_AE)
  1770   apply auto
  1771   done
  1772 
  1773 lemma integral_density:
  1774   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}" and g :: "'a \<Rightarrow> real"
  1775   assumes f: "f \<in> borel_measurable M"
  1776     and g[measurable]: "g \<in> borel_measurable M" "AE x in M. 0 \<le> g x"
  1777   shows "integral\<^sup>L (density M g) f = integral\<^sup>L M (\<lambda>x. g x *\<^sub>R f x)"
  1778 proof (rule integral_eq_cases)
  1779   assume "integrable (density M g) f"
  1780   then show ?thesis
  1781   proof induct
  1782     case (base A c)
  1783     then have [measurable]: "A \<in> sets M" by auto
  1784   
  1785     have int: "integrable M (\<lambda>x. g x * indicator A x)"
  1786       using g base integrable_density[of "indicator A :: 'a \<Rightarrow> real" M g] by simp
  1787     then have "integral\<^sup>L M (\<lambda>x. g x * indicator A x) = (\<integral>\<^sup>+ x. ereal (g x * indicator A x) \<partial>M)"
  1788       using g by (subst nn_integral_eq_integral) auto
  1789     also have "\<dots> = (\<integral>\<^sup>+ x. ereal (g x) * indicator A x \<partial>M)"
  1790       by (intro nn_integral_cong) (auto split: split_indicator)
  1791     also have "\<dots> = emeasure (density M g) A"
  1792       by (rule emeasure_density[symmetric]) auto
  1793     also have "\<dots> = ereal (measure (density M g) A)"
  1794       using base by (auto intro: emeasure_eq_ereal_measure)
  1795     also have "\<dots> = integral\<^sup>L (density M g) (indicator A)"
  1796       using base by simp
  1797     finally show ?case
  1798       using base by (simp add: int)
  1799   next
  1800     case (add f h)
  1801     then have [measurable]: "f \<in> borel_measurable M" "h \<in> borel_measurable M"
  1802       by (auto dest!: borel_measurable_integrable)
  1803     from add g show ?case
  1804       by (simp add: scaleR_add_right integrable_density)
  1805   next
  1806     case (lim f s)
  1807     have [measurable]: "f \<in> borel_measurable M" "\<And>i. s i \<in> borel_measurable M"
  1808       using lim(1,5)[THEN borel_measurable_integrable] by auto
  1809   
  1810     show ?case
  1811     proof (rule LIMSEQ_unique)
  1812       show "(\<lambda>i. integral\<^sup>L M (\<lambda>x. g x *\<^sub>R s i x)) ----> integral\<^sup>L M (\<lambda>x. g x *\<^sub>R f x)"
  1813       proof (rule integral_dominated_convergence)
  1814         show "integrable M (\<lambda>x. 2 * norm (g x *\<^sub>R f x))"
  1815           by (intro integrable_mult_right integrable_norm integrable_density[THEN iffD1] lim g) auto
  1816         show "AE x in M. (\<lambda>i. g x *\<^sub>R s i x) ----> g x *\<^sub>R f x"
  1817           using lim(3) by (auto intro!: tendsto_scaleR AE_I2[of M])
  1818         show "\<And>i. AE x in M. norm (g x *\<^sub>R s i x) \<le> 2 * norm (g x *\<^sub>R f x)"
  1819           using lim(4) g by (auto intro!: AE_I2[of M] mult_left_mono simp: field_simps)
  1820       qed auto
  1821       show "(\<lambda>i. integral\<^sup>L M (\<lambda>x. g x *\<^sub>R s i x)) ----> integral\<^sup>L (density M g) f"
  1822         unfolding lim(2)[symmetric]
  1823         by (rule integral_dominated_convergence[where w="\<lambda>x. 2 * norm (f x)"])
  1824            (insert lim(3-5), auto)
  1825     qed
  1826   qed
  1827 qed (simp add: f g integrable_density)
  1828 
  1829 lemma
  1830   fixes g :: "'a \<Rightarrow> real"
  1831   assumes "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x" "g \<in> borel_measurable M"
  1832   shows integral_real_density: "integral\<^sup>L (density M f) g = (\<integral> x. f x * g x \<partial>M)"
  1833     and integrable_real_density: "integrable (density M f) g \<longleftrightarrow> integrable M (\<lambda>x. f x * g x)"
  1834   using assms integral_density[of g M f] integrable_density[of g M f] by auto
  1835 
  1836 lemma has_bochner_integral_density:
  1837   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}" and g :: "'a \<Rightarrow> real"
  1838   shows "f \<in> borel_measurable M \<Longrightarrow> g \<in> borel_measurable M \<Longrightarrow> (AE x in M. 0 \<le> g x) \<Longrightarrow>
  1839     has_bochner_integral M (\<lambda>x. g x *\<^sub>R f x) x \<Longrightarrow> has_bochner_integral (density M g) f x"
  1840   by (simp add: has_bochner_integral_iff integrable_density integral_density)
  1841 
  1842 subsection {* Distributions *}
  1843 
  1844 lemma integrable_distr_eq:
  1845   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1846   assumes [measurable]: "g \<in> measurable M N" "f \<in> borel_measurable N"
  1847   shows "integrable (distr M N g) f \<longleftrightarrow> integrable M (\<lambda>x. f (g x))"
  1848   unfolding integrable_iff_bounded by (simp_all add: nn_integral_distr)
  1849 
  1850 lemma integrable_distr:
  1851   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1852   shows "T \<in> measurable M M' \<Longrightarrow> integrable (distr M M' T) f \<Longrightarrow> integrable M (\<lambda>x. f (T x))"
  1853   by (subst integrable_distr_eq[symmetric, where g=T])
  1854      (auto dest: borel_measurable_integrable)
  1855 
  1856 lemma integral_distr:
  1857   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1858   assumes g[measurable]: "g \<in> measurable M N" and f: "f \<in> borel_measurable N"
  1859   shows "integral\<^sup>L (distr M N g) f = integral\<^sup>L M (\<lambda>x. f (g x))"
  1860 proof (rule integral_eq_cases)
  1861   assume "integrable (distr M N g) f"
  1862   then show ?thesis
  1863   proof induct
  1864     case (base A c)
  1865     then have [measurable]: "A \<in> sets N" by auto
  1866     from base have int: "integrable (distr M N g) (\<lambda>a. indicator A a *\<^sub>R c)"
  1867       by (intro integrable_indicator)
  1868   
  1869     have "integral\<^sup>L (distr M N g) (\<lambda>a. indicator A a *\<^sub>R c) = measure (distr M N g) A *\<^sub>R c"
  1870       using base by auto
  1871     also have "\<dots> = measure M (g -` A \<inter> space M) *\<^sub>R c"
  1872       by (subst measure_distr) auto
  1873     also have "\<dots> = integral\<^sup>L M (\<lambda>a. indicator (g -` A \<inter> space M) a *\<^sub>R c)"
  1874       using base by (auto simp: emeasure_distr)
  1875     also have "\<dots> = integral\<^sup>L M (\<lambda>a. indicator A (g a) *\<^sub>R c)"
  1876       using int base by (intro integral_cong_AE) (auto simp: emeasure_distr split: split_indicator)
  1877     finally show ?case .
  1878   next
  1879     case (add f h)
  1880     then have [measurable]: "f \<in> borel_measurable N" "h \<in> borel_measurable N"
  1881       by (auto dest!: borel_measurable_integrable)
  1882     from add g show ?case
  1883       by (simp add: scaleR_add_right integrable_distr_eq)
  1884   next
  1885     case (lim f s)
  1886     have [measurable]: "f \<in> borel_measurable N" "\<And>i. s i \<in> borel_measurable N"
  1887       using lim(1,5)[THEN borel_measurable_integrable] by auto
  1888   
  1889     show ?case
  1890     proof (rule LIMSEQ_unique)
  1891       show "(\<lambda>i. integral\<^sup>L M (\<lambda>x. s i (g x))) ----> integral\<^sup>L M (\<lambda>x. f (g x))"
  1892       proof (rule integral_dominated_convergence)
  1893         show "integrable M (\<lambda>x. 2 * norm (f (g x)))"
  1894           using lim by (auto simp: integrable_distr_eq) 
  1895         show "AE x in M. (\<lambda>i. s i (g x)) ----> f (g x)"
  1896           using lim(3) g[THEN measurable_space] by auto
  1897         show "\<And>i. AE x in M. norm (s i (g x)) \<le> 2 * norm (f (g x))"
  1898           using lim(4) g[THEN measurable_space] by auto
  1899       qed auto
  1900       show "(\<lambda>i. integral\<^sup>L M (\<lambda>x. s i (g x))) ----> integral\<^sup>L (distr M N g) f"
  1901         unfolding lim(2)[symmetric]
  1902         by (rule integral_dominated_convergence[where w="\<lambda>x. 2 * norm (f x)"])
  1903            (insert lim(3-5), auto)
  1904     qed
  1905   qed
  1906 qed (simp add: f g integrable_distr_eq)
  1907 
  1908 lemma has_bochner_integral_distr:
  1909   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1910   shows "f \<in> borel_measurable N \<Longrightarrow> g \<in> measurable M N \<Longrightarrow>
  1911     has_bochner_integral M (\<lambda>x. f (g x)) x \<Longrightarrow> has_bochner_integral (distr M N g) f x"
  1912   by (simp add: has_bochner_integral_iff integrable_distr_eq integral_distr)
  1913 
  1914 subsection {* Lebesgue integration on @{const count_space} *}
  1915 
  1916 lemma integrable_count_space:
  1917   fixes f :: "'a \<Rightarrow> 'b::{banach,second_countable_topology}"
  1918   shows "finite X \<Longrightarrow> integrable (count_space X) f"
  1919   by (auto simp: nn_integral_count_space integrable_iff_bounded)
  1920 
  1921 lemma measure_count_space[simp]:
  1922   "B \<subseteq> A \<Longrightarrow> finite B \<Longrightarrow> measure (count_space A) B = card B"
  1923   unfolding measure_def by (subst emeasure_count_space ) auto
  1924 
  1925 lemma lebesgue_integral_count_space_finite_support:
  1926   assumes f: "finite {a\<in>A. f a \<noteq> 0}"
  1927   shows "(\<integral>x. f x \<partial>count_space A) = (\<Sum>a | a \<in> A \<and> f a \<noteq> 0. f a)"
  1928 proof -
  1929   have eq: "\<And>x. x \<in> A \<Longrightarrow> (\<Sum>a | x = a \<and> a \<in> A \<and> f a \<noteq> 0. f a) = (\<Sum>x\<in>{x}. f x)"
  1930     by (intro setsum_mono_zero_cong_left) auto
  1931     
  1932   have "(\<integral>x. f x \<partial>count_space A) = (\<integral>x. (\<Sum>a | a \<in> A \<and> f a \<noteq> 0. indicator {a} x *\<^sub>R f a) \<partial>count_space A)"
  1933     by (intro integral_cong refl) (simp add: f eq)
  1934   also have "\<dots> = (\<Sum>a | a \<in> A \<and> f a \<noteq> 0. measure (count_space A) {a} *\<^sub>R f a)"
  1935     by (subst integral_setsum) (auto intro!: setsum_cong)
  1936   finally show ?thesis
  1937     by auto
  1938 qed
  1939 
  1940 lemma lebesgue_integral_count_space_finite: "finite A \<Longrightarrow> (\<integral>x. f x \<partial>count_space A) = (\<Sum>a\<in>A. f a)"
  1941   by (subst lebesgue_integral_count_space_finite_support)
  1942      (auto intro!: setsum_mono_zero_cong_left)
  1943 
  1944 subsection {* Point measure *}
  1945 
  1946 lemma lebesgue_integral_point_measure_finite:
  1947   fixes g :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  1948   shows "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> 0 \<le> f a) \<Longrightarrow>
  1949     integral\<^sup>L (point_measure A f) g = (\<Sum>a\<in>A. f a *\<^sub>R g a)"
  1950   by (simp add: lebesgue_integral_count_space_finite AE_count_space integral_density point_measure_def)
  1951 
  1952 lemma integrable_point_measure_finite:
  1953   fixes g :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}" and f :: "'a \<Rightarrow> real"
  1954   shows "finite A \<Longrightarrow> integrable (point_measure A f) g"
  1955   unfolding point_measure_def
  1956   apply (subst density_ereal_max_0)
  1957   apply (subst integrable_density)
  1958   apply (auto simp: AE_count_space integrable_count_space)
  1959   done
  1960 
  1961 subsection {* Legacy lemmas for the real-valued Lebesgue integral *}
  1962 
  1963 lemma real_lebesgue_integral_def:
  1964   assumes f[measurable]: "integrable M f"
  1965   shows "integral\<^sup>L M f = real (\<integral>\<^sup>+x. f x \<partial>M) - real (\<integral>\<^sup>+x. - f x \<partial>M)"
  1966 proof -
  1967   have "integral\<^sup>L M f = integral\<^sup>L M (\<lambda>x. max 0 (f x) - max 0 (- f x))"
  1968     by (auto intro!: arg_cong[where f="integral\<^sup>L M"])
  1969   also have "\<dots> = integral\<^sup>L M (\<lambda>x. max 0 (f x)) - integral\<^sup>L M (\<lambda>x. max 0 (- f x))"
  1970     by (intro integral_diff integrable_max integrable_minus integrable_zero f)
  1971   also have "integral\<^sup>L M (\<lambda>x. max 0 (f x)) = real (\<integral>\<^sup>+x. max 0 (f x) \<partial>M)"
  1972     by (subst integral_eq_nn_integral[symmetric]) auto
  1973   also have "integral\<^sup>L M (\<lambda>x. max 0 (- f x)) = real (\<integral>\<^sup>+x. max 0 (- f x) \<partial>M)"
  1974     by (subst integral_eq_nn_integral[symmetric]) auto
  1975   also have "(\<lambda>x. ereal (max 0 (f x))) = (\<lambda>x. max 0 (ereal (f x)))"
  1976     by (auto simp: max_def)
  1977   also have "(\<lambda>x. ereal (max 0 (- f x))) = (\<lambda>x. max 0 (- ereal (f x)))"
  1978     by (auto simp: max_def)
  1979   finally show ?thesis
  1980     unfolding nn_integral_max_0 .
  1981 qed
  1982 
  1983 lemma real_integrable_def:
  1984   "integrable M f \<longleftrightarrow> f \<in> borel_measurable M \<and>
  1985     (\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<noteq> \<infinity> \<and> (\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<noteq> \<infinity>"
  1986   unfolding integrable_iff_bounded
  1987 proof (safe del: notI)
  1988   assume *: "(\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M) < \<infinity>"
  1989   have "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<le> (\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M)"
  1990     by (intro nn_integral_mono) auto
  1991   also note *
  1992   finally show "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<noteq> \<infinity>"
  1993     by simp
  1994   have "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<le> (\<integral>\<^sup>+ x. ereal (norm (f x)) \<partial>M)"
  1995     by (intro nn_integral_mono) auto
  1996   also note *
  1997   finally show "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<noteq> \<infinity>"
  1998     by simp
  1999 next
  2000   assume [measurable]: "f \<in> borel_measurable M"
  2001   assume fin: "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<noteq> \<infinity>" "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<noteq> \<infinity>"
  2002   have "(\<integral>\<^sup>+ x. norm (f x) \<partial>M) = (\<integral>\<^sup>+ x. max 0 (ereal (f x)) + max 0 (ereal (- f x)) \<partial>M)"
  2003     by (intro nn_integral_cong) (auto simp: max_def)
  2004   also have"\<dots> = (\<integral>\<^sup>+ x. max 0 (ereal (f x)) \<partial>M) + (\<integral>\<^sup>+ x. max 0 (ereal (- f x)) \<partial>M)"
  2005     by (intro nn_integral_add) auto
  2006   also have "\<dots> < \<infinity>"
  2007     using fin by (auto simp: nn_integral_max_0)
  2008   finally show "(\<integral>\<^sup>+ x. norm (f x) \<partial>M) < \<infinity>" .
  2009 qed
  2010 
  2011 lemma integrableD[dest]:
  2012   assumes "integrable M f"
  2013   shows "f \<in> borel_measurable M" "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<noteq> \<infinity>" "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<noteq> \<infinity>"
  2014   using assms unfolding real_integrable_def by auto
  2015 
  2016 lemma integrableE:
  2017   assumes "integrable M f"
  2018   obtains r q where
  2019     "(\<integral>\<^sup>+x. ereal (f x)\<partial>M) = ereal r"
  2020     "(\<integral>\<^sup>+x. ereal (-f x)\<partial>M) = ereal q"
  2021     "f \<in> borel_measurable M" "integral\<^sup>L M f = r - q"
  2022   using assms unfolding real_integrable_def real_lebesgue_integral_def[OF assms]
  2023   using nn_integral_nonneg[of M "\<lambda>x. ereal (f x)"]
  2024   using nn_integral_nonneg[of M "\<lambda>x. ereal (-f x)"]
  2025   by (cases rule: ereal2_cases[of "(\<integral>\<^sup>+x. ereal (-f x)\<partial>M)" "(\<integral>\<^sup>+x. ereal (f x)\<partial>M)"]) auto
  2026 
  2027 lemma integral_monotone_convergence_nonneg:
  2028   fixes f :: "nat \<Rightarrow> 'a \<Rightarrow> real"
  2029   assumes i: "\<And>i. integrable M (f i)" and mono: "AE x in M. mono (\<lambda>n. f n x)"
  2030     and pos: "\<And>i. AE x in M. 0 \<le> f i x"
  2031     and lim: "AE x in M. (\<lambda>i. f i x) ----> u x"
  2032     and ilim: "(\<lambda>i. integral\<^sup>L M (f i)) ----> x"
  2033     and u: "u \<in> borel_measurable M"
  2034   shows "integrable M u"
  2035   and "integral\<^sup>L M u = x"
  2036 proof -
  2037   have "(\<integral>\<^sup>+ x. ereal (u x) \<partial>M) = (SUP n. (\<integral>\<^sup>+ x. ereal (f n x) \<partial>M))"
  2038   proof (subst nn_integral_monotone_convergence_SUP_AE[symmetric])
  2039     fix i
  2040     from mono pos show "AE x in M. ereal (f i x) \<le> ereal (f (Suc i) x) \<and> 0 \<le> ereal (f i x)"
  2041       by eventually_elim (auto simp: mono_def)
  2042     show "(\<lambda>x. ereal (f i x)) \<in> borel_measurable M"
  2043       using i by auto
  2044   next
  2045     show "(\<integral>\<^sup>+ x. ereal (u x) \<partial>M) = \<integral>\<^sup>+ x. (SUP i. ereal (f i x)) \<partial>M"
  2046       apply (rule nn_integral_cong_AE)
  2047       using lim mono
  2048       by eventually_elim (simp add: SUP_eq_LIMSEQ[THEN iffD2])
  2049   qed
  2050   also have "\<dots> = ereal x"
  2051     using mono i unfolding nn_integral_eq_integral[OF i pos]
  2052     by (subst SUP_eq_LIMSEQ) (auto simp: mono_def intro!: integral_mono_AE ilim)
  2053   finally have "(\<integral>\<^sup>+ x. ereal (u x) \<partial>M) = ereal x" .
  2054   moreover have "(\<integral>\<^sup>+ x. ereal (- u x) \<partial>M) = 0"
  2055   proof (subst nn_integral_0_iff_AE)
  2056     show "(\<lambda>x. ereal (- u x)) \<in> borel_measurable M"
  2057       using u by auto
  2058     from mono pos[of 0] lim show "AE x in M. ereal (- u x) \<le> 0"
  2059     proof eventually_elim
  2060       fix x assume "mono (\<lambda>n. f n x)" "0 \<le> f 0 x" "(\<lambda>i. f i x) ----> u x"
  2061       then show "ereal (- u x) \<le> 0"
  2062         using incseq_le[of "\<lambda>n. f n x" "u x" 0] by (simp add: mono_def incseq_def)
  2063     qed
  2064   qed
  2065   ultimately show "integrable M u" "integral\<^sup>L M u = x"
  2066     by (auto simp: real_integrable_def real_lebesgue_integral_def u)
  2067 qed
  2068 
  2069 lemma
  2070   fixes f :: "nat \<Rightarrow> 'a \<Rightarrow> real"
  2071   assumes f: "\<And>i. integrable M (f i)" and mono: "AE x in M. mono (\<lambda>n. f n x)"
  2072   and lim: "AE x in M. (\<lambda>i. f i x) ----> u x"
  2073   and ilim: "(\<lambda>i. integral\<^sup>L M (f i)) ----> x"
  2074   and u: "u \<in> borel_measurable M"
  2075   shows integrable_monotone_convergence: "integrable M u"
  2076     and integral_monotone_convergence: "integral\<^sup>L M u = x"
  2077     and has_bochner_integral_monotone_convergence: "has_bochner_integral M u x"
  2078 proof -
  2079   have 1: "\<And>i. integrable M (\<lambda>x. f i x - f 0 x)"
  2080     using f by auto
  2081   have 2: "AE x in M. mono (\<lambda>n. f n x - f 0 x)"
  2082     using mono by (auto simp: mono_def le_fun_def)
  2083   have 3: "\<And>n. AE x in M. 0 \<le> f n x - f 0 x"
  2084     using mono by (auto simp: field_simps mono_def le_fun_def)
  2085   have 4: "AE x in M. (\<lambda>i. f i x - f 0 x) ----> u x - f 0 x"
  2086     using lim by (auto intro!: tendsto_diff)
  2087   have 5: "(\<lambda>i. (\<integral>x. f i x - f 0 x \<partial>M)) ----> x - integral\<^sup>L M (f 0)"
  2088     using f ilim by (auto intro!: tendsto_diff)
  2089   have 6: "(\<lambda>x. u x - f 0 x) \<in> borel_measurable M"
  2090     using f[of 0] u by auto
  2091   note diff = integral_monotone_convergence_nonneg[OF 1 2 3 4 5 6]
  2092   have "integrable M (\<lambda>x. (u x - f 0 x) + f 0 x)"
  2093     using diff(1) f by (rule integrable_add)
  2094   with diff(2) f show "integrable M u" "integral\<^sup>L M u = x"
  2095     by auto
  2096   then show "has_bochner_integral M u x"
  2097     by (metis has_bochner_integral_integrable)
  2098 qed
  2099 
  2100 lemma integral_norm_eq_0_iff:
  2101   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  2102   assumes f[measurable]: "integrable M f"
  2103   shows "(\<integral>x. norm (f x) \<partial>M) = 0 \<longleftrightarrow> emeasure M {x\<in>space M. f x \<noteq> 0} = 0"
  2104 proof -
  2105   have "(\<integral>\<^sup>+x. norm (f x) \<partial>M) = (\<integral>x. norm (f x) \<partial>M)"
  2106     using f by (intro nn_integral_eq_integral integrable_norm) auto
  2107   then have "(\<integral>x. norm (f x) \<partial>M) = 0 \<longleftrightarrow> (\<integral>\<^sup>+x. norm (f x) \<partial>M) = 0"
  2108     by simp
  2109   also have "\<dots> \<longleftrightarrow> emeasure M {x\<in>space M. ereal (norm (f x)) \<noteq> 0} = 0"
  2110     by (intro nn_integral_0_iff) auto
  2111   finally show ?thesis
  2112     by simp
  2113 qed
  2114 
  2115 lemma integral_0_iff:
  2116   fixes f :: "'a \<Rightarrow> real"
  2117   shows "integrable M f \<Longrightarrow> (\<integral>x. abs (f x) \<partial>M) = 0 \<longleftrightarrow> emeasure M {x\<in>space M. f x \<noteq> 0} = 0"
  2118   using integral_norm_eq_0_iff[of M f] by simp
  2119 
  2120 lemma (in finite_measure) integrable_const[intro!, simp]: "integrable M (\<lambda>x. a)"
  2121   using integrable_indicator[of "space M" M a] by (simp cong: integrable_cong)
  2122 
  2123 lemma lebesgue_integral_const[simp]: 
  2124   fixes a :: "'a :: {banach, second_countable_topology}"
  2125   shows "(\<integral>x. a \<partial>M) = measure M (space M) *\<^sub>R a"
  2126 proof -
  2127   { assume "emeasure M (space M) = \<infinity>" "a \<noteq> 0"
  2128     then have ?thesis
  2129       by (simp add: not_integrable_integral_eq measure_def integrable_iff_bounded) }
  2130   moreover
  2131   { assume "a = 0" then have ?thesis by simp }
  2132   moreover
  2133   { assume "emeasure M (space M) \<noteq> \<infinity>"
  2134     interpret finite_measure M
  2135       proof qed fact
  2136     have "(\<integral>x. a \<partial>M) = (\<integral>x. indicator (space M) x *\<^sub>R a \<partial>M)"
  2137       by (intro integral_cong) auto
  2138     also have "\<dots> = measure M (space M) *\<^sub>R a"
  2139       by simp
  2140     finally have ?thesis . }
  2141   ultimately show ?thesis by blast
  2142 qed
  2143 
  2144 lemma (in finite_measure) integrable_const_bound:
  2145   fixes f :: "'a \<Rightarrow> 'b::{banach,second_countable_topology}"
  2146   shows "AE x in M. norm (f x) \<le> B \<Longrightarrow> f \<in> borel_measurable M \<Longrightarrow> integrable M f"
  2147   apply (rule integrable_bound[OF integrable_const[of B], of f])
  2148   apply assumption
  2149   apply (cases "0 \<le> B")
  2150   apply auto
  2151   done
  2152 
  2153 lemma (in finite_measure) integral_less_AE:
  2154   fixes X Y :: "'a \<Rightarrow> real"
  2155   assumes int: "integrable M X" "integrable M Y"
  2156   assumes A: "(emeasure M) A \<noteq> 0" "A \<in> sets M" "AE x in M. x \<in> A \<longrightarrow> X x \<noteq> Y x"
  2157   assumes gt: "AE x in M. X x \<le> Y x"
  2158   shows "integral\<^sup>L M X < integral\<^sup>L M Y"
  2159 proof -
  2160   have "integral\<^sup>L M X \<le> integral\<^sup>L M Y"
  2161     using gt int by (intro integral_mono_AE) auto
  2162   moreover
  2163   have "integral\<^sup>L M X \<noteq> integral\<^sup>L M Y"
  2164   proof
  2165     assume eq: "integral\<^sup>L M X = integral\<^sup>L M Y"
  2166     have "integral\<^sup>L M (\<lambda>x. \<bar>Y x - X x\<bar>) = integral\<^sup>L M (\<lambda>x. Y x - X x)"
  2167       using gt int by (intro integral_cong_AE) auto
  2168     also have "\<dots> = 0"
  2169       using eq int by simp
  2170     finally have "(emeasure M) {x \<in> space M. Y x - X x \<noteq> 0} = 0"
  2171       using int by (simp add: integral_0_iff)
  2172     moreover
  2173     have "(\<integral>\<^sup>+x. indicator A x \<partial>M) \<le> (\<integral>\<^sup>+x. indicator {x \<in> space M. Y x - X x \<noteq> 0} x \<partial>M)"
  2174       using A by (intro nn_integral_mono_AE) auto
  2175     then have "(emeasure M) A \<le> (emeasure M) {x \<in> space M. Y x - X x \<noteq> 0}"
  2176       using int A by (simp add: integrable_def)
  2177     ultimately have "emeasure M A = 0"
  2178       using emeasure_nonneg[of M A] by simp
  2179     with `(emeasure M) A \<noteq> 0` show False by auto
  2180   qed
  2181   ultimately show ?thesis by auto
  2182 qed
  2183 
  2184 lemma (in finite_measure) integral_less_AE_space:
  2185   fixes X Y :: "'a \<Rightarrow> real"
  2186   assumes int: "integrable M X" "integrable M Y"
  2187   assumes gt: "AE x in M. X x < Y x" "emeasure M (space M) \<noteq> 0"
  2188   shows "integral\<^sup>L M X < integral\<^sup>L M Y"
  2189   using gt by (intro integral_less_AE[OF int, where A="space M"]) auto
  2190 
  2191 lemma integrable_mult_indicator:
  2192   fixes f :: "'a \<Rightarrow> real"
  2193   shows "A \<in> sets M \<Longrightarrow> integrable M f \<Longrightarrow> integrable M (\<lambda>x. f x * indicator A x)"
  2194   by (rule integrable_bound[where f="\<lambda>x. \<bar>f x\<bar>"]) (auto split: split_indicator)
  2195 
  2196 lemma tendsto_integral_at_top:
  2197   fixes f :: "real \<Rightarrow> real"
  2198   assumes M: "sets M = sets borel" and f[measurable]: "integrable M f"
  2199   shows "((\<lambda>y. \<integral> x. f x * indicator {.. y} x \<partial>M) ---> \<integral> x. f x \<partial>M) at_top"
  2200 proof -
  2201   have M_measure[simp]: "borel_measurable M = borel_measurable borel"
  2202     using M by (simp add: sets_eq_imp_space_eq measurable_def)
  2203   { fix f :: "real \<Rightarrow> real" assume f: "integrable M f" "\<And>x. 0 \<le> f x"
  2204     then have [measurable]: "f \<in> borel_measurable borel"
  2205       by (simp add: real_integrable_def)
  2206     have "((\<lambda>y. \<integral> x. f x * indicator {.. y} x \<partial>M) ---> \<integral> x. f x \<partial>M) at_top"
  2207     proof (rule tendsto_at_topI_sequentially)
  2208       have int: "\<And>n. integrable M (\<lambda>x. f x * indicator {.. n} x)"
  2209         by (rule integrable_mult_indicator) (auto simp: M f)
  2210       show "(\<lambda>n. \<integral> x. f x * indicator {..real n} x \<partial>M) ----> integral\<^sup>L M f"
  2211       proof (rule integral_dominated_convergence)
  2212         { fix x have "eventually (\<lambda>n. f x * indicator {..real n} x = f x) sequentially"
  2213             by (rule eventually_sequentiallyI[of "natceiling x"])
  2214                (auto split: split_indicator simp: natceiling_le_eq) }
  2215         from filterlim_cong[OF refl refl this]
  2216         show "AE x in M. (\<lambda>n. f x * indicator {..real n} x) ----> f x"
  2217           by (simp add: tendsto_const)
  2218         show "\<And>j. AE x in M. norm (f x * indicator {.. j} x) \<le> f x"
  2219           using f(2) by (intro AE_I2) (auto split: split_indicator)
  2220       qed (simp | fact)+
  2221       show "mono (\<lambda>y. \<integral> x. f x * indicator {..y} x \<partial>M)"
  2222         by (intro monoI integral_mono int) (auto split: split_indicator intro: f)
  2223     qed }
  2224   note nonneg = this
  2225   let ?P = "\<lambda>y. \<integral> x. max 0 (f x) * indicator {..y} x \<partial>M"
  2226   let ?N = "\<lambda>y. \<integral> x. max 0 (- f x) * indicator {..y} x \<partial>M"
  2227   let ?p = "integral\<^sup>L M (\<lambda>x. max 0 (f x))"
  2228   let ?n = "integral\<^sup>L M (\<lambda>x. max 0 (- f x))"
  2229   have "(?P ---> ?p) at_top" "(?N ---> ?n) at_top"
  2230     by (auto intro!: nonneg f)
  2231   note tendsto_diff[OF this]
  2232   also have "(\<lambda>y. ?P y - ?N y) = (\<lambda>y. \<integral> x. f x * indicator {..y} x \<partial>M)"
  2233     by (subst integral_diff[symmetric])
  2234        (auto intro!: integrable_mult_indicator f integral_cong
  2235              simp: M split: split_max)
  2236   also have "?p - ?n = integral\<^sup>L M f"
  2237     by (subst integral_diff[symmetric]) (auto intro!: f integral_cong simp: M split: split_max)
  2238   finally show ?thesis .
  2239 qed
  2240 
  2241 lemma
  2242   fixes f :: "real \<Rightarrow> real"
  2243   assumes M: "sets M = sets borel"
  2244   assumes nonneg: "AE x in M. 0 \<le> f x"
  2245   assumes borel: "f \<in> borel_measurable borel"
  2246   assumes int: "\<And>y. integrable M (\<lambda>x. f x * indicator {.. y} x)"
  2247   assumes conv: "((\<lambda>y. \<integral> x. f x * indicator {.. y} x \<partial>M) ---> x) at_top"
  2248   shows has_bochner_integral_monotone_convergence_at_top: "has_bochner_integral M f x"
  2249     and integrable_monotone_convergence_at_top: "integrable M f"
  2250     and integral_monotone_convergence_at_top:"integral\<^sup>L M f = x"
  2251 proof -
  2252   from nonneg have "AE x in M. mono (\<lambda>n::nat. f x * indicator {..real n} x)"
  2253     by (auto split: split_indicator intro!: monoI)
  2254   { fix x have "eventually (\<lambda>n. f x * indicator {..real n} x = f x) sequentially"
  2255       by (rule eventually_sequentiallyI[of "natceiling x"])
  2256          (auto split: split_indicator simp: natceiling_le_eq) }
  2257   from filterlim_cong[OF refl refl this]
  2258   have "AE x in M. (\<lambda>i. f x * indicator {..real i} x) ----> f x"
  2259     by (simp add: tendsto_const)
  2260   have "(\<lambda>i. \<integral> x. f x * indicator {..real i} x \<partial>M) ----> x"
  2261     using conv filterlim_real_sequentially by (rule filterlim_compose)
  2262   have M_measure[simp]: "borel_measurable M = borel_measurable borel"
  2263     using M by (simp add: sets_eq_imp_space_eq measurable_def)
  2264   have "f \<in> borel_measurable M"
  2265     using borel by simp
  2266   show "has_bochner_integral M f x"
  2267     by (rule has_bochner_integral_monotone_convergence) fact+
  2268   then show "integrable M f" "integral\<^sup>L M f = x"
  2269     by (auto simp: _has_bochner_integral_iff)
  2270 qed
  2271 
  2272 subsection {* Product measure *}
  2273 
  2274 lemma (in sigma_finite_measure) borel_measurable_lebesgue_integrable[measurable (raw)]:
  2275   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _::{banach, second_countable_topology}"
  2276   assumes [measurable]: "split f \<in> borel_measurable (N \<Otimes>\<^sub>M M)"
  2277   shows "Measurable.pred N (\<lambda>x. integrable M (f x))"
  2278 proof -
  2279   have [simp]: "\<And>x. x \<in> space N \<Longrightarrow> integrable M (f x) \<longleftrightarrow> (\<integral>\<^sup>+y. norm (f x y) \<partial>M) < \<infinity>"
  2280     unfolding integrable_iff_bounded by simp
  2281   show ?thesis
  2282     by (simp cong: measurable_cong)
  2283 qed
  2284 
  2285 lemma (in sigma_finite_measure) measurable_measure[measurable (raw)]:
  2286   "(\<And>x. x \<in> space N \<Longrightarrow> A x \<subseteq> space M) \<Longrightarrow>
  2287     {x \<in> space (N \<Otimes>\<^sub>M M). snd x \<in> A (fst x)} \<in> sets (N \<Otimes>\<^sub>M M) \<Longrightarrow>
  2288     (\<lambda>x. measure M (A x)) \<in> borel_measurable N"
  2289   unfolding measure_def by (intro measurable_emeasure borel_measurable_real_of_ereal)
  2290 
  2291 lemma Collect_subset [simp]: "{x\<in>A. P x} \<subseteq> A" by auto
  2292 
  2293 lemma (in sigma_finite_measure) borel_measurable_lebesgue_integral[measurable (raw)]:
  2294   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _::{banach, second_countable_topology}"
  2295   assumes f[measurable]: "split f \<in> borel_measurable (N \<Otimes>\<^sub>M M)"
  2296   shows "(\<lambda>x. \<integral>y. f x y \<partial>M) \<in> borel_measurable N"
  2297 proof -
  2298   from borel_measurable_implies_sequence_metric[OF f, of 0] guess s ..
  2299   then have s: "\<And>i. simple_function (N \<Otimes>\<^sub>M M) (s i)"
  2300     "\<And>x y. x \<in> space N \<Longrightarrow> y \<in> space M \<Longrightarrow> (\<lambda>i. s i (x, y)) ----> f x y"
  2301     "\<And>i x y. x \<in> space N \<Longrightarrow> y \<in> space M \<Longrightarrow> norm (s i (x, y)) \<le> 2 * norm (f x y)"
  2302     by (auto simp: space_pair_measure norm_conv_dist)
  2303 
  2304   have [measurable]: "\<And>i. s i \<in> borel_measurable (N \<Otimes>\<^sub>M M)"
  2305     by (rule borel_measurable_simple_function) fact
  2306 
  2307   have "\<And>i. s i \<in> measurable (N \<Otimes>\<^sub>M M) (count_space UNIV)"
  2308     by (rule measurable_simple_function) fact
  2309 
  2310   def f' \<equiv> "\<lambda>i x. if integrable M (f x) then simple_bochner_integral M (\<lambda>y. s i (x, y)) else 0"
  2311 
  2312   { fix i x assume "x \<in> space N"
  2313     then have "simple_bochner_integral M (\<lambda>y. s i (x, y)) =
  2314       (\<Sum>z\<in>s i ` (space N \<times> space M). measure M {y \<in> space M. s i (x, y) = z} *\<^sub>R z)"
  2315       using s(1)[THEN simple_functionD(1)]
  2316       unfolding simple_bochner_integral_def
  2317       by (intro setsum_mono_zero_cong_left)
  2318          (auto simp: eq_commute space_pair_measure image_iff cong: conj_cong) }
  2319   note eq = this
  2320 
  2321   show ?thesis
  2322   proof (rule borel_measurable_LIMSEQ_metric)
  2323     fix i show "f' i \<in> borel_measurable N"
  2324       unfolding f'_def by (simp_all add: eq cong: measurable_cong if_cong)
  2325   next
  2326     fix x assume x: "x \<in> space N"
  2327     { assume int_f: "integrable M (f x)"
  2328       have int_2f: "integrable M (\<lambda>y. 2 * norm (f x y))"
  2329         by (intro integrable_norm integrable_mult_right int_f)
  2330       have "(\<lambda>i. integral\<^sup>L M (\<lambda>y. s i (x, y))) ----> integral\<^sup>L M (f x)"
  2331       proof (rule integral_dominated_convergence)
  2332         from int_f show "f x \<in> borel_measurable M" by auto
  2333         show "\<And>i. (\<lambda>y. s i (x, y)) \<in> borel_measurable M"
  2334           using x by simp
  2335         show "AE xa in M. (\<lambda>i. s i (x, xa)) ----> f x xa"
  2336           using x s(2) by auto
  2337         show "\<And>i. AE xa in M. norm (s i (x, xa)) \<le> 2 * norm (f x xa)"
  2338           using x s(3) by auto
  2339       qed fact
  2340       moreover
  2341       { fix i
  2342         have "simple_bochner_integrable M (\<lambda>y. s i (x, y))"
  2343         proof (rule simple_bochner_integrableI_bounded)
  2344           have "(\<lambda>y. s i (x, y)) ` space M \<subseteq> s i ` (space N \<times> space M)"
  2345             using x by auto
  2346           then show "simple_function M (\<lambda>y. s i (x, y))"
  2347             using simple_functionD(1)[OF s(1), of i] x
  2348             by (intro simple_function_borel_measurable)
  2349                (auto simp: space_pair_measure dest: finite_subset)
  2350           have "(\<integral>\<^sup>+ y. ereal (norm (s i (x, y))) \<partial>M) \<le> (\<integral>\<^sup>+ y. 2 * norm (f x y) \<partial>M)"
  2351             using x s by (intro nn_integral_mono) auto
  2352           also have "(\<integral>\<^sup>+ y. 2 * norm (f x y) \<partial>M) < \<infinity>"
  2353             using int_2f by (simp add: integrable_iff_bounded)
  2354           finally show "(\<integral>\<^sup>+ xa. ereal (norm (s i (x, xa))) \<partial>M) < \<infinity>" .
  2355         qed
  2356         then have "integral\<^sup>L M (\<lambda>y. s i (x, y)) = simple_bochner_integral M (\<lambda>y. s i (x, y))"
  2357           by (rule simple_bochner_integrable_eq_integral[symmetric]) }
  2358       ultimately have "(\<lambda>i. simple_bochner_integral M (\<lambda>y. s i (x, y))) ----> integral\<^sup>L M (f x)"
  2359         by simp }
  2360     then 
  2361     show "(\<lambda>i. f' i x) ----> integral\<^sup>L M (f x)"
  2362       unfolding f'_def
  2363       by (cases "integrable M (f x)") (simp_all add: not_integrable_integral_eq tendsto_const)
  2364   qed
  2365 qed
  2366 
  2367 lemma (in pair_sigma_finite) integrable_product_swap:
  2368   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2369   assumes "integrable (M1 \<Otimes>\<^sub>M M2) f"
  2370   shows "integrable (M2 \<Otimes>\<^sub>M M1) (\<lambda>(x,y). f (y,x))"
  2371 proof -
  2372   interpret Q: pair_sigma_finite M2 M1 by default
  2373   have *: "(\<lambda>(x,y). f (y,x)) = (\<lambda>x. f (case x of (x,y)\<Rightarrow>(y,x)))" by (auto simp: fun_eq_iff)
  2374   show ?thesis unfolding *
  2375     by (rule integrable_distr[OF measurable_pair_swap'])
  2376        (simp add: distr_pair_swap[symmetric] assms)
  2377 qed
  2378 
  2379 lemma (in pair_sigma_finite) integrable_product_swap_iff:
  2380   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2381   shows "integrable (M2 \<Otimes>\<^sub>M M1) (\<lambda>(x,y). f (y,x)) \<longleftrightarrow> integrable (M1 \<Otimes>\<^sub>M M2) f"
  2382 proof -
  2383   interpret Q: pair_sigma_finite M2 M1 by default
  2384   from Q.integrable_product_swap[of "\<lambda>(x,y). f (y,x)"] integrable_product_swap[of f]
  2385   show ?thesis by auto
  2386 qed
  2387 
  2388 lemma (in pair_sigma_finite) integral_product_swap:
  2389   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2390   assumes f: "f \<in> borel_measurable (M1 \<Otimes>\<^sub>M M2)"
  2391   shows "(\<integral>(x,y). f (y,x) \<partial>(M2 \<Otimes>\<^sub>M M1)) = integral\<^sup>L (M1 \<Otimes>\<^sub>M M2) f"
  2392 proof -
  2393   have *: "(\<lambda>(x,y). f (y,x)) = (\<lambda>x. f (case x of (x,y)\<Rightarrow>(y,x)))" by (auto simp: fun_eq_iff)
  2394   show ?thesis unfolding *
  2395     by (simp add: integral_distr[symmetric, OF measurable_pair_swap' f] distr_pair_swap[symmetric])
  2396 qed
  2397 
  2398 lemma (in pair_sigma_finite) emeasure_pair_measure_finite:
  2399   assumes A: "A \<in> sets (M1 \<Otimes>\<^sub>M M2)" and finite: "emeasure (M1 \<Otimes>\<^sub>M M2) A < \<infinity>"
  2400   shows "AE x in M1. emeasure M2 {y\<in>space M2. (x, y) \<in> A} < \<infinity>"
  2401 proof -
  2402   from M2.emeasure_pair_measure_alt[OF A] finite
  2403   have "(\<integral>\<^sup>+ x. emeasure M2 (Pair x -` A) \<partial>M1) \<noteq> \<infinity>"
  2404     by simp
  2405   then have "AE x in M1. emeasure M2 (Pair x -` A) \<noteq> \<infinity>"
  2406     by (rule nn_integral_PInf_AE[rotated]) (intro M2.measurable_emeasure_Pair A)
  2407   moreover have "\<And>x. x \<in> space M1 \<Longrightarrow> Pair x -` A = {y\<in>space M2. (x, y) \<in> A}"
  2408     using sets.sets_into_space[OF A] by (auto simp: space_pair_measure)
  2409   ultimately show ?thesis by auto
  2410 qed
  2411 
  2412 lemma (in pair_sigma_finite) AE_integrable_fst':
  2413   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2414   assumes f[measurable]: "integrable (M1 \<Otimes>\<^sub>M M2) f"
  2415   shows "AE x in M1. integrable M2 (\<lambda>y. f (x, y))"
  2416 proof -
  2417   have "(\<integral>\<^sup>+x. (\<integral>\<^sup>+y. norm (f (x, y)) \<partial>M2) \<partial>M1) = (\<integral>\<^sup>+x. norm (f x) \<partial>(M1 \<Otimes>\<^sub>M M2))"
  2418     by (rule M2.nn_integral_fst) simp
  2419   also have "(\<integral>\<^sup>+x. norm (f x) \<partial>(M1 \<Otimes>\<^sub>M M2)) \<noteq> \<infinity>"
  2420     using f unfolding integrable_iff_bounded by simp
  2421   finally have "AE x in M1. (\<integral>\<^sup>+y. norm (f (x, y)) \<partial>M2) \<noteq> \<infinity>"
  2422     by (intro nn_integral_PInf_AE M2.borel_measurable_nn_integral )
  2423        (auto simp: measurable_split_conv)
  2424   with AE_space show ?thesis
  2425     by eventually_elim
  2426        (auto simp: integrable_iff_bounded measurable_compose[OF _ borel_measurable_integrable[OF f]])
  2427 qed
  2428 
  2429 lemma (in pair_sigma_finite) integrable_fst':
  2430   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2431   assumes f[measurable]: "integrable (M1 \<Otimes>\<^sub>M M2) f"
  2432   shows "integrable M1 (\<lambda>x. \<integral>y. f (x, y) \<partial>M2)"
  2433   unfolding integrable_iff_bounded
  2434 proof
  2435   show "(\<lambda>x. \<integral> y. f (x, y) \<partial>M2) \<in> borel_measurable M1"
  2436     by (rule M2.borel_measurable_lebesgue_integral) simp
  2437   have "(\<integral>\<^sup>+ x. ereal (norm (\<integral> y. f (x, y) \<partial>M2)) \<partial>M1) \<le> (\<integral>\<^sup>+x. (\<integral>\<^sup>+y. norm (f (x, y)) \<partial>M2) \<partial>M1)"
  2438     using AE_integrable_fst'[OF f] by (auto intro!: nn_integral_mono_AE integral_norm_bound_ereal)
  2439   also have "(\<integral>\<^sup>+x. (\<integral>\<^sup>+y. norm (f (x, y)) \<partial>M2) \<partial>M1) = (\<integral>\<^sup>+x. norm (f x) \<partial>(M1 \<Otimes>\<^sub>M M2))"
  2440     by (rule M2.nn_integral_fst) simp
  2441   also have "(\<integral>\<^sup>+x. norm (f x) \<partial>(M1 \<Otimes>\<^sub>M M2)) < \<infinity>"
  2442     using f unfolding integrable_iff_bounded by simp
  2443   finally show "(\<integral>\<^sup>+ x. ereal (norm (\<integral> y. f (x, y) \<partial>M2)) \<partial>M1) < \<infinity>" .
  2444 qed
  2445 
  2446 lemma (in pair_sigma_finite) integral_fst':
  2447   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2448   assumes f: "integrable (M1 \<Otimes>\<^sub>M M2) f"
  2449   shows "(\<integral>x. (\<integral>y. f (x, y) \<partial>M2) \<partial>M1) = integral\<^sup>L (M1 \<Otimes>\<^sub>M M2) f"
  2450 using f proof induct
  2451   case (base A c)
  2452   have A[measurable]: "A \<in> sets (M1 \<Otimes>\<^sub>M M2)" by fact
  2453 
  2454   have eq: "\<And>x y. x \<in> space M1 \<Longrightarrow> indicator A (x, y) = indicator {y\<in>space M2. (x, y) \<in> A} y"
  2455     using sets.sets_into_space[OF A] by (auto split: split_indicator simp: space_pair_measure)
  2456 
  2457   have int_A: "integrable (M1 \<Otimes>\<^sub>M M2) (indicator A :: _ \<Rightarrow> real)"
  2458     using base by (rule integrable_real_indicator)
  2459 
  2460   have "(\<integral> x. \<integral> y. indicator A (x, y) *\<^sub>R c \<partial>M2 \<partial>M1) = (\<integral>x. measure M2 {y\<in>space M2. (x, y) \<in> A} *\<^sub>R c \<partial>M1)"
  2461   proof (intro integral_cong_AE, simp, simp)
  2462     from AE_integrable_fst'[OF int_A] AE_space
  2463     show "AE x in M1. (\<integral>y. indicator A (x, y) *\<^sub>R c \<partial>M2) = measure M2 {y\<in>space M2. (x, y) \<in> A} *\<^sub>R c"
  2464       by eventually_elim (simp add: eq integrable_indicator_iff)
  2465   qed
  2466   also have "\<dots> = measure (M1 \<Otimes>\<^sub>M M2) A *\<^sub>R c"
  2467   proof (subst integral_scaleR_left)
  2468     have "(\<integral>\<^sup>+x. ereal (measure M2 {y \<in> space M2. (x, y) \<in> A}) \<partial>M1) =
  2469       (\<integral>\<^sup>+x. emeasure M2 {y \<in> space M2. (x, y) \<in> A} \<partial>M1)"
  2470       using emeasure_pair_measure_finite[OF base]
  2471       by (intro nn_integral_cong_AE, eventually_elim) (simp add: emeasure_eq_ereal_measure)
  2472     also have "\<dots> = emeasure (M1 \<Otimes>\<^sub>M M2) A"
  2473       using sets.sets_into_space[OF A]
  2474       by (subst M2.emeasure_pair_measure_alt)
  2475          (auto intro!: nn_integral_cong arg_cong[where f="emeasure M2"] simp: space_pair_measure)
  2476     finally have *: "(\<integral>\<^sup>+x. ereal (measure M2 {y \<in> space M2. (x, y) \<in> A}) \<partial>M1) = emeasure (M1 \<Otimes>\<^sub>M M2) A" .
  2477 
  2478     from base * show "integrable M1 (\<lambda>x. measure M2 {y \<in> space M2. (x, y) \<in> A})"
  2479       by (simp add: measure_nonneg integrable_iff_bounded)
  2480     then have "(\<integral>x. measure M2 {y \<in> space M2. (x, y) \<in> A} \<partial>M1) = 
  2481       (\<integral>\<^sup>+x. ereal (measure M2 {y \<in> space M2. (x, y) \<in> A}) \<partial>M1)"
  2482       by (rule nn_integral_eq_integral[symmetric]) (simp add: measure_nonneg)
  2483     also note *
  2484     finally show "(\<integral>x. measure M2 {y \<in> space M2. (x, y) \<in> A} \<partial>M1) *\<^sub>R c = measure (M1 \<Otimes>\<^sub>M M2) A *\<^sub>R c"
  2485       using base by (simp add: emeasure_eq_ereal_measure)
  2486   qed
  2487   also have "\<dots> = (\<integral> a. indicator A a *\<^sub>R c \<partial>(M1 \<Otimes>\<^sub>M M2))"
  2488     using base by simp
  2489   finally show ?case .
  2490 next
  2491   case (add f g)
  2492   then have [measurable]: "f \<in> borel_measurable (M1 \<Otimes>\<^sub>M M2)" "g \<in> borel_measurable (M1 \<Otimes>\<^sub>M M2)"
  2493     by auto
  2494   have "(\<integral> x. \<integral> y. f (x, y) + g (x, y) \<partial>M2 \<partial>M1) = 
  2495     (\<integral> x. (\<integral> y. f (x, y) \<partial>M2) + (\<integral> y. g (x, y) \<partial>M2) \<partial>M1)"
  2496     apply (rule integral_cong_AE)
  2497     apply simp_all
  2498     using AE_integrable_fst'[OF add(1)] AE_integrable_fst'[OF add(3)]
  2499     apply eventually_elim
  2500     apply simp
  2501     done 
  2502   also have "\<dots> = (\<integral> x. f x \<partial>(M1 \<Otimes>\<^sub>M M2)) + (\<integral> x. g x \<partial>(M1 \<Otimes>\<^sub>M M2))"
  2503     using integrable_fst'[OF add(1)] integrable_fst'[OF add(3)] add(2,4) by simp
  2504   finally show ?case
  2505     using add by simp
  2506 next
  2507   case (lim f s)
  2508   then have [measurable]: "f \<in> borel_measurable (M1 \<Otimes>\<^sub>M M2)" "\<And>i. s i \<in> borel_measurable (M1 \<Otimes>\<^sub>M M2)"
  2509     by auto
  2510   
  2511   show ?case
  2512   proof (rule LIMSEQ_unique)
  2513     show "(\<lambda>i. integral\<^sup>L (M1 \<Otimes>\<^sub>M M2) (s i)) ----> integral\<^sup>L (M1 \<Otimes>\<^sub>M M2) f"
  2514     proof (rule integral_dominated_convergence)
  2515       show "integrable (M1 \<Otimes>\<^sub>M M2) (\<lambda>x. 2 * norm (f x))"
  2516         using lim(5) by auto
  2517     qed (insert lim, auto)
  2518     have "(\<lambda>i. \<integral> x. \<integral> y. s i (x, y) \<partial>M2 \<partial>M1) ----> \<integral> x. \<integral> y. f (x, y) \<partial>M2 \<partial>M1"
  2519     proof (rule integral_dominated_convergence)
  2520       have "AE x in M1. \<forall>i. integrable M2 (\<lambda>y. s i (x, y))"
  2521         unfolding AE_all_countable using AE_integrable_fst'[OF lim(1)] ..
  2522       with AE_space AE_integrable_fst'[OF lim(5)]
  2523       show "AE x in M1. (\<lambda>i. \<integral> y. s i (x, y) \<partial>M2) ----> \<integral> y. f (x, y) \<partial>M2"
  2524       proof eventually_elim
  2525         fix x assume x: "x \<in> space M1" and
  2526           s: "\<forall>i. integrable M2 (\<lambda>y. s i (x, y))" and f: "integrable M2 (\<lambda>y. f (x, y))"
  2527         show "(\<lambda>i. \<integral> y. s i (x, y) \<partial>M2) ----> \<integral> y. f (x, y) \<partial>M2"
  2528         proof (rule integral_dominated_convergence)
  2529           show "integrable M2 (\<lambda>y. 2 * norm (f (x, y)))"
  2530              using f by auto
  2531           show "AE xa in M2. (\<lambda>i. s i (x, xa)) ----> f (x, xa)"
  2532             using x lim(3) by (auto simp: space_pair_measure)
  2533           show "\<And>i. AE xa in M2. norm (s i (x, xa)) \<le> 2 * norm (f (x, xa))"
  2534             using x lim(4) by (auto simp: space_pair_measure)
  2535         qed (insert x, measurable)
  2536       qed
  2537       show "integrable M1 (\<lambda>x. (\<integral> y. 2 * norm (f (x, y)) \<partial>M2))"
  2538         by (intro integrable_mult_right integrable_norm integrable_fst' lim)
  2539       fix i show "AE x in M1. norm (\<integral> y. s i (x, y) \<partial>M2) \<le> (\<integral> y. 2 * norm (f (x, y)) \<partial>M2)"
  2540         using AE_space AE_integrable_fst'[OF lim(1), of i] AE_integrable_fst'[OF lim(5)]
  2541       proof eventually_elim 
  2542         fix x assume x: "x \<in> space M1"
  2543           and s: "integrable M2 (\<lambda>y. s i (x, y))" and f: "integrable M2 (\<lambda>y. f (x, y))"
  2544         from s have "norm (\<integral> y. s i (x, y) \<partial>M2) \<le> (\<integral>\<^sup>+y. norm (s i (x, y)) \<partial>M2)"
  2545           by (rule integral_norm_bound_ereal)
  2546         also have "\<dots> \<le> (\<integral>\<^sup>+y. 2 * norm (f (x, y)) \<partial>M2)"
  2547           using x lim by (auto intro!: nn_integral_mono simp: space_pair_measure)
  2548         also have "\<dots> = (\<integral>y. 2 * norm (f (x, y)) \<partial>M2)"
  2549           using f by (intro nn_integral_eq_integral) auto
  2550         finally show "norm (\<integral> y. s i (x, y) \<partial>M2) \<le> (\<integral> y. 2 * norm (f (x, y)) \<partial>M2)"
  2551           by simp
  2552       qed
  2553     qed simp_all
  2554     then show "(\<lambda>i. integral\<^sup>L (M1 \<Otimes>\<^sub>M M2) (s i)) ----> \<integral> x. \<integral> y. f (x, y) \<partial>M2 \<partial>M1"
  2555       using lim by simp
  2556   qed
  2557 qed
  2558 
  2559 lemma (in pair_sigma_finite)
  2560   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _::{banach, second_countable_topology}"
  2561   assumes f: "integrable (M1 \<Otimes>\<^sub>M M2) (split f)"
  2562   shows AE_integrable_fst: "AE x in M1. integrable M2 (\<lambda>y. f x y)" (is "?AE")
  2563     and integrable_fst: "integrable M1 (\<lambda>x. \<integral>y. f x y \<partial>M2)" (is "?INT")
  2564     and integral_fst: "(\<integral>x. (\<integral>y. f x y \<partial>M2) \<partial>M1) = integral\<^sup>L (M1 \<Otimes>\<^sub>M M2) (\<lambda>(x, y). f x y)" (is "?EQ")
  2565   using AE_integrable_fst'[OF f] integrable_fst'[OF f] integral_fst'[OF f] by auto
  2566 
  2567 lemma (in pair_sigma_finite)
  2568   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _::{banach, second_countable_topology}"
  2569   assumes f[measurable]: "integrable (M1 \<Otimes>\<^sub>M M2) (split f)"
  2570   shows AE_integrable_snd: "AE y in M2. integrable M1 (\<lambda>x. f x y)" (is "?AE")
  2571     and integrable_snd: "integrable M2 (\<lambda>y. \<integral>x. f x y \<partial>M1)" (is "?INT")
  2572     and integral_snd: "(\<integral>y. (\<integral>x. f x y \<partial>M1) \<partial>M2) = integral\<^sup>L (M1 \<Otimes>\<^sub>M M2) (split f)" (is "?EQ")
  2573 proof -
  2574   interpret Q: pair_sigma_finite M2 M1 by default
  2575   have Q_int: "integrable (M2 \<Otimes>\<^sub>M M1) (\<lambda>(x, y). f y x)"
  2576     using f unfolding integrable_product_swap_iff[symmetric] by simp
  2577   show ?AE  using Q.AE_integrable_fst'[OF Q_int] by simp
  2578   show ?INT using Q.integrable_fst'[OF Q_int] by simp
  2579   show ?EQ using Q.integral_fst'[OF Q_int]
  2580     using integral_product_swap[of "split f"] by simp
  2581 qed
  2582 
  2583 lemma (in pair_sigma_finite) Fubini_integral:
  2584   fixes f :: "_ \<Rightarrow> _ \<Rightarrow> _ :: {banach, second_countable_topology}"
  2585   assumes f: "integrable (M1 \<Otimes>\<^sub>M M2) (split f)"
  2586   shows "(\<integral>y. (\<integral>x. f x y \<partial>M1) \<partial>M2) = (\<integral>x. (\<integral>y. f x y \<partial>M2) \<partial>M1)"
  2587   unfolding integral_snd[OF assms] integral_fst[OF assms] ..
  2588 
  2589 lemma (in product_sigma_finite) product_integral_singleton:
  2590   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2591   shows "f \<in> borel_measurable (M i) \<Longrightarrow> (\<integral>x. f (x i) \<partial>Pi\<^sub>M {i} M) = integral\<^sup>L (M i) f"
  2592   apply (subst distr_singleton[symmetric])
  2593   apply (subst integral_distr)
  2594   apply simp_all
  2595   done
  2596 
  2597 lemma (in product_sigma_finite) product_integral_fold:
  2598   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2599   assumes IJ[simp]: "I \<inter> J = {}" and fin: "finite I" "finite J"
  2600   and f: "integrable (Pi\<^sub>M (I \<union> J) M) f"
  2601   shows "integral\<^sup>L (Pi\<^sub>M (I \<union> J) M) f = (\<integral>x. (\<integral>y. f (merge I J (x, y)) \<partial>Pi\<^sub>M J M) \<partial>Pi\<^sub>M I M)"
  2602 proof -
  2603   interpret I: finite_product_sigma_finite M I by default fact
  2604   interpret J: finite_product_sigma_finite M J by default fact
  2605   have "finite (I \<union> J)" using fin by auto
  2606   interpret IJ: finite_product_sigma_finite M "I \<union> J" by default fact
  2607   interpret P: pair_sigma_finite "Pi\<^sub>M I M" "Pi\<^sub>M J M" by default
  2608   let ?M = "merge I J"
  2609   let ?f = "\<lambda>x. f (?M x)"
  2610   from f have f_borel: "f \<in> borel_measurable (Pi\<^sub>M (I \<union> J) M)"
  2611     by auto
  2612   have P_borel: "(\<lambda>x. f (merge I J x)) \<in> borel_measurable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M)"
  2613     using measurable_comp[OF measurable_merge f_borel] by (simp add: comp_def)
  2614   have f_int: "integrable (Pi\<^sub>M I M \<Otimes>\<^sub>M Pi\<^sub>M J M) ?f"
  2615     by (rule integrable_distr[OF measurable_merge]) (simp add: distr_merge[OF IJ fin] f)
  2616   show ?thesis
  2617     apply (subst distr_merge[symmetric, OF IJ fin])
  2618     apply (subst integral_distr[OF measurable_merge f_borel])
  2619     apply (subst P.integral_fst'[symmetric, OF f_int])
  2620     apply simp
  2621     done
  2622 qed
  2623 
  2624 lemma (in product_sigma_finite) product_integral_insert:
  2625   fixes f :: "_ \<Rightarrow> _::{banach, second_countable_topology}"
  2626   assumes I: "finite I" "i \<notin> I"
  2627     and f: "integrable (Pi\<^sub>M (insert i I) M) f"
  2628   shows "integral\<^sup>L (Pi\<^sub>M (insert i I) M) f = (\<integral>x. (\<integral>y. f (x(i:=y)) \<partial>M i) \<partial>Pi\<^sub>M I M)"
  2629 proof -
  2630   have "integral\<^sup>L (Pi\<^sub>M (insert i I) M) f = integral\<^sup>L (Pi\<^sub>M (I \<union> {i}) M) f"
  2631     by simp
  2632   also have "\<dots> = (\<integral>x. (\<integral>y. f (merge I {i} (x,y)) \<partial>Pi\<^sub>M {i} M) \<partial>Pi\<^sub>M I M)"
  2633     using f I by (intro product_integral_fold) auto
  2634   also have "\<dots> = (\<integral>x. (\<integral>y. f (x(i := y)) \<partial>M i) \<partial>Pi\<^sub>M I M)"
  2635   proof (rule integral_cong[OF refl], subst product_integral_singleton[symmetric])
  2636     fix x assume x: "x \<in> space (Pi\<^sub>M I M)"
  2637     have f_borel: "f \<in> borel_measurable (Pi\<^sub>M (insert i I) M)"
  2638       using f by auto
  2639     show "(\<lambda>y. f (x(i := y))) \<in> borel_measurable (M i)"
  2640       using measurable_comp[OF measurable_component_update f_borel, OF x `i \<notin> I`]
  2641       unfolding comp_def .
  2642     from x I show "(\<integral> y. f (merge I {i} (x,y)) \<partial>Pi\<^sub>M {i} M) = (\<integral> xa. f (x(i := xa i)) \<partial>Pi\<^sub>M {i} M)"
  2643       by (auto intro!: integral_cong arg_cong[where f=f] simp: merge_def space_PiM extensional_def PiE_def)
  2644   qed
  2645   finally show ?thesis .
  2646 qed
  2647 
  2648 lemma (in product_sigma_finite) product_integrable_setprod:
  2649   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> _::{real_normed_field,banach,second_countable_topology}"
  2650   assumes [simp]: "finite I" and integrable: "\<And>i. i \<in> I \<Longrightarrow> integrable (M i) (f i)"
  2651   shows "integrable (Pi\<^sub>M I M) (\<lambda>x. (\<Prod>i\<in>I. f i (x i)))" (is "integrable _ ?f")
  2652 proof (unfold integrable_iff_bounded, intro conjI)
  2653   interpret finite_product_sigma_finite M I by default fact
  2654   show "?f \<in> borel_measurable (Pi\<^sub>M I M)"
  2655     using assms by simp
  2656   have "(\<integral>\<^sup>+ x. ereal (norm (\<Prod>i\<in>I. f i (x i))) \<partial>Pi\<^sub>M I M) = 
  2657       (\<integral>\<^sup>+ x. (\<Prod>i\<in>I. ereal (norm (f i (x i)))) \<partial>Pi\<^sub>M I M)"
  2658     by (simp add: setprod_norm setprod_ereal)
  2659   also have "\<dots> = (\<Prod>i\<in>I. \<integral>\<^sup>+ x. ereal (norm (f i x)) \<partial>M i)"
  2660     using assms by (intro product_nn_integral_setprod) auto
  2661   also have "\<dots> < \<infinity>"
  2662     using integrable by (simp add: setprod_PInf nn_integral_nonneg integrable_iff_bounded)
  2663   finally show "(\<integral>\<^sup>+ x. ereal (norm (\<Prod>i\<in>I. f i (x i))) \<partial>Pi\<^sub>M I M) < \<infinity>" .
  2664 qed
  2665 
  2666 lemma (in product_sigma_finite) product_integral_setprod:
  2667   fixes f :: "'i \<Rightarrow> 'a \<Rightarrow> _::{real_normed_field,banach,second_countable_topology}"
  2668   assumes "finite I" and integrable: "\<And>i. i \<in> I \<Longrightarrow> integrable (M i) (f i)"
  2669   shows "(\<integral>x. (\<Prod>i\<in>I. f i (x i)) \<partial>Pi\<^sub>M I M) = (\<Prod>i\<in>I. integral\<^sup>L (M i) (f i))"
  2670 using assms proof induct
  2671   case empty
  2672   interpret finite_measure "Pi\<^sub>M {} M"
  2673     by rule (simp add: space_PiM)
  2674   show ?case by (simp add: space_PiM measure_def)
  2675 next
  2676   case (insert i I)
  2677   then have iI: "finite (insert i I)" by auto
  2678   then have prod: "\<And>J. J \<subseteq> insert i I \<Longrightarrow>
  2679     integrable (Pi\<^sub>M J M) (\<lambda>x. (\<Prod>i\<in>J. f i (x i)))"
  2680     by (intro product_integrable_setprod insert(4)) (auto intro: finite_subset)
  2681   interpret I: finite_product_sigma_finite M I by default fact
  2682   have *: "\<And>x y. (\<Prod>j\<in>I. f j (if j = i then y else x j)) = (\<Prod>j\<in>I. f j (x j))"
  2683     using `i \<notin> I` by (auto intro!: setprod_cong)
  2684   show ?case
  2685     unfolding product_integral_insert[OF insert(1,2) prod[OF subset_refl]]
  2686     by (simp add: * insert prod subset_insertI)
  2687 qed
  2688 
  2689 lemma integrable_subalgebra:
  2690   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  2691   assumes borel: "f \<in> borel_measurable N"
  2692   and N: "sets N \<subseteq> sets M" "space N = space M" "\<And>A. A \<in> sets N \<Longrightarrow> emeasure N A = emeasure M A"
  2693   shows "integrable N f \<longleftrightarrow> integrable M f" (is ?P)
  2694 proof -
  2695   have "f \<in> borel_measurable M"
  2696     using assms by (auto simp: measurable_def)
  2697   with assms show ?thesis
  2698     using assms by (auto simp: integrable_iff_bounded nn_integral_subalgebra)
  2699 qed
  2700 
  2701 lemma integral_subalgebra:
  2702   fixes f :: "'a \<Rightarrow> 'b::{banach, second_countable_topology}"
  2703   assumes borel: "f \<in> borel_measurable N"
  2704   and N: "sets N \<subseteq> sets M" "space N = space M" "\<And>A. A \<in> sets N \<Longrightarrow> emeasure N A = emeasure M A"
  2705   shows "integral\<^sup>L N f = integral\<^sup>L M f"
  2706 proof cases
  2707   assume "integrable N f"
  2708   then show ?thesis
  2709   proof induct
  2710     case base with assms show ?case by (auto simp: subset_eq measure_def)
  2711   next
  2712     case (add f g)
  2713     then have "(\<integral> a. f a + g a \<partial>N) = integral\<^sup>L M f + integral\<^sup>L M g"
  2714       by simp
  2715     also have "\<dots> = (\<integral> a. f a + g a \<partial>M)"
  2716       using add integrable_subalgebra[OF _ N, of f] integrable_subalgebra[OF _ N, of g] by simp
  2717     finally show ?case .
  2718   next
  2719     case (lim f s)
  2720     then have M: "\<And>i. integrable M (s i)" "integrable M f"
  2721       using integrable_subalgebra[OF _ N, of f] integrable_subalgebra[OF _ N, of "s i" for i] by simp_all
  2722     show ?case
  2723     proof (intro LIMSEQ_unique)
  2724       show "(\<lambda>i. integral\<^sup>L N (s i)) ----> integral\<^sup>L N f"
  2725         apply (rule integral_dominated_convergence[where w="\<lambda>x. 2 * norm (f x)"])
  2726         using lim
  2727         apply auto
  2728         done
  2729       show "(\<lambda>i. integral\<^sup>L N (s i)) ----> integral\<^sup>L M f"
  2730         unfolding lim
  2731         apply (rule integral_dominated_convergence[where w="\<lambda>x. 2 * norm (f x)"])
  2732         using lim M N(2)
  2733         apply auto
  2734         done
  2735     qed
  2736   qed
  2737 qed (simp add: not_integrable_integral_eq integrable_subalgebra[OF assms])
  2738 
  2739 hide_const simple_bochner_integral
  2740 hide_const simple_bochner_integrable
  2741 
  2742 end