src/HOL/Inductive.thy
author nipkow
Fri Mar 06 17:38:47 2009 +0100 (2009-03-06)
changeset 30313 b2441b0c8d38
parent 29281 b22ccb3998db
child 31604 eb2f9d709296
permissions -rw-r--r--
added lemmas
     1 (*  Title:      HOL/Inductive.thy
     2     Author:     Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 header {* Knaster-Tarski Fixpoint Theorem and inductive definitions *}
     6 
     7 theory Inductive 
     8 imports Lattices Sum_Type
     9 uses
    10   ("Tools/inductive_package.ML")
    11   "Tools/dseq.ML"
    12   ("Tools/inductive_codegen.ML")
    13   ("Tools/datatype_aux.ML")
    14   ("Tools/datatype_prop.ML")
    15   ("Tools/datatype_rep_proofs.ML")
    16   ("Tools/datatype_abs_proofs.ML")
    17   ("Tools/datatype_case.ML")
    18   ("Tools/datatype_package.ML")
    19   ("Tools/old_primrec_package.ML")
    20   ("Tools/primrec_package.ML")
    21   ("Tools/datatype_codegen.ML")
    22 begin
    23 
    24 subsection {* Least and greatest fixed points *}
    25 
    26 context complete_lattice
    27 begin
    28 
    29 definition
    30   lfp :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a" where
    31   "lfp f = Inf {u. f u \<le> u}"    --{*least fixed point*}
    32 
    33 definition
    34   gfp :: "('a \<Rightarrow> 'a) \<Rightarrow> 'a" where
    35   "gfp f = Sup {u. u \<le> f u}"    --{*greatest fixed point*}
    36 
    37 
    38 subsection{* Proof of Knaster-Tarski Theorem using @{term lfp} *}
    39 
    40 text{*@{term "lfp f"} is the least upper bound of 
    41       the set @{term "{u. f(u) \<le> u}"} *}
    42 
    43 lemma lfp_lowerbound: "f A \<le> A ==> lfp f \<le> A"
    44   by (auto simp add: lfp_def intro: Inf_lower)
    45 
    46 lemma lfp_greatest: "(!!u. f u \<le> u ==> A \<le> u) ==> A \<le> lfp f"
    47   by (auto simp add: lfp_def intro: Inf_greatest)
    48 
    49 end
    50 
    51 lemma lfp_lemma2: "mono f ==> f (lfp f) \<le> lfp f"
    52   by (iprover intro: lfp_greatest order_trans monoD lfp_lowerbound)
    53 
    54 lemma lfp_lemma3: "mono f ==> lfp f \<le> f (lfp f)"
    55   by (iprover intro: lfp_lemma2 monoD lfp_lowerbound)
    56 
    57 lemma lfp_unfold: "mono f ==> lfp f = f (lfp f)"
    58   by (iprover intro: order_antisym lfp_lemma2 lfp_lemma3)
    59 
    60 lemma lfp_const: "lfp (\<lambda>x. t) = t"
    61   by (rule lfp_unfold) (simp add:mono_def)
    62 
    63 
    64 subsection {* General induction rules for least fixed points *}
    65 
    66 theorem lfp_induct:
    67   assumes mono: "mono f" and ind: "f (inf (lfp f) P) <= P"
    68   shows "lfp f <= P"
    69 proof -
    70   have "inf (lfp f) P <= lfp f" by (rule inf_le1)
    71   with mono have "f (inf (lfp f) P) <= f (lfp f)" ..
    72   also from mono have "f (lfp f) = lfp f" by (rule lfp_unfold [symmetric])
    73   finally have "f (inf (lfp f) P) <= lfp f" .
    74   from this and ind have "f (inf (lfp f) P) <= inf (lfp f) P" by (rule le_infI)
    75   hence "lfp f <= inf (lfp f) P" by (rule lfp_lowerbound)
    76   also have "inf (lfp f) P <= P" by (rule inf_le2)
    77   finally show ?thesis .
    78 qed
    79 
    80 lemma lfp_induct_set:
    81   assumes lfp: "a: lfp(f)"
    82       and mono: "mono(f)"
    83       and indhyp: "!!x. [| x: f(lfp(f) Int {x. P(x)}) |] ==> P(x)"
    84   shows "P(a)"
    85   by (rule lfp_induct [THEN subsetD, THEN CollectD, OF mono _ lfp])
    86     (auto simp: inf_set_eq intro: indhyp)
    87 
    88 lemma lfp_ordinal_induct:
    89   fixes f :: "'a\<Colon>complete_lattice \<Rightarrow> 'a"
    90   assumes mono: "mono f"
    91   and P_f: "\<And>S. P S \<Longrightarrow> P (f S)"
    92   and P_Union: "\<And>M. \<forall>S\<in>M. P S \<Longrightarrow> P (Sup M)"
    93   shows "P (lfp f)"
    94 proof -
    95   let ?M = "{S. S \<le> lfp f \<and> P S}"
    96   have "P (Sup ?M)" using P_Union by simp
    97   also have "Sup ?M = lfp f"
    98   proof (rule antisym)
    99     show "Sup ?M \<le> lfp f" by (blast intro: Sup_least)
   100     hence "f (Sup ?M) \<le> f (lfp f)" by (rule mono [THEN monoD])
   101     hence "f (Sup ?M) \<le> lfp f" using mono [THEN lfp_unfold] by simp
   102     hence "f (Sup ?M) \<in> ?M" using P_f P_Union by simp
   103     hence "f (Sup ?M) \<le> Sup ?M" by (rule Sup_upper)
   104     thus "lfp f \<le> Sup ?M" by (rule lfp_lowerbound)
   105   qed
   106   finally show ?thesis .
   107 qed 
   108 
   109 lemma lfp_ordinal_induct_set: 
   110   assumes mono: "mono f"
   111   and P_f: "!!S. P S ==> P(f S)"
   112   and P_Union: "!!M. !S:M. P S ==> P(Union M)"
   113   shows "P(lfp f)"
   114   using assms unfolding Sup_set_eq [symmetric]
   115   by (rule lfp_ordinal_induct [where P=P])
   116 
   117 
   118 text{*Definition forms of @{text lfp_unfold} and @{text lfp_induct}, 
   119     to control unfolding*}
   120 
   121 lemma def_lfp_unfold: "[| h==lfp(f);  mono(f) |] ==> h = f(h)"
   122 by (auto intro!: lfp_unfold)
   123 
   124 lemma def_lfp_induct: 
   125     "[| A == lfp(f); mono(f);
   126         f (inf A P) \<le> P
   127      |] ==> A \<le> P"
   128   by (blast intro: lfp_induct)
   129 
   130 lemma def_lfp_induct_set: 
   131     "[| A == lfp(f);  mono(f);   a:A;                    
   132         !!x. [| x: f(A Int {x. P(x)}) |] ==> P(x)         
   133      |] ==> P(a)"
   134   by (blast intro: lfp_induct_set)
   135 
   136 (*Monotonicity of lfp!*)
   137 lemma lfp_mono: "(!!Z. f Z \<le> g Z) ==> lfp f \<le> lfp g"
   138   by (rule lfp_lowerbound [THEN lfp_greatest], blast intro: order_trans)
   139 
   140 
   141 subsection {* Proof of Knaster-Tarski Theorem using @{term gfp} *}
   142 
   143 text{*@{term "gfp f"} is the greatest lower bound of 
   144       the set @{term "{u. u \<le> f(u)}"} *}
   145 
   146 lemma gfp_upperbound: "X \<le> f X ==> X \<le> gfp f"
   147   by (auto simp add: gfp_def intro: Sup_upper)
   148 
   149 lemma gfp_least: "(!!u. u \<le> f u ==> u \<le> X) ==> gfp f \<le> X"
   150   by (auto simp add: gfp_def intro: Sup_least)
   151 
   152 lemma gfp_lemma2: "mono f ==> gfp f \<le> f (gfp f)"
   153   by (iprover intro: gfp_least order_trans monoD gfp_upperbound)
   154 
   155 lemma gfp_lemma3: "mono f ==> f (gfp f) \<le> gfp f"
   156   by (iprover intro: gfp_lemma2 monoD gfp_upperbound)
   157 
   158 lemma gfp_unfold: "mono f ==> gfp f = f (gfp f)"
   159   by (iprover intro: order_antisym gfp_lemma2 gfp_lemma3)
   160 
   161 
   162 subsection {* Coinduction rules for greatest fixed points *}
   163 
   164 text{*weak version*}
   165 lemma weak_coinduct: "[| a: X;  X \<subseteq> f(X) |] ==> a : gfp(f)"
   166 by (rule gfp_upperbound [THEN subsetD], auto)
   167 
   168 lemma weak_coinduct_image: "!!X. [| a : X; g`X \<subseteq> f (g`X) |] ==> g a : gfp f"
   169 apply (erule gfp_upperbound [THEN subsetD])
   170 apply (erule imageI)
   171 done
   172 
   173 lemma coinduct_lemma:
   174      "[| X \<le> f (sup X (gfp f));  mono f |] ==> sup X (gfp f) \<le> f (sup X (gfp f))"
   175   apply (frule gfp_lemma2)
   176   apply (drule mono_sup)
   177   apply (rule le_supI)
   178   apply assumption
   179   apply (rule order_trans)
   180   apply (rule order_trans)
   181   apply assumption
   182   apply (rule sup_ge2)
   183   apply assumption
   184   done
   185 
   186 text{*strong version, thanks to Coen and Frost*}
   187 lemma coinduct_set: "[| mono(f);  a: X;  X \<subseteq> f(X Un gfp(f)) |] ==> a : gfp(f)"
   188 by (blast intro: weak_coinduct [OF _ coinduct_lemma, simplified sup_set_eq])
   189 
   190 lemma coinduct: "[| mono(f); X \<le> f (sup X (gfp f)) |] ==> X \<le> gfp(f)"
   191   apply (rule order_trans)
   192   apply (rule sup_ge1)
   193   apply (erule gfp_upperbound [OF coinduct_lemma])
   194   apply assumption
   195   done
   196 
   197 lemma gfp_fun_UnI2: "[| mono(f);  a: gfp(f) |] ==> a: f(X Un gfp(f))"
   198 by (blast dest: gfp_lemma2 mono_Un)
   199 
   200 
   201 subsection {* Even Stronger Coinduction Rule, by Martin Coen *}
   202 
   203 text{* Weakens the condition @{term "X \<subseteq> f(X)"} to one expressed using both
   204   @{term lfp} and @{term gfp}*}
   205 
   206 lemma coinduct3_mono_lemma: "mono(f) ==> mono(%x. f(x) Un X Un B)"
   207 by (iprover intro: subset_refl monoI Un_mono monoD)
   208 
   209 lemma coinduct3_lemma:
   210      "[| X \<subseteq> f(lfp(%x. f(x) Un X Un gfp(f)));  mono(f) |]
   211       ==> lfp(%x. f(x) Un X Un gfp(f)) \<subseteq> f(lfp(%x. f(x) Un X Un gfp(f)))"
   212 apply (rule subset_trans)
   213 apply (erule coinduct3_mono_lemma [THEN lfp_lemma3])
   214 apply (rule Un_least [THEN Un_least])
   215 apply (rule subset_refl, assumption)
   216 apply (rule gfp_unfold [THEN equalityD1, THEN subset_trans], assumption)
   217 apply (rule monoD [where f=f], assumption)
   218 apply (subst coinduct3_mono_lemma [THEN lfp_unfold], auto)
   219 done
   220 
   221 lemma coinduct3: 
   222   "[| mono(f);  a:X;  X \<subseteq> f(lfp(%x. f(x) Un X Un gfp(f))) |] ==> a : gfp(f)"
   223 apply (rule coinduct3_lemma [THEN [2] weak_coinduct])
   224 apply (rule coinduct3_mono_lemma [THEN lfp_unfold, THEN ssubst], auto)
   225 done
   226 
   227 
   228 text{*Definition forms of @{text gfp_unfold} and @{text coinduct}, 
   229     to control unfolding*}
   230 
   231 lemma def_gfp_unfold: "[| A==gfp(f);  mono(f) |] ==> A = f(A)"
   232 by (auto intro!: gfp_unfold)
   233 
   234 lemma def_coinduct:
   235      "[| A==gfp(f);  mono(f);  X \<le> f(sup X A) |] ==> X \<le> A"
   236 by (iprover intro!: coinduct)
   237 
   238 lemma def_coinduct_set:
   239      "[| A==gfp(f);  mono(f);  a:X;  X \<subseteq> f(X Un A) |] ==> a: A"
   240 by (auto intro!: coinduct_set)
   241 
   242 (*The version used in the induction/coinduction package*)
   243 lemma def_Collect_coinduct:
   244     "[| A == gfp(%w. Collect(P(w)));  mono(%w. Collect(P(w)));   
   245         a: X;  !!z. z: X ==> P (X Un A) z |] ==>  
   246      a : A"
   247 apply (erule def_coinduct_set, auto) 
   248 done
   249 
   250 lemma def_coinduct3:
   251     "[| A==gfp(f); mono(f);  a:X;  X \<subseteq> f(lfp(%x. f(x) Un X Un A)) |] ==> a: A"
   252 by (auto intro!: coinduct3)
   253 
   254 text{*Monotonicity of @{term gfp}!*}
   255 lemma gfp_mono: "(!!Z. f Z \<le> g Z) ==> gfp f \<le> gfp g"
   256   by (rule gfp_upperbound [THEN gfp_least], blast intro: order_trans)
   257 
   258 
   259 subsection {* Inductive predicates and sets *}
   260 
   261 text {* Inversion of injective functions. *}
   262 
   263 constdefs
   264   myinv :: "('a => 'b) => ('b => 'a)"
   265   "myinv (f :: 'a => 'b) == \<lambda>y. THE x. f x = y"
   266 
   267 lemma myinv_f_f: "inj f ==> myinv f (f x) = x"
   268 proof -
   269   assume "inj f"
   270   hence "(THE x'. f x' = f x) = (THE x'. x' = x)"
   271     by (simp only: inj_eq)
   272   also have "... = x" by (rule the_eq_trivial)
   273   finally show ?thesis by (unfold myinv_def)
   274 qed
   275 
   276 lemma f_myinv_f: "inj f ==> y \<in> range f ==> f (myinv f y) = y"
   277 proof (unfold myinv_def)
   278   assume inj: "inj f"
   279   assume "y \<in> range f"
   280   then obtain x where "y = f x" ..
   281   hence x: "f x = y" ..
   282   thus "f (THE x. f x = y) = y"
   283   proof (rule theI)
   284     fix x' assume "f x' = y"
   285     with x have "f x' = f x" by simp
   286     with inj show "x' = x" by (rule injD)
   287   qed
   288 qed
   289 
   290 hide const myinv
   291 
   292 
   293 text {* Package setup. *}
   294 
   295 theorems basic_monos =
   296   subset_refl imp_refl disj_mono conj_mono ex_mono all_mono if_bool_eq_conj
   297   Collect_mono in_mono vimage_mono
   298   imp_conv_disj not_not de_Morgan_disj de_Morgan_conj
   299   not_all not_ex
   300   Ball_def Bex_def
   301   induct_rulify_fallback
   302 
   303 ML {*
   304 val def_lfp_unfold = @{thm def_lfp_unfold}
   305 val def_gfp_unfold = @{thm def_gfp_unfold}
   306 val def_lfp_induct = @{thm def_lfp_induct}
   307 val def_coinduct = @{thm def_coinduct}
   308 val inf_bool_eq = @{thm inf_bool_eq} RS @{thm eq_reflection}
   309 val inf_fun_eq = @{thm inf_fun_eq} RS @{thm eq_reflection}
   310 val sup_bool_eq = @{thm sup_bool_eq} RS @{thm eq_reflection}
   311 val sup_fun_eq = @{thm sup_fun_eq} RS @{thm eq_reflection}
   312 val le_boolI = @{thm le_boolI}
   313 val le_boolI' = @{thm le_boolI'}
   314 val le_funI = @{thm le_funI}
   315 val le_boolE = @{thm le_boolE}
   316 val le_funE = @{thm le_funE}
   317 val le_boolD = @{thm le_boolD}
   318 val le_funD = @{thm le_funD}
   319 val le_bool_def = @{thm le_bool_def} RS @{thm eq_reflection}
   320 val le_fun_def = @{thm le_fun_def} RS @{thm eq_reflection}
   321 *}
   322 
   323 use "Tools/inductive_package.ML"
   324 setup InductivePackage.setup
   325 
   326 theorems [mono] =
   327   imp_refl disj_mono conj_mono ex_mono all_mono if_bool_eq_conj
   328   imp_conv_disj not_not de_Morgan_disj de_Morgan_conj
   329   not_all not_ex
   330   Ball_def Bex_def
   331   induct_rulify_fallback
   332 
   333 
   334 subsection {* Inductive datatypes and primitive recursion *}
   335 
   336 text {* Package setup. *}
   337 
   338 use "Tools/datatype_aux.ML"
   339 use "Tools/datatype_prop.ML"
   340 use "Tools/datatype_rep_proofs.ML"
   341 use "Tools/datatype_abs_proofs.ML"
   342 use "Tools/datatype_case.ML"
   343 use "Tools/datatype_package.ML"
   344 setup DatatypePackage.setup
   345 use "Tools/old_primrec_package.ML"
   346 use "Tools/primrec_package.ML"
   347 
   348 use "Tools/datatype_codegen.ML"
   349 setup DatatypeCodegen.setup
   350 
   351 use "Tools/inductive_codegen.ML"
   352 setup InductiveCodegen.setup
   353 
   354 text{* Lambda-abstractions with pattern matching: *}
   355 
   356 syntax
   357   "_lam_pats_syntax" :: "cases_syn => 'a => 'b"               ("(%_)" 10)
   358 syntax (xsymbols)
   359   "_lam_pats_syntax" :: "cases_syn => 'a => 'b"               ("(\<lambda>_)" 10)
   360 
   361 parse_translation (advanced) {*
   362 let
   363   fun fun_tr ctxt [cs] =
   364     let
   365       val x = Free (Name.variant (Term.add_free_names cs []) "x", dummyT);
   366       val ft = DatatypeCase.case_tr true DatatypePackage.datatype_of_constr
   367                  ctxt [x, cs]
   368     in lambda x ft end
   369 in [("_lam_pats_syntax", fun_tr)] end
   370 *}
   371 
   372 end