src/HOL/HOLCF/Porder.thy
author kuncar
Fri Dec 09 18:07:04 2011 +0100 (2011-12-09)
changeset 45802 b16f976db515
parent 42151 4da4fc77664b
child 58880 0baae4311a9f
permissions -rw-r--r--
Quotient_Info stores only relation maps
     1 (*  Title:      HOL/HOLCF/Porder.thy
     2     Author:     Franz Regensburger and Brian Huffman
     3 *)
     4 
     5 header {* Partial orders *}
     6 
     7 theory Porder
     8 imports Main
     9 begin
    10 
    11 subsection {* Type class for partial orders *}
    12 
    13 class below =
    14   fixes below :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
    15 begin
    16 
    17 notation
    18   below (infix "<<" 50)
    19 
    20 notation (xsymbols)
    21   below (infix "\<sqsubseteq>" 50)
    22 
    23 abbreviation
    24   not_below :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "~<<" 50)
    25   where "not_below x y \<equiv> \<not> below x y"
    26 
    27 notation (xsymbols)
    28   not_below (infix "\<notsqsubseteq>" 50)
    29 
    30 lemma below_eq_trans: "\<lbrakk>a \<sqsubseteq> b; b = c\<rbrakk> \<Longrightarrow> a \<sqsubseteq> c"
    31   by (rule subst)
    32 
    33 lemma eq_below_trans: "\<lbrakk>a = b; b \<sqsubseteq> c\<rbrakk> \<Longrightarrow> a \<sqsubseteq> c"
    34   by (rule ssubst)
    35 
    36 end
    37 
    38 class po = below +
    39   assumes below_refl [iff]: "x \<sqsubseteq> x"
    40   assumes below_trans: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> z"
    41   assumes below_antisym: "x \<sqsubseteq> y \<Longrightarrow> y \<sqsubseteq> x \<Longrightarrow> x = y"
    42 begin
    43 
    44 lemma eq_imp_below: "x = y \<Longrightarrow> x \<sqsubseteq> y"
    45   by simp
    46 
    47 lemma box_below: "a \<sqsubseteq> b \<Longrightarrow> c \<sqsubseteq> a \<Longrightarrow> b \<sqsubseteq> d \<Longrightarrow> c \<sqsubseteq> d"
    48   by (rule below_trans [OF below_trans])
    49 
    50 lemma po_eq_conv: "x = y \<longleftrightarrow> x \<sqsubseteq> y \<and> y \<sqsubseteq> x"
    51   by (fast intro!: below_antisym)
    52 
    53 lemma rev_below_trans: "y \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> y \<Longrightarrow> x \<sqsubseteq> z"
    54   by (rule below_trans)
    55 
    56 lemma not_below2not_eq: "x \<notsqsubseteq> y \<Longrightarrow> x \<noteq> y"
    57   by auto
    58 
    59 end
    60 
    61 lemmas HOLCF_trans_rules [trans] =
    62   below_trans
    63   below_antisym
    64   below_eq_trans
    65   eq_below_trans
    66 
    67 context po
    68 begin
    69 
    70 subsection {* Upper bounds *}
    71 
    72 definition is_ub :: "'a set \<Rightarrow> 'a \<Rightarrow> bool" (infix "<|" 55) where
    73   "S <| x \<longleftrightarrow> (\<forall>y\<in>S. y \<sqsubseteq> x)"
    74 
    75 lemma is_ubI: "(\<And>x. x \<in> S \<Longrightarrow> x \<sqsubseteq> u) \<Longrightarrow> S <| u"
    76   by (simp add: is_ub_def)
    77 
    78 lemma is_ubD: "\<lbrakk>S <| u; x \<in> S\<rbrakk> \<Longrightarrow> x \<sqsubseteq> u"
    79   by (simp add: is_ub_def)
    80 
    81 lemma ub_imageI: "(\<And>x. x \<in> S \<Longrightarrow> f x \<sqsubseteq> u) \<Longrightarrow> (\<lambda>x. f x) ` S <| u"
    82   unfolding is_ub_def by fast
    83 
    84 lemma ub_imageD: "\<lbrakk>f ` S <| u; x \<in> S\<rbrakk> \<Longrightarrow> f x \<sqsubseteq> u"
    85   unfolding is_ub_def by fast
    86 
    87 lemma ub_rangeI: "(\<And>i. S i \<sqsubseteq> x) \<Longrightarrow> range S <| x"
    88   unfolding is_ub_def by fast
    89 
    90 lemma ub_rangeD: "range S <| x \<Longrightarrow> S i \<sqsubseteq> x"
    91   unfolding is_ub_def by fast
    92 
    93 lemma is_ub_empty [simp]: "{} <| u"
    94   unfolding is_ub_def by fast
    95 
    96 lemma is_ub_insert [simp]: "(insert x A) <| y = (x \<sqsubseteq> y \<and> A <| y)"
    97   unfolding is_ub_def by fast
    98 
    99 lemma is_ub_upward: "\<lbrakk>S <| x; x \<sqsubseteq> y\<rbrakk> \<Longrightarrow> S <| y"
   100   unfolding is_ub_def by (fast intro: below_trans)
   101 
   102 subsection {* Least upper bounds *}
   103 
   104 definition is_lub :: "'a set \<Rightarrow> 'a \<Rightarrow> bool" (infix "<<|" 55) where
   105   "S <<| x \<longleftrightarrow> S <| x \<and> (\<forall>u. S <| u \<longrightarrow> x \<sqsubseteq> u)"
   106 
   107 definition lub :: "'a set \<Rightarrow> 'a" where
   108   "lub S = (THE x. S <<| x)"
   109 
   110 end
   111 
   112 syntax
   113   "_BLub" :: "[pttrn, 'a set, 'b] \<Rightarrow> 'b" ("(3LUB _:_./ _)" [0,0, 10] 10)
   114 
   115 syntax (xsymbols)
   116   "_BLub" :: "[pttrn, 'a set, 'b] \<Rightarrow> 'b" ("(3\<Squnion>_\<in>_./ _)" [0,0, 10] 10)
   117 
   118 translations
   119   "LUB x:A. t" == "CONST lub ((%x. t) ` A)"
   120 
   121 context po
   122 begin
   123 
   124 abbreviation
   125   Lub  (binder "LUB " 10) where
   126   "LUB n. t n == lub (range t)"
   127 
   128 notation (xsymbols)
   129   Lub  (binder "\<Squnion> " 10)
   130 
   131 text {* access to some definition as inference rule *}
   132 
   133 lemma is_lubD1: "S <<| x \<Longrightarrow> S <| x"
   134   unfolding is_lub_def by fast
   135 
   136 lemma is_lubD2: "\<lbrakk>S <<| x; S <| u\<rbrakk> \<Longrightarrow> x \<sqsubseteq> u"
   137   unfolding is_lub_def by fast
   138 
   139 lemma is_lubI: "\<lbrakk>S <| x; \<And>u. S <| u \<Longrightarrow> x \<sqsubseteq> u\<rbrakk> \<Longrightarrow> S <<| x"
   140   unfolding is_lub_def by fast
   141 
   142 lemma is_lub_below_iff: "S <<| x \<Longrightarrow> x \<sqsubseteq> u \<longleftrightarrow> S <| u"
   143   unfolding is_lub_def is_ub_def by (metis below_trans)
   144 
   145 text {* lubs are unique *}
   146 
   147 lemma is_lub_unique: "\<lbrakk>S <<| x; S <<| y\<rbrakk> \<Longrightarrow> x = y"
   148   unfolding is_lub_def is_ub_def by (blast intro: below_antisym)
   149 
   150 text {* technical lemmas about @{term lub} and @{term is_lub} *}
   151 
   152 lemma is_lub_lub: "M <<| x \<Longrightarrow> M <<| lub M"
   153   unfolding lub_def by (rule theI [OF _ is_lub_unique])
   154 
   155 lemma lub_eqI: "M <<| l \<Longrightarrow> lub M = l"
   156   by (rule is_lub_unique [OF is_lub_lub])
   157 
   158 lemma is_lub_singleton: "{x} <<| x"
   159   by (simp add: is_lub_def)
   160 
   161 lemma lub_singleton [simp]: "lub {x} = x"
   162   by (rule is_lub_singleton [THEN lub_eqI])
   163 
   164 lemma is_lub_bin: "x \<sqsubseteq> y \<Longrightarrow> {x, y} <<| y"
   165   by (simp add: is_lub_def)
   166 
   167 lemma lub_bin: "x \<sqsubseteq> y \<Longrightarrow> lub {x, y} = y"
   168   by (rule is_lub_bin [THEN lub_eqI])
   169 
   170 lemma is_lub_maximal: "\<lbrakk>S <| x; x \<in> S\<rbrakk> \<Longrightarrow> S <<| x"
   171   by (erule is_lubI, erule (1) is_ubD)
   172 
   173 lemma lub_maximal: "\<lbrakk>S <| x; x \<in> S\<rbrakk> \<Longrightarrow> lub S = x"
   174   by (rule is_lub_maximal [THEN lub_eqI])
   175 
   176 subsection {* Countable chains *}
   177 
   178 definition chain :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
   179   -- {* Here we use countable chains and I prefer to code them as functions! *}
   180   "chain Y = (\<forall>i. Y i \<sqsubseteq> Y (Suc i))"
   181 
   182 lemma chainI: "(\<And>i. Y i \<sqsubseteq> Y (Suc i)) \<Longrightarrow> chain Y"
   183   unfolding chain_def by fast
   184 
   185 lemma chainE: "chain Y \<Longrightarrow> Y i \<sqsubseteq> Y (Suc i)"
   186   unfolding chain_def by fast
   187 
   188 text {* chains are monotone functions *}
   189 
   190 lemma chain_mono_less: "\<lbrakk>chain Y; i < j\<rbrakk> \<Longrightarrow> Y i \<sqsubseteq> Y j"
   191   by (erule less_Suc_induct, erule chainE, erule below_trans)
   192 
   193 lemma chain_mono: "\<lbrakk>chain Y; i \<le> j\<rbrakk> \<Longrightarrow> Y i \<sqsubseteq> Y j"
   194   by (cases "i = j", simp, simp add: chain_mono_less)
   195 
   196 lemma chain_shift: "chain Y \<Longrightarrow> chain (\<lambda>i. Y (i + j))"
   197   by (rule chainI, simp, erule chainE)
   198 
   199 text {* technical lemmas about (least) upper bounds of chains *}
   200 
   201 lemma is_lub_rangeD1: "range S <<| x \<Longrightarrow> S i \<sqsubseteq> x"
   202   by (rule is_lubD1 [THEN ub_rangeD])
   203 
   204 lemma is_ub_range_shift:
   205   "chain S \<Longrightarrow> range (\<lambda>i. S (i + j)) <| x = range S <| x"
   206 apply (rule iffI)
   207 apply (rule ub_rangeI)
   208 apply (rule_tac y="S (i + j)" in below_trans)
   209 apply (erule chain_mono)
   210 apply (rule le_add1)
   211 apply (erule ub_rangeD)
   212 apply (rule ub_rangeI)
   213 apply (erule ub_rangeD)
   214 done
   215 
   216 lemma is_lub_range_shift:
   217   "chain S \<Longrightarrow> range (\<lambda>i. S (i + j)) <<| x = range S <<| x"
   218   by (simp add: is_lub_def is_ub_range_shift)
   219 
   220 text {* the lub of a constant chain is the constant *}
   221 
   222 lemma chain_const [simp]: "chain (\<lambda>i. c)"
   223   by (simp add: chainI)
   224 
   225 lemma is_lub_const: "range (\<lambda>x. c) <<| c"
   226 by (blast dest: ub_rangeD intro: is_lubI ub_rangeI)
   227 
   228 lemma lub_const [simp]: "(\<Squnion>i. c) = c"
   229   by (rule is_lub_const [THEN lub_eqI])
   230 
   231 subsection {* Finite chains *}
   232 
   233 definition max_in_chain :: "nat \<Rightarrow> (nat \<Rightarrow> 'a) \<Rightarrow> bool" where
   234   -- {* finite chains, needed for monotony of continuous functions *}
   235   "max_in_chain i C \<longleftrightarrow> (\<forall>j. i \<le> j \<longrightarrow> C i = C j)"
   236 
   237 definition finite_chain :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
   238   "finite_chain C = (chain C \<and> (\<exists>i. max_in_chain i C))"
   239 
   240 text {* results about finite chains *}
   241 
   242 lemma max_in_chainI: "(\<And>j. i \<le> j \<Longrightarrow> Y i = Y j) \<Longrightarrow> max_in_chain i Y"
   243   unfolding max_in_chain_def by fast
   244 
   245 lemma max_in_chainD: "\<lbrakk>max_in_chain i Y; i \<le> j\<rbrakk> \<Longrightarrow> Y i = Y j"
   246   unfolding max_in_chain_def by fast
   247 
   248 lemma finite_chainI:
   249   "\<lbrakk>chain C; max_in_chain i C\<rbrakk> \<Longrightarrow> finite_chain C"
   250   unfolding finite_chain_def by fast
   251 
   252 lemma finite_chainE:
   253   "\<lbrakk>finite_chain C; \<And>i. \<lbrakk>chain C; max_in_chain i C\<rbrakk> \<Longrightarrow> R\<rbrakk> \<Longrightarrow> R"
   254   unfolding finite_chain_def by fast
   255 
   256 lemma lub_finch1: "\<lbrakk>chain C; max_in_chain i C\<rbrakk> \<Longrightarrow> range C <<| C i"
   257 apply (rule is_lubI)
   258 apply (rule ub_rangeI, rename_tac j)
   259 apply (rule_tac x=i and y=j in linorder_le_cases)
   260 apply (drule (1) max_in_chainD, simp)
   261 apply (erule (1) chain_mono)
   262 apply (erule ub_rangeD)
   263 done
   264 
   265 lemma lub_finch2:
   266   "finite_chain C \<Longrightarrow> range C <<| C (LEAST i. max_in_chain i C)"
   267 apply (erule finite_chainE)
   268 apply (erule LeastI2 [where Q="\<lambda>i. range C <<| C i"])
   269 apply (erule (1) lub_finch1)
   270 done
   271 
   272 lemma finch_imp_finite_range: "finite_chain Y \<Longrightarrow> finite (range Y)"
   273  apply (erule finite_chainE)
   274  apply (rule_tac B="Y ` {..i}" in finite_subset)
   275   apply (rule subsetI)
   276   apply (erule rangeE, rename_tac j)
   277   apply (rule_tac x=i and y=j in linorder_le_cases)
   278    apply (subgoal_tac "Y j = Y i", simp)
   279    apply (simp add: max_in_chain_def)
   280   apply simp
   281  apply simp
   282 done
   283 
   284 lemma finite_range_has_max:
   285   fixes f :: "nat \<Rightarrow> 'a" and r :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   286   assumes mono: "\<And>i j. i \<le> j \<Longrightarrow> r (f i) (f j)"
   287   assumes finite_range: "finite (range f)"
   288   shows "\<exists>k. \<forall>i. r (f i) (f k)"
   289 proof (intro exI allI)
   290   fix i :: nat
   291   let ?j = "LEAST k. f k = f i"
   292   let ?k = "Max ((\<lambda>x. LEAST k. f k = x) ` range f)"
   293   have "?j \<le> ?k"
   294   proof (rule Max_ge)
   295     show "finite ((\<lambda>x. LEAST k. f k = x) ` range f)"
   296       using finite_range by (rule finite_imageI)
   297     show "?j \<in> (\<lambda>x. LEAST k. f k = x) ` range f"
   298       by (intro imageI rangeI)
   299   qed
   300   hence "r (f ?j) (f ?k)"
   301     by (rule mono)
   302   also have "f ?j = f i"
   303     by (rule LeastI, rule refl)
   304   finally show "r (f i) (f ?k)" .
   305 qed
   306 
   307 lemma finite_range_imp_finch:
   308   "\<lbrakk>chain Y; finite (range Y)\<rbrakk> \<Longrightarrow> finite_chain Y"
   309  apply (subgoal_tac "\<exists>k. \<forall>i. Y i \<sqsubseteq> Y k")
   310   apply (erule exE)
   311   apply (rule finite_chainI, assumption)
   312   apply (rule max_in_chainI)
   313   apply (rule below_antisym)
   314    apply (erule (1) chain_mono)
   315   apply (erule spec)
   316  apply (rule finite_range_has_max)
   317   apply (erule (1) chain_mono)
   318  apply assumption
   319 done
   320 
   321 lemma bin_chain: "x \<sqsubseteq> y \<Longrightarrow> chain (\<lambda>i. if i=0 then x else y)"
   322   by (rule chainI, simp)
   323 
   324 lemma bin_chainmax:
   325   "x \<sqsubseteq> y \<Longrightarrow> max_in_chain (Suc 0) (\<lambda>i. if i=0 then x else y)"
   326   unfolding max_in_chain_def by simp
   327 
   328 lemma is_lub_bin_chain:
   329   "x \<sqsubseteq> y \<Longrightarrow> range (\<lambda>i::nat. if i=0 then x else y) <<| y"
   330 apply (frule bin_chain)
   331 apply (drule bin_chainmax)
   332 apply (drule (1) lub_finch1)
   333 apply simp
   334 done
   335 
   336 text {* the maximal element in a chain is its lub *}
   337 
   338 lemma lub_chain_maxelem: "\<lbrakk>Y i = c; \<forall>i. Y i \<sqsubseteq> c\<rbrakk> \<Longrightarrow> lub (range Y) = c"
   339   by (blast dest: ub_rangeD intro: lub_eqI is_lubI ub_rangeI)
   340 
   341 end
   342 
   343 end