src/Pure/Isar/token.ML
author wenzelm
Fri Apr 08 16:34:14 2011 +0200 (2011-04-08)
changeset 42290 b1f544c84040
parent 40958 755f8fe7ced9
child 42503 27514b6fbe93
permissions -rw-r--r--
discontinued special treatment of structure Lexicon;
     1 (*  Title:      Pure/Isar/token.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Outer token syntax for Isabelle/Isar.
     5 *)
     6 
     7 signature TOKEN =
     8 sig
     9   datatype kind =
    10     Command | Keyword | Ident | LongIdent | SymIdent | Var | TypeIdent | TypeVar |
    11     Nat | Float | String | AltString | Verbatim | Space | Comment | InternalValue |
    12     Error of string | Sync | EOF
    13   datatype value =
    14     Text of string | Typ of typ | Term of term | Fact of thm list |
    15     Attribute of morphism -> attribute
    16   type T
    17   val str_of_kind: kind -> string
    18   val position_of: T -> Position.T
    19   val end_position_of: T -> Position.T
    20   val pos_of: T -> string
    21   val eof: T
    22   val is_eof: T -> bool
    23   val not_eof: T -> bool
    24   val not_sync: T -> bool
    25   val stopper: T Scan.stopper
    26   val kind_of: T -> kind
    27   val is_kind: kind -> T -> bool
    28   val keyword_with: (string -> bool) -> T -> bool
    29   val ident_with: (string -> bool) -> T -> bool
    30   val is_proper: T -> bool
    31   val is_semicolon: T -> bool
    32   val is_comment: T -> bool
    33   val is_begin_ignore: T -> bool
    34   val is_end_ignore: T -> bool
    35   val is_blank: T -> bool
    36   val is_newline: T -> bool
    37   val source_of: T -> string
    38   val source_position_of: T -> Symbol_Pos.text * Position.T
    39   val content_of: T -> string
    40   val unparse: T -> string
    41   val text_of: T -> string * string
    42   val get_value: T -> value option
    43   val map_value: (value -> value) -> T -> T
    44   val mk_text: string -> T
    45   val mk_typ: typ -> T
    46   val mk_term: term -> T
    47   val mk_fact: thm list -> T
    48   val mk_attribute: (morphism -> attribute) -> T
    49   val assignable: T -> T
    50   val assign: value option -> T -> unit
    51   val closure: T -> T
    52   val ident_or_symbolic: string -> bool
    53   val !!! : string -> (Symbol_Pos.T list -> 'a) -> Symbol_Pos.T list -> 'a
    54   val source_proper: (T, 'a) Source.source -> (T, (T, 'a) Source.source) Source.source
    55   val source': {do_recover: bool Option.option} -> (unit -> Scan.lexicon * Scan.lexicon) ->
    56     (Symbol_Pos.T, 'a) Source.source -> (T, (Symbol_Pos.T, 'a) Source.source) Source.source
    57   val source: {do_recover: bool Option.option} -> (unit -> Scan.lexicon * Scan.lexicon) ->
    58     Position.T -> (Symbol.symbol, 'a) Source.source -> (T,
    59       (Symbol_Pos.T, Position.T * (Symbol.symbol, 'a) Source.source) Source.source) Source.source
    60   val read_antiq: Scan.lexicon -> (T list -> 'a * T list) -> Symbol_Pos.T list * Position.T -> 'a
    61 end;
    62 
    63 structure Token: TOKEN =
    64 struct
    65 
    66 (** tokens **)
    67 
    68 (* token values *)
    69 
    70 (*The value slot assigns an (optional) internal value to a token,
    71   usually as a side-effect of special scanner setup (see also
    72   args.ML).  Note that an assignable ref designates an intermediate
    73   state of internalization -- it is NOT meant to persist.*)
    74 
    75 datatype value =
    76   Text of string |
    77   Typ of typ |
    78   Term of term |
    79   Fact of thm list |
    80   Attribute of morphism -> attribute;
    81 
    82 datatype slot =
    83   Slot |
    84   Value of value option |
    85   Assignable of value option Unsynchronized.ref;
    86 
    87 
    88 (* datatype token *)
    89 
    90 datatype kind =
    91   Command | Keyword | Ident | LongIdent | SymIdent | Var | TypeIdent | TypeVar |
    92   Nat | Float | String | AltString | Verbatim | Space | Comment | InternalValue |
    93   Error of string | Sync | EOF;
    94 
    95 datatype T = Token of (Symbol_Pos.text * Position.range) * (kind * string) * slot;
    96 
    97 val str_of_kind =
    98  fn Command => "command"
    99   | Keyword => "keyword"
   100   | Ident => "identifier"
   101   | LongIdent => "long identifier"
   102   | SymIdent => "symbolic identifier"
   103   | Var => "schematic variable"
   104   | TypeIdent => "type variable"
   105   | TypeVar => "schematic type variable"
   106   | Nat => "natural number"
   107   | Float => "floating-point number"
   108   | String => "string"
   109   | AltString => "back-quoted string"
   110   | Verbatim => "verbatim text"
   111   | Space => "white space"
   112   | Comment => "comment text"
   113   | InternalValue => "internal value"
   114   | Error _ => "bad input"
   115   | Sync => "sync marker"
   116   | EOF => "end-of-file";
   117 
   118 
   119 (* position *)
   120 
   121 fun position_of (Token ((_, (pos, _)), _, _)) = pos;
   122 fun end_position_of (Token ((_, (_, pos)), _, _)) = pos;
   123 
   124 val pos_of = Position.str_of o position_of;
   125 
   126 
   127 (* control tokens *)
   128 
   129 fun mk_eof pos = Token (("", (pos, Position.none)), (EOF, ""), Slot);
   130 val eof = mk_eof Position.none;
   131 
   132 fun is_eof (Token (_, (EOF, _), _)) = true
   133   | is_eof _ = false;
   134 
   135 val not_eof = not o is_eof;
   136 
   137 fun not_sync (Token (_, (Sync, _), _)) = false
   138   | not_sync _ = true;
   139 
   140 val stopper =
   141   Scan.stopper (fn [] => eof | toks => mk_eof (end_position_of (List.last toks))) is_eof;
   142 
   143 
   144 (* kind of token *)
   145 
   146 fun kind_of (Token (_, (k, _), _)) = k;
   147 fun is_kind k (Token (_, (k', _), _)) = k = k';
   148 
   149 fun keyword_with pred (Token (_, (Keyword, x), _)) = pred x
   150   | keyword_with _ _ = false;
   151 
   152 fun ident_with pred (Token (_, (Ident, x), _)) = pred x
   153   | ident_with _ _ = false;
   154 
   155 fun is_proper (Token (_, (Space, _), _)) = false
   156   | is_proper (Token (_, (Comment, _), _)) = false
   157   | is_proper _ = true;
   158 
   159 fun is_semicolon (Token (_, (Keyword, ";"), _)) = true
   160   | is_semicolon _ = false;
   161 
   162 fun is_comment (Token (_, (Comment, _), _)) = true
   163   | is_comment _ = false;
   164 
   165 fun is_begin_ignore (Token (_, (Comment, "<"), _)) = true
   166   | is_begin_ignore _ = false;
   167 
   168 fun is_end_ignore (Token (_, (Comment, ">"), _)) = true
   169   | is_end_ignore _ = false;
   170 
   171 
   172 (* blanks and newlines -- space tokens obey lines *)
   173 
   174 fun is_blank (Token (_, (Space, x), _)) = not (String.isSuffix "\n" x)
   175   | is_blank _ = false;
   176 
   177 fun is_newline (Token (_, (Space, x), _)) = String.isSuffix "\n" x
   178   | is_newline _ = false;
   179 
   180 
   181 (* token content *)
   182 
   183 fun source_of (Token ((source, (pos, _)), _, _)) =
   184   YXML.string_of (XML.Elem (Markup.token (Position.properties_of pos), [XML.Text source]));
   185 
   186 fun source_position_of (Token ((source, (pos, _)), _, _)) = (source, pos);
   187 
   188 fun content_of (Token (_, (_, x), _)) = x;
   189 
   190 
   191 (* unparse *)
   192 
   193 fun escape q =
   194   implode o map (fn s => if s = q orelse s = "\\" then "\\" ^ s else s) o Symbol.explode;
   195 
   196 fun unparse (Token (_, (kind, x), _)) =
   197   (case kind of
   198     String => x |> quote o escape "\""
   199   | AltString => x |> enclose "`" "`" o escape "`"
   200   | Verbatim => x |> enclose "{*" "*}"
   201   | Comment => x |> enclose "(*" "*)"
   202   | Sync => ""
   203   | EOF => ""
   204   | _ => x);
   205 
   206 fun text_of tok =
   207   if is_semicolon tok then ("terminator", "")
   208   else
   209     let
   210       val k = str_of_kind (kind_of tok);
   211       val s = unparse tok;
   212     in
   213       if s = "" then (k, "")
   214       else if size s < 40 andalso not (exists_string (fn c => c = "\n") s) then (k ^ " " ^ s, "")
   215       else (k, s)
   216     end;
   217 
   218 
   219 
   220 (** associated values **)
   221 
   222 (* access values *)
   223 
   224 fun get_value (Token (_, _, Value v)) = v
   225   | get_value _ = NONE;
   226 
   227 fun map_value f (Token (x, y, Value (SOME v))) = Token (x, y, Value (SOME (f v)))
   228   | map_value _ tok = tok;
   229 
   230 
   231 (* make values *)
   232 
   233 fun mk_value k v = Token ((k, Position.no_range), (InternalValue, k), Value (SOME v));
   234 
   235 val mk_text = mk_value "<text>" o Text;
   236 val mk_typ = mk_value "<typ>" o Typ;
   237 val mk_term = mk_value "<term>" o Term;
   238 val mk_fact = mk_value "<fact>" o Fact;
   239 val mk_attribute = mk_value "<attribute>" o Attribute;
   240 
   241 
   242 (* static binding *)
   243 
   244 (*1st stage: make empty slots assignable*)
   245 fun assignable (Token (x, y, Slot)) = Token (x, y, Assignable (Unsynchronized.ref NONE))
   246   | assignable tok = tok;
   247 
   248 (*2nd stage: assign values as side-effect of scanning*)
   249 fun assign v (Token (_, _, Assignable r)) = r := v
   250   | assign _ _ = ();
   251 
   252 (*3rd stage: static closure of final values*)
   253 fun closure (Token (x, y, Assignable (Unsynchronized.ref v))) = Token (x, y, Value v)
   254   | closure tok = tok;
   255 
   256 
   257 
   258 (** scanners **)
   259 
   260 open Basic_Symbol_Pos;
   261 
   262 fun !!! msg = Symbol_Pos.!!! ("Outer lexical error: " ^ msg);
   263 
   264 
   265 (* scan symbolic idents *)
   266 
   267 val is_sym_char = member (op =) (raw_explode "!#$%&*+-/<=>?@^_|~");
   268 
   269 val scan_symid =
   270   Scan.many1 (is_sym_char o Symbol_Pos.symbol) ||
   271   Scan.one (Symbol.is_symbolic o Symbol_Pos.symbol) >> single;
   272 
   273 fun is_symid str =
   274   (case try Symbol.explode str of
   275     SOME [s] => Symbol.is_symbolic s orelse is_sym_char s
   276   | SOME ss => forall is_sym_char ss
   277   | _ => false);
   278 
   279 fun ident_or_symbolic "begin" = false
   280   | ident_or_symbolic ":" = true
   281   | ident_or_symbolic "::" = true
   282   | ident_or_symbolic s = Lexicon.is_identifier s orelse is_symid s;
   283 
   284 
   285 (* scan verbatim text *)
   286 
   287 val scan_verb =
   288   $$$ "*" --| Scan.ahead (~$$$ "}") ||
   289   Scan.one (fn (s, _) => s <> "*" andalso Symbol.is_regular s) >> single;
   290 
   291 val scan_verbatim =
   292   (Symbol_Pos.scan_pos --| $$$ "{" --| $$$ "*") -- !!! "missing end of verbatim text"
   293     (Symbol_Pos.change_prompt
   294       ((Scan.repeat scan_verb >> flat) -- ($$$ "*" |-- $$$ "}" |-- Symbol_Pos.scan_pos)));
   295 
   296 
   297 (* scan space *)
   298 
   299 fun is_space s = Symbol.is_blank s andalso s <> "\n";
   300 
   301 val scan_space =
   302   Scan.many1 (is_space o Symbol_Pos.symbol) @@@ Scan.optional ($$$ "\n") [] ||
   303   Scan.many (is_space o Symbol_Pos.symbol) @@@ $$$ "\n";
   304 
   305 
   306 (* scan comment *)
   307 
   308 val scan_comment =
   309   Symbol_Pos.scan_pos -- (Symbol_Pos.scan_comment_body !!! -- Symbol_Pos.scan_pos);
   310 
   311 
   312 
   313 (** token sources **)
   314 
   315 fun source_proper src = src |> Source.filter is_proper;
   316 
   317 local
   318 
   319 fun token_leq ((_, syms1), (_, syms2)) = length syms1 <= length syms2;
   320 
   321 fun token k ss =
   322   Token ((Symbol_Pos.implode ss, Symbol_Pos.range ss), (k, Symbol_Pos.untabify_content ss), Slot);
   323 
   324 fun token_range k (pos1, (ss, pos2)) =
   325   Token (Symbol_Pos.implode_range pos1 pos2 ss, (k, Symbol_Pos.untabify_content ss), Slot);
   326 
   327 fun scan (lex1, lex2) = !!! "bad input"
   328   (Symbol_Pos.scan_string >> token_range String ||
   329     Symbol_Pos.scan_alt_string >> token_range AltString ||
   330     scan_verbatim >> token_range Verbatim ||
   331     scan_comment >> token_range Comment ||
   332     scan_space >> token Space ||
   333     Scan.one (Symbol.is_sync o Symbol_Pos.symbol) >> (token Sync o single) ||
   334     (Scan.max token_leq
   335       (Scan.max token_leq
   336         (Scan.literal lex2 >> pair Command)
   337         (Scan.literal lex1 >> pair Keyword))
   338       (Lexicon.scan_longid >> pair LongIdent ||
   339         Lexicon.scan_id >> pair Ident ||
   340         Lexicon.scan_var >> pair Var ||
   341         Lexicon.scan_tid >> pair TypeIdent ||
   342         Lexicon.scan_tvar >> pair TypeVar ||
   343         Lexicon.scan_float >> pair Float ||
   344         Lexicon.scan_nat >> pair Nat ||
   345         scan_symid >> pair SymIdent) >> uncurry token));
   346 
   347 fun recover msg =
   348   Scan.many ((Symbol.is_regular andf (not o Symbol.is_blank)) o Symbol_Pos.symbol)
   349   >> (single o token (Error msg));
   350 
   351 in
   352 
   353 fun source' {do_recover} get_lex =
   354   Source.source Symbol_Pos.stopper (Scan.bulk (fn xs => scan (get_lex ()) xs))
   355     (Option.map (rpair recover) do_recover);
   356 
   357 fun source do_recover get_lex pos src =
   358   Symbol_Pos.source pos src
   359   |> source' do_recover get_lex;
   360 
   361 end;
   362 
   363 
   364 (* read_antiq *)
   365 
   366 fun read_antiq lex scan (syms, pos) =
   367   let
   368     fun err msg = cat_error msg ("Malformed antiquotation" ^ Position.str_of pos ^ ":\n" ^
   369       "@{" ^ Symbol_Pos.content syms ^ "}");
   370 
   371     val res =
   372       Source.of_list syms
   373       |> source' {do_recover = NONE} (K (lex, Scan.empty_lexicon))
   374       |> source_proper
   375       |> Source.source stopper (Scan.error (Scan.bulk scan)) NONE
   376       |> Source.exhaust;
   377   in (case res of [x] => x | _ => err "") handle ERROR msg => err msg end;
   378 
   379 end;