author eberlm
Mon Jan 04 17:45:36 2016 +0100 (2016-01-04)
changeset 62049 b0f941e207cf
parent 61976 3a27957ac658
child 62083 7582b39f51ed
permissions -rw-r--r--
Added lots of material on infinite sums, convergence radii, harmonic numbers, Gamma function
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     6 section \<open>Topological Spaces\<close>
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    12 named_theorems continuous_intros "structural introduction rules for continuity"
    15 subsection \<open>Topological space\<close>
    17 class "open" =
    18   fixes "open" :: "'a set \<Rightarrow> bool"
    20 class topological_space = "open" +
    21   assumes open_UNIV [simp, intro]: "open UNIV"
    22   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    23   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union>K)"
    24 begin
    26 definition
    27   closed :: "'a set \<Rightarrow> bool" where
    28   "closed S \<longleftrightarrow> open (- S)"
    30 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    31   using open_Union [of "{}"] by simp
    33 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    34   using open_Union [of "{S, T}"] by simp
    36 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    37   using open_Union [of "B ` A"] by simp
    39 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    40   by (induct set: finite) auto
    42 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    43   using open_Inter [of "B ` A"] by simp
    45 lemma openI:
    46   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    47   shows "open S"
    48 proof -
    49   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    50   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    51   ultimately show "open S" by simp
    52 qed
    54 lemma closed_empty [continuous_intros, intro, simp]:  "closed {}"
    55   unfolding closed_def by simp
    57 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    58   unfolding closed_def by auto
    60 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    61   unfolding closed_def by simp
    63 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    64   unfolding closed_def by auto
    66 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    67   unfolding closed_def by auto
    69 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter>K)"
    70   unfolding closed_def uminus_Inf by auto
    72 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    73   by (induct set: finite) auto
    75 lemma closed_UN [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    76   using closed_Union [of "B ` A"] by simp
    78 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    79   unfolding closed_def by simp
    81 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    82   unfolding closed_def by simp
    84 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    85   unfolding closed_open Diff_eq by (rule open_Int)
    87 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    88   unfolding open_closed Diff_eq by (rule closed_Int)
    90 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
    91   unfolding closed_open .
    93 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
    94   unfolding open_closed .
    96 lemma open_Collect_neg: "closed {x. P x} \<Longrightarrow> open {x. \<not> P x}"
    97   unfolding Collect_neg_eq by (rule open_Compl)
    99 lemma open_Collect_conj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<and> Q x}"
   100   using open_Int[OF assms] by (simp add: Int_def)
   102 lemma open_Collect_disj: assumes "open {x. P x}" "open {x. Q x}" shows "open {x. P x \<or> Q x}"
   103   using open_Un[OF assms] by (simp add: Un_def)
   105 lemma open_Collect_ex: "(\<And>i. open {x. P i x}) \<Longrightarrow> open {x. \<exists>i. P i x}"
   106   using open_UN[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_ex_eq by simp 
   108 lemma open_Collect_imp: "closed {x. P x} \<Longrightarrow> open {x. Q x} \<Longrightarrow> open {x. P x \<longrightarrow> Q x}"
   109   unfolding imp_conv_disj by (intro open_Collect_disj open_Collect_neg)
   111 lemma open_Collect_const: "open {x. P}"
   112   by (cases P) auto
   114 lemma closed_Collect_neg: "open {x. P x} \<Longrightarrow> closed {x. \<not> P x}"
   115   unfolding Collect_neg_eq by (rule closed_Compl)
   117 lemma closed_Collect_conj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<and> Q x}"
   118   using closed_Int[OF assms] by (simp add: Int_def)
   120 lemma closed_Collect_disj: assumes "closed {x. P x}" "closed {x. Q x}" shows "closed {x. P x \<or> Q x}"
   121   using closed_Un[OF assms] by (simp add: Un_def)
   123 lemma closed_Collect_all: "(\<And>i. closed {x. P i x}) \<Longrightarrow> closed {x. \<forall>i. P i x}"
   124   using closed_INT[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_all_eq by simp 
   126 lemma closed_Collect_imp: "open {x. P x} \<Longrightarrow> closed {x. Q x} \<Longrightarrow> closed {x. P x \<longrightarrow> Q x}"
   127   unfolding imp_conv_disj by (intro closed_Collect_disj closed_Collect_neg)
   129 lemma closed_Collect_const: "closed {x. P}"
   130   by (cases P) auto
   132 end
   134 subsection\<open>Hausdorff and other separation properties\<close>
   136 class t0_space = topological_space +
   137   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   139 class t1_space = topological_space +
   140   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   142 instance t1_space \<subseteq> t0_space
   143 proof qed (fast dest: t1_space)
   145 lemma separation_t1:
   146   fixes x y :: "'a::t1_space"
   147   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   148   using t1_space[of x y] by blast
   150 lemma closed_singleton:
   151   fixes a :: "'a::t1_space"
   152   shows "closed {a}"
   153 proof -
   154   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   155   have "open ?T" by (simp add: open_Union)
   156   also have "?T = - {a}"
   157     by (simp add: set_eq_iff separation_t1, auto)
   158   finally show "closed {a}" unfolding closed_def .
   159 qed
   161 lemma closed_insert [continuous_intros, simp]:
   162   fixes a :: "'a::t1_space"
   163   assumes "closed S" shows "closed (insert a S)"
   164 proof -
   165   from closed_singleton assms
   166   have "closed ({a} \<union> S)" by (rule closed_Un)
   167   thus "closed (insert a S)" by simp
   168 qed
   170 lemma finite_imp_closed:
   171   fixes S :: "'a::t1_space set"
   172   shows "finite S \<Longrightarrow> closed S"
   173 by (induct set: finite, simp_all)
   175 text \<open>T2 spaces are also known as Hausdorff spaces.\<close>
   177 class t2_space = topological_space +
   178   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   180 instance t2_space \<subseteq> t1_space
   181 proof qed (fast dest: hausdorff)
   183 lemma separation_t2:
   184   fixes x y :: "'a::t2_space"
   185   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   186   using hausdorff[of x y] by blast
   188 lemma separation_t0:
   189   fixes x y :: "'a::t0_space"
   190   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   191   using t0_space[of x y] by blast
   193 text \<open>A perfect space is a topological space with no isolated points.\<close>
   195 class perfect_space = topological_space +
   196   assumes not_open_singleton: "\<not> open {x}"
   199 subsection \<open>Generators for toplogies\<close>
   201 inductive generate_topology for S where
   202   UNIV: "generate_topology S UNIV"
   203 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   204 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   205 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   207 hide_fact (open) UNIV Int UN Basis 
   209 lemma generate_topology_Union: 
   210   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   211   using generate_topology.UN [of "K ` I"] by auto
   213 lemma topological_space_generate_topology:
   214   "class.topological_space (generate_topology S)"
   215   by standard (auto intro: generate_topology.intros)
   217 subsection \<open>Order topologies\<close>
   219 class order_topology = order + "open" +
   220   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   221 begin
   223 subclass topological_space
   224   unfolding open_generated_order
   225   by (rule topological_space_generate_topology)
   227 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   228   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   230 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   231   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   233 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   234    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   236 end
   238 class linorder_topology = linorder + order_topology
   240 lemma closed_atMost [continuous_intros, simp]: "closed {.. a::'a::linorder_topology}"
   241   by (simp add: closed_open)
   243 lemma closed_atLeast [continuous_intros, simp]: "closed {a::'a::linorder_topology ..}"
   244   by (simp add: closed_open)
   246 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a::'a::linorder_topology .. b}"
   247 proof -
   248   have "{a .. b} = {a ..} \<inter> {.. b}"
   249     by auto
   250   then show ?thesis
   251     by (simp add: closed_Int)
   252 qed
   254 lemma (in linorder) less_separate:
   255   assumes "x < y"
   256   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   257 proof (cases "\<exists>z. x < z \<and> z < y")
   258   case True
   259   then obtain z where "x < z \<and> z < y" ..
   260   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   261     by auto
   262   then show ?thesis by blast
   263 next
   264   case False
   265   with \<open>x < y\<close> have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   266     by auto
   267   then show ?thesis by blast
   268 qed
   270 instance linorder_topology \<subseteq> t2_space
   271 proof
   272   fix x y :: 'a
   273   from less_separate[of x y] less_separate[of y x]
   274   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   275     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   276 qed
   278 lemma (in linorder_topology) open_right:
   279   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   280   using assms unfolding open_generated_order
   281 proof induction
   282   case (Int A B)
   283   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   284   then show ?case by (auto intro!: exI[of _ "min a b"])
   285 next
   286   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   287 qed blast+
   289 lemma (in linorder_topology) open_left:
   290   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   291   using assms unfolding open_generated_order
   292 proof induction
   293   case (Int A B)
   294   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   295   then show ?case by (auto intro!: exI[of _ "max a b"])
   296 next
   297   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   298 qed blast+
   300 subsubsection \<open>Boolean is an order topology\<close>
   302 text \<open>It also is a discrete topology, but don't have a type class for it (yet).\<close>
   304 instantiation bool :: order_topology
   305 begin
   307 definition open_bool :: "bool set \<Rightarrow> bool" where
   308   "open_bool = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   310 instance
   311   proof qed (rule open_bool_def)
   313 end
   315 lemma open_bool[simp, intro!]: "open (A::bool set)"
   316 proof -
   317   have *: "{False <..} = {True}" "{..< True} = {False}"
   318     by auto
   319   have "A = UNIV \<or> A = {} \<or> A = {False <..} \<or> A = {..< True}"
   320     using subset_UNIV[of A] unfolding UNIV_bool * by auto
   321   then show "open A"
   322     by auto
   323 qed
   325 subsubsection \<open>Topological filters\<close>
   327 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   328   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   330 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   331   where "at a within s = inf (nhds a) (principal (s - {a}))"
   333 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   334   "at x \<equiv> at x within (CONST UNIV)"
   336 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   337   "at_right x \<equiv> at x within {x <..}"
   339 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   340   "at_left x \<equiv> at x within {..< x}"
   342 lemma (in topological_space) nhds_generated_topology:
   343   "open = generate_topology T \<Longrightarrow> nhds x = (INF S:{S\<in>T. x \<in> S}. principal S)"
   344   unfolding nhds_def
   345 proof (safe intro!: antisym INF_greatest)
   346   fix S assume "generate_topology T S" "x \<in> S"
   347   then show "(INF S:{S \<in> T. x \<in> S}. principal S) \<le> principal S"
   348     by induction 
   349        (auto intro: INF_lower order_trans simp add: inf_principal[symmetric] simp del: inf_principal)
   350 qed (auto intro!: INF_lower intro: generate_topology.intros)
   352 lemma (in topological_space) eventually_nhds:
   353   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   354   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   356 lemma (in topological_space) eventually_nhds_in_open: 
   357   "open s \<Longrightarrow> x \<in> s \<Longrightarrow> eventually (\<lambda>y. y \<in> s) (nhds x)"
   358   by (subst eventually_nhds) blast
   360 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   361   unfolding trivial_limit_def eventually_nhds by simp
   363 lemma (in t1_space) t1_space_nhds:
   364   "x \<noteq> y \<Longrightarrow> (\<forall>\<^sub>F x in nhds x. x \<noteq> y)"
   365   by (drule t1_space) (auto simp: eventually_nhds)
   367 lemma at_within_eq: "at x within s = (INF S:{S. open S \<and> x \<in> S}. principal (S \<inter> s - {x}))"
   368   unfolding nhds_def at_within_def by (subst INF_inf_const2[symmetric]) (auto simp add: Diff_Int_distrib)
   370 lemma eventually_at_filter:
   371   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   372   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   374 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   375   unfolding at_within_def by (intro inf_mono) auto
   377 lemma eventually_at_topological:
   378   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   379   unfolding eventually_nhds eventually_at_filter by simp
   381 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   382   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   384 lemma at_within_open_NO_MATCH:
   385   "a \<in> s \<Longrightarrow> open s \<Longrightarrow> NO_MATCH UNIV s \<Longrightarrow> at a within s = at a"
   386   by (simp only: at_within_open)
   388 lemma at_within_nhd:
   389   assumes "x \<in> S" "open S" "T \<inter> S - {x} = U \<inter> S - {x}"
   390   shows "at x within T = at x within U"
   391   unfolding filter_eq_iff eventually_at_filter
   392 proof (intro allI eventually_subst)
   393   have "eventually (\<lambda>x. x \<in> S) (nhds x)"
   394     using \<open>x \<in> S\<close> \<open>open S\<close> by (auto simp: eventually_nhds)
   395   then show "\<forall>\<^sub>F n in nhds x. (n \<noteq> x \<longrightarrow> n \<in> T \<longrightarrow> P n) = (n \<noteq> x \<longrightarrow> n \<in> U \<longrightarrow> P n)" for P  
   396     by eventually_elim (insert \<open>T \<inter> S - {x} = U \<inter> S - {x}\<close>, blast)
   397 qed
   399 lemma at_within_empty [simp]: "at a within {} = bot"
   400   unfolding at_within_def by simp
   402 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   403   unfolding filter_eq_iff eventually_sup eventually_at_filter
   404   by (auto elim!: eventually_rev_mp)
   406 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   407   unfolding trivial_limit_def eventually_at_topological
   408   by (safe, case_tac "S = {a}", simp, fast, fast)
   410 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   411   by (simp add: at_eq_bot_iff not_open_singleton)
   413 lemma (in order_topology) nhds_order: "nhds x =
   414   inf (INF a:{x <..}. principal {..< a}) (INF a:{..< x}. principal {a <..})"
   415 proof -
   416   have 1: "{S \<in> range lessThan \<union> range greaterThan. x \<in> S} = 
   417       (\<lambda>a. {..< a}) ` {x <..} \<union> (\<lambda>a. {a <..}) ` {..< x}"
   418     by auto
   419   show ?thesis
   420     unfolding nhds_generated_topology[OF open_generated_order] INF_union 1 INF_image comp_def ..
   421 qed
   423 lemma (in linorder_topology) at_within_order: "UNIV \<noteq> {x} \<Longrightarrow> 
   424   at x within s = inf (INF a:{x <..}. principal ({..< a} \<inter> s - {x}))
   425                       (INF a:{..< x}. principal ({a <..} \<inter> s - {x}))"
   426 proof (cases "{x <..} = {}" "{..< x} = {}" rule: case_split[case_product case_split])
   427   assume "UNIV \<noteq> {x}" "{x<..} = {}" "{..< x} = {}"
   428   moreover have "UNIV = {..< x} \<union> {x} \<union> {x <..}"
   429     by auto
   430   ultimately show ?thesis
   431     by auto
   432 qed (auto simp: at_within_def nhds_order Int_Diff inf_principal[symmetric] INF_inf_const2
   433                 inf_sup_aci[where 'a="'a filter"]
   434           simp del: inf_principal)
   436 lemma (in linorder_topology) at_left_eq:
   437   "y < x \<Longrightarrow> at_left x = (INF a:{..< x}. principal {a <..< x})"
   438   by (subst at_within_order)
   439      (auto simp: greaterThan_Int_greaterThan greaterThanLessThan_eq[symmetric] min.absorb2 INF_constant
   440            intro!: INF_lower2 inf_absorb2)
   442 lemma (in linorder_topology) eventually_at_left:
   443   "y < x \<Longrightarrow> eventually P (at_left x) \<longleftrightarrow> (\<exists>b<x. \<forall>y>b. y < x \<longrightarrow> P y)"
   444   unfolding at_left_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   446 lemma (in linorder_topology) at_right_eq:
   447   "x < y \<Longrightarrow> at_right x = (INF a:{x <..}. principal {x <..< a})"
   448   by (subst at_within_order)
   449      (auto simp: lessThan_Int_lessThan greaterThanLessThan_eq[symmetric] max.absorb2 INF_constant Int_commute
   450            intro!: INF_lower2 inf_absorb1)
   452 lemma (in linorder_topology) eventually_at_right:
   453   "x < y \<Longrightarrow> eventually P (at_right x) \<longleftrightarrow> (\<exists>b>x. \<forall>y>x. y < b \<longrightarrow> P y)"
   454   unfolding at_right_eq by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   456 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top, linorder_topology}) = bot"
   457   unfolding filter_eq_iff eventually_at_topological by auto
   459 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot, linorder_topology}) = bot"
   460   unfolding filter_eq_iff eventually_at_topological by auto
   462 lemma trivial_limit_at_left_real [simp]:
   463   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_order, linorder_topology}))"
   464   using lt_ex[of x]
   465   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   467 lemma trivial_limit_at_right_real [simp]:
   468   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_order, linorder_topology}))"
   469   using gt_ex[of x]
   470   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
   472 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   473   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   474            elim: eventually_elim2 eventually_mono)
   476 lemma eventually_at_split:
   477   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   478   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   480 subsubsection \<open>Tendsto\<close>
   482 abbreviation (in topological_space)
   483   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "\<longlongrightarrow>" 55) where
   484   "(f \<longlongrightarrow> l) F \<equiv> filterlim f (nhds l) F"
   486 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   487   "Lim A f = (THE l. (f \<longlongrightarrow> l) A)"
   489 lemma tendsto_eq_rhs: "(f \<longlongrightarrow> x) F \<Longrightarrow> x = y \<Longrightarrow> (f \<longlongrightarrow> y) F"
   490   by simp
   492 named_theorems tendsto_intros "introduction rules for tendsto"
   493 setup \<open>
   494   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   495     fn context =>
   496       Named_Theorems.get (Context.proof_of context) @{named_theorems tendsto_intros}
   497       |> map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])))
   498 \<close>
   500 lemma (in topological_space) tendsto_def:
   501    "(f \<longlongrightarrow> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   502    unfolding nhds_def filterlim_INF filterlim_principal by auto
   504 lemma tendsto_cong:
   505   assumes "eventually (\<lambda>x. f x = g x) F"
   506   shows   "(f \<longlongrightarrow> c) F \<longleftrightarrow> (g \<longlongrightarrow> c) F"
   507   by (rule filterlim_cong[OF refl refl assms])
   510 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f \<longlongrightarrow> l) F' \<Longrightarrow> (f \<longlongrightarrow> l) F"
   511   unfolding tendsto_def le_filter_def by fast
   513 lemma tendsto_within_subset: "(f \<longlongrightarrow> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f \<longlongrightarrow> l) (at x within T)"
   514   by (blast intro: tendsto_mono at_le)
   516 lemma filterlim_at:
   517   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f \<longlongrightarrow> b) F)"
   518   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   520 lemma (in topological_space) topological_tendstoI:
   521   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f \<longlongrightarrow> l) F"
   522   unfolding tendsto_def by auto
   524 lemma (in topological_space) topological_tendstoD:
   525   "(f \<longlongrightarrow> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   526   unfolding tendsto_def by auto
   528 lemma (in order_topology) order_tendsto_iff:
   529   "(f \<longlongrightarrow> x) F \<longleftrightarrow> (\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   530   unfolding nhds_order filterlim_inf filterlim_INF filterlim_principal by auto
   532 lemma (in order_topology) order_tendstoI:
   533   "(\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F) \<Longrightarrow> (\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F) \<Longrightarrow>
   534     (f \<longlongrightarrow> y) F"
   535   unfolding order_tendsto_iff by auto
   537 lemma (in order_topology) order_tendstoD:
   538   assumes "(f \<longlongrightarrow> y) F"
   539   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   540     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   541   using assms unfolding order_tendsto_iff by auto
   543 lemma tendsto_bot [simp]: "(f \<longlongrightarrow> a) bot"
   544   unfolding tendsto_def by simp
   546 lemma (in linorder_topology) tendsto_max:
   547   assumes X: "(X \<longlongrightarrow> x) net"
   548   assumes Y: "(Y \<longlongrightarrow> y) net"
   549   shows "((\<lambda>x. max (X x) (Y x)) \<longlongrightarrow> max x y) net"
   550 proof (rule order_tendstoI)
   551   fix a assume "a < max x y"
   552   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
   553     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   554     by (auto simp: less_max_iff_disj elim: eventually_mono)
   555 next
   556   fix a assume "max x y < a"
   557   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
   558     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   559     by (auto simp: eventually_conj_iff)
   560 qed
   562 lemma (in linorder_topology) tendsto_min:
   563   assumes X: "(X \<longlongrightarrow> x) net"
   564   assumes Y: "(Y \<longlongrightarrow> y) net"
   565   shows "((\<lambda>x. min (X x) (Y x)) \<longlongrightarrow> min x y) net"
   566 proof (rule order_tendstoI)
   567   fix a assume "a < min x y"
   568   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
   569     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   570     by (auto simp: eventually_conj_iff)
   571 next
   572   fix a assume "min x y < a"
   573   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
   574     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   575     by (auto simp: min_less_iff_disj elim: eventually_mono)
   576 qed
   578 lemma tendsto_ident_at [tendsto_intros, simp, intro]: "((\<lambda>x. x) \<longlongrightarrow> a) (at a within s)"
   579   unfolding tendsto_def eventually_at_topological by auto
   581 lemma (in topological_space) tendsto_const [tendsto_intros, simp, intro]: "((\<lambda>x. k) \<longlongrightarrow> k) F"
   582   by (simp add: tendsto_def)
   584 lemma (in t2_space) tendsto_unique:
   585   assumes "F \<noteq> bot" and "(f \<longlongrightarrow> a) F" and "(f \<longlongrightarrow> b) F"
   586   shows "a = b"
   587 proof (rule ccontr)
   588   assume "a \<noteq> b"
   589   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   590     using hausdorff [OF \<open>a \<noteq> b\<close>] by fast
   591   have "eventually (\<lambda>x. f x \<in> U) F"
   592     using \<open>(f \<longlongrightarrow> a) F\<close> \<open>open U\<close> \<open>a \<in> U\<close> by (rule topological_tendstoD)
   593   moreover
   594   have "eventually (\<lambda>x. f x \<in> V) F"
   595     using \<open>(f \<longlongrightarrow> b) F\<close> \<open>open V\<close> \<open>b \<in> V\<close> by (rule topological_tendstoD)
   596   ultimately
   597   have "eventually (\<lambda>x. False) F"
   598   proof eventually_elim
   599     case (elim x)
   600     hence "f x \<in> U \<inter> V" by simp
   601     with \<open>U \<inter> V = {}\<close> show ?case by simp
   602   qed
   603   with \<open>\<not> trivial_limit F\<close> show "False"
   604     by (simp add: trivial_limit_def)
   605 qed
   607 lemma (in t2_space) tendsto_const_iff:
   608   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) \<longlongrightarrow> b) F \<longleftrightarrow> a = b"
   609   by (auto intro!: tendsto_unique [OF assms tendsto_const])
   611 lemma increasing_tendsto:
   612   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   613   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   614       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   615   shows "(f \<longlongrightarrow> l) F"
   616   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   618 lemma decreasing_tendsto:
   619   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   620   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   621       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   622   shows "(f \<longlongrightarrow> l) F"
   623   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   625 lemma tendsto_sandwich:
   626   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
   627   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   628   assumes lim: "(f \<longlongrightarrow> c) net" "(h \<longlongrightarrow> c) net"
   629   shows "(g \<longlongrightarrow> c) net"
   630 proof (rule order_tendstoI)
   631   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
   632     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
   633 next
   634   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
   635     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
   636 qed
   638 lemma limit_frequently_eq:
   639   assumes "F \<noteq> bot"
   640   assumes "frequently (\<lambda>x. f x = c) F"
   641   assumes "(f \<longlongrightarrow> d) F"
   642   shows   "d = (c :: 'a :: t1_space)"
   643 proof (rule ccontr)
   644   assume "d \<noteq> c"
   645   from t1_space[OF this] obtain U where "open U" "d \<in> U" "c \<notin> U" by blast
   646   from this assms have "eventually (\<lambda>x. f x \<in> U) F" unfolding tendsto_def by blast
   647   hence "eventually (\<lambda>x. f x \<noteq> c) F" by eventually_elim (insert \<open>c \<notin> U\<close>, blast)
   648   with assms(2) show False unfolding frequently_def by contradiction
   649 qed
   651 lemma tendsto_imp_eventually_ne:
   652   assumes "F \<noteq> bot" "(f \<longlongrightarrow> c) F" "c \<noteq> (c' :: 'a :: t1_space)"
   653   shows   "eventually (\<lambda>z. f z \<noteq> c') F"
   654 proof (rule ccontr)
   655   assume "\<not>eventually (\<lambda>z. f z \<noteq> c') F"
   656   hence "frequently (\<lambda>z. f z = c') F" by (simp add: frequently_def)
   657   from limit_frequently_eq[OF assms(1) this assms(2)] and assms(3) show False by contradiction
   658 qed
   660 lemma tendsto_le:
   661   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
   662   assumes F: "\<not> trivial_limit F"
   663   assumes x: "(f \<longlongrightarrow> x) F" and y: "(g \<longlongrightarrow> y) F"
   664   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
   665   shows "y \<le> x"
   666 proof (rule ccontr)
   667   assume "\<not> y \<le> x"
   668   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
   669     by (auto simp: not_le)
   670   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
   671     using x y by (auto intro: order_tendstoD)
   672   with ev have "eventually (\<lambda>x. False) F"
   673     by eventually_elim (insert xy, fastforce)
   674   with F show False
   675     by (simp add: eventually_False)
   676 qed
   678 lemma tendsto_le_const:
   679   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
   680   assumes F: "\<not> trivial_limit F"
   681   assumes x: "(f \<longlongrightarrow> x) F" and a: "eventually (\<lambda>i. a \<le> f i) F"
   682   shows "a \<le> x"
   683   using F x tendsto_const a by (rule tendsto_le)
   685 lemma tendsto_ge_const:
   686   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
   687   assumes F: "\<not> trivial_limit F"
   688   assumes x: "(f \<longlongrightarrow> x) F" and a: "eventually (\<lambda>i. a \<ge> f i) F"
   689   shows "a \<ge> x"
   690   by (rule tendsto_le [OF F tendsto_const x a])
   695 subsubsection \<open>Rules about @{const Lim}\<close>
   697 lemma tendsto_Lim:
   698   "\<not>(trivial_limit net) \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> Lim net f = l"
   699   unfolding Lim_def using tendsto_unique[of net f] by auto
   701 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
   702   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
   704 lemma filterlim_at_bot_at_right:
   705   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   706   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   707   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   708   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
   709   assumes P: "eventually P at_bot"
   710   shows "filterlim f at_bot (at_right a)"
   711 proof -
   712   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
   713     unfolding eventually_at_bot_linorder by auto
   714   show ?thesis
   715   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
   716     fix z assume "z \<le> x"
   717     with x have "P z" by auto
   718     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
   719       using bound[OF bij(2)[OF \<open>P z\<close>]]
   720       unfolding eventually_at_right[OF bound[OF bij(2)[OF \<open>P z\<close>]]] by (auto intro!: exI[of _ "g z"])
   721     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
   722       by eventually_elim (metis bij \<open>P z\<close> mono)
   723   qed
   724 qed
   726 lemma filterlim_at_top_at_left:
   727   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   728   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   729   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   730   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
   731   assumes P: "eventually P at_top"
   732   shows "filterlim f at_top (at_left a)"
   733 proof -
   734   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   735     unfolding eventually_at_top_linorder by auto
   736   show ?thesis
   737   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   738     fix z assume "x \<le> z"
   739     with x have "P z" by auto
   740     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
   741       using bound[OF bij(2)[OF \<open>P z\<close>]]
   742       unfolding eventually_at_left[OF bound[OF bij(2)[OF \<open>P z\<close>]]] by (auto intro!: exI[of _ "g z"])
   743     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
   744       by eventually_elim (metis bij \<open>P z\<close> mono)
   745   qed
   746 qed
   748 lemma filterlim_split_at:
   749   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
   750   by (subst at_eq_sup_left_right) (rule filterlim_sup)
   752 lemma filterlim_at_split:
   753   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
   754   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
   756 lemma eventually_nhds_top:
   757   fixes P :: "'a :: {order_top, linorder_topology} \<Rightarrow> bool"
   758   assumes "(b::'a) < top"
   759   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
   760   unfolding eventually_nhds
   761 proof safe
   762   fix S :: "'a set" assume "open S" "top \<in> S"
   763   note open_left[OF this \<open>b < top\<close>]
   764   moreover assume "\<forall>s\<in>S. P s"
   765   ultimately show "\<exists>b<top. \<forall>z>b. P z"
   766     by (auto simp: subset_eq Ball_def)
   767 next
   768   fix b assume "b < top" "\<forall>z>b. P z"
   769   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
   770     by (intro exI[of _ "{b <..}"]) auto
   771 qed
   773 lemma tendsto_at_within_iff_tendsto_nhds:
   774   "(g \<longlongrightarrow> g l) (at l within S) \<longleftrightarrow> (g \<longlongrightarrow> g l) (inf (nhds l) (principal S))"
   775   unfolding tendsto_def eventually_at_filter eventually_inf_principal
   776   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
   778 subsection \<open>Limits on sequences\<close>
   780 abbreviation (in topological_space)
   781   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
   782     ("((_)/ \<longlonglongrightarrow> (_))" [60, 60] 60) where
   783   "X \<longlonglongrightarrow> L \<equiv> (X \<longlongrightarrow> L) sequentially"
   785 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
   786   "lim X \<equiv> Lim sequentially X"
   788 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
   789   "convergent X = (\<exists>L. X \<longlonglongrightarrow> L)"
   791 lemma lim_def: "lim X = (THE L. X \<longlonglongrightarrow> L)"
   792   unfolding Lim_def ..
   794 subsubsection \<open>Monotone sequences and subsequences\<close>
   796 definition
   797   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
   798     \<comment>\<open>Definition of monotonicity.
   799         The use of disjunction here complicates proofs considerably.
   800         One alternative is to add a Boolean argument to indicate the direction.
   801         Another is to develop the notions of increasing and decreasing first.\<close>
   802   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
   804 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
   805   "incseq X \<equiv> mono X"
   807 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
   808   unfolding mono_def ..
   810 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
   811   "decseq X \<equiv> antimono X"
   813 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
   814   unfolding antimono_def ..
   816 definition
   817   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
   818     \<comment>\<open>Definition of subsequence\<close>
   819   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
   821 lemma incseq_SucI:
   822   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
   823   using lift_Suc_mono_le[of X]
   824   by (auto simp: incseq_def)
   826 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
   827   by (auto simp: incseq_def)
   829 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
   830   using incseqD[of A i "Suc i"] by auto
   832 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
   833   by (auto intro: incseq_SucI dest: incseq_SucD)
   835 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
   836   unfolding incseq_def by auto
   838 lemma decseq_SucI:
   839   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
   840   using order.lift_Suc_mono_le[OF dual_order, of X]
   841   by (auto simp: decseq_def)
   843 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
   844   by (auto simp: decseq_def)
   846 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
   847   using decseqD[of A i "Suc i"] by auto
   849 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
   850   by (auto intro: decseq_SucI dest: decseq_SucD)
   852 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
   853   unfolding decseq_def by auto
   855 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
   856   unfolding monoseq_def incseq_def decseq_def ..
   858 lemma monoseq_Suc:
   859   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
   860   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
   862 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   863 by (simp add: monoseq_def)
   865 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   866 by (simp add: monoseq_def)
   868 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   869 by (simp add: monoseq_Suc)
   871 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   872 by (simp add: monoseq_Suc)
   874 lemma monoseq_minus:
   875   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
   876   assumes "monoseq a"
   877   shows "monoseq (\<lambda> n. - a n)"
   878 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   879   case True
   880   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   881   thus ?thesis by (rule monoI2)
   882 next
   883   case False
   884   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using \<open>monoseq a\<close>[unfolded monoseq_def] by auto
   885   thus ?thesis by (rule monoI1)
   886 qed
   888 text\<open>Subsequence (alternative definition, (e.g. Hoskins)\<close>
   890 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   891 apply (simp add: subseq_def)
   892 apply (auto dest!: less_imp_Suc_add)
   893 apply (induct_tac k)
   894 apply (auto intro: less_trans)
   895 done
   897 text\<open>for any sequence, there is a monotonic subsequence\<close>
   898 lemma seq_monosub:
   899   fixes s :: "nat => 'a::linorder"
   900   shows "\<exists>f. subseq f \<and> monoseq (\<lambda>n. (s (f n)))"
   901 proof cases
   902   assume "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. s m \<le> s p"
   903   then have "\<exists>f. \<forall>n. (\<forall>m\<ge>f n. s m \<le> s (f n)) \<and> f n < f (Suc n)"
   904     by (intro dependent_nat_choice) (auto simp: conj_commute)
   905   then obtain f where "subseq f" and mono: "\<And>n m. f n \<le> m \<Longrightarrow> s m \<le> s (f n)"
   906     by (auto simp: subseq_Suc_iff)
   907   moreover 
   908   then have "incseq f"
   909     unfolding subseq_Suc_iff incseq_Suc_iff by (auto intro: less_imp_le)
   910   then have "monoseq (\<lambda>n. s (f n))"
   911     by (auto simp add: incseq_def intro!: mono monoI2)
   912   ultimately show ?thesis
   913     by auto
   914 next
   915   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
   916   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
   917   have "\<exists>f. \<forall>n. N < f n \<and> f n < f (Suc n) \<and> s (f n) \<le> s (f (Suc n))"
   918   proof (intro dependent_nat_choice)
   919     fix x assume "N < x" with N[of x] show "\<exists>y>N. x < y \<and> s x \<le> s y"
   920       by (auto intro: less_trans)
   921   qed auto
   922   then show ?thesis
   923     by (auto simp: monoseq_iff incseq_Suc_iff subseq_Suc_iff)
   924 qed
   926 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   927 proof(induct n)
   928   case 0 thus ?case by simp
   929 next
   930   case (Suc n)
   931   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   932   have "n < f (Suc n)" by arith
   933   thus ?case by arith
   934 qed
   936 lemma eventually_subseq:
   937   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
   938   unfolding eventually_sequentially by (metis seq_suble le_trans)
   940 lemma not_eventually_sequentiallyD:
   941   assumes P: "\<not> eventually P sequentially"
   942   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
   943 proof -
   944   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
   945     unfolding eventually_sequentially by (simp add: not_less)
   946   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
   947     by (auto simp: choice_iff)
   948   then show ?thesis
   949     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
   950              simp: less_eq_Suc_le subseq_Suc_iff)
   951 qed
   953 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
   954   unfolding filterlim_iff by (metis eventually_subseq)
   956 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
   957   unfolding subseq_def by simp
   959 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
   960   using assms by (auto simp: subseq_def)
   962 lemma subseq_imp_inj_on: "subseq g \<Longrightarrow> inj_on g A"
   963 proof (rule inj_onI)
   964   assume g: "subseq g"
   965   fix x y assume "g x = g y"
   966   with subseq_mono[OF g, of x y] subseq_mono[OF g, of y x] show "x = y" 
   967     by (cases x y rule: linorder_cases) simp_all
   968 qed
   970 lemma subseq_strict_mono: "subseq g \<Longrightarrow> strict_mono g"
   971   by (intro strict_monoI subseq_mono[of g])
   973 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   974   by (simp add: incseq_def monoseq_def)
   976 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   977   by (simp add: decseq_def monoseq_def)
   979 lemma decseq_eq_incseq:
   980   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
   981   by (simp add: decseq_def incseq_def)
   983 lemma INT_decseq_offset:
   984   assumes "decseq F"
   985   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
   986 proof safe
   987   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
   988   show "x \<in> F i"
   989   proof cases
   990     from x have "x \<in> F n" by auto
   991     also assume "i \<le> n" with \<open>decseq F\<close> have "F n \<subseteq> F i"
   992       unfolding decseq_def by simp
   993     finally show ?thesis .
   994   qed (insert x, simp)
   995 qed auto
   997 lemma LIMSEQ_const_iff:
   998   fixes k l :: "'a::t2_space"
   999   shows "(\<lambda>n. k) \<longlonglongrightarrow> l \<longleftrightarrow> k = l"
  1000   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1002 lemma LIMSEQ_SUP:
  1003   "incseq X \<Longrightarrow> X \<longlonglongrightarrow> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1004   by (intro increasing_tendsto)
  1005      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1007 lemma LIMSEQ_INF:
  1008   "decseq X \<Longrightarrow> X \<longlonglongrightarrow> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1009   by (intro decreasing_tendsto)
  1010      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1012 lemma LIMSEQ_ignore_initial_segment:
  1013   "f \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. f (n + k)) \<longlonglongrightarrow> a"
  1014   unfolding tendsto_def
  1015   by (subst eventually_sequentially_seg[where k=k])
  1017 lemma LIMSEQ_offset:
  1018   "(\<lambda>n. f (n + k)) \<longlonglongrightarrow> a \<Longrightarrow> f \<longlonglongrightarrow> a"
  1019   unfolding tendsto_def
  1020   by (subst (asm) eventually_sequentially_seg[where k=k])
  1022 lemma LIMSEQ_Suc: "f \<longlonglongrightarrow> l \<Longrightarrow> (\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l"
  1023 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1025 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l \<Longrightarrow> f \<longlonglongrightarrow> l"
  1026 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1028 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l = f \<longlonglongrightarrow> l"
  1029 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1031 lemma LIMSEQ_unique:
  1032   fixes a b :: "'a::t2_space"
  1033   shows "\<lbrakk>X \<longlonglongrightarrow> a; X \<longlonglongrightarrow> b\<rbrakk> \<Longrightarrow> a = b"
  1034   using trivial_limit_sequentially by (rule tendsto_unique)
  1036 lemma LIMSEQ_le_const:
  1037   "\<lbrakk>X \<longlonglongrightarrow> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1038   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1040 lemma LIMSEQ_le:
  1041   "\<lbrakk>X \<longlonglongrightarrow> x; Y \<longlonglongrightarrow> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1042   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1044 lemma LIMSEQ_le_const2:
  1045   "\<lbrakk>X \<longlonglongrightarrow> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1046   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) auto
  1048 lemma convergentD: "convergent X ==> \<exists>L. (X \<longlonglongrightarrow> L)"
  1049 by (simp add: convergent_def)
  1051 lemma convergentI: "(X \<longlonglongrightarrow> L) ==> convergent X"
  1052 by (auto simp add: convergent_def)
  1054 lemma convergent_LIMSEQ_iff: "convergent X = (X \<longlonglongrightarrow> lim X)"
  1055 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1057 lemma convergent_const: "convergent (\<lambda>n. c)"
  1058   by (rule convergentI, rule tendsto_const)
  1060 lemma monoseq_le:
  1061   "monoseq a \<Longrightarrow> a \<longlonglongrightarrow> (x::'a::linorder_topology) \<Longrightarrow>
  1062     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1063   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1065 lemma LIMSEQ_subseq_LIMSEQ:
  1066   "\<lbrakk> X \<longlonglongrightarrow> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) \<longlonglongrightarrow> L"
  1067   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1069 lemma convergent_subseq_convergent:
  1070   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1071   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1073 lemma limI: "X \<longlonglongrightarrow> L ==> lim X = L"
  1074   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1076 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1077   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1079 subsubsection\<open>Increasing and Decreasing Series\<close>
  1081 lemma incseq_le: "incseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1082   by (metis incseq_def LIMSEQ_le_const)
  1084 lemma decseq_le: "decseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1085   by (metis decseq_def LIMSEQ_le_const2)
  1087 subsection \<open>First countable topologies\<close>
  1089 class first_countable_topology = topological_space +
  1090   assumes first_countable_basis:
  1091     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1093 lemma (in first_countable_topology) countable_basis_at_decseq:
  1094   obtains A :: "nat \<Rightarrow> 'a set" where
  1095     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1096     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1097 proof atomize_elim
  1098   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1099     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1100     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1101   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1102   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1103       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1104   proof (safe intro!: exI[of _ F])
  1105     fix i
  1106     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1107     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1108   next
  1109     fix S assume "open S" "x \<in> S"
  1110     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1111     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1112       by (auto simp: F_def)
  1113     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1114       by (auto simp: eventually_sequentially)
  1115   qed
  1116 qed
  1118 lemma (in first_countable_topology) nhds_countable:
  1119   obtains X :: "nat \<Rightarrow> 'a set"
  1120   where "decseq X" "\<And>n. open (X n)" "\<And>n. x \<in> X n" "nhds x = (INF n. principal (X n))"
  1121 proof -
  1122   from first_countable_basis obtain A :: "nat \<Rightarrow> 'a set"
  1123     where A: "\<And>n. x \<in> A n" "\<And>n. open (A n)" "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1124     by metis
  1125   show thesis
  1126   proof
  1127     show "decseq (\<lambda>n. \<Inter>i\<le>n. A i)"
  1128       by (auto simp: decseq_def)
  1129     show "\<And>n. x \<in> (\<Inter>i\<le>n. A i)" "\<And>n. open (\<Inter>i\<le>n. A i)"
  1130       using A by auto
  1131     show "nhds x = (INF n. principal (\<Inter>i\<le>n. A i))"
  1132       using A unfolding nhds_def
  1133       apply (intro INF_eq)
  1134       apply simp_all
  1135       apply force
  1136       apply (intro exI[of _ "\<Inter>i\<le>n. A i" for n] conjI open_INT)
  1137       apply auto
  1138       done
  1139   qed
  1140 qed
  1142 lemma (in first_countable_topology) countable_basis:
  1143   obtains A :: "nat \<Rightarrow> 'a set" where
  1144     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1145     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F \<longlonglongrightarrow> x"
  1146 proof atomize_elim
  1147   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1148     "\<And>i. open (A i)"
  1149     "\<And>i. x \<in> A i"
  1150     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1151     by (rule countable_basis_at_decseq) blast
  1152   {
  1153     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1154     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1155       by (auto elim: eventually_mono simp: subset_eq)
  1156   }
  1157   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F \<longlonglongrightarrow> x)"
  1158     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1159 qed
  1161 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1162   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1163   shows "eventually P (inf (nhds a) (principal s))"
  1164 proof (rule ccontr)
  1165   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1166     "\<And>i. open (A i)"
  1167     "\<And>i. a \<in> A i"
  1168     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F \<longlonglongrightarrow> a"
  1169     by (rule countable_basis) blast
  1170   assume "\<not> ?thesis"
  1171   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1172     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1173   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1174     by blast
  1175   with A have "F \<longlonglongrightarrow> a" by auto
  1176   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1177     using assms F0 by simp
  1178   thus "False" by (simp add: F3)
  1179 qed
  1181 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1182   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1183     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1184 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1185   assume "eventually P (inf (nhds a) (principal s))" 
  1186   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1187     by (auto simp: eventually_inf_principal eventually_nhds)
  1188   moreover fix f assume "\<forall>n. f n \<in> s" "f \<longlonglongrightarrow> a"
  1189   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1190     by (auto dest!: topological_tendstoD elim: eventually_mono)
  1191 qed
  1193 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1194   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1195   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1197 lemma tendsto_at_iff_sequentially:
  1198   fixes f :: "'a :: first_countable_topology \<Rightarrow> _"
  1199   shows "(f \<longlongrightarrow> a) (at x within s) \<longleftrightarrow> (\<forall>X. (\<forall>i. X i \<in> s - {x}) \<longrightarrow> X \<longlonglongrightarrow> x \<longrightarrow> ((f \<circ> X) \<longlonglongrightarrow> a))"
  1200   unfolding filterlim_def[of _ "nhds a"] le_filter_def eventually_filtermap at_within_def eventually_nhds_within_iff_sequentially comp_def
  1201   by metis
  1203 subsection \<open>Function limit at a point\<close>
  1205 abbreviation
  1206   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1207         ("((_)/ \<midarrow>(_)/\<rightarrow> (_))" [60, 0, 60] 60) where
  1208   "f \<midarrow>a\<rightarrow> L \<equiv> (f \<longlongrightarrow> L) (at a)"
  1210 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f \<longlongrightarrow> l) (at a within S) \<longleftrightarrow> (f \<midarrow>a\<rightarrow> l)"
  1211   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1213 lemma LIM_const_not_eq[tendsto_intros]:
  1214   fixes a :: "'a::perfect_space"
  1215   fixes k L :: "'b::t2_space"
  1216   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) \<midarrow>a\<rightarrow> L"
  1217   by (simp add: tendsto_const_iff)
  1219 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1221 lemma LIM_const_eq:
  1222   fixes a :: "'a::perfect_space"
  1223   fixes k L :: "'b::t2_space"
  1224   shows "(\<lambda>x. k) \<midarrow>a\<rightarrow> L \<Longrightarrow> k = L"
  1225   by (simp add: tendsto_const_iff)
  1227 lemma LIM_unique:
  1228   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1229   shows "f \<midarrow>a\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> M \<Longrightarrow> L = M"
  1230   using at_neq_bot by (rule tendsto_unique)
  1232 text \<open>Limits are equal for functions equal except at limit point\<close>
  1234 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>a\<rightarrow> l)"
  1235   unfolding tendsto_def eventually_at_topological by simp
  1237 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>b\<rightarrow> m)"
  1238   by (simp add: LIM_equal)
  1240 lemma LIM_cong_limit: "f \<midarrow>x\<rightarrow> L \<Longrightarrow> K = L \<Longrightarrow> f \<midarrow>x\<rightarrow> K"
  1241   by simp
  1243 lemma tendsto_at_iff_tendsto_nhds:
  1244   "g \<midarrow>l\<rightarrow> g l \<longleftrightarrow> (g \<longlongrightarrow> g l) (nhds l)"
  1245   unfolding tendsto_def eventually_at_filter
  1246   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
  1248 lemma tendsto_compose:
  1249   "g \<midarrow>l\<rightarrow> g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  1250   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1252 lemma LIM_o: "\<lbrakk>g \<midarrow>l\<rightarrow> g l; f \<midarrow>a\<rightarrow> l\<rbrakk> \<Longrightarrow> (g \<circ> f) \<midarrow>a\<rightarrow> g l"
  1253   unfolding o_def by (rule tendsto_compose)
  1255 lemma tendsto_compose_eventually:
  1256   "g \<midarrow>l\<rightarrow> m \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> m) F"
  1257   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1259 lemma LIM_compose_eventually:
  1260   assumes f: "f \<midarrow>a\<rightarrow> b"
  1261   assumes g: "g \<midarrow>b\<rightarrow> c"
  1262   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1263   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  1264   using g f inj by (rule tendsto_compose_eventually)
  1266 lemma tendsto_compose_filtermap: "((g \<circ> f) \<longlongrightarrow> T) F \<longleftrightarrow> (g \<longlongrightarrow> T) (filtermap f F)"
  1267   by (simp add: filterlim_def filtermap_filtermap comp_def)
  1269 subsubsection \<open>Relation of LIM and LIMSEQ\<close>
  1271 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1272   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1273     eventually P (at a within s)"
  1274   unfolding at_within_def
  1275   by (intro sequentially_imp_eventually_nhds_within) auto
  1277 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1278   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1279   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1281 lemma LIMSEQ_SEQ_conv1:
  1282   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1283   assumes f: "f \<midarrow>a\<rightarrow> l"
  1284   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1285   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1287 lemma LIMSEQ_SEQ_conv2:
  1288   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1289   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1290   shows "f \<midarrow>a\<rightarrow> l"
  1291   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1293 lemma LIMSEQ_SEQ_conv:
  1294   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L) =
  1295    (X \<midarrow>a\<rightarrow> (L::'b::topological_space))"
  1296   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1298 lemma sequentially_imp_eventually_at_left:
  1299   fixes a :: "'a :: {linorder_topology, first_countable_topology}"
  1300   assumes b[simp]: "b < a"
  1301   assumes *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1302   shows "eventually P (at_left a)"
  1303 proof (safe intro!: sequentially_imp_eventually_within)
  1304   fix X assume X: "\<forall>n. X n \<in> {..< a} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1305   show "eventually (\<lambda>n. P (X n)) sequentially"
  1306   proof (rule ccontr)
  1307     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1308     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> b < X (s n)) \<and> (X (s n) \<le> X (s (Suc n)) \<and> Suc (s n) \<le> s (Suc n))"
  1309     proof (rule dependent_nat_choice)
  1310       have "\<not> eventually (\<lambda>n. b < X n \<longrightarrow> P (X n)) sequentially"
  1311         by (intro not_eventually_impI neg order_tendstoD(1) [OF X(2) b])
  1312       then show "\<exists>x. \<not> P (X x) \<and> b < X x"
  1313         by (auto dest!: not_eventuallyD)
  1314     next
  1315       fix x n
  1316       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> b < X n \<longrightarrow> X x < X n \<longrightarrow> P (X n)) sequentially"
  1317         using X by (intro not_eventually_impI order_tendstoD(1)[OF X(2)] eventually_ge_at_top neg) auto
  1318       then show "\<exists>n. (\<not> P (X n) \<and> b < X n) \<and> (X x \<le> X n \<and> Suc x \<le> n)"
  1319         by (auto dest!: not_eventuallyD)
  1320     qed
  1321     then guess s ..
  1322     then have "\<And>n. b < X (s n)" "\<And>n. X (s n) < a" "incseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a" "\<And>n. \<not> P (X (s n))"
  1323       using X by (auto simp: subseq_Suc_iff Suc_le_eq incseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1324     from *[OF this(1,2,3,4)] this(5) show False by auto
  1325   qed
  1326 qed
  1328 lemma tendsto_at_left_sequentially:
  1329   fixes a :: "_ :: {linorder_topology, first_countable_topology}"
  1330   assumes "b < a"
  1331   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1332   shows "(X \<longlongrightarrow> L) (at_left a)"
  1333   using assms unfolding tendsto_def [where l=L]
  1334   by (simp add: sequentially_imp_eventually_at_left)
  1336 lemma sequentially_imp_eventually_at_right:
  1337   fixes a :: "'a :: {linorder_topology, first_countable_topology}"
  1338   assumes b[simp]: "a < b"
  1339   assumes *: "\<And>f. (\<And>n. a < f n) \<Longrightarrow> (\<And>n. f n < b) \<Longrightarrow> decseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1340   shows "eventually P (at_right a)"
  1341 proof (safe intro!: sequentially_imp_eventually_within)
  1342   fix X assume X: "\<forall>n. X n \<in> {a <..} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1343   show "eventually (\<lambda>n. P (X n)) sequentially"
  1344   proof (rule ccontr)
  1345     assume neg: "\<not> eventually (\<lambda>n. P (X n)) sequentially"
  1346     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> X (s n) < b) \<and> (X (s (Suc n)) \<le> X (s n) \<and> Suc (s n) \<le> s (Suc n))"
  1347     proof (rule dependent_nat_choice)
  1348       have "\<not> eventually (\<lambda>n. X n < b \<longrightarrow> P (X n)) sequentially"
  1349         by (intro not_eventually_impI neg order_tendstoD(2) [OF X(2) b])
  1350       then show "\<exists>x. \<not> P (X x) \<and> X x < b"
  1351         by (auto dest!: not_eventuallyD)
  1352     next
  1353       fix x n
  1354       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> X n < b \<longrightarrow> X n < X x \<longrightarrow> P (X n)) sequentially"
  1355         using X by (intro not_eventually_impI order_tendstoD(2)[OF X(2)] eventually_ge_at_top neg) auto
  1356       then show "\<exists>n. (\<not> P (X n) \<and> X n < b) \<and> (X n \<le> X x \<and> Suc x \<le> n)"
  1357         by (auto dest!: not_eventuallyD)
  1358     qed
  1359     then guess s ..
  1360     then have "\<And>n. a < X (s n)" "\<And>n. X (s n) < b" "decseq (\<lambda>n. X (s n))" "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a" "\<And>n. \<not> P (X (s n))"
  1361       using X by (auto simp: subseq_Suc_iff Suc_le_eq decseq_Suc_iff intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1362     from *[OF this(1,2,3,4)] this(5) show False by auto
  1363   qed
  1364 qed
  1366 lemma tendsto_at_right_sequentially:
  1367   fixes a :: "_ :: {linorder_topology, first_countable_topology}"
  1368   assumes "a < b"
  1369   assumes *: "\<And>S. (\<And>n. a < S n) \<Longrightarrow> (\<And>n. S n < b) \<Longrightarrow> decseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1370   shows "(X \<longlongrightarrow> L) (at_right a)"
  1371   using assms unfolding tendsto_def [where l=L]
  1372   by (simp add: sequentially_imp_eventually_at_right)
  1374 subsection \<open>Continuity\<close>
  1376 subsubsection \<open>Continuity on a set\<close>
  1378 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1379   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f \<longlongrightarrow> f x) (at x within s))"
  1381 lemma continuous_on_cong [cong]:
  1382   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1383   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1385 lemma continuous_on_topological:
  1386   "continuous_on s f \<longleftrightarrow>
  1387     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1388   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1390 lemma continuous_on_open_invariant:
  1391   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1392 proof safe
  1393   fix B :: "'b set" assume "continuous_on s f" "open B"
  1394   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1395     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1396   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1397     unfolding bchoice_iff ..
  1398   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1399     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1400 next
  1401   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1402   show "continuous_on s f"
  1403     unfolding continuous_on_topological
  1404   proof safe
  1405     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1406     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1407     with \<open>x \<in> s\<close> \<open>f x \<in> B\<close> show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1408       by (intro exI[of _ A]) auto
  1409   qed
  1410 qed
  1412 lemma continuous_on_open_vimage:
  1413   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1414   unfolding continuous_on_open_invariant
  1415   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1417 corollary continuous_imp_open_vimage:
  1418   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  1419     shows "open (f -` B)"
  1420 by (metis assms continuous_on_open_vimage le_iff_inf)
  1422 corollary open_vimage[continuous_intros]:
  1423   assumes "open s" and "continuous_on UNIV f"
  1424   shows "open (f -` s)"
  1425   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  1426   by simp
  1428 lemma continuous_on_closed_invariant:
  1429   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1430 proof -
  1431   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1432     by (metis double_compl)
  1433   show ?thesis
  1434     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1435 qed
  1437 lemma continuous_on_closed_vimage:
  1438   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1439   unfolding continuous_on_closed_invariant
  1440   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1442 corollary closed_vimage_Int[continuous_intros]:
  1443   assumes "closed s" and "continuous_on t f" and t: "closed t"
  1444   shows "closed (f -` s \<inter> t)"
  1445   using assms unfolding continuous_on_closed_vimage [OF t]  by simp
  1447 corollary closed_vimage[continuous_intros]:
  1448   assumes "closed s" and "continuous_on UNIV f"
  1449   shows "closed (f -` s)"
  1450   using closed_vimage_Int [OF assms] by simp
  1452 lemma continuous_on_empty: "continuous_on {} f"
  1453   by (simp add: continuous_on_def)
  1455 lemma continuous_on_sing: "continuous_on {x} f"
  1456   by (simp add: continuous_on_def at_within_def)
  1458 lemma continuous_on_open_Union:
  1459   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1460   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1462 lemma continuous_on_open_UN:
  1463   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1464   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  1466 lemma continuous_on_open_Un:
  1467   "open s \<Longrightarrow> open t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1468   using continuous_on_open_Union [of "{s,t}"] by auto
  1470 lemma continuous_on_closed_Un:
  1471   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1472   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1474 lemma continuous_on_If:
  1475   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1476     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1477   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1478 proof-
  1479   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1480     by auto
  1481   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1482     by simp_all
  1483   with closed show ?thesis
  1484     by (rule continuous_on_closed_Un)
  1485 qed
  1487 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  1488   unfolding continuous_on_def by fast
  1490 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  1491   unfolding continuous_on_def by auto
  1493 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1494   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1496 lemma continuous_on_compose[continuous_intros]:
  1497   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1498   unfolding continuous_on_topological by simp metis
  1500 lemma continuous_on_compose2:
  1501   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1502   using continuous_on_compose[of s f g] continuous_on_subset by (force simp add: comp_def)
  1504 lemma continuous_on_generate_topology:
  1505   assumes *: "open = generate_topology X"
  1506   assumes **: "\<And>B. B \<in> X \<Longrightarrow> \<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1507   shows "continuous_on A f"
  1508   unfolding continuous_on_open_invariant
  1509 proof safe
  1510   fix B :: "'a set" assume "open B" then show "\<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1511     unfolding *
  1512   proof induction
  1513     case (UN K)
  1514     then obtain C where "\<And>k. k \<in> K \<Longrightarrow> open (C k)" "\<And>k. k \<in> K \<Longrightarrow> C k \<inter> A = f -` k \<inter> A"
  1515       by metis
  1516     then show ?case
  1517       by (intro exI[of _ "\<Union>k\<in>K. C k"]) blast
  1518   qed (auto intro: **)
  1519 qed
  1521 lemma continuous_onI_mono:
  1522   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::{dense_order, linorder_topology}"
  1523   assumes "open (f`A)"
  1524   assumes mono: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1525   shows "continuous_on A f"
  1526 proof (rule continuous_on_generate_topology[OF open_generated_order], safe)
  1527   have monoD: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> f x < f y \<Longrightarrow> x < y"
  1528     by (auto simp: not_le[symmetric] mono)
  1530   { fix a b assume "a \<in> A" "f a < b"
  1531     moreover
  1532     with open_right[OF \<open>open (f`A)\<close>, of "f a" b] obtain y where "f a < y" "{f a ..< y} \<subseteq> f`A"
  1533       by auto
  1534     moreover then obtain z where "f a < z" "z < min b y"
  1535       using dense[of "f a" "min b y"] \<open>f a < y\<close> \<open>f a < b\<close> by auto
  1536     moreover then obtain c where "z = f c" "c \<in> A"
  1537       using \<open>{f a ..< y} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1538     ultimately have "\<exists>x. x \<in> A \<and> f x < b \<and> a < x"
  1539       by (auto intro!: exI[of _ c] simp: monoD) }
  1540   then show "\<exists>C. open C \<and> C \<inter> A = f -` {..<b} \<inter> A" for b
  1541     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. f x < b}. {..< x})"])
  1542        (auto intro: le_less_trans[OF mono] less_imp_le)
  1544   { fix a b assume "a \<in> A" "b < f a"
  1545     moreover
  1546     with open_left[OF \<open>open (f`A)\<close>, of "f a" b] obtain y where "y < f a" "{y <.. f a} \<subseteq> f`A"
  1547       by auto
  1548     moreover then obtain z where "max b y < z" "z < f a"
  1549       using dense[of "max b y" "f a"] \<open>y < f a\<close> \<open>b < f a\<close> by auto
  1550     moreover then obtain c where "z = f c" "c \<in> A"
  1551       using \<open>{y <.. f a} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1552     ultimately have "\<exists>x. x \<in> A \<and> b < f x \<and> x < a"
  1553       by (auto intro!: exI[of _ c] simp: monoD) }
  1554   then show "\<exists>C. open C \<and> C \<inter> A = f -` {b <..} \<inter> A" for b
  1555     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. b < f x}. {x <..})"])
  1556        (auto intro: less_le_trans[OF _ mono] less_imp_le)
  1557 qed
  1559 subsubsection \<open>Continuity at a point\<close>
  1561 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1562   "continuous F f \<longleftrightarrow> (f \<longlongrightarrow> f (Lim F (\<lambda>x. x))) F"
  1564 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1565   unfolding continuous_def by auto
  1567 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1568   by simp
  1570 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f \<longlongrightarrow> f x) (at x within s)"
  1571   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1573 lemma continuous_within_topological:
  1574   "continuous (at x within s) f \<longleftrightarrow>
  1575     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1576   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1578 lemma continuous_within_compose[continuous_intros]:
  1579   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1580   continuous (at x within s) (g o f)"
  1581   by (simp add: continuous_within_topological) metis
  1583 lemma continuous_within_compose2:
  1584   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1585   continuous (at x within s) (\<lambda>x. g (f x))"
  1586   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1588 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f \<midarrow>x\<rightarrow> f x"
  1589   using continuous_within[of x UNIV f] by simp
  1591 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1592   unfolding continuous_within by (rule tendsto_ident_at)
  1594 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1595   unfolding continuous_def by (rule tendsto_const)
  1597 lemma continuous_on_eq_continuous_within:
  1598   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1599   unfolding continuous_on_def continuous_within ..
  1601 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  1602   "isCont f a \<equiv> continuous (at a) f"
  1604 lemma isCont_def: "isCont f a \<longleftrightarrow> f \<midarrow>a\<rightarrow> f a"
  1605   by (rule continuous_at)
  1607 lemma continuous_at_imp_continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1608   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1610 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1611   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1613 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1614   by (auto intro: continuous_at_imp_continuous_at_within simp: continuous_on_eq_continuous_within)
  1616 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1617   unfolding isCont_def by (rule tendsto_compose)
  1619 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1620   unfolding o_def by (rule isCont_o2)
  1622 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  1623   unfolding isCont_def by (rule tendsto_compose)
  1625 lemma continuous_on_tendsto_compose:
  1626   assumes f_cont: "continuous_on s f"
  1627   assumes g: "(g \<longlongrightarrow> l) F"
  1628   assumes l: "l \<in> s"
  1629   assumes ev: "\<forall>\<^sub>F x in F. g x \<in> s"
  1630   shows "((\<lambda>x. f (g x)) \<longlongrightarrow> f l) F"
  1631 proof -
  1632   from f_cont l have f: "(f \<longlongrightarrow> f l) (at l within s)"
  1633     by (simp add: continuous_on_def)
  1634   have i: "((\<lambda>x. if g x = l then f l else f (g x)) \<longlongrightarrow> f l) F"
  1635     by (rule filterlim_If)
  1636        (auto intro!: filterlim_compose[OF f] eventually_conj tendsto_mono[OF _ g]
  1637              simp: filterlim_at eventually_inf_principal eventually_mono[OF ev])
  1638   show ?thesis
  1639     by (rule filterlim_cong[THEN iffD1[OF _ i]]) auto
  1640 qed
  1642 lemma continuous_within_compose3:
  1643   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1644   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_imp_continuous_at_within)
  1646 lemma filtermap_nhds_open_map:
  1647   assumes cont: "isCont f a" and open_map: "\<And>S. open S \<Longrightarrow> open (f`S)"
  1648   shows "filtermap f (nhds a) = nhds (f a)"
  1649   unfolding filter_eq_iff
  1650 proof safe
  1651   fix P assume "eventually P (filtermap f (nhds a))"
  1652   then guess S unfolding eventually_filtermap eventually_nhds ..
  1653   then show "eventually P (nhds (f a))"
  1654     unfolding eventually_nhds by (intro exI[of _ "f`S"]) (auto intro!: open_map)
  1655 qed (metis filterlim_iff tendsto_at_iff_tendsto_nhds isCont_def eventually_filtermap cont)
  1657 lemma continuous_at_split: 
  1658   "continuous (at (x::'a::linorder_topology)) f = (continuous (at_left x) f \<and> continuous (at_right x) f)"
  1659   by (simp add: continuous_within filterlim_at_split)
  1661 subsubsection \<open>Open-cover compactness\<close>
  1663 context topological_space
  1664 begin
  1666 definition compact :: "'a set \<Rightarrow> bool" where
  1667   compact_eq_heine_borel: \<comment> "This name is used for backwards compatibility"
  1668     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  1670 lemma compactI:
  1671   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union>C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union>C'"
  1672   shows "compact s"
  1673   unfolding compact_eq_heine_borel using assms by metis
  1675 lemma compact_empty[simp]: "compact {}"
  1676   by (auto intro!: compactI)
  1678 lemma compactE:
  1679   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  1680   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  1681   using assms unfolding compact_eq_heine_borel by metis
  1683 lemma compactE_image:
  1684   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  1685   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  1686   using assms unfolding ball_simps[symmetric] SUP_def
  1687   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  1689 lemma compact_inter_closed [intro]:
  1690   assumes "compact s" and "closed t"
  1691   shows "compact (s \<inter> t)"
  1692 proof (rule compactI)
  1693   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  1694   from C \<open>closed t\<close> have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  1695   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  1696   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  1697     using \<open>compact s\<close> unfolding compact_eq_heine_borel by auto
  1698   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  1699   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  1700     by (intro exI[of _ "D - {-t}"]) auto
  1701 qed
  1703 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  1704   by (auto simp: inj_on_def)
  1706 lemma compact_fip:
  1707   "compact U \<longleftrightarrow>
  1708     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  1709   (is "_ \<longleftrightarrow> ?R")
  1710 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  1711   fix A
  1712   assume "compact U"
  1713     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  1714     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  1715   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  1716     by auto
  1717   with \<open>compact U\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  1718     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  1719   with fi[THEN spec, of B] show False
  1720     by (auto dest: finite_imageD intro: inj_setminus)
  1721 next
  1722   fix A
  1723   assume ?R
  1724   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  1725   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  1726     by auto
  1727   with \<open>?R\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  1728     by (metis subset_image_iff)
  1729   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  1730     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  1731 qed
  1733 lemma compact_imp_fip:
  1734   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter>f') \<noteq> {}) \<Longrightarrow>
  1735     s \<inter> (\<Inter>f) \<noteq> {}"
  1736   unfolding compact_fip by auto
  1738 lemma compact_imp_fip_image:
  1739   assumes "compact s"
  1740     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  1741     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  1742   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  1743 proof -
  1744   note \<open>compact s\<close>
  1745   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  1746   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  1747   proof (rule, rule, erule conjE)
  1748     fix A :: "'a set set"
  1749     assume "finite A"
  1750     moreover assume "A \<subseteq> f ` I"
  1751     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  1752       using finite_subset_image [of A f I] by blast
  1753     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  1754   qed
  1755   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (rule compact_imp_fip)
  1756   then show ?thesis by simp
  1757 qed
  1759 end
  1761 lemma (in t2_space) compact_imp_closed:
  1762   assumes "compact s" shows "closed s"
  1763 unfolding closed_def
  1764 proof (rule openI)
  1765   fix y assume "y \<in> - s"
  1766   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  1767   note \<open>compact s\<close>
  1768   moreover have "\<forall>u\<in>?C. open u" by simp
  1769   moreover have "s \<subseteq> \<Union>?C"
  1770   proof
  1771     fix x assume "x \<in> s"
  1772     with \<open>y \<in> - s\<close> have "x \<noteq> y" by clarsimp
  1773     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  1774       by (rule hausdorff)
  1775     with \<open>x \<in> s\<close> show "x \<in> \<Union>?C"
  1776       unfolding eventually_nhds by auto
  1777   qed
  1778   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  1779     by (rule compactE)
  1780   from \<open>D \<subseteq> ?C\<close> have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  1781   with \<open>finite D\<close> have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  1782     by (simp add: eventually_ball_finite)
  1783   with \<open>s \<subseteq> \<Union>D\<close> have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  1784     by (auto elim!: eventually_mono)
  1785   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  1786     by (simp add: eventually_nhds subset_eq)
  1787 qed
  1789 lemma compact_continuous_image:
  1790   assumes f: "continuous_on s f" and s: "compact s"
  1791   shows "compact (f ` s)"
  1792 proof (rule compactI)
  1793   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  1794   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  1795     unfolding continuous_on_open_invariant by blast
  1796   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  1797     unfolding bchoice_iff ..
  1798   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  1799     by (fastforce simp add: subset_eq set_eq_iff)+
  1800   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  1801   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  1802     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  1803 qed
  1805 lemma continuous_on_inv:
  1806   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1807   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  1808   shows "continuous_on (f ` s) g"
  1809 unfolding continuous_on_topological
  1810 proof (clarsimp simp add: assms(3))
  1811   fix x :: 'a and B :: "'a set"
  1812   assume "x \<in> s" and "open B" and "x \<in> B"
  1813   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  1814     using assms(3) by (auto, metis)
  1815   have "continuous_on (s - B) f"
  1816     using \<open>continuous_on s f\<close> Diff_subset
  1817     by (rule continuous_on_subset)
  1818   moreover have "compact (s - B)"
  1819     using \<open>open B\<close> and \<open>compact s\<close>
  1820     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  1821   ultimately have "compact (f ` (s - B))"
  1822     by (rule compact_continuous_image)
  1823   hence "closed (f ` (s - B))"
  1824     by (rule compact_imp_closed)
  1825   hence "open (- f ` (s - B))"
  1826     by (rule open_Compl)
  1827   moreover have "f x \<in> - f ` (s - B)"
  1828     using \<open>x \<in> s\<close> and \<open>x \<in> B\<close> by (simp add: 1)
  1829   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  1830     by (simp add: 1)
  1831   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  1832     by fast
  1833 qed
  1835 lemma continuous_on_inv_into:
  1836   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1837   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  1838   shows "continuous_on (f ` s) (the_inv_into s f)"
  1839   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  1841 lemma (in linorder_topology) compact_attains_sup:
  1842   assumes "compact S" "S \<noteq> {}"
  1843   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  1844 proof (rule classical)
  1845   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  1846   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  1847     by (metis not_le)
  1848   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  1849     by auto
  1850   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  1851     by (erule compactE_image)
  1852   with \<open>S \<noteq> {}\<close> have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  1853     by (auto intro!: Max_in)
  1854   with C have "S \<subseteq> {..< Max (t`C)}"
  1855     by (auto intro: less_le_trans simp: subset_eq)
  1856   with t Max \<open>C \<subseteq> S\<close> show ?thesis
  1857     by fastforce
  1858 qed
  1860 lemma (in linorder_topology) compact_attains_inf:
  1861   assumes "compact S" "S \<noteq> {}"
  1862   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  1863 proof (rule classical)
  1864   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  1865   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  1866     by (metis not_le)
  1867   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  1868     by auto
  1869   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  1870     by (erule compactE_image)
  1871   with \<open>S \<noteq> {}\<close> have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  1872     by (auto intro!: Min_in)
  1873   with C have "S \<subseteq> {Min (t`C) <..}"
  1874     by (auto intro: le_less_trans simp: subset_eq)
  1875   with t Min \<open>C \<subseteq> S\<close> show ?thesis
  1876     by fastforce
  1877 qed
  1879 lemma continuous_attains_sup:
  1880   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  1881   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  1882   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  1884 lemma continuous_attains_inf:
  1885   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  1886   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  1887   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  1889 subsection \<open>Connectedness\<close>
  1891 context topological_space
  1892 begin
  1894 definition "connected S \<longleftrightarrow>
  1895   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  1897 lemma connectedI:
  1898   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  1899   \<Longrightarrow> connected U"
  1900   by (auto simp: connected_def)
  1902 lemma connected_empty [simp]: "connected {}"
  1903   by (auto intro!: connectedI)
  1905 lemma connected_sing [simp]: "connected {x}"
  1906   by (auto intro!: connectedI)
  1908 lemma connectedD:
  1909   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}" 
  1910   by (auto simp: connected_def)
  1912 end
  1914 lemma connected_closed:
  1915     "connected s \<longleftrightarrow>
  1916      ~ (\<exists>A B. closed A \<and> closed B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {})"
  1917 apply (simp add: connected_def del: ex_simps, safe)
  1918 apply (drule_tac x="-A" in spec)
  1919 apply (drule_tac x="-B" in spec)
  1920 apply (fastforce simp add: closed_def [symmetric])
  1921 apply (drule_tac x="-A" in spec)
  1922 apply (drule_tac x="-B" in spec)
  1923 apply (fastforce simp add: open_closed [symmetric])
  1924 done
  1927 lemma connected_Union:
  1928   assumes cs: "\<And>s. s \<in> S \<Longrightarrow> connected s" and ne: "\<Inter>S \<noteq> {}"
  1929     shows "connected(\<Union>S)"
  1930 proof (rule connectedI)
  1931   fix A B
  1932   assume A: "open A" and B: "open B" and Alap: "A \<inter> \<Union>S \<noteq> {}" and Blap: "B \<inter> \<Union>S \<noteq> {}"
  1933      and disj: "A \<inter> B \<inter> \<Union>S = {}" and cover: "\<Union>S \<subseteq> A \<union> B"
  1934   have disjs:"\<And>s. s \<in> S \<Longrightarrow> A \<inter> B \<inter> s = {}"
  1935     using disj by auto
  1936   obtain sa where sa: "sa \<in> S" "A \<inter> sa \<noteq> {}"
  1937     using Alap by auto
  1938   obtain sb where sb: "sb \<in> S" "B \<inter> sb \<noteq> {}"
  1939     using Blap by auto
  1940   obtain x where x: "\<And>s. s \<in> S \<Longrightarrow> x \<in> s"
  1941     using ne by auto
  1942   then have "x \<in> \<Union>S"
  1943     using \<open>sa \<in> S\<close> by blast
  1944   then have "x \<in> A \<or> x \<in> B"
  1945     using cover by auto
  1946   then show False
  1947     using cs [unfolded connected_def]
  1948     by (metis A B IntI Sup_upper sa sb disjs x cover empty_iff subset_trans)
  1949 qed
  1951 lemma connected_Un: "\<lbrakk>connected s; connected t; s \<inter> t \<noteq> {}\<rbrakk> \<Longrightarrow> connected (s \<union> t)"
  1952   using connected_Union [of "{s,t}"] by auto
  1954 lemma connected_diff_open_from_closed:
  1955   assumes st: "s \<subseteq> t" and tu: "t \<subseteq> u" and s: "open s"
  1956       and t: "closed t" and u: "connected u" and ts: "connected (t - s)"
  1957   shows "connected(u - s)"
  1958 proof (rule connectedI)
  1959   fix A B
  1960   assume AB: "open A" "open B" "A \<inter> (u - s) \<noteq> {}" "B \<inter> (u - s) \<noteq> {}"
  1961      and disj: "A \<inter> B \<inter> (u - s) = {}" and cover: "u - s \<subseteq> A \<union> B"
  1962   then consider "A \<inter> (t - s) = {}" | "B \<inter> (t - s) = {}"
  1963     using st ts tu connectedD [of "t-s" "A" "B"]
  1964     by auto
  1965   then show False
  1966   proof cases
  1967     case 1
  1968     then have "(A - t) \<inter> (B \<union> s) \<inter> u = {}"
  1969       using disj st by auto
  1970     moreover have  "u \<subseteq> (A - t) \<union> (B \<union> s)" using 1 cover by auto
  1971     ultimately show False
  1972       using connectedD [of u "A - t" "B \<union> s"] AB s t 1 u
  1973       by auto
  1974   next
  1975     case 2
  1976     then have "(A \<union> s) \<inter> (B - t) \<inter> u = {}"
  1977       using disj st
  1978       by auto
  1979     moreover have "u \<subseteq> (A \<union> s) \<union> (B - t)" using 2 cover by auto
  1980     ultimately show False
  1981       using connectedD [of u "A \<union> s" "B - t"] AB s t 2 u
  1982       by auto
  1983   qed
  1984 qed
  1986 lemma connected_iff_const:
  1987   fixes S :: "'a::topological_space set"
  1988   shows "connected S \<longleftrightarrow> (\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c))"
  1989 proof safe
  1990   fix P :: "'a \<Rightarrow> bool" assume "connected S" "continuous_on S P"
  1991   then have "\<And>b. \<exists>A. open A \<and> A \<inter> S = P -` {b} \<inter> S"
  1992     unfolding continuous_on_open_invariant by simp
  1993   from this[of True] this[of False]
  1994   obtain t f where "open t" "open f" and *: "f \<inter> S = P -` {False} \<inter> S" "t \<inter> S = P -` {True} \<inter> S"
  1995     by auto
  1996   then have "t \<inter> S = {} \<or> f \<inter> S = {}"
  1997     by (intro connectedD[OF \<open>connected S\<close>])  auto
  1998   then show "\<exists>c. \<forall>s\<in>S. P s = c"
  1999   proof (rule disjE)
  2000     assume "t \<inter> S = {}" then show ?thesis
  2001       unfolding * by (intro exI[of _ False]) auto
  2002   next
  2003     assume "f \<inter> S = {}" then show ?thesis
  2004       unfolding * by (intro exI[of _ True]) auto
  2005   qed
  2006 next
  2007   assume P: "\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c)"
  2008   show "connected S"
  2009   proof (rule connectedI)
  2010     fix A B assume *: "open A" "open B" "A \<inter> S \<noteq> {}" "B \<inter> S \<noteq> {}" "A \<inter> B \<inter> S = {}" "S \<subseteq> A \<union> B"
  2011     have "continuous_on S (\<lambda>x. x \<in> A)"
  2012       unfolding continuous_on_open_invariant
  2013     proof safe
  2014       fix C :: "bool set"
  2015       have "C = UNIV \<or> C = {True} \<or> C = {False} \<or> C = {}"
  2016         using subset_UNIV[of C] unfolding UNIV_bool by auto
  2017       with * show "\<exists>T. open T \<and> T \<inter> S = (\<lambda>x. x \<in> A) -` C \<inter> S"
  2018         by (intro exI[of _ "(if True \<in> C then A else {}) \<union> (if False \<in> C then B else {})"]) auto
  2019     qed
  2020     from P[rule_format, OF this] obtain c where "\<And>s. s \<in> S \<Longrightarrow> (s \<in> A) = c" by blast
  2021     with * show False
  2022       by (cases c) auto
  2023   qed
  2024 qed
  2026 lemma connectedD_const:
  2027   fixes P :: "'a::topological_space \<Rightarrow> bool"
  2028   shows "connected S \<Longrightarrow> continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c"
  2029   unfolding connected_iff_const by auto
  2031 lemma connectedI_const:
  2032   "(\<And>P::'a::topological_space \<Rightarrow> bool. continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c) \<Longrightarrow> connected S"
  2033   unfolding connected_iff_const by auto
  2035 lemma connected_local_const:
  2036   assumes "connected A" "a \<in> A" "b \<in> A"
  2037   assumes *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2038   shows "f a = f b"
  2039 proof -
  2040   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2041     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2042     using * unfolding eventually_at_topological by metis
  2044   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2045   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2046     using \<open>connected A\<close> S \<open>a\<in>A\<close>
  2047     by (intro connectedD) (auto, metis)
  2048   then show "f a = f b"
  2049   proof
  2050     assume "?N \<inter> A = {}"
  2051     then have "\<forall>x\<in>A. f a = f x"
  2052       using S(1) by auto
  2053     with \<open>b\<in>A\<close> show ?thesis by auto
  2054   next
  2055     assume "?P \<inter> A = {}" then show ?thesis
  2056       using \<open>a \<in> A\<close> S(1)[of a] by auto
  2057   qed
  2058 qed
  2060 lemma (in linorder_topology) connectedD_interval:
  2061   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2062   shows "z \<in> U"
  2063 proof -
  2064   have eq: "{..<z} \<union> {z<..} = - {z}"
  2065     by auto
  2066   { assume "z \<notin> U" "x < z" "z < y"
  2067     with xy have "\<not> connected U"
  2068       unfolding connected_def simp_thms
  2069       apply (rule_tac exI[of _ "{..< z}"])
  2070       apply (rule_tac exI[of _ "{z <..}"])
  2071       apply (auto simp add: eq)
  2072       done }
  2073   with assms show "z \<in> U"
  2074     by (metis less_le)
  2075 qed
  2077 lemma connected_continuous_image:
  2078   assumes *: "continuous_on s f"
  2079   assumes "connected s"
  2080   shows "connected (f ` s)"
  2081 proof (rule connectedI_const)
  2082   fix P :: "'b \<Rightarrow> bool" assume "continuous_on (f ` s) P"
  2083   then have "continuous_on s (P \<circ> f)"
  2084     by (rule continuous_on_compose[OF *])
  2085   from connectedD_const[OF \<open>connected s\<close> this] show "\<exists>c. \<forall>s\<in>f ` s. P s = c"
  2086     by auto
  2087 qed
  2090 section \<open>Linear Continuum Topologies\<close>
  2092 class linear_continuum_topology = linorder_topology + linear_continuum
  2093 begin
  2095 lemma Inf_notin_open:
  2096   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2097   shows "Inf A \<notin> A"
  2098 proof
  2099   assume "Inf A \<in> A"
  2100   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2101     using open_left[of A "Inf A" x] assms by auto
  2102   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2103     by (auto simp: subset_eq)
  2104   then show False
  2105     using cInf_lower[OF \<open>c \<in> A\<close>] bnd by (metis not_le less_imp_le bdd_belowI)
  2106 qed
  2108 lemma Sup_notin_open:
  2109   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2110   shows "Sup A \<notin> A"
  2111 proof
  2112   assume "Sup A \<in> A"
  2113   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2114     using open_right[of A "Sup A" x] assms by auto
  2115   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2116     by (auto simp: subset_eq)
  2117   then show False
  2118     using cSup_upper[OF \<open>c \<in> A\<close>] bnd by (metis less_imp_le not_le bdd_aboveI)
  2119 qed
  2121 end
  2123 instance linear_continuum_topology \<subseteq> perfect_space
  2124 proof
  2125   fix x :: 'a
  2126   obtain y where "x < y \<or> y < x"
  2127     using ex_gt_or_lt [of x] ..
  2128   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2129   show "\<not> open {x}"
  2130     by auto
  2131 qed
  2133 lemma connectedI_interval:
  2134   fixes U :: "'a :: linear_continuum_topology set"
  2135   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2136   shows "connected U"
  2137 proof (rule connectedI)
  2138   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2139     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2141     let ?z = "Inf (B \<inter> {x <..})"
  2143     have "x \<le> ?z" "?z \<le> y"
  2144       using \<open>y \<in> B\<close> \<open>x < y\<close> by (auto intro: cInf_lower cInf_greatest)
  2145     with \<open>x \<in> U\<close> \<open>y \<in> U\<close> have "?z \<in> U"
  2146       by (rule *)
  2147     moreover have "?z \<notin> B \<inter> {x <..}"
  2148       using \<open>open B\<close> by (intro Inf_notin_open) auto
  2149     ultimately have "?z \<in> A"
  2150       using \<open>x \<le> ?z\<close> \<open>A \<inter> B \<inter> U = {}\<close> \<open>x \<in> A\<close> \<open>U \<subseteq> A \<union> B\<close> by auto
  2152     { assume "?z < y"
  2153       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2154         using open_right[OF \<open>open A\<close> \<open>?z \<in> A\<close> \<open>?z < y\<close>] by auto
  2155       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2156         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] \<open>?z < a\<close> \<open>?z < y\<close> \<open>x < y\<close> \<open>y \<in> B\<close>
  2157         by (auto intro: less_imp_le)
  2158       moreover have "?z \<le> b"
  2159         using \<open>b \<in> B\<close> \<open>x < b\<close>
  2160         by (intro cInf_lower) auto
  2161       moreover have "b \<in> U"
  2162         using \<open>x \<le> ?z\<close> \<open>?z \<le> b\<close> \<open>b < min a y\<close>
  2163         by (intro *[OF \<open>x \<in> U\<close> \<open>y \<in> U\<close>]) (auto simp: less_imp_le)
  2164       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2165         by (intro bexI[of _ b]) auto }
  2166     then have False
  2167       using \<open>?z \<le> y\<close> \<open>?z \<in> A\<close> \<open>y \<in> B\<close> \<open>y \<in> U\<close> \<open>A \<inter> B \<inter> U = {}\<close> unfolding le_less by blast }
  2168   note not_disjoint = this
  2170   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2171   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2172   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2173   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2174   ultimately show False by (cases x y rule: linorder_cases) auto
  2175 qed
  2177 lemma connected_iff_interval:
  2178   fixes U :: "'a :: linear_continuum_topology set"
  2179   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2180   by (auto intro: connectedI_interval dest: connectedD_interval)
  2182 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2183   unfolding connected_iff_interval by auto
  2185 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2186   unfolding connected_iff_interval by auto
  2188 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2189   unfolding connected_iff_interval by auto
  2191 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2192   unfolding connected_iff_interval by auto
  2194 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2195   unfolding connected_iff_interval by auto
  2197 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2198   unfolding connected_iff_interval by auto
  2200 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2201   unfolding connected_iff_interval by auto
  2203 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2204   unfolding connected_iff_interval by auto
  2206 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2207   unfolding connected_iff_interval by auto
  2209 lemma connected_contains_Ioo: 
  2210   fixes A :: "'a :: linorder_topology set"
  2211   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2212   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2214 lemma connected_contains_Icc:
  2215   assumes "connected (A :: ('a :: {linorder_topology}) set)" "a \<in> A" "b \<in> A"
  2216   shows   "{a..b} \<subseteq> A"
  2217 proof
  2218   fix x assume "x \<in> {a..b}"
  2219   hence "x = a \<or> x = b \<or> x \<in> {a<..<b}" by auto
  2220   thus "x \<in> A" using assms connected_contains_Ioo[of A a b] by auto
  2221 qed
  2223 subsection \<open>Intermediate Value Theorem\<close>
  2225 lemma IVT':
  2226   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2227   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2228   assumes *: "continuous_on {a .. b} f"
  2229   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2230 proof -
  2231   have "connected {a..b}"
  2232     unfolding connected_iff_interval by auto
  2233   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2234   show ?thesis
  2235     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2236 qed
  2238 lemma IVT2':
  2239   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2240   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2241   assumes *: "continuous_on {a .. b} f"
  2242   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2243 proof -
  2244   have "connected {a..b}"
  2245     unfolding connected_iff_interval by auto
  2246   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2247   show ?thesis
  2248     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2249 qed
  2251 lemma IVT:
  2252   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2253   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2254   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2256 lemma IVT2:
  2257   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2258   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2259   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2261 lemma continuous_inj_imp_mono:
  2262   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2263   assumes x: "a < x" "x < b"
  2264   assumes cont: "continuous_on {a..b} f"
  2265   assumes inj: "inj_on f {a..b}"
  2266   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2267 proof -
  2268   note I = inj_on_eq_iff[OF inj]
  2269   { assume "f x < f a" "f x < f b"
  2270     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2271       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2272       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2273     with x I have False by auto }
  2274   moreover
  2275   { assume "f a < f x" "f b < f x"
  2276     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2277       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2278       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2279     with x I have False by auto }
  2280   ultimately show ?thesis
  2281     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2282 qed
  2284 lemma continuous_at_Sup_mono:
  2285   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2286   assumes "mono f"
  2287   assumes cont: "continuous (at_left (Sup S)) f"
  2288   assumes S: "S \<noteq> {}" "bdd_above S"
  2289   shows "f (Sup S) = (SUP s:S. f s)"
  2290 proof (rule antisym)
  2291   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2292     using cont unfolding continuous_within .
  2294   show "f (Sup S) \<le> (SUP s:S. f s)"
  2295   proof cases
  2296     assume "Sup S \<in> S" then show ?thesis
  2297       by (rule cSUP_upper) (auto intro: bdd_above_image_mono S \<open>mono f\<close>)
  2298   next
  2299     assume "Sup S \<notin> S"
  2300     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2301       by auto
  2302     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2303       unfolding less_le by (blast intro: cSup_upper)
  2304     show ?thesis
  2305     proof (rule ccontr)
  2306       assume "\<not> ?thesis"
  2307       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "b < Sup S"
  2308         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> (SUP s:S. f s) < f y"
  2309         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2310       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2311         using less_cSupD[of S b] by auto
  2312       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2313         unfolding less_le by (blast intro: cSup_upper)
  2314       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_mono[of f]]
  2315       show False
  2316         by (auto simp: assms)
  2317     qed
  2318   qed
  2319 qed (intro cSUP_least \<open>mono f\<close>[THEN monoD] cSup_upper S)
  2321 lemma continuous_at_Sup_antimono:
  2322   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2323   assumes "antimono f"
  2324   assumes cont: "continuous (at_left (Sup S)) f"
  2325   assumes S: "S \<noteq> {}" "bdd_above S"
  2326   shows "f (Sup S) = (INF s:S. f s)"
  2327 proof (rule antisym)
  2328   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2329     using cont unfolding continuous_within .
  2331   show "(INF s:S. f s) \<le> f (Sup S)"
  2332   proof cases
  2333     assume "Sup S \<in> S" then show ?thesis
  2334       by (intro cINF_lower) (auto intro: bdd_below_image_antimono S \<open>antimono f\<close>)
  2335   next
  2336     assume "Sup S \<notin> S"
  2337     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2338       by auto
  2339     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2340       unfolding less_le by (blast intro: cSup_upper)
  2341     show ?thesis
  2342     proof (rule ccontr)
  2343       assume "\<not> ?thesis"
  2344       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "b < Sup S"
  2345         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> f y < (INF s:S. f s)"
  2346         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2347       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2348         using less_cSupD[of S b] by auto
  2349       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2350         unfolding less_le by (blast intro: cSup_upper)
  2351       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cINF_lower[OF bdd_below_image_antimono, of f S c] \<open>c \<in> S\<close>
  2352       show False
  2353         by (auto simp: assms)
  2354     qed
  2355   qed
  2356 qed (intro cINF_greatest \<open>antimono f\<close>[THEN antimonoD] cSup_upper S)
  2358 lemma continuous_at_Inf_mono:
  2359   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2360   assumes "mono f"
  2361   assumes cont: "continuous (at_right (Inf S)) f"
  2362   assumes S: "S \<noteq> {}" "bdd_below S"
  2363   shows "f (Inf S) = (INF s:S. f s)"
  2364 proof (rule antisym)
  2365   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2366     using cont unfolding continuous_within .
  2368   show "(INF s:S. f s) \<le> f (Inf S)"
  2369   proof cases
  2370     assume "Inf S \<in> S" then show ?thesis
  2371       by (rule cINF_lower[rotated]) (auto intro: bdd_below_image_mono S \<open>mono f\<close>)
  2372   next
  2373     assume "Inf S \<notin> S"
  2374     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2375       by auto
  2376     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2377       unfolding less_le by (blast intro: cInf_lower)
  2378     show ?thesis
  2379     proof (rule ccontr)
  2380       assume "\<not> ?thesis"
  2381       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "Inf S < b"
  2382         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> f y < (INF s:S. f s)"
  2383         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2384       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2385         using cInf_lessD[of S b] by auto
  2386       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2387         unfolding less_le by (blast intro: cInf_lower)
  2388       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cINF_lower[OF bdd_below_image_mono[of f] \<open>c \<in> S\<close>]
  2389       show False
  2390         by (auto simp: assms)
  2391     qed
  2392   qed
  2393 qed (intro cINF_greatest \<open>mono f\<close>[THEN monoD] cInf_lower \<open>bdd_below S\<close> \<open>S \<noteq> {}\<close>)
  2395 lemma continuous_at_Inf_antimono:
  2396   fixes f :: "'a :: {linorder_topology, conditionally_complete_linorder} \<Rightarrow> 'b :: {linorder_topology, conditionally_complete_linorder}"
  2397   assumes "antimono f"
  2398   assumes cont: "continuous (at_right (Inf S)) f"
  2399   assumes S: "S \<noteq> {}" "bdd_below S"
  2400   shows "f (Inf S) = (SUP s:S. f s)"
  2401 proof (rule antisym)
  2402   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2403     using cont unfolding continuous_within .
  2405   show "f (Inf S) \<le> (SUP s:S. f s)"
  2406   proof cases
  2407     assume "Inf S \<in> S" then show ?thesis
  2408       by (rule cSUP_upper) (auto intro: bdd_above_image_antimono S \<open>antimono f\<close>)
  2409   next
  2410     assume "Inf S \<notin> S"
  2411     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2412       by auto
  2413     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2414       unfolding less_le by (blast intro: cInf_lower)
  2415     show ?thesis
  2416     proof (rule ccontr)
  2417       assume "\<not> ?thesis"
  2418       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "Inf S < b"
  2419         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> (SUP s:S. f s) < f y"
  2420         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2421       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2422         using cInf_lessD[of S b] by auto
  2423       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2424         unfolding less_le by (blast intro: cInf_lower)
  2425       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_antimono[of f]]
  2426       show False
  2427         by (auto simp: assms)
  2428     qed
  2429   qed
  2430 qed (intro cSUP_least \<open>antimono f\<close>[THEN antimonoD] cInf_lower S)
  2432 end