src/HOL/UNITY/Follows.thy
author kuncar
Fri Dec 09 18:07:04 2011 +0100 (2011-12-09)
changeset 45802 b16f976db515
parent 41413 64cd30d6b0b8
child 54859 64ff7f16d5b7
permissions -rw-r--r--
Quotient_Info stores only relation maps
     1 (*  Title:      HOL/UNITY/Follows.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1998  University of Cambridge
     4 *)
     5 
     6 header{*The Follows Relation of Charpentier and Sivilotte*}
     7 
     8 theory Follows
     9 imports SubstAx ListOrder "~~/src/HOL/Library/Multiset"
    10 begin
    11 
    12 definition Follows :: "['a => 'b::{order}, 'a => 'b::{order}] => 'a program set" (infixl "Fols" 65) where
    13    "f Fols g == Increasing g \<inter> Increasing f Int
    14                 Always {s. f s \<le> g s} Int
    15                 (\<Inter>k. {s. k \<le> g s} LeadsTo {s. k \<le> f s})"
    16 
    17 
    18 (*Does this hold for "invariant"?*)
    19 lemma mono_Always_o:
    20      "mono h ==> Always {s. f s \<le> g s} \<subseteq> Always {s. h (f s) \<le> h (g s)}"
    21 apply (simp add: Always_eq_includes_reachable)
    22 apply (blast intro: monoD)
    23 done
    24 
    25 lemma mono_LeadsTo_o:
    26      "mono (h::'a::order => 'b::order)  
    27       ==> (\<Inter>j. {s. j \<le> g s} LeadsTo {s. j \<le> f s}) \<subseteq>  
    28           (\<Inter>k. {s. k \<le> h (g s)} LeadsTo {s. k \<le> h (f s)})"
    29 apply auto
    30 apply (rule single_LeadsTo_I)
    31 apply (drule_tac x = "g s" in spec)
    32 apply (erule LeadsTo_weaken)
    33 apply (blast intro: monoD order_trans)+
    34 done
    35 
    36 lemma Follows_constant [iff]: "F \<in> (%s. c) Fols (%s. c)"
    37 by (simp add: Follows_def)
    38 
    39 lemma mono_Follows_o: "mono h ==> f Fols g \<subseteq> (h o f) Fols (h o g)"
    40 by (auto simp add: Follows_def mono_Increasing_o [THEN [2] rev_subsetD]
    41                    mono_Always_o [THEN [2] rev_subsetD]
    42                    mono_LeadsTo_o [THEN [2] rev_subsetD, THEN INT_D])
    43 
    44 lemma mono_Follows_apply:
    45      "mono h ==> f Fols g \<subseteq> (%x. h (f x)) Fols (%x. h (g x))"
    46 apply (drule mono_Follows_o)
    47 apply (force simp add: o_def)
    48 done
    49 
    50 lemma Follows_trans: 
    51      "[| F \<in> f Fols g;  F \<in> g Fols h |] ==> F \<in> f Fols h"
    52 apply (simp add: Follows_def)
    53 apply (simp add: Always_eq_includes_reachable)
    54 apply (blast intro: order_trans LeadsTo_Trans)
    55 done
    56 
    57 
    58 subsection{*Destruction rules*}
    59 
    60 lemma Follows_Increasing1: "F \<in> f Fols g ==> F \<in> Increasing f"
    61 by (simp add: Follows_def)
    62 
    63 lemma Follows_Increasing2: "F \<in> f Fols g ==> F \<in> Increasing g"
    64 by (simp add: Follows_def)
    65 
    66 lemma Follows_Bounded: "F \<in> f Fols g ==> F \<in> Always {s. f s \<le> g s}"
    67 by (simp add: Follows_def)
    68 
    69 lemma Follows_LeadsTo: 
    70      "F \<in> f Fols g ==> F \<in> {s. k \<le> g s} LeadsTo {s. k \<le> f s}"
    71 by (simp add: Follows_def)
    72 
    73 lemma Follows_LeadsTo_pfixLe:
    74      "F \<in> f Fols g ==> F \<in> {s. k pfixLe g s} LeadsTo {s. k pfixLe f s}"
    75 apply (rule single_LeadsTo_I, clarify)
    76 apply (drule_tac k="g s" in Follows_LeadsTo)
    77 apply (erule LeadsTo_weaken)
    78  apply blast 
    79 apply (blast intro: pfixLe_trans prefix_imp_pfixLe)
    80 done
    81 
    82 lemma Follows_LeadsTo_pfixGe:
    83      "F \<in> f Fols g ==> F \<in> {s. k pfixGe g s} LeadsTo {s. k pfixGe f s}"
    84 apply (rule single_LeadsTo_I, clarify)
    85 apply (drule_tac k="g s" in Follows_LeadsTo)
    86 apply (erule LeadsTo_weaken)
    87  apply blast 
    88 apply (blast intro: pfixGe_trans prefix_imp_pfixGe)
    89 done
    90 
    91 
    92 lemma Always_Follows1: 
    93      "[| F \<in> Always {s. f s = f' s}; F \<in> f Fols g |] ==> F \<in> f' Fols g"
    94 
    95 apply (simp add: Follows_def Increasing_def Stable_def, auto)
    96 apply (erule_tac [3] Always_LeadsTo_weaken)
    97 apply (erule_tac A = "{s. z \<le> f s}" and A' = "{s. z \<le> f s}" 
    98        in Always_Constrains_weaken, auto)
    99 apply (drule Always_Int_I, assumption)
   100 apply (force intro: Always_weaken)
   101 done
   102 
   103 lemma Always_Follows2: 
   104      "[| F \<in> Always {s. g s = g' s}; F \<in> f Fols g |] ==> F \<in> f Fols g'"
   105 apply (simp add: Follows_def Increasing_def Stable_def, auto)
   106 apply (erule_tac [3] Always_LeadsTo_weaken)
   107 apply (erule_tac A = "{s. z \<le> g s}" and A' = "{s. z \<le> g s}"
   108        in Always_Constrains_weaken, auto)
   109 apply (drule Always_Int_I, assumption)
   110 apply (force intro: Always_weaken)
   111 done
   112 
   113 
   114 subsection{*Union properties (with the subset ordering)*}
   115 
   116 (*Can replace "Un" by any sup.  But existing max only works for linorders.*)
   117 lemma increasing_Un: 
   118     "[| F \<in> increasing f;  F \<in> increasing g |]  
   119      ==> F \<in> increasing (%s. (f s) \<union> (g s))"
   120 apply (simp add: increasing_def stable_def constrains_def, auto)
   121 apply (drule_tac x = "f xa" in spec)
   122 apply (drule_tac x = "g xa" in spec)
   123 apply (blast dest!: bspec)
   124 done
   125 
   126 lemma Increasing_Un: 
   127     "[| F \<in> Increasing f;  F \<in> Increasing g |]  
   128      ==> F \<in> Increasing (%s. (f s) \<union> (g s))"
   129 apply (auto simp add: Increasing_def Stable_def Constrains_def
   130                       stable_def constrains_def)
   131 apply (drule_tac x = "f xa" in spec)
   132 apply (drule_tac x = "g xa" in spec)
   133 apply (blast dest!: bspec)
   134 done
   135 
   136 
   137 lemma Always_Un:
   138      "[| F \<in> Always {s. f' s \<le> f s}; F \<in> Always {s. g' s \<le> g s} |]  
   139       ==> F \<in> Always {s. f' s \<union> g' s \<le> f s \<union> g s}"
   140 by (simp add: Always_eq_includes_reachable, blast)
   141 
   142 (*Lemma to re-use the argument that one variable increases (progress)
   143   while the other variable doesn't decrease (safety)*)
   144 lemma Follows_Un_lemma:
   145      "[| F \<in> Increasing f; F \<in> Increasing g;  
   146          F \<in> Increasing g'; F \<in> Always {s. f' s \<le> f s}; 
   147          \<forall>k. F \<in> {s. k \<le> f s} LeadsTo {s. k \<le> f' s} |] 
   148       ==> F \<in> {s. k \<le> f s \<union> g s} LeadsTo {s. k \<le> f' s \<union> g s}"
   149 apply (rule single_LeadsTo_I)
   150 apply (drule_tac x = "f s" in IncreasingD)
   151 apply (drule_tac x = "g s" in IncreasingD)
   152 apply (rule LeadsTo_weaken)
   153 apply (rule PSP_Stable)
   154 apply (erule_tac x = "f s" in spec)
   155 apply (erule Stable_Int, assumption, blast+)
   156 done
   157 
   158 lemma Follows_Un: 
   159     "[| F \<in> f' Fols f;  F \<in> g' Fols g |]  
   160      ==> F \<in> (%s. (f' s) \<union> (g' s)) Fols (%s. (f s) \<union> (g s))"
   161 apply (simp add: Follows_def Increasing_Un Always_Un del: Un_subset_iff le_sup_iff, auto)
   162 apply (rule LeadsTo_Trans)
   163 apply (blast intro: Follows_Un_lemma)
   164 (*Weakening is used to exchange Un's arguments*)
   165 apply (blast intro: Follows_Un_lemma [THEN LeadsTo_weaken])
   166 done
   167 
   168 
   169 subsection{*Multiset union properties (with the multiset ordering)*}
   170 
   171 lemma increasing_union: 
   172     "[| F \<in> increasing f;  F \<in> increasing g |]  
   173      ==> F \<in> increasing (%s. (f s) + (g s :: ('a::order) multiset))"
   174 apply (simp add: increasing_def stable_def constrains_def, auto)
   175 apply (drule_tac x = "f xa" in spec)
   176 apply (drule_tac x = "g xa" in spec)
   177 apply (drule bspec, assumption) 
   178 apply (blast intro: add_mono order_trans)
   179 done
   180 
   181 lemma Increasing_union: 
   182     "[| F \<in> Increasing f;  F \<in> Increasing g |]  
   183      ==> F \<in> Increasing (%s. (f s) + (g s :: ('a::order) multiset))"
   184 apply (auto simp add: Increasing_def Stable_def Constrains_def
   185                       stable_def constrains_def)
   186 apply (drule_tac x = "f xa" in spec)
   187 apply (drule_tac x = "g xa" in spec)
   188 apply (drule bspec, assumption) 
   189 apply (blast intro: add_mono order_trans)
   190 done
   191 
   192 lemma Always_union:
   193      "[| F \<in> Always {s. f' s \<le> f s}; F \<in> Always {s. g' s \<le> g s} |]  
   194       ==> F \<in> Always {s. f' s + g' s \<le> f s + (g s :: ('a::order) multiset)}"
   195 apply (simp add: Always_eq_includes_reachable)
   196 apply (blast intro: add_mono)
   197 done
   198 
   199 (*Except the last line, IDENTICAL to the proof script for Follows_Un_lemma*)
   200 lemma Follows_union_lemma:
   201      "[| F \<in> Increasing f; F \<in> Increasing g;  
   202          F \<in> Increasing g'; F \<in> Always {s. f' s \<le> f s}; 
   203          \<forall>k::('a::order) multiset.  
   204            F \<in> {s. k \<le> f s} LeadsTo {s. k \<le> f' s} |] 
   205       ==> F \<in> {s. k \<le> f s + g s} LeadsTo {s. k \<le> f' s + g s}"
   206 apply (rule single_LeadsTo_I)
   207 apply (drule_tac x = "f s" in IncreasingD)
   208 apply (drule_tac x = "g s" in IncreasingD)
   209 apply (rule LeadsTo_weaken)
   210 apply (rule PSP_Stable)
   211 apply (erule_tac x = "f s" in spec)
   212 apply (erule Stable_Int, assumption, blast)
   213 apply (blast intro: add_mono order_trans)
   214 done
   215 
   216 (*The !! is there to influence to effect of permutative rewriting at the end*)
   217 lemma Follows_union: 
   218      "!!g g' ::'b => ('a::order) multiset.  
   219         [| F \<in> f' Fols f;  F \<in> g' Fols g |]  
   220         ==> F \<in> (%s. (f' s) + (g' s)) Fols (%s. (f s) + (g s))"
   221 apply (simp add: Follows_def)
   222 apply (simp add: Increasing_union Always_union, auto)
   223 apply (rule LeadsTo_Trans)
   224 apply (blast intro: Follows_union_lemma)
   225 (*now exchange union's arguments*)
   226 apply (simp add: union_commute)
   227 apply (blast intro: Follows_union_lemma)
   228 done
   229 
   230 lemma Follows_setsum:
   231      "!!f ::['c,'b] => ('a::order) multiset.  
   232         [| \<forall>i \<in> I. F \<in> f' i Fols f i;  finite I |]  
   233         ==> F \<in> (%s. \<Sum>i \<in> I. f' i s) Fols (%s. \<Sum>i \<in> I. f i s)"
   234 apply (erule rev_mp)
   235 apply (erule finite_induct, simp) 
   236 apply (simp add: Follows_union)
   237 done
   238 
   239 
   240 (*Currently UNUSED, but possibly of interest*)
   241 lemma Increasing_imp_Stable_pfixGe:
   242      "F \<in> Increasing func ==> F \<in> Stable {s. h pfixGe (func s)}"
   243 apply (simp add: Increasing_def Stable_def Constrains_def constrains_def)
   244 apply (blast intro: trans_Ge [THEN trans_genPrefix, THEN transD] 
   245                     prefix_imp_pfixGe)
   246 done
   247 
   248 (*Currently UNUSED, but possibly of interest*)
   249 lemma LeadsTo_le_imp_pfixGe:
   250      "\<forall>z. F \<in> {s. z \<le> f s} LeadsTo {s. z \<le> g s}  
   251       ==> F \<in> {s. z pfixGe f s} LeadsTo {s. z pfixGe g s}"
   252 apply (rule single_LeadsTo_I)
   253 apply (drule_tac x = "f s" in spec)
   254 apply (erule LeadsTo_weaken)
   255  prefer 2
   256  apply (blast intro: trans_Ge [THEN trans_genPrefix, THEN transD] 
   257                      prefix_imp_pfixGe, blast)
   258 done
   259 
   260 end