src/Pure/Isar/local_defs.ML
author wenzelm
Fri Apr 08 16:34:14 2011 +0200 (2011-04-08)
changeset 42290 b1f544c84040
parent 41228 e1fce873b814
child 42357 3305f573294e
permissions -rw-r--r--
discontinued special treatment of structure Lexicon;
     1 (*  Title:      Pure/Isar/local_defs.ML
     2     Author:     Makarius
     3 
     4 Local definitions.
     5 *)
     6 
     7 signature LOCAL_DEFS =
     8 sig
     9   val cert_def: Proof.context -> term -> (string * typ) * term
    10   val abs_def: term -> (string * typ) * term
    11   val mk_def: Proof.context -> (string * term) list -> term list
    12   val expand: cterm list -> thm -> thm
    13   val def_export: Assumption.export
    14   val add_defs: ((binding * mixfix) * (Thm.binding * term)) list -> Proof.context ->
    15     (term * (string * thm)) list * Proof.context
    16   val add_def: (binding * mixfix) * term -> Proof.context -> (term * thm) * Proof.context
    17   val fixed_abbrev: (binding * mixfix) * term -> Proof.context ->
    18     (term * term) * Proof.context
    19   val export: Proof.context -> Proof.context -> thm -> thm list * thm
    20   val export_cterm: Proof.context -> Proof.context -> cterm -> thm list * cterm
    21   val trans_terms: Proof.context -> thm list -> thm
    22   val trans_props: Proof.context -> thm list -> thm
    23   val contract: Proof.context -> thm list -> cterm -> thm -> thm
    24   val print_rules: Proof.context -> unit
    25   val defn_add: attribute
    26   val defn_del: attribute
    27   val meta_rewrite_conv: Proof.context -> conv
    28   val meta_rewrite_rule: Proof.context -> thm -> thm
    29   val unfold: Proof.context -> thm list -> thm -> thm
    30   val unfold_goals: Proof.context -> thm list -> thm -> thm
    31   val unfold_tac: Proof.context -> thm list -> tactic
    32   val fold: Proof.context -> thm list -> thm -> thm
    33   val fold_tac: Proof.context -> thm list -> tactic
    34   val derived_def: Proof.context -> bool -> term ->
    35     ((string * typ) * term) * (Proof.context -> thm -> thm)
    36 end;
    37 
    38 structure Local_Defs: LOCAL_DEFS =
    39 struct
    40 
    41 (** primitive definitions **)
    42 
    43 (* prepare defs *)
    44 
    45 fun cert_def ctxt eq =
    46   let
    47     fun err msg =
    48       cat_error msg ("The error(s) above occurred in definition:\n" ^
    49         quote (Syntax.string_of_term ctxt eq));
    50     val ((lhs, _), eq') = eq
    51       |> Sign.no_vars ctxt
    52       |> Primitive_Defs.dest_def ctxt Term.is_Free (Variable.is_fixed ctxt) (K true)
    53       handle TERM (msg, _) => err msg | ERROR msg => err msg;
    54   in (Term.dest_Free (Term.head_of lhs), eq') end;
    55 
    56 val abs_def = Primitive_Defs.abs_def #>> Term.dest_Free;
    57 
    58 fun mk_def ctxt args =
    59   let
    60     val (xs, rhss) = split_list args;
    61     val (bind, _) = ProofContext.bind_fixes xs ctxt;
    62     val lhss = map (fn (x, rhs) => bind (Free (x, Term.fastype_of rhs))) args;
    63   in map Logic.mk_equals (lhss ~~ rhss) end;
    64 
    65 
    66 (* export defs *)
    67 
    68 val head_of_def =
    69   #1 o Term.dest_Free o Term.head_of o #1 o Logic.dest_equals o Term.strip_all_body;
    70 
    71 
    72 (*
    73   [x, x == a]
    74        :
    75       B x
    76   -----------
    77       B a
    78 *)
    79 fun expand defs =
    80   Drule.implies_intr_list defs
    81   #> Drule.generalize ([], map (head_of_def o Thm.term_of) defs)
    82   #> funpow (length defs) (fn th => Drule.reflexive_thm RS th);
    83 
    84 val expand_term = Envir.expand_term_frees o map (abs_def o Thm.term_of);
    85 
    86 fun def_export _ defs = (expand defs, expand_term defs);
    87 
    88 
    89 (* add defs *)
    90 
    91 fun add_defs defs ctxt =
    92   let
    93     val ((bvars, mxs), specs) = defs |> split_list |>> split_list;
    94     val ((bfacts, atts), rhss) = specs |> split_list |>> split_list;
    95     val xs = map Name.of_binding bvars;
    96     val names = map2 Thm.def_binding_optional bvars bfacts;
    97     val eqs = mk_def ctxt (xs ~~ rhss);
    98     val lhss = map (fst o Logic.dest_equals) eqs;
    99   in
   100     ctxt
   101     |> ProofContext.add_fixes (map2 (fn x => fn mx => (x, NONE, mx)) bvars mxs) |> #2
   102     |> fold Variable.declare_term eqs
   103     |> ProofContext.add_assms_i def_export
   104       (map2 (fn a => fn eq => (a, [(eq, [])])) (names ~~ atts) eqs)
   105     |>> map2 (fn lhs => fn (name, [th]) => (lhs, (name, th))) lhss
   106   end;
   107 
   108 fun add_def (var, rhs) ctxt =
   109   let val ([(lhs, (_, th))], ctxt') = add_defs [(var, (Thm.empty_binding, rhs))] ctxt
   110   in ((lhs, th), ctxt') end;
   111 
   112 
   113 (* fixed_abbrev *)
   114 
   115 fun fixed_abbrev ((x, mx), rhs) ctxt =
   116   let
   117     val T = Term.fastype_of rhs;
   118     val ([x'], ctxt') = ctxt
   119       |> Variable.declare_term rhs
   120       |> ProofContext.add_fixes [(x, SOME T, mx)];
   121     val lhs = Free (x', T);
   122     val _ = cert_def ctxt' (Logic.mk_equals (lhs, rhs));
   123     fun abbrev_export _ _ = (I, Envir.expand_term_frees [((x', T), rhs)]);
   124     val (_, ctxt'') = Assumption.add_assms abbrev_export [] ctxt';
   125   in ((lhs, rhs), ctxt'') end;
   126 
   127 
   128 (* specific export -- result based on educated guessing *)
   129 
   130 (*
   131   [xs, xs == as]
   132         :
   133        B xs
   134   --------------
   135        B as
   136 *)
   137 fun export inner outer =    (*beware of closure sizes*)
   138   let
   139     val exp = Assumption.export false inner outer;
   140     val prems = Assumption.all_prems_of inner;
   141   in fn th =>
   142     let
   143       val th' = exp th;
   144       val still_fixed = map #1 (Thm.fold_terms Term.add_frees th' []);
   145       val defs = prems |> filter_out (fn prem =>
   146         (case try (head_of_def o Thm.prop_of) prem of
   147           SOME x => member (op =) still_fixed x
   148         | NONE => true));
   149     in (map Drule.abs_def defs, th') end
   150   end;
   151 
   152 (*
   153   [xs, xs == as]
   154         :
   155      TERM b xs
   156   --------------  and  --------------
   157      TERM b as          b xs == b as
   158 *)
   159 fun export_cterm inner outer ct =
   160   export inner outer (Drule.mk_term ct) ||> Drule.dest_term;
   161 
   162 
   163 (* basic transitivity reasoning -- modulo beta-eta *)
   164 
   165 local
   166 
   167 val is_trivial = Pattern.aeconv o Logic.dest_equals o Thm.prop_of;
   168 
   169 fun trans_list _ _ [] = raise Empty
   170   | trans_list trans ctxt (th :: raw_eqs) =
   171       (case filter_out is_trivial raw_eqs of
   172         [] => th
   173       | eqs =>
   174           let val ((_, th' :: eqs'), ctxt') = Variable.import true (th :: eqs) ctxt
   175           in singleton (Variable.export ctxt' ctxt) (fold trans eqs' th') end);
   176 
   177 in
   178 
   179 val trans_terms = trans_list (fn eq2 => fn eq1 => eq2 COMP (eq1 COMP Drule.transitive_thm));
   180 val trans_props = trans_list (fn eq => fn th => th COMP (eq COMP Drule.equal_elim_rule1));
   181 
   182 end;
   183 
   184 fun contract ctxt defs ct th =
   185   trans_props ctxt [th, Thm.symmetric (Raw_Simplifier.rewrite true defs ct)];
   186 
   187 
   188 (** defived definitions **)
   189 
   190 (* transformation rules *)
   191 
   192 structure Rules = Generic_Data
   193 (
   194   type T = thm list;
   195   val empty = [];
   196   val extend = I;
   197   val merge = Thm.merge_thms;
   198 );
   199 
   200 fun print_rules ctxt =
   201   Pretty.writeln (Pretty.big_list "definitional transformations:"
   202     (map (Display.pretty_thm ctxt) (Rules.get (Context.Proof ctxt))));
   203 
   204 val defn_add = Thm.declaration_attribute (Rules.map o Thm.add_thm);
   205 val defn_del = Thm.declaration_attribute (Rules.map o Thm.del_thm);
   206 
   207 
   208 (* meta rewrite rules *)
   209 
   210 fun meta_rewrite_conv ctxt =
   211   Raw_Simplifier.rewrite_cterm (false, false, false) (K (K NONE))
   212     (Raw_Simplifier.context ctxt empty_ss
   213       addeqcongs [Drule.equals_cong]    (*protect meta-level equality*)
   214       addsimps (Rules.get (Context.Proof ctxt)));
   215 
   216 val meta_rewrite_rule = Conv.fconv_rule o meta_rewrite_conv;
   217 
   218 
   219 (* rewriting with object-level rules *)
   220 
   221 fun meta f ctxt = f o map (meta_rewrite_rule ctxt);
   222 
   223 val unfold       = meta Raw_Simplifier.rewrite_rule;
   224 val unfold_goals = meta Raw_Simplifier.rewrite_goals_rule;
   225 val unfold_tac   = meta Raw_Simplifier.rewrite_goals_tac;
   226 val fold         = meta Raw_Simplifier.fold_rule;
   227 val fold_tac     = meta Raw_Simplifier.fold_goals_tac;
   228 
   229 
   230 (* derived defs -- potentially within the object-logic *)
   231 
   232 fun derived_def ctxt conditional prop =
   233   let
   234     val ((c, T), rhs) = prop
   235       |> Thm.cterm_of (ProofContext.theory_of ctxt)
   236       |> meta_rewrite_conv ctxt
   237       |> (snd o Logic.dest_equals o Thm.prop_of)
   238       |> conditional ? Logic.strip_imp_concl
   239       |> (abs_def o #2 o cert_def ctxt);
   240     fun prove ctxt' def =
   241       let
   242         val frees = Term.fold_aterms (fn Free (x, _) =>
   243           if Variable.is_fixed ctxt' x then I else insert (op =) x | _ => I) prop [];
   244       in
   245         Goal.prove ctxt' frees [] prop (K (ALLGOALS
   246           (CONVERSION (meta_rewrite_conv ctxt') THEN'
   247             rewrite_goal_tac [def] THEN'
   248             resolve_tac [Drule.reflexive_thm])))
   249         handle ERROR msg => cat_error msg "Failed to prove definitional specification"
   250       end;
   251   in (((c, T), rhs), prove) end;
   252 
   253 end;