src/HOL/RealVector.thy
author nipkow
Fri Mar 06 17:38:47 2009 +0100 (2009-03-06)
changeset 30313 b2441b0c8d38
parent 30273 ecd6f0ca62ea
child 30729 461ee3e49ad3
permissions -rw-r--r--
added lemmas
     1 (*  Title:      HOL/RealVector.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Vector Spaces and Algebras over the Reals *}
     6 
     7 theory RealVector
     8 imports RealPow
     9 begin
    10 
    11 subsection {* Locale for additive functions *}
    12 
    13 locale additive =
    14   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    15   assumes add: "f (x + y) = f x + f y"
    16 begin
    17 
    18 lemma zero: "f 0 = 0"
    19 proof -
    20   have "f 0 = f (0 + 0)" by simp
    21   also have "\<dots> = f 0 + f 0" by (rule add)
    22   finally show "f 0 = 0" by simp
    23 qed
    24 
    25 lemma minus: "f (- x) = - f x"
    26 proof -
    27   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    28   also have "\<dots> = - f x + f x" by (simp add: zero)
    29   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    30 qed
    31 
    32 lemma diff: "f (x - y) = f x - f y"
    33 by (simp add: diff_def add minus)
    34 
    35 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    36 apply (cases "finite A")
    37 apply (induct set: finite)
    38 apply (simp add: zero)
    39 apply (simp add: add)
    40 apply (simp add: zero)
    41 done
    42 
    43 end
    44 
    45 subsection {* Vector spaces *}
    46 
    47 locale vector_space =
    48   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    49   assumes scale_right_distrib [algebra_simps]:
    50     "scale a (x + y) = scale a x + scale a y"
    51   and scale_left_distrib [algebra_simps]:
    52     "scale (a + b) x = scale a x + scale b x"
    53   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    54   and scale_one [simp]: "scale 1 x = x"
    55 begin
    56 
    57 lemma scale_left_commute:
    58   "scale a (scale b x) = scale b (scale a x)"
    59 by (simp add: mult_commute)
    60 
    61 lemma scale_zero_left [simp]: "scale 0 x = 0"
    62   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    63   and scale_left_diff_distrib [algebra_simps]:
    64         "scale (a - b) x = scale a x - scale b x"
    65 proof -
    66   interpret s: additive "\<lambda>a. scale a x"
    67     proof qed (rule scale_left_distrib)
    68   show "scale 0 x = 0" by (rule s.zero)
    69   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    70   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    71 qed
    72 
    73 lemma scale_zero_right [simp]: "scale a 0 = 0"
    74   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    75   and scale_right_diff_distrib [algebra_simps]:
    76         "scale a (x - y) = scale a x - scale a y"
    77 proof -
    78   interpret s: additive "\<lambda>x. scale a x"
    79     proof qed (rule scale_right_distrib)
    80   show "scale a 0 = 0" by (rule s.zero)
    81   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    82   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    83 qed
    84 
    85 lemma scale_eq_0_iff [simp]:
    86   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    87 proof cases
    88   assume "a = 0" thus ?thesis by simp
    89 next
    90   assume anz [simp]: "a \<noteq> 0"
    91   { assume "scale a x = 0"
    92     hence "scale (inverse a) (scale a x) = 0" by simp
    93     hence "x = 0" by simp }
    94   thus ?thesis by force
    95 qed
    96 
    97 lemma scale_left_imp_eq:
    98   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
    99 proof -
   100   assume nonzero: "a \<noteq> 0"
   101   assume "scale a x = scale a y"
   102   hence "scale a (x - y) = 0"
   103      by (simp add: scale_right_diff_distrib)
   104   hence "x - y = 0" by (simp add: nonzero)
   105   thus "x = y" by (simp only: right_minus_eq)
   106 qed
   107 
   108 lemma scale_right_imp_eq:
   109   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   110 proof -
   111   assume nonzero: "x \<noteq> 0"
   112   assume "scale a x = scale b x"
   113   hence "scale (a - b) x = 0"
   114      by (simp add: scale_left_diff_distrib)
   115   hence "a - b = 0" by (simp add: nonzero)
   116   thus "a = b" by (simp only: right_minus_eq)
   117 qed
   118 
   119 lemma scale_cancel_left:
   120   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   121 by (auto intro: scale_left_imp_eq)
   122 
   123 lemma scale_cancel_right:
   124   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   125 by (auto intro: scale_right_imp_eq)
   126 
   127 end
   128 
   129 subsection {* Real vector spaces *}
   130 
   131 class scaleR =
   132   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   133 begin
   134 
   135 abbreviation
   136   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   137 where
   138   "x /\<^sub>R r == scaleR (inverse r) x"
   139 
   140 end
   141 
   142 class real_vector = scaleR + ab_group_add +
   143   assumes scaleR_right_distrib: "scaleR a (x + y) = scaleR a x + scaleR a y"
   144   and scaleR_left_distrib: "scaleR (a + b) x = scaleR a x + scaleR b x"
   145   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   146   and scaleR_one: "scaleR 1 x = x"
   147 
   148 interpretation real_vector!:
   149   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   150 apply unfold_locales
   151 apply (rule scaleR_right_distrib)
   152 apply (rule scaleR_left_distrib)
   153 apply (rule scaleR_scaleR)
   154 apply (rule scaleR_one)
   155 done
   156 
   157 text {* Recover original theorem names *}
   158 
   159 lemmas scaleR_left_commute = real_vector.scale_left_commute
   160 lemmas scaleR_zero_left = real_vector.scale_zero_left
   161 lemmas scaleR_minus_left = real_vector.scale_minus_left
   162 lemmas scaleR_left_diff_distrib = real_vector.scale_left_diff_distrib
   163 lemmas scaleR_zero_right = real_vector.scale_zero_right
   164 lemmas scaleR_minus_right = real_vector.scale_minus_right
   165 lemmas scaleR_right_diff_distrib = real_vector.scale_right_diff_distrib
   166 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   167 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   168 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   169 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   170 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   171 
   172 class real_algebra = real_vector + ring +
   173   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   174   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   175 
   176 class real_algebra_1 = real_algebra + ring_1
   177 
   178 class real_div_algebra = real_algebra_1 + division_ring
   179 
   180 class real_field = real_div_algebra + field
   181 
   182 instantiation real :: real_field
   183 begin
   184 
   185 definition
   186   real_scaleR_def [simp]: "scaleR a x = a * x"
   187 
   188 instance proof
   189 qed (simp_all add: algebra_simps)
   190 
   191 end
   192 
   193 interpretation scaleR_left!: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   194 proof qed (rule scaleR_left_distrib)
   195 
   196 interpretation scaleR_right!: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   197 proof qed (rule scaleR_right_distrib)
   198 
   199 lemma nonzero_inverse_scaleR_distrib:
   200   fixes x :: "'a::real_div_algebra" shows
   201   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   202 by (rule inverse_unique, simp)
   203 
   204 lemma inverse_scaleR_distrib:
   205   fixes x :: "'a::{real_div_algebra,division_by_zero}"
   206   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   207 apply (case_tac "a = 0", simp)
   208 apply (case_tac "x = 0", simp)
   209 apply (erule (1) nonzero_inverse_scaleR_distrib)
   210 done
   211 
   212 
   213 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   214 @{term of_real} *}
   215 
   216 definition
   217   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   218   "of_real r = scaleR r 1"
   219 
   220 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   221 by (simp add: of_real_def)
   222 
   223 lemma of_real_0 [simp]: "of_real 0 = 0"
   224 by (simp add: of_real_def)
   225 
   226 lemma of_real_1 [simp]: "of_real 1 = 1"
   227 by (simp add: of_real_def)
   228 
   229 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   230 by (simp add: of_real_def scaleR_left_distrib)
   231 
   232 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   233 by (simp add: of_real_def)
   234 
   235 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   236 by (simp add: of_real_def scaleR_left_diff_distrib)
   237 
   238 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   239 by (simp add: of_real_def mult_commute)
   240 
   241 lemma nonzero_of_real_inverse:
   242   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   243    inverse (of_real x :: 'a::real_div_algebra)"
   244 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   245 
   246 lemma of_real_inverse [simp]:
   247   "of_real (inverse x) =
   248    inverse (of_real x :: 'a::{real_div_algebra,division_by_zero})"
   249 by (simp add: of_real_def inverse_scaleR_distrib)
   250 
   251 lemma nonzero_of_real_divide:
   252   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   253    (of_real x / of_real y :: 'a::real_field)"
   254 by (simp add: divide_inverse nonzero_of_real_inverse)
   255 
   256 lemma of_real_divide [simp]:
   257   "of_real (x / y) =
   258    (of_real x / of_real y :: 'a::{real_field,division_by_zero})"
   259 by (simp add: divide_inverse)
   260 
   261 lemma of_real_power [simp]:
   262   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1,recpower}) ^ n"
   263 by (induct n) simp_all
   264 
   265 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   266 by (simp add: of_real_def scaleR_cancel_right)
   267 
   268 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   269 
   270 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   271 proof
   272   fix r
   273   show "of_real r = id r"
   274     by (simp add: of_real_def)
   275 qed
   276 
   277 text{*Collapse nested embeddings*}
   278 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   279 by (induct n) auto
   280 
   281 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   282 by (cases z rule: int_diff_cases, simp)
   283 
   284 lemma of_real_number_of_eq:
   285   "of_real (number_of w) = (number_of w :: 'a::{number_ring,real_algebra_1})"
   286 by (simp add: number_of_eq)
   287 
   288 text{*Every real algebra has characteristic zero*}
   289 instance real_algebra_1 < ring_char_0
   290 proof
   291   fix m n :: nat
   292   have "(of_real (of_nat m) = (of_real (of_nat n)::'a)) = (m = n)"
   293     by (simp only: of_real_eq_iff of_nat_eq_iff)
   294   thus "(of_nat m = (of_nat n::'a)) = (m = n)"
   295     by (simp only: of_real_of_nat_eq)
   296 qed
   297 
   298 instance real_field < field_char_0 ..
   299 
   300 
   301 subsection {* The Set of Real Numbers *}
   302 
   303 definition
   304   Reals :: "'a::real_algebra_1 set" where
   305   [code del]: "Reals = range of_real"
   306 
   307 notation (xsymbols)
   308   Reals  ("\<real>")
   309 
   310 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   311 by (simp add: Reals_def)
   312 
   313 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   314 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   315 
   316 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   317 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   318 
   319 lemma Reals_number_of [simp]:
   320   "(number_of w::'a::{number_ring,real_algebra_1}) \<in> Reals"
   321 by (subst of_real_number_of_eq [symmetric], rule Reals_of_real)
   322 
   323 lemma Reals_0 [simp]: "0 \<in> Reals"
   324 apply (unfold Reals_def)
   325 apply (rule range_eqI)
   326 apply (rule of_real_0 [symmetric])
   327 done
   328 
   329 lemma Reals_1 [simp]: "1 \<in> Reals"
   330 apply (unfold Reals_def)
   331 apply (rule range_eqI)
   332 apply (rule of_real_1 [symmetric])
   333 done
   334 
   335 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   336 apply (auto simp add: Reals_def)
   337 apply (rule range_eqI)
   338 apply (rule of_real_add [symmetric])
   339 done
   340 
   341 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   342 apply (auto simp add: Reals_def)
   343 apply (rule range_eqI)
   344 apply (rule of_real_minus [symmetric])
   345 done
   346 
   347 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   348 apply (auto simp add: Reals_def)
   349 apply (rule range_eqI)
   350 apply (rule of_real_diff [symmetric])
   351 done
   352 
   353 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   354 apply (auto simp add: Reals_def)
   355 apply (rule range_eqI)
   356 apply (rule of_real_mult [symmetric])
   357 done
   358 
   359 lemma nonzero_Reals_inverse:
   360   fixes a :: "'a::real_div_algebra"
   361   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   362 apply (auto simp add: Reals_def)
   363 apply (rule range_eqI)
   364 apply (erule nonzero_of_real_inverse [symmetric])
   365 done
   366 
   367 lemma Reals_inverse [simp]:
   368   fixes a :: "'a::{real_div_algebra,division_by_zero}"
   369   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   370 apply (auto simp add: Reals_def)
   371 apply (rule range_eqI)
   372 apply (rule of_real_inverse [symmetric])
   373 done
   374 
   375 lemma nonzero_Reals_divide:
   376   fixes a b :: "'a::real_field"
   377   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   378 apply (auto simp add: Reals_def)
   379 apply (rule range_eqI)
   380 apply (erule nonzero_of_real_divide [symmetric])
   381 done
   382 
   383 lemma Reals_divide [simp]:
   384   fixes a b :: "'a::{real_field,division_by_zero}"
   385   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   386 apply (auto simp add: Reals_def)
   387 apply (rule range_eqI)
   388 apply (rule of_real_divide [symmetric])
   389 done
   390 
   391 lemma Reals_power [simp]:
   392   fixes a :: "'a::{real_algebra_1,recpower}"
   393   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   394 apply (auto simp add: Reals_def)
   395 apply (rule range_eqI)
   396 apply (rule of_real_power [symmetric])
   397 done
   398 
   399 lemma Reals_cases [cases set: Reals]:
   400   assumes "q \<in> \<real>"
   401   obtains (of_real) r where "q = of_real r"
   402   unfolding Reals_def
   403 proof -
   404   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   405   then obtain r where "q = of_real r" ..
   406   then show thesis ..
   407 qed
   408 
   409 lemma Reals_induct [case_names of_real, induct set: Reals]:
   410   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   411   by (rule Reals_cases) auto
   412 
   413 
   414 subsection {* Real normed vector spaces *}
   415 
   416 class norm =
   417   fixes norm :: "'a \<Rightarrow> real"
   418 
   419 class sgn_div_norm = scaleR + norm + sgn +
   420   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   421 
   422 class real_normed_vector = real_vector + sgn_div_norm +
   423   assumes norm_ge_zero [simp]: "0 \<le> norm x"
   424   and norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   425   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   426   and norm_scaleR: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   427 
   428 class real_normed_algebra = real_algebra + real_normed_vector +
   429   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   430 
   431 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   432   assumes norm_one [simp]: "norm 1 = 1"
   433 
   434 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   435   assumes norm_mult: "norm (x * y) = norm x * norm y"
   436 
   437 class real_normed_field = real_field + real_normed_div_algebra
   438 
   439 instance real_normed_div_algebra < real_normed_algebra_1
   440 proof
   441   fix x y :: 'a
   442   show "norm (x * y) \<le> norm x * norm y"
   443     by (simp add: norm_mult)
   444 next
   445   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   446     by (rule norm_mult)
   447   thus "norm (1::'a) = 1" by simp
   448 qed
   449 
   450 instantiation real :: real_normed_field
   451 begin
   452 
   453 definition
   454   real_norm_def [simp]: "norm r = \<bar>r\<bar>"
   455 
   456 instance
   457 apply (intro_classes, unfold real_norm_def real_scaleR_def)
   458 apply (simp add: real_sgn_def)
   459 apply (rule abs_ge_zero)
   460 apply (rule abs_eq_0)
   461 apply (rule abs_triangle_ineq)
   462 apply (rule abs_mult)
   463 apply (rule abs_mult)
   464 done
   465 
   466 end
   467 
   468 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   469 by simp
   470 
   471 lemma zero_less_norm_iff [simp]:
   472   fixes x :: "'a::real_normed_vector"
   473   shows "(0 < norm x) = (x \<noteq> 0)"
   474 by (simp add: order_less_le)
   475 
   476 lemma norm_not_less_zero [simp]:
   477   fixes x :: "'a::real_normed_vector"
   478   shows "\<not> norm x < 0"
   479 by (simp add: linorder_not_less)
   480 
   481 lemma norm_le_zero_iff [simp]:
   482   fixes x :: "'a::real_normed_vector"
   483   shows "(norm x \<le> 0) = (x = 0)"
   484 by (simp add: order_le_less)
   485 
   486 lemma norm_minus_cancel [simp]:
   487   fixes x :: "'a::real_normed_vector"
   488   shows "norm (- x) = norm x"
   489 proof -
   490   have "norm (- x) = norm (scaleR (- 1) x)"
   491     by (simp only: scaleR_minus_left scaleR_one)
   492   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   493     by (rule norm_scaleR)
   494   finally show ?thesis by simp
   495 qed
   496 
   497 lemma norm_minus_commute:
   498   fixes a b :: "'a::real_normed_vector"
   499   shows "norm (a - b) = norm (b - a)"
   500 proof -
   501   have "norm (- (b - a)) = norm (b - a)"
   502     by (rule norm_minus_cancel)
   503   thus ?thesis by simp
   504 qed
   505 
   506 lemma norm_triangle_ineq2:
   507   fixes a b :: "'a::real_normed_vector"
   508   shows "norm a - norm b \<le> norm (a - b)"
   509 proof -
   510   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   511     by (rule norm_triangle_ineq)
   512   thus ?thesis by simp
   513 qed
   514 
   515 lemma norm_triangle_ineq3:
   516   fixes a b :: "'a::real_normed_vector"
   517   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   518 apply (subst abs_le_iff)
   519 apply auto
   520 apply (rule norm_triangle_ineq2)
   521 apply (subst norm_minus_commute)
   522 apply (rule norm_triangle_ineq2)
   523 done
   524 
   525 lemma norm_triangle_ineq4:
   526   fixes a b :: "'a::real_normed_vector"
   527   shows "norm (a - b) \<le> norm a + norm b"
   528 proof -
   529   have "norm (a + - b) \<le> norm a + norm (- b)"
   530     by (rule norm_triangle_ineq)
   531   thus ?thesis
   532     by (simp only: diff_minus norm_minus_cancel)
   533 qed
   534 
   535 lemma norm_diff_ineq:
   536   fixes a b :: "'a::real_normed_vector"
   537   shows "norm a - norm b \<le> norm (a + b)"
   538 proof -
   539   have "norm a - norm (- b) \<le> norm (a - - b)"
   540     by (rule norm_triangle_ineq2)
   541   thus ?thesis by simp
   542 qed
   543 
   544 lemma norm_diff_triangle_ineq:
   545   fixes a b c d :: "'a::real_normed_vector"
   546   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   547 proof -
   548   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   549     by (simp add: diff_minus add_ac)
   550   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   551     by (rule norm_triangle_ineq)
   552   finally show ?thesis .
   553 qed
   554 
   555 lemma abs_norm_cancel [simp]:
   556   fixes a :: "'a::real_normed_vector"
   557   shows "\<bar>norm a\<bar> = norm a"
   558 by (rule abs_of_nonneg [OF norm_ge_zero])
   559 
   560 lemma norm_add_less:
   561   fixes x y :: "'a::real_normed_vector"
   562   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   563 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   564 
   565 lemma norm_mult_less:
   566   fixes x y :: "'a::real_normed_algebra"
   567   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   568 apply (rule order_le_less_trans [OF norm_mult_ineq])
   569 apply (simp add: mult_strict_mono')
   570 done
   571 
   572 lemma norm_of_real [simp]:
   573   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   574 unfolding of_real_def by (simp add: norm_scaleR)
   575 
   576 lemma norm_number_of [simp]:
   577   "norm (number_of w::'a::{number_ring,real_normed_algebra_1})
   578     = \<bar>number_of w\<bar>"
   579 by (subst of_real_number_of_eq [symmetric], rule norm_of_real)
   580 
   581 lemma norm_of_int [simp]:
   582   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   583 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   584 
   585 lemma norm_of_nat [simp]:
   586   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   587 apply (subst of_real_of_nat_eq [symmetric])
   588 apply (subst norm_of_real, simp)
   589 done
   590 
   591 lemma nonzero_norm_inverse:
   592   fixes a :: "'a::real_normed_div_algebra"
   593   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   594 apply (rule inverse_unique [symmetric])
   595 apply (simp add: norm_mult [symmetric])
   596 done
   597 
   598 lemma norm_inverse:
   599   fixes a :: "'a::{real_normed_div_algebra,division_by_zero}"
   600   shows "norm (inverse a) = inverse (norm a)"
   601 apply (case_tac "a = 0", simp)
   602 apply (erule nonzero_norm_inverse)
   603 done
   604 
   605 lemma nonzero_norm_divide:
   606   fixes a b :: "'a::real_normed_field"
   607   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   608 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   609 
   610 lemma norm_divide:
   611   fixes a b :: "'a::{real_normed_field,division_by_zero}"
   612   shows "norm (a / b) = norm a / norm b"
   613 by (simp add: divide_inverse norm_mult norm_inverse)
   614 
   615 lemma norm_power_ineq:
   616   fixes x :: "'a::{real_normed_algebra_1,recpower}"
   617   shows "norm (x ^ n) \<le> norm x ^ n"
   618 proof (induct n)
   619   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   620 next
   621   case (Suc n)
   622   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   623     by (rule norm_mult_ineq)
   624   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   625     using norm_ge_zero by (rule mult_left_mono)
   626   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   627     by simp
   628 qed
   629 
   630 lemma norm_power:
   631   fixes x :: "'a::{real_normed_div_algebra,recpower}"
   632   shows "norm (x ^ n) = norm x ^ n"
   633 by (induct n) (simp_all add: norm_mult)
   634 
   635 
   636 subsection {* Sign function *}
   637 
   638 lemma norm_sgn:
   639   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
   640 by (simp add: sgn_div_norm norm_scaleR)
   641 
   642 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
   643 by (simp add: sgn_div_norm)
   644 
   645 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
   646 by (simp add: sgn_div_norm)
   647 
   648 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
   649 by (simp add: sgn_div_norm)
   650 
   651 lemma sgn_scaleR:
   652   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
   653 by (simp add: sgn_div_norm norm_scaleR mult_ac)
   654 
   655 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
   656 by (simp add: sgn_div_norm)
   657 
   658 lemma sgn_of_real:
   659   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
   660 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
   661 
   662 lemma sgn_mult:
   663   fixes x y :: "'a::real_normed_div_algebra"
   664   shows "sgn (x * y) = sgn x * sgn y"
   665 by (simp add: sgn_div_norm norm_mult mult_commute)
   666 
   667 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
   668 by (simp add: sgn_div_norm divide_inverse)
   669 
   670 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
   671 unfolding real_sgn_eq by simp
   672 
   673 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
   674 unfolding real_sgn_eq by simp
   675 
   676 
   677 subsection {* Bounded Linear and Bilinear Operators *}
   678 
   679 locale bounded_linear = additive +
   680   constrains f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
   681   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
   682   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
   683 begin
   684 
   685 lemma pos_bounded:
   686   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
   687 proof -
   688   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
   689     using bounded by fast
   690   show ?thesis
   691   proof (intro exI impI conjI allI)
   692     show "0 < max 1 K"
   693       by (rule order_less_le_trans [OF zero_less_one le_maxI1])
   694   next
   695     fix x
   696     have "norm (f x) \<le> norm x * K" using K .
   697     also have "\<dots> \<le> norm x * max 1 K"
   698       by (rule mult_left_mono [OF le_maxI2 norm_ge_zero])
   699     finally show "norm (f x) \<le> norm x * max 1 K" .
   700   qed
   701 qed
   702 
   703 lemma nonneg_bounded:
   704   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
   705 proof -
   706   from pos_bounded
   707   show ?thesis by (auto intro: order_less_imp_le)
   708 qed
   709 
   710 end
   711 
   712 locale bounded_bilinear =
   713   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
   714                  \<Rightarrow> 'c::real_normed_vector"
   715     (infixl "**" 70)
   716   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
   717   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
   718   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
   719   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
   720   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
   721 begin
   722 
   723 lemma pos_bounded:
   724   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
   725 apply (cut_tac bounded, erule exE)
   726 apply (rule_tac x="max 1 K" in exI, safe)
   727 apply (rule order_less_le_trans [OF zero_less_one le_maxI1])
   728 apply (drule spec, drule spec, erule order_trans)
   729 apply (rule mult_left_mono [OF le_maxI2])
   730 apply (intro mult_nonneg_nonneg norm_ge_zero)
   731 done
   732 
   733 lemma nonneg_bounded:
   734   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
   735 proof -
   736   from pos_bounded
   737   show ?thesis by (auto intro: order_less_imp_le)
   738 qed
   739 
   740 lemma additive_right: "additive (\<lambda>b. prod a b)"
   741 by (rule additive.intro, rule add_right)
   742 
   743 lemma additive_left: "additive (\<lambda>a. prod a b)"
   744 by (rule additive.intro, rule add_left)
   745 
   746 lemma zero_left: "prod 0 b = 0"
   747 by (rule additive.zero [OF additive_left])
   748 
   749 lemma zero_right: "prod a 0 = 0"
   750 by (rule additive.zero [OF additive_right])
   751 
   752 lemma minus_left: "prod (- a) b = - prod a b"
   753 by (rule additive.minus [OF additive_left])
   754 
   755 lemma minus_right: "prod a (- b) = - prod a b"
   756 by (rule additive.minus [OF additive_right])
   757 
   758 lemma diff_left:
   759   "prod (a - a') b = prod a b - prod a' b"
   760 by (rule additive.diff [OF additive_left])
   761 
   762 lemma diff_right:
   763   "prod a (b - b') = prod a b - prod a b'"
   764 by (rule additive.diff [OF additive_right])
   765 
   766 lemma bounded_linear_left:
   767   "bounded_linear (\<lambda>a. a ** b)"
   768 apply (unfold_locales)
   769 apply (rule add_left)
   770 apply (rule scaleR_left)
   771 apply (cut_tac bounded, safe)
   772 apply (rule_tac x="norm b * K" in exI)
   773 apply (simp add: mult_ac)
   774 done
   775 
   776 lemma bounded_linear_right:
   777   "bounded_linear (\<lambda>b. a ** b)"
   778 apply (unfold_locales)
   779 apply (rule add_right)
   780 apply (rule scaleR_right)
   781 apply (cut_tac bounded, safe)
   782 apply (rule_tac x="norm a * K" in exI)
   783 apply (simp add: mult_ac)
   784 done
   785 
   786 lemma prod_diff_prod:
   787   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
   788 by (simp add: diff_left diff_right)
   789 
   790 end
   791 
   792 interpretation mult!:
   793   bounded_bilinear "op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra"
   794 apply (rule bounded_bilinear.intro)
   795 apply (rule left_distrib)
   796 apply (rule right_distrib)
   797 apply (rule mult_scaleR_left)
   798 apply (rule mult_scaleR_right)
   799 apply (rule_tac x="1" in exI)
   800 apply (simp add: norm_mult_ineq)
   801 done
   802 
   803 interpretation mult_left!:
   804   bounded_linear "(\<lambda>x::'a::real_normed_algebra. x * y)"
   805 by (rule mult.bounded_linear_left)
   806 
   807 interpretation mult_right!:
   808   bounded_linear "(\<lambda>y::'a::real_normed_algebra. x * y)"
   809 by (rule mult.bounded_linear_right)
   810 
   811 interpretation divide!:
   812   bounded_linear "(\<lambda>x::'a::real_normed_field. x / y)"
   813 unfolding divide_inverse by (rule mult.bounded_linear_left)
   814 
   815 interpretation scaleR!: bounded_bilinear "scaleR"
   816 apply (rule bounded_bilinear.intro)
   817 apply (rule scaleR_left_distrib)
   818 apply (rule scaleR_right_distrib)
   819 apply simp
   820 apply (rule scaleR_left_commute)
   821 apply (rule_tac x="1" in exI)
   822 apply (simp add: norm_scaleR)
   823 done
   824 
   825 interpretation scaleR_left!: bounded_linear "\<lambda>r. scaleR r x"
   826 by (rule scaleR.bounded_linear_left)
   827 
   828 interpretation scaleR_right!: bounded_linear "\<lambda>x. scaleR r x"
   829 by (rule scaleR.bounded_linear_right)
   830 
   831 interpretation of_real!: bounded_linear "\<lambda>r. of_real r"
   832 unfolding of_real_def by (rule scaleR.bounded_linear_left)
   833 
   834 end