src/HOL/Probability/Sigma_Algebra.thy
author wenzelm
Fri Oct 12 18:58:20 2012 +0200 (2012-10-12)
changeset 49834 b27bbb021df1
parent 49789 e0a4cb91a8a9
child 50002 ce0d316b5b44
permissions -rw-r--r--
discontinued obsolete typedef (open) syntax;
     1 (*  Title:      HOL/Probability/Sigma_Algebra.thy
     2     Author:     Stefan Richter, Markus Wenzel, TU München
     3     Author:     Johannes Hölzl, TU München
     4     Plus material from the Hurd/Coble measure theory development,
     5     translated by Lawrence Paulson.
     6 *)
     7 
     8 header {* Sigma Algebras *}
     9 
    10 theory Sigma_Algebra
    11 imports
    12   Complex_Main
    13   "~~/src/HOL/Library/Countable"
    14   "~~/src/HOL/Library/FuncSet"
    15   "~~/src/HOL/Library/Indicator_Function"
    16   "~~/src/HOL/Library/Extended_Real"
    17 begin
    18 
    19 text {* Sigma algebras are an elementary concept in measure
    20   theory. To measure --- that is to integrate --- functions, we first have
    21   to measure sets. Unfortunately, when dealing with a large universe,
    22   it is often not possible to consistently assign a measure to every
    23   subset. Therefore it is necessary to define the set of measurable
    24   subsets of the universe. A sigma algebra is such a set that has
    25   three very natural and desirable properties. *}
    26 
    27 subsection {* Families of sets *}
    28 
    29 locale subset_class =
    30   fixes \<Omega> :: "'a set" and M :: "'a set set"
    31   assumes space_closed: "M \<subseteq> Pow \<Omega>"
    32 
    33 lemma (in subset_class) sets_into_space: "x \<in> M \<Longrightarrow> x \<subseteq> \<Omega>"
    34   by (metis PowD contra_subsetD space_closed)
    35 
    36 subsection {* Semiring of sets *}
    37 
    38 subsubsection {* Disjoint sets *}
    39 
    40 definition "disjoint A \<longleftrightarrow> (\<forall>a\<in>A. \<forall>b\<in>A. a \<noteq> b \<longrightarrow> a \<inter> b = {})"
    41 
    42 lemma disjointI:
    43   "(\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<inter> b = {}) \<Longrightarrow> disjoint A"
    44   unfolding disjoint_def by auto
    45 
    46 lemma disjointD:
    47   "disjoint A \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<noteq> b \<Longrightarrow> a \<inter> b = {}"
    48   unfolding disjoint_def by auto
    49 
    50 lemma disjoint_empty[iff]: "disjoint {}"
    51   by (auto simp: disjoint_def)
    52 
    53 lemma disjoint_union: 
    54   assumes C: "disjoint C" and B: "disjoint B" and disj: "\<Union>C \<inter> \<Union>B = {}"
    55   shows "disjoint (C \<union> B)"
    56 proof (rule disjointI)
    57   fix c d assume sets: "c \<in> C \<union> B" "d \<in> C \<union> B" and "c \<noteq> d"
    58   show "c \<inter> d = {}"
    59   proof cases
    60     assume "(c \<in> C \<and> d \<in> C) \<or> (c \<in> B \<and> d \<in> B)"
    61     then show ?thesis
    62     proof 
    63       assume "c \<in> C \<and> d \<in> C" with `c \<noteq> d` C show "c \<inter> d = {}"
    64         by (auto simp: disjoint_def)
    65     next
    66       assume "c \<in> B \<and> d \<in> B" with `c \<noteq> d` B show "c \<inter> d = {}"
    67         by (auto simp: disjoint_def)
    68     qed
    69   next
    70     assume "\<not> ((c \<in> C \<and> d \<in> C) \<or> (c \<in> B \<and> d \<in> B))"
    71     with sets have "(c \<subseteq> \<Union>C \<and> d \<subseteq> \<Union>B) \<or> (c \<subseteq> \<Union>B \<and> d \<subseteq> \<Union>C)"
    72       by auto
    73     with disj show "c \<inter> d = {}" by auto
    74   qed
    75 qed
    76 
    77 locale semiring_of_sets = subset_class +
    78   assumes empty_sets[iff]: "{} \<in> M"
    79   assumes Int[intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<inter> b \<in> M"
    80   assumes Diff_cover:
    81     "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> \<exists>C\<subseteq>M. finite C \<and> disjoint C \<and> a - b = \<Union>C"
    82 
    83 lemma (in semiring_of_sets) finite_INT[intro]:
    84   assumes "finite I" "I \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> A i \<in> M"
    85   shows "(\<Inter>i\<in>I. A i) \<in> M"
    86   using assms by (induct rule: finite_ne_induct) auto
    87 
    88 lemma (in semiring_of_sets) Int_space_eq1 [simp]: "x \<in> M \<Longrightarrow> \<Omega> \<inter> x = x"
    89   by (metis Int_absorb1 sets_into_space)
    90 
    91 lemma (in semiring_of_sets) Int_space_eq2 [simp]: "x \<in> M \<Longrightarrow> x \<inter> \<Omega> = x"
    92   by (metis Int_absorb2 sets_into_space)
    93 
    94 lemma (in semiring_of_sets) sets_Collect_conj:
    95   assumes "{x\<in>\<Omega>. P x} \<in> M" "{x\<in>\<Omega>. Q x} \<in> M"
    96   shows "{x\<in>\<Omega>. Q x \<and> P x} \<in> M"
    97 proof -
    98   have "{x\<in>\<Omega>. Q x \<and> P x} = {x\<in>\<Omega>. Q x} \<inter> {x\<in>\<Omega>. P x}"
    99     by auto
   100   with assms show ?thesis by auto
   101 qed
   102 
   103 lemma (in semiring_of_sets) sets_Collect_finite_All:
   104   assumes "\<And>i. i \<in> S \<Longrightarrow> {x\<in>\<Omega>. P i x} \<in> M" "finite S" "S \<noteq> {}"
   105   shows "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} \<in> M"
   106 proof -
   107   have "{x\<in>\<Omega>. \<forall>i\<in>S. P i x} = (\<Inter>i\<in>S. {x\<in>\<Omega>. P i x})"
   108     using `S \<noteq> {}` by auto
   109   with assms show ?thesis by auto
   110 qed
   111 
   112 locale ring_of_sets = semiring_of_sets +
   113   assumes Un [intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<union> b \<in> M"
   114 
   115 lemma (in ring_of_sets) finite_Union [intro]:
   116   "finite X \<Longrightarrow> X \<subseteq> M \<Longrightarrow> Union X \<in> M"
   117   by (induct set: finite) (auto simp add: Un)
   118 
   119 lemma (in ring_of_sets) finite_UN[intro]:
   120   assumes "finite I" and "\<And>i. i \<in> I \<Longrightarrow> A i \<in> M"
   121   shows "(\<Union>i\<in>I. A i) \<in> M"
   122   using assms by induct auto
   123 
   124 lemma (in ring_of_sets) Diff [intro]:
   125   assumes "a \<in> M" "b \<in> M" shows "a - b \<in> M"
   126   using Diff_cover[OF assms] by auto
   127 
   128 lemma ring_of_setsI:
   129   assumes space_closed: "M \<subseteq> Pow \<Omega>"
   130   assumes empty_sets[iff]: "{} \<in> M"
   131   assumes Un[intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<union> b \<in> M"
   132   assumes Diff[intro]: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a - b \<in> M"
   133   shows "ring_of_sets \<Omega> M"
   134 proof
   135   fix a b assume ab: "a \<in> M" "b \<in> M"
   136   from ab show "\<exists>C\<subseteq>M. finite C \<and> disjoint C \<and> a - b = \<Union>C"
   137     by (intro exI[of _ "{a - b}"]) (auto simp: disjoint_def)
   138   have "a \<inter> b = a - (a - b)" by auto
   139   also have "\<dots> \<in> M" using ab by auto
   140   finally show "a \<inter> b \<in> M" .
   141 qed fact+
   142 
   143 lemma ring_of_sets_iff: "ring_of_sets \<Omega> M \<longleftrightarrow> M \<subseteq> Pow \<Omega> \<and> {} \<in> M \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a \<union> b \<in> M) \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a - b \<in> M)"
   144 proof
   145   assume "ring_of_sets \<Omega> M"
   146   then interpret ring_of_sets \<Omega> M .
   147   show "M \<subseteq> Pow \<Omega> \<and> {} \<in> M \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a \<union> b \<in> M) \<and> (\<forall>a\<in>M. \<forall>b\<in>M. a - b \<in> M)"
   148     using space_closed by auto
   149 qed (auto intro!: ring_of_setsI)
   150 
   151 lemma (in ring_of_sets) insert_in_sets:
   152   assumes "{x} \<in> M" "A \<in> M" shows "insert x A \<in> M"
   153 proof -
   154   have "{x} \<union> A \<in> M" using assms by (rule Un)
   155   thus ?thesis by auto
   156 qed
   157 
   158 lemma (in ring_of_sets) sets_Collect_disj:
   159   assumes "{x\<in>\<Omega>. P x} \<in> M" "{x\<in>\<Omega>. Q x} \<in> M"
   160   shows "{x\<in>\<Omega>. Q x \<or> P x} \<in> M"
   161 proof -
   162   have "{x\<in>\<Omega>. Q x \<or> P x} = {x\<in>\<Omega>. Q x} \<union> {x\<in>\<Omega>. P x}"
   163     by auto
   164   with assms show ?thesis by auto
   165 qed
   166 
   167 lemma (in ring_of_sets) sets_Collect_finite_Ex:
   168   assumes "\<And>i. i \<in> S \<Longrightarrow> {x\<in>\<Omega>. P i x} \<in> M" "finite S"
   169   shows "{x\<in>\<Omega>. \<exists>i\<in>S. P i x} \<in> M"
   170 proof -
   171   have "{x\<in>\<Omega>. \<exists>i\<in>S. P i x} = (\<Union>i\<in>S. {x\<in>\<Omega>. P i x})"
   172     by auto
   173   with assms show ?thesis by auto
   174 qed
   175 
   176 locale algebra = ring_of_sets +
   177   assumes top [iff]: "\<Omega> \<in> M"
   178 
   179 lemma (in algebra) compl_sets [intro]:
   180   "a \<in> M \<Longrightarrow> \<Omega> - a \<in> M"
   181   by auto
   182 
   183 lemma algebra_iff_Un:
   184   "algebra \<Omega> M \<longleftrightarrow>
   185     M \<subseteq> Pow \<Omega> \<and>
   186     {} \<in> M \<and>
   187     (\<forall>a \<in> M. \<Omega> - a \<in> M) \<and>
   188     (\<forall>a \<in> M. \<forall> b \<in> M. a \<union> b \<in> M)" (is "_ \<longleftrightarrow> ?Un")
   189 proof
   190   assume "algebra \<Omega> M"
   191   then interpret algebra \<Omega> M .
   192   show ?Un using sets_into_space by auto
   193 next
   194   assume ?Un
   195   then have "\<Omega> \<in> M" by auto
   196   interpret ring_of_sets \<Omega> M
   197   proof (rule ring_of_setsI)
   198     show \<Omega>: "M \<subseteq> Pow \<Omega>" "{} \<in> M"
   199       using `?Un` by auto
   200     fix a b assume a: "a \<in> M" and b: "b \<in> M"
   201     then show "a \<union> b \<in> M" using `?Un` by auto
   202     have "a - b = \<Omega> - ((\<Omega> - a) \<union> b)"
   203       using \<Omega> a b by auto
   204     then show "a - b \<in> M"
   205       using a b  `?Un` by auto
   206   qed
   207   show "algebra \<Omega> M" proof qed fact
   208 qed
   209 
   210 lemma algebra_iff_Int:
   211      "algebra \<Omega> M \<longleftrightarrow>
   212        M \<subseteq> Pow \<Omega> & {} \<in> M &
   213        (\<forall>a \<in> M. \<Omega> - a \<in> M) &
   214        (\<forall>a \<in> M. \<forall> b \<in> M. a \<inter> b \<in> M)" (is "_ \<longleftrightarrow> ?Int")
   215 proof
   216   assume "algebra \<Omega> M"
   217   then interpret algebra \<Omega> M .
   218   show ?Int using sets_into_space by auto
   219 next
   220   assume ?Int
   221   show "algebra \<Omega> M"
   222   proof (unfold algebra_iff_Un, intro conjI ballI)
   223     show \<Omega>: "M \<subseteq> Pow \<Omega>" "{} \<in> M"
   224       using `?Int` by auto
   225     from `?Int` show "\<And>a. a \<in> M \<Longrightarrow> \<Omega> - a \<in> M" by auto
   226     fix a b assume M: "a \<in> M" "b \<in> M"
   227     hence "a \<union> b = \<Omega> - ((\<Omega> - a) \<inter> (\<Omega> - b))"
   228       using \<Omega> by blast
   229     also have "... \<in> M"
   230       using M `?Int` by auto
   231     finally show "a \<union> b \<in> M" .
   232   qed
   233 qed
   234 
   235 lemma (in algebra) sets_Collect_neg:
   236   assumes "{x\<in>\<Omega>. P x} \<in> M"
   237   shows "{x\<in>\<Omega>. \<not> P x} \<in> M"
   238 proof -
   239   have "{x\<in>\<Omega>. \<not> P x} = \<Omega> - {x\<in>\<Omega>. P x}" by auto
   240   with assms show ?thesis by auto
   241 qed
   242 
   243 lemma (in algebra) sets_Collect_imp:
   244   "{x\<in>\<Omega>. P x} \<in> M \<Longrightarrow> {x\<in>\<Omega>. Q x} \<in> M \<Longrightarrow> {x\<in>\<Omega>. Q x \<longrightarrow> P x} \<in> M"
   245   unfolding imp_conv_disj by (intro sets_Collect_disj sets_Collect_neg)
   246 
   247 lemma (in algebra) sets_Collect_const:
   248   "{x\<in>\<Omega>. P} \<in> M"
   249   by (cases P) auto
   250 
   251 lemma algebra_single_set:
   252   "X \<subseteq> S \<Longrightarrow> algebra S { {}, X, S - X, S }"
   253   by (auto simp: algebra_iff_Int)
   254 
   255 section {* Restricted algebras *}
   256 
   257 abbreviation (in algebra)
   258   "restricted_space A \<equiv> (op \<inter> A) ` M"
   259 
   260 lemma (in algebra) restricted_algebra:
   261   assumes "A \<in> M" shows "algebra A (restricted_space A)"
   262   using assms by (auto simp: algebra_iff_Int)
   263 
   264 subsection {* Sigma Algebras *}
   265 
   266 locale sigma_algebra = algebra +
   267   assumes countable_nat_UN [intro]: "\<And>A. range A \<subseteq> M \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
   268 
   269 lemma (in algebra) is_sigma_algebra:
   270   assumes "finite M"
   271   shows "sigma_algebra \<Omega> M"
   272 proof
   273   fix A :: "nat \<Rightarrow> 'a set" assume "range A \<subseteq> M"
   274   then have "(\<Union>i. A i) = (\<Union>s\<in>M \<inter> range A. s)"
   275     by auto
   276   also have "(\<Union>s\<in>M \<inter> range A. s) \<in> M"
   277     using `finite M` by auto
   278   finally show "(\<Union>i. A i) \<in> M" .
   279 qed
   280 
   281 lemma countable_UN_eq:
   282   fixes A :: "'i::countable \<Rightarrow> 'a set"
   283   shows "(range A \<subseteq> M \<longrightarrow> (\<Union>i. A i) \<in> M) \<longleftrightarrow>
   284     (range (A \<circ> from_nat) \<subseteq> M \<longrightarrow> (\<Union>i. (A \<circ> from_nat) i) \<in> M)"
   285 proof -
   286   let ?A' = "A \<circ> from_nat"
   287   have *: "(\<Union>i. ?A' i) = (\<Union>i. A i)" (is "?l = ?r")
   288   proof safe
   289     fix x i assume "x \<in> A i" thus "x \<in> ?l"
   290       by (auto intro!: exI[of _ "to_nat i"])
   291   next
   292     fix x i assume "x \<in> ?A' i" thus "x \<in> ?r"
   293       by (auto intro!: exI[of _ "from_nat i"])
   294   qed
   295   have **: "range ?A' = range A"
   296     using surj_from_nat
   297     by (auto simp: image_compose intro!: imageI)
   298   show ?thesis unfolding * ** ..
   299 qed
   300 
   301 lemma (in sigma_algebra) countable_UN[intro]:
   302   fixes A :: "'i::countable \<Rightarrow> 'a set"
   303   assumes "A`X \<subseteq> M"
   304   shows  "(\<Union>x\<in>X. A x) \<in> M"
   305 proof -
   306   let ?A = "\<lambda>i. if i \<in> X then A i else {}"
   307   from assms have "range ?A \<subseteq> M" by auto
   308   with countable_nat_UN[of "?A \<circ> from_nat"] countable_UN_eq[of ?A M]
   309   have "(\<Union>x. ?A x) \<in> M" by auto
   310   moreover have "(\<Union>x. ?A x) = (\<Union>x\<in>X. A x)" by (auto split: split_if_asm)
   311   ultimately show ?thesis by simp
   312 qed
   313 
   314 lemma (in sigma_algebra) countable_INT [intro]:
   315   fixes A :: "'i::countable \<Rightarrow> 'a set"
   316   assumes A: "A`X \<subseteq> M" "X \<noteq> {}"
   317   shows "(\<Inter>i\<in>X. A i) \<in> M"
   318 proof -
   319   from A have "\<forall>i\<in>X. A i \<in> M" by fast
   320   hence "\<Omega> - (\<Union>i\<in>X. \<Omega> - A i) \<in> M" by blast
   321   moreover
   322   have "(\<Inter>i\<in>X. A i) = \<Omega> - (\<Union>i\<in>X. \<Omega> - A i)" using space_closed A
   323     by blast
   324   ultimately show ?thesis by metis
   325 qed
   326 
   327 lemma ring_of_sets_Pow: "ring_of_sets sp (Pow sp)"
   328   by (auto simp: ring_of_sets_iff)
   329 
   330 lemma algebra_Pow: "algebra sp (Pow sp)"
   331   by (auto simp: algebra_iff_Un)
   332 
   333 lemma sigma_algebra_iff:
   334   "sigma_algebra \<Omega> M \<longleftrightarrow>
   335     algebra \<Omega> M \<and> (\<forall>A. range A \<subseteq> M \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
   336   by (simp add: sigma_algebra_def sigma_algebra_axioms_def)
   337 
   338 lemma sigma_algebra_Pow: "sigma_algebra sp (Pow sp)"
   339   by (auto simp: sigma_algebra_iff algebra_iff_Int)
   340 
   341 lemma (in sigma_algebra) sets_Collect_countable_All:
   342   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   343   shows "{x\<in>\<Omega>. \<forall>i::'i::countable. P i x} \<in> M"
   344 proof -
   345   have "{x\<in>\<Omega>. \<forall>i::'i::countable. P i x} = (\<Inter>i. {x\<in>\<Omega>. P i x})" by auto
   346   with assms show ?thesis by auto
   347 qed
   348 
   349 lemma (in sigma_algebra) sets_Collect_countable_Ex:
   350   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   351   shows "{x\<in>\<Omega>. \<exists>i::'i::countable. P i x} \<in> M"
   352 proof -
   353   have "{x\<in>\<Omega>. \<exists>i::'i::countable. P i x} = (\<Union>i. {x\<in>\<Omega>. P i x})" by auto
   354   with assms show ?thesis by auto
   355 qed
   356 
   357 lemmas (in sigma_algebra) sets_Collect =
   358   sets_Collect_imp sets_Collect_disj sets_Collect_conj sets_Collect_neg sets_Collect_const
   359   sets_Collect_countable_All sets_Collect_countable_Ex sets_Collect_countable_All
   360 
   361 lemma (in sigma_algebra) sets_Collect_countable_Ball:
   362   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   363   shows "{x\<in>\<Omega>. \<forall>i::'i::countable\<in>X. P i x} \<in> M"
   364   unfolding Ball_def by (intro sets_Collect assms)
   365 
   366 lemma (in sigma_algebra) sets_Collect_countable_Bex:
   367   assumes "\<And>i. {x\<in>\<Omega>. P i x} \<in> M"
   368   shows "{x\<in>\<Omega>. \<exists>i::'i::countable\<in>X. P i x} \<in> M"
   369   unfolding Bex_def by (intro sets_Collect assms)
   370 
   371 lemma sigma_algebra_single_set:
   372   assumes "X \<subseteq> S"
   373   shows "sigma_algebra S { {}, X, S - X, S }"
   374   using algebra.is_sigma_algebra[OF algebra_single_set[OF `X \<subseteq> S`]] by simp
   375 
   376 subsection {* Binary Unions *}
   377 
   378 definition binary :: "'a \<Rightarrow> 'a \<Rightarrow> nat \<Rightarrow> 'a"
   379   where "binary a b =  (\<lambda>\<^isup>x. b)(0 := a)"
   380 
   381 lemma range_binary_eq: "range(binary a b) = {a,b}"
   382   by (auto simp add: binary_def)
   383 
   384 lemma Un_range_binary: "a \<union> b = (\<Union>i::nat. binary a b i)"
   385   by (simp add: SUP_def range_binary_eq)
   386 
   387 lemma Int_range_binary: "a \<inter> b = (\<Inter>i::nat. binary a b i)"
   388   by (simp add: INF_def range_binary_eq)
   389 
   390 lemma sigma_algebra_iff2:
   391      "sigma_algebra \<Omega> M \<longleftrightarrow>
   392        M \<subseteq> Pow \<Omega> \<and>
   393        {} \<in> M \<and> (\<forall>s \<in> M. \<Omega> - s \<in> M) \<and>
   394        (\<forall>A. range A \<subseteq> M \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
   395   by (auto simp add: range_binary_eq sigma_algebra_def sigma_algebra_axioms_def
   396          algebra_iff_Un Un_range_binary)
   397 
   398 subsection {* Initial Sigma Algebra *}
   399 
   400 text {*Sigma algebras can naturally be created as the closure of any set of
   401   M with regard to the properties just postulated.  *}
   402 
   403 inductive_set
   404   sigma_sets :: "'a set \<Rightarrow> 'a set set \<Rightarrow> 'a set set"
   405   for sp :: "'a set" and A :: "'a set set"
   406   where
   407     Basic[intro, simp]: "a \<in> A \<Longrightarrow> a \<in> sigma_sets sp A"
   408   | Empty: "{} \<in> sigma_sets sp A"
   409   | Compl: "a \<in> sigma_sets sp A \<Longrightarrow> sp - a \<in> sigma_sets sp A"
   410   | Union: "(\<And>i::nat. a i \<in> sigma_sets sp A) \<Longrightarrow> (\<Union>i. a i) \<in> sigma_sets sp A"
   411 
   412 lemma (in sigma_algebra) sigma_sets_subset:
   413   assumes a: "a \<subseteq> M"
   414   shows "sigma_sets \<Omega> a \<subseteq> M"
   415 proof
   416   fix x
   417   assume "x \<in> sigma_sets \<Omega> a"
   418   from this show "x \<in> M"
   419     by (induct rule: sigma_sets.induct, auto) (metis a subsetD)
   420 qed
   421 
   422 lemma sigma_sets_into_sp: "A \<subseteq> Pow sp \<Longrightarrow> x \<in> sigma_sets sp A \<Longrightarrow> x \<subseteq> sp"
   423   by (erule sigma_sets.induct, auto)
   424 
   425 lemma sigma_algebra_sigma_sets:
   426      "a \<subseteq> Pow \<Omega> \<Longrightarrow> sigma_algebra \<Omega> (sigma_sets \<Omega> a)"
   427   by (auto simp add: sigma_algebra_iff2 dest: sigma_sets_into_sp
   428            intro!: sigma_sets.Union sigma_sets.Empty sigma_sets.Compl)
   429 
   430 lemma sigma_sets_least_sigma_algebra:
   431   assumes "A \<subseteq> Pow S"
   432   shows "sigma_sets S A = \<Inter>{B. A \<subseteq> B \<and> sigma_algebra S B}"
   433 proof safe
   434   fix B X assume "A \<subseteq> B" and sa: "sigma_algebra S B"
   435     and X: "X \<in> sigma_sets S A"
   436   from sigma_algebra.sigma_sets_subset[OF sa, simplified, OF `A \<subseteq> B`] X
   437   show "X \<in> B" by auto
   438 next
   439   fix X assume "X \<in> \<Inter>{B. A \<subseteq> B \<and> sigma_algebra S B}"
   440   then have [intro!]: "\<And>B. A \<subseteq> B \<Longrightarrow> sigma_algebra S B \<Longrightarrow> X \<in> B"
   441      by simp
   442   have "A \<subseteq> sigma_sets S A" using assms by auto
   443   moreover have "sigma_algebra S (sigma_sets S A)"
   444     using assms by (intro sigma_algebra_sigma_sets[of A]) auto
   445   ultimately show "X \<in> sigma_sets S A" by auto
   446 qed
   447 
   448 lemma sigma_sets_top: "sp \<in> sigma_sets sp A"
   449   by (metis Diff_empty sigma_sets.Compl sigma_sets.Empty)
   450 
   451 lemma sigma_sets_Un:
   452   "a \<in> sigma_sets sp A \<Longrightarrow> b \<in> sigma_sets sp A \<Longrightarrow> a \<union> b \<in> sigma_sets sp A"
   453 apply (simp add: Un_range_binary range_binary_eq)
   454 apply (rule Union, simp add: binary_def)
   455 done
   456 
   457 lemma sigma_sets_Inter:
   458   assumes Asb: "A \<subseteq> Pow sp"
   459   shows "(\<And>i::nat. a i \<in> sigma_sets sp A) \<Longrightarrow> (\<Inter>i. a i) \<in> sigma_sets sp A"
   460 proof -
   461   assume ai: "\<And>i::nat. a i \<in> sigma_sets sp A"
   462   hence "\<And>i::nat. sp-(a i) \<in> sigma_sets sp A"
   463     by (rule sigma_sets.Compl)
   464   hence "(\<Union>i. sp-(a i)) \<in> sigma_sets sp A"
   465     by (rule sigma_sets.Union)
   466   hence "sp-(\<Union>i. sp-(a i)) \<in> sigma_sets sp A"
   467     by (rule sigma_sets.Compl)
   468   also have "sp-(\<Union>i. sp-(a i)) = sp Int (\<Inter>i. a i)"
   469     by auto
   470   also have "... = (\<Inter>i. a i)" using ai
   471     by (blast dest: sigma_sets_into_sp [OF Asb])
   472   finally show ?thesis .
   473 qed
   474 
   475 lemma sigma_sets_INTER:
   476   assumes Asb: "A \<subseteq> Pow sp"
   477       and ai: "\<And>i::nat. i \<in> S \<Longrightarrow> a i \<in> sigma_sets sp A" and non: "S \<noteq> {}"
   478   shows "(\<Inter>i\<in>S. a i) \<in> sigma_sets sp A"
   479 proof -
   480   from ai have "\<And>i. (if i\<in>S then a i else sp) \<in> sigma_sets sp A"
   481     by (simp add: sigma_sets.intros(2-) sigma_sets_top)
   482   hence "(\<Inter>i. (if i\<in>S then a i else sp)) \<in> sigma_sets sp A"
   483     by (rule sigma_sets_Inter [OF Asb])
   484   also have "(\<Inter>i. (if i\<in>S then a i else sp)) = (\<Inter>i\<in>S. a i)"
   485     by auto (metis ai non sigma_sets_into_sp subset_empty subset_iff Asb)+
   486   finally show ?thesis .
   487 qed
   488 
   489 lemma (in sigma_algebra) sigma_sets_eq:
   490      "sigma_sets \<Omega> M = M"
   491 proof
   492   show "M \<subseteq> sigma_sets \<Omega> M"
   493     by (metis Set.subsetI sigma_sets.Basic)
   494   next
   495   show "sigma_sets \<Omega> M \<subseteq> M"
   496     by (metis sigma_sets_subset subset_refl)
   497 qed
   498 
   499 lemma sigma_sets_eqI:
   500   assumes A: "\<And>a. a \<in> A \<Longrightarrow> a \<in> sigma_sets M B"
   501   assumes B: "\<And>b. b \<in> B \<Longrightarrow> b \<in> sigma_sets M A"
   502   shows "sigma_sets M A = sigma_sets M B"
   503 proof (intro set_eqI iffI)
   504   fix a assume "a \<in> sigma_sets M A"
   505   from this A show "a \<in> sigma_sets M B"
   506     by induct (auto intro!: sigma_sets.intros(2-) del: sigma_sets.Basic)
   507 next
   508   fix b assume "b \<in> sigma_sets M B"
   509   from this B show "b \<in> sigma_sets M A"
   510     by induct (auto intro!: sigma_sets.intros(2-) del: sigma_sets.Basic)
   511 qed
   512 
   513 lemma sigma_sets_subseteq: assumes "A \<subseteq> B" shows "sigma_sets X A \<subseteq> sigma_sets X B"
   514 proof
   515   fix x assume "x \<in> sigma_sets X A" then show "x \<in> sigma_sets X B"
   516     by induct (insert `A \<subseteq> B`, auto intro: sigma_sets.intros(2-))
   517 qed
   518 
   519 lemma sigma_sets_mono: assumes "A \<subseteq> sigma_sets X B" shows "sigma_sets X A \<subseteq> sigma_sets X B"
   520 proof
   521   fix x assume "x \<in> sigma_sets X A" then show "x \<in> sigma_sets X B"
   522     by induct (insert `A \<subseteq> sigma_sets X B`, auto intro: sigma_sets.intros(2-))
   523 qed
   524 
   525 lemma sigma_sets_mono': assumes "A \<subseteq> B" shows "sigma_sets X A \<subseteq> sigma_sets X B"
   526 proof
   527   fix x assume "x \<in> sigma_sets X A" then show "x \<in> sigma_sets X B"
   528     by induct (insert `A \<subseteq> B`, auto intro: sigma_sets.intros(2-))
   529 qed
   530 
   531 lemma sigma_sets_superset_generator: "A \<subseteq> sigma_sets X A"
   532   by (auto intro: sigma_sets.Basic)
   533 
   534 lemma (in sigma_algebra) restriction_in_sets:
   535   fixes A :: "nat \<Rightarrow> 'a set"
   536   assumes "S \<in> M"
   537   and *: "range A \<subseteq> (\<lambda>A. S \<inter> A) ` M" (is "_ \<subseteq> ?r")
   538   shows "range A \<subseteq> M" "(\<Union>i. A i) \<in> (\<lambda>A. S \<inter> A) ` M"
   539 proof -
   540   { fix i have "A i \<in> ?r" using * by auto
   541     hence "\<exists>B. A i = B \<inter> S \<and> B \<in> M" by auto
   542     hence "A i \<subseteq> S" "A i \<in> M" using `S \<in> M` by auto }
   543   thus "range A \<subseteq> M" "(\<Union>i. A i) \<in> (\<lambda>A. S \<inter> A) ` M"
   544     by (auto intro!: image_eqI[of _ _ "(\<Union>i. A i)"])
   545 qed
   546 
   547 lemma (in sigma_algebra) restricted_sigma_algebra:
   548   assumes "S \<in> M"
   549   shows "sigma_algebra S (restricted_space S)"
   550   unfolding sigma_algebra_def sigma_algebra_axioms_def
   551 proof safe
   552   show "algebra S (restricted_space S)" using restricted_algebra[OF assms] .
   553 next
   554   fix A :: "nat \<Rightarrow> 'a set" assume "range A \<subseteq> restricted_space S"
   555   from restriction_in_sets[OF assms this[simplified]]
   556   show "(\<Union>i. A i) \<in> restricted_space S" by simp
   557 qed
   558 
   559 lemma sigma_sets_Int:
   560   assumes "A \<in> sigma_sets sp st" "A \<subseteq> sp"
   561   shows "op \<inter> A ` sigma_sets sp st = sigma_sets A (op \<inter> A ` st)"
   562 proof (intro equalityI subsetI)
   563   fix x assume "x \<in> op \<inter> A ` sigma_sets sp st"
   564   then obtain y where "y \<in> sigma_sets sp st" "x = y \<inter> A" by auto
   565   then have "x \<in> sigma_sets (A \<inter> sp) (op \<inter> A ` st)"
   566   proof (induct arbitrary: x)
   567     case (Compl a)
   568     then show ?case
   569       by (force intro!: sigma_sets.Compl simp: Diff_Int_distrib ac_simps)
   570   next
   571     case (Union a)
   572     then show ?case
   573       by (auto intro!: sigma_sets.Union
   574                simp add: UN_extend_simps simp del: UN_simps)
   575   qed (auto intro!: sigma_sets.intros(2-))
   576   then show "x \<in> sigma_sets A (op \<inter> A ` st)"
   577     using `A \<subseteq> sp` by (simp add: Int_absorb2)
   578 next
   579   fix x assume "x \<in> sigma_sets A (op \<inter> A ` st)"
   580   then show "x \<in> op \<inter> A ` sigma_sets sp st"
   581   proof induct
   582     case (Compl a)
   583     then obtain x where "a = A \<inter> x" "x \<in> sigma_sets sp st" by auto
   584     then show ?case using `A \<subseteq> sp`
   585       by (force simp add: image_iff intro!: bexI[of _ "sp - x"] sigma_sets.Compl)
   586   next
   587     case (Union a)
   588     then have "\<forall>i. \<exists>x. x \<in> sigma_sets sp st \<and> a i = A \<inter> x"
   589       by (auto simp: image_iff Bex_def)
   590     from choice[OF this] guess f ..
   591     then show ?case
   592       by (auto intro!: bexI[of _ "(\<Union>x. f x)"] sigma_sets.Union
   593                simp add: image_iff)
   594   qed (auto intro!: sigma_sets.intros(2-))
   595 qed
   596 
   597 lemma sigma_sets_empty_eq: "sigma_sets A {} = {{}, A}"
   598 proof (intro set_eqI iffI)
   599   fix a assume "a \<in> sigma_sets A {}" then show "a \<in> {{}, A}"
   600     by induct blast+
   601 qed (auto intro: sigma_sets.Empty sigma_sets_top)
   602 
   603 lemma sigma_sets_single[simp]: "sigma_sets A {A} = {{}, A}"
   604 proof (intro set_eqI iffI)
   605   fix x assume "x \<in> sigma_sets A {A}"
   606   then show "x \<in> {{}, A}"
   607     by induct blast+
   608 next
   609   fix x assume "x \<in> {{}, A}"
   610   then show "x \<in> sigma_sets A {A}"
   611     by (auto intro: sigma_sets.Empty sigma_sets_top)
   612 qed
   613 
   614 lemma sigma_sets_sigma_sets_eq:
   615   "M \<subseteq> Pow S \<Longrightarrow> sigma_sets S (sigma_sets S M) = sigma_sets S M"
   616   by (rule sigma_algebra.sigma_sets_eq[OF sigma_algebra_sigma_sets, of M S]) auto
   617 
   618 lemma sigma_sets_singleton:
   619   assumes "X \<subseteq> S"
   620   shows "sigma_sets S { X } = { {}, X, S - X, S }"
   621 proof -
   622   interpret sigma_algebra S "{ {}, X, S - X, S }"
   623     by (rule sigma_algebra_single_set) fact
   624   have "sigma_sets S { X } \<subseteq> sigma_sets S { {}, X, S - X, S }"
   625     by (rule sigma_sets_subseteq) simp
   626   moreover have "\<dots> = { {}, X, S - X, S }"
   627     using sigma_sets_eq by simp
   628   moreover
   629   { fix A assume "A \<in> { {}, X, S - X, S }"
   630     then have "A \<in> sigma_sets S { X }"
   631       by (auto intro: sigma_sets.intros(2-) sigma_sets_top) }
   632   ultimately have "sigma_sets S { X } = sigma_sets S { {}, X, S - X, S }"
   633     by (intro antisym) auto
   634   with sigma_sets_eq show ?thesis by simp
   635 qed
   636 
   637 lemma restricted_sigma:
   638   assumes S: "S \<in> sigma_sets \<Omega> M" and M: "M \<subseteq> Pow \<Omega>"
   639   shows "algebra.restricted_space (sigma_sets \<Omega> M) S =
   640     sigma_sets S (algebra.restricted_space M S)"
   641 proof -
   642   from S sigma_sets_into_sp[OF M]
   643   have "S \<in> sigma_sets \<Omega> M" "S \<subseteq> \<Omega>" by auto
   644   from sigma_sets_Int[OF this]
   645   show ?thesis by simp
   646 qed
   647 
   648 lemma sigma_sets_vimage_commute:
   649   assumes X: "X \<in> \<Omega> \<rightarrow> \<Omega>'"
   650   shows "{X -` A \<inter> \<Omega> |A. A \<in> sigma_sets \<Omega>' M'}
   651        = sigma_sets \<Omega> {X -` A \<inter> \<Omega> |A. A \<in> M'}" (is "?L = ?R")
   652 proof
   653   show "?L \<subseteq> ?R"
   654   proof clarify
   655     fix A assume "A \<in> sigma_sets \<Omega>' M'"
   656     then show "X -` A \<inter> \<Omega> \<in> ?R"
   657     proof induct
   658       case Empty then show ?case
   659         by (auto intro!: sigma_sets.Empty)
   660     next
   661       case (Compl B)
   662       have [simp]: "X -` (\<Omega>' - B) \<inter> \<Omega> = \<Omega> - (X -` B \<inter> \<Omega>)"
   663         by (auto simp add: funcset_mem [OF X])
   664       with Compl show ?case
   665         by (auto intro!: sigma_sets.Compl)
   666     next
   667       case (Union F)
   668       then show ?case
   669         by (auto simp add: vimage_UN UN_extend_simps(4) simp del: UN_simps
   670                  intro!: sigma_sets.Union)
   671     qed auto
   672   qed
   673   show "?R \<subseteq> ?L"
   674   proof clarify
   675     fix A assume "A \<in> ?R"
   676     then show "\<exists>B. A = X -` B \<inter> \<Omega> \<and> B \<in> sigma_sets \<Omega>' M'"
   677     proof induct
   678       case (Basic B) then show ?case by auto
   679     next
   680       case Empty then show ?case
   681         by (auto intro!: sigma_sets.Empty exI[of _ "{}"])
   682     next
   683       case (Compl B)
   684       then obtain A where A: "B = X -` A \<inter> \<Omega>" "A \<in> sigma_sets \<Omega>' M'" by auto
   685       then have [simp]: "\<Omega> - B = X -` (\<Omega>' - A) \<inter> \<Omega>"
   686         by (auto simp add: funcset_mem [OF X])
   687       with A(2) show ?case
   688         by (auto intro: sigma_sets.Compl)
   689     next
   690       case (Union F)
   691       then have "\<forall>i. \<exists>B. F i = X -` B \<inter> \<Omega> \<and> B \<in> sigma_sets \<Omega>' M'" by auto
   692       from choice[OF this] guess A .. note A = this
   693       with A show ?case
   694         by (auto simp: vimage_UN[symmetric] intro: sigma_sets.Union)
   695     qed
   696   qed
   697 qed
   698 
   699 section "Disjoint families"
   700 
   701 definition
   702   disjoint_family_on  where
   703   "disjoint_family_on A S \<longleftrightarrow> (\<forall>m\<in>S. \<forall>n\<in>S. m \<noteq> n \<longrightarrow> A m \<inter> A n = {})"
   704 
   705 abbreviation
   706   "disjoint_family A \<equiv> disjoint_family_on A UNIV"
   707 
   708 lemma range_subsetD: "range f \<subseteq> B \<Longrightarrow> f i \<in> B"
   709   by blast
   710 
   711 lemma Int_Diff_disjoint: "A \<inter> B \<inter> (A - B) = {}"
   712   by blast
   713 
   714 lemma Int_Diff_Un: "A \<inter> B \<union> (A - B) = A"
   715   by blast
   716 
   717 lemma disjoint_family_subset:
   718      "disjoint_family A \<Longrightarrow> (!!x. B x \<subseteq> A x) \<Longrightarrow> disjoint_family B"
   719   by (force simp add: disjoint_family_on_def)
   720 
   721 lemma disjoint_family_on_bisimulation:
   722   assumes "disjoint_family_on f S"
   723   and "\<And>n m. n \<in> S \<Longrightarrow> m \<in> S \<Longrightarrow> n \<noteq> m \<Longrightarrow> f n \<inter> f m = {} \<Longrightarrow> g n \<inter> g m = {}"
   724   shows "disjoint_family_on g S"
   725   using assms unfolding disjoint_family_on_def by auto
   726 
   727 lemma disjoint_family_on_mono:
   728   "A \<subseteq> B \<Longrightarrow> disjoint_family_on f B \<Longrightarrow> disjoint_family_on f A"
   729   unfolding disjoint_family_on_def by auto
   730 
   731 lemma disjoint_family_Suc:
   732   assumes Suc: "!!n. A n \<subseteq> A (Suc n)"
   733   shows "disjoint_family (\<lambda>i. A (Suc i) - A i)"
   734 proof -
   735   {
   736     fix m
   737     have "!!n. A n \<subseteq> A (m+n)"
   738     proof (induct m)
   739       case 0 show ?case by simp
   740     next
   741       case (Suc m) thus ?case
   742         by (metis Suc_eq_plus1 assms nat_add_commute nat_add_left_commute subset_trans)
   743     qed
   744   }
   745   hence "!!m n. m < n \<Longrightarrow> A m \<subseteq> A n"
   746     by (metis add_commute le_add_diff_inverse nat_less_le)
   747   thus ?thesis
   748     by (auto simp add: disjoint_family_on_def)
   749       (metis insert_absorb insert_subset le_SucE le_antisym not_leE)
   750 qed
   751 
   752 lemma setsum_indicator_disjoint_family:
   753   fixes f :: "'d \<Rightarrow> 'e::semiring_1"
   754   assumes d: "disjoint_family_on A P" and "x \<in> A j" and "finite P" and "j \<in> P"
   755   shows "(\<Sum>i\<in>P. f i * indicator (A i) x) = f j"
   756 proof -
   757   have "P \<inter> {i. x \<in> A i} = {j}"
   758     using d `x \<in> A j` `j \<in> P` unfolding disjoint_family_on_def
   759     by auto
   760   thus ?thesis
   761     unfolding indicator_def
   762     by (simp add: if_distrib setsum_cases[OF `finite P`])
   763 qed
   764 
   765 definition disjointed :: "(nat \<Rightarrow> 'a set) \<Rightarrow> nat \<Rightarrow> 'a set "
   766   where "disjointed A n = A n - (\<Union>i\<in>{0..<n}. A i)"
   767 
   768 lemma finite_UN_disjointed_eq: "(\<Union>i\<in>{0..<n}. disjointed A i) = (\<Union>i\<in>{0..<n}. A i)"
   769 proof (induct n)
   770   case 0 show ?case by simp
   771 next
   772   case (Suc n)
   773   thus ?case by (simp add: atLeastLessThanSuc disjointed_def)
   774 qed
   775 
   776 lemma UN_disjointed_eq: "(\<Union>i. disjointed A i) = (\<Union>i. A i)"
   777   apply (rule UN_finite2_eq [where k=0])
   778   apply (simp add: finite_UN_disjointed_eq)
   779   done
   780 
   781 lemma less_disjoint_disjointed: "m<n \<Longrightarrow> disjointed A m \<inter> disjointed A n = {}"
   782   by (auto simp add: disjointed_def)
   783 
   784 lemma disjoint_family_disjointed: "disjoint_family (disjointed A)"
   785   by (simp add: disjoint_family_on_def)
   786      (metis neq_iff Int_commute less_disjoint_disjointed)
   787 
   788 lemma disjointed_subset: "disjointed A n \<subseteq> A n"
   789   by (auto simp add: disjointed_def)
   790 
   791 lemma (in ring_of_sets) UNION_in_sets:
   792   fixes A:: "nat \<Rightarrow> 'a set"
   793   assumes A: "range A \<subseteq> M"
   794   shows  "(\<Union>i\<in>{0..<n}. A i) \<in> M"
   795 proof (induct n)
   796   case 0 show ?case by simp
   797 next
   798   case (Suc n)
   799   thus ?case
   800     by (simp add: atLeastLessThanSuc) (metis A Un UNIV_I image_subset_iff)
   801 qed
   802 
   803 lemma (in ring_of_sets) range_disjointed_sets:
   804   assumes A: "range A \<subseteq> M"
   805   shows  "range (disjointed A) \<subseteq> M"
   806 proof (auto simp add: disjointed_def)
   807   fix n
   808   show "A n - (\<Union>i\<in>{0..<n}. A i) \<in> M" using UNION_in_sets
   809     by (metis A Diff UNIV_I image_subset_iff)
   810 qed
   811 
   812 lemma (in algebra) range_disjointed_sets':
   813   "range A \<subseteq> M \<Longrightarrow> range (disjointed A) \<subseteq> M"
   814   using range_disjointed_sets .
   815 
   816 lemma disjointed_0[simp]: "disjointed A 0 = A 0"
   817   by (simp add: disjointed_def)
   818 
   819 lemma incseq_Un:
   820   "incseq A \<Longrightarrow> (\<Union>i\<le>n. A i) = A n"
   821   unfolding incseq_def by auto
   822 
   823 lemma disjointed_incseq:
   824   "incseq A \<Longrightarrow> disjointed A (Suc n) = A (Suc n) - A n"
   825   using incseq_Un[of A]
   826   by (simp add: disjointed_def atLeastLessThanSuc_atLeastAtMost atLeast0AtMost)
   827 
   828 lemma sigma_algebra_disjoint_iff:
   829   "sigma_algebra \<Omega> M \<longleftrightarrow> algebra \<Omega> M \<and>
   830     (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
   831 proof (auto simp add: sigma_algebra_iff)
   832   fix A :: "nat \<Rightarrow> 'a set"
   833   assume M: "algebra \<Omega> M"
   834      and A: "range A \<subseteq> M"
   835      and UnA: "\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i::nat. A i) \<in> M"
   836   hence "range (disjointed A) \<subseteq> M \<longrightarrow>
   837          disjoint_family (disjointed A) \<longrightarrow>
   838          (\<Union>i. disjointed A i) \<in> M" by blast
   839   hence "(\<Union>i. disjointed A i) \<in> M"
   840     by (simp add: algebra.range_disjointed_sets'[of \<Omega>] M A disjoint_family_disjointed)
   841   thus "(\<Union>i::nat. A i) \<in> M" by (simp add: UN_disjointed_eq)
   842 qed
   843 
   844 lemma disjoint_family_on_disjoint_image:
   845   "disjoint_family_on A I \<Longrightarrow> disjoint (A ` I)"
   846   unfolding disjoint_family_on_def disjoint_def by force
   847 
   848 lemma disjoint_image_disjoint_family_on:
   849   assumes d: "disjoint (A ` I)" and i: "inj_on A I"
   850   shows "disjoint_family_on A I"
   851   unfolding disjoint_family_on_def
   852 proof (intro ballI impI)
   853   fix n m assume nm: "m \<in> I" "n \<in> I" and "n \<noteq> m"
   854   with i[THEN inj_onD, of n m] show "A n \<inter> A m = {}"
   855     by (intro disjointD[OF d]) auto
   856 qed
   857 
   858 section {* Ring generated by a semiring *}
   859 
   860 definition (in semiring_of_sets)
   861   "generated_ring = { \<Union>C | C. C \<subseteq> M \<and> finite C \<and> disjoint C }"
   862 
   863 lemma (in semiring_of_sets) generated_ringE[elim?]:
   864   assumes "a \<in> generated_ring"
   865   obtains C where "finite C" "disjoint C" "C \<subseteq> M" "a = \<Union>C"
   866   using assms unfolding generated_ring_def by auto
   867 
   868 lemma (in semiring_of_sets) generated_ringI[intro?]:
   869   assumes "finite C" "disjoint C" "C \<subseteq> M" "a = \<Union>C"
   870   shows "a \<in> generated_ring"
   871   using assms unfolding generated_ring_def by auto
   872 
   873 lemma (in semiring_of_sets) generated_ringI_Basic:
   874   "A \<in> M \<Longrightarrow> A \<in> generated_ring"
   875   by (rule generated_ringI[of "{A}"]) (auto simp: disjoint_def)
   876 
   877 lemma (in semiring_of_sets) generated_ring_disjoint_Un[intro]:
   878   assumes a: "a \<in> generated_ring" and b: "b \<in> generated_ring"
   879   and "a \<inter> b = {}"
   880   shows "a \<union> b \<in> generated_ring"
   881 proof -
   882   from a guess Ca .. note Ca = this
   883   from b guess Cb .. note Cb = this
   884   show ?thesis
   885   proof
   886     show "disjoint (Ca \<union> Cb)"
   887       using `a \<inter> b = {}` Ca Cb by (auto intro!: disjoint_union)
   888   qed (insert Ca Cb, auto)
   889 qed
   890 
   891 lemma (in semiring_of_sets) generated_ring_empty: "{} \<in> generated_ring"
   892   by (auto simp: generated_ring_def disjoint_def)
   893 
   894 lemma (in semiring_of_sets) generated_ring_disjoint_Union:
   895   assumes "finite A" shows "A \<subseteq> generated_ring \<Longrightarrow> disjoint A \<Longrightarrow> \<Union>A \<in> generated_ring"
   896   using assms by (induct A) (auto simp: disjoint_def intro!: generated_ring_disjoint_Un generated_ring_empty)
   897 
   898 lemma (in semiring_of_sets) generated_ring_disjoint_UNION:
   899   "finite I \<Longrightarrow> disjoint (A ` I) \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> A i \<in> generated_ring) \<Longrightarrow> UNION I A \<in> generated_ring"
   900   unfolding SUP_def by (intro generated_ring_disjoint_Union) auto
   901 
   902 lemma (in semiring_of_sets) generated_ring_Int:
   903   assumes a: "a \<in> generated_ring" and b: "b \<in> generated_ring"
   904   shows "a \<inter> b \<in> generated_ring"
   905 proof -
   906   from a guess Ca .. note Ca = this
   907   from b guess Cb .. note Cb = this
   908   def C \<equiv> "(\<lambda>(a,b). a \<inter> b)` (Ca\<times>Cb)"
   909   show ?thesis
   910   proof
   911     show "disjoint C"
   912     proof (simp add: disjoint_def C_def, intro ballI impI)
   913       fix a1 b1 a2 b2 assume sets: "a1 \<in> Ca" "b1 \<in> Cb" "a2 \<in> Ca" "b2 \<in> Cb"
   914       assume "a1 \<inter> b1 \<noteq> a2 \<inter> b2"
   915       then have "a1 \<noteq> a2 \<or> b1 \<noteq> b2" by auto
   916       then show "(a1 \<inter> b1) \<inter> (a2 \<inter> b2) = {}"
   917       proof
   918         assume "a1 \<noteq> a2"
   919         with sets Ca have "a1 \<inter> a2 = {}"
   920           by (auto simp: disjoint_def)
   921         then show ?thesis by auto
   922       next
   923         assume "b1 \<noteq> b2"
   924         with sets Cb have "b1 \<inter> b2 = {}"
   925           by (auto simp: disjoint_def)
   926         then show ?thesis by auto
   927       qed
   928     qed
   929   qed (insert Ca Cb, auto simp: C_def)
   930 qed
   931 
   932 lemma (in semiring_of_sets) generated_ring_Inter:
   933   assumes "finite A" "A \<noteq> {}" shows "A \<subseteq> generated_ring \<Longrightarrow> \<Inter>A \<in> generated_ring"
   934   using assms by (induct A rule: finite_ne_induct) (auto intro: generated_ring_Int)
   935 
   936 lemma (in semiring_of_sets) generated_ring_INTER:
   937   "finite I \<Longrightarrow> I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> A i \<in> generated_ring) \<Longrightarrow> INTER I A \<in> generated_ring"
   938   unfolding INF_def by (intro generated_ring_Inter) auto
   939 
   940 lemma (in semiring_of_sets) generating_ring:
   941   "ring_of_sets \<Omega> generated_ring"
   942 proof (rule ring_of_setsI)
   943   let ?R = generated_ring
   944   show "?R \<subseteq> Pow \<Omega>"
   945     using sets_into_space by (auto simp: generated_ring_def generated_ring_empty)
   946   show "{} \<in> ?R" by (rule generated_ring_empty)
   947 
   948   { fix a assume a: "a \<in> ?R" then guess Ca .. note Ca = this
   949     fix b assume b: "b \<in> ?R" then guess Cb .. note Cb = this
   950   
   951     show "a - b \<in> ?R"
   952     proof cases
   953       assume "Cb = {}" with Cb `a \<in> ?R` show ?thesis
   954         by simp
   955     next
   956       assume "Cb \<noteq> {}"
   957       with Ca Cb have "a - b = (\<Union>a'\<in>Ca. \<Inter>b'\<in>Cb. a' - b')" by auto
   958       also have "\<dots> \<in> ?R"
   959       proof (intro generated_ring_INTER generated_ring_disjoint_UNION)
   960         fix a b assume "a \<in> Ca" "b \<in> Cb"
   961         with Ca Cb Diff_cover[of a b] show "a - b \<in> ?R"
   962           by (auto simp add: generated_ring_def)
   963       next
   964         show "disjoint ((\<lambda>a'. \<Inter>b'\<in>Cb. a' - b')`Ca)"
   965           using Ca by (auto simp add: disjoint_def `Cb \<noteq> {}`)
   966       next
   967         show "finite Ca" "finite Cb" "Cb \<noteq> {}" by fact+
   968       qed
   969       finally show "a - b \<in> ?R" .
   970     qed }
   971   note Diff = this
   972 
   973   fix a b assume sets: "a \<in> ?R" "b \<in> ?R"
   974   have "a \<union> b = (a - b) \<union> (a \<inter> b) \<union> (b - a)" by auto
   975   also have "\<dots> \<in> ?R"
   976     by (intro sets generated_ring_disjoint_Un generated_ring_Int Diff) auto
   977   finally show "a \<union> b \<in> ?R" .
   978 qed
   979 
   980 lemma (in semiring_of_sets) sigma_sets_generated_ring_eq: "sigma_sets \<Omega> generated_ring = sigma_sets \<Omega> M"
   981 proof
   982   interpret M: sigma_algebra \<Omega> "sigma_sets \<Omega> M"
   983     using space_closed by (rule sigma_algebra_sigma_sets)
   984   show "sigma_sets \<Omega> generated_ring \<subseteq> sigma_sets \<Omega> M"
   985     by (blast intro!: sigma_sets_mono elim: generated_ringE)
   986 qed (auto intro!: generated_ringI_Basic sigma_sets_mono)
   987 
   988 section {* Measure type *}
   989 
   990 definition positive :: "'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> bool" where
   991   "positive M \<mu> \<longleftrightarrow> \<mu> {} = 0 \<and> (\<forall>A\<in>M. 0 \<le> \<mu> A)"
   992 
   993 definition countably_additive :: "'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> bool" where
   994   "countably_additive M f \<longleftrightarrow> (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow>
   995     (\<Sum>i. f (A i)) = f (\<Union>i. A i))"
   996 
   997 definition measure_space :: "'a set \<Rightarrow> 'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> bool" where
   998   "measure_space \<Omega> A \<mu> \<longleftrightarrow> sigma_algebra \<Omega> A \<and> positive A \<mu> \<and> countably_additive A \<mu>"
   999 
  1000 typedef 'a measure = "{(\<Omega>::'a set, A, \<mu>). (\<forall>a\<in>-A. \<mu> a = 0) \<and> measure_space \<Omega> A \<mu> }"
  1001 proof
  1002   have "sigma_algebra UNIV {{}, UNIV}"
  1003     by (auto simp: sigma_algebra_iff2)
  1004   then show "(UNIV, {{}, UNIV}, \<lambda>A. 0) \<in> {(\<Omega>, A, \<mu>). (\<forall>a\<in>-A. \<mu> a = 0) \<and> measure_space \<Omega> A \<mu>} "
  1005     by (auto simp: measure_space_def positive_def countably_additive_def)
  1006 qed
  1007 
  1008 definition space :: "'a measure \<Rightarrow> 'a set" where
  1009   "space M = fst (Rep_measure M)"
  1010 
  1011 definition sets :: "'a measure \<Rightarrow> 'a set set" where
  1012   "sets M = fst (snd (Rep_measure M))"
  1013 
  1014 definition emeasure :: "'a measure \<Rightarrow> 'a set \<Rightarrow> ereal" where
  1015   "emeasure M = snd (snd (Rep_measure M))"
  1016 
  1017 definition measure :: "'a measure \<Rightarrow> 'a set \<Rightarrow> real" where
  1018   "measure M A = real (emeasure M A)"
  1019 
  1020 declare [[coercion sets]]
  1021 
  1022 declare [[coercion measure]]
  1023 
  1024 declare [[coercion emeasure]]
  1025 
  1026 lemma measure_space: "measure_space (space M) (sets M) (emeasure M)"
  1027   by (cases M) (auto simp: space_def sets_def emeasure_def Abs_measure_inverse)
  1028 
  1029 interpretation sigma_algebra "space M" "sets M" for M :: "'a measure"
  1030   using measure_space[of M] by (auto simp: measure_space_def)
  1031 
  1032 definition measure_of :: "'a set \<Rightarrow> 'a set set \<Rightarrow> ('a set \<Rightarrow> ereal) \<Rightarrow> 'a measure" where
  1033   "measure_of \<Omega> A \<mu> = Abs_measure (\<Omega>, sigma_sets \<Omega> A,
  1034     \<lambda>a. if a \<in> sigma_sets \<Omega> A \<and> measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> then \<mu> a else 0)"
  1035 
  1036 abbreviation "sigma \<Omega> A \<equiv> measure_of \<Omega> A (\<lambda>x. 0)"
  1037 
  1038 lemma measure_space_0: "A \<subseteq> Pow \<Omega> \<Longrightarrow> measure_space \<Omega> (sigma_sets \<Omega> A) (\<lambda>x. 0)"
  1039   unfolding measure_space_def
  1040   by (auto intro!: sigma_algebra_sigma_sets simp: positive_def countably_additive_def)
  1041 
  1042 lemma (in ring_of_sets) positive_cong_eq:
  1043   "(\<And>a. a \<in> M \<Longrightarrow> \<mu>' a = \<mu> a) \<Longrightarrow> positive M \<mu>' = positive M \<mu>"
  1044   by (auto simp add: positive_def)
  1045 
  1046 lemma (in sigma_algebra) countably_additive_eq:
  1047   "(\<And>a. a \<in> M \<Longrightarrow> \<mu>' a = \<mu> a) \<Longrightarrow> countably_additive M \<mu>' = countably_additive M \<mu>"
  1048   unfolding countably_additive_def
  1049   by (intro arg_cong[where f=All] ext) (auto simp add: countably_additive_def subset_eq)
  1050 
  1051 lemma measure_space_eq:
  1052   assumes closed: "A \<subseteq> Pow \<Omega>" and eq: "\<And>a. a \<in> sigma_sets \<Omega> A \<Longrightarrow> \<mu> a = \<mu>' a"
  1053   shows "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> = measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>'"
  1054 proof -
  1055   interpret sigma_algebra \<Omega> "sigma_sets \<Omega> A" using closed by (rule sigma_algebra_sigma_sets)
  1056   from positive_cong_eq[OF eq, of "\<lambda>i. i"] countably_additive_eq[OF eq, of "\<lambda>i. i"] show ?thesis
  1057     by (auto simp: measure_space_def)
  1058 qed
  1059 
  1060 lemma measure_of_eq:
  1061   assumes closed: "A \<subseteq> Pow \<Omega>" and eq: "(\<And>a. a \<in> sigma_sets \<Omega> A \<Longrightarrow> \<mu> a = \<mu>' a)"
  1062   shows "measure_of \<Omega> A \<mu> = measure_of \<Omega> A \<mu>'"
  1063 proof -
  1064   have "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> = measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>'"
  1065     using assms by (rule measure_space_eq)
  1066   with eq show ?thesis
  1067     by (auto simp add: measure_of_def intro!: arg_cong[where f=Abs_measure])
  1068 qed
  1069 
  1070 lemma
  1071   assumes A: "A \<subseteq> Pow \<Omega>"
  1072   shows sets_measure_of[simp]: "sets (measure_of \<Omega> A \<mu>) = sigma_sets \<Omega> A" (is ?sets)
  1073     and space_measure_of[simp]: "space (measure_of \<Omega> A \<mu>) = \<Omega>" (is ?space)
  1074 proof -
  1075   have "?sets \<and> ?space"
  1076   proof cases
  1077     assume "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1078     moreover have "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu> = measure_space \<Omega> (sigma_sets \<Omega> A)
  1079        (\<lambda>a. if a \<in> sigma_sets \<Omega> A then \<mu> a else 0)"
  1080       using A by (rule measure_space_eq) auto
  1081     ultimately show "?sets \<and> ?space"
  1082       by (auto simp: Abs_measure_inverse measure_of_def sets_def space_def)
  1083   next
  1084     assume "\<not> measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1085     with A show "?sets \<and> ?space"
  1086       by (auto simp: Abs_measure_inverse measure_of_def sets_def space_def measure_space_0)
  1087   qed
  1088   then show ?sets ?space by auto
  1089 qed
  1090 
  1091 lemma (in sigma_algebra) sets_measure_of_eq[simp]:
  1092   "sets (measure_of \<Omega> M \<mu>) = M"
  1093   using space_closed by (auto intro!: sigma_sets_eq)
  1094 
  1095 lemma (in sigma_algebra) space_measure_of_eq[simp]:
  1096   "space (measure_of \<Omega> M \<mu>) = \<Omega>"
  1097   using space_closed by (auto intro!: sigma_sets_eq)
  1098 
  1099 lemma measure_of_subset:
  1100   "M \<subseteq> Pow \<Omega> \<Longrightarrow> M' \<subseteq> M \<Longrightarrow> sets (measure_of \<Omega> M' \<mu>) \<subseteq> sets (measure_of \<Omega> M \<mu>')"
  1101   by (auto intro!: sigma_sets_subseteq)
  1102 
  1103 lemma in_measure_of[intro, simp]: "M \<subseteq> Pow \<Omega> \<Longrightarrow> A \<in> M \<Longrightarrow> A \<in> sets (measure_of \<Omega> M \<mu>)"
  1104   by auto
  1105 
  1106 section {* Constructing simple @{typ "'a measure"} *}
  1107 
  1108 lemma emeasure_measure_of:
  1109   assumes M: "M = measure_of \<Omega> A \<mu>"
  1110   assumes ms: "A \<subseteq> Pow \<Omega>" "positive (sets M) \<mu>" "countably_additive (sets M) \<mu>"
  1111   assumes X: "X \<in> sets M"
  1112   shows "emeasure M X = \<mu> X"
  1113 proof -
  1114   interpret sigma_algebra \<Omega> "sigma_sets \<Omega> A" by (rule sigma_algebra_sigma_sets) fact
  1115   have "measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1116     using ms M by (simp add: measure_space_def sigma_algebra_sigma_sets)
  1117   moreover have "measure_space \<Omega> (sigma_sets \<Omega> A) (\<lambda>a. if a \<in> sigma_sets \<Omega> A then \<mu> a else 0)
  1118     = measure_space \<Omega> (sigma_sets \<Omega> A) \<mu>"
  1119     using ms(1) by (rule measure_space_eq) auto
  1120   moreover have "X \<in> sigma_sets \<Omega> A"
  1121     using X M ms by simp
  1122   ultimately show ?thesis
  1123     unfolding emeasure_def measure_of_def M
  1124     by (subst Abs_measure_inverse) (simp_all add: sigma_sets_eq)
  1125 qed
  1126 
  1127 lemma emeasure_measure_of_sigma:
  1128   assumes ms: "sigma_algebra \<Omega> M" "positive M \<mu>" "countably_additive M \<mu>"
  1129   assumes A: "A \<in> M"
  1130   shows "emeasure (measure_of \<Omega> M \<mu>) A = \<mu> A"
  1131 proof -
  1132   interpret sigma_algebra \<Omega> M by fact
  1133   have "measure_space \<Omega> (sigma_sets \<Omega> M) \<mu>"
  1134     using ms sigma_sets_eq by (simp add: measure_space_def)
  1135   moreover have "measure_space \<Omega> (sigma_sets \<Omega> M) (\<lambda>a. if a \<in> sigma_sets \<Omega> M then \<mu> a else 0)
  1136     = measure_space \<Omega> (sigma_sets \<Omega> M) \<mu>"
  1137     using space_closed by (rule measure_space_eq) auto
  1138   ultimately show ?thesis using A
  1139     unfolding emeasure_def measure_of_def
  1140     by (subst Abs_measure_inverse) (simp_all add: sigma_sets_eq)
  1141 qed
  1142 
  1143 lemma measure_cases[cases type: measure]:
  1144   obtains (measure) \<Omega> A \<mu> where "x = Abs_measure (\<Omega>, A, \<mu>)" "\<forall>a\<in>-A. \<mu> a = 0" "measure_space \<Omega> A \<mu>"
  1145   by atomize_elim (cases x, auto)
  1146 
  1147 lemma sets_eq_imp_space_eq:
  1148   "sets M = sets M' \<Longrightarrow> space M = space M'"
  1149   using top[of M] top[of M'] space_closed[of M] space_closed[of M']
  1150   by blast
  1151 
  1152 lemma emeasure_notin_sets: "A \<notin> sets M \<Longrightarrow> emeasure M A = 0"
  1153   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
  1154 
  1155 lemma measure_notin_sets: "A \<notin> sets M \<Longrightarrow> measure M A = 0"
  1156   by (simp add: measure_def emeasure_notin_sets)
  1157 
  1158 lemma measure_eqI:
  1159   fixes M N :: "'a measure"
  1160   assumes "sets M = sets N" and eq: "\<And>A. A \<in> sets M \<Longrightarrow> emeasure M A = emeasure N A"
  1161   shows "M = N"
  1162 proof (cases M N rule: measure_cases[case_product measure_cases])
  1163   case (measure_measure \<Omega> A \<mu> \<Omega>' A' \<mu>')
  1164   interpret M: sigma_algebra \<Omega> A using measure_measure by (auto simp: measure_space_def)
  1165   interpret N: sigma_algebra \<Omega>' A' using measure_measure by (auto simp: measure_space_def)
  1166   have "A = sets M" "A' = sets N"
  1167     using measure_measure by (simp_all add: sets_def Abs_measure_inverse)
  1168   with `sets M = sets N` have "A = A'" by simp
  1169   moreover with M.top N.top M.space_closed N.space_closed have "\<Omega> = \<Omega>'" by auto
  1170   moreover { fix B have "\<mu> B = \<mu>' B"
  1171     proof cases
  1172       assume "B \<in> A"
  1173       with eq `A = sets M` have "emeasure M B = emeasure N B" by simp
  1174       with measure_measure show "\<mu> B = \<mu>' B"
  1175         by (simp add: emeasure_def Abs_measure_inverse)
  1176     next
  1177       assume "B \<notin> A"
  1178       with `A = sets M` `A' = sets N` `A = A'` have "B \<notin> sets M" "B \<notin> sets N"
  1179         by auto
  1180       then have "emeasure M B = 0" "emeasure N B = 0"
  1181         by (simp_all add: emeasure_notin_sets)
  1182       with measure_measure show "\<mu> B = \<mu>' B"
  1183         by (simp add: emeasure_def Abs_measure_inverse)
  1184     qed }
  1185   then have "\<mu> = \<mu>'" by auto
  1186   ultimately show "M = N"
  1187     by (simp add: measure_measure)
  1188 qed
  1189 
  1190 lemma emeasure_sigma: "A \<subseteq> Pow \<Omega> \<Longrightarrow> emeasure (sigma \<Omega> A) = (\<lambda>_. 0)"
  1191   using measure_space_0[of A \<Omega>]
  1192   by (simp add: measure_of_def emeasure_def Abs_measure_inverse)
  1193 
  1194 lemma sigma_eqI:
  1195   assumes [simp]: "M \<subseteq> Pow \<Omega>" "N \<subseteq> Pow \<Omega>" "sigma_sets \<Omega> M = sigma_sets \<Omega> N"
  1196   shows "sigma \<Omega> M = sigma \<Omega> N"
  1197   by (rule measure_eqI) (simp_all add: emeasure_sigma)
  1198 
  1199 section {* Measurable functions *}
  1200 
  1201 definition measurable :: "'a measure \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) set" where
  1202   "measurable A B = {f \<in> space A -> space B. \<forall>y \<in> sets B. f -` y \<inter> space A \<in> sets A}"
  1203 
  1204 lemma measurable_space:
  1205   "f \<in> measurable M A \<Longrightarrow> x \<in> space M \<Longrightarrow> f x \<in> space A"
  1206    unfolding measurable_def by auto
  1207 
  1208 lemma measurable_sets:
  1209   "f \<in> measurable M A \<Longrightarrow> S \<in> sets A \<Longrightarrow> f -` S \<inter> space M \<in> sets M"
  1210    unfolding measurable_def by auto
  1211 
  1212 lemma measurable_sigma_sets:
  1213   assumes B: "sets N = sigma_sets \<Omega> A" "A \<subseteq> Pow \<Omega>"
  1214       and f: "f \<in> space M \<rightarrow> \<Omega>"
  1215       and ba: "\<And>y. y \<in> A \<Longrightarrow> (f -` y) \<inter> space M \<in> sets M"
  1216   shows "f \<in> measurable M N"
  1217 proof -
  1218   interpret A: sigma_algebra \<Omega> "sigma_sets \<Omega> A" using B(2) by (rule sigma_algebra_sigma_sets)
  1219   from B top[of N] A.top space_closed[of N] A.space_closed have \<Omega>: "\<Omega> = space N" by force
  1220   
  1221   { fix X assume "X \<in> sigma_sets \<Omega> A"
  1222     then have "f -` X \<inter> space M \<in> sets M \<and> X \<subseteq> \<Omega>"
  1223       proof induct
  1224         case (Basic a) then show ?case
  1225           by (auto simp add: ba) (metis B(2) subsetD PowD)
  1226       next
  1227         case (Compl a)
  1228         have [simp]: "f -` \<Omega> \<inter> space M = space M"
  1229           by (auto simp add: funcset_mem [OF f])
  1230         then show ?case
  1231           by (auto simp add: vimage_Diff Diff_Int_distrib2 compl_sets Compl)
  1232       next
  1233         case (Union a)
  1234         then show ?case
  1235           by (simp add: vimage_UN, simp only: UN_extend_simps(4)) blast
  1236       qed auto }
  1237   with f show ?thesis
  1238     by (auto simp add: measurable_def B \<Omega>)
  1239 qed
  1240 
  1241 lemma measurable_measure_of:
  1242   assumes B: "N \<subseteq> Pow \<Omega>"
  1243       and f: "f \<in> space M \<rightarrow> \<Omega>"
  1244       and ba: "\<And>y. y \<in> N \<Longrightarrow> (f -` y) \<inter> space M \<in> sets M"
  1245   shows "f \<in> measurable M (measure_of \<Omega> N \<mu>)"
  1246 proof -
  1247   have "sets (measure_of \<Omega> N \<mu>) = sigma_sets \<Omega> N"
  1248     using B by (rule sets_measure_of)
  1249   from this assms show ?thesis by (rule measurable_sigma_sets)
  1250 qed
  1251 
  1252 lemma measurable_iff_measure_of:
  1253   assumes "N \<subseteq> Pow \<Omega>" "f \<in> space M \<rightarrow> \<Omega>"
  1254   shows "f \<in> measurable M (measure_of \<Omega> N \<mu>) \<longleftrightarrow> (\<forall>A\<in>N. f -` A \<inter> space M \<in> sets M)"
  1255   by (metis assms in_measure_of measurable_measure_of assms measurable_sets)
  1256 
  1257 lemma measurable_cong:
  1258   assumes "\<And> w. w \<in> space M \<Longrightarrow> f w = g w"
  1259   shows "f \<in> measurable M M' \<longleftrightarrow> g \<in> measurable M M'"
  1260   unfolding measurable_def using assms
  1261   by (simp cong: vimage_inter_cong Pi_cong)
  1262 
  1263 lemma measurable_eqI:
  1264      "\<lbrakk> space m1 = space m1' ; space m2 = space m2' ;
  1265         sets m1 = sets m1' ; sets m2 = sets m2' \<rbrakk>
  1266       \<Longrightarrow> measurable m1 m2 = measurable m1' m2'"
  1267   by (simp add: measurable_def sigma_algebra_iff2)
  1268 
  1269 lemma measurable_const[intro, simp]:
  1270   "c \<in> space M' \<Longrightarrow> (\<lambda>x. c) \<in> measurable M M'"
  1271   by (auto simp add: measurable_def)
  1272 
  1273 lemma measurable_If:
  1274   assumes measure: "f \<in> measurable M M'" "g \<in> measurable M M'"
  1275   assumes P: "{x\<in>space M. P x} \<in> sets M"
  1276   shows "(\<lambda>x. if P x then f x else g x) \<in> measurable M M'"
  1277   unfolding measurable_def
  1278 proof safe
  1279   fix x assume "x \<in> space M"
  1280   thus "(if P x then f x else g x) \<in> space M'"
  1281     using measure unfolding measurable_def by auto
  1282 next
  1283   fix A assume "A \<in> sets M'"
  1284   hence *: "(\<lambda>x. if P x then f x else g x) -` A \<inter> space M =
  1285     ((f -` A \<inter> space M) \<inter> {x\<in>space M. P x}) \<union>
  1286     ((g -` A \<inter> space M) \<inter> (space M - {x\<in>space M. P x}))"
  1287     using measure unfolding measurable_def by (auto split: split_if_asm)
  1288   show "(\<lambda>x. if P x then f x else g x) -` A \<inter> space M \<in> sets M"
  1289     using `A \<in> sets M'` measure P unfolding * measurable_def
  1290     by (auto intro!: Un)
  1291 qed
  1292 
  1293 lemma measurable_If_set:
  1294   assumes measure: "f \<in> measurable M M'" "g \<in> measurable M M'"
  1295   assumes P: "A \<inter> space M \<in> sets M"
  1296   shows "(\<lambda>x. if x \<in> A then f x else g x) \<in> measurable M M'"
  1297 proof (rule measurable_If[OF measure])
  1298   have "{x \<in> space M. x \<in> A} = A \<inter> space M" by auto
  1299   thus "{x \<in> space M. x \<in> A} \<in> sets M" using `A \<inter> space M \<in> sets M` by auto
  1300 qed
  1301 
  1302 lemma measurable_ident[intro, simp]: "id \<in> measurable M M"
  1303   by (auto simp add: measurable_def)
  1304 
  1305 lemma measurable_comp[intro]:
  1306   fixes f :: "'a \<Rightarrow> 'b" and g :: "'b \<Rightarrow> 'c"
  1307   shows "f \<in> measurable a b \<Longrightarrow> g \<in> measurable b c \<Longrightarrow> (g o f) \<in> measurable a c"
  1308   apply (auto simp add: measurable_def vimage_compose)
  1309   apply (subgoal_tac "f -` g -` y \<inter> space a = f -` (g -` y \<inter> space b) \<inter> space a")
  1310   apply force+
  1311   done
  1312 
  1313 lemma measurable_compose:
  1314   "f \<in> measurable M N \<Longrightarrow> g \<in> measurable N L \<Longrightarrow> (\<lambda>x. g (f x)) \<in> measurable M L"
  1315   using measurable_comp[of f M N g L] by (simp add: comp_def)
  1316 
  1317 lemma measurable_Least:
  1318   assumes meas: "\<And>i::nat. {x\<in>space M. P i x} \<in> M"
  1319   shows "(\<lambda>x. LEAST j. P j x) -` A \<inter> space M \<in> sets M"
  1320 proof -
  1321   { fix i have "(\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M \<in> sets M"
  1322     proof cases
  1323       assume i: "(LEAST j. False) = i"
  1324       have "(\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M =
  1325         {x\<in>space M. P i x} \<inter> (space M - (\<Union>j<i. {x\<in>space M. P j x})) \<union> (space M - (\<Union>i. {x\<in>space M. P i x}))"
  1326         by (simp add: set_eq_iff, safe)
  1327            (insert i, auto dest: Least_le intro: LeastI intro!: Least_equality)
  1328       with meas show ?thesis
  1329         by (auto intro!: Int)
  1330     next
  1331       assume i: "(LEAST j. False) \<noteq> i"
  1332       then have "(\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M =
  1333         {x\<in>space M. P i x} \<inter> (space M - (\<Union>j<i. {x\<in>space M. P j x}))"
  1334       proof (simp add: set_eq_iff, safe)
  1335         fix x assume neq: "(LEAST j. False) \<noteq> (LEAST j. P j x)"
  1336         have "\<exists>j. P j x"
  1337           by (rule ccontr) (insert neq, auto)
  1338         then show "P (LEAST j. P j x) x" by (rule LeastI_ex)
  1339       qed (auto dest: Least_le intro!: Least_equality)
  1340       with meas show ?thesis
  1341         by auto
  1342     qed }
  1343   then have "(\<Union>i\<in>A. (\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M) \<in> sets M"
  1344     by (intro countable_UN) auto
  1345   moreover have "(\<Union>i\<in>A. (\<lambda>x. LEAST j. P j x) -` {i} \<inter> space M) =
  1346     (\<lambda>x. LEAST j. P j x) -` A \<inter> space M" by auto
  1347   ultimately show ?thesis by auto
  1348 qed
  1349 
  1350 lemma measurable_strong:
  1351   fixes f :: "'a \<Rightarrow> 'b" and g :: "'b \<Rightarrow> 'c"
  1352   assumes f: "f \<in> measurable a b" and g: "g \<in> space b \<rightarrow> space c"
  1353       and t: "f ` (space a) \<subseteq> t"
  1354       and cb: "\<And>s. s \<in> sets c \<Longrightarrow> (g -` s) \<inter> t \<in> sets b"
  1355   shows "(g o f) \<in> measurable a c"
  1356 proof -
  1357   have fab: "f \<in> (space a -> space b)"
  1358    and ba: "\<And>y. y \<in> sets b \<Longrightarrow> (f -` y) \<inter> (space a) \<in> sets a" using f
  1359      by (auto simp add: measurable_def)
  1360   have eq: "\<And>y. f -` g -` y \<inter> space a = f -` (g -` y \<inter> t) \<inter> space a" using t
  1361     by force
  1362   show ?thesis
  1363     apply (auto simp add: measurable_def vimage_compose)
  1364     apply (metis funcset_mem fab g)
  1365     apply (subst eq, metis ba cb)
  1366     done
  1367 qed
  1368 
  1369 lemma measurable_mono1:
  1370   "M' \<subseteq> Pow \<Omega> \<Longrightarrow> M \<subseteq> M' \<Longrightarrow>
  1371     measurable (measure_of \<Omega> M \<mu>) N \<subseteq> measurable (measure_of \<Omega> M' \<mu>') N"
  1372   using measure_of_subset[of M' \<Omega> M] by (auto simp add: measurable_def)
  1373 
  1374 subsection {* Extend measure *}
  1375 
  1376 definition "extend_measure \<Omega> I G \<mu> =
  1377   (if (\<exists>\<mu>'. (\<forall>i\<in>I. \<mu>' (G i) = \<mu> i) \<and> measure_space \<Omega> (sigma_sets \<Omega> (G`I)) \<mu>') \<and> \<not> (\<forall>i\<in>I. \<mu> i = 0)
  1378       then measure_of \<Omega> (G`I) (SOME \<mu>'. (\<forall>i\<in>I. \<mu>' (G i) = \<mu> i) \<and> measure_space \<Omega> (sigma_sets \<Omega> (G`I)) \<mu>')
  1379       else measure_of \<Omega> (G`I) (\<lambda>_. 0))"
  1380 
  1381 lemma space_extend_measure: "G ` I \<subseteq> Pow \<Omega> \<Longrightarrow> space (extend_measure \<Omega> I G \<mu>) = \<Omega>"
  1382   unfolding extend_measure_def by simp
  1383 
  1384 lemma sets_extend_measure: "G ` I \<subseteq> Pow \<Omega> \<Longrightarrow> sets (extend_measure \<Omega> I G \<mu>) = sigma_sets \<Omega> (G`I)"
  1385   unfolding extend_measure_def by simp
  1386 
  1387 lemma emeasure_extend_measure:
  1388   assumes M: "M = extend_measure \<Omega> I G \<mu>"
  1389     and eq: "\<And>i. i \<in> I \<Longrightarrow> \<mu>' (G i) = \<mu> i"
  1390     and ms: "G ` I \<subseteq> Pow \<Omega>" "positive (sets M) \<mu>'" "countably_additive (sets M) \<mu>'"
  1391     and "i \<in> I"
  1392   shows "emeasure M (G i) = \<mu> i"
  1393 proof cases
  1394   assume *: "(\<forall>i\<in>I. \<mu> i = 0)"
  1395   with M have M_eq: "M = measure_of \<Omega> (G`I) (\<lambda>_. 0)"
  1396    by (simp add: extend_measure_def)
  1397   from measure_space_0[OF ms(1)] ms `i\<in>I`
  1398   have "emeasure M (G i) = 0"
  1399     by (intro emeasure_measure_of[OF M_eq]) (auto simp add: M measure_space_def sets_extend_measure)
  1400   with `i\<in>I` * show ?thesis
  1401     by simp
  1402 next
  1403   def P \<equiv> "\<lambda>\<mu>'. (\<forall>i\<in>I. \<mu>' (G i) = \<mu> i) \<and> measure_space \<Omega> (sigma_sets \<Omega> (G`I)) \<mu>'"
  1404   assume "\<not> (\<forall>i\<in>I. \<mu> i = 0)"
  1405   moreover
  1406   have "measure_space (space M) (sets M) \<mu>'"
  1407     using ms unfolding measure_space_def by auto default
  1408   with ms eq have "\<exists>\<mu>'. P \<mu>'"
  1409     unfolding P_def
  1410     by (intro exI[of _ \<mu>']) (auto simp add: M space_extend_measure sets_extend_measure)
  1411   ultimately have M_eq: "M = measure_of \<Omega> (G`I) (Eps P)"
  1412     by (simp add: M extend_measure_def P_def[symmetric])
  1413 
  1414   from `\<exists>\<mu>'. P \<mu>'` have P: "P (Eps P)" by (rule someI_ex)
  1415   show "emeasure M (G i) = \<mu> i"
  1416   proof (subst emeasure_measure_of[OF M_eq])
  1417     have sets_M: "sets M = sigma_sets \<Omega> (G`I)"
  1418       using M_eq ms by (auto simp: sets_extend_measure)
  1419     then show "G i \<in> sets M" using `i \<in> I` by auto
  1420     show "positive (sets M) (Eps P)" "countably_additive (sets M) (Eps P)" "Eps P (G i) = \<mu> i"
  1421       using P `i\<in>I` by (auto simp add: sets_M measure_space_def P_def)
  1422   qed fact
  1423 qed
  1424 
  1425 lemma emeasure_extend_measure_Pair:
  1426   assumes M: "M = extend_measure \<Omega> {(i, j). I i j} (\<lambda>(i, j). G i j) (\<lambda>(i, j). \<mu> i j)"
  1427     and eq: "\<And>i j. I i j \<Longrightarrow> \<mu>' (G i j) = \<mu> i j"
  1428     and ms: "\<And>i j. I i j \<Longrightarrow> G i j \<in> Pow \<Omega>" "positive (sets M) \<mu>'" "countably_additive (sets M) \<mu>'"
  1429     and "I i j"
  1430   shows "emeasure M (G i j) = \<mu> i j"
  1431   using emeasure_extend_measure[OF M _ _ ms(2,3), of "(i,j)"] eq ms(1) `I i j`
  1432   by (auto simp: subset_eq)
  1433 
  1434 subsection {* Sigma algebra generated by function preimages *}
  1435 
  1436 definition
  1437   "vimage_algebra M S f = sigma S ((\<lambda>A. f -` A \<inter> S) ` sets M)"
  1438 
  1439 lemma sigma_algebra_preimages:
  1440   fixes f :: "'x \<Rightarrow> 'a"
  1441   assumes "f \<in> S \<rightarrow> space M"
  1442   shows "sigma_algebra S ((\<lambda>A. f -` A \<inter> S) ` sets M)"
  1443     (is "sigma_algebra _ (?F ` sets M)")
  1444 proof (simp add: sigma_algebra_iff2, safe)
  1445   show "{} \<in> ?F ` sets M" by blast
  1446 next
  1447   fix A assume "A \<in> sets M"
  1448   moreover have "S - ?F A = ?F (space M - A)"
  1449     using assms by auto
  1450   ultimately show "S - ?F A \<in> ?F ` sets M"
  1451     by blast
  1452 next
  1453   fix A :: "nat \<Rightarrow> 'x set" assume *: "range A \<subseteq> ?F ` M"
  1454   have "\<forall>i. \<exists>b. b \<in> M \<and> A i = ?F b"
  1455   proof safe
  1456     fix i
  1457     have "A i \<in> ?F ` M" using * by auto
  1458     then show "\<exists>b. b \<in> M \<and> A i = ?F b" by auto
  1459   qed
  1460   from choice[OF this] obtain b where b: "range b \<subseteq> M" "\<And>i. A i = ?F (b i)"
  1461     by auto
  1462   then have "(\<Union>i. A i) = ?F (\<Union>i. b i)" by auto
  1463   then show "(\<Union>i. A i) \<in> ?F ` M" using b(1) by blast
  1464 qed
  1465 
  1466 lemma sets_vimage_algebra[simp]:
  1467   "f \<in> S \<rightarrow> space M \<Longrightarrow> sets (vimage_algebra M S f) = (\<lambda>A. f -` A \<inter> S) ` sets M"
  1468   using sigma_algebra.sets_measure_of_eq[OF sigma_algebra_preimages, of f S M]
  1469   by (simp add: vimage_algebra_def)
  1470 
  1471 lemma space_vimage_algebra[simp]:
  1472   "f \<in> S \<rightarrow> space M \<Longrightarrow> space (vimage_algebra M S f) = S"
  1473   using sigma_algebra.space_measure_of_eq[OF sigma_algebra_preimages, of f S M]
  1474   by (simp add: vimage_algebra_def)
  1475 
  1476 lemma in_vimage_algebra[simp]:
  1477   "f \<in> S \<rightarrow> space M \<Longrightarrow> A \<in> sets (vimage_algebra M S f) \<longleftrightarrow> (\<exists>B\<in>sets M. A = f -` B \<inter> S)"
  1478   by (simp add: image_iff)
  1479 
  1480 lemma measurable_vimage_algebra:
  1481   fixes S :: "'c set" assumes "f \<in> S \<rightarrow> space M"
  1482   shows "f \<in> measurable (vimage_algebra M S f) M"
  1483   unfolding measurable_def using assms by force
  1484 
  1485 lemma measurable_vimage:
  1486   fixes g :: "'a \<Rightarrow> 'c" and f :: "'d \<Rightarrow> 'a"
  1487   assumes "g \<in> measurable M M2" "f \<in> S \<rightarrow> space M"
  1488   shows "(\<lambda>x. g (f x)) \<in> measurable (vimage_algebra M S f) M2"
  1489 proof -
  1490   note measurable_vimage_algebra[OF assms(2)]
  1491   from measurable_comp[OF this assms(1)]
  1492   show ?thesis by (simp add: comp_def)
  1493 qed
  1494 
  1495 lemma sigma_sets_vimage:
  1496   assumes "f \<in> S' \<rightarrow> S" and "A \<subseteq> Pow S"
  1497   shows "sigma_sets S' ((\<lambda>X. f -` X \<inter> S') ` A) = (\<lambda>X. f -` X \<inter> S') ` sigma_sets S A"
  1498 proof (intro set_eqI iffI)
  1499   let ?F = "\<lambda>X. f -` X \<inter> S'"
  1500   fix X assume "X \<in> sigma_sets S' (?F ` A)"
  1501   then show "X \<in> ?F ` sigma_sets S A"
  1502   proof induct
  1503     case (Basic X) then obtain X' where "X = ?F X'" "X' \<in> A"
  1504       by auto
  1505     then show ?case by auto
  1506   next
  1507     case Empty then show ?case
  1508       by (auto intro!: image_eqI[of _ _ "{}"] sigma_sets.Empty)
  1509   next
  1510     case (Compl X) then obtain X' where X: "X = ?F X'" and "X' \<in> sigma_sets S A"
  1511       by auto
  1512     then have "S - X' \<in> sigma_sets S A"
  1513       by (auto intro!: sigma_sets.Compl)
  1514     then show ?case
  1515       using X assms by (auto intro!: image_eqI[where x="S - X'"])
  1516   next
  1517     case (Union F)
  1518     then have "\<forall>i. \<exists>F'.  F' \<in> sigma_sets S A \<and> F i = f -` F' \<inter> S'"
  1519       by (auto simp: image_iff Bex_def)
  1520     from choice[OF this] obtain F' where
  1521       "\<And>i. F' i \<in> sigma_sets S A" and "\<And>i. F i = f -` F' i \<inter> S'"
  1522       by auto
  1523     then show ?case
  1524       by (auto intro!: sigma_sets.Union image_eqI[where x="\<Union>i. F' i"])
  1525   qed
  1526 next
  1527   let ?F = "\<lambda>X. f -` X \<inter> S'"
  1528   fix X assume "X \<in> ?F ` sigma_sets S A"
  1529   then obtain X' where "X' \<in> sigma_sets S A" "X = ?F X'" by auto
  1530   then show "X \<in> sigma_sets S' (?F ` A)"
  1531   proof (induct arbitrary: X)
  1532     case Empty then show ?case by (auto intro: sigma_sets.Empty)
  1533   next
  1534     case (Compl X')
  1535     have "S' - (S' - X) \<in> sigma_sets S' (?F ` A)"
  1536       apply (rule sigma_sets.Compl)
  1537       using assms by (auto intro!: Compl.hyps simp: Compl.prems)
  1538     also have "S' - (S' - X) = X"
  1539       using assms Compl by auto
  1540     finally show ?case .
  1541   next
  1542     case (Union F)
  1543     have "(\<Union>i. f -` F i \<inter> S') \<in> sigma_sets S' (?F ` A)"
  1544       by (intro sigma_sets.Union Union.hyps) simp
  1545     also have "(\<Union>i. f -` F i \<inter> S') = X"
  1546       using assms Union by auto
  1547     finally show ?case .
  1548   qed auto
  1549 qed
  1550 
  1551 subsection {* A Two-Element Series *}
  1552 
  1553 definition binaryset :: "'a set \<Rightarrow> 'a set \<Rightarrow> nat \<Rightarrow> 'a set "
  1554   where "binaryset A B = (\<lambda>\<^isup>x. {})(0 := A, Suc 0 := B)"
  1555 
  1556 lemma range_binaryset_eq: "range(binaryset A B) = {A,B,{}}"
  1557   apply (simp add: binaryset_def)
  1558   apply (rule set_eqI)
  1559   apply (auto simp add: image_iff)
  1560   done
  1561 
  1562 lemma UN_binaryset_eq: "(\<Union>i. binaryset A B i) = A \<union> B"
  1563   by (simp add: SUP_def range_binaryset_eq)
  1564 
  1565 section {* Closed CDI *}
  1566 
  1567 definition closed_cdi where
  1568   "closed_cdi \<Omega> M \<longleftrightarrow>
  1569    M \<subseteq> Pow \<Omega> &
  1570    (\<forall>s \<in> M. \<Omega> - s \<in> M) &
  1571    (\<forall>A. (range A \<subseteq> M) & (A 0 = {}) & (\<forall>n. A n \<subseteq> A (Suc n)) \<longrightarrow>
  1572         (\<Union>i. A i) \<in> M) &
  1573    (\<forall>A. (range A \<subseteq> M) & disjoint_family A \<longrightarrow> (\<Union>i::nat. A i) \<in> M)"
  1574 
  1575 inductive_set
  1576   smallest_ccdi_sets :: "'a set \<Rightarrow> 'a set set \<Rightarrow> 'a set set"
  1577   for \<Omega> M
  1578   where
  1579     Basic [intro]:
  1580       "a \<in> M \<Longrightarrow> a \<in> smallest_ccdi_sets \<Omega> M"
  1581   | Compl [intro]:
  1582       "a \<in> smallest_ccdi_sets \<Omega> M \<Longrightarrow> \<Omega> - a \<in> smallest_ccdi_sets \<Omega> M"
  1583   | Inc:
  1584       "range A \<in> Pow(smallest_ccdi_sets \<Omega> M) \<Longrightarrow> A 0 = {} \<Longrightarrow> (\<And>n. A n \<subseteq> A (Suc n))
  1585        \<Longrightarrow> (\<Union>i. A i) \<in> smallest_ccdi_sets \<Omega> M"
  1586   | Disj:
  1587       "range A \<in> Pow(smallest_ccdi_sets \<Omega> M) \<Longrightarrow> disjoint_family A
  1588        \<Longrightarrow> (\<Union>i::nat. A i) \<in> smallest_ccdi_sets \<Omega> M"
  1589 
  1590 lemma (in subset_class) smallest_closed_cdi1: "M \<subseteq> smallest_ccdi_sets \<Omega> M"
  1591   by auto
  1592 
  1593 lemma (in subset_class) smallest_ccdi_sets: "smallest_ccdi_sets \<Omega> M \<subseteq> Pow \<Omega>"
  1594   apply (rule subsetI)
  1595   apply (erule smallest_ccdi_sets.induct)
  1596   apply (auto intro: range_subsetD dest: sets_into_space)
  1597   done
  1598 
  1599 lemma (in subset_class) smallest_closed_cdi2: "closed_cdi \<Omega> (smallest_ccdi_sets \<Omega> M)"
  1600   apply (auto simp add: closed_cdi_def smallest_ccdi_sets)
  1601   apply (blast intro: smallest_ccdi_sets.Inc smallest_ccdi_sets.Disj) +
  1602   done
  1603 
  1604 lemma closed_cdi_subset: "closed_cdi \<Omega> M \<Longrightarrow> M \<subseteq> Pow \<Omega>"
  1605   by (simp add: closed_cdi_def)
  1606 
  1607 lemma closed_cdi_Compl: "closed_cdi \<Omega> M \<Longrightarrow> s \<in> M \<Longrightarrow> \<Omega> - s \<in> M"
  1608   by (simp add: closed_cdi_def)
  1609 
  1610 lemma closed_cdi_Inc:
  1611   "closed_cdi \<Omega> M \<Longrightarrow> range A \<subseteq> M \<Longrightarrow> A 0 = {} \<Longrightarrow> (!!n. A n \<subseteq> A (Suc n)) \<Longrightarrow> (\<Union>i. A i) \<in> M"
  1612   by (simp add: closed_cdi_def)
  1613 
  1614 lemma closed_cdi_Disj:
  1615   "closed_cdi \<Omega> M \<Longrightarrow> range A \<subseteq> M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  1616   by (simp add: closed_cdi_def)
  1617 
  1618 lemma closed_cdi_Un:
  1619   assumes cdi: "closed_cdi \<Omega> M" and empty: "{} \<in> M"
  1620       and A: "A \<in> M" and B: "B \<in> M"
  1621       and disj: "A \<inter> B = {}"
  1622     shows "A \<union> B \<in> M"
  1623 proof -
  1624   have ra: "range (binaryset A B) \<subseteq> M"
  1625    by (simp add: range_binaryset_eq empty A B)
  1626  have di:  "disjoint_family (binaryset A B)" using disj
  1627    by (simp add: disjoint_family_on_def binaryset_def Int_commute)
  1628  from closed_cdi_Disj [OF cdi ra di]
  1629  show ?thesis
  1630    by (simp add: UN_binaryset_eq)
  1631 qed
  1632 
  1633 lemma (in algebra) smallest_ccdi_sets_Un:
  1634   assumes A: "A \<in> smallest_ccdi_sets \<Omega> M" and B: "B \<in> smallest_ccdi_sets \<Omega> M"
  1635       and disj: "A \<inter> B = {}"
  1636     shows "A \<union> B \<in> smallest_ccdi_sets \<Omega> M"
  1637 proof -
  1638   have ra: "range (binaryset A B) \<in> Pow (smallest_ccdi_sets \<Omega> M)"
  1639     by (simp add: range_binaryset_eq  A B smallest_ccdi_sets.Basic)
  1640   have di:  "disjoint_family (binaryset A B)" using disj
  1641     by (simp add: disjoint_family_on_def binaryset_def Int_commute)
  1642   from Disj [OF ra di]
  1643   show ?thesis
  1644     by (simp add: UN_binaryset_eq)
  1645 qed
  1646 
  1647 lemma (in algebra) smallest_ccdi_sets_Int1:
  1648   assumes a: "a \<in> M"
  1649   shows "b \<in> smallest_ccdi_sets \<Omega> M \<Longrightarrow> a \<inter> b \<in> smallest_ccdi_sets \<Omega> M"
  1650 proof (induct rule: smallest_ccdi_sets.induct)
  1651   case (Basic x)
  1652   thus ?case
  1653     by (metis a Int smallest_ccdi_sets.Basic)
  1654 next
  1655   case (Compl x)
  1656   have "a \<inter> (\<Omega> - x) = \<Omega> - ((\<Omega> - a) \<union> (a \<inter> x))"
  1657     by blast
  1658   also have "... \<in> smallest_ccdi_sets \<Omega> M"
  1659     by (metis smallest_ccdi_sets.Compl a Compl(2) Diff_Int2 Diff_Int_distrib2
  1660            Diff_disjoint Int_Diff Int_empty_right smallest_ccdi_sets_Un
  1661            smallest_ccdi_sets.Basic smallest_ccdi_sets.Compl)
  1662   finally show ?case .
  1663 next
  1664   case (Inc A)
  1665   have 1: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) = a \<inter> (\<Union>i. A i)"
  1666     by blast
  1667   have "range (\<lambda>i. a \<inter> A i) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Inc
  1668     by blast
  1669   moreover have "(\<lambda>i. a \<inter> A i) 0 = {}"
  1670     by (simp add: Inc)
  1671   moreover have "!!n. (\<lambda>i. a \<inter> A i) n \<subseteq> (\<lambda>i. a \<inter> A i) (Suc n)" using Inc
  1672     by blast
  1673   ultimately have 2: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) \<in> smallest_ccdi_sets \<Omega> M"
  1674     by (rule smallest_ccdi_sets.Inc)
  1675   show ?case
  1676     by (metis 1 2)
  1677 next
  1678   case (Disj A)
  1679   have 1: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) = a \<inter> (\<Union>i. A i)"
  1680     by blast
  1681   have "range (\<lambda>i. a \<inter> A i) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Disj
  1682     by blast
  1683   moreover have "disjoint_family (\<lambda>i. a \<inter> A i)" using Disj
  1684     by (auto simp add: disjoint_family_on_def)
  1685   ultimately have 2: "(\<Union>i. (\<lambda>i. a \<inter> A i) i) \<in> smallest_ccdi_sets \<Omega> M"
  1686     by (rule smallest_ccdi_sets.Disj)
  1687   show ?case
  1688     by (metis 1 2)
  1689 qed
  1690 
  1691 
  1692 lemma (in algebra) smallest_ccdi_sets_Int:
  1693   assumes b: "b \<in> smallest_ccdi_sets \<Omega> M"
  1694   shows "a \<in> smallest_ccdi_sets \<Omega> M \<Longrightarrow> a \<inter> b \<in> smallest_ccdi_sets \<Omega> M"
  1695 proof (induct rule: smallest_ccdi_sets.induct)
  1696   case (Basic x)
  1697   thus ?case
  1698     by (metis b smallest_ccdi_sets_Int1)
  1699 next
  1700   case (Compl x)
  1701   have "(\<Omega> - x) \<inter> b = \<Omega> - (x \<inter> b \<union> (\<Omega> - b))"
  1702     by blast
  1703   also have "... \<in> smallest_ccdi_sets \<Omega> M"
  1704     by (metis Compl(2) Diff_disjoint Int_Diff Int_commute Int_empty_right b
  1705            smallest_ccdi_sets.Compl smallest_ccdi_sets_Un)
  1706   finally show ?case .
  1707 next
  1708   case (Inc A)
  1709   have 1: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) = (\<Union>i. A i) \<inter> b"
  1710     by blast
  1711   have "range (\<lambda>i. A i \<inter> b) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Inc
  1712     by blast
  1713   moreover have "(\<lambda>i. A i \<inter> b) 0 = {}"
  1714     by (simp add: Inc)
  1715   moreover have "!!n. (\<lambda>i. A i \<inter> b) n \<subseteq> (\<lambda>i. A i \<inter> b) (Suc n)" using Inc
  1716     by blast
  1717   ultimately have 2: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) \<in> smallest_ccdi_sets \<Omega> M"
  1718     by (rule smallest_ccdi_sets.Inc)
  1719   show ?case
  1720     by (metis 1 2)
  1721 next
  1722   case (Disj A)
  1723   have 1: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) = (\<Union>i. A i) \<inter> b"
  1724     by blast
  1725   have "range (\<lambda>i. A i \<inter> b) \<in> Pow(smallest_ccdi_sets \<Omega> M)" using Disj
  1726     by blast
  1727   moreover have "disjoint_family (\<lambda>i. A i \<inter> b)" using Disj
  1728     by (auto simp add: disjoint_family_on_def)
  1729   ultimately have 2: "(\<Union>i. (\<lambda>i. A i \<inter> b) i) \<in> smallest_ccdi_sets \<Omega> M"
  1730     by (rule smallest_ccdi_sets.Disj)
  1731   show ?case
  1732     by (metis 1 2)
  1733 qed
  1734 
  1735 lemma (in algebra) sigma_property_disjoint_lemma:
  1736   assumes sbC: "M \<subseteq> C"
  1737       and ccdi: "closed_cdi \<Omega> C"
  1738   shows "sigma_sets \<Omega> M \<subseteq> C"
  1739 proof -
  1740   have "smallest_ccdi_sets \<Omega> M \<in> {B . M \<subseteq> B \<and> sigma_algebra \<Omega> B}"
  1741     apply (auto simp add: sigma_algebra_disjoint_iff algebra_iff_Int
  1742             smallest_ccdi_sets_Int)
  1743     apply (metis Union_Pow_eq Union_upper subsetD smallest_ccdi_sets)
  1744     apply (blast intro: smallest_ccdi_sets.Disj)
  1745     done
  1746   hence "sigma_sets (\<Omega>) (M) \<subseteq> smallest_ccdi_sets \<Omega> M"
  1747     by clarsimp
  1748        (drule sigma_algebra.sigma_sets_subset [where a="M"], auto)
  1749   also have "...  \<subseteq> C"
  1750     proof
  1751       fix x
  1752       assume x: "x \<in> smallest_ccdi_sets \<Omega> M"
  1753       thus "x \<in> C"
  1754         proof (induct rule: smallest_ccdi_sets.induct)
  1755           case (Basic x)
  1756           thus ?case
  1757             by (metis Basic subsetD sbC)
  1758         next
  1759           case (Compl x)
  1760           thus ?case
  1761             by (blast intro: closed_cdi_Compl [OF ccdi, simplified])
  1762         next
  1763           case (Inc A)
  1764           thus ?case
  1765                by (auto intro: closed_cdi_Inc [OF ccdi, simplified])
  1766         next
  1767           case (Disj A)
  1768           thus ?case
  1769                by (auto intro: closed_cdi_Disj [OF ccdi, simplified])
  1770         qed
  1771     qed
  1772   finally show ?thesis .
  1773 qed
  1774 
  1775 lemma (in algebra) sigma_property_disjoint:
  1776   assumes sbC: "M \<subseteq> C"
  1777       and compl: "!!s. s \<in> C \<inter> sigma_sets (\<Omega>) (M) \<Longrightarrow> \<Omega> - s \<in> C"
  1778       and inc: "!!A. range A \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)
  1779                      \<Longrightarrow> A 0 = {} \<Longrightarrow> (!!n. A n \<subseteq> A (Suc n))
  1780                      \<Longrightarrow> (\<Union>i. A i) \<in> C"
  1781       and disj: "!!A. range A \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)
  1782                       \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i::nat. A i) \<in> C"
  1783   shows "sigma_sets (\<Omega>) (M) \<subseteq> C"
  1784 proof -
  1785   have "sigma_sets (\<Omega>) (M) \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)"
  1786     proof (rule sigma_property_disjoint_lemma)
  1787       show "M \<subseteq> C \<inter> sigma_sets (\<Omega>) (M)"
  1788         by (metis Int_greatest Set.subsetI sbC sigma_sets.Basic)
  1789     next
  1790       show "closed_cdi \<Omega> (C \<inter> sigma_sets (\<Omega>) (M))"
  1791         by (simp add: closed_cdi_def compl inc disj)
  1792            (metis PowI Set.subsetI le_infI2 sigma_sets_into_sp space_closed
  1793              IntE sigma_sets.Compl range_subsetD sigma_sets.Union)
  1794     qed
  1795   thus ?thesis
  1796     by blast
  1797 qed
  1798 
  1799 section {* Dynkin systems *}
  1800 
  1801 locale dynkin_system = subset_class +
  1802   assumes space: "\<Omega> \<in> M"
  1803     and   compl[intro!]: "\<And>A. A \<in> M \<Longrightarrow> \<Omega> - A \<in> M"
  1804     and   UN[intro!]: "\<And>A. disjoint_family A \<Longrightarrow> range A \<subseteq> M
  1805                            \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  1806 
  1807 lemma (in dynkin_system) empty[intro, simp]: "{} \<in> M"
  1808   using space compl[of "\<Omega>"] by simp
  1809 
  1810 lemma (in dynkin_system) diff:
  1811   assumes sets: "D \<in> M" "E \<in> M" and "D \<subseteq> E"
  1812   shows "E - D \<in> M"
  1813 proof -
  1814   let ?f = "\<lambda>x. if x = 0 then D else if x = Suc 0 then \<Omega> - E else {}"
  1815   have "range ?f = {D, \<Omega> - E, {}}"
  1816     by (auto simp: image_iff)
  1817   moreover have "D \<union> (\<Omega> - E) = (\<Union>i. ?f i)"
  1818     by (auto simp: image_iff split: split_if_asm)
  1819   moreover
  1820   then have "disjoint_family ?f" unfolding disjoint_family_on_def
  1821     using `D \<in> M`[THEN sets_into_space] `D \<subseteq> E` by auto
  1822   ultimately have "\<Omega> - (D \<union> (\<Omega> - E)) \<in> M"
  1823     using sets by auto
  1824   also have "\<Omega> - (D \<union> (\<Omega> - E)) = E - D"
  1825     using assms sets_into_space by auto
  1826   finally show ?thesis .
  1827 qed
  1828 
  1829 lemma dynkin_systemI:
  1830   assumes "\<And> A. A \<in> M \<Longrightarrow> A \<subseteq> \<Omega>" "\<Omega> \<in> M"
  1831   assumes "\<And> A. A \<in> M \<Longrightarrow> \<Omega> - A \<in> M"
  1832   assumes "\<And> A. disjoint_family A \<Longrightarrow> range A \<subseteq> M
  1833           \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  1834   shows "dynkin_system \<Omega> M"
  1835   using assms by (auto simp: dynkin_system_def dynkin_system_axioms_def subset_class_def)
  1836 
  1837 lemma dynkin_systemI':
  1838   assumes 1: "\<And> A. A \<in> M \<Longrightarrow> A \<subseteq> \<Omega>"
  1839   assumes empty: "{} \<in> M"
  1840   assumes Diff: "\<And> A. A \<in> M \<Longrightarrow> \<Omega> - A \<in> M"
  1841   assumes 2: "\<And> A. disjoint_family A \<Longrightarrow> range A \<subseteq> M
  1842           \<Longrightarrow> (\<Union>i::nat. A i) \<in> M"
  1843   shows "dynkin_system \<Omega> M"
  1844 proof -
  1845   from Diff[OF empty] have "\<Omega> \<in> M" by auto
  1846   from 1 this Diff 2 show ?thesis
  1847     by (intro dynkin_systemI) auto
  1848 qed
  1849 
  1850 lemma dynkin_system_trivial:
  1851   shows "dynkin_system A (Pow A)"
  1852   by (rule dynkin_systemI) auto
  1853 
  1854 lemma sigma_algebra_imp_dynkin_system:
  1855   assumes "sigma_algebra \<Omega> M" shows "dynkin_system \<Omega> M"
  1856 proof -
  1857   interpret sigma_algebra \<Omega> M by fact
  1858   show ?thesis using sets_into_space by (fastforce intro!: dynkin_systemI)
  1859 qed
  1860 
  1861 subsection "Intersection stable algebras"
  1862 
  1863 definition "Int_stable M \<longleftrightarrow> (\<forall> a \<in> M. \<forall> b \<in> M. a \<inter> b \<in> M)"
  1864 
  1865 lemma (in algebra) Int_stable: "Int_stable M"
  1866   unfolding Int_stable_def by auto
  1867 
  1868 lemma Int_stableI:
  1869   "(\<And>a b. a \<in> A \<Longrightarrow> b \<in> A \<Longrightarrow> a \<inter> b \<in> A) \<Longrightarrow> Int_stable A"
  1870   unfolding Int_stable_def by auto
  1871 
  1872 lemma Int_stableD:
  1873   "Int_stable M \<Longrightarrow> a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<inter> b \<in> M"
  1874   unfolding Int_stable_def by auto
  1875 
  1876 lemma (in dynkin_system) sigma_algebra_eq_Int_stable:
  1877   "sigma_algebra \<Omega> M \<longleftrightarrow> Int_stable M"
  1878 proof
  1879   assume "sigma_algebra \<Omega> M" then show "Int_stable M"
  1880     unfolding sigma_algebra_def using algebra.Int_stable by auto
  1881 next
  1882   assume "Int_stable M"
  1883   show "sigma_algebra \<Omega> M"
  1884     unfolding sigma_algebra_disjoint_iff algebra_iff_Un
  1885   proof (intro conjI ballI allI impI)
  1886     show "M \<subseteq> Pow (\<Omega>)" using sets_into_space by auto
  1887   next
  1888     fix A B assume "A \<in> M" "B \<in> M"
  1889     then have "A \<union> B = \<Omega> - ((\<Omega> - A) \<inter> (\<Omega> - B))"
  1890               "\<Omega> - A \<in> M" "\<Omega> - B \<in> M"
  1891       using sets_into_space by auto
  1892     then show "A \<union> B \<in> M"
  1893       using `Int_stable M` unfolding Int_stable_def by auto
  1894   qed auto
  1895 qed
  1896 
  1897 subsection "Smallest Dynkin systems"
  1898 
  1899 definition dynkin where
  1900   "dynkin \<Omega> M =  (\<Inter>{D. dynkin_system \<Omega> D \<and> M \<subseteq> D})"
  1901 
  1902 lemma dynkin_system_dynkin:
  1903   assumes "M \<subseteq> Pow (\<Omega>)"
  1904   shows "dynkin_system \<Omega> (dynkin \<Omega> M)"
  1905 proof (rule dynkin_systemI)
  1906   fix A assume "A \<in> dynkin \<Omega> M"
  1907   moreover
  1908   { fix D assume "A \<in> D" and d: "dynkin_system \<Omega> D"
  1909     then have "A \<subseteq> \<Omega>" by (auto simp: dynkin_system_def subset_class_def) }
  1910   moreover have "{D. dynkin_system \<Omega> D \<and> M \<subseteq> D} \<noteq> {}"
  1911     using assms dynkin_system_trivial by fastforce
  1912   ultimately show "A \<subseteq> \<Omega>"
  1913     unfolding dynkin_def using assms
  1914     by auto
  1915 next
  1916   show "\<Omega> \<in> dynkin \<Omega> M"
  1917     unfolding dynkin_def using dynkin_system.space by fastforce
  1918 next
  1919   fix A assume "A \<in> dynkin \<Omega> M"
  1920   then show "\<Omega> - A \<in> dynkin \<Omega> M"
  1921     unfolding dynkin_def using dynkin_system.compl by force
  1922 next
  1923   fix A :: "nat \<Rightarrow> 'a set"
  1924   assume A: "disjoint_family A" "range A \<subseteq> dynkin \<Omega> M"
  1925   show "(\<Union>i. A i) \<in> dynkin \<Omega> M" unfolding dynkin_def
  1926   proof (simp, safe)
  1927     fix D assume "dynkin_system \<Omega> D" "M \<subseteq> D"
  1928     with A have "(\<Union>i. A i) \<in> D"
  1929       by (intro dynkin_system.UN) (auto simp: dynkin_def)
  1930     then show "(\<Union>i. A i) \<in> D" by auto
  1931   qed
  1932 qed
  1933 
  1934 lemma dynkin_Basic[intro]: "A \<in> M \<Longrightarrow> A \<in> dynkin \<Omega> M"
  1935   unfolding dynkin_def by auto
  1936 
  1937 lemma (in dynkin_system) restricted_dynkin_system:
  1938   assumes "D \<in> M"
  1939   shows "dynkin_system \<Omega> {Q. Q \<subseteq> \<Omega> \<and> Q \<inter> D \<in> M}"
  1940 proof (rule dynkin_systemI, simp_all)
  1941   have "\<Omega> \<inter> D = D"
  1942     using `D \<in> M` sets_into_space by auto
  1943   then show "\<Omega> \<inter> D \<in> M"
  1944     using `D \<in> M` by auto
  1945 next
  1946   fix A assume "A \<subseteq> \<Omega> \<and> A \<inter> D \<in> M"
  1947   moreover have "(\<Omega> - A) \<inter> D = (\<Omega> - (A \<inter> D)) - (\<Omega> - D)"
  1948     by auto
  1949   ultimately show "\<Omega> - A \<subseteq> \<Omega> \<and> (\<Omega> - A) \<inter> D \<in> M"
  1950     using  `D \<in> M` by (auto intro: diff)
  1951 next
  1952   fix A :: "nat \<Rightarrow> 'a set"
  1953   assume "disjoint_family A" "range A \<subseteq> {Q. Q \<subseteq> \<Omega> \<and> Q \<inter> D \<in> M}"
  1954   then have "\<And>i. A i \<subseteq> \<Omega>" "disjoint_family (\<lambda>i. A i \<inter> D)"
  1955     "range (\<lambda>i. A i \<inter> D) \<subseteq> M" "(\<Union>x. A x) \<inter> D = (\<Union>x. A x \<inter> D)"
  1956     by ((fastforce simp: disjoint_family_on_def)+)
  1957   then show "(\<Union>x. A x) \<subseteq> \<Omega> \<and> (\<Union>x. A x) \<inter> D \<in> M"
  1958     by (auto simp del: UN_simps)
  1959 qed
  1960 
  1961 lemma (in dynkin_system) dynkin_subset:
  1962   assumes "N \<subseteq> M"
  1963   shows "dynkin \<Omega> N \<subseteq> M"
  1964 proof -
  1965   have "dynkin_system \<Omega> M" by default
  1966   then have "dynkin_system \<Omega> M"
  1967     using assms unfolding dynkin_system_def dynkin_system_axioms_def subset_class_def by simp
  1968   with `N \<subseteq> M` show ?thesis by (auto simp add: dynkin_def)
  1969 qed
  1970 
  1971 lemma sigma_eq_dynkin:
  1972   assumes sets: "M \<subseteq> Pow \<Omega>"
  1973   assumes "Int_stable M"
  1974   shows "sigma_sets \<Omega> M = dynkin \<Omega> M"
  1975 proof -
  1976   have "dynkin \<Omega> M \<subseteq> sigma_sets (\<Omega>) (M)"
  1977     using sigma_algebra_imp_dynkin_system
  1978     unfolding dynkin_def sigma_sets_least_sigma_algebra[OF sets] by auto
  1979   moreover
  1980   interpret dynkin_system \<Omega> "dynkin \<Omega> M"
  1981     using dynkin_system_dynkin[OF sets] .
  1982   have "sigma_algebra \<Omega> (dynkin \<Omega> M)"
  1983     unfolding sigma_algebra_eq_Int_stable Int_stable_def
  1984   proof (intro ballI)
  1985     fix A B assume "A \<in> dynkin \<Omega> M" "B \<in> dynkin \<Omega> M"
  1986     let ?D = "\<lambda>E. {Q. Q \<subseteq> \<Omega> \<and> Q \<inter> E \<in> dynkin \<Omega> M}"
  1987     have "M \<subseteq> ?D B"
  1988     proof
  1989       fix E assume "E \<in> M"
  1990       then have "M \<subseteq> ?D E" "E \<in> dynkin \<Omega> M"
  1991         using sets_into_space `Int_stable M` by (auto simp: Int_stable_def)
  1992       then have "dynkin \<Omega> M \<subseteq> ?D E"
  1993         using restricted_dynkin_system `E \<in> dynkin \<Omega> M`
  1994         by (intro dynkin_system.dynkin_subset) simp_all
  1995       then have "B \<in> ?D E"
  1996         using `B \<in> dynkin \<Omega> M` by auto
  1997       then have "E \<inter> B \<in> dynkin \<Omega> M"
  1998         by (subst Int_commute) simp
  1999       then show "E \<in> ?D B"
  2000         using sets `E \<in> M` by auto
  2001     qed
  2002     then have "dynkin \<Omega> M \<subseteq> ?D B"
  2003       using restricted_dynkin_system `B \<in> dynkin \<Omega> M`
  2004       by (intro dynkin_system.dynkin_subset) simp_all
  2005     then show "A \<inter> B \<in> dynkin \<Omega> M"
  2006       using `A \<in> dynkin \<Omega> M` sets_into_space by auto
  2007   qed
  2008   from sigma_algebra.sigma_sets_subset[OF this, of "M"]
  2009   have "sigma_sets (\<Omega>) (M) \<subseteq> dynkin \<Omega> M" by auto
  2010   ultimately have "sigma_sets (\<Omega>) (M) = dynkin \<Omega> M" by auto
  2011   then show ?thesis
  2012     by (auto simp: dynkin_def)
  2013 qed
  2014 
  2015 lemma (in dynkin_system) dynkin_idem:
  2016   "dynkin \<Omega> M = M"
  2017 proof -
  2018   have "dynkin \<Omega> M = M"
  2019   proof
  2020     show "M \<subseteq> dynkin \<Omega> M"
  2021       using dynkin_Basic by auto
  2022     show "dynkin \<Omega> M \<subseteq> M"
  2023       by (intro dynkin_subset) auto
  2024   qed
  2025   then show ?thesis
  2026     by (auto simp: dynkin_def)
  2027 qed
  2028 
  2029 lemma (in dynkin_system) dynkin_lemma:
  2030   assumes "Int_stable E"
  2031   and E: "E \<subseteq> M" "M \<subseteq> sigma_sets \<Omega> E"
  2032   shows "sigma_sets \<Omega> E = M"
  2033 proof -
  2034   have "E \<subseteq> Pow \<Omega>"
  2035     using E sets_into_space by force
  2036   then have "sigma_sets \<Omega> E = dynkin \<Omega> E"
  2037     using `Int_stable E` by (rule sigma_eq_dynkin)
  2038   moreover then have "dynkin \<Omega> E = M"
  2039     using assms dynkin_subset[OF E(1)] by simp
  2040   ultimately show ?thesis
  2041     using assms by (auto simp: dynkin_def)
  2042 qed
  2043 
  2044 lemma sigma_sets_induct_disjoint[consumes 3, case_names basic empty compl union]:
  2045   assumes "Int_stable G"
  2046     and closed: "G \<subseteq> Pow \<Omega>"
  2047     and A: "A \<in> sigma_sets \<Omega> G"
  2048   assumes basic: "\<And>A. A \<in> G \<Longrightarrow> P A"
  2049     and empty: "P {}"
  2050     and compl: "\<And>A. A \<in> sigma_sets \<Omega> G \<Longrightarrow> P A \<Longrightarrow> P (\<Omega> - A)"
  2051     and union: "\<And>A. disjoint_family A \<Longrightarrow> range A \<subseteq> sigma_sets \<Omega> G \<Longrightarrow> (\<And>i. P (A i)) \<Longrightarrow> P (\<Union>i::nat. A i)"
  2052   shows "P A"
  2053 proof -
  2054   let ?D = "{ A \<in> sigma_sets \<Omega> G. P A }"
  2055   interpret sigma_algebra \<Omega> "sigma_sets \<Omega> G"
  2056     using closed by (rule sigma_algebra_sigma_sets)
  2057   from compl[OF _ empty] closed have space: "P \<Omega>" by simp
  2058   interpret dynkin_system \<Omega> ?D
  2059     by default (auto dest: sets_into_space intro!: space compl union)
  2060   have "sigma_sets \<Omega> G = ?D"
  2061     by (rule dynkin_lemma) (auto simp: basic `Int_stable G`)
  2062   with A show ?thesis by auto
  2063 qed
  2064 
  2065 end