src/Pure/drule.ML
author haftmann
Tue Oct 20 16:13:01 2009 +0200 (2009-10-20)
changeset 33037 b22e44496dc2
parent 32958 3228627994d9
child 33095 bbd52d2f8696
permissions -rw-r--r--
replaced old_style infixes eq_set, subset, union, inter and variants by generic versions
     1 (*  Title:      Pure/drule.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3 
     4 Derived rules and other operations on theorems.
     5 *)
     6 
     7 infix 0 RS RSN RL RLN MRS MRL OF COMP INCR_COMP COMP_INCR;
     8 
     9 signature BASIC_DRULE =
    10 sig
    11   val mk_implies: cterm * cterm -> cterm
    12   val list_implies: cterm list * cterm -> cterm
    13   val strip_imp_prems: cterm -> cterm list
    14   val strip_imp_concl: cterm -> cterm
    15   val cprems_of: thm -> cterm list
    16   val cterm_fun: (term -> term) -> (cterm -> cterm)
    17   val ctyp_fun: (typ -> typ) -> (ctyp -> ctyp)
    18   val forall_intr_list: cterm list -> thm -> thm
    19   val forall_intr_frees: thm -> thm
    20   val forall_intr_vars: thm -> thm
    21   val forall_elim_list: cterm list -> thm -> thm
    22   val gen_all: thm -> thm
    23   val lift_all: cterm -> thm -> thm
    24   val freeze_thaw: thm -> thm * (thm -> thm)
    25   val freeze_thaw_robust: thm -> thm * (int -> thm -> thm)
    26   val implies_elim_list: thm -> thm list -> thm
    27   val implies_intr_list: cterm list -> thm -> thm
    28   val instantiate: (ctyp * ctyp) list * (cterm * cterm) list -> thm -> thm
    29   val zero_var_indexes_list: thm list -> thm list
    30   val zero_var_indexes: thm -> thm
    31   val implies_intr_hyps: thm -> thm
    32   val rotate_prems: int -> thm -> thm
    33   val rearrange_prems: int list -> thm -> thm
    34   val RSN: thm * (int * thm) -> thm
    35   val RS: thm * thm -> thm
    36   val RLN: thm list * (int * thm list) -> thm list
    37   val RL: thm list * thm list -> thm list
    38   val MRS: thm list * thm -> thm
    39   val MRL: thm list list * thm list -> thm list
    40   val OF: thm * thm list -> thm
    41   val compose: thm * int * thm -> thm list
    42   val COMP: thm * thm -> thm
    43   val INCR_COMP: thm * thm -> thm
    44   val COMP_INCR: thm * thm -> thm
    45   val cterm_instantiate: (cterm*cterm)list -> thm -> thm
    46   val size_of_thm: thm -> int
    47   val reflexive_thm: thm
    48   val symmetric_thm: thm
    49   val transitive_thm: thm
    50   val symmetric_fun: thm -> thm
    51   val extensional: thm -> thm
    52   val equals_cong: thm
    53   val imp_cong: thm
    54   val swap_prems_eq: thm
    55   val asm_rl: thm
    56   val cut_rl: thm
    57   val revcut_rl: thm
    58   val thin_rl: thm
    59   val triv_forall_equality: thm
    60   val distinct_prems_rl: thm
    61   val swap_prems_rl: thm
    62   val equal_intr_rule: thm
    63   val equal_elim_rule1: thm
    64   val equal_elim_rule2: thm
    65   val instantiate': ctyp option list -> cterm option list -> thm -> thm
    66 end;
    67 
    68 signature DRULE =
    69 sig
    70   include BASIC_DRULE
    71   val generalize: string list * string list -> thm -> thm
    72   val list_comb: cterm * cterm list -> cterm
    73   val strip_comb: cterm -> cterm * cterm list
    74   val strip_type: ctyp -> ctyp list * ctyp
    75   val beta_conv: cterm -> cterm -> cterm
    76   val types_sorts: thm -> (indexname-> typ option) * (indexname-> sort option)
    77   val flexflex_unique: thm -> thm
    78   val standard: thm -> thm
    79   val standard': thm -> thm
    80   val get_def: theory -> xstring -> thm
    81   val store_thm: bstring -> thm -> thm
    82   val store_standard_thm: bstring -> thm -> thm
    83   val store_thm_open: bstring -> thm -> thm
    84   val store_standard_thm_open: bstring -> thm -> thm
    85   val compose_single: thm * int * thm -> thm
    86   val imp_cong_rule: thm -> thm -> thm
    87   val arg_cong_rule: cterm -> thm -> thm
    88   val binop_cong_rule: cterm -> thm -> thm -> thm
    89   val fun_cong_rule: thm -> cterm -> thm
    90   val beta_eta_conversion: cterm -> thm
    91   val eta_long_conversion: cterm -> thm
    92   val eta_contraction_rule: thm -> thm
    93   val norm_hhf_eq: thm
    94   val norm_hhf_eqs: thm list
    95   val is_norm_hhf: term -> bool
    96   val norm_hhf: theory -> term -> term
    97   val norm_hhf_cterm: cterm -> cterm
    98   val protect: cterm -> cterm
    99   val protectI: thm
   100   val protectD: thm
   101   val protect_cong: thm
   102   val implies_intr_protected: cterm list -> thm -> thm
   103   val termI: thm
   104   val mk_term: cterm -> thm
   105   val dest_term: thm -> cterm
   106   val cterm_rule: (thm -> thm) -> cterm -> cterm
   107   val term_rule: theory -> (thm -> thm) -> term -> term
   108   val dummy_thm: thm
   109   val sort_constraintI: thm
   110   val sort_constraint_eq: thm
   111   val unconstrainTs: thm -> thm
   112   val with_subgoal: int -> (thm -> thm) -> thm -> thm
   113   val comp_no_flatten: thm * int -> int -> thm -> thm
   114   val rename_bvars: (string * string) list -> thm -> thm
   115   val rename_bvars': string option list -> thm -> thm
   116   val incr_type_indexes: int -> thm -> thm
   117   val incr_indexes: thm -> thm -> thm
   118   val incr_indexes2: thm -> thm -> thm -> thm
   119   val remdups_rl: thm
   120   val multi_resolve: thm list -> thm -> thm Seq.seq
   121   val multi_resolves: thm list -> thm list -> thm Seq.seq
   122   val abs_def: thm -> thm
   123 end;
   124 
   125 structure Drule: DRULE =
   126 struct
   127 
   128 
   129 (** some cterm->cterm operations: faster than calling cterm_of! **)
   130 
   131 (* A1==>...An==>B  goes to  [A1,...,An], where B is not an implication *)
   132 fun strip_imp_prems ct =
   133   let val (cA, cB) = Thm.dest_implies ct
   134   in cA :: strip_imp_prems cB end
   135   handle TERM _ => [];
   136 
   137 (* A1==>...An==>B  goes to B, where B is not an implication *)
   138 fun strip_imp_concl ct =
   139   (case Thm.term_of ct of
   140     Const ("==>", _) $ _ $ _ => strip_imp_concl (Thm.dest_arg ct)
   141   | _ => ct);
   142 
   143 (*The premises of a theorem, as a cterm list*)
   144 val cprems_of = strip_imp_prems o cprop_of;
   145 
   146 fun cterm_fun f ct = Thm.cterm_of (Thm.theory_of_cterm ct) (f (Thm.term_of ct));
   147 fun ctyp_fun f cT = Thm.ctyp_of (Thm.theory_of_ctyp cT) (f (Thm.typ_of cT));
   148 
   149 fun certify t = Thm.cterm_of (Context.the_theory (Context.the_thread_data ())) t;
   150 
   151 val implies = certify Logic.implies;
   152 fun mk_implies (A, B) = Thm.capply (Thm.capply implies A) B;
   153 
   154 (*cterm version of list_implies: [A1,...,An], B  goes to [|A1;==>;An|]==>B *)
   155 fun list_implies([], B) = B
   156   | list_implies(A::AS, B) = mk_implies (A, list_implies(AS,B));
   157 
   158 (*cterm version of list_comb: maps  (f, [t1,...,tn])  to  f(t1,...,tn) *)
   159 fun list_comb (f, []) = f
   160   | list_comb (f, t::ts) = list_comb (Thm.capply f t, ts);
   161 
   162 (*cterm version of strip_comb: maps  f(t1,...,tn)  to  (f, [t1,...,tn]) *)
   163 fun strip_comb ct =
   164   let
   165     fun stripc (p as (ct, cts)) =
   166       let val (ct1, ct2) = Thm.dest_comb ct
   167       in stripc (ct1, ct2 :: cts) end handle CTERM _ => p
   168   in stripc (ct, []) end;
   169 
   170 (* cterm version of strip_type: maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T) *)
   171 fun strip_type cT = (case Thm.typ_of cT of
   172     Type ("fun", _) =>
   173       let
   174         val [cT1, cT2] = Thm.dest_ctyp cT;
   175         val (cTs, cT') = strip_type cT2
   176       in (cT1 :: cTs, cT') end
   177   | _ => ([], cT));
   178 
   179 (*Beta-conversion for cterms, where x is an abstraction. Simply returns the rhs
   180   of the meta-equality returned by the beta_conversion rule.*)
   181 fun beta_conv x y =
   182   Thm.dest_arg (cprop_of (Thm.beta_conversion false (Thm.capply x y)));
   183 
   184 
   185 
   186 (*** Find the type (sort) associated with a (T)Var or (T)Free in a term
   187      Used for establishing default types (of variables) and sorts (of
   188      type variables) when reading another term.
   189      Index -1 indicates that a (T)Free rather than a (T)Var is wanted.
   190 ***)
   191 
   192 fun types_sorts thm =
   193   let
   194     val vars = Thm.fold_terms Term.add_vars thm [];
   195     val frees = Thm.fold_terms Term.add_frees thm [];
   196     val tvars = Thm.fold_terms Term.add_tvars thm [];
   197     val tfrees = Thm.fold_terms Term.add_tfrees thm [];
   198     fun types (a, i) =
   199       if i < 0 then AList.lookup (op =) frees a else AList.lookup (op =) vars (a, i);
   200     fun sorts (a, i) =
   201       if i < 0 then AList.lookup (op =) tfrees a else AList.lookup (op =) tvars (a, i);
   202   in (types, sorts) end;
   203 
   204 
   205 
   206 
   207 (** Standardization of rules **)
   208 
   209 (* type classes and sorts *)
   210 
   211 fun unconstrainTs th =
   212   fold (Thm.unconstrainT o Thm.ctyp_of (Thm.theory_of_thm th) o TVar)
   213     (Thm.fold_terms Term.add_tvars th []) th;
   214 
   215 (*Generalization over a list of variables*)
   216 val forall_intr_list = fold_rev forall_intr;
   217 
   218 (*Generalization over all suitable Free variables*)
   219 fun forall_intr_frees th =
   220     let
   221       val thy = Thm.theory_of_thm th;
   222       val {prop, hyps, tpairs, ...} = rep_thm th;
   223       val fixed = fold Term.add_frees (Thm.terms_of_tpairs tpairs @ hyps) [];
   224       val frees = Term.fold_aterms (fn Free v =>
   225         if member (op =) fixed v then I else insert (op =) v | _ => I) prop [];
   226     in fold (forall_intr o cterm_of thy o Free) frees th end;
   227 
   228 (*Generalization over Vars -- canonical order*)
   229 fun forall_intr_vars th =
   230   fold forall_intr
   231     (map (Thm.cterm_of (Thm.theory_of_thm th) o Var) (Thm.fold_terms Term.add_vars th [])) th;
   232 
   233 fun outer_params t =
   234   let val vs = Term.strip_all_vars t
   235   in Name.variant_list [] (map (Name.clean o #1) vs) ~~ map #2 vs end;
   236 
   237 (*generalize outermost parameters*)
   238 fun gen_all th =
   239   let
   240     val thy = Thm.theory_of_thm th;
   241     val {prop, maxidx, ...} = Thm.rep_thm th;
   242     val cert = Thm.cterm_of thy;
   243     fun elim (x, T) = Thm.forall_elim (cert (Var ((x, maxidx + 1), T)));
   244   in fold elim (outer_params prop) th end;
   245 
   246 (*lift vars wrt. outermost goal parameters
   247   -- reverses the effect of gen_all modulo higher-order unification*)
   248 fun lift_all goal th =
   249   let
   250     val thy = Theory.merge (Thm.theory_of_cterm goal, Thm.theory_of_thm th);
   251     val cert = Thm.cterm_of thy;
   252     val maxidx = Thm.maxidx_of th;
   253     val ps = outer_params (Thm.term_of goal)
   254       |> map (fn (x, T) => Var ((x, maxidx + 1), Logic.incr_tvar (maxidx + 1) T));
   255     val Ts = map Term.fastype_of ps;
   256     val inst = Thm.fold_terms Term.add_vars th [] |> map (fn (xi, T) =>
   257       (cert (Var (xi, T)), cert (Term.list_comb (Var (xi, Ts ---> T), ps))));
   258   in
   259     th |> Thm.instantiate ([], inst)
   260     |> fold_rev (Thm.forall_intr o cert) ps
   261   end;
   262 
   263 (*direct generalization*)
   264 fun generalize names th = Thm.generalize names (Thm.maxidx_of th + 1) th;
   265 
   266 (*specialization over a list of cterms*)
   267 val forall_elim_list = fold forall_elim;
   268 
   269 (*maps A1,...,An |- B  to  [| A1;...;An |] ==> B*)
   270 val implies_intr_list = fold_rev implies_intr;
   271 
   272 (*maps [| A1;...;An |] ==> B and [A1,...,An]  to  B*)
   273 fun implies_elim_list impth ths = fold Thm.elim_implies ths impth;
   274 
   275 (*Reset Var indexes to zero, renaming to preserve distinctness*)
   276 fun zero_var_indexes_list [] = []
   277   | zero_var_indexes_list ths =
   278       let
   279         val thy = Theory.merge_list (map Thm.theory_of_thm ths);
   280         val certT = Thm.ctyp_of thy and cert = Thm.cterm_of thy;
   281         val (instT, inst) = Term_Subst.zero_var_indexes_inst (map Thm.full_prop_of ths);
   282         val cinstT = map (fn (v, T) => (certT (TVar v), certT T)) instT;
   283         val cinst = map (fn (v, t) => (cert (Var v), cert t)) inst;
   284       in map (Thm.adjust_maxidx_thm ~1 o Thm.instantiate (cinstT, cinst)) ths end;
   285 
   286 val zero_var_indexes = singleton zero_var_indexes_list;
   287 
   288 
   289 (** Standard form of object-rule: no hypotheses, flexflex constraints,
   290     Frees, or outer quantifiers; all generality expressed by Vars of index 0.**)
   291 
   292 (*Discharge all hypotheses.*)
   293 fun implies_intr_hyps th =
   294   fold Thm.implies_intr (#hyps (Thm.crep_thm th)) th;
   295 
   296 (*Squash a theorem's flexflex constraints provided it can be done uniquely.
   297   This step can lose information.*)
   298 fun flexflex_unique th =
   299   if null (tpairs_of th) then th else
   300     case distinct Thm.eq_thm (Seq.list_of (flexflex_rule th)) of
   301       [th] => th
   302     | []   => raise THM("flexflex_unique: impossible constraints", 0, [th])
   303     |  _   => raise THM("flexflex_unique: multiple unifiers", 0, [th]);
   304 
   305 
   306 (* legacy standard operations *)
   307 
   308 val standard' =
   309   implies_intr_hyps
   310   #> forall_intr_frees
   311   #> `Thm.maxidx_of
   312   #-> (fn maxidx =>
   313     Thm.forall_elim_vars (maxidx + 1)
   314     #> Thm.strip_shyps
   315     #> zero_var_indexes
   316     #> Thm.varifyT);
   317 
   318 val standard =
   319   flexflex_unique
   320   #> standard'
   321   #> Thm.close_derivation;
   322 
   323 
   324 (*Convert all Vars in a theorem to Frees.  Also return a function for
   325   reversing that operation.  DOES NOT WORK FOR TYPE VARIABLES.
   326   Similar code in type/freeze_thaw*)
   327 
   328 fun freeze_thaw_robust th =
   329  let val fth = Thm.freezeT th
   330      val thy = Thm.theory_of_thm fth
   331      val {prop, tpairs, ...} = rep_thm fth
   332  in
   333    case List.foldr OldTerm.add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   334        [] => (fth, fn i => fn x => x)   (*No vars: nothing to do!*)
   335      | vars =>
   336          let fun newName (Var(ix,_)) = (ix, gensym (string_of_indexname ix))
   337              val alist = map newName vars
   338              fun mk_inst (Var(v,T)) =
   339                  (cterm_of thy (Var(v,T)),
   340                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   341              val insts = map mk_inst vars
   342              fun thaw i th' = (*i is non-negative increment for Var indexes*)
   343                  th' |> forall_intr_list (map #2 insts)
   344                      |> forall_elim_list (map (Thm.incr_indexes_cterm i o #1) insts)
   345          in  (Thm.instantiate ([],insts) fth, thaw)  end
   346  end;
   347 
   348 (*Basic version of the function above. No option to rename Vars apart in thaw.
   349   The Frees created from Vars have nice names. FIXME: does not check for
   350   clashes with variables in the assumptions, so delete and use freeze_thaw_robust instead?*)
   351 fun freeze_thaw th =
   352  let val fth = Thm.freezeT th
   353      val thy = Thm.theory_of_thm fth
   354      val {prop, tpairs, ...} = rep_thm fth
   355  in
   356    case List.foldr OldTerm.add_term_vars [] (prop :: Thm.terms_of_tpairs tpairs) of
   357        [] => (fth, fn x => x)
   358      | vars =>
   359          let fun newName (Var(ix,_), (pairs,used)) =
   360                    let val v = Name.variant used (string_of_indexname ix)
   361                    in  ((ix,v)::pairs, v::used)  end;
   362              val (alist, _) = List.foldr newName ([], Library.foldr OldTerm.add_term_names
   363                (prop :: Thm.terms_of_tpairs tpairs, [])) vars
   364              fun mk_inst (Var(v,T)) =
   365                  (cterm_of thy (Var(v,T)),
   366                   cterm_of thy (Free(((the o AList.lookup (op =) alist) v), T)))
   367              val insts = map mk_inst vars
   368              fun thaw th' =
   369                  th' |> forall_intr_list (map #2 insts)
   370                      |> forall_elim_list (map #1 insts)
   371          in  (Thm.instantiate ([],insts) fth, thaw)  end
   372  end;
   373 
   374 (*Rotates a rule's premises to the left by k*)
   375 fun rotate_prems 0 = I
   376   | rotate_prems k = Thm.permute_prems 0 k;
   377 
   378 fun with_subgoal i f = rotate_prems (i - 1) #> f #> rotate_prems (1 - i);
   379 
   380 (*Permute prems, where the i-th position in the argument list (counting from 0)
   381   gives the position within the original thm to be transferred to position i.
   382   Any remaining trailing positions are left unchanged.*)
   383 val rearrange_prems =
   384   let
   385     fun rearr new [] thm = thm
   386       | rearr new (p :: ps) thm =
   387           rearr (new + 1)
   388             (map (fn q => if new <= q andalso q < p then q + 1 else q) ps)
   389             (Thm.permute_prems (new + 1) (new - p) (Thm.permute_prems new (p - new) thm))
   390   in rearr 0 end;
   391 
   392 (*Resolution: exactly one resolvent must be produced.*)
   393 fun tha RSN (i,thb) =
   394   case Seq.chop 2 (Thm.biresolution false [(false,tha)] i thb) of
   395       ([th],_) => th
   396     | ([],_)   => raise THM("RSN: no unifiers", i, [tha,thb])
   397     |      _   => raise THM("RSN: multiple unifiers", i, [tha,thb]);
   398 
   399 (*resolution: P==>Q, Q==>R gives P==>R. *)
   400 fun tha RS thb = tha RSN (1,thb);
   401 
   402 (*For joining lists of rules*)
   403 fun thas RLN (i,thbs) =
   404   let val resolve = Thm.biresolution false (map (pair false) thas) i
   405       fun resb thb = Seq.list_of (resolve thb) handle THM _ => []
   406   in maps resb thbs end;
   407 
   408 fun thas RL thbs = thas RLN (1,thbs);
   409 
   410 (*Resolve a list of rules against bottom_rl from right to left;
   411   makes proof trees*)
   412 fun rls MRS bottom_rl =
   413   let fun rs_aux i [] = bottom_rl
   414         | rs_aux i (rl::rls) = rl RSN (i, rs_aux (i+1) rls)
   415   in  rs_aux 1 rls  end;
   416 
   417 (*As above, but for rule lists*)
   418 fun rlss MRL bottom_rls =
   419   let fun rs_aux i [] = bottom_rls
   420         | rs_aux i (rls::rlss) = rls RLN (i, rs_aux (i+1) rlss)
   421   in  rs_aux 1 rlss  end;
   422 
   423 (*A version of MRS with more appropriate argument order*)
   424 fun bottom_rl OF rls = rls MRS bottom_rl;
   425 
   426 (*compose Q and [...,Qi,Q(i+1),...]==>R to [...,Q(i+1),...]==>R
   427   with no lifting or renaming!  Q may contain ==> or meta-quants
   428   ALWAYS deletes premise i *)
   429 fun compose(tha,i,thb) =
   430     distinct Thm.eq_thm (Seq.list_of (Thm.bicompose false (false,tha,0) i thb));
   431 
   432 fun compose_single (tha,i,thb) =
   433   case compose (tha,i,thb) of
   434     [th] => th
   435   | _ => raise THM ("compose: unique result expected", i, [tha,thb]);
   436 
   437 (*compose Q and [Q1,Q2,...,Qk]==>R to [Q2,...,Qk]==>R getting unique result*)
   438 fun tha COMP thb =
   439     case compose(tha,1,thb) of
   440         [th] => th
   441       | _ =>   raise THM("COMP", 1, [tha,thb]);
   442 
   443 
   444 (** theorem equality **)
   445 
   446 (*Useful "distance" function for BEST_FIRST*)
   447 val size_of_thm = size_of_term o Thm.full_prop_of;
   448 
   449 
   450 
   451 (*** Meta-Rewriting Rules ***)
   452 
   453 val read_prop = certify o SimpleSyntax.read_prop;
   454 
   455 fun get_def thy = Thm.axiom thy o NameSpace.intern (Theory.axiom_space thy) o Thm.def_name;
   456 
   457 fun store_thm name th =
   458   Context.>>> (Context.map_theory_result (PureThy.store_thm (Binding.name name, th)));
   459 
   460 fun store_thm_open name th =
   461   Context.>>> (Context.map_theory_result (PureThy.store_thm_open (Binding.name name, th)));
   462 
   463 fun store_standard_thm name th = store_thm name (standard th);
   464 fun store_standard_thm_open name thm = store_thm_open name (standard' thm);
   465 
   466 val reflexive_thm =
   467   let val cx = certify (Var(("x",0),TVar(("'a",0),[])))
   468   in store_standard_thm_open "reflexive" (Thm.reflexive cx) end;
   469 
   470 val symmetric_thm =
   471   let val xy = read_prop "x::'a == y::'a"
   472   in store_standard_thm_open "symmetric" (Thm.implies_intr xy (Thm.symmetric (Thm.assume xy))) end;
   473 
   474 val transitive_thm =
   475   let val xy = read_prop "x::'a == y::'a"
   476       val yz = read_prop "y::'a == z::'a"
   477       val xythm = Thm.assume xy and yzthm = Thm.assume yz
   478   in store_standard_thm_open "transitive" (Thm.implies_intr yz (Thm.transitive xythm yzthm)) end;
   479 
   480 fun symmetric_fun thm = thm RS symmetric_thm;
   481 
   482 fun extensional eq =
   483   let val eq' =
   484     abstract_rule "x" (Thm.dest_arg (fst (Thm.dest_equals (cprop_of eq)))) eq
   485   in equal_elim (eta_conversion (cprop_of eq')) eq' end;
   486 
   487 val equals_cong =
   488   store_standard_thm_open "equals_cong" (Thm.reflexive (read_prop "x::'a == y::'a"));
   489 
   490 val imp_cong =
   491   let
   492     val ABC = read_prop "A ==> B::prop == C::prop"
   493     val AB = read_prop "A ==> B"
   494     val AC = read_prop "A ==> C"
   495     val A = read_prop "A"
   496   in
   497     store_standard_thm_open "imp_cong" (implies_intr ABC (equal_intr
   498       (implies_intr AB (implies_intr A
   499         (equal_elim (implies_elim (assume ABC) (assume A))
   500           (implies_elim (assume AB) (assume A)))))
   501       (implies_intr AC (implies_intr A
   502         (equal_elim (symmetric (implies_elim (assume ABC) (assume A)))
   503           (implies_elim (assume AC) (assume A)))))))
   504   end;
   505 
   506 val swap_prems_eq =
   507   let
   508     val ABC = read_prop "A ==> B ==> C"
   509     val BAC = read_prop "B ==> A ==> C"
   510     val A = read_prop "A"
   511     val B = read_prop "B"
   512   in
   513     store_standard_thm_open "swap_prems_eq" (equal_intr
   514       (implies_intr ABC (implies_intr B (implies_intr A
   515         (implies_elim (implies_elim (assume ABC) (assume A)) (assume B)))))
   516       (implies_intr BAC (implies_intr A (implies_intr B
   517         (implies_elim (implies_elim (assume BAC) (assume B)) (assume A))))))
   518   end;
   519 
   520 val imp_cong_rule = Thm.combination o Thm.combination (Thm.reflexive implies);
   521 
   522 fun arg_cong_rule ct th = Thm.combination (Thm.reflexive ct) th;    (*AP_TERM in LCF/HOL*)
   523 fun fun_cong_rule th ct = Thm.combination th (Thm.reflexive ct);    (*AP_THM in LCF/HOL*)
   524 fun binop_cong_rule ct th1 th2 = Thm.combination (arg_cong_rule ct th1) th2;
   525 
   526 local
   527   val dest_eq = Thm.dest_equals o cprop_of
   528   val rhs_of = snd o dest_eq
   529 in
   530 fun beta_eta_conversion t =
   531   let val thm = beta_conversion true t
   532   in transitive thm (eta_conversion (rhs_of thm)) end
   533 end;
   534 
   535 fun eta_long_conversion ct = transitive (beta_eta_conversion ct)
   536   (symmetric (beta_eta_conversion (cterm_fun (Pattern.eta_long []) ct)));
   537 
   538 (*Contract all eta-redexes in the theorem, lest they give rise to needless abstractions*)
   539 fun eta_contraction_rule th =
   540   equal_elim (eta_conversion (cprop_of th)) th;
   541 
   542 
   543 (* abs_def *)
   544 
   545 (*
   546    f ?x1 ... ?xn == u
   547   --------------------
   548    f == %x1 ... xn. u
   549 *)
   550 
   551 local
   552 
   553 fun contract_lhs th =
   554   Thm.transitive (Thm.symmetric (beta_eta_conversion
   555     (fst (Thm.dest_equals (cprop_of th))))) th;
   556 
   557 fun var_args ct =
   558   (case try Thm.dest_comb ct of
   559     SOME (f, arg) =>
   560       (case Thm.term_of arg of
   561         Var ((x, _), _) => update (eq_snd (op aconvc)) (x, arg) (var_args f)
   562       | _ => [])
   563   | NONE => []);
   564 
   565 in
   566 
   567 fun abs_def th =
   568   let
   569     val th' = contract_lhs th;
   570     val args = var_args (Thm.lhs_of th');
   571   in contract_lhs (fold (uncurry Thm.abstract_rule) args th') end;
   572 
   573 end;
   574 
   575 
   576 
   577 (*** Some useful meta-theorems ***)
   578 
   579 (*The rule V/V, obtains assumption solving for eresolve_tac*)
   580 val asm_rl = store_standard_thm_open "asm_rl" (Thm.trivial (read_prop "?psi"));
   581 val _ = store_thm_open "_" asm_rl;
   582 
   583 (*Meta-level cut rule: [| V==>W; V |] ==> W *)
   584 val cut_rl =
   585   store_standard_thm_open "cut_rl"
   586     (Thm.trivial (read_prop "?psi ==> ?theta"));
   587 
   588 (*Generalized elim rule for one conclusion; cut_rl with reversed premises:
   589      [| PROP V;  PROP V ==> PROP W |] ==> PROP W *)
   590 val revcut_rl =
   591   let val V = read_prop "V"
   592       and VW = read_prop "V ==> W";
   593   in
   594     store_standard_thm_open "revcut_rl"
   595       (implies_intr V (implies_intr VW (implies_elim (assume VW) (assume V))))
   596   end;
   597 
   598 (*for deleting an unwanted assumption*)
   599 val thin_rl =
   600   let val V = read_prop "V"
   601       and W = read_prop "W";
   602   in store_standard_thm_open "thin_rl" (implies_intr V (implies_intr W (assume W))) end;
   603 
   604 (* (!!x. PROP ?V) == PROP ?V       Allows removal of redundant parameters*)
   605 val triv_forall_equality =
   606   let val V  = read_prop "V"
   607       and QV = read_prop "!!x::'a. V"
   608       and x  = certify (Free ("x", Term.aT []));
   609   in
   610     store_standard_thm_open "triv_forall_equality"
   611       (equal_intr (implies_intr QV (forall_elim x (assume QV)))
   612         (implies_intr V  (forall_intr x (assume V))))
   613   end;
   614 
   615 (* (PROP ?Phi ==> PROP ?Phi ==> PROP ?Psi) ==>
   616    (PROP ?Phi ==> PROP ?Psi)
   617 *)
   618 val distinct_prems_rl =
   619   let
   620     val AAB = read_prop "Phi ==> Phi ==> Psi"
   621     val A = read_prop "Phi";
   622   in
   623     store_standard_thm_open "distinct_prems_rl"
   624       (implies_intr_list [AAB, A] (implies_elim_list (assume AAB) [assume A, assume A]))
   625   end;
   626 
   627 (* (PROP ?PhiA ==> PROP ?PhiB ==> PROP ?Psi) ==>
   628    (PROP ?PhiB ==> PROP ?PhiA ==> PROP ?Psi)
   629    `thm COMP swap_prems_rl' swaps the first two premises of `thm'
   630 *)
   631 val swap_prems_rl =
   632   let val cmajor = read_prop "PhiA ==> PhiB ==> Psi";
   633       val major = assume cmajor;
   634       val cminor1 = read_prop "PhiA";
   635       val minor1 = assume cminor1;
   636       val cminor2 = read_prop "PhiB";
   637       val minor2 = assume cminor2;
   638   in store_standard_thm_open "swap_prems_rl"
   639        (implies_intr cmajor (implies_intr cminor2 (implies_intr cminor1
   640          (implies_elim (implies_elim major minor1) minor2))))
   641   end;
   642 
   643 (* [| PROP ?phi ==> PROP ?psi; PROP ?psi ==> PROP ?phi |]
   644    ==> PROP ?phi == PROP ?psi
   645    Introduction rule for == as a meta-theorem.
   646 *)
   647 val equal_intr_rule =
   648   let val PQ = read_prop "phi ==> psi"
   649       and QP = read_prop "psi ==> phi"
   650   in
   651     store_standard_thm_open "equal_intr_rule"
   652       (implies_intr PQ (implies_intr QP (equal_intr (assume PQ) (assume QP))))
   653   end;
   654 
   655 (* PROP ?phi == PROP ?psi ==> PROP ?phi ==> PROP ?psi *)
   656 val equal_elim_rule1 =
   657   let val eq = read_prop "phi::prop == psi::prop"
   658       and P = read_prop "phi"
   659   in store_standard_thm_open "equal_elim_rule1"
   660     (Thm.equal_elim (assume eq) (assume P) |> implies_intr_list [eq, P])
   661   end;
   662 
   663 (* PROP ?psi == PROP ?phi ==> PROP ?phi ==> PROP ?psi *)
   664 val equal_elim_rule2 =
   665   store_standard_thm_open "equal_elim_rule2" (symmetric_thm RS equal_elim_rule1);
   666 
   667 (* PROP ?phi ==> PROP ?phi ==> PROP ?psi ==> PROP ?psi *)
   668 val remdups_rl =
   669   let val P = read_prop "phi" and Q = read_prop "psi";
   670   in store_standard_thm_open "remdups_rl" (implies_intr_list [P, P, Q] (Thm.assume Q)) end;
   671 
   672 
   673 
   674 (** embedded terms and types **)
   675 
   676 local
   677   val A = certify (Free ("A", propT));
   678   val axiom = Thm.unvarify o Thm.axiom (Context.the_theory (Context.the_thread_data ()));
   679   val prop_def = axiom "Pure.prop_def";
   680   val term_def = axiom "Pure.term_def";
   681   val sort_constraint_def = axiom "Pure.sort_constraint_def";
   682   val C = Thm.lhs_of sort_constraint_def;
   683   val T = Thm.dest_arg C;
   684   val CA = mk_implies (C, A);
   685 in
   686 
   687 (* protect *)
   688 
   689 val protect = Thm.capply (certify Logic.protectC);
   690 
   691 val protectI = store_thm "protectI" (Thm.kind_rule Thm.internalK (standard
   692     (Thm.equal_elim (Thm.symmetric prop_def) (Thm.assume A))));
   693 
   694 val protectD = store_thm "protectD" (Thm.kind_rule Thm.internalK (standard
   695     (Thm.equal_elim prop_def (Thm.assume (protect A)))));
   696 
   697 val protect_cong = store_standard_thm_open "protect_cong" (Thm.reflexive (protect A));
   698 
   699 fun implies_intr_protected asms th =
   700   let val asms' = map protect asms in
   701     implies_elim_list
   702       (implies_intr_list asms th)
   703       (map (fn asm' => Thm.assume asm' RS protectD) asms')
   704     |> implies_intr_list asms'
   705   end;
   706 
   707 
   708 (* term *)
   709 
   710 val termI = store_thm "termI" (Thm.kind_rule Thm.internalK (standard
   711     (Thm.equal_elim (Thm.symmetric term_def) (Thm.forall_intr A (Thm.trivial A)))));
   712 
   713 fun mk_term ct =
   714   let
   715     val thy = Thm.theory_of_cterm ct;
   716     val cert = Thm.cterm_of thy;
   717     val certT = Thm.ctyp_of thy;
   718     val T = Thm.typ_of (Thm.ctyp_of_term ct);
   719     val a = certT (TVar (("'a", 0), []));
   720     val x = cert (Var (("x", 0), T));
   721   in Thm.instantiate ([(a, certT T)], [(x, ct)]) termI end;
   722 
   723 fun dest_term th =
   724   let val cprop = strip_imp_concl (Thm.cprop_of th) in
   725     if can Logic.dest_term (Thm.term_of cprop) then
   726       Thm.dest_arg cprop
   727     else raise THM ("dest_term", 0, [th])
   728   end;
   729 
   730 fun cterm_rule f = dest_term o f o mk_term;
   731 fun term_rule thy f t = Thm.term_of (cterm_rule f (Thm.cterm_of thy t));
   732 
   733 val dummy_thm = mk_term (certify (Term.dummy_pattern propT));
   734 
   735 
   736 (* sort_constraint *)
   737 
   738 val sort_constraintI = store_thm "sort_constraintI" (Thm.kind_rule Thm.internalK (standard
   739   (Thm.equal_elim (Thm.symmetric sort_constraint_def) (mk_term T))));
   740 
   741 val sort_constraint_eq = store_thm "sort_constraint_eq" (Thm.kind_rule Thm.internalK (standard
   742   (Thm.equal_intr
   743     (Thm.implies_intr CA (Thm.implies_elim (Thm.assume CA) (Thm.unvarify sort_constraintI)))
   744     (implies_intr_list [A, C] (Thm.assume A)))));
   745 
   746 end;
   747 
   748 
   749 (* HHF normalization *)
   750 
   751 (* (PROP ?phi ==> (!!x. PROP ?psi(x))) == (!!x. PROP ?phi ==> PROP ?psi(x)) *)
   752 val norm_hhf_eq =
   753   let
   754     val aT = TFree ("'a", []);
   755     val all = Term.all aT;
   756     val x = Free ("x", aT);
   757     val phi = Free ("phi", propT);
   758     val psi = Free ("psi", aT --> propT);
   759 
   760     val cx = certify x;
   761     val cphi = certify phi;
   762     val lhs = certify (Logic.mk_implies (phi, all $ Abs ("x", aT, psi $ Bound 0)));
   763     val rhs = certify (all $ Abs ("x", aT, Logic.mk_implies (phi, psi $ Bound 0)));
   764   in
   765     Thm.equal_intr
   766       (Thm.implies_elim (Thm.assume lhs) (Thm.assume cphi)
   767         |> Thm.forall_elim cx
   768         |> Thm.implies_intr cphi
   769         |> Thm.forall_intr cx
   770         |> Thm.implies_intr lhs)
   771       (Thm.implies_elim
   772           (Thm.assume rhs |> Thm.forall_elim cx) (Thm.assume cphi)
   773         |> Thm.forall_intr cx
   774         |> Thm.implies_intr cphi
   775         |> Thm.implies_intr rhs)
   776     |> store_standard_thm_open "norm_hhf_eq"
   777   end;
   778 
   779 val norm_hhf_prop = Logic.dest_equals (Thm.prop_of norm_hhf_eq);
   780 val norm_hhf_eqs = [norm_hhf_eq, sort_constraint_eq];
   781 
   782 fun is_norm_hhf (Const ("Pure.sort_constraint", _)) = false
   783   | is_norm_hhf (Const ("==>", _) $ _ $ (Const ("all", _) $ _)) = false
   784   | is_norm_hhf (Abs _ $ _) = false
   785   | is_norm_hhf (t $ u) = is_norm_hhf t andalso is_norm_hhf u
   786   | is_norm_hhf (Abs (_, _, t)) = is_norm_hhf t
   787   | is_norm_hhf _ = true;
   788 
   789 fun norm_hhf thy t =
   790   if is_norm_hhf t then t
   791   else Pattern.rewrite_term thy [norm_hhf_prop] [] t;
   792 
   793 fun norm_hhf_cterm ct =
   794   if is_norm_hhf (Thm.term_of ct) then ct
   795   else cterm_fun (Pattern.rewrite_term (Thm.theory_of_cterm ct) [norm_hhf_prop] []) ct;
   796 
   797 
   798 (* var indexes *)
   799 
   800 (*Increment the indexes of only the type variables*)
   801 fun incr_type_indexes inc th =
   802   let val tvs = OldTerm.term_tvars (prop_of th)
   803       and thy = Thm.theory_of_thm th
   804       fun inc_tvar ((a,i),s) = pairself (ctyp_of thy) (TVar ((a,i),s), TVar ((a,i+inc),s))
   805   in Thm.instantiate (map inc_tvar tvs, []) th end;
   806 
   807 fun incr_indexes th = Thm.incr_indexes (Thm.maxidx_of th + 1);
   808 
   809 fun incr_indexes2 th1 th2 =
   810   Thm.incr_indexes (Int.max (Thm.maxidx_of th1, Thm.maxidx_of th2) + 1);
   811 
   812 fun th1 INCR_COMP th2 = incr_indexes th2 th1 COMP th2;
   813 fun th1 COMP_INCR th2 = th1 COMP incr_indexes th1 th2;
   814 
   815 fun comp_no_flatten (th, n) i rule =
   816   (case distinct Thm.eq_thm (Seq.list_of
   817       (Thm.compose_no_flatten false (th, n) i (incr_indexes th rule))) of
   818     [th'] => th'
   819   | [] => raise THM ("comp_no_flatten", i, [th, rule])
   820   | _ => raise THM ("comp_no_flatten: unique result expected", i, [th, rule]));
   821 
   822 
   823 
   824 (*** Instantiate theorem th, reading instantiations in theory thy ****)
   825 
   826 (*Version that normalizes the result: Thm.instantiate no longer does that*)
   827 fun instantiate instpair th =
   828   Thm.adjust_maxidx_thm ~1 (Thm.instantiate instpair th COMP_INCR asm_rl);
   829 
   830 (*Left-to-right replacements: tpairs = [...,(vi,ti),...].
   831   Instantiates distinct Vars by terms, inferring type instantiations. *)
   832 local
   833   fun add_types ((ct,cu), (thy,tye,maxidx)) =
   834     let
   835         val thyt = Thm.theory_of_cterm ct;
   836         val thyu = Thm.theory_of_cterm cu;
   837         val {t, T, maxidx = maxt, ...} = Thm.rep_cterm ct;
   838         val {t = u, T = U, maxidx = maxu, ...} = Thm.rep_cterm cu;
   839         val maxi = Int.max(maxidx, Int.max(maxt, maxu));
   840         val thy' = Theory.merge(thy, Theory.merge(thyt, thyu))
   841         val (tye',maxi') = Sign.typ_unify thy' (T, U) (tye, maxi)
   842           handle Type.TUNIFY => raise TYPE ("Ill-typed instantiation:\nType\n" ^
   843             Syntax.string_of_typ_global thy' (Envir.norm_type tye T) ^
   844             "\nof variable " ^
   845             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) t) ^
   846             "\ncannot be unified with type\n" ^
   847             Syntax.string_of_typ_global thy' (Envir.norm_type tye U) ^ "\nof term " ^
   848             Syntax.string_of_term_global thy' (Term.map_types (Envir.norm_type tye) u),
   849             [T, U], [t, u])
   850     in  (thy', tye', maxi')  end;
   851 in
   852 fun cterm_instantiate [] th = th
   853   | cterm_instantiate ctpairs0 th =
   854   let val (thy,tye,_) = List.foldr add_types (Thm.theory_of_thm th, Vartab.empty, 0) ctpairs0
   855       fun instT(ct,cu) =
   856         let val inst = cterm_of thy o Term.map_types (Envir.norm_type tye) o term_of
   857         in (inst ct, inst cu) end
   858       fun ctyp2 (ixn, (S, T)) = (ctyp_of thy (TVar (ixn, S)), ctyp_of thy (Envir.norm_type tye T))
   859   in  instantiate (map ctyp2 (Vartab.dest tye), map instT ctpairs0) th  end
   860   handle TERM _ =>
   861            raise THM("cterm_instantiate: incompatible theories",0,[th])
   862        | TYPE (msg, _, _) => raise THM(msg, 0, [th])
   863 end;
   864 
   865 
   866 
   867 (** variations on instantiate **)
   868 
   869 (* instantiate by left-to-right occurrence of variables *)
   870 
   871 fun instantiate' cTs cts thm =
   872   let
   873     fun err msg =
   874       raise TYPE ("instantiate': " ^ msg,
   875         map_filter (Option.map Thm.typ_of) cTs,
   876         map_filter (Option.map Thm.term_of) cts);
   877 
   878     fun inst_of (v, ct) =
   879       (Thm.cterm_of (Thm.theory_of_cterm ct) (Var v), ct)
   880         handle TYPE (msg, _, _) => err msg;
   881 
   882     fun tyinst_of (v, cT) =
   883       (Thm.ctyp_of (Thm.theory_of_ctyp cT) (TVar v), cT)
   884         handle TYPE (msg, _, _) => err msg;
   885 
   886     fun zip_vars xs ys =
   887       zip_options xs ys handle Library.UnequalLengths =>
   888         err "more instantiations than variables in thm";
   889 
   890     (*instantiate types first!*)
   891     val thm' =
   892       if forall is_none cTs then thm
   893       else Thm.instantiate
   894         (map tyinst_of (zip_vars (rev (Thm.fold_terms Term.add_tvars thm [])) cTs), []) thm;
   895     val thm'' =
   896       if forall is_none cts then thm'
   897       else Thm.instantiate
   898         ([], map inst_of (zip_vars (rev (Thm.fold_terms Term.add_vars thm' [])) cts)) thm';
   899     in thm'' end;
   900 
   901 
   902 
   903 (** renaming of bound variables **)
   904 
   905 (* replace bound variables x_i in thm by y_i *)
   906 (* where vs = [(x_1, y_1), ..., (x_n, y_n)]  *)
   907 
   908 fun rename_bvars [] thm = thm
   909   | rename_bvars vs thm =
   910       let
   911         val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   912         fun ren (Abs (x, T, t)) = Abs (AList.lookup (op =) vs x |> the_default x, T, ren t)
   913           | ren (t $ u) = ren t $ ren u
   914           | ren t = t;
   915       in equal_elim (reflexive (cert (ren (Thm.prop_of thm)))) thm end;
   916 
   917 
   918 (* renaming in left-to-right order *)
   919 
   920 fun rename_bvars' xs thm =
   921   let
   922     val cert = Thm.cterm_of (Thm.theory_of_thm thm);
   923     val prop = Thm.prop_of thm;
   924     fun rename [] t = ([], t)
   925       | rename (x' :: xs) (Abs (x, T, t)) =
   926           let val (xs', t') = rename xs t
   927           in (xs', Abs (the_default x x', T, t')) end
   928       | rename xs (t $ u) =
   929           let
   930             val (xs', t') = rename xs t;
   931             val (xs'', u') = rename xs' u
   932           in (xs'', t' $ u') end
   933       | rename xs t = (xs, t);
   934   in case rename xs prop of
   935       ([], prop') => equal_elim (reflexive (cert prop')) thm
   936     | _ => error "More names than abstractions in theorem"
   937   end;
   938 
   939 
   940 
   941 (** multi_resolve **)
   942 
   943 local
   944 
   945 fun res th i rule =
   946   Thm.biresolution false [(false, th)] i rule handle THM _ => Seq.empty;
   947 
   948 fun multi_res _ [] rule = Seq.single rule
   949   | multi_res i (th :: ths) rule = Seq.maps (res th i) (multi_res (i + 1) ths rule);
   950 
   951 in
   952 
   953 val multi_resolve = multi_res 1;
   954 fun multi_resolves facts rules = Seq.maps (multi_resolve facts) (Seq.of_list rules);
   955 
   956 end;
   957 
   958 end;
   959 
   960 structure BasicDrule: BASIC_DRULE = Drule;
   961 open BasicDrule;