src/HOL/Tools/Datatype/datatype.ML
author haftmann
Tue Oct 20 16:13:01 2009 +0200 (2009-10-20)
changeset 33037 b22e44496dc2
parent 32922 8e40cd05de7a
child 33038 8f9594c31de4
permissions -rw-r--r--
replaced old_style infixes eq_set, subset, union, inter and variants by generic versions
     1 (*  Title:      HOL/Tools/datatype.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Datatype package for Isabelle/HOL.
     5 *)
     6 
     7 signature DATATYPE =
     8 sig
     9   include DATATYPE_COMMON
    10   val add_datatype : config -> string list -> (string list * binding * mixfix *
    11     (binding * typ list * mixfix) list) list -> theory -> string list * theory
    12   val datatype_cmd : string list -> (string list * binding * mixfix *
    13     (binding * string list * mixfix) list) list -> theory -> theory
    14   val rep_datatype : config -> (string list -> Proof.context -> Proof.context)
    15     -> string list option -> term list -> theory -> Proof.state
    16   val rep_datatype_cmd : string list option -> string list -> theory -> Proof.state
    17   val get_info : theory -> string -> info option
    18   val the_info : theory -> string -> info
    19   val the_descr : theory -> string list
    20     -> descr * (string * sort) list * string list
    21       * string * (string list * string list) * (typ list * typ list)
    22   val the_spec : theory -> string -> (string * sort) list * (string * typ list) list
    23   val all_distincts : theory -> typ list -> thm list list
    24   val get_constrs : theory -> string -> (string * typ) list option
    25   val get_all : theory -> info Symtab.table
    26   val info_of_constr : theory -> string * typ -> info option
    27   val info_of_case : theory -> string -> info option
    28   val interpretation : (config -> string list -> theory -> theory) -> theory -> theory
    29   val distinct_simproc : simproc
    30   val make_case :  Proof.context -> DatatypeCase.config -> string list -> term ->
    31     (term * term) list -> term * (term * (int * bool)) list
    32   val strip_case : Proof.context -> bool -> term -> (term * (term * term) list) option
    33   val read_typ: theory ->
    34     (typ list * (string * sort) list) * string -> typ list * (string * sort) list
    35   val setup: theory -> theory
    36 end;
    37 
    38 structure Datatype : DATATYPE =
    39 struct
    40 
    41 open DatatypeAux;
    42 
    43 (** theory data **)
    44 
    45 (* data management *)
    46 
    47 structure DatatypesData = TheoryDataFun
    48 (
    49   type T =
    50     {types: info Symtab.table,
    51      constrs: (string * info) list Symtab.table,
    52      cases: info Symtab.table};
    53 
    54   val empty =
    55     {types = Symtab.empty, constrs = Symtab.empty, cases = Symtab.empty};
    56   val copy = I;
    57   val extend = I;
    58   fun merge _
    59     ({types = types1, constrs = constrs1, cases = cases1},
    60      {types = types2, constrs = constrs2, cases = cases2}) =
    61     {types = Symtab.merge (K true) (types1, types2),
    62      constrs = Symtab.join (K (AList.merge (op =) (K true))) (constrs1, constrs2),
    63      cases = Symtab.merge (K true) (cases1, cases2)};
    64 );
    65 
    66 val get_all = #types o DatatypesData.get;
    67 val get_info = Symtab.lookup o get_all;
    68 fun the_info thy name = (case get_info thy name of
    69       SOME info => info
    70     | NONE => error ("Unknown datatype " ^ quote name));
    71 
    72 fun info_of_constr thy (c, T) =
    73   let
    74     val tab = Symtab.lookup_list ((#constrs o DatatypesData.get) thy) c;
    75     val hint = case strip_type T of (_, Type (tyco, _)) => SOME tyco | _ => NONE;
    76     val default = if null tab then NONE
    77       else SOME (snd (Library.last_elem tab))
    78         (*conservative wrt. overloaded constructors*);
    79   in case hint
    80    of NONE => default
    81     | SOME tyco => case AList.lookup (op =) tab tyco
    82        of NONE => default (*permissive*)
    83         | SOME info => SOME info
    84   end;
    85 
    86 val info_of_case = Symtab.lookup o #cases o DatatypesData.get;
    87 
    88 fun register (dt_infos : (string * info) list) =
    89   DatatypesData.map (fn {types, constrs, cases} =>
    90     {types = types |> fold Symtab.update dt_infos,
    91      constrs = constrs |> fold (fn (constr, dtname_info) =>
    92          Symtab.map_default (constr, []) (cons dtname_info))
    93        (maps (fn (dtname, info as {descr, index, ...}) =>
    94           map (rpair (dtname, info) o fst)
    95             (#3 (the (AList.lookup op = descr index)))) dt_infos),
    96      cases = cases |> fold Symtab.update
    97        (map (fn (_, info as {case_name, ...}) => (case_name, info)) dt_infos)});
    98 
    99 (* complex queries *)
   100 
   101 fun the_spec thy dtco =
   102   let
   103     val info as { descr, index, sorts = raw_sorts, ... } = the_info thy dtco;
   104     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr index;
   105     val sorts = map ((fn v => (v, (the o AList.lookup (op =) raw_sorts) v))
   106       o DatatypeAux.dest_DtTFree) dtys;
   107     val cos = map
   108       (fn (co, tys) => (co, map (DatatypeAux.typ_of_dtyp descr sorts) tys)) raw_cos;
   109   in (sorts, cos) end;
   110 
   111 fun the_descr thy (raw_tycos as raw_tyco :: _) =
   112   let
   113     val info = the_info thy raw_tyco;
   114     val descr = #descr info;
   115 
   116     val SOME (_, dtys, raw_cos) = AList.lookup (op =) descr (#index info);
   117     val vs = map ((fn v => (v, (the o AList.lookup (op =) (#sorts info)) v))
   118       o dest_DtTFree) dtys;
   119 
   120     fun is_DtTFree (DtTFree _) = true
   121       | is_DtTFree _ = false
   122     val k = find_index (fn (_, (_, dTs, _)) => not (forall is_DtTFree dTs)) descr;
   123     val protoTs as (dataTs, _) = chop k descr
   124       |> (pairself o map) (fn (_, (tyco, dTs, _)) => (tyco, map (typ_of_dtyp descr vs) dTs));
   125     
   126     val tycos = map fst dataTs;
   127     val _ = if gen_eq_set (op =) (tycos, raw_tycos) then ()
   128       else error ("Type constructors " ^ commas (map quote raw_tycos)
   129         ^ " do not belong exhaustively to one mutual recursive datatype");
   130 
   131     val (Ts, Us) = (pairself o map) Type protoTs;
   132 
   133     val names = map Long_Name.base_name (the_default tycos (#alt_names info));
   134     val (auxnames, _) = Name.make_context names
   135       |> fold_map (yield_singleton Name.variants o name_of_typ) Us;
   136     val prefix = space_implode "_" names;
   137 
   138   in (descr, vs, tycos, prefix, (names, auxnames), (Ts, Us)) end;
   139 
   140 fun all_distincts thy Ts =
   141   let
   142     fun add_tycos (Type (tyco, Ts)) = insert (op =) tyco #> fold add_tycos Ts
   143       | add_tycos _ = I;
   144     val tycos = fold add_tycos Ts [];
   145   in map_filter (Option.map #distinct o get_info thy) tycos end;
   146 
   147 fun get_constrs thy dtco =
   148   case try (the_spec thy) dtco
   149    of SOME (sorts, cos) =>
   150         let
   151           fun subst (v, sort) = TVar ((v, 0), sort);
   152           fun subst_ty (TFree v) = subst v
   153             | subst_ty ty = ty;
   154           val dty = Type (dtco, map subst sorts);
   155           fun mk_co (co, tys) = (co, map (Term.map_atyps subst_ty) tys ---> dty);
   156         in SOME (map mk_co cos) end
   157     | NONE => NONE;
   158 
   159 
   160 (** various auxiliary **)
   161 
   162 (* simplification procedure for showing distinctness of constructors *)
   163 
   164 fun stripT (i, Type ("fun", [_, T])) = stripT (i + 1, T)
   165   | stripT p = p;
   166 
   167 fun stripC (i, f $ x) = stripC (i + 1, f)
   168   | stripC p = p;
   169 
   170 val distinctN = "constr_distinct";
   171 
   172 fun distinct_rule thy ss tname eq_t = Goal.prove (Simplifier.the_context ss) [] [] eq_t
   173   (K (EVERY [rtac eq_reflection 1, rtac iffI 1, rtac notE 1,
   174     atac 2, resolve_tac (#distinct (the_info thy tname)) 1, etac FalseE 1]));
   175 
   176 fun get_constr thy dtco =
   177   get_info thy dtco
   178   |> Option.map (fn { descr, index, ... } => (#3 o the o AList.lookup (op =) descr) index);
   179 
   180 fun distinct_proc thy ss (t as Const ("op =", _) $ t1 $ t2) =
   181   (case (stripC (0, t1), stripC (0, t2)) of
   182      ((i, Const (cname1, T1)), (j, Const (cname2, T2))) =>
   183          (case (stripT (0, T1), stripT (0, T2)) of
   184             ((i', Type (tname1, _)), (j', Type (tname2, _))) =>
   185                 if tname1 = tname2 andalso not (cname1 = cname2) andalso i = i' andalso j = j' then
   186                    (case get_constr thy tname1 of
   187                       SOME constrs => let val cnames = map fst constrs
   188                         in if cname1 mem cnames andalso cname2 mem cnames then
   189                              SOME (distinct_rule thy ss tname1
   190                                (Logic.mk_equals (t, HOLogic.false_const)))
   191                            else NONE
   192                         end
   193                     | NONE => NONE)
   194                 else NONE
   195           | _ => NONE)
   196    | _ => NONE)
   197   | distinct_proc _ _ _ = NONE;
   198 
   199 val distinct_simproc =
   200   Simplifier.simproc @{theory HOL} distinctN ["s = t"] distinct_proc;
   201 
   202 val simproc_setup =
   203   Simplifier.map_simpset (fn ss => ss addsimprocs [distinct_simproc]);
   204 
   205 (* prepare datatype specifications *)
   206 
   207 fun read_typ thy ((Ts, sorts), str) =
   208   let
   209     val ctxt = ProofContext.init thy
   210       |> fold (Variable.declare_typ o TFree) sorts;
   211     val T = Syntax.read_typ ctxt str;
   212   in (Ts @ [T], Term.add_tfreesT T sorts) end;
   213 
   214 fun cert_typ sign ((Ts, sorts), raw_T) =
   215   let
   216     val T = Type.no_tvars (Sign.certify_typ sign raw_T) handle
   217       TYPE (msg, _, _) => error msg;
   218     val sorts' = Term.add_tfreesT T sorts;
   219   in (Ts @ [T],
   220       case duplicates (op =) (map fst sorts') of
   221          [] => sorts'
   222        | dups => error ("Inconsistent sort constraints for " ^ commas dups))
   223   end;
   224 
   225 (* case names *)
   226 
   227 local
   228 
   229 fun dt_recs (DtTFree _) = []
   230   | dt_recs (DtType (_, dts)) = maps dt_recs dts
   231   | dt_recs (DtRec i) = [i];
   232 
   233 fun dt_cases (descr: descr) (_, args, constrs) =
   234   let
   235     fun the_bname i = Long_Name.base_name (#1 (the (AList.lookup (op =) descr i)));
   236     val bnames = map the_bname (distinct (op =) (maps dt_recs args));
   237   in map (fn (c, _) => space_implode "_" (Long_Name.base_name c :: bnames)) constrs end;
   238 
   239 fun induct_cases descr =
   240   DatatypeProp.indexify_names (maps (dt_cases descr) (map #2 descr));
   241 
   242 fun exhaust_cases descr i = dt_cases descr (the (AList.lookup (op =) descr i));
   243 
   244 in
   245 
   246 fun mk_case_names_induct descr = RuleCases.case_names (induct_cases descr);
   247 
   248 fun mk_case_names_exhausts descr new =
   249   map (RuleCases.case_names o exhaust_cases descr o #1)
   250     (filter (fn ((_, (name, _, _))) => member (op =) new name) descr);
   251 
   252 end;
   253 
   254 (* translation rules for case *)
   255 
   256 fun make_case ctxt = DatatypeCase.make_case
   257   (info_of_constr (ProofContext.theory_of ctxt)) ctxt;
   258 
   259 fun strip_case ctxt = DatatypeCase.strip_case
   260   (info_of_case (ProofContext.theory_of ctxt));
   261 
   262 fun add_case_tr' case_names thy =
   263   Sign.add_advanced_trfuns ([], [],
   264     map (fn case_name =>
   265       let val case_name' = Sign.const_syntax_name thy case_name
   266       in (case_name', DatatypeCase.case_tr' info_of_case case_name')
   267       end) case_names, []) thy;
   268 
   269 val trfun_setup =
   270   Sign.add_advanced_trfuns ([],
   271     [("_case_syntax", DatatypeCase.case_tr true info_of_constr)],
   272     [], []);
   273 
   274 (* document antiquotation *)
   275 
   276 val _ = ThyOutput.antiquotation "datatype" Args.tyname
   277   (fn {source = src, context = ctxt, ...} => fn dtco =>
   278     let
   279       val thy = ProofContext.theory_of ctxt;
   280       val (vs, cos) = the_spec thy dtco;
   281       val ty = Type (dtco, map TFree vs);
   282       fun pretty_typ_bracket (ty as Type (_, _ :: _)) =
   283             Pretty.enclose "(" ")" [Syntax.pretty_typ ctxt ty]
   284         | pretty_typ_bracket ty =
   285             Syntax.pretty_typ ctxt ty;
   286       fun pretty_constr (co, tys) =
   287         (Pretty.block o Pretty.breaks)
   288           (Syntax.pretty_term ctxt (Const (co, tys ---> ty)) ::
   289             map pretty_typ_bracket tys);
   290       val pretty_datatype =
   291         Pretty.block
   292           (Pretty.command "datatype" :: Pretty.brk 1 ::
   293            Syntax.pretty_typ ctxt ty ::
   294            Pretty.str " =" :: Pretty.brk 1 ::
   295            flat (separate [Pretty.brk 1, Pretty.str "| "]
   296              (map (single o pretty_constr) cos)));
   297     in ThyOutput.output (ThyOutput.maybe_pretty_source (K pretty_datatype) src [()]) end);
   298 
   299 
   300 (** abstract theory extensions relative to a datatype characterisation **)
   301 
   302 structure DatatypeInterpretation = InterpretationFun
   303   (type T = config * string list val eq: T * T -> bool = eq_snd op =);
   304 fun interpretation f = DatatypeInterpretation.interpretation (uncurry f);
   305 
   306 fun make_dt_info alt_names descr sorts induct inducts rec_names rec_rewrites
   307     (index, (((((((((((_, (tname, _, _))), inject), distinct),
   308       exhaust), nchotomy), case_name), case_rewrites), case_cong), weak_case_cong), (split, split_asm))) =
   309   (tname,
   310    {index = index,
   311     alt_names = alt_names,
   312     descr = descr,
   313     sorts = sorts,
   314     inject = inject,
   315     distinct = distinct,
   316     induct = induct,
   317     inducts = inducts,
   318     exhaust = exhaust,
   319     nchotomy = nchotomy,
   320     rec_names = rec_names,
   321     rec_rewrites = rec_rewrites,
   322     case_name = case_name,
   323     case_rewrites = case_rewrites,
   324     case_cong = case_cong,
   325     weak_case_cong = weak_case_cong,
   326     split = split,
   327     split_asm = split_asm});
   328 
   329 fun derive_datatype_props config dt_names alt_names descr sorts
   330     induct inject distinct thy1 =
   331   let
   332     val thy2 = thy1 |> Theory.checkpoint;
   333     val flat_descr = flat descr;
   334     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   335     val _ = message config ("Deriving properties for datatype(s) " ^ commas_quote new_type_names);
   336 
   337     val (exhaust, thy3) = DatatypeAbsProofs.prove_casedist_thms config new_type_names
   338       descr sorts induct (mk_case_names_exhausts flat_descr dt_names) thy2;
   339     val (nchotomys, thy4) = DatatypeAbsProofs.prove_nchotomys config new_type_names
   340       descr sorts exhaust thy3;
   341     val ((rec_names, rec_rewrites), thy5) = DatatypeAbsProofs.prove_primrec_thms
   342       config new_type_names descr sorts (#inject o the o Symtab.lookup (get_all thy4))
   343       inject (distinct, all_distincts thy2 (get_rec_types flat_descr sorts))
   344       induct thy4;
   345     val ((case_rewrites, case_names), thy6) = DatatypeAbsProofs.prove_case_thms
   346       config new_type_names descr sorts rec_names rec_rewrites thy5;
   347     val (case_congs, thy7) = DatatypeAbsProofs.prove_case_congs new_type_names
   348       descr sorts nchotomys case_rewrites thy6;
   349     val (weak_case_congs, thy8) = DatatypeAbsProofs.prove_weak_case_congs new_type_names
   350       descr sorts thy7;
   351     val (splits, thy9) = DatatypeAbsProofs.prove_split_thms
   352       config new_type_names descr sorts inject distinct exhaust case_rewrites thy8;
   353 
   354     val inducts = Project_Rule.projections (ProofContext.init thy2) induct;
   355     val dt_infos = map_index (make_dt_info alt_names flat_descr sorts induct inducts rec_names rec_rewrites)
   356       (hd descr ~~ inject ~~ distinct ~~ exhaust ~~ nchotomys ~~
   357         case_names ~~ case_rewrites ~~ case_congs ~~ weak_case_congs ~~ splits);
   358     val dt_names = map fst dt_infos;
   359     val prfx = Binding.qualify true (space_implode "_" new_type_names);
   360     val simps = flat (inject @ distinct @ case_rewrites) @ rec_rewrites;
   361     val named_rules = flat (map_index (fn (index, tname) =>
   362       [((Binding.empty, [nth inducts index]), [Induct.induct_type tname]),
   363        ((Binding.empty, [nth exhaust index]), [Induct.cases_type tname])]) dt_names);
   364     val unnamed_rules = map (fn induct =>
   365       ((Binding.empty, [induct]), [Thm.kind_internal, Induct.induct_type ""]))
   366         (Library.drop (length dt_names, inducts));
   367   in
   368     thy9
   369     |> PureThy.add_thmss ([((prfx (Binding.name "simps"), simps), []),
   370         ((prfx (Binding.name "inducts"), inducts), []),
   371         ((prfx (Binding.name "splits"), maps (fn (x, y) => [x, y]) splits), []),
   372         ((Binding.empty, flat case_rewrites @ flat distinct @ rec_rewrites),
   373           [Simplifier.simp_add]),
   374         ((Binding.empty, rec_rewrites), [Code.add_default_eqn_attribute]),
   375         ((Binding.empty, flat inject), [iff_add]),
   376         ((Binding.empty, map (fn th => th RS notE) (flat distinct)),
   377           [Classical.safe_elim NONE]),
   378         ((Binding.empty, weak_case_congs), [Simplifier.attrib (op addcongs)])]
   379         @ named_rules @ unnamed_rules)
   380     |> snd
   381     |> add_case_tr' case_names
   382     |> register dt_infos
   383     |> DatatypeInterpretation.data (config, dt_names)
   384     |> pair dt_names
   385   end;
   386 
   387 
   388 (** declare existing type as datatype **)
   389 
   390 fun prove_rep_datatype config dt_names alt_names descr sorts raw_inject half_distinct raw_induct thy1 =
   391   let
   392     val raw_distinct = (map o maps) (fn thm => [thm, thm RS not_sym]) half_distinct;
   393     val new_type_names = map Long_Name.base_name (the_default dt_names alt_names);
   394     val (((inject, distinct), [induct]), thy2) =
   395       thy1
   396       |> store_thmss "inject" new_type_names raw_inject
   397       ||>> store_thmss "distinct" new_type_names raw_distinct
   398       ||> Sign.add_path (space_implode "_" new_type_names)
   399       ||>> PureThy.add_thms [((Binding.name "induct", raw_induct), [mk_case_names_induct descr])]
   400       ||> Sign.restore_naming thy1;
   401   in
   402     thy2
   403     |> derive_datatype_props config dt_names alt_names [descr] sorts
   404          induct inject distinct
   405  end;
   406 
   407 fun gen_rep_datatype prep_term config after_qed alt_names raw_ts thy =
   408   let
   409     fun constr_of_term (Const (c, T)) = (c, T)
   410       | constr_of_term t =
   411           error ("Not a constant: " ^ Syntax.string_of_term_global thy t);
   412     fun no_constr (c, T) = error ("Bad constructor: "
   413       ^ Sign.extern_const thy c ^ "::"
   414       ^ Syntax.string_of_typ_global thy T);
   415     fun type_of_constr (cT as (_, T)) =
   416       let
   417         val frees = OldTerm.typ_tfrees T;
   418         val (tyco, vs) = ((apsnd o map) (dest_TFree) o dest_Type o snd o strip_type) T
   419           handle TYPE _ => no_constr cT
   420         val _ = if has_duplicates (eq_fst (op =)) vs then no_constr cT else ();
   421         val _ = if length frees <> length vs then no_constr cT else ();
   422       in (tyco, (vs, cT)) end;
   423 
   424     val raw_cs = AList.group (op =) (map (type_of_constr o constr_of_term o prep_term thy) raw_ts);
   425     val _ = case map_filter (fn (tyco, _) =>
   426         if Symtab.defined (get_all thy) tyco then SOME tyco else NONE) raw_cs
   427      of [] => ()
   428       | tycos => error ("Type(s) " ^ commas (map quote tycos)
   429           ^ " already represented inductivly");
   430     val raw_vss = maps (map (map snd o fst) o snd) raw_cs;
   431     val ms = case distinct (op =) (map length raw_vss)
   432      of [n] => 0 upto n - 1
   433       | _ => error ("Different types in given constructors");
   434     fun inter_sort m = map (fn xs => nth xs m) raw_vss
   435       |> Library.foldr1 (Sorts.inter_sort (Sign.classes_of thy))
   436     val sorts = map inter_sort ms;
   437     val vs = Name.names Name.context Name.aT sorts;
   438 
   439     fun norm_constr (raw_vs, (c, T)) = (c, map_atyps
   440       (TFree o (the o AList.lookup (op =) (map fst raw_vs ~~ vs)) o fst o dest_TFree) T);
   441 
   442     val cs = map (apsnd (map norm_constr)) raw_cs;
   443     val dtyps_of_typ = map (dtyp_of_typ (map (rpair (map fst vs) o fst) cs))
   444       o fst o strip_type;
   445     val dt_names = map fst cs;
   446 
   447     fun mk_spec (i, (tyco, constr)) = (i, (tyco,
   448       map (DtTFree o fst) vs,
   449       (map o apsnd) dtyps_of_typ constr))
   450     val descr = map_index mk_spec cs;
   451     val injs = DatatypeProp.make_injs [descr] vs;
   452     val half_distincts = map snd (DatatypeProp.make_distincts [descr] vs);
   453     val ind = DatatypeProp.make_ind [descr] vs;
   454     val rules = (map o map o map) Logic.close_form [[[ind]], injs, half_distincts];
   455 
   456     fun after_qed' raw_thms =
   457       let
   458         val [[[raw_induct]], raw_inject, half_distinct] =
   459           unflat rules (map Drule.zero_var_indexes_list raw_thms);
   460             (*FIXME somehow dubious*)
   461       in
   462         ProofContext.theory_result
   463           (prove_rep_datatype config dt_names alt_names descr vs raw_inject half_distinct raw_induct)
   464         #-> after_qed
   465       end;
   466   in
   467     thy
   468     |> ProofContext.init
   469     |> Proof.theorem_i NONE after_qed' ((map o map) (rpair []) (flat rules))
   470   end;
   471 
   472 val rep_datatype = gen_rep_datatype Sign.cert_term;
   473 val rep_datatype_cmd = gen_rep_datatype Syntax.read_term_global default_config (K I);
   474 
   475 
   476 (** definitional introduction of datatypes **)
   477 
   478 fun gen_add_datatype prep_typ config new_type_names dts thy =
   479   let
   480     val _ = Theory.requires thy "Datatype" "datatype definitions";
   481 
   482     (* this theory is used just for parsing *)
   483     val tmp_thy = thy |>
   484       Theory.copy |>
   485       Sign.add_types (map (fn (tvs, tname, mx, _) =>
   486         (tname, length tvs, mx)) dts);
   487 
   488     val (tyvars, _, _, _)::_ = dts;
   489     val (new_dts, types_syntax) = ListPair.unzip (map (fn (tvs, tname, mx, _) =>
   490       let val full_tname = Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname)
   491       in (case duplicates (op =) tvs of
   492             [] => if gen_eq_set (op =) (tyvars, tvs) then ((full_tname, tvs), (tname, mx))
   493                   else error ("Mutually recursive datatypes must have same type parameters")
   494           | dups => error ("Duplicate parameter(s) for datatype " ^ quote (Binding.str_of tname) ^
   495               " : " ^ commas dups))
   496       end) dts);
   497     val dt_names = map fst new_dts;
   498 
   499     val _ = (case duplicates (op =) (map fst new_dts) @ duplicates (op =) new_type_names of
   500       [] => () | dups => error ("Duplicate datatypes: " ^ commas dups));
   501 
   502     fun prep_dt_spec ((tvs, tname, mx, constrs), tname') (dts', constr_syntax, sorts, i) =
   503       let
   504         fun prep_constr (cname, cargs, mx') (constrs, constr_syntax', sorts') =
   505           let
   506             val (cargs', sorts'') = Library.foldl (prep_typ tmp_thy) (([], sorts'), cargs);
   507             val _ = (case fold (curry OldTerm.add_typ_tfree_names) cargs' [] \\ tvs of
   508                 [] => ()
   509               | vs => error ("Extra type variables on rhs: " ^ commas vs))
   510           in (constrs @ [(Sign.full_name_path tmp_thy tname'
   511                   (Binding.map_name (Syntax.const_name mx') cname),
   512                    map (dtyp_of_typ new_dts) cargs')],
   513               constr_syntax' @ [(cname, mx')], sorts'')
   514           end handle ERROR msg => cat_error msg
   515            ("The error above occured in constructor " ^ quote (Binding.str_of cname) ^
   516             " of datatype " ^ quote (Binding.str_of tname));
   517 
   518         val (constrs', constr_syntax', sorts') =
   519           fold prep_constr constrs ([], [], sorts)
   520 
   521       in
   522         case duplicates (op =) (map fst constrs') of
   523            [] =>
   524              (dts' @ [(i, (Sign.full_name tmp_thy (Binding.map_name (Syntax.type_name mx) tname),
   525                 map DtTFree tvs, constrs'))],
   526               constr_syntax @ [constr_syntax'], sorts', i + 1)
   527          | dups => error ("Duplicate constructors " ^ commas dups ^
   528              " in datatype " ^ quote (Binding.str_of tname))
   529       end;
   530 
   531     val (dts', constr_syntax, sorts', i) =
   532       fold prep_dt_spec (dts ~~ new_type_names) ([], [], [], 0);
   533     val sorts = sorts' @ (map (rpair (Sign.defaultS tmp_thy)) (tyvars \\ map fst sorts'));
   534     val dt_info = get_all thy;
   535     val (descr, _) = unfold_datatypes tmp_thy dts' sorts dt_info dts' i;
   536     val _ = check_nonempty descr handle (exn as Datatype_Empty s) =>
   537       if #strict config then error ("Nonemptiness check failed for datatype " ^ s)
   538       else raise exn;
   539 
   540     val _ = message config ("Constructing datatype(s) " ^ commas_quote new_type_names);
   541     val ((inject, distinct, induct), thy') = thy |>
   542       DatatypeRepProofs.representation_proofs config dt_info new_type_names descr sorts
   543         types_syntax constr_syntax (mk_case_names_induct (flat descr));
   544   in
   545     derive_datatype_props config dt_names (SOME new_type_names) descr sorts
   546       induct inject distinct thy'
   547   end;
   548 
   549 val add_datatype = gen_add_datatype cert_typ;
   550 val datatype_cmd = snd ooo gen_add_datatype read_typ default_config;
   551 
   552 
   553 (** package setup **)
   554 
   555 (* setup theory *)
   556 
   557 val setup =
   558   trfun_setup #>
   559   DatatypeInterpretation.init;
   560 
   561 (* outer syntax *)
   562 
   563 local
   564 
   565 structure P = OuterParse and K = OuterKeyword
   566 
   567 fun prep_datatype_decls args =
   568   let
   569     val names = map
   570       (fn ((((NONE, _), t), _), _) => Binding.name_of t | ((((SOME t, _), _), _), _) => t) args;
   571     val specs = map (fn ((((_, vs), t), mx), cons) =>
   572       (vs, t, mx, map (fn ((x, y), z) => (x, y, z)) cons)) args;
   573   in (names, specs) end;
   574 
   575 val parse_datatype_decl =
   576   (Scan.option (P.$$$ "(" |-- P.name --| P.$$$ ")") -- P.type_args -- P.binding -- P.opt_infix --
   577     (P.$$$ "=" |-- P.enum1 "|" (P.binding -- Scan.repeat P.typ -- P.opt_mixfix)));
   578 
   579 val parse_datatype_decls = P.and_list1 parse_datatype_decl >> prep_datatype_decls;
   580 
   581 in
   582 
   583 val _ =
   584   OuterSyntax.command "datatype" "define inductive datatypes" K.thy_decl
   585     (parse_datatype_decls >> (fn (names, specs) => Toplevel.theory (datatype_cmd names specs)));
   586 
   587 val _ =
   588   OuterSyntax.command "rep_datatype" "represent existing types inductively" K.thy_goal
   589     (Scan.option (P.$$$ "(" |-- Scan.repeat1 P.name --| P.$$$ ")") -- Scan.repeat1 P.term
   590       >> (fn (alt_names, ts) => Toplevel.print
   591            o Toplevel.theory_to_proof (rep_datatype_cmd alt_names ts)));
   592 
   593 end;
   594 
   595 end;
   596