src/HOL/Complex.thy
 author kuncar Fri Dec 09 18:07:04 2011 +0100 (2011-12-09) changeset 45802 b16f976db515 parent 44902 9ba11d41cd1f child 47108 2a1953f0d20d permissions -rw-r--r--
Quotient_Info stores only relation maps
     1 (*  Title:       HOL/Complex.thy

     2     Author:      Jacques D. Fleuriot

     3     Copyright:   2001 University of Edinburgh

     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4

     5 *)

     6

     7 header {* Complex Numbers: Rectangular and Polar Representations *}

     8

     9 theory Complex

    10 imports Transcendental

    11 begin

    12

    13 datatype complex = Complex real real

    14

    15 primrec Re :: "complex \<Rightarrow> real"

    16   where Re: "Re (Complex x y) = x"

    17

    18 primrec Im :: "complex \<Rightarrow> real"

    19   where Im: "Im (Complex x y) = y"

    20

    21 lemma complex_surj [simp]: "Complex (Re z) (Im z) = z"

    22   by (induct z) simp

    23

    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"

    25   by (induct x, induct y) simp

    26

    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"

    28   by (induct x, induct y) simp

    29

    30

    31 subsection {* Addition and Subtraction *}

    32

    33 instantiation complex :: ab_group_add

    34 begin

    35

    36 definition complex_zero_def:

    37   "0 = Complex 0 0"

    38

    39 definition complex_add_def:

    40   "x + y = Complex (Re x + Re y) (Im x + Im y)"

    41

    42 definition complex_minus_def:

    43   "- x = Complex (- Re x) (- Im x)"

    44

    45 definition complex_diff_def:

    46   "x - (y\<Colon>complex) = x + - y"

    47

    48 lemma Complex_eq_0 [simp]: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"

    49   by (simp add: complex_zero_def)

    50

    51 lemma complex_Re_zero [simp]: "Re 0 = 0"

    52   by (simp add: complex_zero_def)

    53

    54 lemma complex_Im_zero [simp]: "Im 0 = 0"

    55   by (simp add: complex_zero_def)

    56

    57 lemma complex_add [simp]:

    58   "Complex a b + Complex c d = Complex (a + c) (b + d)"

    59   by (simp add: complex_add_def)

    60

    61 lemma complex_Re_add [simp]: "Re (x + y) = Re x + Re y"

    62   by (simp add: complex_add_def)

    63

    64 lemma complex_Im_add [simp]: "Im (x + y) = Im x + Im y"

    65   by (simp add: complex_add_def)

    66

    67 lemma complex_minus [simp]:

    68   "- (Complex a b) = Complex (- a) (- b)"

    69   by (simp add: complex_minus_def)

    70

    71 lemma complex_Re_minus [simp]: "Re (- x) = - Re x"

    72   by (simp add: complex_minus_def)

    73

    74 lemma complex_Im_minus [simp]: "Im (- x) = - Im x"

    75   by (simp add: complex_minus_def)

    76

    77 lemma complex_diff [simp]:

    78   "Complex a b - Complex c d = Complex (a - c) (b - d)"

    79   by (simp add: complex_diff_def)

    80

    81 lemma complex_Re_diff [simp]: "Re (x - y) = Re x - Re y"

    82   by (simp add: complex_diff_def)

    83

    84 lemma complex_Im_diff [simp]: "Im (x - y) = Im x - Im y"

    85   by (simp add: complex_diff_def)

    86

    87 instance

    88   by intro_classes (simp_all add: complex_add_def complex_diff_def)

    89

    90 end

    91

    92

    93 subsection {* Multiplication and Division *}

    94

    95 instantiation complex :: field_inverse_zero

    96 begin

    97

    98 definition complex_one_def:

    99   "1 = Complex 1 0"

   100

   101 definition complex_mult_def:

   102   "x * y = Complex (Re x * Re y - Im x * Im y) (Re x * Im y + Im x * Re y)"

   103

   104 definition complex_inverse_def:

   105   "inverse x =

   106     Complex (Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)) (- Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>))"

   107

   108 definition complex_divide_def:

   109   "x / (y\<Colon>complex) = x * inverse y"

   110

   111 lemma Complex_eq_1 [simp]: "(Complex a b = 1) = (a = 1 \<and> b = 0)"

   112   by (simp add: complex_one_def)

   113

   114 lemma complex_Re_one [simp]: "Re 1 = 1"

   115   by (simp add: complex_one_def)

   116

   117 lemma complex_Im_one [simp]: "Im 1 = 0"

   118   by (simp add: complex_one_def)

   119

   120 lemma complex_mult [simp]:

   121   "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"

   122   by (simp add: complex_mult_def)

   123

   124 lemma complex_Re_mult [simp]: "Re (x * y) = Re x * Re y - Im x * Im y"

   125   by (simp add: complex_mult_def)

   126

   127 lemma complex_Im_mult [simp]: "Im (x * y) = Re x * Im y + Im x * Re y"

   128   by (simp add: complex_mult_def)

   129

   130 lemma complex_inverse [simp]:

   131   "inverse (Complex a b) = Complex (a / (a\<twosuperior> + b\<twosuperior>)) (- b / (a\<twosuperior> + b\<twosuperior>))"

   132   by (simp add: complex_inverse_def)

   133

   134 lemma complex_Re_inverse:

   135   "Re (inverse x) = Re x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"

   136   by (simp add: complex_inverse_def)

   137

   138 lemma complex_Im_inverse:

   139   "Im (inverse x) = - Im x / ((Re x)\<twosuperior> + (Im x)\<twosuperior>)"

   140   by (simp add: complex_inverse_def)

   141

   142 instance

   143   by intro_classes (simp_all add: complex_mult_def

   144     right_distrib left_distrib right_diff_distrib left_diff_distrib

   145     complex_inverse_def complex_divide_def

   146     power2_eq_square add_divide_distrib [symmetric]

   147     complex_eq_iff)

   148

   149 end

   150

   151

   152 subsection {* Numerals and Arithmetic *}

   153

   154 instantiation complex :: number_ring

   155 begin

   156

   157 definition complex_number_of_def:

   158   "number_of w = (of_int w \<Colon> complex)"

   159

   160 instance

   161   by intro_classes (simp only: complex_number_of_def)

   162

   163 end

   164

   165 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"

   166   by (induct n) simp_all

   167

   168 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"

   169   by (induct n) simp_all

   170

   171 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"

   172   by (cases z rule: int_diff_cases) simp

   173

   174 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"

   175   by (cases z rule: int_diff_cases) simp

   176

   177 lemma complex_Re_number_of [simp]: "Re (number_of v) = number_of v"

   178   unfolding number_of_eq by (rule complex_Re_of_int)

   179

   180 lemma complex_Im_number_of [simp]: "Im (number_of v) = 0"

   181   unfolding number_of_eq by (rule complex_Im_of_int)

   182

   183 lemma Complex_eq_number_of [simp]:

   184   "(Complex a b = number_of w) = (a = number_of w \<and> b = 0)"

   185   by (simp add: complex_eq_iff)

   186

   187

   188 subsection {* Scalar Multiplication *}

   189

   190 instantiation complex :: real_field

   191 begin

   192

   193 definition complex_scaleR_def:

   194   "scaleR r x = Complex (r * Re x) (r * Im x)"

   195

   196 lemma complex_scaleR [simp]:

   197   "scaleR r (Complex a b) = Complex (r * a) (r * b)"

   198   unfolding complex_scaleR_def by simp

   199

   200 lemma complex_Re_scaleR [simp]: "Re (scaleR r x) = r * Re x"

   201   unfolding complex_scaleR_def by simp

   202

   203 lemma complex_Im_scaleR [simp]: "Im (scaleR r x) = r * Im x"

   204   unfolding complex_scaleR_def by simp

   205

   206 instance

   207 proof

   208   fix a b :: real and x y :: complex

   209   show "scaleR a (x + y) = scaleR a x + scaleR a y"

   210     by (simp add: complex_eq_iff right_distrib)

   211   show "scaleR (a + b) x = scaleR a x + scaleR b x"

   212     by (simp add: complex_eq_iff left_distrib)

   213   show "scaleR a (scaleR b x) = scaleR (a * b) x"

   214     by (simp add: complex_eq_iff mult_assoc)

   215   show "scaleR 1 x = x"

   216     by (simp add: complex_eq_iff)

   217   show "scaleR a x * y = scaleR a (x * y)"

   218     by (simp add: complex_eq_iff algebra_simps)

   219   show "x * scaleR a y = scaleR a (x * y)"

   220     by (simp add: complex_eq_iff algebra_simps)

   221 qed

   222

   223 end

   224

   225

   226 subsection{* Properties of Embedding from Reals *}

   227

   228 abbreviation complex_of_real :: "real \<Rightarrow> complex"

   229   where "complex_of_real \<equiv> of_real"

   230

   231 lemma complex_of_real_def: "complex_of_real r = Complex r 0"

   232   by (simp add: of_real_def complex_scaleR_def)

   233

   234 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"

   235   by (simp add: complex_of_real_def)

   236

   237 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"

   238   by (simp add: complex_of_real_def)

   239

   240 lemma Complex_add_complex_of_real [simp]:

   241   shows "Complex x y + complex_of_real r = Complex (x+r) y"

   242   by (simp add: complex_of_real_def)

   243

   244 lemma complex_of_real_add_Complex [simp]:

   245   shows "complex_of_real r + Complex x y = Complex (r+x) y"

   246   by (simp add: complex_of_real_def)

   247

   248 lemma Complex_mult_complex_of_real:

   249   shows "Complex x y * complex_of_real r = Complex (x*r) (y*r)"

   250   by (simp add: complex_of_real_def)

   251

   252 lemma complex_of_real_mult_Complex:

   253   shows "complex_of_real r * Complex x y = Complex (r*x) (r*y)"

   254   by (simp add: complex_of_real_def)

   255

   256 lemma complex_eq_cancel_iff2 [simp]:

   257   shows "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"

   258   by (simp add: complex_of_real_def)

   259

   260 lemma complex_split_polar:

   261      "\<exists>r a. z = complex_of_real r * (Complex (cos a) (sin a))"

   262   by (simp add: complex_eq_iff polar_Ex)

   263

   264

   265 subsection {* Vector Norm *}

   266

   267 instantiation complex :: real_normed_field

   268 begin

   269

   270 definition complex_norm_def:

   271   "norm z = sqrt ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"

   272

   273 abbreviation cmod :: "complex \<Rightarrow> real"

   274   where "cmod \<equiv> norm"

   275

   276 definition complex_sgn_def:

   277   "sgn x = x /\<^sub>R cmod x"

   278

   279 definition dist_complex_def:

   280   "dist x y = cmod (x - y)"

   281

   282 definition open_complex_def:

   283   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"

   284

   285 lemmas cmod_def = complex_norm_def

   286

   287 lemma complex_norm [simp]: "cmod (Complex x y) = sqrt (x\<twosuperior> + y\<twosuperior>)"

   288   by (simp add: complex_norm_def)

   289

   290 instance proof

   291   fix r :: real and x y :: complex and S :: "complex set"

   292   show "0 \<le> norm x"

   293     by (induct x) simp

   294   show "(norm x = 0) = (x = 0)"

   295     by (induct x) simp

   296   show "norm (x + y) \<le> norm x + norm y"

   297     by (induct x, induct y)

   298        (simp add: real_sqrt_sum_squares_triangle_ineq)

   299   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"

   300     by (induct x)

   301        (simp add: power_mult_distrib right_distrib [symmetric] real_sqrt_mult)

   302   show "norm (x * y) = norm x * norm y"

   303     by (induct x, induct y)

   304        (simp add: real_sqrt_mult [symmetric] power2_eq_square algebra_simps)

   305   show "sgn x = x /\<^sub>R cmod x"

   306     by (rule complex_sgn_def)

   307   show "dist x y = cmod (x - y)"

   308     by (rule dist_complex_def)

   309   show "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"

   310     by (rule open_complex_def)

   311 qed

   312

   313 end

   314

   315 lemma cmod_unit_one: "cmod (Complex (cos a) (sin a)) = 1"

   316   by simp

   317

   318 lemma cmod_complex_polar:

   319   "cmod (complex_of_real r * Complex (cos a) (sin a)) = abs r"

   320   by (simp add: norm_mult)

   321

   322 lemma complex_Re_le_cmod: "Re x \<le> cmod x"

   323   unfolding complex_norm_def

   324   by (rule real_sqrt_sum_squares_ge1)

   325

   326 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"

   327   by (rule order_trans [OF _ norm_ge_zero], simp)

   328

   329 lemma complex_mod_triangle_ineq2: "cmod(b + a) - cmod b \<le> cmod a"

   330   by (rule ord_le_eq_trans [OF norm_triangle_ineq2], simp)

   331

   332 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"

   333   by (cases x) simp

   334

   335 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"

   336   by (cases x) simp

   337

   338 text {* Properties of complex signum. *}

   339

   340 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"

   341   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult_commute)

   342

   343 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"

   344   by (simp add: complex_sgn_def divide_inverse)

   345

   346 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"

   347   by (simp add: complex_sgn_def divide_inverse)

   348

   349

   350 subsection {* Completeness of the Complexes *}

   351

   352 lemma bounded_linear_Re: "bounded_linear Re"

   353   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)

   354

   355 lemma bounded_linear_Im: "bounded_linear Im"

   356   by (rule bounded_linear_intro [where K=1], simp_all add: complex_norm_def)

   357

   358 lemmas tendsto_Re [tendsto_intros] =

   359   bounded_linear.tendsto [OF bounded_linear_Re]

   360

   361 lemmas tendsto_Im [tendsto_intros] =

   362   bounded_linear.tendsto [OF bounded_linear_Im]

   363

   364 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]

   365 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]

   366 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]

   367 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]

   368

   369 lemma tendsto_Complex [tendsto_intros]:

   370   assumes "(f ---> a) F" and "(g ---> b) F"

   371   shows "((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"

   372 proof (rule tendstoI)

   373   fix r :: real assume "0 < r"

   374   hence "0 < r / sqrt 2" by (simp add: divide_pos_pos)

   375   have "eventually (\<lambda>x. dist (f x) a < r / sqrt 2) F"

   376     using (f ---> a) F and 0 < r / sqrt 2 by (rule tendstoD)

   377   moreover

   378   have "eventually (\<lambda>x. dist (g x) b < r / sqrt 2) F"

   379     using (g ---> b) F and 0 < r / sqrt 2 by (rule tendstoD)

   380   ultimately

   381   show "eventually (\<lambda>x. dist (Complex (f x) (g x)) (Complex a b) < r) F"

   382     by (rule eventually_elim2)

   383        (simp add: dist_norm real_sqrt_sum_squares_less)

   384 qed

   385

   386 instance complex :: banach

   387 proof

   388   fix X :: "nat \<Rightarrow> complex"

   389   assume X: "Cauchy X"

   390   from Cauchy_Re [OF X] have 1: "(\<lambda>n. Re (X n)) ----> lim (\<lambda>n. Re (X n))"

   391     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)

   392   from Cauchy_Im [OF X] have 2: "(\<lambda>n. Im (X n)) ----> lim (\<lambda>n. Im (X n))"

   393     by (simp add: Cauchy_convergent_iff convergent_LIMSEQ_iff)

   394   have "X ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"

   395     using tendsto_Complex [OF 1 2] by simp

   396   thus "convergent X"

   397     by (rule convergentI)

   398 qed

   399

   400

   401 subsection {* The Complex Number $i$ *}

   402

   403 definition "ii" :: complex  ("\<i>")

   404   where i_def: "ii \<equiv> Complex 0 1"

   405

   406 lemma complex_Re_i [simp]: "Re ii = 0"

   407   by (simp add: i_def)

   408

   409 lemma complex_Im_i [simp]: "Im ii = 1"

   410   by (simp add: i_def)

   411

   412 lemma Complex_eq_i [simp]: "(Complex x y = ii) = (x = 0 \<and> y = 1)"

   413   by (simp add: i_def)

   414

   415 lemma norm_ii [simp]: "norm ii = 1"

   416   by (simp add: i_def)

   417

   418 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"

   419   by (simp add: complex_eq_iff)

   420

   421 lemma complex_i_not_one [simp]: "ii \<noteq> 1"

   422   by (simp add: complex_eq_iff)

   423

   424 lemma complex_i_not_number_of [simp]: "ii \<noteq> number_of w"

   425   by (simp add: complex_eq_iff)

   426

   427 lemma i_mult_Complex [simp]: "ii * Complex a b = Complex (- b) a"

   428   by (simp add: complex_eq_iff)

   429

   430 lemma Complex_mult_i [simp]: "Complex a b * ii = Complex (- b) a"

   431   by (simp add: complex_eq_iff)

   432

   433 lemma i_complex_of_real [simp]: "ii * complex_of_real r = Complex 0 r"

   434   by (simp add: i_def complex_of_real_def)

   435

   436 lemma complex_of_real_i [simp]: "complex_of_real r * ii = Complex 0 r"

   437   by (simp add: i_def complex_of_real_def)

   438

   439 lemma i_squared [simp]: "ii * ii = -1"

   440   by (simp add: i_def)

   441

   442 lemma power2_i [simp]: "ii\<twosuperior> = -1"

   443   by (simp add: power2_eq_square)

   444

   445 lemma inverse_i [simp]: "inverse ii = - ii"

   446   by (rule inverse_unique, simp)

   447

   448 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"

   449   by (simp add: mult_assoc [symmetric])

   450

   451

   452 subsection {* Complex Conjugation *}

   453

   454 definition cnj :: "complex \<Rightarrow> complex" where

   455   "cnj z = Complex (Re z) (- Im z)"

   456

   457 lemma complex_cnj [simp]: "cnj (Complex a b) = Complex a (- b)"

   458   by (simp add: cnj_def)

   459

   460 lemma complex_Re_cnj [simp]: "Re (cnj x) = Re x"

   461   by (simp add: cnj_def)

   462

   463 lemma complex_Im_cnj [simp]: "Im (cnj x) = - Im x"

   464   by (simp add: cnj_def)

   465

   466 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"

   467   by (simp add: complex_eq_iff)

   468

   469 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"

   470   by (simp add: cnj_def)

   471

   472 lemma complex_cnj_zero [simp]: "cnj 0 = 0"

   473   by (simp add: complex_eq_iff)

   474

   475 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"

   476   by (simp add: complex_eq_iff)

   477

   478 lemma complex_cnj_add: "cnj (x + y) = cnj x + cnj y"

   479   by (simp add: complex_eq_iff)

   480

   481 lemma complex_cnj_diff: "cnj (x - y) = cnj x - cnj y"

   482   by (simp add: complex_eq_iff)

   483

   484 lemma complex_cnj_minus: "cnj (- x) = - cnj x"

   485   by (simp add: complex_eq_iff)

   486

   487 lemma complex_cnj_one [simp]: "cnj 1 = 1"

   488   by (simp add: complex_eq_iff)

   489

   490 lemma complex_cnj_mult: "cnj (x * y) = cnj x * cnj y"

   491   by (simp add: complex_eq_iff)

   492

   493 lemma complex_cnj_inverse: "cnj (inverse x) = inverse (cnj x)"

   494   by (simp add: complex_inverse_def)

   495

   496 lemma complex_cnj_divide: "cnj (x / y) = cnj x / cnj y"

   497   by (simp add: complex_divide_def complex_cnj_mult complex_cnj_inverse)

   498

   499 lemma complex_cnj_power: "cnj (x ^ n) = cnj x ^ n"

   500   by (induct n, simp_all add: complex_cnj_mult)

   501

   502 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"

   503   by (simp add: complex_eq_iff)

   504

   505 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"

   506   by (simp add: complex_eq_iff)

   507

   508 lemma complex_cnj_number_of [simp]: "cnj (number_of w) = number_of w"

   509   by (simp add: complex_eq_iff)

   510

   511 lemma complex_cnj_scaleR: "cnj (scaleR r x) = scaleR r (cnj x)"

   512   by (simp add: complex_eq_iff)

   513

   514 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"

   515   by (simp add: complex_norm_def)

   516

   517 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"

   518   by (simp add: complex_eq_iff)

   519

   520 lemma complex_cnj_i [simp]: "cnj ii = - ii"

   521   by (simp add: complex_eq_iff)

   522

   523 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"

   524   by (simp add: complex_eq_iff)

   525

   526 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"

   527   by (simp add: complex_eq_iff)

   528

   529 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<twosuperior> + (Im z)\<twosuperior>)"

   530   by (simp add: complex_eq_iff power2_eq_square)

   531

   532 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<twosuperior>"

   533   by (simp add: norm_mult power2_eq_square)

   534

   535 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"

   536   by (simp add: cmod_def power2_eq_square)

   537

   538 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"

   539   by simp

   540

   541 lemma bounded_linear_cnj: "bounded_linear cnj"

   542   using complex_cnj_add complex_cnj_scaleR

   543   by (rule bounded_linear_intro [where K=1], simp)

   544

   545 lemmas tendsto_cnj [tendsto_intros] =

   546   bounded_linear.tendsto [OF bounded_linear_cnj]

   547

   548 lemmas isCont_cnj [simp] =

   549   bounded_linear.isCont [OF bounded_linear_cnj]

   550

   551

   552 subsection{*Finally! Polar Form for Complex Numbers*}

   553

   554 subsubsection {* $\cos \theta + i \sin \theta$ *}

   555

   556 definition cis :: "real \<Rightarrow> complex" where

   557   "cis a = Complex (cos a) (sin a)"

   558

   559 lemma Re_cis [simp]: "Re (cis a) = cos a"

   560   by (simp add: cis_def)

   561

   562 lemma Im_cis [simp]: "Im (cis a) = sin a"

   563   by (simp add: cis_def)

   564

   565 lemma cis_zero [simp]: "cis 0 = 1"

   566   by (simp add: cis_def)

   567

   568 lemma norm_cis [simp]: "norm (cis a) = 1"

   569   by (simp add: cis_def)

   570

   571 lemma sgn_cis [simp]: "sgn (cis a) = cis a"

   572   by (simp add: sgn_div_norm)

   573

   574 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"

   575   by (metis norm_cis norm_zero zero_neq_one)

   576

   577 lemma cis_mult: "cis a * cis b = cis (a + b)"

   578   by (simp add: cis_def cos_add sin_add)

   579

   580 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"

   581   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)

   582

   583 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"

   584   by (simp add: cis_def)

   585

   586 lemma cis_divide: "cis a / cis b = cis (a - b)"

   587   by (simp add: complex_divide_def cis_mult diff_minus)

   588

   589 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"

   590   by (auto simp add: DeMoivre)

   591

   592 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"

   593   by (auto simp add: DeMoivre)

   594

   595 subsubsection {* $r(\cos \theta + i \sin \theta)$ *}

   596

   597 definition rcis :: "[real, real] \<Rightarrow> complex" where

   598   "rcis r a = complex_of_real r * cis a"

   599

   600 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"

   601   by (simp add: rcis_def)

   602

   603 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"

   604   by (simp add: rcis_def)

   605

   606 lemma rcis_Ex: "\<exists>r a. z = rcis r a"

   607   by (simp add: complex_eq_iff polar_Ex)

   608

   609 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"

   610   by (simp add: rcis_def norm_mult)

   611

   612 lemma cis_rcis_eq: "cis a = rcis 1 a"

   613   by (simp add: rcis_def)

   614

   615 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"

   616   by (simp add: rcis_def cis_mult)

   617

   618 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"

   619   by (simp add: rcis_def)

   620

   621 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"

   622   by (simp add: rcis_def)

   623

   624 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"

   625   by (simp add: rcis_def)

   626

   627 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"

   628   by (simp add: rcis_def power_mult_distrib DeMoivre)

   629

   630 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"

   631   by (simp add: divide_inverse rcis_def)

   632

   633 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"

   634   by (simp add: rcis_def cis_divide [symmetric])

   635

   636 subsubsection {* Complex exponential *}

   637

   638 abbreviation expi :: "complex \<Rightarrow> complex"

   639   where "expi \<equiv> exp"

   640

   641 lemma cis_conv_exp: "cis b = exp (Complex 0 b)"

   642 proof (rule complex_eqI)

   643   { fix n have "Complex 0 b ^ n =

   644     real (fact n) *\<^sub>R Complex (cos_coeff n * b ^ n) (sin_coeff n * b ^ n)"

   645       apply (induct n)

   646       apply (simp add: cos_coeff_def sin_coeff_def)

   647       apply (simp add: sin_coeff_Suc cos_coeff_Suc del: mult_Suc)

   648       done } note * = this

   649   show "Re (cis b) = Re (exp (Complex 0 b))"

   650     unfolding exp_def cis_def cos_def

   651     by (subst bounded_linear.suminf[OF bounded_linear_Re summable_exp_generic],

   652       simp add: * mult_assoc [symmetric])

   653   show "Im (cis b) = Im (exp (Complex 0 b))"

   654     unfolding exp_def cis_def sin_def

   655     by (subst bounded_linear.suminf[OF bounded_linear_Im summable_exp_generic],

   656       simp add: * mult_assoc [symmetric])

   657 qed

   658

   659 lemma expi_def: "expi z = complex_of_real (exp (Re z)) * cis (Im z)"

   660   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by simp

   661

   662 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"

   663   unfolding expi_def by simp

   664

   665 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"

   666   unfolding expi_def by simp

   667

   668 lemma complex_expi_Ex: "\<exists>a r. z = complex_of_real r * expi a"

   669 apply (insert rcis_Ex [of z])

   670 apply (auto simp add: expi_def rcis_def mult_assoc [symmetric])

   671 apply (rule_tac x = "ii * complex_of_real a" in exI, auto)

   672 done

   673

   674 lemma expi_two_pi_i [simp]: "expi((2::complex) * complex_of_real pi * ii) = 1"

   675   by (simp add: expi_def cis_def)

   676

   677 subsubsection {* Complex argument *}

   678

   679 definition arg :: "complex \<Rightarrow> real" where

   680   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"

   681

   682 lemma arg_zero: "arg 0 = 0"

   683   by (simp add: arg_def)

   684

   685 lemma of_nat_less_of_int_iff: (* TODO: move *)

   686   "(of_nat n :: 'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"

   687   by (metis of_int_of_nat_eq of_int_less_iff)

   688

   689 lemma real_of_nat_less_number_of_iff [simp]: (* TODO: move *)

   690   "real (n::nat) < number_of w \<longleftrightarrow> n < number_of w"

   691   unfolding real_of_nat_def nat_number_of_def number_of_eq

   692   by (simp add: of_nat_less_of_int_iff zless_nat_eq_int_zless)

   693

   694 lemma arg_unique:

   695   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"

   696   shows "arg z = x"

   697 proof -

   698   from assms have "z \<noteq> 0" by auto

   699   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"

   700   proof

   701     fix a def d \<equiv> "a - x"

   702     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"

   703     from a assms have "- (2*pi) < d \<and> d < 2*pi"

   704       unfolding d_def by simp

   705     moreover from a assms have "cos a = cos x" and "sin a = sin x"

   706       by (simp_all add: complex_eq_iff)

   707     hence "cos d = 1" unfolding d_def cos_diff by simp

   708     moreover hence "sin d = 0" by (rule cos_one_sin_zero)

   709     ultimately have "d = 0"

   710       unfolding sin_zero_iff even_mult_two_ex

   711       by (safe, auto simp add: numeral_2_eq_2 less_Suc_eq)

   712     thus "a = x" unfolding d_def by simp

   713   qed (simp add: assms del: Re_sgn Im_sgn)

   714   with z \<noteq> 0 show "arg z = x"

   715     unfolding arg_def by simp

   716 qed

   717

   718 lemma arg_correct:

   719   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"

   720 proof (simp add: arg_def assms, rule someI_ex)

   721   obtain r a where z: "z = rcis r a" using rcis_Ex by fast

   722   with assms have "r \<noteq> 0" by auto

   723   def b \<equiv> "if 0 < r then a else a + pi"

   724   have b: "sgn z = cis b"

   725     unfolding z b_def rcis_def using r \<noteq> 0

   726     by (simp add: of_real_def sgn_scaleR sgn_if, simp add: cis_def)

   727   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"

   728     by (induct_tac n, simp_all add: right_distrib cis_mult [symmetric],

   729       simp add: cis_def)

   730   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"

   731     by (case_tac x rule: int_diff_cases,

   732       simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)

   733   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"

   734   have "sgn z = cis c"

   735     unfolding b c_def

   736     by (simp add: cis_divide [symmetric] cis_2pi_int)

   737   moreover have "- pi < c \<and> c \<le> pi"

   738     using ceiling_correct [of "(b - pi) / (2*pi)"]

   739     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)

   740   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast

   741 qed

   742

   743 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"

   744   by (cases "z = 0", simp_all add: arg_zero arg_correct)

   745

   746 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"

   747   by (simp add: arg_correct)

   748

   749 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"

   750   by (cases "z = 0", simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)

   751

   752 lemma cos_arg_i_mult_zero [simp]:

   753      "y \<noteq> 0 ==> cos (arg(Complex 0 y)) = 0"

   754   using cis_arg [of "Complex 0 y"] by (simp add: complex_eq_iff)

   755

   756 text {* Legacy theorem names *}

   757

   758 lemmas expand_complex_eq = complex_eq_iff

   759 lemmas complex_Re_Im_cancel_iff = complex_eq_iff

   760 lemmas complex_equality = complex_eqI

   761

   762 end