src/HOL/Presburger.thy
author nipkow
Fri Mar 06 17:38:47 2009 +0100 (2009-03-06)
changeset 30313 b2441b0c8d38
parent 30242 aea5d7fa7ef5
child 30510 4120fc59dd85
permissions -rw-r--r--
added lemmas
     1 (* Title:      HOL/Presburger.thy
     2    Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 header {* Decision Procedure for Presburger Arithmetic *}
     6 
     7 theory Presburger
     8 imports Groebner_Basis SetInterval
     9 uses
    10   "Tools/Qelim/cooper_data.ML"
    11   "Tools/Qelim/generated_cooper.ML"
    12   ("Tools/Qelim/cooper.ML")
    13   ("Tools/Qelim/presburger.ML")
    14 begin
    15 
    16 setup CooperData.setup
    17 
    18 subsection{* The @{text "-\<infinity>"} and @{text "+\<infinity>"} Properties *}
    19 
    20 
    21 lemma minf:
    22   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x<z. P x = P' x; \<exists>z.\<forall>x<z. Q x = Q' x\<rbrakk> 
    23      \<Longrightarrow> \<exists>z.\<forall>x<z. (P x \<and> Q x) = (P' x \<and> Q' x)"
    24   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x<z. P x = P' x; \<exists>z.\<forall>x<z. Q x = Q' x\<rbrakk> 
    25      \<Longrightarrow> \<exists>z.\<forall>x<z. (P x \<or> Q x) = (P' x \<or> Q' x)"
    26   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x = t) = False"
    27   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<noteq> t) = True"
    28   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x < t) = True"
    29   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<le> t) = True"
    30   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x > t) = False"
    31   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<ge> t) = False"
    32   "\<exists>z.\<forall>(x::'a::{linorder,plus,Ring_and_Field.dvd})<z. (d dvd x + s) = (d dvd x + s)"
    33   "\<exists>z.\<forall>(x::'a::{linorder,plus,Ring_and_Field.dvd})<z. (\<not> d dvd x + s) = (\<not> d dvd x + s)"
    34   "\<exists>z.\<forall>x<z. F = F"
    35   by ((erule exE, erule exE,rule_tac x="min z za" in exI,simp)+, (rule_tac x="t" in exI,fastsimp)+) simp_all
    36 
    37 lemma pinf:
    38   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x>z. P x = P' x; \<exists>z.\<forall>x>z. Q x = Q' x\<rbrakk> 
    39      \<Longrightarrow> \<exists>z.\<forall>x>z. (P x \<and> Q x) = (P' x \<and> Q' x)"
    40   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x>z. P x = P' x; \<exists>z.\<forall>x>z. Q x = Q' x\<rbrakk> 
    41      \<Longrightarrow> \<exists>z.\<forall>x>z. (P x \<or> Q x) = (P' x \<or> Q' x)"
    42   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x = t) = False"
    43   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<noteq> t) = True"
    44   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x < t) = False"
    45   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<le> t) = False"
    46   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x > t) = True"
    47   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<ge> t) = True"
    48   "\<exists>z.\<forall>(x::'a::{linorder,plus,Ring_and_Field.dvd})>z. (d dvd x + s) = (d dvd x + s)"
    49   "\<exists>z.\<forall>(x::'a::{linorder,plus,Ring_and_Field.dvd})>z. (\<not> d dvd x + s) = (\<not> d dvd x + s)"
    50   "\<exists>z.\<forall>x>z. F = F"
    51   by ((erule exE, erule exE,rule_tac x="max z za" in exI,simp)+,(rule_tac x="t" in exI,fastsimp)+) simp_all
    52 
    53 lemma inf_period:
    54   "\<lbrakk>\<forall>x k. P x = P (x - k*D); \<forall>x k. Q x = Q (x - k*D)\<rbrakk> 
    55     \<Longrightarrow> \<forall>x k. (P x \<and> Q x) = (P (x - k*D) \<and> Q (x - k*D))"
    56   "\<lbrakk>\<forall>x k. P x = P (x - k*D); \<forall>x k. Q x = Q (x - k*D)\<rbrakk> 
    57     \<Longrightarrow> \<forall>x k. (P x \<or> Q x) = (P (x - k*D) \<or> Q (x - k*D))"
    58   "(d::'a::{comm_ring,Ring_and_Field.dvd}) dvd D \<Longrightarrow> \<forall>x k. (d dvd x + t) = (d dvd (x - k*D) + t)"
    59   "(d::'a::{comm_ring,Ring_and_Field.dvd}) dvd D \<Longrightarrow> \<forall>x k. (\<not>d dvd x + t) = (\<not>d dvd (x - k*D) + t)"
    60   "\<forall>x k. F = F"
    61 apply (auto elim!: dvdE simp add: algebra_simps)
    62 unfolding mult_assoc [symmetric] left_distrib [symmetric] left_diff_distrib [symmetric]
    63 unfolding dvd_def mult_commute [of d] 
    64 by auto
    65 
    66 subsection{* The A and B sets *}
    67 lemma bset:
    68   "\<lbrakk>\<forall>x.(\<forall>j \<in> {1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> P x \<longrightarrow> P(x - D) ;
    69      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> Q x \<longrightarrow> Q(x - D)\<rbrakk> \<Longrightarrow> 
    70   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j) \<longrightarrow> (P x \<and> Q x) \<longrightarrow> (P(x - D) \<and> Q (x - D))"
    71   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> P x \<longrightarrow> P(x - D) ;
    72      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> Q x \<longrightarrow> Q(x - D)\<rbrakk> \<Longrightarrow> 
    73   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (P x \<or> Q x) \<longrightarrow> (P(x - D) \<or> Q (x - D))"
    74   "\<lbrakk>D>0; t - 1\<in> B\<rbrakk> \<Longrightarrow> (\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x = t) \<longrightarrow> (x - D = t))"
    75   "\<lbrakk>D>0 ; t \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x - D \<noteq> t))"
    76   "D>0 \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x < t) \<longrightarrow> (x - D < t))"
    77   "D>0 \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x - D \<le> t))"
    78   "\<lbrakk>D>0 ; t \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x > t) \<longrightarrow> (x - D > t))"
    79   "\<lbrakk>D>0 ; t - 1 \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x - D \<ge> t))"
    80   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x - D) + t))"
    81   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not> d dvd (x - D) + t))"
    82   "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j) \<longrightarrow> F \<longrightarrow> F"
    83 proof (blast, blast)
    84   assume dp: "D > 0" and tB: "t - 1\<in> B"
    85   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x = t) \<longrightarrow> (x - D = t))" 
    86     apply (rule allI, rule impI,erule ballE[where x="1"],erule ballE[where x="t - 1"]) 
    87     apply algebra using dp tB by simp_all
    88 next
    89   assume dp: "D > 0" and tB: "t \<in> B"
    90   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x - D \<noteq> t))" 
    91     apply (rule allI, rule impI,erule ballE[where x="D"],erule ballE[where x="t"])
    92     apply algebra
    93     using dp tB by simp_all
    94 next
    95   assume dp: "D > 0" thus "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x < t) \<longrightarrow> (x - D < t))" by arith
    96 next
    97   assume dp: "D > 0" thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x - D \<le> t)" by arith
    98 next
    99   assume dp: "D > 0" and tB:"t \<in> B"
   100   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j" and g: "x > t" and ng: "\<not> (x - D) > t"
   101     hence "x -t \<le> D" and "1 \<le> x - t" by simp+
   102       hence "\<exists>j \<in> {1 .. D}. x - t = j" by auto
   103       hence "\<exists>j \<in> {1 .. D}. x = t + j" by (simp add: algebra_simps)
   104       with nob tB have "False" by simp}
   105   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x > t) \<longrightarrow> (x - D > t)" by blast
   106 next
   107   assume dp: "D > 0" and tB:"t - 1\<in> B"
   108   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j" and g: "x \<ge> t" and ng: "\<not> (x - D) \<ge> t"
   109     hence "x - (t - 1) \<le> D" and "1 \<le> x - (t - 1)" by simp+
   110       hence "\<exists>j \<in> {1 .. D}. x - (t - 1) = j" by auto
   111       hence "\<exists>j \<in> {1 .. D}. x = (t - 1) + j" by (simp add: algebra_simps)
   112       with nob tB have "False" by simp}
   113   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x - D \<ge> t)" by blast
   114 next
   115   assume d: "d dvd D"
   116   {fix x assume H: "d dvd x + t" with d have "d dvd (x - D) + t" by algebra}
   117   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x - D) + t)" by simp
   118 next
   119   assume d: "d dvd D"
   120   {fix x assume H: "\<not>(d dvd x + t)" with d have "\<not> d dvd (x - D) + t"
   121       by (clarsimp simp add: dvd_def,erule_tac x= "ka + k" in allE,simp add: algebra_simps)}
   122   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not>d dvd (x - D) + t)" by auto
   123 qed blast
   124 
   125 lemma aset:
   126   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> P x \<longrightarrow> P(x + D) ;
   127      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> Q x \<longrightarrow> Q(x + D)\<rbrakk> \<Longrightarrow> 
   128   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j) \<longrightarrow> (P x \<and> Q x) \<longrightarrow> (P(x + D) \<and> Q (x + D))"
   129   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> P x \<longrightarrow> P(x + D) ;
   130      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> Q x \<longrightarrow> Q(x + D)\<rbrakk> \<Longrightarrow> 
   131   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (P x \<or> Q x) \<longrightarrow> (P(x + D) \<or> Q (x + D))"
   132   "\<lbrakk>D>0; t + 1\<in> A\<rbrakk> \<Longrightarrow> (\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x = t) \<longrightarrow> (x + D = t))"
   133   "\<lbrakk>D>0 ; t \<in> A\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x + D \<noteq> t))"
   134   "\<lbrakk>D>0; t\<in> A\<rbrakk> \<Longrightarrow>(\<forall>(x::int). (\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x < t) \<longrightarrow> (x + D < t))"
   135   "\<lbrakk>D>0; t + 1 \<in> A\<rbrakk> \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x + D \<le> t))"
   136   "D>0 \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x > t) \<longrightarrow> (x + D > t))"
   137   "D>0 \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x + D \<ge> t))"
   138   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x + D) + t))"
   139   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not> d dvd (x + D) + t))"
   140   "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j) \<longrightarrow> F \<longrightarrow> F"
   141 proof (blast, blast)
   142   assume dp: "D > 0" and tA: "t + 1 \<in> A"
   143   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x = t) \<longrightarrow> (x + D = t))" 
   144     apply (rule allI, rule impI,erule ballE[where x="1"],erule ballE[where x="t + 1"])
   145     using dp tA by simp_all
   146 next
   147   assume dp: "D > 0" and tA: "t \<in> A"
   148   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x + D \<noteq> t))" 
   149     apply (rule allI, rule impI,erule ballE[where x="D"],erule ballE[where x="t"])
   150     using dp tA by simp_all
   151 next
   152   assume dp: "D > 0" thus "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x > t) \<longrightarrow> (x + D > t))" by arith
   153 next
   154   assume dp: "D > 0" thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x + D \<ge> t)" by arith
   155 next
   156   assume dp: "D > 0" and tA:"t \<in> A"
   157   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j" and g: "x < t" and ng: "\<not> (x + D) < t"
   158     hence "t - x \<le> D" and "1 \<le> t - x" by simp+
   159       hence "\<exists>j \<in> {1 .. D}. t - x = j" by auto
   160       hence "\<exists>j \<in> {1 .. D}. x = t - j" by (auto simp add: algebra_simps) 
   161       with nob tA have "False" by simp}
   162   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x < t) \<longrightarrow> (x + D < t)" by blast
   163 next
   164   assume dp: "D > 0" and tA:"t + 1\<in> A"
   165   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j" and g: "x \<le> t" and ng: "\<not> (x + D) \<le> t"
   166     hence "(t + 1) - x \<le> D" and "1 \<le> (t + 1) - x" by (simp_all add: algebra_simps)
   167       hence "\<exists>j \<in> {1 .. D}. (t + 1) - x = j" by auto
   168       hence "\<exists>j \<in> {1 .. D}. x = (t + 1) - j" by (auto simp add: algebra_simps)
   169       with nob tA have "False" by simp}
   170   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x + D \<le> t)" by blast
   171 next
   172   assume d: "d dvd D"
   173   {fix x assume H: "d dvd x + t" with d have "d dvd (x + D) + t"
   174       by (clarsimp simp add: dvd_def,rule_tac x= "ka + k" in exI,simp add: algebra_simps)}
   175   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x + D) + t)" by simp
   176 next
   177   assume d: "d dvd D"
   178   {fix x assume H: "\<not>(d dvd x + t)" with d have "\<not>d dvd (x + D) + t"
   179       by (clarsimp simp add: dvd_def,erule_tac x= "ka - k" in allE,simp add: algebra_simps)}
   180   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not>d dvd (x + D) + t)" by auto
   181 qed blast
   182 
   183 subsection{* Cooper's Theorem @{text "-\<infinity>"} and @{text "+\<infinity>"} Version *}
   184 
   185 subsubsection{* First some trivial facts about periodic sets or predicates *}
   186 lemma periodic_finite_ex:
   187   assumes dpos: "(0::int) < d" and modd: "ALL x k. P x = P(x - k*d)"
   188   shows "(EX x. P x) = (EX j : {1..d}. P j)"
   189   (is "?LHS = ?RHS")
   190 proof
   191   assume ?LHS
   192   then obtain x where P: "P x" ..
   193   have "x mod d = x - (x div d)*d" by(simp add:zmod_zdiv_equality mult_ac eq_diff_eq)
   194   hence Pmod: "P x = P(x mod d)" using modd by simp
   195   show ?RHS
   196   proof (cases)
   197     assume "x mod d = 0"
   198     hence "P 0" using P Pmod by simp
   199     moreover have "P 0 = P(0 - (-1)*d)" using modd by blast
   200     ultimately have "P d" by simp
   201     moreover have "d : {1..d}" using dpos by(simp add:atLeastAtMost_iff)
   202     ultimately show ?RHS ..
   203   next
   204     assume not0: "x mod d \<noteq> 0"
   205     have "P(x mod d)" using dpos P Pmod by(simp add:pos_mod_sign pos_mod_bound)
   206     moreover have "x mod d : {1..d}"
   207     proof -
   208       from dpos have "0 \<le> x mod d" by(rule pos_mod_sign)
   209       moreover from dpos have "x mod d < d" by(rule pos_mod_bound)
   210       ultimately show ?thesis using not0 by(simp add:atLeastAtMost_iff)
   211     qed
   212     ultimately show ?RHS ..
   213   qed
   214 qed auto
   215 
   216 subsubsection{* The @{text "-\<infinity>"} Version*}
   217 
   218 lemma decr_lemma: "0 < (d::int) \<Longrightarrow> x - (abs(x-z)+1) * d < z"
   219 by(induct rule: int_gr_induct,simp_all add:int_distrib)
   220 
   221 lemma incr_lemma: "0 < (d::int) \<Longrightarrow> z < x + (abs(x-z)+1) * d"
   222 by(induct rule: int_gr_induct, simp_all add:int_distrib)
   223 
   224 theorem int_induct[case_names base step1 step2]:
   225   assumes 
   226   base: "P(k::int)" and step1: "\<And>i. \<lbrakk>k \<le> i; P i\<rbrakk> \<Longrightarrow> P(i+1)" and
   227   step2: "\<And>i. \<lbrakk>k \<ge> i; P i\<rbrakk> \<Longrightarrow> P(i - 1)"
   228   shows "P i"
   229 proof -
   230   have "i \<le> k \<or> i\<ge> k" by arith
   231   thus ?thesis using prems int_ge_induct[where P="P" and k="k" and i="i"] int_le_induct[where P="P" and k="k" and i="i"] by blast
   232 qed
   233 
   234 lemma decr_mult_lemma:
   235   assumes dpos: "(0::int) < d" and minus: "\<forall>x. P x \<longrightarrow> P(x - d)" and knneg: "0 <= k"
   236   shows "ALL x. P x \<longrightarrow> P(x - k*d)"
   237 using knneg
   238 proof (induct rule:int_ge_induct)
   239   case base thus ?case by simp
   240 next
   241   case (step i)
   242   {fix x
   243     have "P x \<longrightarrow> P (x - i * d)" using step.hyps by blast
   244     also have "\<dots> \<longrightarrow> P(x - (i + 1) * d)" using minus[THEN spec, of "x - i * d"]
   245       by (simp add:int_distrib OrderedGroup.diff_diff_eq[symmetric])
   246     ultimately have "P x \<longrightarrow> P(x - (i + 1) * d)" by blast}
   247   thus ?case ..
   248 qed
   249 
   250 lemma  minusinfinity:
   251   assumes dpos: "0 < d" and
   252     P1eqP1: "ALL x k. P1 x = P1(x - k*d)" and ePeqP1: "EX z::int. ALL x. x < z \<longrightarrow> (P x = P1 x)"
   253   shows "(EX x. P1 x) \<longrightarrow> (EX x. P x)"
   254 proof
   255   assume eP1: "EX x. P1 x"
   256   then obtain x where P1: "P1 x" ..
   257   from ePeqP1 obtain z where P1eqP: "ALL x. x < z \<longrightarrow> (P x = P1 x)" ..
   258   let ?w = "x - (abs(x-z)+1) * d"
   259   from dpos have w: "?w < z" by(rule decr_lemma)
   260   have "P1 x = P1 ?w" using P1eqP1 by blast
   261   also have "\<dots> = P(?w)" using w P1eqP by blast
   262   finally have "P ?w" using P1 by blast
   263   thus "EX x. P x" ..
   264 qed
   265 
   266 lemma cpmi: 
   267   assumes dp: "0 < D" and p1:"\<exists>z. \<forall> x< z. P x = P' x"
   268   and nb:"\<forall>x.(\<forall> j\<in> {1..D}. \<forall>(b::int) \<in> B. x \<noteq> b+j) --> P (x) --> P (x - D)"
   269   and pd: "\<forall> x k. P' x = P' (x-k*D)"
   270   shows "(\<exists>x. P x) = ((\<exists> j\<in> {1..D} . P' j) | (\<exists> j \<in> {1..D}.\<exists> b\<in> B. P (b+j)))" 
   271          (is "?L = (?R1 \<or> ?R2)")
   272 proof-
   273  {assume "?R2" hence "?L"  by blast}
   274  moreover
   275  {assume H:"?R1" hence "?L" using minusinfinity[OF dp pd p1] periodic_finite_ex[OF dp pd] by simp}
   276  moreover 
   277  { fix x
   278    assume P: "P x" and H: "\<not> ?R2"
   279    {fix y assume "\<not> (\<exists>j\<in>{1..D}. \<exists>b\<in>B. P (b + j))" and P: "P y"
   280      hence "~(EX (j::int) : {1..D}. EX (b::int) : B. y = b+j)" by auto
   281      with nb P  have "P (y - D)" by auto }
   282    hence "ALL x.~(EX (j::int) : {1..D}. EX (b::int) : B. P(b+j)) --> P (x) --> P (x - D)" by blast
   283    with H P have th: " \<forall>x. P x \<longrightarrow> P (x - D)" by auto
   284    from p1 obtain z where z: "ALL x. x < z --> (P x = P' x)" by blast
   285    let ?y = "x - (\<bar>x - z\<bar> + 1)*D"
   286    have zp: "0 <= (\<bar>x - z\<bar> + 1)" by arith
   287    from dp have yz: "?y < z" using decr_lemma[OF dp] by simp   
   288    from z[rule_format, OF yz] decr_mult_lemma[OF dp th zp, rule_format, OF P] have th2: " P' ?y" by auto
   289    with periodic_finite_ex[OF dp pd]
   290    have "?R1" by blast}
   291  ultimately show ?thesis by blast
   292 qed
   293 
   294 subsubsection {* The @{text "+\<infinity>"} Version*}
   295 
   296 lemma  plusinfinity:
   297   assumes dpos: "(0::int) < d" and
   298     P1eqP1: "\<forall>x k. P' x = P'(x - k*d)" and ePeqP1: "\<exists> z. \<forall> x>z. P x = P' x"
   299   shows "(\<exists> x. P' x) \<longrightarrow> (\<exists> x. P x)"
   300 proof
   301   assume eP1: "EX x. P' x"
   302   then obtain x where P1: "P' x" ..
   303   from ePeqP1 obtain z where P1eqP: "\<forall>x>z. P x = P' x" ..
   304   let ?w' = "x + (abs(x-z)+1) * d"
   305   let ?w = "x - (-(abs(x-z) + 1))*d"
   306   have ww'[simp]: "?w = ?w'" by (simp add: algebra_simps)
   307   from dpos have w: "?w > z" by(simp only: ww' incr_lemma)
   308   hence "P' x = P' ?w" using P1eqP1 by blast
   309   also have "\<dots> = P(?w)" using w P1eqP by blast
   310   finally have "P ?w" using P1 by blast
   311   thus "EX x. P x" ..
   312 qed
   313 
   314 lemma incr_mult_lemma:
   315   assumes dpos: "(0::int) < d" and plus: "ALL x::int. P x \<longrightarrow> P(x + d)" and knneg: "0 <= k"
   316   shows "ALL x. P x \<longrightarrow> P(x + k*d)"
   317 using knneg
   318 proof (induct rule:int_ge_induct)
   319   case base thus ?case by simp
   320 next
   321   case (step i)
   322   {fix x
   323     have "P x \<longrightarrow> P (x + i * d)" using step.hyps by blast
   324     also have "\<dots> \<longrightarrow> P(x + (i + 1) * d)" using plus[THEN spec, of "x + i * d"]
   325       by (simp add:int_distrib zadd_ac)
   326     ultimately have "P x \<longrightarrow> P(x + (i + 1) * d)" by blast}
   327   thus ?case ..
   328 qed
   329 
   330 lemma cppi: 
   331   assumes dp: "0 < D" and p1:"\<exists>z. \<forall> x> z. P x = P' x"
   332   and nb:"\<forall>x.(\<forall> j\<in> {1..D}. \<forall>(b::int) \<in> A. x \<noteq> b - j) --> P (x) --> P (x + D)"
   333   and pd: "\<forall> x k. P' x= P' (x-k*D)"
   334   shows "(\<exists>x. P x) = ((\<exists> j\<in> {1..D} . P' j) | (\<exists> j \<in> {1..D}.\<exists> b\<in> A. P (b - j)))" (is "?L = (?R1 \<or> ?R2)")
   335 proof-
   336  {assume "?R2" hence "?L"  by blast}
   337  moreover
   338  {assume H:"?R1" hence "?L" using plusinfinity[OF dp pd p1] periodic_finite_ex[OF dp pd] by simp}
   339  moreover 
   340  { fix x
   341    assume P: "P x" and H: "\<not> ?R2"
   342    {fix y assume "\<not> (\<exists>j\<in>{1..D}. \<exists>b\<in>A. P (b - j))" and P: "P y"
   343      hence "~(EX (j::int) : {1..D}. EX (b::int) : A. y = b - j)" by auto
   344      with nb P  have "P (y + D)" by auto }
   345    hence "ALL x.~(EX (j::int) : {1..D}. EX (b::int) : A. P(b-j)) --> P (x) --> P (x + D)" by blast
   346    with H P have th: " \<forall>x. P x \<longrightarrow> P (x + D)" by auto
   347    from p1 obtain z where z: "ALL x. x > z --> (P x = P' x)" by blast
   348    let ?y = "x + (\<bar>x - z\<bar> + 1)*D"
   349    have zp: "0 <= (\<bar>x - z\<bar> + 1)" by arith
   350    from dp have yz: "?y > z" using incr_lemma[OF dp] by simp
   351    from z[rule_format, OF yz] incr_mult_lemma[OF dp th zp, rule_format, OF P] have th2: " P' ?y" by auto
   352    with periodic_finite_ex[OF dp pd]
   353    have "?R1" by blast}
   354  ultimately show ?thesis by blast
   355 qed
   356 
   357 lemma simp_from_to: "{i..j::int} = (if j < i then {} else insert i {i+1..j})"
   358 apply(simp add:atLeastAtMost_def atLeast_def atMost_def)
   359 apply(fastsimp)
   360 done
   361 
   362 theorem unity_coeff_ex: "(\<exists>(x::'a::{semiring_0,Ring_and_Field.dvd}). P (l * x)) \<equiv> (\<exists>x. l dvd (x + 0) \<and> P x)"
   363   apply (rule eq_reflection [symmetric])
   364   apply (rule iffI)
   365   defer
   366   apply (erule exE)
   367   apply (rule_tac x = "l * x" in exI)
   368   apply (simp add: dvd_def)
   369   apply (rule_tac x = x in exI, simp)
   370   apply (erule exE)
   371   apply (erule conjE)
   372   apply simp
   373   apply (erule dvdE)
   374   apply (rule_tac x = k in exI)
   375   apply simp
   376   done
   377 
   378 lemma zdvd_mono: assumes not0: "(k::int) \<noteq> 0"
   379 shows "((m::int) dvd t) \<equiv> (k*m dvd k*t)" 
   380   using not0 by (simp add: dvd_def)
   381 
   382 lemma uminus_dvd_conv: "(d dvd (t::int)) \<equiv> (-d dvd t)" "(d dvd (t::int)) \<equiv> (d dvd -t)"
   383   by simp_all
   384 text {* \bigskip Theorems for transforming predicates on nat to predicates on @{text int}*}
   385 lemma all_nat: "(\<forall>x::nat. P x) = (\<forall>x::int. 0 <= x \<longrightarrow> P (nat x))"
   386   by (simp split add: split_nat)
   387 
   388 lemma ex_nat: "(\<exists>x::nat. P x) = (\<exists>x::int. 0 <= x \<and> P (nat x))"
   389   apply (auto split add: split_nat)
   390   apply (rule_tac x="int x" in exI, simp)
   391   apply (rule_tac x = "nat x" in exI,erule_tac x = "nat x" in allE, simp)
   392   done
   393 
   394 lemma zdiff_int_split: "P (int (x - y)) =
   395   ((y \<le> x \<longrightarrow> P (int x - int y)) \<and> (x < y \<longrightarrow> P 0))"
   396   by (case_tac "y \<le> x", simp_all add: zdiff_int)
   397 
   398 lemma number_of1: "(0::int) <= number_of n \<Longrightarrow> (0::int) <= number_of (Int.Bit0 n) \<and> (0::int) <= number_of (Int.Bit1 n)"
   399 by simp
   400 lemma number_of2: "(0::int) <= Numeral0" by simp
   401 lemma Suc_plus1: "Suc n = n + 1" by simp
   402 
   403 text {*
   404   \medskip Specific instances of congruence rules, to prevent
   405   simplifier from looping. *}
   406 
   407 theorem imp_le_cong: "(0 <= x \<Longrightarrow> P = P') \<Longrightarrow> (0 <= (x::int) \<longrightarrow> P) = (0 <= x \<longrightarrow> P')" by simp
   408 
   409 theorem conj_le_cong: "(0 <= x \<Longrightarrow> P = P') \<Longrightarrow> (0 <= (x::int) \<and> P) = (0 <= x \<and> P')" 
   410   by (simp cong: conj_cong)
   411 lemma int_eq_number_of_eq:
   412   "(((number_of v)::int) = (number_of w)) = iszero ((number_of (v + (uminus w)))::int)"
   413   by (rule eq_number_of_eq)
   414 
   415 declare dvd_eq_mod_eq_0[symmetric, presburger]
   416 declare mod_1[presburger] 
   417 declare mod_0[presburger]
   418 declare mod_by_1[presburger]
   419 declare zmod_zero[presburger]
   420 declare zmod_self[presburger]
   421 declare mod_self[presburger]
   422 declare mod_by_0[presburger]
   423 declare mod_div_trivial[presburger]
   424 declare div_mod_equality2[presburger]
   425 declare div_mod_equality[presburger]
   426 declare mod_div_equality2[presburger]
   427 declare mod_div_equality[presburger]
   428 declare mod_mult_self1[presburger]
   429 declare mod_mult_self2[presburger]
   430 declare zdiv_zmod_equality2[presburger]
   431 declare zdiv_zmod_equality[presburger]
   432 declare mod2_Suc_Suc[presburger]
   433 lemma [presburger]: "(a::int) div 0 = 0" and [presburger]: "a mod 0 = a"
   434 by simp_all
   435 
   436 use "Tools/Qelim/cooper.ML"
   437 oracle linzqe_oracle = Coopereif.cooper_oracle
   438 
   439 use "Tools/Qelim/presburger.ML"
   440 
   441 declaration {* fn _ =>
   442   arith_tactic_add
   443     (mk_arith_tactic "presburger" (fn ctxt => fn i => fn st =>
   444        (warning "Trying Presburger arithmetic ...";   
   445     Presburger.cooper_tac true [] [] ctxt i st)))
   446 *}
   447 
   448 method_setup presburger = {*
   449 let
   450  fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   451  fun simple_keyword k = Scan.lift (Args.$$$ k) >> K ()
   452  val addN = "add"
   453  val delN = "del"
   454  val elimN = "elim"
   455  val any_keyword = keyword addN || keyword delN || simple_keyword elimN
   456  val thms = Scan.repeat (Scan.unless any_keyword Attrib.multi_thm) >> flat;
   457 in
   458   fn src => Method.syntax 
   459    ((Scan.optional (simple_keyword elimN >> K false) true) -- 
   460     (Scan.optional (keyword addN |-- thms) []) -- 
   461     (Scan.optional (keyword delN |-- thms) [])) src 
   462   #> (fn (((elim, add_ths), del_ths),ctxt) => 
   463          Method.SIMPLE_METHOD' (Presburger.cooper_tac elim add_ths del_ths ctxt))
   464 end
   465 *} "Cooper's algorithm for Presburger arithmetic"
   466 
   467 lemma [presburger, algebra]: "m mod 2 = (1::nat) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   468 lemma [presburger, algebra]: "m mod 2 = Suc 0 \<longleftrightarrow> \<not> 2 dvd m " by presburger
   469 lemma [presburger, algebra]: "m mod (Suc (Suc 0)) = (1::nat) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   470 lemma [presburger, algebra]: "m mod (Suc (Suc 0)) = Suc 0 \<longleftrightarrow> \<not> 2 dvd m " by presburger
   471 lemma [presburger, algebra]: "m mod 2 = (1::int) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   472 
   473 
   474 lemma zdvd_period:
   475   fixes a d :: int
   476   assumes advdd: "a dvd d"
   477   shows "a dvd (x + t) \<longleftrightarrow> a dvd ((x + c * d) + t)"
   478   using advdd
   479   apply -
   480   apply (rule iffI)
   481   by algebra+
   482 
   483 end