src/Pure/theory.ML
author wenzelm
Wed Apr 04 00:11:03 2007 +0200 (2007-04-04)
changeset 22578 b0eb5652f210
parent 22485 3a7d623485fa
child 22600 043232f8dde2
permissions -rw-r--r--
removed obsolete sign_of/sign_of_thm;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   val rep_theory: theory ->
    11    {axioms: term NameSpace.table,
    12     defs: Defs.T,
    13     oracles: ((theory * Object.T -> term) * stamp) NameSpace.table}
    14   val parents_of: theory -> theory list
    15   val ancestors_of: theory -> theory list
    16   val eq_thy: theory * theory -> bool
    17   val subthy: theory * theory -> bool
    18   val cert_axm: theory -> string * term -> string * term
    19   val read_def_axm: theory * (indexname -> typ option) * (indexname -> sort option) ->
    20     string list -> string * string -> string * term
    21   val read_axm: theory -> string * string -> string * term
    22   val inferT_axm: theory -> string * term -> string * term
    23 end
    24 
    25 signature THEORY =
    26 sig
    27   include BASIC_THEORY
    28   include SIGN_THEORY
    29   val begin_theory: string -> theory list -> theory
    30   val end_theory: theory -> theory
    31   val checkpoint: theory -> theory
    32   val copy: theory -> theory
    33   val init_data: theory -> theory
    34   val axiom_space: theory -> NameSpace.T
    35   val oracle_space: theory -> NameSpace.T
    36   val axioms_of: theory -> (string * term) list
    37   val all_axioms_of: theory -> (string * term) list
    38   val defs_of : theory -> Defs.T
    39   val self_ref: theory -> theory_ref
    40   val deref: theory_ref -> theory
    41   val merge: theory * theory -> theory                     (*exception TERM*)
    42   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    43   val merge_list: theory list -> theory                    (*exception TERM*)
    44   val requires: theory -> string -> string -> unit
    45   val assert_super: theory -> theory -> theory
    46   val add_axioms: (bstring * string) list -> theory -> theory
    47   val add_axioms_i: (bstring * term) list -> theory -> theory
    48   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    49   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    50   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    51   val add_finals: bool -> string list -> theory -> theory
    52   val add_finals_i: bool -> term list -> theory -> theory
    53   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    54   val dep_graph: theory -> unit Graph.T;
    55 end
    56 
    57 structure Theory: THEORY =
    58 struct
    59 
    60 
    61 (** type theory **)
    62 
    63 (* context operations *)
    64 
    65 val eq_thy = Context.eq_thy;
    66 val subthy = Context.subthy;
    67 
    68 val parents_of = Context.parents_of;
    69 val ancestors_of = Context.ancestors_of;
    70 
    71 val self_ref = Context.self_ref;
    72 val deref = Context.deref;
    73 val merge = Context.merge;
    74 val merge_refs = Context.merge_refs;
    75 
    76 fun merge_list [] = raise TERM ("Empty merge of theories", [])
    77   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    78 
    79 val begin_theory = Sign.local_path oo Context.begin_thy Sign.pp;
    80 val end_theory = Context.finish_thy;
    81 val checkpoint = Context.checkpoint_thy;
    82 val copy = Context.copy_thy;
    83 
    84 
    85 (* signature operations *)
    86 
    87 structure SignTheory: SIGN_THEORY = Sign;
    88 open SignTheory;
    89 
    90 
    91 
    92 (** datatype thy **)
    93 
    94 datatype thy = Thy of
    95  {axioms: term NameSpace.table,
    96   defs: Defs.T,
    97   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table};
    98 
    99 fun make_thy (axioms, defs, oracles) =
   100   Thy {axioms = axioms, defs = defs, oracles = oracles};
   101 
   102 fun err_dup_axms dups = error ("Duplicate axiom(s): " ^ commas_quote dups);
   103 fun err_dup_oras dups = error ("Duplicate oracle(s): " ^ commas_quote dups);
   104 
   105 structure ThyData = TheoryDataFun
   106 (struct
   107   val name = "Pure/theory";
   108   type T = thy;
   109   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table);
   110   val copy = I;
   111 
   112   fun extend (Thy {axioms, defs, oracles}) = make_thy (NameSpace.empty_table, defs, oracles);
   113 
   114   fun merge pp (thy1, thy2) =
   115     let
   116       val Thy {axioms = _, defs = defs1, oracles = oracles1} = thy1;
   117       val Thy {axioms = _, defs = defs2, oracles = oracles2} = thy2;
   118 
   119       val axioms = NameSpace.empty_table;
   120       val defs = Defs.merge pp (defs1, defs2);
   121       val oracles = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   122         handle Symtab.DUPS dups => err_dup_oras dups;
   123     in make_thy (axioms, defs, oracles) end;
   124 
   125   fun print _ _ = ();
   126 end);
   127 
   128 val init_data = ThyData.init;
   129 
   130 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   131 
   132 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles}) =>
   133   make_thy (f (axioms, defs, oracles)));
   134 
   135 fun map_axioms f = map_thy (fn (axioms, defs, oracles) => (f axioms, defs, oracles));
   136 fun map_defs f = map_thy (fn (axioms, defs, oracles) => (axioms, f defs, oracles));
   137 fun map_oracles f = map_thy (fn (axioms, defs, oracles) => (axioms, defs, f oracles));
   138 
   139 
   140 (* basic operations *)
   141 
   142 val axiom_space = #1 o #axioms o rep_theory;
   143 val oracle_space = #1 o #oracles o rep_theory;
   144 
   145 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   146 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   147 
   148 val defs_of = #defs o rep_theory;
   149 
   150 fun requires thy name what =
   151   if Context.exists_name name thy then ()
   152   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   153 
   154 fun assert_super thy1 thy2 =
   155   if subthy (thy1, thy2) then thy2
   156   else raise THEORY ("Not a super theory", [thy1, thy2]);
   157 
   158 
   159 
   160 (** add axioms **)
   161 
   162 (* prepare axioms *)
   163 
   164 fun err_in_axm msg name =
   165   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   166 
   167 fun cert_axm thy (name, raw_tm) =
   168   let
   169     val (t, T, _) = Sign.certify_prop thy raw_tm
   170       handle TYPE (msg, _, _) => error msg
   171         | TERM (msg, _) => error msg;
   172   in
   173     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   174     (name, Sign.no_vars (Sign.pp thy) t)
   175   end;
   176 
   177 fun read_def_axm (thy, types, sorts) used (name, str) =
   178   let
   179     val ts = Syntax.read (ProofContext.init thy) (Sign.is_logtype thy) (Sign.syn_of thy) propT str;
   180     val (t, _) =
   181       Sign.infer_types (Sign.pp thy) thy (Sign.consts_of thy)
   182         types sorts (Name.make_context used) true (ts, propT);
   183   in cert_axm thy (name, t) end
   184   handle ERROR msg => err_in_axm msg name;
   185 
   186 fun read_axm thy name_str = read_def_axm (thy, K NONE, K NONE) [] name_str;
   187 
   188 fun inferT_axm thy (name, pre_tm) =
   189   let
   190     val pp = Sign.pp thy;
   191     val (t, _) =
   192       Sign.infer_types pp thy (Sign.consts_of thy)
   193         (K NONE) (K NONE) Name.context true ([pre_tm], propT);
   194   in (name, Sign.no_vars pp t) end
   195   handle ERROR msg => err_in_axm msg name;
   196 
   197 
   198 (* add_axioms(_i) *)
   199 
   200 local
   201 
   202 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   203   let
   204     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   205     val axioms' = NameSpace.extend_table (Sign.naming_of thy) (axioms, axms)
   206       handle Symtab.DUPS dups => err_dup_axms dups;
   207   in axioms' end);
   208 
   209 in
   210 
   211 val add_axioms = gen_add_axioms read_axm;
   212 val add_axioms_i = gen_add_axioms cert_axm;
   213 
   214 end;
   215 
   216 
   217 
   218 (** add constant definitions **)
   219 
   220 (* dependencies *)
   221 
   222 fun dependencies thy unchecked is_def name lhs rhs =
   223   let
   224     val pp = Sign.pp thy;
   225     val consts = Sign.consts_of thy;
   226     fun prep const =
   227       let val Const (c, T) = Sign.no_vars pp (Const const)
   228       in (c, Consts.typargs consts (c, Compress.typ thy (Logic.varifyT T))) end;
   229 
   230     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   231     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   232       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   233     val _ =
   234       if null rhs_extras then ()
   235       else error ("Specification depends on extra type variables: " ^
   236         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   237         "\nThe error(s) above occurred in " ^ quote name);
   238   in Defs.define pp unchecked is_def (Context.theory_name thy) name (prep lhs) (map prep rhs) end;
   239 
   240 fun add_deps a raw_lhs raw_rhs thy =
   241   let
   242     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   243     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   244   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   245 
   246 
   247 (* check_overloading *)
   248 
   249 fun check_overloading thy overloaded (c, T) =
   250   let
   251     val declT =
   252       (case Sign.const_constraint thy c of
   253         NONE => error ("Undeclared constant " ^ quote c)
   254       | SOME declT => declT);
   255     val T' = Logic.varifyT T;
   256 
   257     fun message txt =
   258       [Pretty.block [Pretty.str "Specification of constant ",
   259         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   260         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   261   in
   262     if Sign.typ_instance thy (declT, T') then ()
   263     else if Type.raw_instance (declT, T') then
   264       error (Library.setmp show_sorts true
   265         message "imposes additional sort constraints on the constant declaration")
   266     else if overloaded then ()
   267     else warning (message "is strictly less general than the declared type");
   268     (c, T)
   269   end;
   270 
   271 
   272 (* check_def *)
   273 
   274 fun check_def thy unchecked overloaded (bname, tm) defs =
   275   let
   276     val name = Sign.full_name thy bname;
   277     val (lhs_const, rhs) = Sign.cert_def (Sign.pp thy) tm;
   278     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   279     val _ = check_overloading thy overloaded lhs_const;
   280   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   281   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   282    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   283     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   284 
   285 
   286 (* add_defs(_i) *)
   287 
   288 local
   289 
   290 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   291   let val axms = map (prep_axm thy) raw_axms in
   292     thy
   293     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   294     |> add_axioms_i axms
   295   end;
   296 
   297 in
   298 
   299 val add_defs_i = gen_add_defs cert_axm;
   300 val add_defs = gen_add_defs read_axm;
   301 
   302 end;
   303 
   304 
   305 (* add_finals(_i) *)
   306 
   307 local
   308 
   309 fun gen_add_finals prep_term overloaded args thy =
   310   let
   311     fun const_of (Const const) = const
   312       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   313       | const_of _ = error "Attempt to finalize non-constant term";
   314     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   315     val finalize = specify o check_overloading thy overloaded o const_of o prep_term thy;
   316   in thy |> map_defs (fold finalize args) end;
   317 
   318 in
   319 
   320 val add_finals = gen_add_finals Sign.read_term;
   321 val add_finals_i = gen_add_finals Sign.cert_term;
   322 
   323 end;
   324 
   325 
   326 
   327 (** add oracle **)
   328 
   329 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   330   NameSpace.extend_table (Sign.naming_of thy) (oracles, [(bname, (oracle, stamp ()))])
   331     handle Symtab.DUPS dups => err_dup_oras dups);
   332 
   333 
   334 
   335 (** graph of theory parents **)
   336 
   337 fun dep_graph thy =
   338   let
   339     fun add_thy thy gr =
   340       let
   341         val name = Context.theory_name thy;
   342       in if can (Graph.get_node gr) name then (name, gr)
   343       else
   344         gr
   345         |> Graph.new_node (name, ())
   346         |> fold_map add_thy (parents_of thy)
   347         |-> (fn names => fold (fn name' => Graph.add_edge (name, name')) names)
   348         |> pair name
   349       end;
   350   in snd (add_thy thy Graph.empty) end;
   351 
   352 end;
   353 
   354 structure BasicTheory: BASIC_THEORY = Theory;
   355 open BasicTheory;