src/Pure/Isar/calculation.ML
author wenzelm
Fri Apr 08 16:34:14 2011 +0200 (2011-04-08)
changeset 42290 b1f544c84040
parent 39557 fe5722fce758
child 42360 da8817d01e7c
permissions -rw-r--r--
discontinued special treatment of structure Lexicon;
     1 (*  Title:      Pure/Isar/calculation.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Generic calculational proofs.
     5 *)
     6 
     7 signature CALCULATION =
     8 sig
     9   val print_rules: Proof.context -> unit
    10   val get_calculation: Proof.state -> thm list option
    11   val trans_add: attribute
    12   val trans_del: attribute
    13   val sym_add: attribute
    14   val sym_del: attribute
    15   val symmetric: attribute
    16   val also: thm list option -> bool -> Proof.state -> Proof.state Seq.seq
    17   val also_cmd: (Facts.ref * Attrib.src list) list option ->
    18     bool -> Proof.state -> Proof.state Seq.seq
    19   val finally: thm list option -> bool -> Proof.state -> Proof.state Seq.seq
    20   val finally_cmd: (Facts.ref * Attrib.src list) list option -> bool ->
    21     Proof.state -> Proof.state Seq.seq
    22   val moreover: bool -> Proof.state -> Proof.state
    23   val ultimately: bool -> Proof.state -> Proof.state
    24 end;
    25 
    26 structure Calculation: CALCULATION =
    27 struct
    28 
    29 (** calculation data **)
    30 
    31 structure Data = Generic_Data
    32 (
    33   type T = (thm Item_Net.T * thm list) * (thm list * int) option;
    34   val empty = ((Thm.elim_rules, []), NONE);
    35   val extend = I;
    36   fun merge (((trans1, sym1), _), ((trans2, sym2), _)) =
    37     ((Item_Net.merge (trans1, trans2), Thm.merge_thms (sym1, sym2)), NONE);
    38 );
    39 
    40 val get_rules = #1 o Data.get o Context.Proof;
    41 
    42 fun print_rules ctxt =
    43   let val (trans, sym) = get_rules ctxt in
    44     [Pretty.big_list "transitivity rules:"
    45         (map (Display.pretty_thm ctxt) (Item_Net.content trans)),
    46       Pretty.big_list "symmetry rules:" (map (Display.pretty_thm ctxt) sym)]
    47     |> Pretty.chunks |> Pretty.writeln
    48   end;
    49 
    50 
    51 (* access calculation *)
    52 
    53 fun get_calculation state =
    54   (case #2 (Data.get (Context.Proof (Proof.context_of state))) of
    55     NONE => NONE
    56   | SOME (thms, lev) => if lev = Proof.level state then SOME thms else NONE);
    57 
    58 val calculationN = "calculation";
    59 
    60 fun put_calculation calc =
    61   `Proof.level #-> (fn lev => Proof.map_context (Context.proof_map
    62      (Data.map (apsnd (K (Option.map (rpair lev) calc))))))
    63   #> Proof.put_thms false (calculationN, calc);
    64 
    65 
    66 
    67 (** attributes **)
    68 
    69 (* add/del rules *)
    70 
    71 val trans_add = Thm.declaration_attribute (Data.map o apfst o apfst o Item_Net.update);
    72 val trans_del = Thm.declaration_attribute (Data.map o apfst o apfst o Item_Net.remove);
    73 
    74 val sym_add =
    75   Thm.declaration_attribute (Data.map o apfst o apsnd o Thm.add_thm)
    76   #> Context_Rules.elim_query NONE;
    77 
    78 val sym_del =
    79   Thm.declaration_attribute (Data.map o apfst o apsnd o Thm.del_thm)
    80   #> Context_Rules.rule_del;
    81 
    82 
    83 (* symmetric *)
    84 
    85 val symmetric = Thm.rule_attribute (fn x => fn th =>
    86   (case Seq.chop 2 (Drule.multi_resolves [th] (#2 (#1 (Data.get x)))) of
    87     ([th'], _) => Drule.zero_var_indexes th'
    88   | ([], _) => raise THM ("symmetric: no unifiers", 1, [th])
    89   | _ => raise THM ("symmetric: multiple unifiers", 1, [th])));
    90 
    91 
    92 (* concrete syntax *)
    93 
    94 val _ = Context.>> (Context.map_theory
    95  (Attrib.setup (Binding.name "trans") (Attrib.add_del trans_add trans_del)
    96     "declaration of transitivity rule" #>
    97   Attrib.setup (Binding.name "sym") (Attrib.add_del sym_add sym_del)
    98     "declaration of symmetry rule" #>
    99   Attrib.setup (Binding.name "symmetric") (Scan.succeed symmetric)
   100     "resolution with symmetry rule" #>
   101   Global_Theory.add_thms
   102    [((Binding.empty, transitive_thm), [trans_add]),
   103     ((Binding.empty, symmetric_thm), [sym_add])] #> snd));
   104 
   105 
   106 
   107 (** proof commands **)
   108 
   109 fun assert_sane final =
   110   if final then Proof.assert_forward else Proof.assert_forward_or_chain;
   111 
   112 fun maintain_calculation int final calc state =
   113   let
   114     val state' = put_calculation (SOME calc) state;
   115     val ctxt' = Proof.context_of state';
   116     val _ =
   117       if int then
   118         Pretty.writeln
   119           (ProofContext.pretty_fact ctxt'
   120             (ProofContext.full_name ctxt' (Binding.name calculationN), calc))
   121       else ();
   122   in state' |> final ? (put_calculation NONE #> Proof.chain_facts calc) end;
   123 
   124 
   125 (* also and finally *)
   126 
   127 fun calculate prep_rules final raw_rules int state =
   128   let
   129     val ctxt = Proof.context_of state;
   130 
   131     val strip_assums_concl = Logic.strip_assums_concl o Thm.prop_of;
   132     val eq_prop = op aconv o pairself (Envir.beta_eta_contract o strip_assums_concl);
   133     fun projection ths th = exists (curry eq_prop th) ths;
   134 
   135     val opt_rules = Option.map (prep_rules ctxt) raw_rules;
   136     fun combine ths =
   137       (case opt_rules of SOME rules => rules
   138       | NONE =>
   139           (case ths of
   140             [] => Item_Net.content (#1 (get_rules ctxt))
   141           | th :: _ => Item_Net.retrieve (#1 (get_rules ctxt)) (strip_assums_concl th)))
   142       |> Seq.of_list |> Seq.maps (Drule.multi_resolve ths)
   143       |> Seq.filter (not o projection ths);
   144 
   145     val facts = Proof.the_facts (assert_sane final state);
   146     val (initial, calculations) =
   147       (case get_calculation state of
   148         NONE => (true, Seq.single facts)
   149       | SOME calc => (false, Seq.map single (combine (calc @ facts))));
   150 
   151     val _ = initial andalso final andalso error "No calculation yet";
   152     val _ = initial andalso is_some opt_rules andalso
   153       error "Initial calculation -- no rules to be given";
   154   in
   155     calculations |> Seq.map (fn calc => maintain_calculation int final calc state)
   156   end;
   157 
   158 val also = calculate (K I) false;
   159 val also_cmd = calculate Attrib.eval_thms false;
   160 val finally = calculate (K I) true;
   161 val finally_cmd = calculate Attrib.eval_thms true;
   162 
   163 
   164 (* moreover and ultimately *)
   165 
   166 fun collect final int state =
   167   let
   168     val facts = Proof.the_facts (assert_sane final state);
   169     val (initial, thms) =
   170       (case get_calculation state of
   171         NONE => (true, [])
   172       | SOME thms => (false, thms));
   173     val calc = thms @ facts;
   174     val _ = initial andalso final andalso error "No calculation yet";
   175   in maintain_calculation int final calc state end;
   176 
   177 val moreover = collect false;
   178 val ultimately = collect true;
   179 
   180 end;